configure.ac

   1 ###############################################################################
   2 #                                                                             #
   3 # Pakfire - The IPFire package management system                              #
   4 # Copyright (C) 2013 Pakfire development team                                 #
   5 #                                                                             #
   6 # This program is free software: you can redistribute it and/or modify        #
   7 # it under the terms of the GNU General Public License as published by        #
   8 # the Free Software Foundation, either version 3 of the License, or           #
   9 # (at your option) any later version.                                         #
  10 #                                                                             #
  11 # This program is distributed in the hope that it will be useful,             #
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of              #
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the               #
  14 # GNU General Public License for more details.                                #
  15 #                                                                             #
  16 # You should have received a copy of the GNU General Public License           #
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.       #
  18 #                                                                             #
  19 ###############################################################################
  20
  21 AC_PREREQ([2.64])
  22
  23 AC_INIT([pakfire],
  24         [0.9.27],
  25         [info@ipfire.org],
  26         [pakfire],
  27         [http://git.ipfire.org/?p=pakfire.git;a=summary])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36
  37 AM_INIT_AUTOMAKE([
  38         foreign
  39         1.11
  40         -Wall
  41         -Wno-portability
  42         silent-rules
  43         tar-pax
  44         subdir-objects
  45 ])
  46 AM_SILENT_RULES([yes])
  47 LT_PREREQ(2.2)
  48 LT_INIT([disable-static])
  49
  50 IT_PROG_INTLTOOL([0.40.0])
  51
  52 XGETTEXT="${XGETTEXT} --keyword=_:1,2 --keyword=N_:1,2 --no-location"
  53
  54 GETTEXT_PACKAGE=pakfire
  55 AC_SUBST(GETTEXT_PACKAGE)
  56
  57 AC_PROG_LN_S
  58 AC_PROG_MKDIR_P
  59 AC_PROG_SED
  60
  61 AC_ARG_ENABLE([debug],
  62         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
  63         [], [enable_debug=no])
  64 AS_IF([test "x$enable_debug" = "xyes"], [
  65         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  66 ])
  67
  68 # Online Tests
  69 AC_ARG_ENABLE([online-tests],
  70         AS_HELP_STRING(
  71                 [--enable-online-tests],
  72                 [enable tests that require internet access @<:@default=disabled@:>@]
  73         ), [], [enable_online_tests=no]
  74 )
  75 AS_IF([test "x$enable_online_tests" = "xyes"], [
  76         AC_DEFINE(ENABLE_ONLINE_TESTS, [1], [Online Tests])
  77 ])
  78
  79 # pkg-config
  80 PKG_PROG_PKG_CONFIG
  81 # This makes sure pkg.m4 is available.
  82 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
  83
  84 # C Compiler
  85 AC_PROG_CC
  86 AC_PROG_CC_C99
  87 AC_PROG_CC_C_O
  88 AC_PROG_GCC_TRADITIONAL
  89 AC_OPENMP
  90
  91 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
  92         -pipe \
  93         -Wall \
  94         -Wextra \
  95         -Wno-inline \
  96         -Wundef \
  97         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
  98         -Wno-unused-parameter \
  99         -Wno-unused-result \
 100         -fno-strict-aliasing \
 101         -ffunction-sections \
 102         -fdata-sections \
 103         -fstack-protector-all \
 104         --param=ssp-buffer-size=4])
 105
 106 # Enable -fanalyzer if requested
 107 AC_ARG_ENABLE([analyzer],
 108         AS_HELP_STRING([--enable-analyzer], [enable static analyzer (-fanalyzer) @<:@default=disabled@:>@]),
 109         [], [enable_analyzer=no])
 110 AS_IF([test "x$enable_analyzer" = "xyes"],
 111         CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [-fanalyzer])
 112 )
 113
 114 AC_SUBST([OUR_CFLAGS], $with_cflags)
 115
 116 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*],
 117         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 118                 -Wp,-D_FORTIFY_SOURCE=2])],
 119         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 120 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 121
 122 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 123         -Wl,--as-needed \
 124         -Wl,--no-undefined \
 125         -Wl,--gc-sections \
 126         -Wl,-z,relro \
 127         -Wl,-z,now])
 128 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 129
 130 # Bison
 131 AC_PROG_YACC
 132
 133 if test -z "${ac_cv_prog_YACC}"; then
 134         echo "*** Error: No suitable bison/yacc found. ***"
 135         echo "    Please install the 'bison' package."
 136         exit 1
 137 fi
 138
 139 # Flex
 140 AM_PROG_LEX
 141
 142 if test -z "${ac_cv_prog_LEX}"; then
 143         echo "*** Error: No suitable flex/lex found. ***"
 144         echo "    Please install the 'flex' package."
 145         exit 1
 146 fi
 147
 148 AC_C_CONST
 149 AC_CHECK_LIB([m], [round])
 150
 151 AC_CHECK_HEADERS([ \
 152         ctype.h \
 153         dirent.h \
 154         errno.h \
 155         fcntl.h \
 156         fnmatch.h \
 157         fts.h \
 158         ftw.h \
 159         glob.h \
 160         grp.h \
 161         libgen.h \
 162         libintl.h \
 163         linux/limits.h \
 164         linux/magic.h \
 165         linux/sched.h \
 166         math.h \
 167         pwd.h \
 168         regex.h \
 169         sched.h \
 170         signal.h \
 171         stdarg.h \
 172         stdint.h \
 173         stdio.h \
 174         stdlib.h \
 175         string.h \
 176         syslog.h \
 177         sys/epoll.h \
 178         sys/ioctl.h \
 179         sys/mount.h \
 180         sys/personality.h \
 181         sys/random.h \
 182         sys/resource.h \
 183         sys/sendfile.h \
 184         sys/stat.h \
 185         sys/sysmacros.h \
 186         sys/types.h \
 187         sys/user.h \
 188         sys/utsname.h \
 189         sys/vfs.h \
 190         sys/wait.h \
 191         time.h \
 192         unistd.h \
 193         utime.h
 194 ])
 195
 196 AC_CHECK_FUNCS([ \
 197         asprintf \
 198         epoll_ctl \
 199         epoll_create1 \
 200         epoll_wait \
 201         fnctl \
 202         fts_close \
 203         fts_open \
 204         fts_read \
 205         getpid \
 206         glob \
 207         nftw \
 208         openlog \
 209         personality \
 210         remove \
 211         secure_getenv \
 212         sendfile \
 213         snprintf \
 214         strcmp \
 215         strdup \
 216         syslog \
 217         qsort \
 218         uname \
 219         unlink \
 220         vasprintf \
 221         vsnprintf
 222 ])
 223
 224 # Python Stuff
 225 AM_PATH_PYTHON([3.6])
 226
 227 AX_PYTHON_MODULE([systemd], [fatal])
 228 AX_PYTHON_MODULE([tornado], [fatal])
 229
 230 # Libraries we depend on
 231 PKG_CHECK_MODULES([ARCHIVE], [libarchive >= 3.5.0])
 232 PKG_CHECK_MODULES([CURL], [libcurl])
 233 PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}-embed],
 234         [], [PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}])])
 235 PKG_CHECK_MODULES([JSON_C], [json-c >= 0.15])
 236 PKG_CHECK_MODULES([LZMA], [liblzma])
 237 PKG_CHECK_MODULES([OPENSSL], [openssl >= 1.1.1])
 238 PKG_CHECK_MODULES([PCRE2], [libpcre2-8])
 239 PKG_CHECK_MODULES([SOLV], [libsolv >= 0.7.5])
 240 PKG_CHECK_MODULES([SQLITE3], [sqlite3])
 241 PKG_CHECK_MODULES([SYSTEMD], [libsystemd],
 242         [AC_DEFINE([HAVE_SYSTEMD], [1], [Use systemd])])
 243 PKG_CHECK_MODULES([UUID], [uuid])
 244 PKG_CHECK_MODULES([ZSTD], [libzstd])
 245
 246 AM_PATH_GPGME([1.6.0], [], [AC_MSG_ERROR([*** GPGME not found])])
 247
 248 AC_ARG_WITH([systemdsystemunitdir],
 249         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 250         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 251 AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 252 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir"])
 253
 254 AC_DEFINE_UNQUOTED([PAKFIRE_CONFIG_DIR], ["${sysconfdir}/${PACKAGE_NAME}"],
 255         [The path where Pakfire stores configuration files])
 256 AC_DEFINE_UNQUOTED([PAKFIRE_CACHE_DIR], ["/var/cache/${PACKAGE_NAME}"],
 257         [The path where Pakfire caches downloaded data])
 258 AC_DEFINE_UNQUOTED([PAKFIRE_PRIVATE_DIR], ["/var/lib/${PACKAGE_NAME}"],
 259         [The path where Pakfire stores its private data])
 260 AC_DEFINE_UNQUOTED([PAKFIRE_SCRIPTS_DIR], ["${PREFIX}/lib/${PACKAGE_NAME}"],
 261         [The path where Pakfire stores its scripts])
 262 AC_DEFINE_UNQUOTED([PAKFIRE_TMP_DIR], ["/var/tmp/${PACKAGE_NAME}"],
 263         [The path where Pakfire stores temporary data])
 264
 265 AC_CONFIG_FILES([
 266         Makefile
 267         po/Makefile.in
 268         src/pakfire/__version__.py
 269 ])
 270
 271 AC_OUTPUT
 272 AC_MSG_RESULT([
 273         $PACKAGE_NAME $VERSION
 274
 275         Debug:                  ${enable_debug}
 276         Online Tests:           ${enable_online_tests}
 277
 278         CFLAGS:                 ${OUR_CFLAGS} ${CFLAGS}
 279         CPPFLAGS:               ${OUR_CPPFLAGS} ${CPPFLAGS}
 280         LDFLAGS:                ${OUR_LDFLAGS} ${LDFLAGS}
 281         PYTHON_CFLAGS:          ${PYTHON_DEVEL_CFLAGS}
 282         PYTHON_LIBS:            ${PYTHON_DEVEL_LIBS}
 283 ])