configure.ac

   1 ###############################################################################
   2 #                                                                             #
   3 # Pakfire - The IPFire package management system                              #
   4 # Copyright (C) 2017 Pakfire development team                                 #
   5 #                                                                             #
   6 # This program is free software: you can redistribute it and/or modify        #
   7 # it under the terms of the GNU General Public License as published by        #
   8 # the Free Software Foundation, either version 3 of the License, or           #
   9 # (at your option) any later version.                                         #
  10 #                                                                             #
  11 # This program is distributed in the hope that it will be useful,             #
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of              #
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the               #
  14 # GNU General Public License for more details.                                #
  15 #                                                                             #
  16 # You should have received a copy of the GNU General Public License           #
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.       #
  18 #                                                                             #
  19 ###############################################################################
  20
  21 AC_PREREQ([2.64])
  22
  23 AC_INIT([pakfire-build-service],
  24         [2017.01],
  25         [info@ipfire.org],
  26         [pakfire-build-service],
  27         [https://git.ipfire.org/?p=pbs.git;a=summary])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 AC_PREFIX_DEFAULT([/usr])
  33
  34 AM_INIT_AUTOMAKE([
  35         foreign
  36         1.11
  37         -Wall
  38         -Wno-portability
  39         silent-rules
  40         tar-pax
  41         subdir-objects
  42 ])
  43 AM_SILENT_RULES([yes])
  44
  45 IT_PROG_INTLTOOL([0.40.0])
  46
  47 XGETTEXT="${XGETTEXT} --keyword=_:1,2 --keyword=N_:1,2 --no-location"
  48
  49 GETTEXT_PACKAGE=pakfire-build-service
  50 AC_SUBST(GETTEXT_PACKAGE)
  51
  52 AC_PROG_LN_S
  53 AC_PROG_MKDIR_P
  54 AC_PROG_SED
  55
  56 # Python
  57 AM_PATH_PYTHON([3.9])
  58
  59 # pygmentize (from pygments)
  60 AC_CHECK_PROG(PYGMENTIZE, [pygmentize], [pygmentize])
  61 if test -z "${PYGMENTIZE}"; then
  62         AC_MSG_ERROR([pygmentize is required])
  63 fi
  64
  65 # SASSC
  66 AC_CHECK_PROG(SASSC, [sassc], [sassc])
  67 if test -z "${SASSC}"; then
  68         AC_MSG_ERROR([sassc is required])
  69 fi
  70
  71 # uglifyjs.terser
  72 AC_CHECK_PROG(UGLIFYJS, [uglifyjs.terser], [uglifyjs.terser])
  73 if test -z "${UGLIFYJS}"; then
  74         AC_MSG_ERROR([uglifyjs.terser is required])
  75 fi
  76
  77 save_LIBS="$LIBS"
  78
  79 # pkg-config
  80 PKG_PROG_PKG_CONFIG
  81 # This makes sure pkg.m4 is available.
  82 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
  83
  84 # ------------------------------------------------------------------------------
  85
  86 AX_PYTHON_MODULE([boto3], [fatal])
  87 AX_PYTHON_MODULE([kerberos], [fatal])
  88 AX_PYTHON_MODULE([location], [fatal])
  89 AX_PYTHON_MODULE([pygments], [fatal])
  90
  91 # ------------------------------------------------------------------------------
  92
  93 AC_ARG_WITH([systemd],
  94         AS_HELP_STRING([--with-systemd], [Enable systemd support.])
  95 )
  96
  97 AS_IF([test "x$with_systemd" != "xno"],
  98       [PKG_CHECK_MODULES(systemd, [libsystemd],
  99       [have_systemd=yes], [have_systemd=no])],
 100       [have_systemd=no]
 101 )
 102
 103 AS_IF([test "x$have_systemd" = "xyes"],
 104       [AC_MSG_CHECKING([for systemd system unit directory])
 105         AC_ARG_WITH([systemdsystemunitdir],
 106                 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 107                 [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)]
 108         )
 109
 110         AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 111
 112         if test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno; then
 113                 AC_MSG_RESULT([$systemdsystemunitdir])
 114         else
 115                 AC_MSG_ERROR([not found (try --with-systemdsystemunitdir)])
 116         fi
 117       ],
 118       [AS_IF([test "x$with_systemd" = "xyes"],
 119              [AC_MSG_ERROR([Systemd support is enabled but no systemd has been found.])
 120       ])
 121 ])
 122
 123 AM_CONDITIONAL(HAVE_SYSTEMD, [test "x$have_systemd" = "xyes"])
 124
 125 # ------------------------------------------------------------------------------
 126
 127 datadir="${datadir}/pakfire-build-service"
 128 localedir="${datadir}/translations"
 129
 130 AC_CONFIG_FILES([
 131         Makefile
 132         po/Makefile.in
 133         src/buildservice/__version__.py
 134 ])
 135
 136 AC_OUTPUT
 137 AC_MSG_RESULT([
 138         ${PACKAGE_NAME} ${VERSION}
 139
 140         prefix:                 ${prefix}
 141         sysconfdir:             ${sysconfdir}
 142
 143         Systemd support         ${have_systemd}
 144 ])