configure.ac

   1 dnl ** This is a configure script template for BIRD
   2 dnl ** Process it with autoconf to get ./configure
   3 dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz>
   4
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([conf/confbase.Y])
   7 AC_CONFIG_AUX_DIR([tools])
   8
   9 AC_ARG_ENABLE([client],
  10   [AS_HELP_STRING([--enable-client], [enable building of BIRD client @<:@yes@:>@])],
  11   [],
  12   [enable_client=yes]
  13 )
  14
  15 AC_ARG_ENABLE([debug],
  16   [AS_HELP_STRING([--enable-debug], [enable internal debugging routines @<:@no@:>@])],
  17   [],
  18   [enable_debug=no]
  19 )
  20
  21 AC_ARG_ENABLE([debug-generated],
  22   [AS_HELP_STRING([--enable-debug-generated], [enable this to abstain from generating #line @<:@no@:>@])],
  23   [],
  24   [enable_debug_generated=no]
  25 )
  26
  27 AC_ARG_ENABLE([memcheck],
  28   [AS_HELP_STRING([--enable-memcheck], [check memory allocations when debugging @<:@yes@:>@])],
  29   [],
  30   [enable_memcheck=yes]
  31 )
  32
  33 AC_ARG_ENABLE([pthreads],
  34   [AS_HELP_STRING([--enable-pthreads], [enable POSIX threads support @<:@try@:>@])],
  35   [],
  36   [enable_pthreads=try]
  37 )
  38
  39 AC_ARG_ENABLE([libssh],
  40   [AS_HELP_STRING([--enable-libssh], [enable LibSSH support together with RPKI @<:@try@:>@])],
  41   [],
  42   [enable_libssh=try]
  43 )
  44
  45 AC_ARG_ENABLE([mpls-kernel],
  46   [AS_HELP_STRING([--enable-mpls-kernel], [enable MPLS support in kernel protocol @<:@try@:>@])],
  47   [],
  48   [enable_mpls_kernel=try]
  49 )
  50
  51 AC_ARG_WITH([protocols],
  52   [AS_HELP_STRING([--with-protocols=LIST], [include specified routing protocols @<:@all@:>@])],
  53   [],
  54   [with_protocols="all"]
  55 )
  56
  57 AC_ARG_WITH([sysconfig],
  58   [AS_HELP_STRING([--with-sysconfig=FILE], [use specified BIRD system configuration file])]
  59 )
  60
  61 AC_ARG_WITH([runtimedir],
  62   [AS_HELP_STRING([--with-runtimedir=PATH], [run-state data, obsolete variant of --runstatedir])],
  63   [runstatedir="$with_runtimedir"]
  64 )
  65
  66 AC_ARG_WITH([iproutedir],
  67   [AS_HELP_STRING([--with-iproutedir=PATH], [path to iproute2 config files @<:@/etc/iproute2@:>@])],
  68   [given_iproutedir="yes"]
  69 )
  70
  71 AC_ARG_VAR([FLEX], [location of the Flex program])
  72 AC_ARG_VAR([BISON], [location of the Bison program])
  73 AC_ARG_VAR([M4], [location of the M4 program])
  74
  75
  76 if test "$srcdir" = . ; then
  77   # Building in current directory => create obj directory holding all objects
  78   objdir=obj
  79 else
  80   # Building in separate directory
  81   objdir=.
  82 fi
  83
  84 exedir=.
  85
  86 AC_SUBST([objdir])
  87 AC_SUBST([exedir])
  88 AC_SUBST([srcdir])
  89
  90 # Workaround for older Autoconfs that do not define runstatedir
  91 AS_IF([test -z "${runstatedir}"], [runstatedir='${localstatedir}/run'])
  92 AC_SUBST([runstatedir])
  93
  94 CONFIG_FILE="\$(sysconfdir)/bird.conf"
  95 AC_SUBST([CONFIG_FILE])
  96
  97 CONTROL_SOCKET="\$(runstatedir)/bird.ctl"
  98 AC_SUBST([CONTROL_SOCKET])
  99
 100 AC_SEARCH_LIBS([clock_gettime], [rt posix4],
 101   [],
 102   [AC_MSG_ERROR([Function clock_gettime not available.])]
 103 )
 104
 105 AC_CANONICAL_HOST
 106
 107 # Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC
 108 if test "$ac_test_CFLAGS" != set ; then
 109   bird_cflags_default=yes
 110 fi
 111
 112 AC_PROG_CC
 113 AC_PROG_CC_C99
 114 if test -z "$GCC" ; then
 115   AC_MSG_ERROR([This program requires the GNU C Compiler.])
 116 fi
 117
 118 BIRD_CHECK_THREAD_LOCAL
 119 if test "$bird_cv_thread_local" = yes ; then
 120   AC_DEFINE([HAVE_THREAD_LOCAL], [1], [Define to 1 if _Thread_local is available])
 121 fi
 122
 123 if test "$enable_pthreads" != no ; then
 124   BIRD_CHECK_PTHREADS
 125
 126   if test "$bird_cv_lib_pthreads" = yes ; then
 127     AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
 128     CFLAGS="$CFLAGS -pthread"
 129     LDFLAGS="$LDFLAGS -pthread"
 130     proto_bfd=bfd
 131   elif test "$enable_pthreads" = yes ; then
 132     AC_MSG_ERROR([POSIX threads not available.])
 133   fi
 134
 135   if test "$enable_pthreads" = try ; then
 136     enable_pthreads="$bird_cv_lib_pthreads"
 137   fi
 138 fi
 139
 140 if test "$bird_cflags_default" = yes ; then
 141   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign], [-Wall])
 142   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers], [-Wall -Wextra])
 143   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
 144   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 145
 146   CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wno-parentheses"
 147   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign])
 148   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers])
 149   BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
 150   BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 151 fi
 152 AC_MSG_CHECKING([CFLAGS])
 153 AC_MSG_RESULT([$CFLAGS])
 154
 155 if test "$enable_debug" = no; then
 156   BIRD_CHECK_LTO
 157 fi
 158
 159 if test "$bird_cv_c_lto" = yes; then
 160   CFLAGS="$CFLAGS -flto"
 161   LDFLAGS="$LDFLAGS -flto"
 162 fi
 163
 164 AC_PROG_CPP
 165 AC_PROG_INSTALL
 166 AC_PROG_RANLIB
 167 AC_CHECK_PROG([FLEX], [flex], [flex])
 168 AC_CHECK_PROG([BISON], [bison], [bison])
 169 AC_CHECK_PROGS([M4], [gm4 m4])
 170
 171 test -z "$FLEX"  && AC_MSG_ERROR([Flex is missing.])
 172 test -z "$BISON" && AC_MSG_ERROR([Bison is missing.])
 173 test -z "$M4"    && AC_MSG_ERROR([M4 is missing.])
 174
 175 AC_MSG_CHECKING([bison version])
 176 BIRD_CHECK_BISON_VERSION(BISON_VERSION)
 177 AC_MSG_RESULT([$BISON_VERSION])
 178 if test "$bird_bison_synclines" = yes && test "$enable_debug_generated" = no; then
 179   M4FLAGS="$M4FLAGS -s"
 180 fi
 181
 182 if test "$bird_bison_enhanced_error" = yes; then
 183   BISONFLAGS="$BISONFLAGS -Dparse.lac=full -Dparse.error=verbose"
 184 fi
 185
 186 AC_SUBST([M4FLAGS])
 187 AC_SUBST([BISONFLAGS])
 188
 189 BIRD_CHECK_PROG_FLAVOR_GNU([$M4],
 190   [],
 191   [AC_MSG_ERROR([Provided M4 is not GNU M4.])]
 192 )
 193
 194 if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then
 195   if test -f $with_sysconfig ; then
 196     sysdesc=$with_sysconfig
 197   else
 198     sysdesc=$srcdir/sysdep/cf/$with_sysconfig
 199     if ! test -f $sysdesc ; then
 200       sysdesc=$sysdesc.h
 201     fi
 202   fi
 203 elif test -f sysconfig.h ; then
 204   sysdesc=sysconfig
 205 else
 206   case "$host_os" in
 207     linux*)
 208       sysdesc=linux
 209       default_iproutedir="/etc/iproute2"
 210       ;;
 211     freebsd*)
 212       sysdesc=bsd
 213       CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 214       LDFLAGS="$LDFLAGS -L/usr/local/lib"
 215       ;;
 216     kfreebsd*)
 217       sysdesc=bsd
 218       ;;
 219     netbsd*)
 220       sysdesc=bsd
 221       CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
 222       LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
 223       ;;
 224     openbsd*)
 225       sysdesc=bsd
 226       ;;
 227     dragonfly*)
 228       sysdesc=bsd
 229       ;;
 230     *)
 231       AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
 232       ;;
 233     esac
 234     sysdesc=$srcdir/sysdep/cf/$sysdesc.h
 235 fi
 236 AC_MSG_CHECKING([which OS configuration should we use])
 237 AC_MSG_RESULT([$sysdesc])
 238 if ! test -f $sysdesc ; then
 239   AC_MSG_ERROR([The system configuration file is missing.])
 240 fi
 241 sysname=`echo $sysdesc | sed 's/\.h$//'`
 242 AC_DEFINE_UNQUOTED([SYSCONF_INCLUDE], ["$sysdesc"], [Which sysdep header to include])
 243
 244 AC_MSG_CHECKING([system-dependent directories])
 245 sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '`"
 246 AC_MSG_RESULT([$sysdep_dirs])
 247 AC_SUBST([sysdep_dirs])
 248
 249 if test "$with_iproutedir" = no ; then with_iproutedir= ; fi
 250
 251 if test -n "$given_iproutedir"
 252 then iproutedir=$with_iproutedir
 253 else iproutedir=$default_iproutedir
 254 fi
 255
 256 AC_SUBST([iproutedir])
 257
 258 DAEMON_LIBS=
 259 AC_SUBST(DAEMON_LIBS)
 260
 261 if test "$enable_libssh" != no ; then
 262   AC_CHECK_HEADER([libssh/libssh.h], [true], [fail=yes], [ ])
 263   AC_CHECK_LIB([ssh], [ssh_connect], [true], [fail=yes])
 264
 265   if test "$fail" != yes ; then
 266     AC_DEFINE([HAVE_LIBSSH], [1], [Define to 1 if you have the `ssh' library (-lssh).])
 267     DAEMON_LIBS="-lssh $DAEMON_LIBS"
 268     proto_rpki=rpki
 269     enable_libssh=yes
 270   else
 271     if test "$enable_libssh" = yes ; then
 272       AC_MSG_ERROR([LibSSH not available.])
 273     else
 274       enable_libssh=no
 275     fi
 276   fi
 277 fi
 278
 279 if test "$enable_mpls_kernel" != no ; then
 280   BIRD_CHECK_MPLS_KERNEL
 281
 282   if test "$bird_cv_mpls_kernel" = yes ; then
 283     AC_DEFINE([HAVE_MPLS_KERNEL], [1], [Define to 1 if kernel is MPLS capable])
 284   elif test "$enable_mpls_kernel" = yes ; then
 285     AC_MSG_ERROR([Kernel MPLS support not found.])
 286   fi
 287
 288   if test "$enable_mpls_kernel" = try ; then
 289     enable_mpls_kernel="$bird_cv_mpls_kernel"
 290   fi
 291 fi
 292
 293 all_protocols="$proto_bfd babel bgp mrt ospf perf pipe radv rip $proto_rpki static"
 294
 295 all_protocols=`echo $all_protocols | sed 's/ /,/g'`
 296
 297 if test "$with_protocols" = all ; then
 298   with_protocols="$all_protocols"
 299 fi
 300
 301 AH_TEMPLATE([CONFIG_BABEL],     [Babel protocol])
 302 AH_TEMPLATE([CONFIG_BFD],       [BFD protocol])
 303 AH_TEMPLATE([CONFIG_BGP],       [BGP protocol])
 304 AH_TEMPLATE([CONFIG_MRT],       [MRT protocol])
 305 AH_TEMPLATE([CONFIG_OSPF],      [OSPF protocol])
 306 AH_TEMPLATE([CONFIG_PIPE],      [Pipe protocol])
 307 AH_TEMPLATE([CONFIG_RADV],      [RAdv protocol])
 308 AH_TEMPLATE([CONFIG_RIP],       [RIP protocol])
 309 AH_TEMPLATE([CONFIG_RPKI],      [RPKI protocol])
 310 AH_TEMPLATE([CONFIG_STATIC],    [Static protocol])
 311
 312 AC_MSG_CHECKING([protocols])
 313 protocols=`echo "$with_protocols" | sed 's/,/ /g'`
 314 if test "$protocols" = no ; then protocols= ; fi
 315 for a in $protocols ; do
 316   if ! test -f $srcdir/proto/$a/Makefile ; then
 317     AC_MSG_RESULT([failed])
 318     AC_MSG_ERROR([Requested protocol $a not found])
 319   fi
 320   AC_DEFINE_UNQUOTED([CONFIG_`echo $a | tr 'a-z' 'A-Z'`])
 321 done
 322 AC_MSG_RESULT([ok])
 323 AC_SUBST([protocols])
 324
 325 case $sysdesc in
 326   */linux*)
 327     AC_CHECK_HEADER([linux/rtnetlink.h],
 328       [],
 329       [AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],
 330       [
 331         dnl Some older versions of Linux kernel headers require these includes
 332         #include <asm/types.h>
 333         #include <sys/socket.h>
 334       ]
 335     )
 336     ;;
 337 esac
 338
 339 AC_CHECK_HEADERS_ONCE([alloca.h syslog.h])
 340 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [], [#include <sys/socket.h>])
 341
 342 AC_C_BIGENDIAN(
 343   [AC_DEFINE([CPU_BIG_ENDIAN], [1], [Define to 1 if cpu is big endian])],
 344   [AC_DEFINE([CPU_LITTLE_ENDIAN], [1], [Define to 1 if cpu is little endian])],
 345   [AC_MSG_ERROR([Cannot determine CPU endianity.])]
 346 )
 347
 348 BIRD_CHECK_ANDROID_GLOB
 349 if test "$bird_cv_lib_glob" = no ; then
 350   AC_MSG_ERROR([glob.h not found.])
 351 elif test "$bird_cv_lib_glob" != yes ; then
 352   LIBS="$LIBS $bird_cv_lib_glob"
 353 fi
 354
 355 BIRD_CHECK_ANDROID_LOG
 356 if test "$bird_cv_lib_log" = no ; then
 357   AC_MSG_ERROR([don't know how to link syslog.])
 358 elif test "$bird_cv_lib_log" != yes ; then
 359   LIBS="$LIBS $bird_cv_lib_log"
 360 fi
 361
 362 if test "$enable_debug" = yes ; then
 363   AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
 364   LDFLAGS="$LDFLAGS -rdynamic"
 365   CFLAGS="$CFLAGS -O0 -ggdb -g3"
 366
 367   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_dwarf4], [-gdwarf-4], [])
 368   BIRD_ADD_GCC_OPTION([bird_cv_c_option_dwarf4], [-gdwarf-4])
 369
 370   AC_CHECK_HEADER([execinfo.h],
 371     [
 372       AC_DEFINE([HAVE_EXECINFO_H], [1], [Define to 1 if you have the <execinfo.h> header file.])
 373       AC_SEARCH_LIBS([backtrace], [execinfo],
 374         [],
 375         [AC_MSG_ERROR([Function backtrace not available.])]
 376       )
 377     ]
 378   )
 379
 380   if test "$enable_memcheck" = yes ; then
 381     AC_CHECK_LIB([dmalloc], [dmalloc_debug])
 382     if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
 383       AC_CHECK_LIB([efence], [malloc])
 384     fi
 385   fi
 386 else
 387   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_implicit_fallthrough], [-Wno-implicit-fallthrough])
 388   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_implicit_fallthrough], [-Wno-implicit-fallthrough])
 389 fi
 390
 391 CLIENT=birdcl
 392 CLIENT_LIBS=
 393 if test "$enable_client" = yes ; then
 394   CLIENT="$CLIENT birdc"
 395   BASE_LIBS="$LIBS"
 396   LIBS=""
 397
 398   AC_CHECK_HEADERS([curses.h],
 399     [],
 400     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 401     [AC_INCLUDES_DEFAULT]
 402   )
 403
 404   AC_SEARCH_LIBS([tgetent], [tinfo tinfow ncurses curses termcap],
 405     [TINFO_LIBS="$LIBS"; LIBS=""],
 406     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 407   )
 408
 409   AC_CHECK_HEADERS([readline/readline.h readline/history.h],
 410     [],
 411     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 412     [AC_INCLUDES_DEFAULT]
 413   )
 414
 415   AC_SEARCH_LIBS([rl_callback_read_char], [readline],
 416     [READLINE_LIBS="$LIBS"; LIBS=""],
 417     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 418     [$TINFO_LIBS]
 419   )
 420
 421   AC_CHECK_LIB([readline], [rl_crlf],
 422     [AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()])],
 423     [],
 424     [$TINFO_LIBS]
 425   )
 426
 427   AC_CHECK_LIB([readline], [rl_ding],
 428     [AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()])],
 429     [],
 430     [$TINFO_LIBS]
 431   )
 432
 433   LIBS="$BASE_LIBS"
 434   CLIENT_LIBS="$READLINE_LIBS $TINFO_LIBS"
 435 fi
 436 AC_SUBST([CLIENT])
 437 AC_SUBST([CLIENT_LIBS])
 438
 439 mkdir -p $objdir/sysdep
 440 AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in])
 441 AC_CONFIG_FILES([Makefile:Makefile.in])
 442 AC_OUTPUT
 443
 444 AC_MSG_RESULT()
 445 AC_MSG_RESULT([BIRD was configured with the following options:])
 446 AC_MSG_RESULT([        Source directory:        $srcdir])
 447 AC_MSG_RESULT([        Object directory:        $objdir])
 448 AC_MSG_RESULT([        Iproute2 directory:      $iproutedir])
 449 AC_MSG_RESULT([        System configuration:    $sysdesc])
 450 AC_MSG_RESULT([        Debugging:               $enable_debug])
 451 AC_MSG_RESULT([        POSIX threads:           $enable_pthreads])
 452 AC_MSG_RESULT([        Routing protocols:       $protocols])
 453 AC_MSG_RESULT([        Kernel MPLS support:     $enable_mpls_kernel])
 454 AC_MSG_RESULT([        Client:                  $enable_client])
 455
 456 rm -f $objdir/.*-stamp