configure.ac

   1 dnl ** This is a configure script template for BIRD
   2 dnl ** Process it with autoconf to get ./configure
   3 dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz>
   4
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([conf/confbase.Y])
   7 AC_CONFIG_AUX_DIR([tools])
   8
   9 AC_ARG_ENABLE([client],
  10   [AS_HELP_STRING([--enable-client], [enable building of BIRD client @<:@yes@:>@])],
  11   [],
  12   [enable_client=yes]
  13 )
  14
  15 AC_ARG_ENABLE([debug],
  16   [AS_HELP_STRING([--enable-debug], [enable internal debugging routines @<:@no@:>@])],
  17   [],
  18   [enable_debug=no]
  19 )
  20
  21 AC_ARG_ENABLE([debug-generated],
  22   [AS_HELP_STRING([--enable-debug-generated], [enable this to abstain from generating #line @<:@no@:>@])],
  23   [],
  24   [enable_debug_generated=no]
  25 )
  26
  27 AC_ARG_ENABLE([memcheck],
  28   [AS_HELP_STRING([--enable-memcheck], [check memory allocations when debugging @<:@yes@:>@])],
  29   [],
  30   [enable_memcheck=yes]
  31 )
  32
  33 AC_ARG_ENABLE([pthreads],
  34   [AS_HELP_STRING([--enable-pthreads], [enable POSIX threads support @<:@try@:>@])],
  35   [],
  36   [enable_pthreads=try]
  37 )
  38
  39 AC_ARG_ENABLE([libssh],
  40   [AS_HELP_STRING([--enable-libssh], [enable LibSSH support together with RPKI @<:@try@:>@])],
  41   [],
  42   [enable_libssh=try]
  43 )
  44
  45 AC_ARG_ENABLE([mpls-kernel],
  46   [AS_HELP_STRING([--enable-mpls-kernel], [enable MPLS support in kernel protocol @<:@try@:>@])],
  47   [],
  48   [enable_mpls_kernel=try]
  49 )
  50
  51 AC_ARG_WITH([protocols],
  52   [AS_HELP_STRING([--with-protocols=LIST], [include specified routing protocols @<:@all@:>@])],
  53   [],
  54   [with_protocols="all"]
  55 )
  56
  57 AC_ARG_WITH([sysconfig],
  58   [AS_HELP_STRING([--with-sysconfig=FILE], [use specified BIRD system configuration file])]
  59 )
  60
  61 AC_ARG_WITH([runtimedir],
  62   [AS_HELP_STRING([--with-runtimedir=PATH], [run-state data, obsolete variant of --runstatedir])],
  63   [runstatedir="$with_runtimedir"]
  64 )
  65
  66 AC_ARG_WITH([iproutedir],
  67   [AS_HELP_STRING([--with-iproutedir=PATH], [path to iproute2 config files @<:@/etc/iproute2@:>@])],
  68   [given_iproutedir="yes"]
  69 )
  70
  71 AC_ARG_VAR([FLEX], [location of the Flex program])
  72 AC_ARG_VAR([BISON], [location of the Bison program])
  73 AC_ARG_VAR([M4], [location of the M4 program])
  74
  75
  76 if test "$srcdir" = . ; then
  77   # Building in current directory => create obj directory holding all objects
  78   objdir=obj
  79 else
  80   # Building in separate directory
  81   objdir=.
  82 fi
  83
  84 exedir=.
  85
  86 AC_SUBST([objdir])
  87 AC_SUBST([exedir])
  88 AC_SUBST([srcdir])
  89
  90 # Workaround for older Autoconfs that do not define runstatedir
  91 AS_IF([test -z "${runstatedir}"], [runstatedir='${localstatedir}/run'])
  92 AC_SUBST([runstatedir])
  93
  94 CONFIG_FILE="\$(sysconfdir)/bird.conf"
  95 AC_SUBST([CONFIG_FILE])
  96
  97 CONTROL_SOCKET="\$(runstatedir)/bird.ctl"
  98 AC_SUBST([CONTROL_SOCKET])
  99
 100 AC_SEARCH_LIBS([clock_gettime], [rt posix4],
 101   [],
 102   [AC_MSG_ERROR([Function clock_gettime not available.])]
 103 )
 104
 105 AC_CANONICAL_HOST
 106
 107 # Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC
 108 if test "$ac_test_CFLAGS" != set ; then
 109   bird_cflags_default=yes
 110 fi
 111
 112 AC_PROG_CC
 113 AC_PROG_CC_C99
 114 if test -z "$GCC" ; then
 115   AC_MSG_ERROR([This program requires the GNU C Compiler.])
 116 fi
 117
 118 if test "$enable_pthreads" != no ; then
 119   BIRD_CHECK_PTHREADS
 120
 121   if test "$bird_cv_lib_pthreads" = yes ; then
 122     AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
 123     CFLAGS="$CFLAGS -pthread"
 124     LDFLAGS="$LDFLAGS -pthread"
 125     proto_bfd=bfd
 126   elif test "$enable_pthreads" = yes ; then
 127     AC_MSG_ERROR([POSIX threads not available.])
 128   fi
 129
 130   if test "$enable_pthreads" = try ; then
 131     enable_pthreads="$bird_cv_lib_pthreads"
 132   fi
 133 fi
 134
 135 if test "$bird_cflags_default" = yes ; then
 136   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign], [-Wall])
 137   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers], [-Wall -Wextra])
 138   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
 139   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 140   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_flto], [-flto])
 141
 142   CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wno-parentheses"
 143   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign])
 144   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers])
 145   BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
 146   BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 147   BIRD_ADD_GCC_OPTION([bird_cv_c_option_flto], [-flto])
 148 fi
 149 AC_MSG_CHECKING([CFLAGS])
 150 AC_MSG_RESULT([$CFLAGS])
 151
 152
 153 AC_PROG_CPP
 154 AC_PROG_INSTALL
 155 AC_PROG_RANLIB
 156 AC_CHECK_PROG([FLEX], [flex], [flex])
 157 AC_CHECK_PROG([BISON], [bison], [bison])
 158 AC_CHECK_PROGS([M4], [gm4 m4])
 159
 160 test -z "$FLEX"  && AC_MSG_ERROR([Flex is missing.])
 161 test -z "$BISON" && AC_MSG_ERROR([Bison is missing.])
 162 test -z "$M4"    && AC_MSG_ERROR([M4 is missing.])
 163
 164 AC_MSG_CHECKING([bison version])
 165 BIRD_CHECK_BISON_VERSION(BISON_VERSION)
 166 AC_MSG_RESULT([$BISON_VERSION])
 167 if test "$bird_bison_synclines" = yes && test "$enable_debug_generated" = no; then
 168   M4FLAGS="$M4FLAGS -s"
 169 fi
 170
 171 if test "$bird_bison_enhanced_error" = yes; then
 172   BISONFLAGS="$BISONFLAGS -Dparse.lac=full -Dparse.error=verbose"
 173 fi
 174
 175 AC_SUBST([M4FLAGS])
 176 AC_SUBST([BISONFLAGS])
 177
 178 BIRD_CHECK_PROG_FLAVOR_GNU([$M4],
 179   [],
 180   [AC_MSG_ERROR([Provided M4 is not GNU M4.])]
 181 )
 182
 183 if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then
 184   if test -f $with_sysconfig ; then
 185     sysdesc=$with_sysconfig
 186   else
 187     sysdesc=$srcdir/sysdep/cf/$with_sysconfig
 188     if ! test -f $sysdesc ; then
 189       sysdesc=$sysdesc.h
 190     fi
 191   fi
 192 elif test -f sysconfig.h ; then
 193   sysdesc=sysconfig
 194 else
 195   case "$host_os" in
 196     linux*)
 197       sysdesc=linux
 198       default_iproutedir="/etc/iproute2"
 199       ;;
 200     freebsd*)
 201       sysdesc=bsd
 202       CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 203       LDFLAGS="$LDFLAGS -L/usr/local/lib"
 204       ;;
 205     kfreebsd*)
 206       sysdesc=bsd
 207       ;;
 208     netbsd*)
 209       sysdesc=bsd
 210       CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
 211       LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
 212       ;;
 213     openbsd*)
 214       sysdesc=bsd
 215       ;;
 216     dragonfly*)
 217       sysdesc=bsd
 218       ;;
 219     *)
 220       AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
 221       ;;
 222     esac
 223     sysdesc=$srcdir/sysdep/cf/$sysdesc.h
 224 fi
 225 AC_MSG_CHECKING([which OS configuration should we use])
 226 AC_MSG_RESULT([$sysdesc])
 227 if ! test -f $sysdesc ; then
 228   AC_MSG_ERROR([The system configuration file is missing.])
 229 fi
 230 sysname=`echo $sysdesc | sed 's/\.h$//'`
 231 AC_DEFINE_UNQUOTED([SYSCONF_INCLUDE], ["$sysdesc"], [Which sysdep header to include])
 232
 233 AC_MSG_CHECKING([system-dependent directories])
 234 sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '`"
 235 AC_MSG_RESULT([$sysdep_dirs])
 236 AC_SUBST([sysdep_dirs])
 237
 238 if test "$with_iproutedir" = no ; then with_iproutedir= ; fi
 239
 240 if test -n "$given_iproutedir"
 241 then iproutedir=$with_iproutedir
 242 else iproutedir=$default_iproutedir
 243 fi
 244
 245 AC_SUBST([iproutedir])
 246
 247 DAEMON_LIBS=
 248 AC_SUBST(DAEMON_LIBS)
 249
 250 if test "$enable_libssh" != no ; then
 251   AC_CHECK_HEADER([libssh/libssh.h], [true], [fail=yes], [ ])
 252   AC_CHECK_LIB([ssh], [ssh_connect], [true], [fail=yes])
 253
 254   if test "$fail" != yes ; then
 255     AC_DEFINE([HAVE_LIBSSH], [1], [Define to 1 if you have the `ssh' library (-lssh).])
 256     DAEMON_LIBS="-lssh $DAEMON_LIBS"
 257     proto_rpki=rpki
 258     enable_libssh=yes
 259   else
 260     if test "$enable_libssh" = yes ; then
 261       AC_MSG_ERROR([LibSSH not available.])
 262     else
 263       enable_libssh=no
 264     fi
 265   fi
 266 fi
 267
 268 if test "$enable_mpls_kernel" != no ; then
 269   BIRD_CHECK_MPLS_KERNEL
 270
 271   if test "$bird_cv_mpls_kernel" = yes ; then
 272     AC_DEFINE([HAVE_MPLS_KERNEL], [1], [Define to 1 if kernel is MPLS capable])
 273   elif test "$enable_mpls_kernel" = yes ; then
 274     AC_MSG_ERROR([Kernel MPLS support not found.])
 275   fi
 276
 277   if test "$enable_mpls_kernel" = try ; then
 278     enable_mpls_kernel="$bird_cv_mpls_kernel"
 279   fi
 280 fi
 281
 282 all_protocols="$proto_bfd babel bgp mrt ospf perf pipe radv rip $proto_rpki static"
 283
 284 all_protocols=`echo $all_protocols | sed 's/ /,/g'`
 285
 286 if test "$with_protocols" = all ; then
 287   with_protocols="$all_protocols"
 288 fi
 289
 290 AH_TEMPLATE([CONFIG_BABEL],     [Babel protocol])
 291 AH_TEMPLATE([CONFIG_BFD],       [BFD protocol])
 292 AH_TEMPLATE([CONFIG_BGP],       [BGP protocol])
 293 AH_TEMPLATE([CONFIG_MRT],       [MRT protocol])
 294 AH_TEMPLATE([CONFIG_OSPF],      [OSPF protocol])
 295 AH_TEMPLATE([CONFIG_PIPE],      [Pipe protocol])
 296 AH_TEMPLATE([CONFIG_RADV],      [RAdv protocol])
 297 AH_TEMPLATE([CONFIG_RIP],       [RIP protocol])
 298 AH_TEMPLATE([CONFIG_RPKI],      [RPKI protocol])
 299 AH_TEMPLATE([CONFIG_STATIC],    [Static protocol])
 300
 301 AC_MSG_CHECKING([protocols])
 302 protocols=`echo "$with_protocols" | sed 's/,/ /g'`
 303 if test "$protocols" = no ; then protocols= ; fi
 304 for a in $protocols ; do
 305   if ! test -f $srcdir/proto/$a/Makefile ; then
 306     AC_MSG_RESULT([failed])
 307     AC_MSG_ERROR([Requested protocol $a not found])
 308   fi
 309   AC_DEFINE_UNQUOTED([CONFIG_`echo $a | tr 'a-z' 'A-Z'`])
 310 done
 311 AC_MSG_RESULT([ok])
 312 AC_SUBST([protocols])
 313
 314 case $sysdesc in
 315   */linux*)
 316     AC_CHECK_HEADER([linux/rtnetlink.h],
 317       [],
 318       [AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],
 319       [
 320         dnl Some older versions of Linux kernel headers require these includes
 321         #include <asm/types.h>
 322         #include <sys/socket.h>
 323       ]
 324     )
 325     ;;
 326 esac
 327
 328 AC_CHECK_HEADERS_ONCE([alloca.h syslog.h])
 329 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [], [#include <sys/socket.h>])
 330
 331 AC_C_BIGENDIAN(
 332   [AC_DEFINE([CPU_BIG_ENDIAN], [1], [Define to 1 if cpu is big endian])],
 333   [AC_DEFINE([CPU_LITTLE_ENDIAN], [1], [Define to 1 if cpu is little endian])],
 334   [AC_MSG_ERROR([Cannot determine CPU endianity.])]
 335 )
 336
 337 BIRD_CHECK_ANDROID_GLOB
 338 if test "$bird_cv_lib_glob" = no ; then
 339   AC_MSG_ERROR([glob.h not found.])
 340 elif test "$bird_cv_lib_glob" != yes ; then
 341   LIBS="$LIBS $bird_cv_lib_glob"
 342 fi
 343
 344 BIRD_CHECK_ANDROID_LOG
 345 if test "$bird_cv_lib_log" = no ; then
 346   AC_MSG_ERROR([don't know how to link syslog.])
 347 elif test "$bird_cv_lib_log" != yes ; then
 348   LIBS="$LIBS $bird_cv_lib_log"
 349 fi
 350
 351 if test "$enable_debug" = yes ; then
 352   AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
 353   LDFLAGS="$LDFLAGS -rdynamic"
 354   CFLAGS="$CFLAGS -O0 -ggdb -g3"
 355
 356   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_dwarf4], [-gdwarf-4], [])
 357   BIRD_ADD_GCC_OPTION([bird_cv_c_option_dwarf4], [-gdwarf-4])
 358
 359   AC_CHECK_HEADER([execinfo.h],
 360     [
 361       AC_DEFINE([HAVE_EXECINFO_H], [1], [Define to 1 if you have the <execinfo.h> header file.])
 362       AC_SEARCH_LIBS([backtrace], [execinfo],
 363         [],
 364         [AC_MSG_ERROR([Function backtrace not available.])]
 365       )
 366     ]
 367   )
 368
 369   if test "$enable_memcheck" = yes ; then
 370     AC_CHECK_LIB([dmalloc], [dmalloc_debug])
 371     if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
 372       AC_CHECK_LIB([efence], [malloc])
 373     fi
 374   fi
 375 else
 376   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_implicit_fallthrough], [-Wno-implicit-fallthrough])
 377   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_implicit_fallthrough], [-Wno-implicit-fallthrough])
 378 fi
 379
 380 CLIENT=birdcl
 381 CLIENT_LIBS=
 382 if test "$enable_client" = yes ; then
 383   CLIENT="$CLIENT birdc"
 384   BASE_LIBS="$LIBS"
 385   LIBS=""
 386
 387   AC_CHECK_HEADERS([curses.h],
 388     [],
 389     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 390     [AC_INCLUDES_DEFAULT]
 391   )
 392
 393   AC_SEARCH_LIBS([tgetent], [tinfo tinfow ncurses curses termcap],
 394     [TINFO_LIBS="$LIBS"; LIBS=""],
 395     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 396   )
 397
 398   AC_CHECK_HEADERS([readline/readline.h readline/history.h],
 399     [],
 400     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 401     [AC_INCLUDES_DEFAULT]
 402   )
 403
 404   AC_SEARCH_LIBS([rl_callback_read_char], [readline],
 405     [READLINE_LIBS="$LIBS"; LIBS=""],
 406     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 407     [$TINFO_LIBS]
 408   )
 409
 410   AC_CHECK_LIB([readline], [rl_crlf],
 411     [AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()])],
 412     [],
 413     [$TINFO_LIBS]
 414   )
 415
 416   AC_CHECK_LIB([readline], [rl_ding],
 417     [AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()])],
 418     [],
 419     [$TINFO_LIBS]
 420   )
 421
 422   LIBS="$BASE_LIBS"
 423   CLIENT_LIBS="$READLINE_LIBS $TINFO_LIBS"
 424 fi
 425 AC_SUBST([CLIENT])
 426 AC_SUBST([CLIENT_LIBS])
 427
 428 mkdir -p $objdir/sysdep
 429 AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in])
 430 AC_CONFIG_FILES([Makefile:Makefile.in])
 431 AC_OUTPUT
 432
 433 AC_MSG_RESULT()
 434 AC_MSG_RESULT([BIRD was configured with the following options:])
 435 AC_MSG_RESULT([        Source directory:        $srcdir])
 436 AC_MSG_RESULT([        Object directory:        $objdir])
 437 AC_MSG_RESULT([        Iproute2 directory:      $iproutedir])
 438 AC_MSG_RESULT([        System configuration:    $sysdesc])
 439 AC_MSG_RESULT([        Debugging:               $enable_debug])
 440 AC_MSG_RESULT([        POSIX threads:           $enable_pthreads])
 441 AC_MSG_RESULT([        Routing protocols:       $protocols])
 442 AC_MSG_RESULT([        Kernel MPLS support:     $enable_mpls_kernel])
 443 AC_MSG_RESULT([        Client:                  $enable_client])
 444
 445 rm -f $objdir/.*-stamp