configure.ac

   1 ###############################################################################
   2 #                                                                             #
   3 # Pakfire - The IPFire package management system                              #
   4 # Copyright (C) 2013 Pakfire development team                                 #
   5 #                                                                             #
   6 # This program is free software: you can redistribute it and/or modify        #
   7 # it under the terms of the GNU General Public License as published by        #
   8 # the Free Software Foundation, either version 3 of the License, or           #
   9 # (at your option) any later version.                                         #
  10 #                                                                             #
  11 # This program is distributed in the hope that it will be useful,             #
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of              #
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the               #
  14 # GNU General Public License for more details.                                #
  15 #                                                                             #
  16 # You should have received a copy of the GNU General Public License           #
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.       #
  18 #                                                                             #
  19 ###############################################################################
  20
  21 AC_PREREQ([2.64])
  22
  23 AC_INIT([pakfire],
  24         [0.9.27],
  25         [info@ipfire.org],
  26         [pakfire],
  27         [http://git.ipfire.org/?p=pakfire.git;a=summary])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36
  37 AM_INIT_AUTOMAKE([
  38         foreign
  39         1.11
  40         -Wall
  41         -Wno-portability
  42         silent-rules
  43         tar-pax
  44         subdir-objects
  45 ])
  46 AM_SILENT_RULES([yes])
  47 LT_PREREQ(2.2)
  48 LT_INIT([disable-static])
  49
  50 IT_PROG_INTLTOOL([0.40.0])
  51
  52 XGETTEXT="${XGETTEXT} --keyword=_:1,2 --keyword=N_:1,2 --no-location"
  53
  54 GETTEXT_PACKAGE=pakfire
  55 AC_SUBST(GETTEXT_PACKAGE)
  56
  57 AC_PROG_LN_S
  58 AC_PROG_MKDIR_P
  59 AC_PROG_SED
  60
  61 AC_ARG_ENABLE([debug],
  62         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
  63         [], [enable_debug=no])
  64 AS_IF([test "x$enable_debug" = "xyes"], [
  65         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  66 ])
  67
  68 # pkg-config
  69 PKG_PROG_PKG_CONFIG
  70 # This makes sure pkg.m4 is available.
  71 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
  72
  73 # C Compiler
  74 AC_PROG_CC
  75 AC_PROG_CC_C99
  76 AC_PROG_CC_C_O
  77 AC_PROG_GCC_TRADITIONAL
  78 AC_OPENMP
  79
  80 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
  81         -pipe \
  82         -Wall \
  83         -Wextra \
  84         -Wno-inline \
  85         -Wundef \
  86         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
  87         -Wno-unused-parameter \
  88         -Wno-unused-result \
  89         -fno-strict-aliasing \
  90         -ffunction-sections \
  91         -fdata-sections \
  92         -fstack-protector-all \
  93         --param=ssp-buffer-size=4])
  94
  95 # Enable -fanalyzer if requested
  96 AC_ARG_ENABLE([analyzer],
  97         AS_HELP_STRING([--enable-analyzer], [enable static analyzer (-fanalyzer) @<:@default=disabled@:>@]),
  98         [], [enable_analyzer=no])
  99 AS_IF([test "x$enable_analyzer" = "xyes"],
 100         CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [-fanalyzer])
 101 )
 102
 103 AC_SUBST([OUR_CFLAGS], $with_cflags)
 104
 105 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*],
 106         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 107                 -Wp,-D_FORTIFY_SOURCE=2])],
 108         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 109 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 110
 111 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 112         -Wl,--as-needed \
 113         -Wl,--no-undefined \
 114         -Wl,--gc-sections \
 115         -Wl,-z,relro \
 116         -Wl,-z,now])
 117 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 118
 119 # Bison
 120 AC_PROG_YACC
 121
 122 if test -z "${ac_cv_prog_YACC}"; then
 123         echo "*** Error: No suitable bison/yacc found. ***"
 124         echo "    Please install the 'bison' package."
 125         exit 1
 126 fi
 127
 128 # Flex
 129 AM_PROG_LEX
 130
 131 if test -z "${ac_cv_prog_LEX}"; then
 132         echo "*** Error: No suitable flex/lex found. ***"
 133         echo "    Please install the 'flex' package."
 134         exit 1
 135 fi
 136
 137 AC_C_CONST
 138 AC_CHECK_LIB([m], [round])
 139
 140 AC_CHECK_HEADERS([ \
 141         ctypes.h \
 142         fcntl.h \
 143         math.h \
 144         regex.h \
 145         sched.h \
 146         stdarg.h \
 147         stdlib.h \
 148         string.h \
 149         syslog.h \
 150         sys/epoll.h \
 151         sys/personality.h \
 152         sys/stat.h \
 153         unistd.h
 154 ])
 155
 156 AC_CHECK_FUNCS([ \
 157         assert \
 158         epoll_ctl \
 159         epoll_create1 \
 160         epoll_wait \
 161         fnctl \
 162         personality \
 163         secure_getenv \
 164         strcmp \
 165         strdup \
 166         qsort \
 167         unshare
 168 ])
 169
 170 # Python Stuff
 171 AM_PATH_PYTHON([3.7])
 172
 173 AX_PYTHON_MODULE([systemd],
 174         [AC_MSG_ERROR([*** systemd Python module not found])])
 175
 176 # Libraries we depend on
 177 PKG_CHECK_MODULES([ARCHIVE], [libarchive >= 3.3.3])
 178 PKG_CHECK_MODULES([CURL], [libcurl])
 179 PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}-embed],
 180         [], [PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}])])
 181 PKG_CHECK_MODULES([JSON_C], [json-c])
 182 PKG_CHECK_MODULES([LZMA], [liblzma])
 183 PKG_CHECK_MODULES([OPENSSL], [openssl >= 1.1.1])
 184 PKG_CHECK_MODULES([PCRE2], [libpcre2-8])
 185 PKG_CHECK_MODULES([SOLV], [libsolv >= 0.7.5])
 186 PKG_CHECK_MODULES([SQLITE3], [sqlite3])
 187 PKG_CHECK_MODULES([SYSTEMD], [libsystemd],
 188         [AC_DEFINE([HAVE_SYSTEMD], [1], [Use systemd])])
 189 PKG_CHECK_MODULES([UUID], [uuid])
 190 PKG_CHECK_MODULES([ZSTD], [libzstd])
 191
 192 AM_PATH_GPGME([1.6.0], [], [AC_MSG_ERROR([*** GPGME not found])])
 193
 194 AC_ARG_WITH([systemdsystemunitdir],
 195         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 196         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 197 AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 198 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir"])
 199
 200 AC_DEFINE_UNQUOTED([PAKFIRE_CONFIG_PATH], ["${sysconfdir}/${PACKAGE_NAME}"],
 201         [The path where Pakfire stores configuration files])
 202 AC_DEFINE_UNQUOTED([PAKFIRE_CACHE_PATH], ["/var/cache/${PACKAGE_NAME}"],
 203         [The path where Pakfire stores temporary data])
 204 AC_DEFINE_UNQUOTED([PAKFIRE_PRIVATE_DIR], ["/var/lib/${PACKAGE_NAME}"],
 205         [The path where Pakfire stores its private data])
 206 AC_DEFINE_UNQUOTED([PAKFIRE_SCRIPTS_DIR], ["${PREFIX}/lib/${PACKAGE_NAME}"],
 207         [The path where Pakfire stores its scripts])
 208
 209 AC_CONFIG_FILES([
 210         Makefile
 211         po/Makefile.in
 212         src/pakfire/__version__.py
 213 ])
 214
 215 AC_OUTPUT
 216 AC_MSG_RESULT([
 217         $PACKAGE_NAME $VERSION
 218
 219         Debug:                  ${enable_debug}
 220
 221         CFLAGS:                 ${OUR_CFLAGS} ${CFLAGS}
 222         CPPFLAGS:               ${OUR_CPPFLAGS} ${CPPFLAGS}
 223         LDFLAGS:                ${OUR_LDFLAGS} ${LDFLAGS}
 224         PYTHON_CFLAGS:          ${PYTHON_DEVEL_CFLAGS}
 225         PYTHON_LIBS:            ${PYTHON_DEVEL_LIBS}
 226 ])