configure.ac

   1 dnl ** This is a configure script template for BIRD
   2 dnl ** Process it with autoconf to get ./configure
   3 dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz>
   4
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([conf/confbase.Y])
   7 AC_CONFIG_AUX_DIR([tools])
   8
   9 AC_ARG_ENABLE([client],
  10   [AS_HELP_STRING([--enable-client], [enable building of BIRD client @<:@yes@:>@])],
  11   [],
  12   [enable_client=yes]
  13 )
  14
  15 AC_ARG_ENABLE([debug],
  16   [AS_HELP_STRING([--enable-debug], [enable internal debugging routines @<:@no@:>@])],
  17   [],
  18   [enable_debug=no]
  19 )
  20
  21 AC_ARG_ENABLE([memcheck],
  22   [AS_HELP_STRING([--enable-memcheck], [check memory allocations when debugging @<:@yes@:>@])],
  23   [],
  24   [enable_memcheck=yes]
  25 )
  26
  27 AC_ARG_ENABLE([pthreads],
  28   [AS_HELP_STRING([--enable-pthreads], [enable POSIX threads support @<:@try@:>@])],
  29   [],
  30   [enable_pthreads=try]
  31 )
  32
  33 AC_ARG_ENABLE([libssh],
  34   [AS_HELP_STRING([--enable-libssh], [enable LibSSH support together with RPKI @<:@try@:>@])],
  35   [],
  36   [enable_libssh=try]
  37 )
  38
  39 AC_ARG_ENABLE([mpls-kernel],
  40   [AS_HELP_STRING([--enable-mpls-kernel], [enable MPLS support in kernel protocol @<:@try@:>@])],
  41   [],
  42   [enable_mpls_kernel=try]
  43 )
  44
  45 AC_ARG_WITH([protocols],
  46   [AS_HELP_STRING([--with-protocols=LIST], [include specified routing protocols @<:@all@:>@])],
  47   [],
  48   [with_protocols="all"]
  49 )
  50
  51 AC_ARG_WITH([sysconfig],
  52   [AS_HELP_STRING([--with-sysconfig=FILE], [use specified BIRD system configuration file])],
  53   []
  54 )
  55
  56 AC_ARG_WITH([runtimedir],
  57   [AS_HELP_STRING([--with-runtimedir=PATH], [run-state data, obsolete variant of --runstatedir])],
  58   [runstatedir="$with_runtimedir"],
  59   []
  60 )
  61
  62 AC_ARG_WITH([iproutedir],
  63   [AS_HELP_STRING([--with-iproutedir=PATH], [path to iproute2 config files @<:@/etc/iproute2@:>@])],
  64   [given_iproutedir="yes"]
  65 )
  66
  67 AC_ARG_VAR([FLEX], [location of the Flex program])
  68 AC_ARG_VAR([BISON], [location of the Bison program])
  69 AC_ARG_VAR([M4], [location of the M4 program])
  70
  71
  72 if test "$srcdir" = . ; then
  73   # Building in current directory => create obj directory holding all objects
  74   objdir=obj
  75 else
  76   # Building in separate directory
  77   objdir=.
  78 fi
  79
  80 exedir=.
  81
  82 AC_SUBST([objdir])
  83 AC_SUBST([exedir])
  84 AC_SUBST([srcdir])
  85
  86 # Workaround for older Autoconfs that do not define runstatedir
  87 AS_IF([test -z "${runstatedir}"], [runstatedir='${localstatedir}/run'])
  88 AC_SUBST([runstatedir])
  89
  90
  91 if test "$enable_debug" = yes ; then
  92   CONFIG_FILE="bird.conf"
  93   CONTROL_SOCKET="bird.ctl"
  94 else
  95   CONFIG_FILE="\$(sysconfdir)/bird.conf"
  96   CONTROL_SOCKET="\$(runstatedir)/bird.ctl"
  97 fi
  98 AC_SUBST([CONFIG_FILE])
  99 AC_SUBST([CONTROL_SOCKET])
 100
 101 AC_SEARCH_LIBS([clock_gettime], [rt posix4],
 102   [],
 103   [AC_MSG_ERROR([Function clock_gettime not available.])]
 104 )
 105
 106 AC_CANONICAL_HOST
 107
 108 # Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC
 109 if test "$ac_test_CFLAGS" != set ; then
 110   bird_cflags_default=yes
 111 fi
 112
 113 AC_PROG_CC
 114 AC_PROG_CC_C99
 115 if test -z "$GCC" ; then
 116   AC_MSG_ERROR([This program requires the GNU C Compiler.])
 117 fi
 118
 119 if test "$enable_pthreads" != no ; then
 120   BIRD_CHECK_PTHREADS
 121
 122   if test "$bird_cv_lib_pthreads" = yes ; then
 123     AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
 124     CFLAGS="$CFLAGS -pthread"
 125     LDFLAGS="$LDFLAGS -pthread"
 126     proto_bfd=bfd
 127   elif test "$enable_pthreads" = yes ; then
 128     AC_MSG_ERROR([POSIX threads not available.])
 129   fi
 130
 131   if test "$enable_pthreads" = try ; then
 132     enable_pthreads="$bird_cv_lib_pthreads"
 133   fi
 134 fi
 135
 136 if test "$bird_cflags_default" = yes ; then
 137   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign], [-Wall])
 138   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers], [-Wall -Wextra])
 139   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
 140   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 141
 142   CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wno-parentheses"
 143   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign])
 144   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers])
 145   BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
 146   BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 147 fi
 148 AC_MSG_CHECKING([CFLAGS])
 149 AC_MSG_RESULT([$CFLAGS])
 150
 151
 152 AC_PROG_CPP
 153 AC_PROG_INSTALL
 154 AC_PROG_RANLIB
 155 AC_CHECK_PROG([FLEX], [flex], [flex])
 156 AC_CHECK_PROG([BISON], [bison], [bison])
 157 AC_CHECK_PROGS([M4], [gm4 m4])
 158
 159 test -z "$FLEX"  && AC_MSG_ERROR([Flex is missing.])
 160 test -z "$BISON" && AC_MSG_ERROR([Bison is missing.])
 161 test -z "$M4"    && AC_MSG_ERROR([M4 is missing.])
 162
 163 AC_MSG_CHECKING([bison version])
 164 BIRD_CHECK_BISON_VERSION(BISON_VERSION)
 165 AC_MSG_RESULT([$BISON_VERSION])
 166 if test "$bird_bison_synclines" = yes; then
 167   M4FLAGS="$M4FLAGS -s"
 168 fi
 169
 170 if test "$bird_bison_enhanced_error" = yes; then
 171   BISONFLAGS="$BISONFLAGS -Dparse.lac=full -Dparse.error=verbose"
 172 fi
 173
 174 AC_SUBST([M4FLAGS])
 175 AC_SUBST([BISONFLAGS])
 176
 177 BIRD_CHECK_PROG_FLAVOR_GNU([$M4],
 178   [],
 179   [AC_MSG_ERROR([Provided M4 is not GNU M4.])]
 180 )
 181
 182 if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then
 183   if test -f $with_sysconfig ; then
 184     sysdesc=$with_sysconfig
 185   else
 186     sysdesc=$srcdir/sysdep/cf/$with_sysconfig
 187     if ! test -f $sysdesc ; then
 188       sysdesc=$sysdesc.h
 189     fi
 190   fi
 191 elif test -f sysconfig.h ; then
 192   sysdesc=sysconfig
 193 else
 194   case "$host_os" in
 195     linux*)
 196       sysdesc=linux
 197       default_iproutedir="/etc/iproute2"
 198       ;;
 199     freebsd*)
 200       sysdesc=bsd
 201       CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 202       LDFLAGS="$LDFLAGS -L/usr/local/lib"
 203       ;;
 204     kfreebsd*)
 205       sysdesc=bsd
 206       ;;
 207     netbsd*)
 208       sysdesc=bsd
 209       CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
 210       LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
 211       ;;
 212     openbsd*)
 213       sysdesc=bsd
 214       ;;
 215     dragonfly*)
 216       sysdesc=bsd
 217       ;;
 218     *)
 219       AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
 220       ;;
 221     esac
 222     sysdesc=$srcdir/sysdep/cf/$sysdesc.h
 223 fi
 224 AC_MSG_CHECKING([which OS configuration should we use])
 225 AC_MSG_RESULT([$sysdesc])
 226 if ! test -f $sysdesc ; then
 227   AC_MSG_ERROR([The system configuration file is missing.])
 228 fi
 229 sysname=`echo $sysdesc | sed 's/\.h$//'`
 230 AC_DEFINE_UNQUOTED([SYSCONF_INCLUDE], ["$sysdesc"], [Which sysdep header to include])
 231
 232 AC_MSG_CHECKING([system-dependent directories])
 233 sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '`"
 234 AC_MSG_RESULT([$sysdep_dirs])
 235 AC_SUBST([sysdep_dirs])
 236
 237 if test "$with_iproutedir" = no ; then with_iproutedir= ; fi
 238
 239 if test -n "$given_iproutedir"
 240 then iproutedir=$with_iproutedir
 241 else iproutedir=$default_iproutedir
 242 fi
 243
 244 AC_SUBST([iproutedir])
 245
 246 DAEMON_LIBS=
 247 AC_SUBST(DAEMON_LIBS)
 248
 249 if test "$enable_libssh" != no ; then
 250   AC_CHECK_HEADER([libssh/libssh.h], [true], [fail=yes], [ ])
 251   AC_CHECK_LIB([ssh], [ssh_connect], [true], [fail=yes])
 252
 253   if test "$fail" != yes ; then
 254     AC_DEFINE([HAVE_LIBSSH], [1], [Define to 1 if you have the `ssh' library (-lssh).])
 255     DAEMON_LIBS="-lssh $DAEMON_LIBS"
 256     proto_rpki=rpki
 257     enable_libssh=yes
 258   else
 259     if test "$enable_libssh" = yes ; then
 260       AC_MSG_ERROR([LibSSH not available.])
 261     else
 262       enable_libssh=no
 263     fi
 264   fi
 265 fi
 266
 267 if test "$enable_mpls_kernel" != no ; then
 268   BIRD_CHECK_MPLS_KERNEL
 269
 270   if test "$bird_cv_mpls_kernel" = yes ; then
 271     AC_DEFINE([HAVE_MPLS_KERNEL], [1], [Define to 1 if kernel is MPLS capable])
 272   elif test "$enable_mpls_kernel" = yes ; then
 273     AC_MSG_ERROR([Kernel MPLS support not found.])
 274   fi
 275
 276   if test "$enable_mpls_kernel" = try ; then
 277     enable_mpls_kernel="$bird_cv_mpls_kernel"
 278   fi
 279 fi
 280
 281 all_protocols="$proto_bfd babel bgp ospf pipe radv rip $proto_rpki static"
 282
 283 all_protocols=`echo $all_protocols | sed 's/ /,/g'`
 284
 285 if test "$with_protocols" = all ; then
 286   with_protocols="$all_protocols"
 287 fi
 288
 289 AH_TEMPLATE([CONFIG_BABEL],     [Babel protocol])
 290 AH_TEMPLATE([CONFIG_BFD],       [BFD protocol])
 291 AH_TEMPLATE([CONFIG_BGP],       [BGP protocol])
 292 AH_TEMPLATE([CONFIG_OSPF],      [OSPF protocol])
 293 AH_TEMPLATE([CONFIG_PIPE],      [Pipe protocol])
 294 AH_TEMPLATE([CONFIG_RADV],      [RAdv protocol])
 295 AH_TEMPLATE([CONFIG_RIP],       [RIP protocol])
 296 AH_TEMPLATE([CONFIG_RPKI],      [RPKI protocol])
 297 AH_TEMPLATE([CONFIG_STATIC],    [Static protocol])
 298
 299 AC_MSG_CHECKING([protocols])
 300 protocols=`echo "$with_protocols" | sed 's/,/ /g'`
 301 if test "$protocols" = no ; then protocols= ; fi
 302 for a in $protocols ; do
 303   if ! test -f $srcdir/proto/$a/Makefile ; then
 304     AC_MSG_RESULT([failed])
 305     AC_MSG_ERROR([Requested protocol $a not found])
 306   fi
 307   AC_DEFINE_UNQUOTED([CONFIG_`echo $a | tr 'a-z' 'A-Z'`])
 308 done
 309 AC_MSG_RESULT([ok])
 310 AC_SUBST([protocols])
 311
 312 case $sysdesc in
 313   */linux*)
 314     AC_CHECK_HEADER([linux/rtnetlink.h],
 315       [],
 316       [AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],
 317       [
 318         dnl Some older versions of Linux kernel headers require these includes
 319         #include <asm/types.h>
 320         #include <sys/socket.h>
 321       ]
 322     )
 323     ;;
 324 esac
 325
 326 AC_CHECK_HEADERS_ONCE([alloca.h syslog.h])
 327 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [], [#include <sys/socket.h>])
 328
 329 AC_C_BIGENDIAN(
 330   [AC_DEFINE([CPU_BIG_ENDIAN], [1], [Define to 1 if cpu is big endian])],
 331   [AC_DEFINE([CPU_LITTLE_ENDIAN], [1], [Define to 1 if cpu is little endian])],
 332   [AC_MSG_ERROR([Cannot determine CPU endianity.])]
 333 )
 334
 335 BIRD_CHECK_ANDROID_GLOB
 336 if test "$bird_cv_lib_glob" = no ; then
 337   AC_MSG_ERROR([glob.h not found.])
 338 elif test "$bird_cv_lib_glob" != yes ; then
 339   LIBS="$LIBS $bird_cv_lib_glob"
 340 fi
 341
 342 BIRD_CHECK_ANDROID_LOG
 343 if test "$bird_cv_lib_log" = no ; then
 344   AC_MSG_ERROR([don't know how to link syslog.])
 345 elif test "$bird_cv_lib_log" != yes ; then
 346   LIBS="$LIBS $bird_cv_lib_log"
 347 fi
 348
 349 if test "$enable_debug" = yes ; then
 350   AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
 351   LDFLAGS="$LDFLAGS -rdynamic"
 352   CFLAGS="$CFLAGS -O0 -ggdb -g3 -gdwarf-4"
 353
 354   AC_CHECK_HEADER([execinfo.h],
 355     [
 356       AC_DEFINE([HAVE_EXECINFO_H], [1], [Define to 1 if you have the <execinfo.h> header file.])
 357       AC_SEARCH_LIBS([backtrace], [execinfo],
 358         [],
 359         [AC_MSG_ERROR([Function backtrace not available.])]
 360       )
 361     ]
 362   )
 363
 364   if test "$enable_memcheck" = yes ; then
 365     AC_CHECK_LIB([dmalloc], [dmalloc_debug])
 366     if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
 367       AC_CHECK_LIB([efence], [malloc])
 368     fi
 369   fi
 370 fi
 371
 372 CLIENT=birdcl
 373 CLIENT_LIBS=
 374 if test "$enable_client" = yes ; then
 375   CLIENT="$CLIENT birdc"
 376   BASE_LIBS="$LIBS"
 377   LIBS=""
 378
 379   AC_CHECK_HEADERS([curses.h],
 380     [],
 381     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 382     [AC_INCLUDES_DEFAULT]
 383   )
 384
 385   AC_SEARCH_LIBS([tgetent], [tinfo tinfow ncurses curses termcap],
 386     [TINFO_LIBS="$LIBS"; LIBS=""],
 387     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 388   )
 389
 390   AC_CHECK_HEADERS([readline/readline.h readline/history.h],
 391     [],
 392     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 393     [AC_INCLUDES_DEFAULT]
 394   )
 395
 396   AC_SEARCH_LIBS([rl_callback_read_char], [readline],
 397     [READLINE_LIBS="$LIBS"; LIBS=""],
 398     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 399     [$TINFO_LIBS]
 400   )
 401
 402   AC_CHECK_LIB([readline], [rl_crlf],
 403     [AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()])],
 404     [],
 405     [$TINFO_LIBS]
 406   )
 407
 408   AC_CHECK_LIB([readline], [rl_ding],
 409     [AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()])],
 410     [],
 411     [$TINFO_LIBS]
 412   )
 413
 414   LIBS="$BASE_LIBS"
 415   CLIENT_LIBS="$READLINE_LIBS $TINFO_LIBS"
 416 fi
 417 AC_SUBST([CLIENT])
 418 AC_SUBST([CLIENT_LIBS])
 419
 420 mkdir -p $objdir/sysdep
 421 AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in])
 422 AC_CONFIG_FILES([Makefile:Makefile.in])
 423 AC_OUTPUT
 424
 425 AC_MSG_RESULT()
 426 AC_MSG_RESULT([BIRD was configured with the following options:])
 427 AC_MSG_RESULT([        Source directory:        $srcdir])
 428 AC_MSG_RESULT([        Object directory:        $objdir])
 429 AC_MSG_RESULT([        Iproute2 directory:      $iproutedir])
 430 AC_MSG_RESULT([        System configuration:    $sysdesc])
 431 AC_MSG_RESULT([        Debugging:               $enable_debug])
 432 AC_MSG_RESULT([        POSIX threads:           $enable_pthreads])
 433 AC_MSG_RESULT([        Routing protocols:       $protocols])
 434 AC_MSG_RESULT([        Kernel MPLS support:     $enable_mpls_kernel])
 435 AC_MSG_RESULT([        Client:                  $enable_client])
 436
 437 rm -f $objdir/.*-stamp