configure.ac

   1 dnl ** This is a configure script template for BIRD
   2 dnl ** Process it with autoconf to get ./configure
   3 dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz>
   4
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([conf/confbase.Y])
   7 AC_CONFIG_AUX_DIR([tools])
   8
   9 AC_ARG_ENABLE([client],
  10   [AS_HELP_STRING([--enable-client], [enable building of BIRD client @<:@yes@:>@])],
  11   [],
  12   [enable_client=yes]
  13 )
  14
  15 AC_ARG_ENABLE([debug],
  16   [AS_HELP_STRING([--enable-debug], [enable internal debugging routines @<:@no@:>@])],
  17   [],
  18   [enable_debug=no]
  19 )
  20
  21 AC_ARG_ENABLE([debug-generated],
  22   [AS_HELP_STRING([--enable-debug-generated], [enable this to abstain from generating #line @<:@no@:>@])],
  23   [],
  24   [enable_debug_generated=no]
  25 )
  26
  27 AC_ARG_ENABLE([memcheck],
  28   [AS_HELP_STRING([--enable-memcheck], [check memory allocations when debugging @<:@yes@:>@])],
  29   [],
  30   [enable_memcheck=yes]
  31 )
  32
  33 AC_ARG_ENABLE([pthreads],
  34   [AS_HELP_STRING([--enable-pthreads], [enable POSIX threads support @<:@try@:>@])],
  35   [],
  36   [enable_pthreads=try]
  37 )
  38
  39 AC_ARG_ENABLE([libssh],
  40   [AS_HELP_STRING([--enable-libssh], [enable LibSSH support together with RPKI @<:@try@:>@])],
  41   [],
  42   [enable_libssh=try]
  43 )
  44
  45 AC_ARG_ENABLE([mpls-kernel],
  46   [AS_HELP_STRING([--enable-mpls-kernel], [enable MPLS support in kernel protocol @<:@try@:>@])],
  47   [],
  48   [enable_mpls_kernel=try]
  49 )
  50
  51 AC_ARG_WITH([protocols],
  52   [AS_HELP_STRING([--with-protocols=LIST], [include specified routing protocols @<:@all@:>@])],
  53   [],
  54   [with_protocols="all"]
  55 )
  56
  57 AC_ARG_WITH([sysconfig],
  58   [AS_HELP_STRING([--with-sysconfig=FILE], [use specified BIRD system configuration file])]
  59 )
  60
  61 AC_ARG_WITH([runtimedir],
  62   [AS_HELP_STRING([--with-runtimedir=PATH], [run-state data, obsolete variant of --runstatedir])],
  63   [runstatedir="$with_runtimedir"]
  64 )
  65
  66 AC_ARG_WITH([iproutedir],
  67   [AS_HELP_STRING([--with-iproutedir=PATH], [path to iproute2 config files @<:@/etc/iproute2@:>@])],
  68   [given_iproutedir="yes"]
  69 )
  70
  71 AC_ARG_VAR([FLEX], [location of the Flex program])
  72 AC_ARG_VAR([BISON], [location of the Bison program])
  73 AC_ARG_VAR([M4], [location of the M4 program])
  74
  75
  76 if test "$srcdir" = . ; then
  77   # Building in current directory => create obj directory holding all objects
  78   objdir=obj
  79 else
  80   # Building in separate directory
  81   objdir=.
  82 fi
  83
  84 exedir=.
  85
  86 AC_SUBST([objdir])
  87 AC_SUBST([exedir])
  88 AC_SUBST([srcdir])
  89
  90 # Workaround for older Autoconfs that do not define runstatedir
  91 AS_IF([test -z "${runstatedir}"], [runstatedir='${localstatedir}/run'])
  92 AC_SUBST([runstatedir])
  93
  94 CONFIG_FILE="\$(sysconfdir)/bird.conf"
  95 AC_SUBST([CONFIG_FILE])
  96
  97 CONTROL_SOCKET="\$(runstatedir)/bird.ctl"
  98 AC_SUBST([CONTROL_SOCKET])
  99
 100 AC_SEARCH_LIBS([clock_gettime], [rt posix4],
 101   [],
 102   [AC_MSG_ERROR([Function clock_gettime not available.])]
 103 )
 104
 105 AC_CANONICAL_HOST
 106
 107 # Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC
 108 if test "$ac_test_CFLAGS" != set ; then
 109   bird_cflags_default=yes
 110 fi
 111
 112 AC_PROG_CC
 113 AC_PROG_CC_C99
 114 if test -z "$GCC" ; then
 115   AC_MSG_ERROR([This program requires the GNU C Compiler.])
 116 fi
 117
 118 BIRD_CHECK_THREAD_LOCAL
 119 if test "$bird_cv_thread_local" = yes ; then
 120   AC_DEFINE([HAVE_THREAD_LOCAL], [1], [Define to 1 if _Thread_local is available])
 121 fi
 122
 123 if test "$enable_pthreads" != no ; then
 124   BIRD_CHECK_PTHREADS
 125
 126   if test "$bird_cv_lib_pthreads" = yes ; then
 127     AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
 128     CFLAGS="$CFLAGS -pthread"
 129     LDFLAGS="$LDFLAGS -pthread"
 130     proto_bfd=bfd
 131   elif test "$enable_pthreads" = yes ; then
 132     AC_MSG_ERROR([POSIX threads not available.])
 133   fi
 134
 135   if test "$enable_pthreads" = try ; then
 136     enable_pthreads="$bird_cv_lib_pthreads"
 137   fi
 138 fi
 139
 140 # This is assumed to be necessary for proper BIRD build
 141 CFLAGS="$CFLAGS -fno-strict-aliasing -fno-strict-overflow"
 142
 143 if test "$bird_cflags_default" = yes ; then
 144   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign], [-Wall])
 145   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers], [-Wall -Wextra])
 146
 147   if test "$enable_debug" = no; then
 148     BIRD_CHECK_LTO
 149   fi
 150
 151   if test "$bird_cv_c_lto" = yes; then
 152     CFLAGS="$CFLAGS -flto"
 153     LDFLAGS="$LDFLAGS -flto=4"
 154   fi
 155
 156   CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wno-parentheses"
 157   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign])
 158   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers])
 159 fi
 160
 161
 162 AC_MSG_CHECKING([CFLAGS])
 163 AC_MSG_RESULT([$CFLAGS])
 164
 165 AC_MSG_CHECKING([LDFLAGS])
 166 AC_MSG_RESULT([$LDFLAGS])
 167
 168 AC_PROG_CPP
 169 AC_PROG_INSTALL
 170 AC_PROG_RANLIB
 171 AC_CHECK_PROG([FLEX], [flex], [flex])
 172 AC_CHECK_PROG([BISON], [bison], [bison])
 173 AC_CHECK_PROGS([M4], [gm4 m4])
 174
 175 test -z "$FLEX"  && AC_MSG_ERROR([Flex is missing.])
 176 test -z "$BISON" && AC_MSG_ERROR([Bison is missing.])
 177 test -z "$M4"    && AC_MSG_ERROR([M4 is missing.])
 178
 179 AC_MSG_CHECKING([bison version])
 180 BIRD_CHECK_BISON_VERSION(BISON_VERSION)
 181 AC_MSG_RESULT([$BISON_VERSION])
 182 if test "$bird_bison_synclines" = yes && test "$enable_debug_generated" = no; then
 183   M4FLAGS="$M4FLAGS -s"
 184 fi
 185
 186 if test "$bird_bison_enhanced_error" = yes; then
 187   BISONFLAGS="$BISONFLAGS -Dparse.lac=full -Dparse.error=verbose"
 188 fi
 189
 190 AC_SUBST([M4FLAGS])
 191 AC_SUBST([BISONFLAGS])
 192
 193 BIRD_CHECK_PROG_FLAVOR_GNU([$M4],
 194   [],
 195   [AC_MSG_ERROR([Provided M4 is not GNU M4.])]
 196 )
 197
 198 if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then
 199   if test -f $with_sysconfig ; then
 200     sysdesc=$with_sysconfig
 201   else
 202     sysdesc=$srcdir/sysdep/cf/$with_sysconfig
 203     if ! test -f $sysdesc ; then
 204       sysdesc=$sysdesc.h
 205     fi
 206   fi
 207 elif test -f sysconfig.h ; then
 208   sysdesc=sysconfig
 209 else
 210   case "$host_os" in
 211     linux*)
 212       sysdesc=linux
 213       default_iproutedir="/etc/iproute2"
 214       ;;
 215     freebsd*)
 216       sysdesc=bsd
 217       CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 218       LDFLAGS="$LDFLAGS -L/usr/local/lib"
 219       ;;
 220     kfreebsd*)
 221       sysdesc=bsd
 222       ;;
 223     netbsd*)
 224       sysdesc=bsd
 225       CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
 226       LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
 227       ;;
 228     openbsd*)
 229       sysdesc=bsd
 230       ;;
 231     dragonfly*)
 232       sysdesc=bsd
 233       ;;
 234     *)
 235       AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
 236       ;;
 237     esac
 238     sysdesc=$srcdir/sysdep/cf/$sysdesc.h
 239 fi
 240 AC_MSG_CHECKING([which OS configuration should we use])
 241 AC_MSG_RESULT([$sysdesc])
 242 if ! test -f $sysdesc ; then
 243   AC_MSG_ERROR([The system configuration file is missing.])
 244 fi
 245 sysname=`echo $sysdesc | sed 's/\.h$//'`
 246 AC_DEFINE_UNQUOTED([SYSCONF_INCLUDE], ["$sysdesc"], [Which sysdep header to include])
 247
 248 AC_MSG_CHECKING([system-dependent directories])
 249 sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '`"
 250 AC_MSG_RESULT([$sysdep_dirs])
 251 AC_SUBST([sysdep_dirs])
 252
 253 if test "$with_iproutedir" = no ; then with_iproutedir= ; fi
 254
 255 if test -n "$given_iproutedir"
 256 then iproutedir=$with_iproutedir
 257 else iproutedir=$default_iproutedir
 258 fi
 259
 260 AC_SUBST([iproutedir])
 261
 262 DAEMON_LIBS=
 263 AC_SUBST(DAEMON_LIBS)
 264
 265 if test "$enable_libssh" != no ; then
 266   AC_CHECK_HEADER([libssh/libssh.h], [true], [fail=yes], [ ])
 267   AC_CHECK_LIB([ssh], [ssh_connect], [true], [fail=yes])
 268
 269   if test "$fail" != yes ; then
 270     AC_DEFINE([HAVE_LIBSSH], [1], [Define to 1 if you have the `ssh' library (-lssh).])
 271     DAEMON_LIBS="-lssh $DAEMON_LIBS"
 272     proto_rpki=rpki
 273     enable_libssh=yes
 274   else
 275     if test "$enable_libssh" = yes ; then
 276       AC_MSG_ERROR([LibSSH not available.])
 277     else
 278       enable_libssh=no
 279     fi
 280   fi
 281 fi
 282
 283 if test "$enable_mpls_kernel" != no ; then
 284   BIRD_CHECK_MPLS_KERNEL
 285
 286   if test "$bird_cv_mpls_kernel" = yes ; then
 287     AC_DEFINE([HAVE_MPLS_KERNEL], [1], [Define to 1 if kernel is MPLS capable])
 288   elif test "$enable_mpls_kernel" = yes ; then
 289     AC_MSG_ERROR([Kernel MPLS support not found.])
 290   fi
 291
 292   if test "$enable_mpls_kernel" = try ; then
 293     enable_mpls_kernel="$bird_cv_mpls_kernel"
 294   fi
 295 fi
 296
 297 all_protocols="$proto_bfd babel bgp mrt ospf perf pipe radv rip $proto_rpki static"
 298
 299 all_protocols=`echo $all_protocols | sed 's/ /,/g'`
 300
 301 if test "$with_protocols" = all ; then
 302   with_protocols="$all_protocols"
 303 fi
 304
 305 AH_TEMPLATE([CONFIG_BABEL],     [Babel protocol])
 306 AH_TEMPLATE([CONFIG_BFD],       [BFD protocol])
 307 AH_TEMPLATE([CONFIG_BGP],       [BGP protocol])
 308 AH_TEMPLATE([CONFIG_MRT],       [MRT protocol])
 309 AH_TEMPLATE([CONFIG_OSPF],      [OSPF protocol])
 310 AH_TEMPLATE([CONFIG_PIPE],      [Pipe protocol])
 311 AH_TEMPLATE([CONFIG_RADV],      [RAdv protocol])
 312 AH_TEMPLATE([CONFIG_RIP],       [RIP protocol])
 313 AH_TEMPLATE([CONFIG_RPKI],      [RPKI protocol])
 314 AH_TEMPLATE([CONFIG_STATIC],    [Static protocol])
 315
 316 AC_MSG_CHECKING([protocols])
 317 protocols=`echo "$with_protocols" | sed 's/,/ /g'`
 318 if test "$protocols" = no ; then protocols= ; fi
 319 for a in $protocols ; do
 320   if ! test -f $srcdir/proto/$a/Makefile ; then
 321     AC_MSG_RESULT([failed])
 322     AC_MSG_ERROR([Requested protocol $a not found])
 323   fi
 324   AC_DEFINE_UNQUOTED([CONFIG_`echo $a | tr 'a-z' 'A-Z'`])
 325 done
 326 AC_MSG_RESULT([ok])
 327 AC_SUBST([protocols])
 328
 329 case $sysdesc in
 330   */linux*)
 331     AC_CHECK_HEADER([linux/rtnetlink.h],
 332       [],
 333       [AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],
 334       [
 335         dnl Some older versions of Linux kernel headers require these includes
 336         #include <asm/types.h>
 337         #include <sys/socket.h>
 338       ]
 339     )
 340     ;;
 341 esac
 342
 343 AC_CHECK_HEADERS_ONCE([alloca.h syslog.h])
 344 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [], [#include <sys/socket.h>])
 345
 346 AC_C_BIGENDIAN(
 347   [AC_DEFINE([CPU_BIG_ENDIAN], [1], [Define to 1 if cpu is big endian])],
 348   [AC_DEFINE([CPU_LITTLE_ENDIAN], [1], [Define to 1 if cpu is little endian])],
 349   [AC_MSG_ERROR([Cannot determine CPU endianity.])]
 350 )
 351
 352 BIRD_CHECK_ANDROID_GLOB
 353 if test "$bird_cv_lib_glob" = no ; then
 354   AC_MSG_ERROR([glob.h not found.])
 355 elif test "$bird_cv_lib_glob" != yes ; then
 356   LIBS="$LIBS $bird_cv_lib_glob"
 357 fi
 358
 359 BIRD_CHECK_ANDROID_LOG
 360 if test "$bird_cv_lib_log" = no ; then
 361   AC_MSG_ERROR([don't know how to link syslog.])
 362 elif test "$bird_cv_lib_log" != yes ; then
 363   LIBS="$LIBS $bird_cv_lib_log"
 364 fi
 365
 366 if test "$enable_debug" = yes ; then
 367   AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
 368   LDFLAGS="$LDFLAGS -rdynamic"
 369   CFLAGS="$CFLAGS -O0 -ggdb -g3"
 370
 371   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_dwarf4], [-gdwarf-4], [])
 372   BIRD_ADD_GCC_OPTION([bird_cv_c_option_dwarf4], [-gdwarf-4])
 373
 374   AC_CHECK_HEADER([execinfo.h],
 375     [
 376       AC_DEFINE([HAVE_EXECINFO_H], [1], [Define to 1 if you have the <execinfo.h> header file.])
 377       AC_SEARCH_LIBS([backtrace], [execinfo],
 378         [],
 379         [AC_MSG_ERROR([Function backtrace not available.])]
 380       )
 381     ]
 382   )
 383
 384   if test "$enable_memcheck" = yes ; then
 385     AC_CHECK_LIB([dmalloc], [dmalloc_debug])
 386     if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
 387       AC_CHECK_LIB([efence], [malloc])
 388     fi
 389   fi
 390 fi
 391
 392 CLIENT=birdcl
 393 CLIENT_LIBS=
 394 if test "$enable_client" = yes ; then
 395   CLIENT="$CLIENT birdc"
 396   BASE_LIBS="$LIBS"
 397   LIBS=""
 398
 399   AC_CHECK_HEADERS([curses.h],
 400     [],
 401     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 402     [AC_INCLUDES_DEFAULT]
 403   )
 404
 405   AC_SEARCH_LIBS([tgetent], [tinfo tinfow ncurses curses termcap],
 406     [TINFO_LIBS="$LIBS"; LIBS=""],
 407     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 408   )
 409
 410   AC_CHECK_HEADERS([readline/readline.h readline/history.h],
 411     [],
 412     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 413     [AC_INCLUDES_DEFAULT]
 414   )
 415
 416   AC_SEARCH_LIBS([rl_callback_read_char], [readline],
 417     [READLINE_LIBS="$LIBS"; LIBS=""],
 418     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 419     [$TINFO_LIBS]
 420   )
 421
 422   AC_CHECK_LIB([readline], [rl_crlf],
 423     [AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()])],
 424     [],
 425     [$TINFO_LIBS]
 426   )
 427
 428   AC_CHECK_LIB([readline], [rl_ding],
 429     [AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()])],
 430     [],
 431     [$TINFO_LIBS]
 432   )
 433
 434   LIBS="$BASE_LIBS"
 435   CLIENT_LIBS="$READLINE_LIBS $TINFO_LIBS"
 436 fi
 437 AC_SUBST([CLIENT])
 438 AC_SUBST([CLIENT_LIBS])
 439
 440 mkdir -p $objdir/sysdep
 441 AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in])
 442 AC_CONFIG_FILES([Makefile:Makefile.in])
 443 AC_OUTPUT
 444
 445 AC_MSG_RESULT()
 446 AC_MSG_RESULT([BIRD was configured with the following options:])
 447 AC_MSG_RESULT([        Source directory:        $srcdir])
 448 AC_MSG_RESULT([        Object directory:        $objdir])
 449 AC_MSG_RESULT([        Iproute2 directory:      $iproutedir])
 450 AC_MSG_RESULT([        System configuration:    $sysdesc])
 451 AC_MSG_RESULT([        Debugging:               $enable_debug])
 452 AC_MSG_RESULT([        POSIX threads:           $enable_pthreads])
 453 AC_MSG_RESULT([        Routing protocols:       $protocols])
 454 AC_MSG_RESULT([        Kernel MPLS support:     $enable_mpls_kernel])
 455 AC_MSG_RESULT([        Client:                  $enable_client])
 456
 457 rm -f $objdir/.*-stamp