configure.ac

   1 dnl ** This is a configure script template for BIRD
   2 dnl ** Process it with autoconf to get ./configure
   3 dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz>
   4
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([conf/confbase.Y])
   7 AC_CONFIG_AUX_DIR([tools])
   8
   9 AC_ARG_ENABLE([client],
  10   [AS_HELP_STRING([--enable-client], [enable building of BIRD client @<:@yes@:>@])],
  11   [],
  12   [enable_client=yes]
  13 )
  14
  15 AC_ARG_ENABLE([debug],
  16   [AS_HELP_STRING([--enable-debug], [enable internal debugging routines @<:@no@:>@])],
  17   [],
  18   [enable_debug=no]
  19 )
  20
  21 AC_ARG_ENABLE([debug-generated],
  22   [AS_HELP_STRING([--enable-debug-generated], [enable this to abstain from generating #line @<:@no@:>@])],
  23   [],
  24   [enable_debug_generated=no]
  25 )
  26
  27 AC_ARG_ENABLE([memcheck],
  28   [AS_HELP_STRING([--enable-memcheck], [check memory allocations when debugging @<:@yes@:>@])],
  29   [],
  30   [enable_memcheck=yes]
  31 )
  32
  33 AC_ARG_ENABLE([pthreads],
  34   [AS_HELP_STRING([--enable-pthreads], [enable POSIX threads support @<:@try@:>@])],
  35   [],
  36   [enable_pthreads=try]
  37 )
  38
  39 AC_ARG_ENABLE([libssh],
  40   [AS_HELP_STRING([--enable-libssh], [enable LibSSH support together with RPKI @<:@try@:>@])],
  41   [],
  42   [enable_libssh=try]
  43 )
  44
  45 AC_ARG_ENABLE([mpls-kernel],
  46   [AS_HELP_STRING([--enable-mpls-kernel], [enable MPLS support in kernel protocol @<:@try@:>@])],
  47   [],
  48   [enable_mpls_kernel=try]
  49 )
  50
  51 AC_ARG_WITH([protocols],
  52   [AS_HELP_STRING([--with-protocols=LIST], [include specified routing protocols @<:@all@:>@])],
  53   [],
  54   [with_protocols="all"]
  55 )
  56
  57 AC_ARG_WITH([sysconfig],
  58   [AS_HELP_STRING([--with-sysconfig=FILE], [use specified BIRD system configuration file])]
  59 )
  60
  61 AC_ARG_WITH([runtimedir],
  62   [AS_HELP_STRING([--with-runtimedir=PATH], [run-state data, obsolete variant of --runstatedir])],
  63   [runstatedir="$with_runtimedir"]
  64 )
  65
  66 AC_ARG_WITH([iproutedir],
  67   [AS_HELP_STRING([--with-iproutedir=PATH], [path to iproute2 config files @<:@/etc/iproute2@:>@])],
  68   [given_iproutedir="yes"]
  69 )
  70
  71 AC_ARG_VAR([FLEX], [location of the Flex program])
  72 AC_ARG_VAR([BISON], [location of the Bison program])
  73 AC_ARG_VAR([M4], [location of the M4 program])
  74
  75
  76 if test "$srcdir" = . ; then
  77   # Building in current directory => create obj directory holding all objects
  78   objdir=obj
  79 else
  80   # Building in separate directory
  81   objdir=.
  82 fi
  83
  84 exedir=.
  85
  86 AC_SUBST([objdir])
  87 AC_SUBST([exedir])
  88 AC_SUBST([srcdir])
  89
  90 # Workaround for older Autoconfs that do not define runstatedir
  91 AS_IF([test -z "${runstatedir}"], [runstatedir='${localstatedir}/run'])
  92 AC_SUBST([runstatedir])
  93
  94 CONFIG_FILE="\$(sysconfdir)/bird.conf"
  95 AC_SUBST([CONFIG_FILE])
  96
  97 CONTROL_SOCKET="\$(runstatedir)/bird.ctl"
  98 AC_SUBST([CONTROL_SOCKET])
  99
 100 AC_SEARCH_LIBS([clock_gettime], [rt posix4],
 101   [],
 102   [AC_MSG_ERROR([Function clock_gettime not available.])]
 103 )
 104
 105 AC_CANONICAL_HOST
 106
 107 # Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC
 108 if test "$ac_test_CFLAGS" != set ; then
 109   bird_cflags_default=yes
 110 fi
 111
 112 AC_PROG_CC
 113 AC_PROG_CC_C99
 114 if test -z "$GCC" ; then
 115   AC_MSG_ERROR([This program requires the GNU C Compiler.])
 116 fi
 117
 118 if test "$enable_pthreads" != no ; then
 119   BIRD_CHECK_PTHREADS
 120
 121   if test "$bird_cv_lib_pthreads" = yes ; then
 122     AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
 123     CFLAGS="$CFLAGS -pthread"
 124     LDFLAGS="$LDFLAGS -pthread"
 125     proto_bfd=bfd
 126   elif test "$enable_pthreads" = yes ; then
 127     AC_MSG_ERROR([POSIX threads not available.])
 128   fi
 129
 130   if test "$enable_pthreads" = try ; then
 131     enable_pthreads="$bird_cv_lib_pthreads"
 132   fi
 133 fi
 134
 135 if test "$bird_cflags_default" = yes ; then
 136   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign], [-Wall])
 137   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers], [-Wall -Wextra])
 138   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
 139   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 140
 141   CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wno-parentheses"
 142   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign])
 143   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers])
 144   BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
 145   BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 146 fi
 147 AC_MSG_CHECKING([CFLAGS])
 148 AC_MSG_RESULT([$CFLAGS])
 149
 150 if test "$enable_debug" = no; then
 151   BIRD_CHECK_LTO
 152 fi
 153
 154 if test "$bird_cv_c_lto" = yes; then
 155   CFLAGS="$CFLAGS -flto"
 156   LDFLAGS="$LDFLAGS -flto"
 157 fi
 158
 159 AC_PROG_CPP
 160 AC_PROG_INSTALL
 161 AC_PROG_RANLIB
 162 AC_CHECK_PROG([FLEX], [flex], [flex])
 163 AC_CHECK_PROG([BISON], [bison], [bison])
 164 AC_CHECK_PROGS([M4], [gm4 m4])
 165
 166 test -z "$FLEX"  && AC_MSG_ERROR([Flex is missing.])
 167 test -z "$BISON" && AC_MSG_ERROR([Bison is missing.])
 168 test -z "$M4"    && AC_MSG_ERROR([M4 is missing.])
 169
 170 AC_MSG_CHECKING([bison version])
 171 BIRD_CHECK_BISON_VERSION(BISON_VERSION)
 172 AC_MSG_RESULT([$BISON_VERSION])
 173 if test "$bird_bison_synclines" = yes && test "$enable_debug_generated" = no; then
 174   M4FLAGS="$M4FLAGS -s"
 175 fi
 176
 177 if test "$bird_bison_enhanced_error" = yes; then
 178   BISONFLAGS="$BISONFLAGS -Dparse.lac=full -Dparse.error=verbose"
 179 fi
 180
 181 AC_SUBST([M4FLAGS])
 182 AC_SUBST([BISONFLAGS])
 183
 184 BIRD_CHECK_PROG_FLAVOR_GNU([$M4],
 185   [],
 186   [AC_MSG_ERROR([Provided M4 is not GNU M4.])]
 187 )
 188
 189 if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then
 190   if test -f $with_sysconfig ; then
 191     sysdesc=$with_sysconfig
 192   else
 193     sysdesc=$srcdir/sysdep/cf/$with_sysconfig
 194     if ! test -f $sysdesc ; then
 195       sysdesc=$sysdesc.h
 196     fi
 197   fi
 198 elif test -f sysconfig.h ; then
 199   sysdesc=sysconfig
 200 else
 201   case "$host_os" in
 202     linux*)
 203       sysdesc=linux
 204       default_iproutedir="/etc/iproute2"
 205       ;;
 206     freebsd*)
 207       sysdesc=bsd
 208       CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 209       LDFLAGS="$LDFLAGS -L/usr/local/lib"
 210       ;;
 211     kfreebsd*)
 212       sysdesc=bsd
 213       ;;
 214     netbsd*)
 215       sysdesc=bsd
 216       CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
 217       LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
 218       ;;
 219     openbsd*)
 220       sysdesc=bsd
 221       ;;
 222     dragonfly*)
 223       sysdesc=bsd
 224       ;;
 225     *)
 226       AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
 227       ;;
 228     esac
 229     sysdesc=$srcdir/sysdep/cf/$sysdesc.h
 230 fi
 231 AC_MSG_CHECKING([which OS configuration should we use])
 232 AC_MSG_RESULT([$sysdesc])
 233 if ! test -f $sysdesc ; then
 234   AC_MSG_ERROR([The system configuration file is missing.])
 235 fi
 236 sysname=`echo $sysdesc | sed 's/\.h$//'`
 237 AC_DEFINE_UNQUOTED([SYSCONF_INCLUDE], ["$sysdesc"], [Which sysdep header to include])
 238
 239 AC_MSG_CHECKING([system-dependent directories])
 240 sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '`"
 241 AC_MSG_RESULT([$sysdep_dirs])
 242 AC_SUBST([sysdep_dirs])
 243
 244 if test "$with_iproutedir" = no ; then with_iproutedir= ; fi
 245
 246 if test -n "$given_iproutedir"
 247 then iproutedir=$with_iproutedir
 248 else iproutedir=$default_iproutedir
 249 fi
 250
 251 AC_SUBST([iproutedir])
 252
 253 DAEMON_LIBS=
 254 AC_SUBST(DAEMON_LIBS)
 255
 256 if test "$enable_libssh" != no ; then
 257   AC_CHECK_HEADER([libssh/libssh.h], [true], [fail=yes], [ ])
 258   AC_CHECK_LIB([ssh], [ssh_connect], [true], [fail=yes])
 259
 260   if test "$fail" != yes ; then
 261     AC_DEFINE([HAVE_LIBSSH], [1], [Define to 1 if you have the `ssh' library (-lssh).])
 262     DAEMON_LIBS="-lssh $DAEMON_LIBS"
 263     proto_rpki=rpki
 264     enable_libssh=yes
 265   else
 266     if test "$enable_libssh" = yes ; then
 267       AC_MSG_ERROR([LibSSH not available.])
 268     else
 269       enable_libssh=no
 270     fi
 271   fi
 272 fi
 273
 274 if test "$enable_mpls_kernel" != no ; then
 275   BIRD_CHECK_MPLS_KERNEL
 276
 277   if test "$bird_cv_mpls_kernel" = yes ; then
 278     AC_DEFINE([HAVE_MPLS_KERNEL], [1], [Define to 1 if kernel is MPLS capable])
 279   elif test "$enable_mpls_kernel" = yes ; then
 280     AC_MSG_ERROR([Kernel MPLS support not found.])
 281   fi
 282
 283   if test "$enable_mpls_kernel" = try ; then
 284     enable_mpls_kernel="$bird_cv_mpls_kernel"
 285   fi
 286 fi
 287
 288 all_protocols="$proto_bfd babel bgp mrt ospf perf pipe radv rip $proto_rpki static"
 289
 290 all_protocols=`echo $all_protocols | sed 's/ /,/g'`
 291
 292 if test "$with_protocols" = all ; then
 293   with_protocols="$all_protocols"
 294 fi
 295
 296 AH_TEMPLATE([CONFIG_BABEL],     [Babel protocol])
 297 AH_TEMPLATE([CONFIG_BFD],       [BFD protocol])
 298 AH_TEMPLATE([CONFIG_BGP],       [BGP protocol])
 299 AH_TEMPLATE([CONFIG_MRT],       [MRT protocol])
 300 AH_TEMPLATE([CONFIG_OSPF],      [OSPF protocol])
 301 AH_TEMPLATE([CONFIG_PIPE],      [Pipe protocol])
 302 AH_TEMPLATE([CONFIG_RADV],      [RAdv protocol])
 303 AH_TEMPLATE([CONFIG_RIP],       [RIP protocol])
 304 AH_TEMPLATE([CONFIG_RPKI],      [RPKI protocol])
 305 AH_TEMPLATE([CONFIG_STATIC],    [Static protocol])
 306
 307 AC_MSG_CHECKING([protocols])
 308 protocols=`echo "$with_protocols" | sed 's/,/ /g'`
 309 if test "$protocols" = no ; then protocols= ; fi
 310 for a in $protocols ; do
 311   if ! test -f $srcdir/proto/$a/Makefile ; then
 312     AC_MSG_RESULT([failed])
 313     AC_MSG_ERROR([Requested protocol $a not found])
 314   fi
 315   AC_DEFINE_UNQUOTED([CONFIG_`echo $a | tr 'a-z' 'A-Z'`])
 316 done
 317 AC_MSG_RESULT([ok])
 318 AC_SUBST([protocols])
 319
 320 case $sysdesc in
 321   */linux*)
 322     AC_CHECK_HEADER([linux/rtnetlink.h],
 323       [],
 324       [AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],
 325       [
 326         dnl Some older versions of Linux kernel headers require these includes
 327         #include <asm/types.h>
 328         #include <sys/socket.h>
 329       ]
 330     )
 331     ;;
 332 esac
 333
 334 AC_CHECK_HEADERS_ONCE([alloca.h syslog.h])
 335 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [], [#include <sys/socket.h>])
 336
 337 AC_C_BIGENDIAN(
 338   [AC_DEFINE([CPU_BIG_ENDIAN], [1], [Define to 1 if cpu is big endian])],
 339   [AC_DEFINE([CPU_LITTLE_ENDIAN], [1], [Define to 1 if cpu is little endian])],
 340   [AC_MSG_ERROR([Cannot determine CPU endianity.])]
 341 )
 342
 343 BIRD_CHECK_ANDROID_GLOB
 344 if test "$bird_cv_lib_glob" = no ; then
 345   AC_MSG_ERROR([glob.h not found.])
 346 elif test "$bird_cv_lib_glob" != yes ; then
 347   LIBS="$LIBS $bird_cv_lib_glob"
 348 fi
 349
 350 BIRD_CHECK_ANDROID_LOG
 351 if test "$bird_cv_lib_log" = no ; then
 352   AC_MSG_ERROR([don't know how to link syslog.])
 353 elif test "$bird_cv_lib_log" != yes ; then
 354   LIBS="$LIBS $bird_cv_lib_log"
 355 fi
 356
 357 if test "$enable_debug" = yes ; then
 358   AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
 359   LDFLAGS="$LDFLAGS -rdynamic"
 360   CFLAGS="$CFLAGS -O0 -ggdb -g3"
 361
 362   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_dwarf4], [-gdwarf-4], [])
 363   BIRD_ADD_GCC_OPTION([bird_cv_c_option_dwarf4], [-gdwarf-4])
 364
 365   AC_CHECK_HEADER([execinfo.h],
 366     [
 367       AC_DEFINE([HAVE_EXECINFO_H], [1], [Define to 1 if you have the <execinfo.h> header file.])
 368       AC_SEARCH_LIBS([backtrace], [execinfo],
 369         [],
 370         [AC_MSG_ERROR([Function backtrace not available.])]
 371       )
 372     ]
 373   )
 374
 375   if test "$enable_memcheck" = yes ; then
 376     AC_CHECK_LIB([dmalloc], [dmalloc_debug])
 377     if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
 378       AC_CHECK_LIB([efence], [malloc])
 379     fi
 380   fi
 381 else
 382   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_implicit_fallthrough], [-Wno-implicit-fallthrough])
 383   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_implicit_fallthrough], [-Wno-implicit-fallthrough])
 384 fi
 385
 386 CLIENT=birdcl
 387 CLIENT_LIBS=
 388 if test "$enable_client" = yes ; then
 389   CLIENT="$CLIENT birdc"
 390   BASE_LIBS="$LIBS"
 391   LIBS=""
 392
 393   AC_CHECK_HEADERS([curses.h],
 394     [],
 395     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 396     [AC_INCLUDES_DEFAULT]
 397   )
 398
 399   AC_SEARCH_LIBS([tgetent], [tinfo tinfow ncurses curses termcap],
 400     [TINFO_LIBS="$LIBS"; LIBS=""],
 401     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 402   )
 403
 404   AC_CHECK_HEADERS([readline/readline.h readline/history.h],
 405     [],
 406     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 407     [AC_INCLUDES_DEFAULT]
 408   )
 409
 410   AC_SEARCH_LIBS([rl_callback_read_char], [readline],
 411     [READLINE_LIBS="$LIBS"; LIBS=""],
 412     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 413     [$TINFO_LIBS]
 414   )
 415
 416   AC_CHECK_LIB([readline], [rl_crlf],
 417     [AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()])],
 418     [],
 419     [$TINFO_LIBS]
 420   )
 421
 422   AC_CHECK_LIB([readline], [rl_ding],
 423     [AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()])],
 424     [],
 425     [$TINFO_LIBS]
 426   )
 427
 428   LIBS="$BASE_LIBS"
 429   CLIENT_LIBS="$READLINE_LIBS $TINFO_LIBS"
 430 fi
 431 AC_SUBST([CLIENT])
 432 AC_SUBST([CLIENT_LIBS])
 433
 434 mkdir -p $objdir/sysdep
 435 AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in])
 436 AC_CONFIG_FILES([Makefile:Makefile.in])
 437 AC_OUTPUT
 438
 439 AC_MSG_RESULT()
 440 AC_MSG_RESULT([BIRD was configured with the following options:])
 441 AC_MSG_RESULT([        Source directory:        $srcdir])
 442 AC_MSG_RESULT([        Object directory:        $objdir])
 443 AC_MSG_RESULT([        Iproute2 directory:      $iproutedir])
 444 AC_MSG_RESULT([        System configuration:    $sysdesc])
 445 AC_MSG_RESULT([        Debugging:               $enable_debug])
 446 AC_MSG_RESULT([        POSIX threads:           $enable_pthreads])
 447 AC_MSG_RESULT([        Routing protocols:       $protocols])
 448 AC_MSG_RESULT([        Kernel MPLS support:     $enable_mpls_kernel])
 449 AC_MSG_RESULT([        Client:                  $enable_client])
 450
 451 rm -f $objdir/.*-stamp