config/firewall/rules.pl

   1 #!/usr/bin/perl -w
   2 ###############################################################################
   3 #                                                                             #
   4 # IPFire.org - A linux based firewall                                         #
   5 # Copyright (C) 2013 Alexander Marx <amarx@ipfire.org>                        #
   6 #                                                                             #
   7 # This program is free software: you can redistribute it and/or modify        #
   8 # it under the terms of the GNU General Public License as published by        #
   9 # the Free Software Foundation, either version 3 of the License, or           #
  10 # (at your option) any later version.                                         #
  11 #                                                                             #
  12 # This program is distributed in the hope that it will be useful,             #
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of              #
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the               #
  15 # GNU General Public License for more details.                                #
  16 #                                                                             #
  17 # You should have received a copy of the GNU General Public License           #
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.       #
  19 #                                                                             #
  20 ###############################################################################
  21
  22 use strict;
  23
  24 require '/var/ipfire/general-functions.pl';
  25 require "${General::swroot}/lang.pl";
  26 require "/usr/lib/firewall/firewall-lib.pl";
  27
  28 # Set to one to enable debugging mode.
  29 my $DEBUG = 0;
  30
  31 my $IPTABLES = "iptables --wait";
  32
  33 # iptables chains
  34 my $CHAIN_INPUT           = "INPUTFW";
  35 my $CHAIN_FORWARD         = "FORWARDFW";
  36 my $CHAIN_OUTPUT          = "OUTGOINGFW";
  37 my $CHAIN                 = $CHAIN_FORWARD;
  38 my $CHAIN_NAT_SOURCE      = "NAT_SOURCE";
  39 my $CHAIN_NAT_DESTINATION = "NAT_DESTINATION";
  40 my $CHAIN_MANGLE_NAT_DESTINATION_FIX = "NAT_DESTINATION";
  41 my @VALID_CHAINS          = ($CHAIN_INPUT, $CHAIN_FORWARD, $CHAIN_OUTPUT);
  42 my @ANY_ADDRESSES         = ("0.0.0.0/0.0.0.0", "0.0.0.0/0", "0/0");
  43
  44 my @PROTOCOLS = ("tcp", "udp", "icmp", "igmp", "ah", "esp", "gre", "ipv6", "ipip");
  45 my @PROTOCOLS_WITH_PORTS = ("tcp", "udp");
  46
  47 my @VALID_TARGETS = ("ACCEPT", "DROP", "REJECT");
  48
  49 my %fwdfwsettings=();
  50 my %defaultNetworks=();
  51 my %configfwdfw=();;
  52 my %customgrp=();
  53 my %configinputfw=();
  54 my %configoutgoingfw=();
  55 my %confignatfw=();
  56 my %aliases=();
  57 my @p2ps=();
  58
  59 my $configfwdfw         = "${General::swroot}/firewall/config";
  60 my $configinput     = "${General::swroot}/firewall/input";
  61 my $configoutgoing  = "${General::swroot}/firewall/outgoing";
  62 my $p2pfile                     = "${General::swroot}/firewall/p2protocols";
  63 my $configgrp           = "${General::swroot}/fwhosts/customgroups";
  64 my $netsettings         = "${General::swroot}/ethernet/settings";
  65
  66 &General::readhash("${General::swroot}/firewall/settings", \%fwdfwsettings);
  67 &General::readhash("$netsettings", \%defaultNetworks);
  68 &General::readhasharray($configfwdfw, \%configfwdfw);
  69 &General::readhasharray($configinput, \%configinputfw);
  70 &General::readhasharray($configoutgoing, \%configoutgoingfw);
  71 &General::readhasharray($configgrp, \%customgrp);
  72 &General::get_aliases(\%aliases);
  73
  74 my @log_limit_options = &make_log_limit_options();
  75
  76 # MAIN
  77 &main();
  78
  79 sub main {
  80         # Flush all chains.
  81         &flush();
  82
  83         # Reload firewall rules.
  84         &preparerules();
  85
  86         # Load P2P block rules.
  87         &p2pblock();
  88
  89         # Reload firewall policy.
  90         run("/usr/sbin/firewall-policy");
  91 }
  92
  93 sub run {
  94         # Executes or prints the given shell command.
  95         my $command = shift;
  96
  97         if ($DEBUG) {
  98                 print "$command\n";
  99         } else {
 100                 system "$command";
 101
 102                 if ($?) {
 103                         print_error("ERROR: $command");
 104                 }
 105         }
 106 }
 107
 108 sub print_error {
 109         my $message = shift;
 110
 111         print STDERR "$message\n";
 112 }
 113
 114 sub print_rule {
 115         my $hash = shift;
 116
 117         print "\nRULE:";
 118
 119         my $i = 0;
 120         foreach (@$hash) {
 121                 printf("  %2d: %s", $i++, $_);
 122         }
 123         print "\n";
 124 }
 125
 126 sub flush {
 127         run("$IPTABLES -F $CHAIN_INPUT");
 128         run("$IPTABLES -F $CHAIN_FORWARD");
 129         run("$IPTABLES -F $CHAIN_OUTPUT");
 130         run("$IPTABLES -t nat -F $CHAIN_NAT_SOURCE");
 131         run("$IPTABLES -t nat -F $CHAIN_NAT_DESTINATION");
 132         run("$IPTABLES -t mangle -F $CHAIN_MANGLE_NAT_DESTINATION_FIX");
 133 }
 134
 135 sub preparerules {
 136         if (! -z  "${General::swroot}/firewall/config"){
 137                 &buildrules(\%configfwdfw);
 138         }
 139         if (! -z  "${General::swroot}/firewall/input"){
 140                 &buildrules(\%configinputfw);
 141         }
 142         if (! -z  "${General::swroot}/firewall/outgoing"){
 143                 &buildrules(\%configoutgoingfw);
 144         }
 145 }
 146
 147 sub buildrules {
 148         my $hash = shift;
 149
 150         foreach my $key (sort {$a <=> $b} keys %$hash) {
 151                 # Skip disabled rules.
 152                 next unless ($$hash{$key}[2] eq 'ON');
 153
 154                 if ($DEBUG) {
 155                         print_rule($$hash{$key});
 156                 }
 157
 158                 # Check if the target is valid.
 159                 my $target = $$hash{$key}[0];
 160                 if (!$target ~~ @VALID_TARGETS) {
 161                         print_error("Invalid target '$target' for rule $key");
 162                         next;
 163                 }
 164
 165                 # Check if the chain is valid.
 166                 my $chain = $$hash{$key}[1];
 167                 if (!$chain ~~ @VALID_CHAINS) {
 168                         print_error("Invalid chain '$chain' in rule $key");
 169                         next;
 170                 }
 171
 172                 # Collect all sources.
 173                 my @sources = &fwlib::get_addresses($hash, $key, "src");
 174
 175                 # Collect all destinations.
 176                 my @destinations = &fwlib::get_addresses($hash, $key, "tgt");
 177
 178                 # Check if logging should be enabled.
 179                 my $LOG = ($$hash{$key}[17] eq 'ON');
 180
 181                 # Check if NAT is enabled and initialize variables, that we use for that.
 182                 my $NAT = ($$hash{$key}[28] eq 'ON');
 183                 my $NAT_MODE;
 184                 if ($NAT) {
 185                         $NAT_MODE = uc($$hash{$key}[31]);
 186                 }
 187
 188                 # Set up time constraints.
 189                 my @time_options = ();
 190                 if ($$hash{$key}[18] eq 'ON') {
 191                         push(@time_options, ("-m", "time"));
 192
 193                         # Select all days of the week this match is active.
 194                         my @weekdays = ();
 195                         if ($$hash{$key}[19] ne '') {
 196                                 push (@weekdays, "Mon");
 197                         }
 198                         if ($$hash{$key}[20] ne '') {
 199                                 push (@weekdays, "Tue");
 200                         }
 201                         if ($$hash{$key}[21] ne '') {
 202                                 push (@weekdays, "Wed");
 203                         }
 204                         if ($$hash{$key}[22] ne '') {
 205                                 push (@weekdays, "Thu");
 206                         }
 207                         if ($$hash{$key}[23] ne '') {
 208                                 push (@weekdays, "Fri");
 209                         }
 210                         if ($$hash{$key}[24] ne '') {
 211                                 push (@weekdays, "Sat");
 212                         }
 213                         if ($$hash{$key}[25] ne '') {
 214                                 push (@weekdays, "Sun");
 215                         }
 216                         if (@weekdays) {
 217                                 push(@time_options, ("--weekdays", join(",", @weekdays)));
 218                         }
 219
 220                         # Convert start time.
 221                         my $time_start = &format_time($$hash{$key}[26]);
 222                         if ($time_start) {
 223                                 push(@time_options, ("--timestart", $time_start));
 224                         }
 225
 226                         # Convert end time.
 227                         my $time_stop = &format_time($$hash{$key}[27]);
 228                         if ($time_stop) {
 229                                 push(@time_options, ("--timestop", $time_stop));
 230                         }
 231                 }
 232
 233                 # Check which protocols are used in this rule and so that we can
 234                 # later group rules by protocols.
 235                 my @protocols = &get_protocols($hash, $key);
 236                 if (!@protocols) {
 237                         print_error("Invalid protocol configuration for rule $key");
 238                         next;
 239                 }
 240
 241                 foreach my $protocol (@protocols) {
 242                         # Check if the given protocol is supported.
 243                         if (($protocol ne "all") && (!$protocol ~~ @PROTOCOLS)) {
 244                                 print_error("Protocol $protocol is not supported (rule $key)");
 245                                 next;
 246                         }
 247
 248                         # Prepare protocol options (like ICMP types, ports, etc...).
 249                         my @protocol_options = &get_protocol_options($hash, $key, $protocol, 0);
 250
 251                         # Check if this protocol knows ports.
 252                         my $protocol_has_ports = ($protocol ~~ @PROTOCOLS_WITH_PORTS);
 253
 254                         foreach my $source (@sources) {
 255                                 foreach my $destination (@destinations) {
 256                                         # Skip invalid rules.
 257                                         next if (!$source || !$destination || ($destination eq "none"));
 258
 259                                         # Sanitize source.
 260                                         if ($source ~~ @ANY_ADDRESSES) {
 261                                                 $source = "";
 262                                         }
 263
 264                                         # Sanitize destination.
 265                                         if ($destination ~~ @ANY_ADDRESSES) {
 266                                                 $destination = "";
 267                                         }
 268
 269                                         # Array with iptables arguments.
 270                                         my @options = ();
 271
 272                                         # Append protocol.
 273                                         if ($protocol ne "all") {
 274                                                 push(@options, @protocol_options);
 275                                         }
 276
 277                                         # Prepare source options.
 278                                         my @source_options = ();
 279                                         if ($source =~ /mac/) {
 280                                                 push(@source_options, $source);
 281                                         } elsif ($source) {
 282                                                 push(@source_options, ("-s", $source));
 283                                         }
 284
 285                                         # Prepare destination options.
 286                                         my @destination_options = ();
 287                                         if ($destination) {
 288                                                 push(@destination_options, ("-d", $destination));
 289                                         }
 290
 291                                         # Add time constraint options.
 292                                         push(@options, @time_options);
 293
 294                                         my $firewall_is_in_source_subnet = 0;
 295                                         if ($source) {
 296                                                 $firewall_is_in_source_subnet = &firewall_is_in_subnet($source);
 297                                         }
 298
 299                                         # Process NAT rules.
 300                                         if ($NAT) {
 301                                                 my $nat_address = &fwlib::get_nat_address($$hash{$key}[29], $source);
 302
 303                                                 # Skip NAT rules if the NAT address is unknown
 304                                                 # (i.e. no internet connection has been established, yet).
 305                                                 next unless ($nat_address);
 306
 307                                                 # Destination NAT
 308                                                 if ($NAT_MODE eq "DNAT") {
 309                                                         # Make port-forwardings useable from the internal networks.
 310                                                         my @internal_addresses = &fwlib::get_internal_firewall_ip_addresses(1);
 311                                                         unless ($nat_address ~~ @internal_addresses) {
 312                                                                 &add_dnat_mangle_rules($nat_address, @options);
 313                                                         }
 314
 315                                                         my @nat_options = ();
 316                                                         if ($protocol ne "all") {
 317                                                                 my @nat_protocol_options = &get_protocol_options($hash, $key, $protocol, 1);
 318                                                                 push(@nat_options, @nat_protocol_options);
 319                                                         }
 320                                                         push(@nat_options, @source_options);
 321                                                         push(@nat_options, ("-d", $nat_address));
 322
 323                                                         my ($dnat_address, $dnat_mask) = split("/", $destination);
 324                                                         @destination_options = ("-d", $dnat_address);
 325
 326                                                         if ($protocol_has_ports) {
 327                                                                 my $dnat_port = &get_dnat_target_port($hash, $key);
 328
 329                                                                 if ($dnat_port) {
 330                                                                         $dnat_address .= ":$dnat_port";
 331                                                                 }
 332                                                         }
 333
 334                                                         if ($LOG) {
 335                                                                 run("$IPTABLES -t nat -A $CHAIN_NAT_DESTINATION @nat_options @log_limit_options -j LOG --log-prefix 'DNAT '");
 336                                                         }
 337                                                         run("$IPTABLES -t nat -A $CHAIN_NAT_DESTINATION @nat_options -j DNAT --to-destination $dnat_address");
 338
 339                                                 # Source NAT
 340                                                 } elsif ($NAT_MODE eq "SNAT") {
 341                                                         my @nat_options = @options;
 342
 343                                                         push(@nat_options, @source_options);
 344                                                         push(@nat_options, @destination_options);
 345
 346                                                         if ($LOG) {
 347                                                                 run("$IPTABLES -t nat -A $CHAIN_NAT_SOURCE @nat_options @log_limit_options -j LOG --log-prefix 'SNAT '");
 348                                                         }
 349                                                         run("$IPTABLES -t nat -A $CHAIN_NAT_SOURCE @nat_options -j SNAT --to-source $nat_address");
 350                                                 }
 351                                         }
 352
 353                                         push(@options, @source_options);
 354
 355                                         if ($firewall_is_in_source_subnet && ($fwdfwsettings{"POLICY"} eq "MODE1") && ($chain eq $CHAIN_FORWARD)) {
 356                                                 if ($LOG && !$NAT) {
 357                                                         run("$IPTABLES -A $CHAIN_INPUT @options @log_limit_options -j LOG --log-prefix '$CHAIN_INPUT '");
 358                                                 }
 359                                                 run("$IPTABLES -A $CHAIN_INPUT @options -j $target");
 360                                         }
 361
 362                                         push(@options, @destination_options);
 363
 364                                         # Insert firewall rule.
 365                                         if ($LOG && !$NAT) {
 366                                                 run("$IPTABLES -A $chain @options @log_limit_options -j LOG --log-prefix '$chain '");
 367                                         }
 368                                         run("$IPTABLES -A $chain @options -j $target");
 369                                 }
 370                         }
 371                 }
 372         }
 373 }
 374
 375 # Formats the given timestamp into the iptables format which is "hh:mm" UTC.
 376 sub format_time {
 377         my $val = shift;
 378
 379         # Convert the given time into minutes.
 380         my $minutes = &time_convert_to_minutes($val);
 381
 382         # Move the timestamp into UTC.
 383         $minutes += &time_utc_offset();
 384
 385         # Make sure $minutes is between 00:00 and 23:59.
 386         if ($minutes < 0) {
 387                 $minutes += 1440;
 388         }
 389
 390         if ($minutes > 1440) {
 391                 $minutes -= 1440;
 392         }
 393
 394         # Format as hh:mm.
 395         return sprintf("%02d:%02d", $minutes / 60, $minutes % 60);
 396 }
 397
 398 # Calculates the offsets in minutes from the local timezone to UTC.
 399 sub time_utc_offset {
 400         my @localtime = localtime(time);
 401         my @gmtime = gmtime(time);
 402
 403         return ($gmtime[2] * 60 + $gmtime[1] % 60) - ($localtime[2] * 60 + $localtime[1] % 60);
 404 }
 405
 406 # Takes a timestamp like "14:00" and converts it into minutes since midnight.
 407 sub time_convert_to_minutes {
 408         my ($hrs, $min) = split(":", shift);
 409
 410         return ($hrs * 60) + $min;
 411 }
 412
 413 sub p2pblock {
 414         my $P2PSTRING = "";
 415         my $DO;
 416         open( FILE, "< $p2pfile" ) or die "Unable to read $p2pfile";
 417         @p2ps = <FILE>;
 418         close FILE;
 419         my $CMD = "-m ipp2p";
 420         foreach my $p2pentry (sort @p2ps) {
 421                 my @p2pline = split( /\;/, $p2pentry );
 422                 if ( $fwdfwsettings{'POLICY'} eq 'MODE1' ) {
 423                         $DO = "ACCEPT";
 424                         if ("$p2pline[2]" eq "on") {
 425                                 $P2PSTRING = "$P2PSTRING --$p2pline[1]";
 426                         }
 427                 }else {
 428                         $DO = "RETURN";
 429                         if ("$p2pline[2]" eq "off") {
 430                                 $P2PSTRING = "$P2PSTRING --$p2pline[1]";
 431                         }
 432                 }
 433         }
 434
 435         if($P2PSTRING) {
 436                 run("$IPTABLES -A FORWARDFW $CMD $P2PSTRING -j $DO");
 437         }
 438 }
 439
 440 sub get_protocols {
 441         my $hash = shift;
 442         my $key = shift;
 443
 444         my $uses_source_ports = ($$hash{$key}[7] eq "ON");
 445         my $uses_services = ($$hash{$key}[11] eq "ON");
 446
 447         my @protocols = ();
 448
 449         # Rules which don't have source ports or services (like ICMP, ESP, ...).
 450         if (!$uses_source_ports && !$uses_services) {
 451                 push(@protocols, $$hash{$key}[8]);
 452
 453         # Rules which either use ports or services.
 454         } elsif ($uses_source_ports || $uses_services) {
 455                 # Check if service group or service
 456                 if ($$hash{$key}[14] eq 'cust_srv') {
 457                         push(@protocols, &fwlib::get_srv_prot($$hash{$key}[15]));
 458
 459                 } elsif($$hash{$key}[14] eq 'cust_srvgrp'){
 460                         my $protos = &fwlib::get_srvgrp_prot($$hash{$key}[15]);
 461                         push(@protocols, split(",", $protos));
 462
 463                 } else {
 464                         # Fetch the protocol for this rule.
 465                         my $protocol = lc($$hash{$key}[8]);
 466
 467                         # Fetch source and destination ports for this rule.
 468                         my $source_ports = $$hash{$key}[10];
 469                         my $destination_ports = $$hash{$key}[15];
 470
 471                         # Check if ports are set for protocols which do not support ports.
 472                         if (!($protocol ~~ @PROTOCOLS_WITH_PORTS) && ($source_ports || $destination_ports)) {
 473                                 print_error("$protocol does not support ports");
 474                                 return ();
 475                         }
 476
 477                         push(@protocols, $protocol);
 478                 }
 479         }
 480
 481         # Remove all empty elements
 482         @protocols = map { $_ ? $_ : () } @protocols;
 483
 484         # If no protocol has been defined, we assume "all".
 485         if (!@protocols) {
 486                 push(@protocols, "all");
 487         }
 488
 489         # Make all protocol names lowercase.
 490         @protocols = map { lc } @protocols;
 491
 492         return @protocols;
 493 }
 494
 495 sub get_protocol_options {
 496         my $hash = shift;
 497         my $key  = shift;
 498         my $protocol = shift;
 499         my $nat_options_wanted = shift;
 500         my @options = ();
 501
 502         # Nothing to do if no protocol is specified.
 503         if ($protocol eq "all") {
 504                 return @options;
 505         } else {
 506                 push(@options, ("-p", $protocol));
 507         }
 508
 509         # Process source ports.
 510         my $use_src_ports = ($$hash{$key}[7] eq "ON");
 511         my $src_ports     = $$hash{$key}[10];
 512
 513         if ($use_src_ports && $src_ports) {
 514                 push(@options, &format_ports($src_ports, "src"));
 515         }
 516
 517         # Process destination ports.
 518         my $use_dst_ports  = ($$hash{$key}[11] eq "ON");
 519         my $use_dnat       = (($$hash{$key}[28] eq "ON") && ($$hash{$key}[31] eq "dnat"));
 520
 521         if ($use_dst_ports) {
 522                 my $dst_ports_mode = $$hash{$key}[14];
 523                 my $dst_ports      = $$hash{$key}[15];
 524
 525                 if (($dst_ports_mode eq "TGT_PORT") && $dst_ports) {
 526                         if ($nat_options_wanted && $use_dnat && $$hash{$key}[30]) {
 527                                 $dst_ports = $$hash{$key}[30];
 528                         }
 529                         push(@options, &format_ports($dst_ports, "dst"));
 530
 531                 } elsif ($dst_ports_mode eq "cust_srv") {
 532                         if ($protocol eq "ICMP") {
 533                                 push(@options, ("--icmp-type", &fwlib::get_srv_port($dst_ports, 3, "ICMP")));
 534                         } else {
 535                                 $dst_ports = &fwlib::get_srv_port($dst_ports, 1, uc($protocol));
 536                                 push(@options, &format_ports($dst_ports, "dst"));
 537                         }
 538
 539                 } elsif ($dst_ports_mode eq "cust_srvgrp") {
 540                         push(@options, &fwlib::get_srvgrp_port($dst_ports, uc($protocol)));
 541                 }
 542         }
 543
 544         # Check if a single ICMP type is selected.
 545         if (!$use_src_ports && !$use_dst_ports && $protocol eq "icmp") {
 546                 my $icmp_type = $$hash{$key}[9];
 547
 548                 if (($icmp_type ne "All ICMP-Types") && $icmp_type) {
 549                         push(@options, ("--icmp-type", $icmp_type));
 550                 }
 551         }
 552
 553         return @options;
 554 }
 555
 556 sub format_ports {
 557         my $ports = shift;
 558         my $type = shift;
 559
 560         my $arg;
 561         if ($type eq "src") {
 562                 $arg = "--sport";
 563         } elsif ($type eq "dst") {
 564                 $arg = "--dport";
 565         }
 566
 567         my @options = ();
 568
 569         if ($ports =~ /\|/) {
 570                 $ports =~ s/\|/,/g;
 571                 push(@options, ("-m", "multiport"));
 572         }
 573
 574         if ($ports) {
 575                 push(@options, ($arg, $ports));
 576         }
 577
 578         return @options;
 579 }
 580
 581 sub get_dnat_target_port {
 582         my $hash = shift;
 583         my $key  = shift;
 584
 585         if ($$hash{$key}[14] eq "TGT_PORT") {
 586                 my $port = $$hash{$key}[15];
 587                 my $external_port = $$hash{$key}[30];
 588
 589                 if ($external_port && ($port ne $external_port)) {
 590                         return $$hash{$key}[15];
 591                 }
 592         }
 593 }
 594
 595 sub add_dnat_mangle_rules {
 596         my $nat_address = shift;
 597         my @options = @_;
 598
 599         my $mark = 0;
 600         foreach my $zone ("GREEN", "BLUE", "ORANGE") {
 601                 $mark++;
 602
 603                 # Skip rule if not all required information exists.
 604                 next unless (exists $defaultNetworks{$zone . "_NETADDRESS"});
 605                 next unless (exists $defaultNetworks{$zone . "_NETMASK"});
 606
 607                 my @mangle_options = @options;
 608
 609                 my $netaddress = $defaultNetworks{$zone . "_NETADDRESS"};
 610                 $netaddress .= "/" . $defaultNetworks{$zone . "_NETMASK"};
 611
 612                 push(@mangle_options, ("-s", $netaddress, "-d", $nat_address));
 613                 push(@mangle_options, ("-j", "MARK", "--set-mark", $mark));
 614
 615                 run("$IPTABLES -t mangle -A $CHAIN_MANGLE_NAT_DESTINATION_FIX @mangle_options");
 616         }
 617 }
 618
 619 sub make_log_limit_options {
 620         my @options = ("-m", "limit");
 621
 622         # Maybe we should get this from the configuration.
 623         my $limit = 10;
 624
 625         # We limit log messages to $limit messages per minute.
 626         push(@options, ("--limit", "$limit/min"));
 627
 628         # And we allow bursts of 2x $limit.
 629         push(@options, ("--limit-burst", $limit * 2));
 630
 631         return @options;
 632 }
 633
 634 sub firewall_is_in_subnet {
 635         my $subnet = shift;
 636
 637         # ORANGE is missing here, because nothing may ever access
 638         # the firewall from this network.
 639         my $address = &fwlib::get_internal_firewall_ip_address($subnet, 0);
 640
 641         if ($address) {
 642                 return 1;
 643         }
 644
 645         return 0;
 646 }
 647