configure.ac

   1 dnl ** This is a configure script template for BIRD
   2 dnl ** Process it with autoconf to get ./configure
   3 dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz>
   4
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([conf/confbase.Y])
   7 AC_CONFIG_AUX_DIR([tools])
   8
   9 AC_ARG_ENABLE([client],
  10   [AS_HELP_STRING([--enable-client], [enable building of BIRD client @<:@yes@:>@])],
  11   [],
  12   [enable_client=yes]
  13 )
  14
  15 AC_ARG_ENABLE([debug],
  16   [AS_HELP_STRING([--enable-debug], [enable internal debugging routines @<:@no@:>@])],
  17   [],
  18   [enable_debug=no]
  19 )
  20
  21 AC_ARG_ENABLE([memcheck],
  22   [AS_HELP_STRING([--enable-memcheck], [check memory allocations when debugging @<:@yes@:>@])],
  23   [],
  24   [enable_memcheck=yes]
  25 )
  26
  27 AC_ARG_ENABLE([pthreads],
  28   [AS_HELP_STRING([--enable-pthreads], [enable POSIX threads support @<:@try@:>@])],
  29   [],
  30   [enable_pthreads=try]
  31 )
  32
  33 AC_ARG_ENABLE([libssh],
  34   [AS_HELP_STRING([--enable-libssh], [enable LibSSH support together with RPKI @<:@try@:>@])],
  35   [],
  36   [enable_libssh=try]
  37 )
  38
  39 AC_ARG_ENABLE([mpls-kernel],
  40   [AS_HELP_STRING([--enable-mpls-kernel], [enable MPLS support in kernel protocol @<:@try@:>@])],
  41   [],
  42   [enable_mpls_kernel=try]
  43 )
  44
  45 AC_ARG_WITH([protocols],
  46   [AS_HELP_STRING([--with-protocols=LIST], [include specified routing protocols @<:@all@:>@])],
  47   [],
  48   [with_protocols="all"]
  49 )
  50
  51 AC_ARG_WITH([sysconfig],
  52   [AS_HELP_STRING([--with-sysconfig=FILE], [use specified BIRD system configuration file])],
  53   []
  54 )
  55
  56 AC_ARG_WITH([runtimedir],
  57   [AS_HELP_STRING([--with-runtimedir=PATH], [path for runtime files @<:@LOCALSTATEDIR/run@:>@])],
  58   [runtimedir="$with_runtimedir"],
  59   [runtimedir="\$(localstatedir)/run"]
  60 )
  61
  62 AC_ARG_WITH([iproutedir],
  63   [AS_HELP_STRING([--with-iproutedir=PATH], [path to iproute2 config files @<:@/etc/iproute2@:>@])],
  64   [given_iproutedir="yes"]
  65 )
  66
  67 AC_ARG_VAR([FLEX], [location of the Flex program])
  68 AC_ARG_VAR([BISON], [location of the Bison program])
  69 AC_ARG_VAR([M4], [location of the M4 program])
  70
  71
  72 if test "$srcdir" = . ; then
  73   # Building in current directory => create obj directory holding all objects
  74   objdir=obj
  75 else
  76   # Building in separate directory
  77   objdir=.
  78 fi
  79
  80 exedir=.
  81
  82 AC_SUBST([objdir])
  83 AC_SUBST([exedir])
  84 AC_SUBST([srcdir])
  85 AC_SUBST([runtimedir])
  86
  87
  88 if test "$enable_debug" = yes ; then
  89   CONFIG_FILE="bird.conf"
  90   CONTROL_SOCKET="bird.ctl"
  91 else
  92   CONFIG_FILE="\$(sysconfdir)/bird.conf"
  93   CONTROL_SOCKET="$runtimedir/bird.ctl"
  94 fi
  95 AC_SUBST([CONFIG_FILE])
  96 AC_SUBST([CONTROL_SOCKET])
  97
  98 AC_SEARCH_LIBS([clock_gettime], [rt posix4],
  99   [],
 100   [AC_MSG_ERROR([Function clock_gettime not available.])]
 101 )
 102
 103 AC_CANONICAL_HOST
 104
 105 # Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC
 106 if test "$ac_test_CFLAGS" != set ; then
 107   bird_cflags_default=yes
 108 fi
 109
 110 AC_PROG_CC
 111 AC_PROG_CC_C99
 112 if test -z "$GCC" ; then
 113   AC_MSG_ERROR([This program requires the GNU C Compiler.])
 114 fi
 115
 116 if test "$enable_pthreads" != no ; then
 117   BIRD_CHECK_PTHREADS
 118
 119   if test "$bird_cv_lib_pthreads" = yes ; then
 120     AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
 121     CFLAGS="$CFLAGS -pthread"
 122     LDFLAGS="$LDFLAGS -pthread"
 123     proto_bfd=bfd
 124   elif test "$enable_pthreads" = yes ; then
 125     AC_MSG_ERROR([POSIX threads not available.])
 126   fi
 127
 128   if test "$enable_pthreads" = try ; then
 129     enable_pthreads="$bird_cv_lib_pthreads"
 130   fi
 131 fi
 132
 133 if test "$bird_cflags_default" = yes ; then
 134   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign], [-Wall])
 135   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers], [-Wall -Wextra])
 136   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
 137   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 138
 139   CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wno-parentheses"
 140   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign])
 141   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers])
 142   BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
 143   BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 144 fi
 145 AC_MSG_CHECKING([CFLAGS])
 146 AC_MSG_RESULT([$CFLAGS])
 147
 148
 149 AC_PROG_CPP
 150 AC_PROG_INSTALL
 151 AC_PROG_RANLIB
 152 AC_CHECK_PROG([FLEX], [flex], [flex])
 153 AC_CHECK_PROG([BISON], [bison], [bison])
 154 AC_CHECK_PROGS([M4], [gm4 m4])
 155
 156 test -z "$FLEX"  && AC_MSG_ERROR([Flex is missing.])
 157 test -z "$BISON" && AC_MSG_ERROR([Bison is missing.])
 158 test -z "$M4"    && AC_MSG_ERROR([M4 is missing.])
 159
 160 AC_MSG_CHECKING([bison version])
 161 BIRD_CHECK_BISON_VERSION(BISON_VERSION)
 162 AC_MSG_RESULT([$BISON_VERSION])
 163 if test "$bird_bison_synclines" = yes; then
 164   M4FLAGS="$M4FLAGS -s"
 165 fi
 166
 167 if test "$bird_bison_enhanced_error" = yes; then
 168   BISONFLAGS="$BISONFLAGS -Dparse.lac=full -Dparse.error=verbose"
 169 fi
 170
 171 AC_SUBST([M4FLAGS])
 172 AC_SUBST([BISONFLAGS])
 173
 174 BIRD_CHECK_PROG_FLAVOR_GNU([$M4],
 175   [],
 176   [AC_MSG_ERROR([Provided M4 is not GNU M4.])]
 177 )
 178
 179 if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then
 180   if test -f $with_sysconfig ; then
 181     sysdesc=$with_sysconfig
 182   else
 183     sysdesc=$srcdir/sysdep/cf/$with_sysconfig
 184     if ! test -f $sysdesc ; then
 185       sysdesc=$sysdesc.h
 186     fi
 187   fi
 188 elif test -f sysconfig.h ; then
 189   sysdesc=sysconfig
 190 else
 191   case "$host_os" in
 192     linux*)
 193       sysdesc=linux
 194       default_iproutedir="/etc/iproute2"
 195       ;;
 196     freebsd*)
 197       sysdesc=bsd
 198       CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 199       LDFLAGS="$LDFLAGS -L/usr/local/lib"
 200       ;;
 201     kfreebsd*)
 202       sysdesc=bsd
 203       ;;
 204     netbsd*)
 205       sysdesc=bsd
 206       CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
 207       LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
 208       ;;
 209     openbsd*)
 210       sysdesc=bsd
 211       ;;
 212     dragonfly*)
 213       sysdesc=bsd
 214       ;;
 215     *)
 216       AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
 217       ;;
 218     esac
 219     sysdesc=$srcdir/sysdep/cf/$sysdesc.h
 220 fi
 221 AC_MSG_CHECKING([which OS configuration should we use])
 222 AC_MSG_RESULT([$sysdesc])
 223 if ! test -f $sysdesc ; then
 224   AC_MSG_ERROR([The system configuration file is missing.])
 225 fi
 226 sysname=`echo $sysdesc | sed 's/\.h$//'`
 227 AC_DEFINE_UNQUOTED([SYSCONF_INCLUDE], ["$sysdesc"], [Which sysdep header to include])
 228
 229 AC_MSG_CHECKING([system-dependent directories])
 230 sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '`"
 231 AC_MSG_RESULT([$sysdep_dirs])
 232 AC_SUBST([sysdep_dirs])
 233
 234 if test "$with_iproutedir" = no ; then with_iproutedir= ; fi
 235
 236 if test -n "$given_iproutedir"
 237 then iproutedir=$with_iproutedir
 238 else iproutedir=$default_iproutedir
 239 fi
 240
 241 AC_SUBST([iproutedir])
 242
 243 DAEMON_LIBS=
 244 AC_SUBST(DAEMON_LIBS)
 245
 246 if test "$enable_libssh" != no ; then
 247   AC_CHECK_HEADER([libssh/libssh.h], [true], [fail=yes], [ ])
 248   AC_CHECK_LIB([ssh], [ssh_connect], [true], [fail=yes])
 249
 250   if test "$fail" != yes ; then
 251     AC_DEFINE([HAVE_LIBSSH], [1], [Define to 1 if you have the `ssh' library (-lssh).])
 252     DAEMON_LIBS="-lssh $DAEMON_LIBS"
 253     proto_rpki=rpki
 254     enable_libssh=yes
 255   else
 256     if test "$enable_libssh" = yes ; then
 257       AC_MSG_ERROR([LibSSH not available.])
 258     else
 259       enable_libssh=no
 260     fi
 261   fi
 262 fi
 263
 264 if test "$enable_mpls_kernel" != no ; then
 265   BIRD_CHECK_MPLS_KERNEL
 266
 267   if test "$bird_cv_mpls_kernel" = yes ; then
 268     AC_DEFINE([HAVE_MPLS_KERNEL], [1], [Define to 1 if kernel is MPLS capable])
 269   elif test "$enable_mpls_kernel" = yes ; then
 270     AC_MSG_ERROR([Kernel MPLS support not found.])
 271   fi
 272
 273   if test "$enable_mpls_kernel" = try ; then
 274     enable_mpls_kernel="$bird_cv_mpls_kernel"
 275   fi
 276 fi
 277
 278 all_protocols="$proto_bfd babel bgp ospf pipe radv rip $proto_rpki static"
 279
 280 all_protocols=`echo $all_protocols | sed 's/ /,/g'`
 281
 282 if test "$with_protocols" = all ; then
 283   with_protocols="$all_protocols"
 284 fi
 285
 286 AH_TEMPLATE([CONFIG_BABEL],     [Babel protocol])
 287 AH_TEMPLATE([CONFIG_BFD],       [BFD protocol])
 288 AH_TEMPLATE([CONFIG_BGP],       [BGP protocol])
 289 AH_TEMPLATE([CONFIG_OSPF],      [OSPF protocol])
 290 AH_TEMPLATE([CONFIG_PIPE],      [Pipe protocol])
 291 AH_TEMPLATE([CONFIG_RADV],      [RAdv protocol])
 292 AH_TEMPLATE([CONFIG_RIP],       [RIP protocol])
 293 AH_TEMPLATE([CONFIG_RPKI],      [RPKI protocol])
 294 AH_TEMPLATE([CONFIG_STATIC],    [Static protocol])
 295
 296 AC_MSG_CHECKING([protocols])
 297 protocols=`echo "$with_protocols" | sed 's/,/ /g'`
 298 if test "$protocols" = no ; then protocols= ; fi
 299 for a in $protocols ; do
 300   if ! test -f $srcdir/proto/$a/Makefile ; then
 301     AC_MSG_RESULT([failed])
 302     AC_MSG_ERROR([Requested protocol $a not found])
 303   fi
 304   AC_DEFINE_UNQUOTED([CONFIG_`echo $a | tr 'a-z' 'A-Z'`])
 305 done
 306 AC_MSG_RESULT([ok])
 307 AC_SUBST([protocols])
 308
 309 case $sysdesc in
 310   */linux*)
 311     AC_CHECK_HEADER([linux/rtnetlink.h],
 312       [],
 313       [AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],
 314       [
 315         dnl Some older versions of Linux kernel headers require these includes
 316         #include <asm/types.h>
 317         #include <sys/socket.h>
 318       ]
 319     )
 320     ;;
 321 esac
 322
 323 AC_CHECK_HEADERS_ONCE([alloca.h syslog.h])
 324 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [], [#include <sys/socket.h>])
 325
 326 AC_C_BIGENDIAN(
 327   [AC_DEFINE([CPU_BIG_ENDIAN], [1], [Define to 1 if cpu is big endian])],
 328   [AC_DEFINE([CPU_LITTLE_ENDIAN], [1], [Define to 1 if cpu is little endian])],
 329   [AC_MSG_ERROR([Cannot determine CPU endianity.])]
 330 )
 331
 332 BIRD_CHECK_ANDROID_GLOB
 333 if test "$bird_cv_lib_glob" = no ; then
 334   AC_MSG_ERROR([glob.h not found.])
 335 elif test "$bird_cv_lib_glob" != yes ; then
 336   LIBS="$LIBS $bird_cv_lib_glob"
 337 fi
 338
 339 BIRD_CHECK_ANDROID_LOG
 340 if test "$bird_cv_lib_log" = no ; then
 341   AC_MSG_ERROR([don't know how to link syslog.])
 342 elif test "$bird_cv_lib_log" != yes ; then
 343   LIBS="$LIBS $bird_cv_lib_log"
 344 fi
 345
 346 if test "$enable_debug" = yes ; then
 347   AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
 348   LDFLAGS="$LDFLAGS -rdynamic"
 349   CFLAGS="$CFLAGS -O0 -ggdb -g3 -gdwarf-4"
 350
 351   AC_CHECK_HEADER([execinfo.h],
 352     [
 353       AC_DEFINE([HAVE_EXECINFO_H], [1], [Define to 1 if you have the <execinfo.h> header file.])
 354       AC_SEARCH_LIBS([backtrace], [execinfo],
 355         [],
 356         [AC_MSG_ERROR([Function backtrace not available.])]
 357       )
 358     ]
 359   )
 360
 361   if test "$enable_memcheck" = yes ; then
 362     AC_CHECK_LIB([dmalloc], [dmalloc_debug])
 363     if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
 364       AC_CHECK_LIB([efence], [malloc])
 365     fi
 366   fi
 367 fi
 368
 369 CLIENT=birdcl
 370 CLIENT_LIBS=
 371 if test "$enable_client" = yes ; then
 372   CLIENT="$CLIENT birdc"
 373   BASE_LIBS="$LIBS"
 374   LIBS=""
 375
 376   AC_CHECK_HEADERS([curses.h],
 377     [],
 378     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 379     [AC_INCLUDES_DEFAULT]
 380   )
 381
 382   AC_SEARCH_LIBS([tgetent], [tinfo tinfow ncurses curses termcap],
 383     [TINFO_LIBS="$LIBS"; LIBS=""],
 384     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 385   )
 386
 387   AC_CHECK_HEADERS([readline/readline.h readline/history.h],
 388     [],
 389     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 390     [AC_INCLUDES_DEFAULT]
 391   )
 392
 393   AC_SEARCH_LIBS([rl_callback_read_char], [readline],
 394     [READLINE_LIBS="$LIBS"; LIBS=""],
 395     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 396     [$TINFO_LIBS]
 397   )
 398
 399   AC_CHECK_LIB([readline], [rl_crlf],
 400     [AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()])],
 401     [],
 402     [$TINFO_LIBS]
 403   )
 404
 405   AC_CHECK_LIB([readline], [rl_ding],
 406     [AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()])],
 407     [],
 408     [$TINFO_LIBS]
 409   )
 410
 411   LIBS="$BASE_LIBS"
 412   CLIENT_LIBS="$READLINE_LIBS $TINFO_LIBS"
 413 fi
 414 AC_SUBST([CLIENT])
 415 AC_SUBST([CLIENT_LIBS])
 416
 417 mkdir -p $objdir/sysdep
 418 AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in])
 419 AC_CONFIG_FILES([Makefile:Makefile.in])
 420 AC_OUTPUT
 421
 422 AC_MSG_RESULT()
 423 AC_MSG_RESULT([BIRD was configured with the following options:])
 424 AC_MSG_RESULT([        Source directory:        $srcdir])
 425 AC_MSG_RESULT([        Object directory:        $objdir])
 426 AC_MSG_RESULT([        Iproute2 directory:      $iproutedir])
 427 AC_MSG_RESULT([        System configuration:    $sysdesc])
 428 AC_MSG_RESULT([        Debugging:               $enable_debug])
 429 AC_MSG_RESULT([        POSIX threads:           $enable_pthreads])
 430 AC_MSG_RESULT([        Routing protocols:       $protocols])
 431 AC_MSG_RESULT([        Kernel MPLS support:     $enable_mpls_kernel])
 432 AC_MSG_RESULT([        Client:                  $enable_client])
 433
 434 rm -f $objdir/.*-stamp