configure.ac

   1 ###############################################################################
   2 #                                                                             #
   3 # Pakfire - The IPFire package management system                              #
   4 # Copyright (C) 2013 Pakfire development team                                 #
   5 #                                                                             #
   6 # This program is free software: you can redistribute it and/or modify        #
   7 # it under the terms of the GNU General Public License as published by        #
   8 # the Free Software Foundation, either version 3 of the License, or           #
   9 # (at your option) any later version.                                         #
  10 #                                                                             #
  11 # This program is distributed in the hope that it will be useful,             #
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of              #
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the               #
  14 # GNU General Public License for more details.                                #
  15 #                                                                             #
  16 # You should have received a copy of the GNU General Public License           #
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.       #
  18 #                                                                             #
  19 ###############################################################################
  20
  21 AC_PREREQ([2.64])
  22
  23 AC_INIT([pakfire],
  24         [0.9.27],
  25         [info@ipfire.org],
  26         [pakfire],
  27         [http://git.ipfire.org/?p=pakfire.git;a=summary])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36
  37 AM_INIT_AUTOMAKE([
  38         foreign
  39         1.11
  40         -Wall
  41         -Wno-portability
  42         silent-rules
  43         tar-pax
  44         subdir-objects
  45 ])
  46 AM_SILENT_RULES([yes])
  47 LT_PREREQ(2.2)
  48 LT_INIT([disable-static])
  49
  50 IT_PROG_INTLTOOL([0.40.0])
  51
  52 XGETTEXT="${XGETTEXT} --keyword=_:1,2 --keyword=N_:1,2 --no-location"
  53
  54 GETTEXT_PACKAGE=pakfire
  55 AC_SUBST(GETTEXT_PACKAGE)
  56
  57 AC_PROG_LN_S
  58 AC_PROG_MKDIR_P
  59 AC_PROG_SED
  60
  61 AC_ARG_ENABLE([debug],
  62         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
  63         [], [enable_debug=no])
  64 AS_IF([test "x$enable_debug" = "xyes"], [
  65         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  66 ])
  67
  68 # pkg-config
  69 PKG_PROG_PKG_CONFIG
  70 # This makes sure pkg.m4 is available.
  71 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
  72
  73 # C Compiler
  74 AC_PROG_CC
  75 AC_PROG_CC_C99
  76 AC_PROG_CC_C_O
  77 AC_PROG_GCC_TRADITIONAL
  78 AC_OPENMP
  79
  80 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
  81         -pipe \
  82         -Wall \
  83         -Wextra \
  84         -Wno-inline \
  85         -Wundef \
  86         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
  87         -Wno-unused-parameter \
  88         -Wno-unused-result \
  89         -fno-strict-aliasing \
  90         -ffunction-sections \
  91         -fdata-sections \
  92         -fstack-protector-all \
  93         --param=ssp-buffer-size=4])
  94 AC_SUBST([OUR_CFLAGS], $with_cflags)
  95
  96 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*],
  97         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
  98                 -Wp,-D_FORTIFY_SOURCE=2])],
  99         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 100 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 101
 102 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 103         -Wl,--as-needed \
 104         -Wl,--no-undefined \
 105         -Wl,--gc-sections \
 106         -Wl,-z,relro \
 107         -Wl,-z,now])
 108 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 109
 110 # Bison
 111 AC_PROG_YACC
 112 AC_PATH_PROG([BISON],[bison])
 113
 114 # Flex
 115 AM_PROG_LEX
 116
 117 # Python
 118 AM_PATH_PYTHON([3.6])
 119
 120 AC_C_CONST
 121 AC_CHECK_LIB([m], [round])
 122
 123 AC_CHECK_HEADERS([ \
 124         assert.h \
 125         ctypes.h \
 126         fcntl.h \
 127         math.h \
 128         regex.h \
 129         sched.h \
 130         stdarg.h \
 131         stdlib.h \
 132         string.h \
 133         syslog.h \
 134         sys/epoll.h \
 135         sys/personality.h \
 136         sys/stat.h \
 137         unistd.h
 138 ])
 139
 140 AC_CHECK_FUNCS([ \
 141         assert \
 142         epoll_ctl \
 143         epoll_create1 \
 144         epoll_wait \
 145         fnctl \
 146         personality \
 147         secure_getenv \
 148         strcmp \
 149         strdup \
 150         qsort \
 151         unshare
 152 ])
 153
 154 save_LIBS="$LIBS"
 155
 156 # libdl
 157 LIBS=
 158 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 159 DL_LIBS="$LIBS"
 160 AC_SUBST(DL_LIBS)
 161
 162 # libcap
 163 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 164
 165 LIBS=
 166 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 167 CAP_LIBS="$LIBS"
 168 AC_SUBST(CAP_LIBS)
 169
 170 # libsolv
 171 AC_CHECK_HEADERS([solv/solvversion.h], [], [AC_MSG_ERROR([*** libsolv headers not found])])
 172
 173 LIBS=
 174 AC_SEARCH_LIBS([solver_create], [solv], [], [AC_MSG_ERROR([*** libsolv library not found])])
 175 SOLV_LIBS="$LIBS"
 176 AC_SUBST(SOLV_LIBS)
 177 LIBS="$save_LIBS"
 178
 179 PKG_CHECK_MODULES([ARCHIVE], [libarchive >= 3.3.3])
 180 PKG_CHECK_MODULES([CURL], [libcurl])
 181 PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}])
 182 PKG_CHECK_MODULES([LZMA], [liblzma])
 183 PKG_CHECK_MODULES([OPENSSL], [openssl >= 1.1.1])
 184 PKG_CHECK_MODULES([PCRE2], [libpcre2-8])
 185 PKG_CHECK_MODULES([SQLITE3], [sqlite3])
 186 PKG_CHECK_MODULES([UUID], [uuid])
 187
 188 AM_PATH_GPGME([1.6.0], [], [AC_MSG_ERROR([*** GPGME not found])])
 189
 190 AC_ARG_WITH([systemdsystemunitdir],
 191         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 192         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 193 AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 194 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir"])
 195
 196 AC_DEFINE_UNQUOTED([PAKFIRE_PRIVATE_DIR], ["/var/lib/${PACKAGE_NAME}"],
 197         [The path where Pakfire stores its private data])
 198
 199 AC_CONFIG_FILES([
 200         Makefile
 201         po/Makefile.in
 202         src/pakfire/__version__.py
 203 ])
 204
 205 AC_OUTPUT
 206 AC_MSG_RESULT([
 207         $PACKAGE_NAME $VERSION
 208
 209         Debug:                  ${enable_debug}
 210
 211         CFLAGS:                 ${OUR_CFLAGS} ${CFLAGS}
 212         CPPFLAGS:               ${OUR_CPPFLAGS} ${CPPFLAGS}
 213         LDFLAGS:                ${OUR_LDFLAGS} ${LDFLAGS}
 214         PYTHON_CFLAGS:          ${PYTHON_DEVEL_CFLAGS}
 215         PYTHON_LIBS:            ${PYTHON_DEVEL_LIBS}
 216 ])