configure.ac

   1 dnl ** This is a configure script template for BIRD
   2 dnl ** Process it with autoconf to get ./configure
   3 dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz>
   4
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([conf/confbase.Y])
   7 AC_CONFIG_AUX_DIR([tools])
   8
   9 AC_ARG_ENABLE([client],
  10   [AS_HELP_STRING([--enable-client], [enable building of BIRD client @<:@yes@:>@])],
  11   [],
  12   [enable_client=yes]
  13 )
  14
  15 AC_ARG_ENABLE([debug],
  16   [AS_HELP_STRING([--enable-debug], [enable internal debugging routines @<:@no@:>@])],
  17   [],
  18   [enable_debug=no]
  19 )
  20
  21 AC_ARG_ENABLE([memcheck],
  22   [AS_HELP_STRING([--enable-memcheck], [check memory allocations when debugging @<:@yes@:>@])],
  23   [],
  24   [enable_memcheck=yes]
  25 )
  26
  27 AC_ARG_ENABLE([pthreads],
  28   [AS_HELP_STRING([--enable-pthreads], [enable POSIX threads support @<:@try@:>@])],
  29   [],
  30   [enable_pthreads=try]
  31 )
  32
  33 AC_ARG_ENABLE([libssh],
  34   [AS_HELP_STRING([--enable-libssh], [enable LibSSH support together with RPKI @<:@try@:>@])],
  35   [],
  36   [enable_libssh=try]
  37 )
  38
  39 AC_ARG_ENABLE([mpls-kernel],
  40   [AS_HELP_STRING([--enable-mpls-kernel], [enable MPLS support in kernel protocol @<:@try@:>@])],
  41   [],
  42   [enable_mpls_kernel=try]
  43 )
  44
  45 AC_ARG_WITH([protocols],
  46   [AS_HELP_STRING([--with-protocols=LIST], [include specified routing protocols @<:@all@:>@])],
  47   [],
  48   [with_protocols="all"]
  49 )
  50
  51 AC_ARG_WITH([sysconfig],
  52   [AS_HELP_STRING([--with-sysconfig=FILE], [use specified BIRD system configuration file])],
  53   []
  54 )
  55
  56 AC_ARG_WITH([runtimedir],
  57   [AS_HELP_STRING([--with-runtimedir=PATH], [path for runtime files @<:@LOCALSTATEDIR/run@:>@])],
  58   [runtimedir="$with_runtimedir"],
  59   [runtimedir="\$(localstatedir)/run"]
  60 )
  61
  62 AC_ARG_WITH([iproutedir],
  63   [AS_HELP_STRING([--with-iproutedir=PATH], [path to iproute2 config files @<:@/etc/iproute2@:>@])],
  64   [given_iproutedir="yes"]
  65 )
  66
  67 AC_ARG_VAR([FLEX], [location of the Flex program])
  68 AC_ARG_VAR([BISON], [location of the Bison program])
  69 AC_ARG_VAR([M4], [location of the M4 program])
  70
  71
  72 if test "$srcdir" = . ; then
  73   # Building in current directory => create obj directory holding all objects
  74   objdir=obj
  75 else
  76   # Building in separate directory
  77   objdir=.
  78 fi
  79
  80 exedir=.
  81
  82 AC_SUBST([objdir])
  83 AC_SUBST([exedir])
  84 AC_SUBST([srcdir])
  85 AC_SUBST([runtimedir])
  86
  87
  88 if test "$enable_debug" = yes ; then
  89   CONFIG_FILE="bird.conf"
  90   CONTROL_SOCKET="bird.ctl"
  91 else
  92   CONFIG_FILE="\$(sysconfdir)/bird.conf"
  93   CONTROL_SOCKET="$runtimedir/bird.ctl"
  94 fi
  95 AC_SUBST([CONFIG_FILE])
  96 AC_SUBST([CONTROL_SOCKET])
  97
  98 AC_SEARCH_LIBS([clock_gettime], [rt posix4],
  99   [],
 100   [AC_MSG_ERROR([Function clock_gettime not available.])]
 101 )
 102
 103 AC_CANONICAL_HOST
 104
 105 # Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC
 106 if test "$ac_test_CFLAGS" != set ; then
 107   bird_cflags_default=yes
 108 fi
 109
 110 AC_PROG_CC
 111 AC_PROG_CC_C99
 112 if test -z "$GCC" ; then
 113   AC_MSG_ERROR([This program requires the GNU C Compiler.])
 114 fi
 115
 116 if test "$enable_pthreads" != no ; then
 117   BIRD_CHECK_PTHREADS
 118
 119   if test "$bird_cv_lib_pthreads" = yes ; then
 120     AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
 121     CFLAGS="$CFLAGS -pthread"
 122     LDFLAGS="$LDFLAGS -pthread"
 123     proto_bfd=bfd
 124   elif test "$enable_pthreads" = yes ; then
 125     AC_MSG_ERROR([POSIX threads not available.])
 126   fi
 127
 128   if test "$enable_pthreads" = try ; then
 129     enable_pthreads="$bird_cv_lib_pthreads"
 130   fi
 131 fi
 132
 133 if test "$bird_cflags_default" = yes ; then
 134   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign], [-Wall])
 135   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers], [-Wall -Wextra])
 136   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
 137   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 138
 139   CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wno-parentheses"
 140   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign])
 141   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers])
 142   BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
 143   BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 144 fi
 145 AC_MSG_CHECKING([CFLAGS])
 146 AC_MSG_RESULT([$CFLAGS])
 147
 148
 149 AC_PROG_CPP
 150 AC_PROG_INSTALL
 151 AC_PROG_RANLIB
 152 AC_CHECK_PROG([FLEX], [flex], [flex])
 153 AC_CHECK_PROG([BISON], [bison], [bison])
 154 AC_CHECK_PROGS([M4], [gm4 m4])
 155
 156 test -z "$FLEX"  && AC_MSG_ERROR([Flex is missing.])
 157 test -z "$BISON" && AC_MSG_ERROR([Bison is missing.])
 158 test -z "$M4"    && AC_MSG_ERROR([M4 is missing.])
 159
 160 BIRD_CHECK_PROG_FLAVOR_GNU([$M4],
 161   [],
 162   [AC_MSG_ERROR([Provided M4 is not GNU M4.])]
 163 )
 164
 165 if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then
 166   if test -f $with_sysconfig ; then
 167     sysdesc=$with_sysconfig
 168   else
 169     sysdesc=$srcdir/sysdep/cf/$with_sysconfig
 170     if ! test -f $sysdesc ; then
 171       sysdesc=$sysdesc.h
 172     fi
 173   fi
 174 elif test -f sysconfig.h ; then
 175   sysdesc=sysconfig
 176 else
 177   case "$host_os" in
 178     linux*)
 179       sysdesc=linux
 180       default_iproutedir="/etc/iproute2"
 181       ;;
 182     freebsd*)
 183       sysdesc=bsd
 184       ;;
 185     kfreebsd*)
 186       sysdesc=bsd
 187       ;;
 188     netbsd*)
 189       sysdesc=bsd
 190       CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
 191       LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
 192       ;;
 193     openbsd*)
 194       sysdesc=bsd
 195       ;;
 196     dragonfly*)
 197       sysdesc=bsd
 198       ;;
 199     *)
 200       AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
 201       ;;
 202     esac
 203     sysdesc=$srcdir/sysdep/cf/$sysdesc.h
 204 fi
 205 AC_MSG_CHECKING([which OS configuration should we use])
 206 AC_MSG_RESULT([$sysdesc])
 207 if ! test -f $sysdesc ; then
 208   AC_MSG_ERROR([The system configuration file is missing.])
 209 fi
 210 sysname=`echo $sysdesc | sed 's/\.h$//'`
 211 AC_DEFINE_UNQUOTED([SYSCONF_INCLUDE], ["$sysdesc"], [Which sysdep header to include])
 212
 213 AC_MSG_CHECKING([system-dependent directories])
 214 sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '`"
 215 AC_MSG_RESULT([$sysdep_dirs])
 216 AC_SUBST([sysdep_dirs])
 217
 218 if test "$with_iproutedir" = no ; then with_iproutedir= ; fi
 219
 220 if test -n "$given_iproutedir"
 221 then iproutedir=$with_iproutedir
 222 else iproutedir=$default_iproutedir
 223 fi
 224
 225 AC_SUBST([iproutedir])
 226
 227 DAEMON_LIBS=
 228 AC_SUBST(DAEMON_LIBS)
 229
 230 if test "$enable_libssh" != no ; then
 231   AC_CHECK_HEADER([libssh/libssh.h], [true], [fail=yes], [ ])
 232   AC_CHECK_LIB([ssh], [ssh_connect], [true], [fail=yes])
 233
 234   if test "$fail" != yes ; then
 235     AC_DEFINE([HAVE_LIBSSH], [1], [Define to 1 if you have the `ssh' library (-lssh).])
 236     DAEMON_LIBS="-lssh $DAEMON_LIBS"
 237     proto_rpki=rpki
 238     enable_libssh=yes
 239   else
 240     if test "$enable_libssh" = yes ; then
 241       AC_MSG_ERROR([LibSSH not available.])
 242     else
 243       enable_libssh=no
 244     fi
 245   fi
 246 fi
 247
 248 if test "$enable_mpls_kernel" != no ; then
 249   BIRD_CHECK_MPLS_KERNEL
 250
 251   if test "$bird_cv_mpls_kernel" = yes ; then
 252     AC_DEFINE([HAVE_MPLS_KERNEL], [1], [Define to 1 if kernel is MPLS capable])
 253   elif test "$enable_mpls_kernel" = yes ; then
 254     AC_MSG_ERROR([Kernel MPLS support not found.])
 255   fi
 256
 257   if test "$enable_mpls_kernel" = try ; then
 258     enable_mpls_kernel="$bird_cv_mpls_kernel"
 259   fi
 260 fi
 261
 262 all_protocols="$proto_bfd babel bgp ospf pipe radv rip $proto_rpki static"
 263
 264 all_protocols=`echo $all_protocols | sed 's/ /,/g'`
 265
 266 if test "$with_protocols" = all ; then
 267   with_protocols="$all_protocols"
 268 fi
 269
 270 AH_TEMPLATE([CONFIG_BABEL],     [Babel protocol])
 271 AH_TEMPLATE([CONFIG_BFD],       [BFD protocol])
 272 AH_TEMPLATE([CONFIG_BGP],       [BGP protocol])
 273 AH_TEMPLATE([CONFIG_OSPF],      [OSPF protocol])
 274 AH_TEMPLATE([CONFIG_PIPE],      [Pipe protocol])
 275 AH_TEMPLATE([CONFIG_RADV],      [RAdv protocol])
 276 AH_TEMPLATE([CONFIG_RIP],       [RIP protocol])
 277 AH_TEMPLATE([CONFIG_RPKI],      [RPKI protocol])
 278 AH_TEMPLATE([CONFIG_STATIC],    [Static protocol])
 279
 280 AC_MSG_CHECKING([protocols])
 281 protocols=`echo "$with_protocols" | sed 's/,/ /g'`
 282 if test "$protocols" = no ; then protocols= ; fi
 283 for a in $protocols ; do
 284   if ! test -f $srcdir/proto/$a/Makefile ; then
 285     AC_MSG_RESULT([failed])
 286     AC_MSG_ERROR([Requested protocol $a not found])
 287   fi
 288   AC_DEFINE_UNQUOTED([CONFIG_`echo $a | tr 'a-z' 'A-Z'`])
 289 done
 290 AC_MSG_RESULT([ok])
 291 AC_SUBST([protocols])
 292
 293 case $sysdesc in
 294   */linux*)
 295     AC_CHECK_HEADER([linux/rtnetlink.h],
 296       [],
 297       [AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],
 298       [
 299         dnl Some older versions of Linux kernel headers require these includes
 300         #include <asm/types.h>
 301         #include <sys/socket.h>
 302       ]
 303     )
 304     ;;
 305 esac
 306
 307 AC_CHECK_HEADERS_ONCE([alloca.h syslog.h])
 308 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [], [#include <sys/socket.h>])
 309
 310 AC_C_BIGENDIAN(
 311   [AC_DEFINE([CPU_BIG_ENDIAN], [1], [Define to 1 if cpu is big endian])],
 312   [AC_DEFINE([CPU_LITTLE_ENDIAN], [1], [Define to 1 if cpu is little endian])],
 313   [AC_MSG_ERROR([Cannot determine CPU endianity.])]
 314 )
 315
 316 if test "$enable_debug" = yes ; then
 317   AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
 318   LDFLAGS="$LDFLAGS -rdynamic"
 319   CFLAGS="$CFLAGS -O0 -ggdb -g3 -gdwarf-4"
 320
 321   AC_CHECK_HEADER([execinfo.h],
 322     [
 323       AC_DEFINE([HAVE_EXECINFO_H], [1], [Define to 1 if you have the <execinfo.h> header file.])
 324       AC_SEARCH_LIBS([backtrace], [execinfo],
 325         [],
 326         [AC_MSG_ERROR([Function backtrace not available.])]
 327       )
 328     ]
 329   )
 330
 331   if test "$enable_memcheck" = yes ; then
 332     AC_CHECK_LIB([dmalloc], [dmalloc_debug])
 333     if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
 334       AC_CHECK_LIB([efence], [malloc])
 335     fi
 336   fi
 337 fi
 338
 339 CLIENT=birdcl
 340 CLIENT_LIBS=
 341 if test "$enable_client" = yes ; then
 342   CLIENT="$CLIENT birdc"
 343   BASE_LIBS="$LIBS"
 344   LIBS=""
 345
 346   AC_CHECK_HEADERS([curses.h],
 347     [],
 348     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 349     [AC_INCLUDES_DEFAULT]
 350   )
 351
 352   AC_SEARCH_LIBS([tgetent], [tinfo tinfow ncurses curses termcap],
 353     [TINFO_LIBS="$LIBS"; LIBS=""],
 354     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 355   )
 356
 357   AC_CHECK_HEADERS([readline/readline.h readline/history.h],
 358     [],
 359     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 360     [AC_INCLUDES_DEFAULT]
 361   )
 362
 363   AC_SEARCH_LIBS([rl_callback_read_char], [readline],
 364     [READLINE_LIBS="$LIBS"; LIBS=""],
 365     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 366     [$TINFO_LIBS]
 367   )
 368
 369   AC_CHECK_LIB([readline], [rl_crlf],
 370     [AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()])],
 371     [],
 372     [$TINFO_LIBS]
 373   )
 374
 375   AC_CHECK_LIB([readline], [rl_ding],
 376     [AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()])],
 377     [],
 378     [$TINFO_LIBS]
 379   )
 380
 381   LIBS="$BASE_LIBS"
 382   CLIENT_LIBS="$READLINE_LIBS $TINFO_LIBS"
 383 fi
 384 AC_SUBST([CLIENT])
 385 AC_SUBST([CLIENT_LIBS])
 386
 387 mkdir -p $objdir/sysdep
 388 AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in])
 389 AC_CONFIG_FILES([Makefile:Makefile.in])
 390 AC_OUTPUT
 391
 392 AC_MSG_RESULT()
 393 AC_MSG_RESULT([BIRD was configured with the following options:])
 394 AC_MSG_RESULT([        Source directory:        $srcdir])
 395 AC_MSG_RESULT([        Object directory:        $objdir])
 396 AC_MSG_RESULT([        Iproute2 directory:      $iproutedir])
 397 AC_MSG_RESULT([        System configuration:    $sysdesc])
 398 AC_MSG_RESULT([        Debugging:               $enable_debug])
 399 AC_MSG_RESULT([        POSIX threads:           $enable_pthreads])
 400 AC_MSG_RESULT([        Routing protocols:       $protocols])
 401 AC_MSG_RESULT([        Kernel MPLS support:     $enable_mpls_kernel])
 402 AC_MSG_RESULT([        Client:                  $enable_client])
 403
 404 rm -f $objdir/.*-stamp