configure.ac

   1 ###############################################################################
   2 #                                                                             #
   3 # Pakfire - The IPFire package management system                              #
   4 # Copyright (C) 2013 Pakfire development team                                 #
   5 #                                                                             #
   6 # This program is free software: you can redistribute it and/or modify        #
   7 # it under the terms of the GNU General Public License as published by        #
   8 # the Free Software Foundation, either version 3 of the License, or           #
   9 # (at your option) any later version.                                         #
  10 #                                                                             #
  11 # This program is distributed in the hope that it will be useful,             #
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of              #
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the               #
  14 # GNU General Public License for more details.                                #
  15 #                                                                             #
  16 # You should have received a copy of the GNU General Public License           #
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.       #
  18 #                                                                             #
  19 ###############################################################################
  20
  21 AC_PREREQ([2.64])
  22
  23 AC_INIT([pakfire],
  24         [0.9.27],
  25         [info@ipfire.org],
  26         [pakfire],
  27         [http://git.ipfire.org/?p=pakfire.git;a=summary])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36
  37 AM_INIT_AUTOMAKE([
  38         foreign
  39         1.11
  40         -Wall
  41         -Wno-portability
  42         silent-rules
  43         tar-pax
  44         subdir-objects
  45 ])
  46 AM_SILENT_RULES([yes])
  47 LT_PREREQ(2.2)
  48 LT_INIT([disable-static])
  49
  50 IT_PROG_INTLTOOL([0.40.0])
  51
  52 XGETTEXT="${XGETTEXT} --keyword=_:1,2 --keyword=N_:1,2 --no-location"
  53
  54 GETTEXT_PACKAGE=pakfire
  55 AC_SUBST(GETTEXT_PACKAGE)
  56
  57 AC_PROG_LN_S
  58 AC_PROG_MKDIR_P
  59 AC_PROG_SED
  60
  61 AC_ARG_ENABLE([debug],
  62         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
  63         [], [enable_debug=no])
  64 AS_IF([test "x$enable_debug" = "xyes"], [
  65         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  66 ])
  67
  68 # pkg-config
  69 PKG_PROG_PKG_CONFIG
  70 # This makes sure pkg.m4 is available.
  71 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
  72
  73 # C Compiler
  74 AC_PROG_CC
  75 AC_PROG_CC_C99
  76 AC_PROG_CC_C_O
  77 AC_PROG_GCC_TRADITIONAL
  78 AC_OPENMP
  79
  80 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
  81         -pipe \
  82         -Wall \
  83         -Wextra \
  84         -Wno-inline \
  85         -Wundef \
  86         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
  87         -Wno-unused-parameter \
  88         -Wno-unused-result \
  89         -fno-strict-aliasing \
  90         -ffunction-sections \
  91         -fdata-sections \
  92         -fstack-protector-all \
  93         --param=ssp-buffer-size=4])
  94 AC_SUBST([OUR_CFLAGS], $with_cflags)
  95
  96 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*],
  97         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
  98                 -Wp,-D_FORTIFY_SOURCE=2])],
  99         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 100 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 101
 102 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 103         -Wl,--as-needed \
 104         -Wl,--no-undefined \
 105         -Wl,--gc-sections \
 106         -Wl,-z,relro \
 107         -Wl,-z,now])
 108 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 109
 110 # Bison & Flex
 111 AC_PROG_YACC
 112 AM_PROG_LEX
 113
 114 # Python
 115 AM_PATH_PYTHON([3.6])
 116
 117 AC_C_CONST
 118 AC_CHECK_LIB([m], [round])
 119
 120 AC_CHECK_HEADERS([ \
 121         assert.h \
 122         ctypes.h \
 123         math.h \
 124         regex.h \
 125         stdarg.h \
 126         stdlib.h \
 127         string.h \
 128         syslog.h \
 129         sys/personality.h \
 130         sys/stat.h \
 131         unistd.h
 132 ])
 133
 134 AC_CHECK_FUNCS([ \
 135         assert \
 136         personality \
 137         secure_getenv \
 138         strcmp \
 139         strdup
 140 ])
 141
 142 save_LIBS="$LIBS"
 143
 144 # libdl
 145 LIBS=
 146 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 147 DL_LIBS="$LIBS"
 148 AC_SUBST(DL_LIBS)
 149
 150 # libcap
 151 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 152
 153 LIBS=
 154 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 155 CAP_LIBS="$LIBS"
 156 AC_SUBST(CAP_LIBS)
 157
 158 # libsolv
 159 AC_CHECK_HEADERS([solv/solvversion.h], [], [AC_MSG_ERROR([*** libsolv headers not found])])
 160
 161 LIBS=
 162 AC_SEARCH_LIBS([solver_create], [solv], [], [AC_MSG_ERROR([*** libsolv library not found])])
 163 SOLV_LIBS="$LIBS"
 164 AC_SUBST(SOLV_LIBS)
 165 LIBS="$save_LIBS"
 166
 167 PKG_CHECK_MODULES([ARCHIVE], [libarchive])
 168 PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}])
 169 PKG_CHECK_MODULES([LZMA], [liblzma])
 170
 171 AM_PATH_LIBGCRYPT([1.8.0], [], [AC_MSG_ERROR([*** libgcrypt not found])])
 172 AM_PATH_GPGME([1.6.0], [], [AC_MSG_ERROR([*** GPGME not found])])
 173
 174 AC_ARG_WITH([systemdsystemunitdir],
 175         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 176         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 177 AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 178 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir"])
 179
 180 AC_CONFIG_FILES([
 181         Makefile
 182         po/Makefile.in
 183         src/pakfire/__version__.py
 184 ])
 185
 186 AC_OUTPUT
 187 AC_MSG_RESULT([
 188         $PACKAGE_NAME $VERSION
 189
 190         Debug:                  ${enable_debug}
 191
 192         CFLAGS:                 ${OUR_CFLAGS} ${CFLAGS}
 193         CPPFLAGS:               ${OUR_CPPFLAGS} ${CPPFLAGS}
 194         LDFLAGS:                ${OUR_LDFLAGS} ${LDFLAGS}
 195         PYTHON_CFLAGS:          ${PYTHON_DEVEL_CFLAGS}
 196         PYTHON_LIBS:            ${PYTHON_DEVEL_LIBS}
 197 ])