configure.ac

   1 ###############################################################################
   2 #                                                                             #
   3 # Pakfire - The IPFire package management system                              #
   4 # Copyright (C) 2013 Pakfire development team                                 #
   5 #                                                                             #
   6 # This program is free software: you can redistribute it and/or modify        #
   7 # it under the terms of the GNU General Public License as published by        #
   8 # the Free Software Foundation, either version 3 of the License, or           #
   9 # (at your option) any later version.                                         #
  10 #                                                                             #
  11 # This program is distributed in the hope that it will be useful,             #
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of              #
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the               #
  14 # GNU General Public License for more details.                                #
  15 #                                                                             #
  16 # You should have received a copy of the GNU General Public License           #
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.       #
  18 #                                                                             #
  19 ###############################################################################
  20
  21 AC_PREREQ([2.64])
  22
  23 AC_INIT([pakfire],
  24         [0.9.27],
  25         [info@ipfire.org],
  26         [pakfire],
  27         [http://git.ipfire.org/?p=pakfire.git;a=summary])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36
  37 AM_INIT_AUTOMAKE([
  38         foreign
  39         1.11
  40         -Wall
  41         -Wno-portability
  42         silent-rules
  43         tar-pax
  44         subdir-objects
  45 ])
  46 AM_SILENT_RULES([yes])
  47 LT_PREREQ(2.2)
  48 LT_INIT([disable-static])
  49
  50 IT_PROG_INTLTOOL([0.40.0])
  51
  52 XGETTEXT="${XGETTEXT} --keyword=_:1,2 --keyword=N_:1,2 --no-location"
  53
  54 GETTEXT_PACKAGE=pakfire
  55 AC_SUBST(GETTEXT_PACKAGE)
  56
  57 AC_PROG_LN_S
  58 AC_PROG_MKDIR_P
  59 AC_PROG_SED
  60
  61 AC_ARG_ENABLE([debug],
  62         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
  63         [], [enable_debug=no])
  64 AS_IF([test "x$enable_debug" = "xyes"], [
  65         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  66 ])
  67
  68 # Online Tests
  69 AC_ARG_ENABLE([online-tests],
  70         AS_HELP_STRING(
  71                 [--enable-online-tests],
  72                 [enable tests that require internet access @<:@default=disabled@:>@]
  73         ), [], [enable_online_tests=no]
  74 )
  75 AS_IF([test "x$enable_online_tests" = "xyes"], [
  76         AC_DEFINE(ENABLE_ONLINE_TESTS, [1], [Online Tests])
  77 ])
  78
  79 # Man Pages
  80
  81 have_man_pages=no
  82 AC_ARG_ENABLE(man_pages, AS_HELP_STRING([--disable-man-pages],
  83         [do not install man pages]))
  84 AS_IF([test "x$enable_man_pages" != xno], [have_man_pages=yes])
  85 AM_CONDITIONAL(ENABLE_MAN_PAGES, [test "x$have_man_pages" = "xyes"])
  86
  87 AC_PATH_PROG([XSLTPROC], [xsltproc])
  88
  89 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
  90 if test "${have_man_pages}" = "yes" && test -z "${ASCIIDOC}"; then
  91         AC_MSG_ERROR([Required program 'asciidoc' not found])
  92 fi
  93
  94 # pkg-config
  95 PKG_PROG_PKG_CONFIG
  96 # This makes sure pkg.m4 is available.
  97 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
  98
  99 # C Compiler
 100 AC_PROG_CC_STDC
 101
 102 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 103         -Wall \
 104         -Wchar-subscripts \
 105         -Wformat-security \
 106         -Wmissing-declarations \
 107         -Wmissing-prototypes \
 108         -Wnested-externs \
 109         -Wpointer-arith \
 110         -Wshadow \
 111         -Wsign-compare \
 112         -Wstrict-prototypes \
 113         -Wtype-limits \
 114 ])
 115
 116 # Enable -fanalyzer if requested
 117 AC_ARG_ENABLE([analyzer],
 118         AS_HELP_STRING([--enable-analyzer], [enable static analyzer (-fanalyzer) @<:@default=disabled@:>@]),
 119         [], [enable_analyzer=no])
 120 AS_IF([test "x$enable_analyzer" = "xyes"],
 121         CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [-fanalyzer])
 122 )
 123
 124 # Enable -fno-semantic-interposition (if available)
 125 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [-fno-semantic-interposition])
 126 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [-fno-semantic-interposition])
 127
 128 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 129 AC_SUBST([OUR_CFLAGS], $with_cflags)
 130 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 131
 132 # Bison
 133 AC_PROG_YACC
 134
 135 if test -z "${ac_cv_prog_YACC}"; then
 136         echo "*** Error: No suitable bison/yacc found. ***"
 137         echo "    Please install the 'bison' package."
 138         exit 1
 139 fi
 140
 141 # Flex
 142 AM_PROG_LEX
 143
 144 if test -z "${ac_cv_prog_LEX}"; then
 145         echo "*** Error: No suitable flex/lex found. ***"
 146         echo "    Please install the 'flex' package."
 147         exit 1
 148 fi
 149
 150 AC_C_CONST
 151 AC_CHECK_LIB([m], [round])
 152
 153 AC_CHECK_HEADERS([ \
 154         ctype.h \
 155         dirent.h \
 156         errno.h \
 157         fcntl.h \
 158         fnmatch.h \
 159         fts.h \
 160         ftw.h \
 161         glob.h \
 162         grp.h \
 163         libgen.h \
 164         libintl.h \
 165         linux/capability.h \
 166         linux/limits.h \
 167         linux/magic.h \
 168         linux/sched.h \
 169         math.h \
 170         pwd.h \
 171         regex.h \
 172         sched.h \
 173         signal.h \
 174         stdarg.h \
 175         stdint.h \
 176         stdio.h \
 177         stdlib.h \
 178         string.h \
 179         syslog.h \
 180         sys/capability.h \
 181         sys/epoll.h \
 182         sys/file.h \
 183         sys/ioctl.h \
 184         sys/mount.h \
 185         sys/personality.h \
 186         sys/prctl.h \
 187         sys/random.h \
 188         sys/resource.h \
 189         sys/sendfile.h \
 190         sys/stat.h \
 191         sys/sysmacros.h \
 192         sys/types.h \
 193         sys/user.h \
 194         sys/utsname.h \
 195         sys/vfs.h \
 196         sys/wait.h \
 197         time.h \
 198         unistd.h \
 199         utime.h
 200 ])
 201
 202 AC_CHECK_FUNCS([ \
 203         asprintf \
 204         epoll_ctl \
 205         epoll_create1 \
 206         epoll_wait \
 207         flock \
 208         fnctl \
 209         fts_close \
 210         fts_open \
 211         fts_read \
 212         getpid \
 213         glob \
 214         nftw \
 215         openlog \
 216         personality \
 217         prctl \
 218         remove \
 219         secure_getenv \
 220         sendfile \
 221         snprintf \
 222         strcmp \
 223         strdup \
 224         syslog \
 225         qsort \
 226         uname \
 227         unlink \
 228         vasprintf \
 229         vsnprintf
 230 ])
 231
 232 # Python Stuff
 233 AM_PATH_PYTHON([3.6])
 234
 235 AX_PYTHON_MODULE([systemd], [fatal])
 236 AX_PYTHON_MODULE([tornado], [fatal])
 237
 238 # Libraries we depend on
 239 PKG_CHECK_MODULES([ARCHIVE], [libarchive >= 3.5.0])
 240 PKG_CHECK_MODULES([CURL], [libcurl])
 241 PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}-embed],
 242         [], [PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}])])
 243 PKG_CHECK_MODULES([JSON_C], [json-c >= 0.15])
 244 PKG_CHECK_MODULES([LZMA], [liblzma])
 245 PKG_CHECK_MODULES([OPENSSL], [openssl >= 1.1.1])
 246 PKG_CHECK_MODULES([PCRE2], [libpcre2-8])
 247 PKG_CHECK_MODULES([SOLV], [libsolv >= 0.7.5])
 248 PKG_CHECK_MODULES([SOLVEXT], [libsolvext >= 0.7.5])
 249 PKG_CHECK_MODULES([SQLITE3], [sqlite3])
 250 PKG_CHECK_MODULES([SYSTEMD], [libsystemd],
 251         [AC_DEFINE([HAVE_SYSTEMD], [1], [Use systemd])])
 252 PKG_CHECK_MODULES([UUID], [uuid])
 253 PKG_CHECK_MODULES([ZSTD], [libzstd])
 254
 255 AM_PATH_GPGME([1.6.0], [], [AC_MSG_ERROR([*** GPGME not found])])
 256
 257 AC_ARG_WITH([systemdsystemunitdir],
 258         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 259         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 260 AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 261 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir"])
 262
 263 AC_DEFINE_UNQUOTED([PAKFIRE_CONFIG_DIR], ["${sysconfdir}/${PACKAGE_NAME}"],
 264         [The path where Pakfire stores configuration files])
 265 AC_DEFINE_UNQUOTED([PAKFIRE_CACHE_DIR], ["/var/cache/${PACKAGE_NAME}"],
 266         [The path where Pakfire caches downloaded data])
 267 AC_DEFINE_UNQUOTED([PAKFIRE_PRIVATE_DIR], ["/var/lib/${PACKAGE_NAME}"],
 268         [The path where Pakfire stores its private data])
 269 AC_DEFINE_UNQUOTED([PAKFIRE_SCRIPTS_DIR], ["${PREFIX}/lib/${PACKAGE_NAME}"],
 270         [The path where Pakfire stores its scripts])
 271 AC_DEFINE_UNQUOTED([PAKFIRE_TMP_DIR], ["/var/tmp/${PACKAGE_NAME}"],
 272         [The path where Pakfire stores temporary data])
 273
 274 AC_CONFIG_FILES([
 275         Makefile
 276         po/Makefile.in
 277         src/pakfire/__version__.py
 278 ])
 279
 280 AC_OUTPUT
 281 AC_MSG_RESULT([
 282         $PACKAGE_NAME $VERSION
 283
 284         Debug:                  ${enable_debug}
 285         Online Tests:           ${enable_online_tests}
 286
 287         CPPFLAGS:               ${OUR_CPPFLAGS} ${CPPFLAGS}
 288         CFLAGS:                 ${OUR_CFLAGS} ${CFLAGS}
 289         LDFLAGS:                ${OUR_LDFLAGS} ${LDFLAGS}
 290         PYTHON_CFLAGS:          ${PYTHON_DEVEL_CFLAGS}
 291         PYTHON_LIBS:            ${PYTHON_DEVEL_LIBS}
 292 ])