html/cgi-bin/tor.cgi

   1 #!/usr/bin/perl
   2 ###############################################################################
   3 #                                                                             #
   4 # IPFire.org - A linux based firewall                                         #
   5 # Copyright (C) 2013  IPFire Team  <info@ipfire.org>                          #
   6 #                                                                             #
   7 # This program is free software: you can redistribute it and/or modify        #
   8 # it under the terms of the GNU General Public License as published by        #
   9 # the Free Software Foundation, either version 3 of the License, or           #
  10 # (at your option) any later version.                                         #
  11 #                                                                             #
  12 # This program is distributed in the hope that it will be useful,             #
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of              #
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the               #
  15 # GNU General Public License for more details.                                #
  16 #                                                                             #
  17 # You should have received a copy of the GNU General Public License           #
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.       #
  19 #                                                                             #
  20 ###############################################################################
  21
  22 use strict;
  23 use Locale::Codes::Country;
  24
  25 # enable only the following on debugging purpose
  26 use warnings;
  27 use CGI::Carp 'fatalsToBrowser';
  28
  29 require '/var/ipfire/general-functions.pl';
  30 require "${General::swroot}/lang.pl";
  31 require "${General::swroot}/header.pl";
  32
  33 #workaround to suppress a warning when a variable is used only once
  34 my @dummy = ( ${Header::colouryellow} );
  35 undef (@dummy);
  36
  37 my @bandwidth_limits = (
  38         1000 * 1024, # 1G
  39          500 * 1024,
  40          200 * 1024,
  41          100 * 1024, # 100M
  42           64 * 1024,
  43           50 * 1024,
  44           25 * 1024,
  45           20 * 1024,
  46           16 * 1024,
  47           10 * 1024,
  48            8 * 1024,
  49            4 * 1024,
  50            2 * 1024,
  51                1024, # 1M
  52                 512,
  53                 256,
  54                 160
  55 );
  56 my @accounting_periods = ('daily', 'weekly', 'monthly');
  57
  58 my $TOR_CONTROL_PORT = 9051;
  59
  60 my $string=();
  61 my $memory=();
  62 my @memory=();
  63 my @pid=();
  64 my @tor=();
  65 sub daemonstats
  66 {
  67         $memory = 0;
  68         # for pid and memory
  69         open(FILE, '/usr/local/bin/addonctrl tor status | ');
  70         @tor = <FILE>;
  71         close(FILE);
  72         $string = join("", @tor);
  73         $string =~ s/[a-z_]//gi;
  74         $string =~ s/\[[0-1]\;[0-9]+//gi;
  75         $string =~ s/[\(\)\.]//gi;
  76         $string =~ s/  //gi;
  77         $string =~ s/\e//gi;
  78         @pid = split(/\s/,$string);
  79         if (open(FILE, "/proc/$pid[0]/statm")){
  80                 my $temp = <FILE>;
  81                 @memory = split(/ /,$temp);
  82                 close(FILE);
  83                 }
  84         $memory+=$memory[0];
  85 }
  86 daemonstats();
  87
  88 our %netsettings = ();
  89 &General::readhash("${General::swroot}/ethernet/settings", \%netsettings);
  90
  91 our %color = ();
  92 our %mainsettings = ();
  93 &General::readhash("${General::swroot}/main/settings", \%mainsettings);
  94 &General::readhash("/srv/web/ipfire/html/themes/".$mainsettings{'THEME'}."/include/colors.txt", \%color);
  95
  96 our %settings = ();
  97
  98 $settings{'TOR_ENABLED'} = 'off';
  99 $settings{'TOR_SOCKS_PORT'} = 9050;
 100 $settings{'TOR_EXIT_COUNTRY'} = '';
 101 $settings{'TOR_USE_EXIT_NODES'} = '';
 102 $settings{'TOR_ALLOWED_SUBNETS'} = "$netsettings{'GREEN_NETADDRESS'}\/$netsettings{'GREEN_NETMASK'}";
 103 if (&Header::blue_used()) {
 104         $settings{'TOR_ALLOWED_SUBNETS'} .= ",$netsettings{'BLUE_NETADDRESS'}\/$netsettings{'BLUE_NETMASK'}";
 105 }
 106
 107 $settings{'TOR_RELAY_ENABLED'} = 'off';
 108 $settings{'TOR_RELAY_MODE'} = 'exit';
 109 $settings{'TOR_RELAY_ADDRESS'} = '';
 110 $settings{'TOR_RELAY_PORT'} = 9001;
 111 $settings{'TOR_RELAY_DIRPORT'} = 0;
 112 $settings{'TOR_RELAY_NICKNAME'} = '';
 113 $settings{'TOR_RELAY_CONTACT_INFO'} = '';
 114 $settings{'TOR_RELAY_BANDWIDTH_RATE'} = 0;
 115 $settings{'TOR_RELAY_BANDWIDTH_BURST'} = 0;
 116 $settings{'TOR_RELAY_ACCOUNTING_LIMIT'} = 0;
 117 $settings{'TOR_RELAY_ACCOUNTING_PERIOD'} = 'daily';
 118
 119 $settings{'ACTION'} = '';
 120
 121 my $errormessage = '';
 122 my $warnmessage = '';
 123
 124 &Header::showhttpheaders();
 125
 126 # Get GUI values.
 127 &Header::getcgihash(\%settings);
 128
 129 # Create tor command connection.
 130 our $torctrl = &TorConnect();
 131
 132 # Toggle enable/disable field.
 133 if ($settings{'ACTION'} eq $Lang::tr{'save'}) {
 134         if ($settings{'TOR_RELAY_NICKNAME'} ne '') {
 135                 if ($settings{'TOR_RELAY_NICKNAME'} !~ /^[a-zA-Z0-9]+$/) {
 136                         $errormessage = "$Lang::tr{'tor errmsg invalid relay name'}: $settings{'TOR_RELAY_NICKNAME'}";
 137                 }
 138         }
 139
 140         if (!&General::validport($settings{'TOR_SOCKS_PORT'})) {
 141                 $errormessage = "$Lang::tr{'tor errmsg invalid socks port'}: $settings{'TOR_SOCKS_PORT'}";
 142         }
 143
 144         if (!&General::validport($settings{'TOR_RELAY_PORT'})) {
 145                 $errormessage = "$Lang::tr{'tor errmsg invalid relay port'}: $settings{'TOR_RELAY_PORT'}";
 146         }
 147         if ($settings{'TOR_RELAY_DIRPORT'} ne '0') {
 148                 if (!&General::validport($settings{'TOR_RELAY_DIRPORT'})) {
 149                         $errormessage = "$Lang::tr{'tor errmsg invalid directory port'}: $settings{'TOR_RELAY_DIRPORT'}";
 150                 }
 151         }
 152
 153         if ($settings{'TOR_RELAY_ADDRESS'} ne '') {
 154                 if ((!&General::validfqdn($settings{'TOR_RELAY_ADDRESS'})) && (!&General::validip($settings{'TOR_RELAY_ADDRESS'}))) {
 155                         $errormessage = "$Lang::tr{'tor errmsg invalid relay address'}: $settings{'TOR_RELAY_ADDRESS'}";
 156                 }
 157         }
 158
 159         if ($settings{'TOR_RELAY_ACCOUNTING_LIMIT'} !~ /^\d+$/) {
 160                 $errormessage = "$Lang::tr{'tor errmsg invalid accounting limit'}: $settings{'TOR_RELAY_ACCOUNTING_LIMIT'}";
 161         }
 162
 163         my @temp = split(/[\n,]/,$settings{'TOR_ALLOWED_SUBNETS'});
 164         $settings{'TOR_ALLOWED_SUBNETS'} = "";
 165         foreach (@temp) {
 166                 s/^\s+//g; s/\s+$//g;
 167                 if ($_) {
 168                         unless (&General::validipandmask($_)) {
 169                                 $errormessage = "$Lang::tr{'tor errmsg invalid ip or mask'}: $_";
 170                         }
 171                         $settings{'TOR_ALLOWED_SUBNETS'} .= $_.",";
 172                 }
 173         }
 174
 175         @temp = split(/[\n,]/,$settings{'TOR_USE_EXIT_NODES'});
 176         $settings{'TOR_USE_EXIT_NODES'} = "";
 177         foreach (@temp) {
 178                 s/^\s+//g; s/\s+$//g;
 179                 if ($_) {
 180                         $settings{'TOR_USE_EXIT_NODES'} .= $_.",";
 181                 }
 182         }
 183
 184         # Burst bandwidth must be less or equal to bandwidth rate.
 185         if ($settings{'TOR_RELAY_BANDWIDTH_RATE'} == 0) {
 186                 $settings{'TOR_RELAY_BANDWIDTH_BURST'} = 0;
 187
 188         } elsif ($settings{'TOR_RELAY_BANDWIDTH_BURST'} < $settings{'TOR_RELAY_BANDWIDTH_RATE'}) {
 189                 $settings{'TOR_RELAY_BANDWIDTH_BURST'} = $settings{'TOR_RELAY_BANDWIDTH_RATE'};
 190         }
 191
 192         if ($errormessage eq '') {
 193                 # Write configuration settings to file.
 194                 &General::writehash("${General::swroot}/tor/settings", \%settings);
 195
 196                 # Update configuration files.
 197                 &BuildConfiguration();
 198         }
 199 } else {
 200         # Load settings from file.
 201         &General::readhash("${General::swroot}/tor/settings", \%settings);
 202 }
 203
 204 &showMainBox();
 205
 206 # Close Tor control connection.
 207 &TorClose($torctrl);
 208
 209 # Functions
 210
 211 sub showMainBox() {
 212         my %checked = ();
 213         my %selected = ();
 214
 215         $checked{'TOR_ENABLED'}{'on'} = '';
 216         $checked{'TOR_ENABLED'}{'off'} = '';
 217         $checked{'TOR_ENABLED'}{$settings{'TOR_ENABLED'}} = 'checked';
 218
 219         $checked{'TOR_RELAY_ENABLED'}{'on'} = '';
 220         $checked{'TOR_RELAY_ENABLED'}{'off'} = '';
 221         $checked{'TOR_RELAY_ENABLED'}{$settings{'TOR_RELAY_ENABLED'}} = 'checked';
 222
 223         &Header::openpage($Lang::tr{'tor configuration'}, 1, '');
 224         &Header::openbigbox('100%', 'left', '', $errormessage);
 225
 226         if ($errormessage) {
 227                 &Header::openbox('100%', 'left', $Lang::tr{'error messages'});
 228                 print "<font class='base'>$errormessage&nbsp;</font>\n";
 229                 &Header::closebox();
 230         }
 231
 232         print "<form method='post' action='$ENV{'SCRIPT_NAME'}'>\n";
 233
 234         &Header::openbox('100%', 'center', $Lang::tr{'tor'});
 235
 236
 237 if ( ($memory != 0) && (@pid[0] ne "///") ){
 238                 print "<table width='95%' cellspacing='0' class='tbl'>";
 239                 print "<tr><th bgcolor='$color{'color20'}' colspan='3' align='left'><strong>$Lang::tr{'tor service'}</strong></th></tr>";
 240                 print "<tr><td class='base'>$Lang::tr{'tor daemon'}</td>";
 241                 print "<td align='center' colspan='2' width='75%' bgcolor='${Header::colourgreen}'><font color='white'><strong>$Lang::tr{'running'}</strong></font></td></tr>";
 242                 print "<tr><td class='base'></td>";
 243                 print "<td bgcolor='$color{'color20'}' align='center'><strong>PID</strong></td>";
 244                 print "<td bgcolor='$color{'color20'}' align='center'><strong>$Lang::tr{'memory'}</strong></td></tr>";
 245                 print "<tr><td class='base'></td>";
 246                 print "<td bgcolor='$color{'color22'}' align='center'>@pid[0]</td>";
 247                 print "<td bgcolor='$color{'color22'}' align='center'>$memory KB</td></tr>";
 248                 print "</table>";
 249         } else {
 250                 print "<table width='95%' cellspacing='0' class='tbl'>";
 251                 print "<tr><th bgcolor='$color{'color20'}' colspan='3' align='left'><strong>$Lang::tr{'tor service'}</strong></th></tr>";
 252                 print "<tr><td class='base'>$Lang::tr{'tor daemon'}</td>";
 253                 print "<td align='center' width='75%' bgcolor='${Header::colourred}'><font color='white'><strong>$Lang::tr{'stopped'}</strong></font></td></tr>";
 254                 print "</table>";
 255         }
 256
 257         &Header::closebox();
 258
 259         &Header::openbox('100%', 'center', $Lang::tr{'tor configuration'});
 260
 261         print <<END;
 262                 <table width='95%'>
 263                         <tr>
 264                                 <td colspan='4' class='base' bgcolor='$color{'color20'}'><b>$Lang::tr{'tor common settings'}</b></td>
 265                         </tr>
 266                         <tr>
 267                                 <td width='25%' class='base'>$Lang::tr{'tor enabled'}:</td>
 268                                 <td width='30%'><input type='checkbox' name='TOR_ENABLED' $checked{'TOR_ENABLED'}{'on'} /></td>
 269                                 <td width='25%' class='base'>$Lang::tr{'tor socks port'}:&nbsp;<img src='/blob.gif' alt='*' /></td>
 270                                 <td width='20%'><input type='text' name='TOR_SOCKS_PORT' value='$settings{'TOR_SOCKS_PORT'}' size='5' /></td>
 271                         </tr>
 272                         <tr>
 273                                 <td width='25%' class='base'>$Lang::tr{'tor relay enabled'}:</td>
 274                                 <td width='30%'><input type='checkbox' name='TOR_RELAY_ENABLED' $checked{'TOR_RELAY_ENABLED'}{'on'} /></td>
 275                                 <td width='25%' class='base'></td>
 276                                 <td width='20%'></td>
 277                         </tr>
 278                 </table>
 279 END
 280
 281         my @temp = split(",", $settings{'TOR_ALLOWED_SUBNETS'});
 282         $settings{'TOR_ALLOWED_SUBNETS'} = join("\n", @temp);
 283
 284         @temp = split(",", $settings{'TOR_USE_EXIT_NODES'});
 285         $settings{'TOR_USE_EXIT_NODES'} = join("\n", @temp);
 286
 287         print <<END;
 288                 <br>
 289                 <br>
 290
 291                 <table width='95%'>
 292                         <tr>
 293                                 <td colspan='4' class='base' bgcolor='$color{'color20'}'><b>$Lang::tr{'tor acls'}</b></td>
 294                         </tr>
 295                         <tr>
 296                                 <td colspan='2' class='base' width='55%'>
 297                                         $Lang::tr{'tor allowed subnets'}:
 298                                 </td>
 299                                 <td colspan='2' width='45%'></td>
 300                         </tr>
 301                         <tr>
 302                                 <td colspan='2' class='base' width='55%'>
 303                                         <textarea name='TOR_ALLOWED_SUBNETS' cols='32' rows='3' wrap='off'>$settings{'TOR_ALLOWED_SUBNETS'}</textarea>
 304                                 </td>
 305                                 <td colspan='2' width='45%'></td>
 306                         </tr>
 307                 </table>
 308
 309                 <br>
 310                 <br>
 311
 312                 <table width='95%'>
 313                         <tr>
 314                                 <td colspan='4' class='base' bgcolor='$color{'color20'}'><b>$Lang::tr{'tor exit nodes'}</b></td>
 315                         </tr>
 316                         <tr>
 317                                 <td colspan='2' class='base' width='55%'></td>
 318                                 <td colspan='2' class='base' width='45%'>$Lang::tr{'tor use exit nodes'}:</td>
 319                         </tr>
 320                         <tr>
 321                                 <td width='50%' colspan='2'>
 322                                         <select name='TOR_EXIT_COUNTRY'>
 323                                                 <option value=''>- $Lang::tr{'tor exit country any'} -</option>
 324 END
 325
 326                 my @country_names = Locale::Codes::Country::all_country_names();
 327                 foreach my $country_name (sort @country_names) {
 328                         my $country_code = Locale::Codes::Country::country2code($country_name);
 329                         $country_code = uc($country_code);
 330                         print "<option value='$country_code'";
 331
 332                         if ($settings{'TOR_EXIT_COUNTRY'} eq $country_code) {
 333                                 print " selected";
 334                         }
 335
 336                         print ">$country_name ($country_code)</option>\n";
 337                 }
 338
 339         print <<END;
 340                                         </select>
 341                                 </td>
 342                                 <td width='50%' colspan='2'>
 343                                         <textarea name='TOR_USE_EXIT_NODES' cols='32' rows='3' wrap='off'>$settings{'TOR_USE_EXIT_NODES'}</textarea>
 344                                 </td>
 345                         </tr>
 346                 </table>
 347 END
 348
 349         &Header::closebox();
 350
 351         # Tor relay box
 352         $selected{'TOR_RELAY_MODE'}{'bridge'} = '';
 353         $selected{'TOR_RELAY_MODE'}{'exit'} = '';
 354         $selected{'TOR_RELAY_MODE'}{'private-bridge'} = '';
 355         $selected{'TOR_RELAY_MODE'}{'relay'} = '';
 356         $selected{'TOR_RELAY_MODE'}{$settings{'TOR_RELAY_MODE'}} = 'selected';
 357
 358         $selected{'TOR_RELAY_BANDWIDTH_RATE'}{'0'} = '';
 359         foreach (@bandwidth_limits) {
 360                 $selected{'TOR_RELAY_BANDWIDTH_RATE'}{$_} = '';
 361         }
 362         $selected{'TOR_RELAY_BANDWIDTH_RATE'}{$settings{'TOR_RELAY_BANDWIDTH_RATE'}} = 'selected';
 363
 364         $selected{'TOR_RELAY_BANDWIDTH_BURST'}{'0'} = '';
 365         foreach (@bandwidth_limits) {
 366                 $selected{'TOR_RELAY_BANDWIDTH_BURST'}{$_} = '';
 367         }
 368         $selected{'TOR_RELAY_BANDWIDTH_BURST'}{$settings{'TOR_RELAY_BANDWIDTH_BURST'}} = 'selected';
 369
 370         foreach (@accounting_periods) {
 371                 $selected{'TOR_RELAY_ACCOUNTING_PERIOD'}{$_} = '';
 372         }
 373         $selected{'TOR_RELAY_ACCOUNTING_PERIOD'}{$settings{'TOR_RELAY_ACCOUNTING_PERIOD'}} = 'selected';
 374
 375         &Header::openbox('100%', 'center', $Lang::tr{'tor relay configuration'});
 376
 377         print <<END;
 378                 <table width='95%'>
 379                         <tr>
 380                                 <td width='25%' class='base'>$Lang::tr{'tor relay mode'}:</td>
 381                                 <td width='30%'>
 382                                         <select name='TOR_RELAY_MODE'>
 383                                                 <option value='exit' $selected{'TOR_RELAY_MODE'}{'exit'}>$Lang::tr{'tor relay mode exit'}</option>
 384                                                 <option value='relay' $selected{'TOR_RELAY_MODE'}{'relay'}>$Lang::tr{'tor relay mode relay'}</option>
 385                                                 <option value='bridge' $selected{'TOR_RELAY_MODE'}{'bridge'}>$Lang::tr{'tor relay mode bridge'}</option>
 386                                                 <option value='private-bridge' $selected{'TOR_RELAY_MODE'}{'private-bridge'}>$Lang::tr{'tor relay mode private bridge'}</option>
 387                                         </select>
 388                                 </td>
 389                                 <td width='25%' class='base'>$Lang::tr{'tor relay nickname'}:</td>
 390                                 <td width='20%'>
 391                                         <input type='text' name='TOR_RELAY_NICKNAME' value='$settings{'TOR_RELAY_NICKNAME'}' maxlength='19' />
 392                                 </td>
 393                         </tr>
 394                         <tr>
 395                                 <td width='25%' class='base'>$Lang::tr{'tor relay address'}:</td>
 396                                 <td width='30%'>
 397                                         <input type='text' name='TOR_RELAY_ADDRESS' value='$settings{'TOR_RELAY_ADDRESS'}' />
 398                                 </td>
 399                                 <td width='25%' class='base'>$Lang::tr{'tor relay port'}:&nbsp;<img src='/blob.gif' alt='*' /></td>
 400                                 <td width='20%'>
 401                                         <input type='text' name='TOR_RELAY_PORT' value='$settings{'TOR_RELAY_PORT'}' size='5' />
 402                                 </td>
 403                         </tr>
 404                         <tr>
 405                                 <td width='25%'>&nbsp;</td>
 406                                 <td width='30%'>&nbsp;</td>
 407                                 <td width='25%' class='base'>$Lang::tr{'tor directory port'}:&nbsp;<img src='/blob.gif' alt='*' /></td>
 408                                 <td width='20%'>
 409                                         <input type='text' name='TOR_RELAY_DIRPORT' value='$settings{'TOR_RELAY_DIRPORT'}' size='5' />&nbsp;$Lang::tr{'tor 0 = disabled'}
 410                                 </td>
 411                         </tr>
 412                         <tr>
 413                                 <td width='25%' class='base'>$Lang::tr{'tor contact info'}:</td>
 414                                 <td width='75%' colspan='3'>
 415                                         <input type='text' name='TOR_RELAY_CONTACT_INFO' value='$settings{'TOR_RELAY_CONTACT_INFO'}' style='width: 98%;' />
 416                                 </td>
 417                         </tr>
 418                 </table>
 419
 420                 <br>
 421
 422                 <table width='95%'>
 423                         <tr>
 424                                 <td colspan='4' class='base' bgcolor='$color{'color20'}'><b>$Lang::tr{'tor bandwidth settings'}</b></td>
 425                         </tr>
 426                         <tr>
 427                                 <td width='25%' class='base'>$Lang::tr{'tor bandwidth rate'}:</td>
 428                                 <td width='30%' class='base'>
 429                                         <select name='TOR_RELAY_BANDWIDTH_RATE'>
 430 END
 431
 432         foreach (@bandwidth_limits) {
 433                 if ($_ >= 1024) {
 434                         print "<option value='$_' $selected{'TOR_RELAY_BANDWIDTH_RATE'}{$_}>". $_ / 1024 ." MBit/s</option>\n";
 435                 } else {
 436                         print "<option value='$_' $selected{'TOR_RELAY_BANDWIDTH_RATE'}{$_}>$_ kBit/s</option>\n";
 437                 }
 438         }
 439
 440         print <<END;
 441                                                 <option value='0' $selected{'TOR_RELAY_BANDWIDTH_RATE'}{'0'}>$Lang::tr{'tor bandwidth unlimited'}</option>
 442                                         </select>
 443                                 </td>
 444                                 <td width='25%' class='base'>$Lang::tr{'tor accounting limit'}:&nbsp;<img src='/blob.gif' alt='*' /></td>
 445                                 <td width='20%'>
 446                                         <input type='text' name='TOR_RELAY_ACCOUNTING_LIMIT' value='$settings{'TOR_RELAY_ACCOUNTING_LIMIT'}' size='12' />
 447                                 </td>
 448                         </tr>
 449                         <tr>
 450                                 <td width='25%' class='base'>$Lang::tr{'tor bandwidth burst'}:</td>
 451                                 <td width='20%' class='base'>
 452                                         <select name='TOR_RELAY_BANDWIDTH_BURST'>
 453 END
 454
 455         foreach (@bandwidth_limits) {
 456                 if ($_ >= 1024) {
 457                         print "<option value='$_' $selected{'TOR_RELAY_BANDWIDTH_BURST'}{$_}>". $_ / 1024 ." MBit/s</option>\n";
 458                 } else {
 459                         print "<option value='$_' $selected{'TOR_RELAY_BANDWIDTH_BURST'}{$_}>$_ kBit/s</option>\n";
 460                 }
 461         }
 462         print <<END;
 463                                                 <option value='0' $selected{'TOR_RELAY_BANDWIDTH_BURST'}{'0'}>$Lang::tr{'tor bandwidth unlimited'}</option>
 464                                         </select>
 465                                 </td>
 466                                 <td width='25%' class='base'>$Lang::tr{'tor accounting period'}:</td>
 467                                 <td width='20%'>
 468                                         <select name='TOR_RELAY_ACCOUNTING_PERIOD'>
 469 END
 470
 471         foreach (@accounting_periods) {
 472                 print "<option value='$_' $selected{'TOR_RELAY_ACCOUNTING_PERIOD'}{$_}>$Lang::tr{'tor accounting period '.$_}</option>";
 473         }
 474
 475         print <<END;
 476                                         </select>
 477                                 </td>
 478                         </tr>
 479                 </table>
 480 END
 481
 482         &Header::closebox();
 483
 484         print <<END;
 485                 <table width='95%'>
 486                         <tr>
 487                                 <td><img src='/blob.gif' align='top' alt='*' />&nbsp;<font class='base'>$Lang::tr{'required field'}</font></td>
 488                                 <td align='right'>&nbsp;</td>
 489                         </tr>
 490                 </table>
 491
 492                 <hr>
 493
 494                 <table width='95%'>
 495                         <tr>
 496                                 <td>&nbsp;</td>
 497                                 <td align='center'><input type='submit' name='ACTION' value='$Lang::tr{'save'}' /></td>
 498                                 <td>&nbsp;</td>
 499                         </tr>
 500                 </table>
 501 END
 502
 503         # If we have a control connection, show the stats.
 504         if ($torctrl) {
 505                 &Header::openbox('100%', 'center', $Lang::tr{'tor stats'});
 506
 507                 my @traffic = &TorTrafficStats($torctrl);
 508
 509                 if (@traffic) {
 510                         print <<END;
 511                                 <table width='95%'>
 512 END
 513
 514                 if ($settings{'TOR_RELAY_ENABLED'} eq 'on') {
 515                         my $fingerprint = &TorRelayFingerprint($torctrl);
 516                         if ($fingerprint) {
 517                                 print <<END;
 518                                         <tr>
 519                                                 <td width='40%' class='base'>$Lang::tr{'tor relay fingerprint'}:</td>
 520                                                 <td width='60%'>
 521                                                         <a href='https://atlas.torproject.org/#details/$fingerprint' target='_blank'>$fingerprint</a>
 522                                                 </td>
 523                                         </tr>
 524 END
 525                         }
 526                 }
 527
 528                 my $address = TorGetInfo($torctrl, "address");
 529                 if ($address) {
 530                         print <<END;
 531                                 <tr>
 532                                         <td width='40%' class='base'>$Lang::tr{'tor relay external address'}:</td>
 533                                         <td width='60%'>$address</td>
 534                                 </tr>
 535 END
 536                 }
 537
 538                 print <<END;
 539                                         <tr>
 540                                                 <td width='40%'>$Lang::tr{'tor traffic read written'}:</td>
 541 END
 542                         print "<td width='60%'>" . &FormatBytes($traffic[0]) ."/". &FormatBytes($traffic[1]) . "</td>";
 543                         print <<END;
 544                                         </tr>
 545                                 </table>
 546 END
 547                 }
 548
 549                 my $accounting = &TorAccountingStats($torctrl);
 550                 if ($accounting) {
 551                         print <<END;
 552                                 <table width='95%'>
 553                                         <tr>
 554                                                 <td colspan='2' class='base'><b>$Lang::tr{'tor accounting'}</b></td>
 555                                         </tr>
 556 END
 557
 558                         if ($accounting->{'hibernating'} eq "hard") {
 559                                 print <<END;
 560                                         <tr>
 561                                                 <td class='base' colspan='2' bgcolor="$Header::colourred" align='center'>
 562                                                         <font color='white'>$Lang::tr{'tor traffic limit hard'}</font>
 563                                                 </td>
 564                                         </tr>
 565 END
 566                         } elsif ($accounting->{'hibernating'} eq "soft") {
 567                                 print <<END;
 568                                         <tr>
 569                                                 <td class='base' colspan='2' bgcolor="$Header::colourorange" align='center'>
 570                                                         <font color='white'>$Lang::tr{'tor traffic limit soft'}</font>
 571                                                 </td>
 572                                         </tr>
 573 END
 574                         }
 575
 576                         print <<END;
 577                                         <tr>
 578                                                 <td width='40%' class='base'>$Lang::tr{'tor accounting interval'}</td>
 579                                                 <td width='60%'>
 580                                                         $accounting->{'interval-start'} - $accounting->{'interval-end'}
 581                                                 </td>
 582                                         </tr>
 583                                         <tr>
 584                                                 <td width='40%' class='base'>$Lang::tr{'tor accounting bytes'}</td>
 585                                                 <td width='60%'>
 586 END
 587
 588                         print &FormatBytes($accounting->{'bytes_read'}) . "/" . &FormatBytes($accounting->{'bytes_written'});
 589                         print " (" . &FormatBytes($accounting->{'bytes-left_read'}) . "/" . &FormatBytes($accounting->{'bytes-left_written'});
 590                         print " $Lang::tr{'tor accounting bytes left'})";
 591
 592                         print <<END;
 593                                                 </td>
 594                                         </tr>
 595                                 </table>
 596 END
 597                 }
 598
 599                 my @nodes = &TorORConnStatus($torctrl);
 600                 if (@nodes) {
 601                         my $nodes_length = scalar @nodes;
 602                         print <<END;
 603                                 <table width='95%'>
 604                                         <tr>
 605                                                 <td width='40%' class='base'><b>$Lang::tr{'tor connected relays'}</b></td>
 606                                                 <td width='60%' colspan='2'>($nodes_length)</td>
 607                                         </tr>
 608 END
 609
 610                         foreach my $node (@nodes) {
 611                                 print <<END;
 612                                         <tr>
 613                                                 <td width='40%'>
 614                                                         <a href='https://atlas.torproject.org/#details/$node->{'fingerprint'}' target='_blank'>
 615                                                                 $node->{'name'}
 616                                                         </a>
 617                                                 </td>
 618                                                 <td width='30%'>
 619 END
 620
 621                                 if (exists($node->{'country_code'})) {
 622                                         if (!$node->{'country_code'} or $node->{'country_code'} eq '??') {
 623                                                 print "<img src='/images/flags/blank.png' border='0' align='absmiddle'/>";
 624                                         } else {
 625                                                 print "<a href='country.cgi#$node->{'country_code'}'><img src='/images/flags/$node->{'country_code'}.png' border='0' align='absmiddle' alt='$node->{'country_code'}'></a>";
 626                                         }
 627                                 }
 628
 629                                 print <<END;
 630                                                         <a href='ipinfo.cgi?ip=$node->{'address'}'>$node->{'address'}</a>:$node->{'port'}
 631                                                 </td>
 632                                                 <td width='30%' align='right'>
 633                                                         ~$node->{'bandwidth_string'}
 634                                                 </td>
 635                                         </tr>
 636 END
 637                         }
 638                         print "</table>";
 639                 }
 640
 641                 &Header::closebox();
 642         }
 643
 644         print "</form>\n";
 645
 646         &Header::closebigbox();
 647         &Header::closepage();
 648 }
 649
 650 sub BuildConfiguration() {
 651         my %settings = ();
 652         &General::readhash("${General::swroot}/tor/settings", \%settings);
 653
 654         my $torrc = "${General::swroot}/tor/torrc";
 655
 656         open(FILE, ">$torrc");
 657
 658         # Global settings.
 659         print FILE "ControlPort $TOR_CONTROL_PORT\n";
 660
 661         if ($settings{'TOR_ENABLED'} eq 'on') {
 662                 my $strict_nodes = 0;
 663
 664                 print FILE "SocksPort 0.0.0.0:$settings{'TOR_SOCKS_PORT'}\n";
 665
 666                 my @subnets = split(",", $settings{'TOR_ALLOWED_SUBNETS'});
 667                 foreach (@subnets) {
 668                         print FILE "SocksPolicy accept $_\n" if (&General::validipandmask($_));
 669                 }
 670                 print FILE "SocksPolicy reject *\n" if (@subnets);
 671
 672                 if ($settings{'TOR_EXIT_COUNTRY'} ne '') {
 673                         $strict_nodes = 1;
 674
 675                         print FILE "ExitNodes {$settings{'TOR_EXIT_COUNTRY'}}\n";
 676                 }
 677
 678                 if ($settings{'TOR_USE_EXIT_NODES'} ne '') {
 679                         $strict_nodes = 1;
 680
 681                         my @nodes = split(",", $settings{'TOR_USE_EXIT_NODES'});
 682                         foreach (@nodes) {
 683                                 print FILE "ExitNode $_\n";
 684                         }
 685                 }
 686
 687                 if ($strict_nodes > 0) {
 688                         print FILE "StrictNodes 1\n";
 689                 }
 690         }
 691
 692         if ($settings{'TOR_RELAY_ENABLED'} eq 'on') {
 693                 # Reject access to private networks.
 694                 print FILE "ExitPolicyRejectPrivate 1\n";
 695
 696                 print FILE "ORPort $settings{'TOR_RELAY_PORT'}\n";
 697
 698                 if ($settings{'TOR_RELAY_DIRPORT'} ne '0') {
 699                         print FILE "DirPort $settings{'TOR_RELAY_DIRPORT'}\n";
 700                 }
 701
 702                 if ($settings{'TOR_RELAY_ADDRESS'} ne '') {
 703                         print FILE "Address $settings{'TOR_RELAY_ADDRESS'}\n";
 704                 }
 705
 706                 if ($settings{'TOR_RELAY_NICKNAME'} ne '') {
 707                         print FILE "Nickname $settings{'TOR_RELAY_NICKNAME'}\n";
 708                 }
 709
 710                 if ($settings{'TOR_RELAY_CONTACT_INFO'} ne '') {
 711                         print FILE "ContactInfo $settings{'TOR_RELAY_CONTACT_INFO'}\n";
 712                 }
 713
 714                 # Limit to bridge mode.
 715                 my $is_bridge = 0;
 716
 717                 if ($settings{'TOR_RELAY_MODE'} eq 'bridge') {
 718                         $is_bridge++;
 719
 720                 # Private bridge.
 721                 } elsif ($settings{'TOR_RELAY_MODE'} eq 'private-bridge') {
 722                         $is_bridge++;
 723
 724                         print FILE "PublishServerDescriptor 0\n";
 725
 726                 # Exit node.
 727                 } elsif ($settings{'TOR_RELAY_MODE'} eq 'exit') {
 728                         print FILE "ExitPolicy accept *:*\n";
 729
 730                 # Relay only.
 731                 } elsif ($settings{'TOR_RELAY_MODE'} eq 'relay') {
 732                         print FILE "ExitPolicy reject *:*\n";
 733                 }
 734
 735                 if ($is_bridge > 0) {
 736                         print FILE "BridgeRelay 1\n";
 737                         print FILE "Exitpolicy reject *:*\n";
 738                 }
 739
 740                 if ($settings{'TOR_RELAY_BANDWIDTH_RATE'} > 0) {
 741                         print FILE "RelayBandwidthRate ";
 742                         print FILE $settings{'TOR_RELAY_BANDWIDTH_RATE'} / 8;
 743                         print FILE " KB\n";
 744
 745                         if ($settings{'TOR_RELAY_BANDWIDTH_BURST'} > 0) {
 746                                 print FILE "RelayBandwidthBurst ";
 747                                 print FILE $settings{'TOR_RELAY_BANDWIDTH_BURST'} / 8;
 748                                 print FILE " KB\n";
 749                         }
 750                 }
 751
 752                 if ($settings{'TOR_RELAY_ACCOUNTING_LIMIT'} > 0) {
 753                         print FILE "AccountingMax ".$settings{'TOR_RELAY_ACCOUNTING_LIMIT'}." MB\n";
 754
 755                         if ($settings{'TOR_RELAY_ACCOUNTING_PERIOD'} eq 'daily') {
 756                                 print FILE "AccountingStart day 00:00\n";
 757                         } elsif ($settings{'TOR_RELAY_ACCOUNTING_PERIOD'} eq 'weekly') {
 758                                 print FILE "AccountingStart week 1 00:00\n";
 759                         } elsif ($settings{'TOR_RELAY_ACCOUNTING_PERIOD'} eq 'monthly') {
 760                                 print FILE "AccountingStart month 1 00:00\n";
 761                         }
 762                 }
 763         }
 764
 765         close(FILE);
 766
 767         # Restart the service.
 768         if (($settings{'TOR_ENABLED'} eq 'on') || ($settings{'TOR_RELAY_ENABLED'} eq 'on')) {
 769                 system("/usr/local/bin/torctrl restart &>/dev/null");
 770         } else {
 771                 system("/usr/local/bin/torctrl stop &>/dev/null");
 772         }
 773         # Update pid and memory
 774         daemonstats();
 775 }
 776
 777 sub TorConnect() {
 778         my $socket = new IO::Socket::INET(
 779                 Proto => 'tcp', PeerAddr => '127.0.0.1', PeerPort => $TOR_CONTROL_PORT,
 780         ) or return;
 781
 782         $socket->autoflush(1);
 783
 784         # Authenticate.
 785         &TorSendCommand($socket, "AUTHENTICATE");
 786
 787         return $socket;
 788 }
 789
 790 sub TorSendCommand() {
 791         my ($socket, $cmd) = @_;
 792
 793         # Replace line ending with \r\n.
 794         chomp $cmd;
 795         $cmd .= "\r\n";
 796
 797         $socket->send($cmd);
 798
 799         my @output = ();
 800         while (my $line = <$socket>) {
 801                 # Skip empty lines.
 802                 if ($line =~ /^.\r\n$/) {
 803                         next;
 804                 }
 805
 806                 # Command has been successfully executed.
 807                 if ($line =~ /250 OK/) {
 808                         last;
 809
 810                 # Error.
 811                 } elsif ($line =~ /^5\d+/) {
 812                         last;
 813
 814                 } else {
 815                         # Remove line endings.
 816                         $line =~ s/\r\n$//;
 817
 818                         push(@output, $line);
 819                 }
 820         }
 821
 822         return @output;
 823 }
 824
 825 sub TorSendCommandOneLine() {
 826         my ($tor, $cmd) = @_;
 827
 828         my @output = &TorSendCommand($tor, $cmd);
 829         return $output[0];
 830 }
 831
 832 sub TorGetInfo() {
 833         my ($tor, $cmd) = @_;
 834
 835         my $output = &TorSendCommandOneLine($tor, "GETINFO ".$cmd);
 836
 837         my ($key, $value) = split("=", $output);
 838         return $value;
 839 }
 840
 841 sub TorClose() {
 842         my $socket = shift;
 843
 844         if ($socket) {
 845                 $socket->shutdown(2);
 846         }
 847 }
 848
 849 sub TorTrafficStats() {
 850         my $tor = shift;
 851
 852         my $output_read    = &TorGetInfo($tor, "traffic/read");
 853         my $output_written = &TorGetInfo($tor, "traffic/written");
 854
 855         return ($output_read, $output_written);
 856 }
 857
 858 sub TorRelayFingerprint() {
 859         my $tor = shift;
 860
 861         return &TorGetInfo($tor, "fingerprint");
 862 }
 863
 864 sub TorORConnStatus() {
 865         my $tor = shift;
 866         my @nodes = ();
 867
 868         my @output = &TorSendCommand($tor, "GETINFO orconn-status");
 869         foreach (@output) {
 870                 $_ =~ s/^250[\+-]orconn-status=//;
 871                 next if ($_ eq "");
 872                 last if ($_ eq ".");
 873                 next unless ($_ =~ /^\$/);
 874
 875                 my @line = split(" ", $_);
 876                 my @node = split(/[=~]/, $line[0]);
 877
 878                 my $node = &TorNodeDescription($tor, $node[0]);
 879                 if ($node) {
 880                         push(@nodes, $node);
 881                 }
 882         }
 883
 884         # Sort by names.
 885         @nodes = sort { $a->{'name'} cmp $b->{'name'} } @nodes;
 886
 887         return @nodes;
 888 }
 889
 890 sub TorNodeDescription() {
 891         my ($tor, $fingerprint) = @_;
 892         $fingerprint =~ s/\$//;
 893
 894         my $node = {
 895                 fingerprint  => $fingerprint,
 896                 exit_node    => 0,
 897         };
 898
 899         my @output = &TorSendCommand($tor, "GETINFO ns/id/$node->{'fingerprint'}");
 900
 901         foreach (@output) {
 902                 # Router
 903                 if ($_ =~ /^r (\w+) (.*) (\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}) (\d+)/) {
 904                         $node->{'name'}    = $1;
 905                         $node->{'address'} = $3;
 906                         $node->{'port'}    = $4;
 907
 908                         my $country_code = &TorGetInfo($tor, "ip-to-country/$node->{'address'}");
 909                         $node->{'country_code'} = $country_code;
 910
 911                 # Flags
 912                 } elsif ($_ =~ /^s (.*)$/) {
 913                         $node->{'flags'} = split(" ", $1);
 914
 915                         foreach my $flag ($node->{'flags'}) {
 916                                 if ($flag eq "Exit") {
 917                                         $node->{'exit_node'}++;
 918                                 }
 919                         }
 920
 921                 # Bandwidth
 922                 } elsif ($_ =~ /^w Bandwidth=(\d+)/) {
 923                         $node->{'bandwidth'} = $1 * 8;
 924                         $node->{'bandwidth_string'} = &FormatBitsPerSecond($node->{'bandwidth'});
 925                 }
 926         }
 927
 928         if (exists($node->{'name'})) {
 929                 return $node;
 930         }
 931 }
 932
 933 sub TorAccountingStats() {
 934         my $tor = shift;
 935         my $ret = {};
 936
 937         my $enabled = &TorGetInfo($tor, "accounting/enabled");
 938         if ($enabled ne '1') {
 939                 return;
 940         }
 941
 942         my @cmds = ("hibernating", "interval-start", "interval-end");
 943         foreach (@cmds) {
 944                 $ret->{$_} = &TorGetInfo($tor, "accounting/$_");
 945         }
 946
 947         my @cmds = ("bytes", "bytes-left");
 948         foreach (@cmds) {
 949                 my $output = &TorGetInfo($tor, "accounting/$_");
 950                 my @bytes = split(" ", $output);
 951
 952                 $ret->{$_."_read"}    = $bytes[0];
 953                 $ret->{$_."_written"} = $bytes[1];
 954         }
 955
 956         return $ret;
 957 }
 958
 959 sub FormatBytes() {
 960         my $bytes = shift;
 961
 962         my @units = ("B", "KB", "MB", "GB", "TB");
 963         my $units_index = 0;
 964
 965         while (($units_index <= $#units) && ($bytes >= 1024)) {
 966                 $units_index++;
 967                 $bytes /= 1024;
 968         }
 969
 970         return sprintf("%.2f %s", $bytes, $units[$units_index]);
 971 }
 972
 973 sub FormatBitsPerSecond() {
 974         my $bits = shift;
 975
 976         my @units = ("Bit/s", "KBit/s", "MBit/s", "GBit/s", "TBit/s");
 977         my $units_index = 0;
 978
 979         while (($units_index <= $#units) && ($bits >= 1024)) {
 980                 $units_index++;
 981                 $bits /= 1024;
 982         }
 983
 984         return sprintf("%.2f %s", $bits, $units[$units_index]);
 985 }