configure.ac

   1 ###############################################################################
   2 #                                                                             #
   3 # Pakfire - The IPFire package management system                              #
   4 # Copyright (C) 2013 Pakfire development team                                 #
   5 #                                                                             #
   6 # This program is free software: you can redistribute it and/or modify        #
   7 # it under the terms of the GNU General Public License as published by        #
   8 # the Free Software Foundation, either version 3 of the License, or           #
   9 # (at your option) any later version.                                         #
  10 #                                                                             #
  11 # This program is distributed in the hope that it will be useful,             #
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of              #
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the               #
  14 # GNU General Public License for more details.                                #
  15 #                                                                             #
  16 # You should have received a copy of the GNU General Public License           #
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.       #
  18 #                                                                             #
  19 ###############################################################################
  20
  21 AC_PREREQ([2.69])
  22
  23 AC_INIT([pakfire],
  24         [0.9.27],
  25         [info@ipfire.org],
  26         [pakfire],
  27         [http://git.ipfire.org/?p=pakfire.git;a=summary])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36
  37 AM_INIT_AUTOMAKE([
  38         foreign
  39         1.11
  40         -Wall
  41         -Wno-portability
  42         silent-rules
  43         tar-pax
  44         subdir-objects
  45 ])
  46 AM_SILENT_RULES([yes])
  47 LT_PREREQ(2.2)
  48 LT_INIT([disable-static])
  49
  50 IT_PROG_INTLTOOL([0.40.0])
  51
  52 XGETTEXT="${XGETTEXT} --keyword=_:1,2 --keyword=N_:1,2 --no-location"
  53
  54 GETTEXT_PACKAGE=pakfire
  55 AC_SUBST(GETTEXT_PACKAGE)
  56
  57 AC_PROG_LN_S
  58 AC_PROG_MKDIR_P
  59 AC_PROG_SED
  60
  61 AC_ARG_ENABLE([debug],
  62         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
  63         [], [enable_debug=no])
  64 AS_IF([test "x$enable_debug" = "xyes"], [
  65         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  66 ])
  67
  68 # Online Tests
  69 AC_ARG_ENABLE([online-tests],
  70         AS_HELP_STRING(
  71                 [--enable-online-tests],
  72                 [enable tests that require internet access @<:@default=disabled@:>@]
  73         ), [], [enable_online_tests=no]
  74 )
  75 AS_IF([test "x$enable_online_tests" = "xyes"], [
  76         AC_DEFINE(ENABLE_ONLINE_TESTS, [1], [Online Tests])
  77 ])
  78
  79 # Man Pages
  80
  81 have_man_pages=no
  82 AC_ARG_ENABLE(man_pages, AS_HELP_STRING([--disable-man-pages],
  83         [do not install man pages]))
  84 AS_IF([test "x$enable_man_pages" != xno], [have_man_pages=yes])
  85 AM_CONDITIONAL(ENABLE_MAN_PAGES, [test "x$have_man_pages" = "xyes"])
  86
  87 AC_PATH_PROG([XSLTPROC], [xsltproc])
  88
  89 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
  90 if test "${have_man_pages}" = "yes" && test -z "${ASCIIDOC}"; then
  91         AC_MSG_ERROR([Required program 'asciidoc' not found])
  92 fi
  93
  94 # pkg-config
  95 PKG_PROG_PKG_CONFIG
  96 # This makes sure pkg.m4 is available.
  97 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
  98
  99 # C Compiler
 100 AC_PROG_CC
 101
 102 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 103         -Wall \
 104         -Wchar-subscripts \
 105         -Wformat-security \
 106         -Wmissing-declarations \
 107         -Wmissing-prototypes \
 108         -Wnested-externs \
 109         -Wpointer-arith \
 110         -Wshadow \
 111         -Wsign-compare \
 112         -Wstrict-prototypes \
 113         -Wtype-limits \
 114 ])
 115
 116 # Enable -fanalyzer if requested
 117 AC_ARG_ENABLE([analyzer],
 118         AS_HELP_STRING([--enable-analyzer], [enable static analyzer (-fanalyzer) @<:@default=disabled@:>@]),
 119         [], [enable_analyzer=no])
 120 AS_IF([test "x$enable_analyzer" = "xyes"],
 121         CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [-fanalyzer])
 122 )
 123
 124 # Enable -fno-semantic-interposition (if available)
 125 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [-fno-semantic-interposition])
 126 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [-fno-semantic-interposition])
 127
 128 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 129 AC_SUBST([OUR_CFLAGS], $with_cflags)
 130 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 131
 132 # C Types
 133 AC_TYPE_INT64_T
 134 AC_TYPE_INTMAX_T
 135 AC_TYPE_INTPTR_T
 136 AC_TYPE_MODE_T
 137 AC_TYPE_OFF_T
 138 AC_TYPE_PID_T
 139 AC_TYPE_SIZE_T
 140 AC_TYPE_SSIZE_T
 141 AC_TYPE_UID_T
 142 AC_TYPE_UINT64_T
 143
 144 # Bison
 145 AC_PROG_YACC
 146
 147 if test -z "${ac_cv_prog_YACC}"; then
 148         echo "*** Error: No suitable bison/yacc found. ***"
 149         echo "    Please install the 'bison' package."
 150         exit 1
 151 fi
 152
 153 # Flex
 154 AM_PROG_LEX
 155
 156 if test -z "${ac_cv_prog_LEX}"; then
 157         echo "*** Error: No suitable flex/lex found. ***"
 158         echo "    Please install the 'flex' package."
 159         exit 1
 160 fi
 161
 162 AC_C_CONST
 163 AC_CHECK_LIB([m], [round])
 164
 165 AC_CHECK_HEADERS([ \
 166         ctype.h \
 167         dirent.h \
 168         errno.h \
 169         fcntl.h \
 170         fnmatch.h \
 171         fts.h \
 172         ftw.h \
 173         glob.h \
 174         grp.h \
 175         libgen.h \
 176         libintl.h \
 177         linux/capability.h \
 178         linux/limits.h \
 179         linux/magic.h \
 180         linux/sched.h \
 181         math.h \
 182         pwd.h \
 183         regex.h \
 184         sched.h \
 185         signal.h \
 186         stdarg.h \
 187         stdint.h \
 188         stdio.h \
 189         stdlib.h \
 190         string.h \
 191         syslog.h \
 192         sys/capability.h \
 193         sys/epoll.h \
 194         sys/file.h \
 195         sys/ioctl.h \
 196         sys/mount.h \
 197         sys/personality.h \
 198         sys/prctl.h \
 199         sys/random.h \
 200         sys/resource.h \
 201         sys/sendfile.h \
 202         sys/stat.h \
 203         sys/sysmacros.h \
 204         sys/types.h \
 205         sys/user.h \
 206         sys/utsname.h \
 207         sys/vfs.h \
 208         sys/wait.h \
 209         time.h \
 210         unistd.h \
 211         utime.h
 212 ])
 213
 214 AC_CHECK_FUNCS([ \
 215         asprintf \
 216         epoll_ctl \
 217         epoll_create1 \
 218         epoll_wait \
 219         flock \
 220         fnctl \
 221         fts_close \
 222         fts_open \
 223         fts_read \
 224         getpid \
 225         glob \
 226         nftw \
 227         openlog \
 228         personality \
 229         prctl \
 230         remove \
 231         secure_getenv \
 232         sendfile \
 233         snprintf \
 234         strcmp \
 235         strdup \
 236         syslog \
 237         qsort \
 238         uname \
 239         unlink \
 240         vasprintf \
 241         vsnprintf
 242 ])
 243
 244 # Python Stuff
 245 AM_PATH_PYTHON([3.6])
 246
 247 AX_PYTHON_MODULE([cpuinfo], [fatal])
 248 AX_PYTHON_MODULE([kerberos], [fatal])
 249 AX_PYTHON_MODULE([psutil], [fatal])
 250 AX_PYTHON_MODULE([setproctitle], [fatal])
 251 AX_PYTHON_MODULE([systemd], [fatal])
 252 AX_PYTHON_MODULE([tornado], [fatal])
 253
 254 # Libraries we depend on
 255 PKG_CHECK_MODULES([ARCHIVE], [libarchive >= 3.4.0])
 256 PKG_CHECK_MODULES([CAP], [libcap])
 257 PKG_CHECK_MODULES([CURL], [libcurl])
 258 PKG_CHECK_MODULES([GPGME], [gpgme >= 1.6.0])
 259 PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}-embed],
 260         [], [PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}])])
 261 PKG_CHECK_MODULES([JSON_C], [json-c >= 0.15])
 262 PKG_CHECK_MODULES([LZMA], [liblzma])
 263 PKG_CHECK_MODULES([MOUNT], [mount])
 264 PKG_CHECK_MODULES([OPENSSL], [openssl >= 1.1.1])
 265 PKG_CHECK_MODULES([PCRE2], [libpcre2-8])
 266 PKG_CHECK_MODULES([SECCOMP], [libseccomp])
 267 PKG_CHECK_MODULES([SOLV], [libsolv >= 0.7.5])
 268 PKG_CHECK_MODULES([SOLVEXT], [libsolvext >= 0.7.5])
 269 PKG_CHECK_MODULES([SQLITE3], [sqlite3])
 270 PKG_CHECK_MODULES([SYSTEMD], [libsystemd],
 271         [AC_DEFINE([HAVE_SYSTEMD], [1], [Use systemd])])
 272 PKG_CHECK_MODULES([UUID], [uuid])
 273 PKG_CHECK_MODULES([ZSTD], [libzstd])
 274
 275 AC_ARG_WITH([systemdsystemunitdir],
 276         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 277         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 278 AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 279 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir"])
 280
 281 AC_DEFINE_UNQUOTED([PAKFIRE_CONFIG_DIR], ["${sysconfdir}/${PACKAGE_NAME}"],
 282         [The path where Pakfire stores configuration files])
 283 AC_DEFINE_UNQUOTED([PAKFIRE_CACHE_DIR], ["/var/cache/${PACKAGE_NAME}"],
 284         [The path where Pakfire caches downloaded data])
 285 AC_DEFINE_UNQUOTED([PAKFIRE_PRIVATE_DIR], ["/var/lib/${PACKAGE_NAME}"],
 286         [The path where Pakfire stores its private data])
 287 AC_DEFINE_UNQUOTED([PAKFIRE_SCRIPTS_DIR], ["${PREFIX}/lib/${PACKAGE_NAME}"],
 288         [The path where Pakfire stores its scripts])
 289 AC_DEFINE_UNQUOTED([PAKFIRE_TMP_DIR], ["/var/tmp"],
 290         [The path where Pakfire stores temporary data])
 291
 292 AC_CONFIG_FILES([
 293         Makefile
 294         po/Makefile.in
 295         src/pakfire/__version__.py
 296 ])
 297
 298 AC_OUTPUT
 299 AC_MSG_RESULT([
 300         $PACKAGE_NAME $VERSION
 301
 302         Debug:                  ${enable_debug}
 303         Online Tests:           ${enable_online_tests}
 304
 305         CPPFLAGS:               ${OUR_CPPFLAGS} ${CPPFLAGS}
 306         CFLAGS:                 ${OUR_CFLAGS} ${CFLAGS}
 307         LDFLAGS:                ${OUR_LDFLAGS} ${LDFLAGS}
 308         PYTHON_CFLAGS:          ${PYTHON_DEVEL_CFLAGS}
 309         PYTHON_LIBS:            ${PYTHON_DEVEL_LIBS}
 310 ])