configure.ac

   1 dnl ** This is a configure script template for BIRD
   2 dnl ** Process it with autoconf to get ./configure
   3 dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz>
   4
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([conf/confbase.Y])
   7 AC_CONFIG_AUX_DIR([tools])
   8
   9 AC_ARG_ENABLE([client],
  10   [AS_HELP_STRING([--enable-client], [enable building of BIRD client @<:@yes@:>@])],
  11   [],
  12   [enable_client=yes]
  13 )
  14
  15 AC_ARG_ENABLE([debug],
  16   [AS_HELP_STRING([--enable-debug], [enable internal debugging routines @<:@no@:>@])],
  17   [],
  18   [enable_debug=no]
  19 )
  20
  21 AC_ARG_ENABLE([ipv6],
  22   [AS_HELP_STRING([--enable-ipv6], [enable building of IPv6 version @<:@no@:>@])],
  23   [],
  24   [enable_ipv6=no]
  25 )
  26
  27 AC_ARG_ENABLE([memcheck],
  28   [AS_HELP_STRING([--enable-memcheck], [check memory allocations when debugging @<:@yes@:>@])],
  29   [],
  30   [enable_memcheck=yes]
  31 )
  32
  33 AC_ARG_ENABLE([pthreads],
  34   [AS_HELP_STRING([--enable-pthreads], [enable POSIX threads support @<:@try@:>@])],
  35   [],
  36   [enable_pthreads=try]
  37 )
  38
  39 AC_ARG_WITH([protocols],
  40   [AS_HELP_STRING([--with-protocols=LIST], [include specified routing protocols @<:@all@:>@])],
  41   [],
  42   [with_protocols="all"]
  43 )
  44
  45 AC_ARG_WITH([suffix],
  46   [AS_HELP_STRING([--with-suffix=STRING], [use specified suffix for BIRD files @<:@6 for IPv6@:>@])],
  47   [given_suffix="yes"]
  48 )
  49
  50 AC_ARG_WITH([sysconfig],
  51   [AS_HELP_STRING([--with-sysconfig=FILE], [use specified BIRD system configuration file])],
  52   []
  53 )
  54
  55 AC_ARG_WITH([runtimedir],
  56   [AS_HELP_STRING([--with-runtimedir=PATH], [path for runtime files @<:@LOCALSTATEDIR/run@:>@])],
  57   [runtimedir="$with_runtimedir"],
  58   [runtimedir="\$(localstatedir)/run"]
  59 )
  60
  61 AC_ARG_WITH([iproutedir],
  62   [AS_HELP_STRING([--with-iproutedir=PATH], [path to iproute2 config files @<:@/etc/iproute2@:>@])],
  63   [given_iproutedir="yes"]
  64 )
  65
  66 AC_ARG_VAR([FLEX], [location of the Flex program])
  67 AC_ARG_VAR([BISON], [location of the Bison program])
  68 AC_ARG_VAR([M4], [location of the M4 program])
  69
  70
  71 if test "$srcdir" = . ; then
  72   # Building in current directory => create obj directory holding all objects
  73   objdir=obj
  74   mkdir -p obj
  75   srcdir_rel=..
  76   makefiles="Makefile:tools/Makefile-top.in obj/Makefile:tools/Makefile.in obj/Rules:tools/Rules.in"
  77   exedir=..
  78 else
  79   # Building in separate directory
  80   objdir=.
  81   srcdir_rel=$srcdir
  82   makefiles="Makefile:tools/Makefile.in Rules:tools/Rules.in"
  83   exedir=.
  84 fi
  85
  86 case $srcdir_rel in
  87   /*)   srcdir_rel_mf=$srcdir_rel ;;
  88   *)    srcdir_rel_mf="\$(root-rel)$srcdir_rel" ;;
  89 esac
  90
  91 AC_SUBST([objdir])
  92 AC_SUBST([exedir])
  93 AC_SUBST([srcdir_rel_mf])
  94 AC_SUBST([runtimedir])
  95
  96 if test "$enable_ipv6" = yes ; then
  97   ip=ipv6
  98   SUFFIX=6
  99   proto_radv=radv
 100 else
 101   ip=ipv4
 102   SUFFIX=""
 103 fi
 104
 105 if test "$given_suffix" = yes ; then
 106   SUFFIX="$with_suffix"
 107 fi
 108 AC_SUBST([SUFFIX])
 109
 110 if test "$enable_debug" = yes ; then
 111   CONFIG_FILE="bird$SUFFIX.conf"
 112   CONTROL_SOCKET="bird$SUFFIX.ctl"
 113 else
 114   CONFIG_FILE="\$(sysconfdir)/bird$SUFFIX.conf"
 115   CONTROL_SOCKET="$runtimedir/bird$SUFFIX.ctl"
 116 fi
 117 AC_SUBST([CONFIG_FILE])
 118 AC_SUBST([CONTROL_SOCKET])
 119
 120 AC_SEARCH_LIBS([clock_gettime], [rt posix4],
 121   [],
 122   [AC_MSG_ERROR([Function clock_gettime not available.])]
 123 )
 124
 125 AC_CANONICAL_HOST
 126
 127 # Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC
 128 if test "$ac_test_CFLAGS" != set ; then
 129   bird_cflags_default=yes
 130 fi
 131
 132 AC_PROG_CC
 133 if test -z "$GCC" ; then
 134   AC_MSG_ERROR([This program requires the GNU C Compiler.])
 135 fi
 136
 137 if test "$enable_pthreads" != no ; then
 138   BIRD_CHECK_PTHREADS
 139
 140   if test "$bird_cv_lib_pthreads" = yes ; then
 141     AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
 142     CFLAGS="$CFLAGS -pthread"
 143     LDFLAGS="$LDFLAGS -pthread"
 144     proto_bfd=bfd
 145   elif test "$enable_pthreads" = yes ; then
 146     AC_MSG_ERROR([POSIX threads not available.])
 147   fi
 148
 149   if test "$enable_pthreads" = try ; then
 150     enable_pthreads="$bird_cv_lib_pthreads"
 151   fi
 152 fi
 153
 154 if test "$bird_cflags_default" = yes ; then
 155   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign], [-Wall])
 156   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers], [-Wall -Wextra])
 157   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
 158   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 159
 160   CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wno-parentheses"
 161   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign])
 162   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers])
 163   BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
 164   BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 165 fi
 166 AC_MSG_CHECKING([CFLAGS])
 167 AC_MSG_RESULT([$CFLAGS])
 168
 169
 170 AC_PROG_CPP
 171 AC_PROG_INSTALL
 172 AC_PROG_RANLIB
 173 AC_CHECK_PROG([FLEX], [flex], [flex])
 174 AC_CHECK_PROG([BISON], [bison], [bison])
 175 AC_CHECK_PROGS([M4], [gm4 m4])
 176
 177 test -z "$FLEX"  && AC_MSG_ERROR([Flex is missing.])
 178 test -z "$BISON" && AC_MSG_ERROR([Bison is missing.])
 179 test -z "$M4"    && AC_MSG_ERROR([M4 is missing.])
 180
 181 BIRD_CHECK_PROG_FLAVOR_GNU([$M4],
 182   [],
 183   [AC_MSG_ERROR([Provided M4 is not GNU M4.])]
 184 )
 185
 186 if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then
 187   if test -f $with_sysconfig ; then
 188     sysdesc=$with_sysconfig
 189   else
 190     sysdesc=$srcdir/sysdep/cf/$with_sysconfig
 191     if ! test -f $sysdesc ; then
 192       sysdesc=$sysdesc.h
 193     fi
 194   fi
 195 elif test -f sysconfig.h ; then
 196   sysdesc=sysconfig
 197 else
 198   case "$ip:$host_os" in
 199     ipv6:linux*)
 200       sysdesc=linux-v6
 201       default_iproutedir="/etc/iproute2"
 202       ;;
 203     ipv4:linux*)
 204       sysdesc=linux
 205       default_iproutedir="/etc/iproute2"
 206       ;;
 207     ipv6:netbsd*)
 208       sysdesc=bsd-v6
 209       CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
 210       LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
 211       ;;
 212     ipv4:netbsd*)
 213       sysdesc=bsd
 214       CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
 215       LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
 216       ;;
 217     ipv6:freebsd*)
 218       sysdesc=bsd-v6
 219       ;;
 220     ipv4:freebsd*)
 221       sysdesc=bsd
 222       ;;
 223     ipv6:dragonfly*)
 224       sysdesc=bsd-v6
 225       ;;
 226     ipv4:dragonfly*)
 227       sysdesc=bsd
 228       ;;
 229     ipv6:kfreebsd*)
 230       sysdesc=bsd-v6
 231       ;;
 232     ipv4:kfreebsd*)
 233       sysdesc=bsd
 234       ;;
 235     ipv6:openbsd*)
 236       sysdesc=bsd-v6
 237       ;;
 238     ipv4:openbsd*)
 239       sysdesc=bsd
 240       ;;
 241     *)
 242       AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
 243       ;;
 244   esac
 245   sysdesc=$srcdir/sysdep/cf/$sysdesc.h
 246 fi
 247 AC_MSG_CHECKING([which OS configuration should we use])
 248 AC_MSG_RESULT([$sysdesc])
 249 if ! test -f $sysdesc ; then
 250   AC_MSG_ERROR([The system configuration file is missing.])
 251 fi
 252 sysname=`echo $sysdesc | sed 's/\.h$//'`
 253 AC_DEFINE_UNQUOTED([SYSCONF_INCLUDE], ["$sysdesc"], [Which sysdep header to include])
 254
 255 AC_MSG_CHECKING([system-dependent directories])
 256 sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '` lib"
 257 AC_MSG_RESULT([$sysdep_dirs])
 258 AC_SUBST([sysdep_dirs])
 259
 260 if test "$with_iproutedir" = no ; then with_iproutedir= ; fi
 261
 262 if test -n "$given_iproutedir"
 263 then iproutedir=$with_iproutedir
 264 else iproutedir=$default_iproutedir
 265 fi
 266
 267 AC_SUBST([iproutedir])
 268
 269 all_protocols="$proto_bfd bgp ospf pipe $proto_radv rip static"
 270 if test "$ip" = ipv6 ; then
 271    all_protocols="$all_protocols babel"
 272 fi
 273 all_protocols=`echo $all_protocols | sed 's/ /,/g'`
 274
 275 if test "$with_protocols" = all ; then
 276   with_protocols="$all_protocols"
 277 fi
 278
 279 AH_TEMPLATE([CONFIG_BABEL],     [Babel protocol])
 280 AH_TEMPLATE([CONFIG_BFD],       [BFD protocol])
 281 AH_TEMPLATE([CONFIG_BGP],       [BGP protocol])
 282 AH_TEMPLATE([CONFIG_OSPF],      [OSPF protocol])
 283 AH_TEMPLATE([CONFIG_PIPE],      [Pipe protocol])
 284 AH_TEMPLATE([CONFIG_RADV],      [RAdv protocol])
 285 AH_TEMPLATE([CONFIG_RIP],       [RIP protocol])
 286 AH_TEMPLATE([CONFIG_STATIC],    [Static protocol])
 287
 288 AC_MSG_CHECKING([protocols])
 289 protocols=`echo "$with_protocols" | sed 's/,/ /g'`
 290 if test "$protocols" = no ; then protocols= ; fi
 291 for a in $protocols ; do
 292   if ! test -f $srcdir/proto/$a/Makefile ; then
 293     AC_MSG_RESULT([failed])
 294     AC_MSG_ERROR([Requested protocol $a not found])
 295   fi
 296   AC_DEFINE_UNQUOTED([CONFIG_`echo $a | tr 'a-z' 'A-Z'`])
 297 done
 298 AC_MSG_RESULT([ok])
 299 AC_SUBST([protocols])
 300
 301 case $sysdesc in
 302   */linux*|*/linux-v6*)
 303     AC_CHECK_HEADER([linux/rtnetlink.h],
 304       [],
 305       [AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],
 306       [
 307         dnl Some older versions of Linux kernel headers require these includes
 308         #include <asm/types.h>
 309         #include <sys/socket.h>
 310       ]
 311     )
 312     ;;
 313 esac
 314
 315 AC_CHECK_HEADERS_ONCE([alloca.h syslog.h])
 316 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [], [#include <sys/socket.h>])
 317
 318 AC_C_BIGENDIAN(
 319   [AC_DEFINE([CPU_BIG_ENDIAN], [1], [Define to 1 if cpu is big endian])],
 320   [AC_DEFINE([CPU_LITTLE_ENDIAN], [1], [Define to 1 if cpu is little endian])],
 321   [AC_MSG_ERROR([Cannot determine CPU endianity.])]
 322 )
 323
 324 if test "$enable_debug" = yes ; then
 325   AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
 326   if test "$enable_memcheck" = yes ; then
 327     AC_CHECK_LIB([dmalloc], [dmalloc_debug])
 328     if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
 329       AC_CHECK_LIB([efence], [malloc])
 330     fi
 331   fi
 332 fi
 333
 334 CLIENT=
 335 CLIENT_LIBS=
 336 if test "$enable_client" = yes ; then
 337   CLIENT=birdc
 338   BASE_LIBS="$LIBS"
 339   LIBS=""
 340
 341   AC_CHECK_HEADERS([curses.h],
 342     [],
 343     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 344     [AC_INCLUDES_DEFAULT]
 345   )
 346
 347   AC_SEARCH_LIBS([tgetent], [tinfo tinfow ncurses curses termcap],
 348     [TINFO_LIBS="$LIBS"; LIBS=""],
 349     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 350   )
 351
 352   AC_CHECK_HEADERS([readline/readline.h readline/history.h],
 353     [],
 354     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 355     [AC_INCLUDES_DEFAULT]
 356   )
 357
 358   AC_SEARCH_LIBS([rl_callback_read_char], [readline],
 359     [READLINE_LIBS="$LIBS"; LIBS=""],
 360     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 361     [$TINFO_LIBS]
 362   )
 363
 364   AC_SEARCH_LIBS([add_history], [history readline],
 365     [HISTORY_LIBS="$LIBS"; LIBS=""],
 366     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 367     [$TINFO_LIBS]
 368   )
 369
 370   AC_CHECK_LIB([readline], [rl_crlf],
 371     [AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()])],
 372     [],
 373     [$TINFO_LIBS]
 374   )
 375
 376   AC_CHECK_LIB([readline], [rl_ding],
 377     [AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()])],
 378     [],
 379     [$TINFO_LIBS]
 380   )
 381
 382   LIBS="$BASE_LIBS"
 383   CLIENT_LIBS="$HISTORY_LIBS $READLINE_LIBS $TINFO_LIBS"
 384 fi
 385 AC_SUBST([CLIENT])
 386 AC_SUBST([CLIENT_LIBS])
 387
 388 mkdir -p $objdir/sysdep
 389 AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in])
 390 AC_CONFIG_COMMANDS([merge],
 391   [ export CPP="$CPP"; $srcdir/tools/mergedirs $srcdir $srcdir_rel $objdir $sysdep_dirs ],
 392   [
 393     srcdir=$srcdir
 394     srcdir_rel=$srcdir_rel
 395     objdir=$objdir
 396     sysdep_dirs="$sysdep_dirs"
 397   ]
 398 )
 399 AC_CONFIG_FILES([$makefiles])
 400 AC_OUTPUT
 401
 402 rm -f $objdir/sysdep/paths.h
 403
 404 AC_MSG_RESULT()
 405 AC_MSG_RESULT([BIRD was configured with the following options:])
 406 AC_MSG_RESULT([        Source directory:        $srcdir])
 407 AC_MSG_RESULT([        Object directory:        $objdir])
 408 AC_MSG_RESULT([        Iproute2 directory:      $iproutedir])
 409 AC_MSG_RESULT([        System configuration:    $sysdesc])
 410 AC_MSG_RESULT([        Debugging:               $enable_debug])
 411 AC_MSG_RESULT([        POSIX threads:           $enable_pthreads])
 412 AC_MSG_RESULT([        Routing protocols:       $protocols])
 413 AC_MSG_RESULT([        Client:                  $enable_client])
 414 rm -f $objdir/.*-stamp