nest/config.Y

   1 /*
   2  *      BIRD -- Core Configuration
   3  *
   4  *      (c) 1998--2000 Martin Mares <mj@ucw.cz>
   5  *      (c) 2004       Ondrej Filip <feela@network.cz>
   6  *
   7  *      Can be freely distributed and used under the terms of the GNU GPL.
   8  */
   9
  10 CF_HDR
  11
  12 #include "nest/rt-dev.h"
  13 #include "nest/password.h"
  14 #include "nest/cmds.h"
  15 #include "lib/lists.h"
  16 #include "lib/mac.h"
  17
  18 CF_DEFINES
  19
  20 static struct proto_config *this_proto;
  21 static struct channel_config *this_channel;
  22 static struct iface_patt *this_ipatt;
  23 static struct iface_patt_node *this_ipn;
  24 /* static struct roa_table_config *this_roa_table; */
  25 static list *this_p_list;
  26 static struct password_item *this_p_item;
  27 static int password_id;
  28
  29 static void
  30 iface_patt_check(void)
  31 {
  32   struct iface_patt_node *pn;
  33
  34   WALK_LIST(pn, this_ipatt->ipn_list)
  35     if (!pn->pattern || pn->prefix.type)
  36       cf_error("Interface name/mask expected, not IP prefix");
  37 }
  38
  39
  40 static inline void
  41 reset_passwords(void)
  42 {
  43   this_p_list = NULL;
  44 }
  45
  46 static inline list *
  47 get_passwords(void)
  48 {
  49   list *rv = this_p_list;
  50   this_p_list = NULL;
  51   return rv;
  52 }
  53
  54 static void
  55 proto_postconfig(void)
  56 {
  57   CALL(this_proto->protocol->postconfig, this_proto);
  58   this_channel = NULL;
  59   this_proto = NULL;
  60 }
  61
  62
  63 #define DIRECT_CFG ((struct rt_dev_config *) this_proto)
  64
  65 CF_DECLS
  66
  67 CF_KEYWORDS(ROUTER, ID, PROTOCOL, TEMPLATE, PREFERENCE, DISABLED, DEBUG, ALL, OFF, DIRECT)
  68 CF_KEYWORDS(INTERFACE, IMPORT, EXPORT, FILTER, NONE, VRF, TABLE, STATES, ROUTES, FILTERS)
  69 CF_KEYWORDS(IPV4, IPV6, VPN4, VPN6, ROA4, ROA6, FLOW4, FLOW6, SADR, MPLS)
  70 CF_KEYWORDS(RECEIVE, LIMIT, ACTION, WARN, BLOCK, RESTART, DISABLE, KEEP, FILTERED)
  71 CF_KEYWORDS(PASSWORD, FROM, PASSIVE, TO, ID, EVENTS, PACKETS, PROTOCOLS, INTERFACES)
  72 CF_KEYWORDS(ALGORITHM, KEYED, HMAC, MD5, SHA1, SHA256, SHA384, SHA512)
  73 CF_KEYWORDS(PRIMARY, STATS, COUNT, BY, FOR, COMMANDS, PREEXPORT, NOEXPORT, GENERATE)
  74 CF_KEYWORDS(BGP, PASSWORDS, DESCRIPTION, SORTED)
  75 CF_KEYWORDS(RELOAD, IN, OUT, MRTDUMP, MESSAGES, RESTRICT, MEMORY, IGP_METRIC, CLASS, DSCP)
  76 CF_KEYWORDS(TIMEFORMAT, ISO, SHORT, LONG, ROUTE, PROTOCOL, BASE, LOG, S, MS, US)
  77 CF_KEYWORDS(GRACEFUL, RESTART, WAIT, MAX, FLUSH, AS)
  78
  79 /* For r_args_channel */
  80 CF_KEYWORDS(IPV4, IPV4_MC, IPV4_MPLS, IPV6, IPV6_MC, IPV6_MPLS, IPV6_SADR, VPN4, VPN4_MC, VPN4_MPLS, VPN6, VPN6_MC, VPN6_MPLS, ROA4, ROA6, FLOW4, FLOW6, MPLS, PRI, SEC)
  81
  82 CF_ENUM(T_ENUM_RTS, RTS_, DUMMY, STATIC, INHERIT, DEVICE, STATIC_DEVICE, REDIRECT,
  83         RIP, OSPF, OSPF_IA, OSPF_EXT1, OSPF_EXT2, BGP, PIPE, BABEL)
  84 CF_ENUM(T_ENUM_SCOPE, SCOPE_, HOST, LINK, SITE, ORGANIZATION, UNIVERSE, UNDEFINED)
  85 CF_ENUM(T_ENUM_RTD, RTD_, UNICAST, BLACKHOLE, UNREACHABLE, PROHIBIT)
  86 CF_ENUM(T_ENUM_ROA, ROA_, UNKNOWN, VALID, INVALID)
  87
  88 %type <i32> idval
  89 %type <f> imexport
  90 %type <r> rtable
  91 %type <s> optproto sym_proto_or_template
  92 %type <ra> r_args
  93 %type <sd> sym_args
  94 %type <i> proto_start echo_mask echo_size debug_mask debug_list debug_flag mrtdump_mask mrtdump_list mrtdump_flag export_mode limit_action net_type table_sorted tos password_algorithm
  95 %type <ps> proto_patt proto_patt2
  96 %type <cc> channel_start proto_channel
  97 %type <cl> limit_spec
  98 %type <net> r_args_for_val
  99 %type <net_ptr> r_args_for
 100 %type <t> r_args_channel
 101
 102 CF_GRAMMAR
 103
 104 /* Setting of router ID */
 105
 106 conf: rtrid ;
 107
 108 rtrid:
 109    ROUTER ID idval ';' { new_config->router_id = $3; }
 110  | ROUTER ID FROM iface_patt ';' { new_config->router_id_from = this_ipatt; }
 111  ;
 112
 113 idval:
 114    NUM { $$ = $1; }
 115  | '(' term ')' { $$ = f_eval_int(f_postfixify($2)); }
 116  | IP4 { $$ = ip4_to_u32($1); }
 117  | CF_SYM_CONSTANT {
 118      if ($1->class == (SYM_CONSTANT | T_INT) || $1->class == (SYM_CONSTANT | T_QUAD))
 119        $$ = SYM_VAL($1).i;
 120      else if (($1->class == (SYM_CONSTANT | T_IP)) && ipa_is_ip4(SYM_VAL($1).ip))
 121        $$ = ipa_to_u32(SYM_VAL($1).ip);
 122      else
 123        cf_error("Number or IPv4 address constant expected");
 124    }
 125  ;
 126
 127 conf: gr_opts ;
 128
 129 gr_opts: GRACEFUL RESTART WAIT expr ';' { new_config->gr_wait = $4; } ;
 130
 131
 132 /* Network types (for tables, channels) */
 133
 134 net_type:
 135    IPV4 { $$ = NET_IP4; }
 136  | IPV6 { $$ = NET_IP6; }
 137  | IPV6 SADR { $$ = NET_IP6_SADR; }
 138  | VPN4 { $$ = NET_VPN4; }
 139  | VPN6 { $$ = NET_VPN6; }
 140  | ROA4 { $$ = NET_ROA4; }
 141  | ROA6 { $$ = NET_ROA6; }
 142  | FLOW4{ $$ = NET_FLOW4; }
 143  | FLOW6{ $$ = NET_FLOW6; }
 144  | MPLS { $$ = NET_MPLS; }
 145  ;
 146
 147 CF_ENUM(T_ENUM_NETTYPE, NET_, IP4, IP6, VPN4, VPN6, ROA4, ROA6, FLOW4, FLOW6, IP6_SADR)
 148
 149
 150 /* Creation of routing tables */
 151
 152 conf: table ;
 153
 154 table_sorted:
 155           { $$ = 0; }
 156  | SORTED { $$ = 1; }
 157  ;
 158
 159 table: net_type TABLE CF_SYM_VOID table_sorted {
 160    struct rtable_config *cf;
 161    cf = rt_new_table($3, $1);
 162    cf->sorted = $4;
 163    }
 164  ;
 165
 166
 167 /* Definition of protocols */
 168
 169 conf: proto { proto_postconfig(); } ;
 170
 171 proto_start:
 172    PROTOCOL { $$ = SYM_PROTO; }
 173  | TEMPLATE { $$ = SYM_TEMPLATE; }
 174  ;
 175
 176 sym_proto_or_template: CF_SYM_PROTO | CF_SYM_TEMPLATE ;
 177
 178 proto_name:
 179    /* EMPTY */ {
 180      struct symbol *s = cf_default_name(this_proto->protocol->template, &this_proto->protocol->name_counter);
 181      s->class = this_proto->class;
 182      s->proto = this_proto;
 183      this_proto->name = s->name;
 184      }
 185  | CF_SYM_VOID {
 186      cf_define_symbol($1, this_proto->class, proto, this_proto);
 187      this_proto->name = $1->name;
 188    }
 189  | FROM sym_proto_or_template {
 190      struct symbol *s = cf_default_name(this_proto->protocol->template, &this_proto->protocol->name_counter);
 191      s->class = this_proto->class;
 192      s->proto = this_proto;
 193      this_proto->name = s->name;
 194
 195      if (($2->class != SYM_TEMPLATE) && ($2->class != SYM_PROTO)) cf_error("Template or protocol name expected");
 196      proto_copy_config(this_proto, $2->proto);
 197    }
 198  | CF_SYM_VOID FROM sym_proto_or_template {
 199      cf_define_symbol($1, this_proto->class, proto, this_proto);
 200      this_proto->name = $1->name;
 201
 202      if (($3->class != SYM_TEMPLATE) && ($3->class != SYM_PROTO)) cf_error("Template or protocol name expected");
 203      proto_copy_config(this_proto, $3->proto);
 204    }
 205  ;
 206
 207 proto_item:
 208    /* EMPTY */
 209  | DISABLED bool { this_proto->disabled = $2; }
 210  | DEBUG debug_mask { this_proto->debug = $2; }
 211  | MRTDUMP mrtdump_mask { this_proto->mrtdump = $2; }
 212  | ROUTER ID idval { this_proto->router_id = $3; }
 213  | DESCRIPTION text { this_proto->dsc = $2; }
 214  | VRF text { this_proto->vrf = if_get_by_name($2); }
 215  ;
 216
 217
 218 channel_start: net_type
 219 {
 220   $$ = this_channel = channel_config_get(NULL, net_label[$1], $1, this_proto);
 221 };
 222
 223 channel_item:
 224    TABLE rtable {
 225      if (this_channel->net_type && ($2->addr_type != this_channel->net_type))
 226        cf_error("Incompatible table type");
 227      this_channel->table = $2;
 228    }
 229  | IMPORT imexport { this_channel->in_filter = $2; }
 230  | EXPORT imexport { this_channel->out_filter = $2; }
 231  | RECEIVE LIMIT limit_spec { this_channel->rx_limit = $3; }
 232  | IMPORT LIMIT limit_spec { this_channel->in_limit = $3; }
 233  | EXPORT LIMIT limit_spec { this_channel->out_limit = $3; }
 234  | PREFERENCE expr { this_channel->preference = $2; check_u16($2); }
 235  | IMPORT KEEP FILTERED bool { this_channel->in_keep_filtered = $4; }
 236  ;
 237
 238 channel_opts:
 239    /* empty */
 240  | channel_opts channel_item ';'
 241  ;
 242
 243 channel_opt_list:
 244    /* empty */
 245  | '{' channel_opts '}'
 246  ;
 247
 248 channel_end:
 249 {
 250   if (!this_channel->table)
 251     cf_error("Routing table not specified");
 252
 253   this_channel = NULL;
 254 };
 255
 256 proto_channel: channel_start channel_opt_list channel_end;
 257
 258
 259 rtable: CF_SYM_TABLE { $$ = $1->table; } ;
 260
 261 imexport:
 262    FILTER filter { $$ = $2; }
 263  | where_filter
 264  | ALL { $$ = FILTER_ACCEPT; }
 265  | NONE { $$ = FILTER_REJECT; }
 266  ;
 267
 268 limit_action:
 269    /* default */ { $$ = PLA_DISABLE; }
 270  | ACTION WARN { $$ = PLA_WARN; }
 271  | ACTION BLOCK { $$ = PLA_BLOCK; }
 272  | ACTION RESTART { $$ = PLA_RESTART; }
 273  | ACTION DISABLE { $$ = PLA_DISABLE; }
 274  ;
 275
 276 limit_spec:
 277    expr limit_action { $$ = (struct channel_limit){ .limit = $1, $$.action = $2 }; }
 278  | OFF { $$ = (struct channel_limit){}; }
 279  ;
 280
 281
 282 conf: debug_default ;
 283
 284 debug_default:
 285    DEBUG PROTOCOLS debug_mask { new_config->proto_default_debug = $3; }
 286  | DEBUG COMMANDS expr { new_config->cli_debug = $3; }
 287  ;
 288
 289 /* MRTDUMP PROTOCOLS is in systep/unix/config.Y */
 290
 291 conf: timeformat_base ;
 292
 293 timeformat_which:
 294    ROUTE { $$ = &new_config->tf_route; }
 295  | PROTOCOL { $$ = &new_config->tf_proto; }
 296  | BASE { $$ = &new_config->tf_base; }
 297  | LOG { $$ = &new_config->tf_log; }
 298  ;
 299
 300 timeformat_spec:
 301    timeformat_which TEXT { *$1 = (struct timeformat){$2, NULL, 0}; }
 302  | timeformat_which TEXT expr TEXT { *$1 = (struct timeformat){$2, $4, (s64) $3 S_}; }
 303  | timeformat_which ISO SHORT    { *$1 = TM_ISO_SHORT_S; }
 304  | timeformat_which ISO SHORT MS { *$1 = TM_ISO_SHORT_MS; }
 305  | timeformat_which ISO SHORT US { *$1 = TM_ISO_SHORT_US; }
 306  | timeformat_which ISO LONG    { *$1 = TM_ISO_LONG_S; }
 307  | timeformat_which ISO LONG MS { *$1 = TM_ISO_LONG_MS; }
 308  | timeformat_which ISO LONG US { *$1 = TM_ISO_LONG_US; }
 309  ;
 310
 311 timeformat_base:
 312    TIMEFORMAT timeformat_spec ';'
 313  ;
 314
 315
 316 /* Interface patterns */
 317
 318 iface_patt_node_init:
 319    /* EMPTY */ {
 320      struct iface_patt_node *ipn = cfg_allocz(sizeof(struct iface_patt_node));
 321      add_tail(&this_ipatt->ipn_list, NODE ipn);
 322      this_ipn = ipn;
 323    }
 324  ;
 325
 326 iface_patt_node_body:
 327    TEXT { this_ipn->pattern = $1; /* this_ipn->prefix stays zero */ }
 328  | opttext net_or_ipa { this_ipn->pattern = $1; this_ipn->prefix = $2; }
 329  ;
 330
 331 iface_negate:
 332        { this_ipn->positive = 1; }
 333  | '-' { this_ipn->positive = 0; }
 334  ;
 335
 336 iface_patt_node:
 337    iface_patt_node_init iface_negate iface_patt_node_body
 338  ;
 339
 340
 341 iface_patt_list:
 342    iface_patt_node
 343  | iface_patt_list ',' iface_patt_node
 344  ;
 345
 346 /* For name/mask-only iface patterns */
 347 iface_patt_list_nopx: iface_patt_list { iface_patt_check(); }
 348
 349 iface_patt_init: {
 350    /* Generic this_ipatt init */
 351    this_ipatt = cfg_allocz(sizeof(struct iface_patt));
 352    init_list(&this_ipatt->ipn_list);
 353  }
 354  ;
 355
 356 iface_patt:
 357    iface_patt_init iface_patt_list
 358  ;
 359
 360 tos:
 361    CLASS expr { $$ = $2 & 0xfc;        if ($2 > 255) cf_error("TX class must be in range 0-255"); }
 362  | DSCP expr  { $$ = ($2 & 0x3f) << 2; if ($2 > 63)  cf_error("TX DSCP must be in range 0-63"); }
 363  ;
 364
 365 /* Direct device route protocol */
 366
 367 proto: dev_proto '}' ;
 368
 369 dev_proto_start: proto_start DIRECT {
 370      this_proto = proto_config_new(&proto_device, $1);
 371      init_list(&DIRECT_CFG->iface_list);
 372    }
 373  ;
 374
 375 dev_proto:
 376    dev_proto_start proto_name '{'
 377  | dev_proto proto_item ';'
 378  | dev_proto proto_channel ';'
 379  | dev_proto dev_iface_patt ';'
 380  | dev_proto CHECK LINK bool ';' { DIRECT_CFG->check_link = $4; }
 381  ;
 382
 383 dev_iface_init:
 384    /* EMPTY */ {
 385      this_ipatt = cfg_allocz(sizeof(struct iface_patt));
 386      add_tail(&DIRECT_CFG->iface_list, NODE this_ipatt);
 387      init_list(&this_ipatt->ipn_list);
 388    }
 389  ;
 390
 391 dev_iface_patt:
 392    INTERFACE dev_iface_init iface_patt_list
 393  ;
 394
 395 /* Debug flags */
 396
 397 debug_mask:
 398    ALL { $$ = ~0; }
 399  | OFF { $$ = 0; }
 400  | '{' debug_list '}' { $$ = $2; }
 401  ;
 402
 403 debug_list:
 404    debug_flag
 405  | debug_list ',' debug_flag { $$ = $1 | $3; }
 406  ;
 407
 408 debug_flag:
 409    STATES       { $$ = D_STATES; }
 410  | ROUTES       { $$ = D_ROUTES; }
 411  | FILTERS      { $$ = D_FILTERS; }
 412  | INTERFACES   { $$ = D_IFACES; }
 413  | EVENTS       { $$ = D_EVENTS; }
 414  | PACKETS      { $$ = D_PACKETS; }
 415  ;
 416
 417 /* MRTDump flags */
 418
 419 mrtdump_mask:
 420    ALL { $$ = ~0; }
 421  | OFF { $$ = 0; }
 422  | '{' mrtdump_list '}' { $$ = $2; }
 423  ;
 424
 425 mrtdump_list:
 426    mrtdump_flag
 427  | mrtdump_list ',' mrtdump_flag { $$ = $1 | $3; }
 428  ;
 429
 430 mrtdump_flag:
 431    STATES       { $$ = MD_STATES; }
 432  | MESSAGES     { $$ = MD_MESSAGES; }
 433  ;
 434
 435 /* Password lists */
 436
 437 password_list:
 438    PASSWORDS '{' password_items '}'
 439  | password_item
 440 ;
 441
 442 password_items:
 443     /* empty */
 444   | password_item ';' password_items
 445 ;
 446
 447 password_item:
 448     password_item_begin '{' password_item_params '}'
 449   | password_item_begin
 450 ;
 451
 452 password_item_begin:
 453    PASSWORD text {
 454      if (!this_p_list) {
 455         this_p_list = cfg_alloc(sizeof(list));
 456         init_list(this_p_list);
 457         password_id = 1;
 458      }
 459      this_p_item = cfg_alloc(sizeof (struct password_item));
 460      this_p_item->password = $2;
 461      this_p_item->length = strlen($2);
 462      this_p_item->genfrom = 0;
 463      this_p_item->gento = TIME_INFINITY;
 464      this_p_item->accfrom = 0;
 465      this_p_item->accto = TIME_INFINITY;
 466      this_p_item->id = password_id++;
 467      this_p_item->alg = ALG_UNDEFINED;
 468      add_tail(this_p_list, &this_p_item->n);
 469    }
 470 ;
 471
 472 password_item_params:
 473    /* empty */ { }
 474  | GENERATE FROM time ';' password_item_params { this_p_item->genfrom = $3; }
 475  | GENERATE TO time ';' password_item_params { this_p_item->gento = $3; }
 476  | ACCEPT FROM time ';' password_item_params { this_p_item->accfrom = $3; }
 477  | ACCEPT TO time ';' password_item_params { this_p_item->accto = $3; }
 478  | FROM time ';' password_item_params { this_p_item->genfrom = this_p_item->accfrom = $2; }
 479  | TO time ';' password_item_params { this_p_item->gento = this_p_item->accto = $2; }
 480  | ID expr ';' password_item_params { this_p_item->id = $2; if ($2 <= 0) cf_error("Password ID has to be greated than zero."); }
 481  | ALGORITHM password_algorithm ';' password_item_params { this_p_item->alg = $2; }
 482  ;
 483
 484 password_algorithm:
 485    KEYED MD5    { $$ = ALG_MD5; }
 486  | KEYED SHA1   { $$ = ALG_SHA1; }
 487  | KEYED SHA256 { $$ = ALG_SHA256; }
 488  | KEYED SHA384 { $$ = ALG_SHA384; }
 489  | KEYED SHA512 { $$ = ALG_SHA512; }
 490  | HMAC MD5     { $$ = ALG_HMAC_MD5; }
 491  | HMAC SHA1    { $$ = ALG_HMAC_SHA1; }
 492  | HMAC SHA256  { $$ = ALG_HMAC_SHA256; }
 493  | HMAC SHA384  { $$ = ALG_HMAC_SHA384; }
 494  | HMAC SHA512  { $$ = ALG_HMAC_SHA512; }
 495  ;
 496
 497 /* Core commands */
 498 CF_CLI_HELP(SHOW, ..., [[Show status information]])
 499
 500 CF_CLI(SHOW STATUS,,, [[Show router status]])
 501 { cmd_show_status(); } ;
 502
 503 CF_CLI(SHOW MEMORY,,, [[Show memory usage]])
 504 { cmd_show_memory(); } ;
 505
 506 CF_CLI(SHOW PROTOCOLS, proto_patt2, [<protocol> | \"<pattern>\"], [[Show routing protocols]])
 507 { proto_apply_cmd($3, proto_cmd_show, 0, 0); } ;
 508
 509 CF_CLI(SHOW PROTOCOLS ALL, proto_patt2, [<protocol> | \"<pattern>\"], [[Show routing protocol details]])
 510 { proto_apply_cmd($4, proto_cmd_show, 0, 1); } ;
 511
 512 optproto:
 513    CF_SYM_PROTO
 514  | /* empty */ { $$ = NULL; }
 515  ;
 516
 517 CF_CLI(SHOW INTERFACES,,, [[Show network interfaces]])
 518 { if_show(); } ;
 519
 520 CF_CLI(SHOW INTERFACES SUMMARY,,, [[Show summary of network interfaces]])
 521 { if_show_summary(); } ;
 522
 523 CF_CLI_HELP(SHOW ROUTE, ..., [[Show routing table]])
 524 CF_CLI(SHOW ROUTE, r_args, [[[<prefix>|for <prefix>|for <ip>] [table <t>] [filter <f>|where <cond>] [all] [primary] [filtered] [(export|preexport|noexport) <p>] [protocol <p>] [stats|count]]], [[Show routing table]])
 525 { rt_show($3); } ;
 526
 527 r_args:
 528    /* empty */ {
 529      $$ = cfg_allocz(sizeof(struct rt_show_data));
 530      init_list(&($$->tables));
 531      $$->filter = FILTER_ACCEPT;
 532      $$->running_on_config = new_config->fallback;
 533    }
 534  | r_args net_any {
 535      $$ = $1;
 536      if ($$->addr) cf_error("Only one prefix expected");
 537      $$->addr = $2;
 538    }
 539  | r_args FOR r_args_for {
 540      $$ = $1;
 541      if ($$->addr) cf_error("Only one prefix expected");
 542      $$->show_for = 1;
 543      $$->addr = $3;
 544    }
 545  | r_args TABLE CF_SYM_TABLE {
 546      $$ = $1;
 547      rt_show_add_table($$, $3->table->table);
 548      $$->tables_defined_by = RSD_TDB_DIRECT;
 549    }
 550  | r_args TABLE ALL {
 551      struct rtable_config *t;
 552      $$ = $1;
 553      WALK_LIST(t, config->tables)
 554        rt_show_add_table($$, t->table);
 555      $$->tables_defined_by = RSD_TDB_ALL;
 556    }
 557  | r_args IMPORT TABLE CF_SYM_PROTO '.' r_args_channel {
 558      $$ = $1;
 559      struct proto_config *cf = $4->proto;
 560      if (!cf->proto) cf_error("%s is not a protocol", $4->name);
 561      struct channel *c = proto_find_channel_by_name(cf->proto, $6);
 562      if (!c) cf_error("Channel %s.%s not found", $4->name, $6);
 563      if (!c->in_table) cf_error("No import table in channel %s.%s", $4->name, $6);
 564      rt_show_add_table($$, c->in_table);
 565      $$->tables_defined_by = RSD_TDB_DIRECT;
 566    }
 567  | r_args FILTER filter {
 568      $$ = $1;
 569      if ($$->filter != FILTER_ACCEPT) cf_error("Filter specified twice");
 570      $$->filter = $3;
 571    }
 572  | r_args where_filter {
 573      $$ = $1;
 574      if ($$->filter != FILTER_ACCEPT) cf_error("Filter specified twice");
 575      $$->filter = $2;
 576    }
 577  | r_args ALL {
 578      $$ = $1;
 579      $$->verbose = 1;
 580    }
 581  | r_args PRIMARY {
 582      $$ = $1;
 583      $$->primary_only = 1;
 584    }
 585  | r_args FILTERED {
 586      $$ = $1;
 587      $$->filtered = 1;
 588    }
 589  | r_args export_mode CF_SYM_PROTO {
 590      struct proto_config *c = (struct proto_config *) $3->proto;
 591      $$ = $1;
 592      if ($$->export_mode) cf_error("Export specified twice");
 593      if (!c->proto) cf_error("%s is not a protocol", $3->name);
 594      $$->export_mode = $2;
 595      $$->export_protocol = c->proto;
 596      $$->tables_defined_by = RSD_TDB_INDIRECT;
 597    }
 598  | r_args export_mode CF_SYM_PROTO '.' r_args_channel {
 599      struct proto_config *c = (struct proto_config *) $3->proto;
 600      $$ = $1;
 601      if ($$->export_mode) cf_error("Export specified twice");
 602      if (!c->proto) cf_error("%s is not a protocol", $3->name);
 603      $$->export_mode = $2;
 604      $$->export_channel = proto_find_channel_by_name(c->proto, $5);
 605      if (!$$->export_channel) cf_error("Export channel not found");
 606      $$->tables_defined_by = RSD_TDB_INDIRECT;
 607    }
 608  | r_args PROTOCOL CF_SYM_PROTO {
 609      struct proto_config *c = (struct proto_config *) $3->proto;
 610      $$ = $1;
 611      if ($$->show_protocol) cf_error("Protocol specified twice");
 612      if (!c->proto) cf_error("%s is not a protocol", $3->name);
 613      $$->show_protocol = c->proto;
 614      $$->tables_defined_by = RSD_TDB_INDIRECT;
 615    }
 616  | r_args STATS {
 617      $$ = $1;
 618      $$->stats = 1;
 619    }
 620  | r_args COUNT {
 621      $$ = $1;
 622      $$->stats = 2;
 623    }
 624  ;
 625
 626 r_args_for:
 627   r_args_for_val {
 628     $$ = cfg_alloc($1.length);
 629     net_copy($$, &$1);
 630   }
 631  | net_vpn4_
 632  | net_vpn6_
 633  | net_ip6_sadr_
 634  | VPN_RD IP4 {
 635     $$ = cfg_alloc(sizeof(net_addr_vpn4));
 636     net_fill_vpn4($$, $2, IP4_MAX_PREFIX_LENGTH, $1);
 637   }
 638  | VPN_RD IP6 {
 639     $$ = cfg_alloc(sizeof(net_addr_vpn6));
 640     net_fill_vpn6($$, $2, IP6_MAX_PREFIX_LENGTH, $1);
 641   }
 642  | IP6 FROM IP6 {
 643     $$ = cfg_alloc(sizeof(net_addr_ip6_sadr));
 644     net_fill_ip6_sadr($$, $1, IP6_MAX_PREFIX_LENGTH, $3, IP6_MAX_PREFIX_LENGTH);
 645   }
 646  | CF_SYM_CONSTANT {
 647      if ($1->class == (SYM_CONSTANT | T_IP))
 648      {
 649        $$ = cfg_alloc(ipa_is_ip4(SYM_VAL($1).ip) ? sizeof(net_addr_ip4) : sizeof(net_addr_ip6));
 650        net_fill_ip_host($$, SYM_VAL($1).ip);
 651      }
 652      else if (($1->class == (SYM_CONSTANT | T_NET)) && net_type_match(SYM_VAL($1).net, NB_IP | NB_VPN))
 653        $$ = (net_addr *) SYM_VAL($1).net; /* Avoid const warning */
 654      else
 655        cf_error("IP address or network expected");
 656    }
 657  ;
 658
 659 r_args_for_val:
 660    net_ip4_
 661  | net_ip6_
 662  | IP4 { net_fill_ip4(&($$), $1, IP4_MAX_PREFIX_LENGTH); }
 663  | IP6 { net_fill_ip6(&($$), $1, IP6_MAX_PREFIX_LENGTH); }
 664
 665 export_mode:
 666    PREEXPORT    { $$ = RSEM_PREEXPORT; }
 667  | EXPORT       { $$ = RSEM_EXPORT; }
 668  | NOEXPORT     { $$ = RSEM_NOEXPORT; }
 669  ;
 670
 671 /* This is ugly hack */
 672 r_args_channel:
 673    IPV4         { $$ = "ipv4"; }
 674  | IPV4_MC      { $$ = "ipv4-mc"; }
 675  | IPV4_MPLS    { $$ = "ipv4-mpls"; }
 676  | IPV6         { $$ = "ipv6"; }
 677  | IPV6_MC      { $$ = "ipv6-mc"; }
 678  | IPV6_MPLS    { $$ = "ipv6-mpls"; }
 679  | IPV6_SADR    { $$ = "ipv6-sadr"; }
 680  | VPN4         { $$ = "vpn4"; }
 681  | VPN4_MC      { $$ = "vpn4-mc"; }
 682  | VPN4_MPLS    { $$ = "vpn4-mpls"; }
 683  | VPN6         { $$ = "vpn6"; }
 684  | VPN6_MC      { $$ = "vpn6-mc"; }
 685  | VPN6_MPLS    { $$ = "vpn6-mpls"; }
 686  | ROA4         { $$ = "roa4"; }
 687  | ROA6         { $$ = "roa6"; }
 688  | FLOW4        { $$ = "flow4"; }
 689  | FLOW6        { $$ = "flow6"; }
 690  | MPLS         { $$ = "mpls"; }
 691  | PRI          { $$ = "pri"; }
 692  | SEC          { $$ = "sec"; }
 693  ;
 694
 695 CF_CLI_HELP(SHOW SYMBOLS, ..., [[Show all known symbolic names]])
 696 CF_CLI(SHOW SYMBOLS, sym_args, [table|filter|function|protocol|template|<symbol>], [[Show all known symbolic names]])
 697 { cmd_show_symbols($3); } ;
 698
 699 sym_args:
 700    /* empty */ {
 701      $$ = cfg_allocz(sizeof(struct sym_show_data));
 702    }
 703  | sym_args TABLE { $$ = $1; $$->type = SYM_TABLE; }
 704  | sym_args FUNCTION { $$ = $1; $$->type = SYM_FUNCTION; }
 705  | sym_args FILTER { $$ = $1; $$->type = SYM_FILTER; }
 706  | sym_args PROTOCOL { $$ = $1; $$->type = SYM_PROTO; }
 707  | sym_args TEMPLATE { $$ = $1; $$->type = SYM_TEMPLATE; }
 708  | sym_args symbol { $$ = $1; $$->sym = $2; }
 709  ;
 710
 711
 712 CF_CLI_HELP(DUMP, ..., [[Dump debugging information]])
 713 CF_CLI(DUMP RESOURCES,,, [[Dump all allocated resource]])
 714 { rdump(&root_pool); cli_msg(0, ""); } ;
 715 CF_CLI(DUMP SOCKETS,,, [[Dump open sockets]])
 716 { sk_dump_all(); cli_msg(0, ""); } ;
 717 CF_CLI(DUMP EVENTS,,, [[Dump event log]])
 718 { io_log_dump(); cli_msg(0, ""); } ;
 719 CF_CLI(DUMP INTERFACES,,, [[Dump interface information]])
 720 { if_dump_all(); cli_msg(0, ""); } ;
 721 CF_CLI(DUMP NEIGHBORS,,, [[Dump neighbor cache]])
 722 { neigh_dump_all(); cli_msg(0, ""); } ;
 723 CF_CLI(DUMP ATTRIBUTES,,, [[Dump attribute cache]])
 724 { rta_dump_all(); cli_msg(0, ""); } ;
 725 CF_CLI(DUMP ROUTES,,, [[Dump routing table]])
 726 { rt_dump_all(); cli_msg(0, ""); } ;
 727 CF_CLI(DUMP PROTOCOLS,,, [[Dump protocol information]])
 728 { protos_dump_all(); cli_msg(0, ""); } ;
 729
 730 CF_CLI(EVAL, term, <expr>, [[Evaluate an expression]])
 731 { cmd_eval(f_postfixify($2)); } ;
 732
 733 CF_CLI_HELP(ECHO, ..., [[Control echoing of log messages]])
 734 CF_CLI(ECHO, echo_mask echo_size, (all | off | { debug|trace|info|remote|warning|error|auth [, ...] }) [<buffer-size>], [[Control echoing of log messages]]) {
 735   cli_set_log_echo(this_cli, $2, $3);
 736   cli_msg(0, "");
 737 } ;
 738
 739 echo_mask:
 740    ALL { $$ = ~0; }
 741  | OFF { $$ = 0; }
 742  | '{' log_mask_list '}' { $$ = $2; }
 743  ;
 744
 745 echo_size:
 746    /* empty */ { $$ = 4096; }
 747  | NUM {
 748      if ($1 < 256 || $1 > 65536) cf_error("Invalid log buffer size");
 749      $$ = $1;
 750    }
 751  ;
 752
 753 CF_CLI(DISABLE, proto_patt opttext, (<protocol> | \"<pattern>\" | all) [message], [[Disable protocol]])
 754 { proto_apply_cmd($2, proto_cmd_disable, 1, (uintptr_t) $3); } ;
 755 CF_CLI(ENABLE, proto_patt opttext, (<protocol> | \"<pattern>\" | all) [message], [[Enable protocol]])
 756 { proto_apply_cmd($2, proto_cmd_enable, 1, (uintptr_t) $3); } ;
 757 CF_CLI(RESTART, proto_patt opttext, (<protocol> | \"<pattern>\" | all) [message], [[Restart protocol]])
 758 { proto_apply_cmd($2, proto_cmd_restart, 1, (uintptr_t) $3); } ;
 759 CF_CLI(RELOAD, proto_patt, <protocol> | \"<pattern>\" | all, [[Reload protocol]])
 760 { proto_apply_cmd($2, proto_cmd_reload, 1, CMD_RELOAD); } ;
 761 CF_CLI(RELOAD IN, proto_patt, <protocol> | \"<pattern>\" | all, [[Reload protocol (just imported routes)]])
 762 { proto_apply_cmd($3, proto_cmd_reload, 1, CMD_RELOAD_IN); } ;
 763 CF_CLI(RELOAD OUT, proto_patt, <protocol> | \"<pattern>\" | all, [[Reload protocol (just exported routes)]])
 764 { proto_apply_cmd($3, proto_cmd_reload, 1, CMD_RELOAD_OUT); } ;
 765
 766 CF_CLI_HELP(DEBUG, ..., [[Control protocol debugging via BIRD logs]])
 767 CF_CLI(DEBUG, proto_patt debug_mask, (<protocol> | \"<pattern>\" | all) (all | off | { states|routes|filters|interfaces|events|packets [, ...] }), [[Control protocol debugging via BIRD logs]])
 768 { proto_apply_cmd($2, proto_cmd_debug, 1, $3); } ;
 769
 770 CF_CLI_HELP(MRTDUMP, ..., [[Control protocol debugging via MRTdump files]])
 771 CF_CLI(MRTDUMP, proto_patt mrtdump_mask, (<protocol> | \"<pattern>\" | all) (all | off | { states|messages [, ...] }), [[Control protocol debugging via MRTdump format]])
 772 { proto_apply_cmd($2, proto_cmd_mrtdump, 1, $3); } ;
 773
 774 CF_CLI(RESTRICT,,,[[Restrict current CLI session to safe commands]])
 775 { this_cli->restricted = 1; cli_msg(16, "Access restricted"); } ;
 776
 777 proto_patt:
 778    CF_SYM_PROTO { $$.ptr = $1; $$.patt = 0; }
 779  | ALL  { $$.ptr = NULL; $$.patt = 1; }
 780  | TEXT { $$.ptr = $1; $$.patt = 1; }
 781  ;
 782
 783 proto_patt2:
 784    CF_SYM_PROTO { $$.ptr = $1; $$.patt = 0; }
 785  |      { $$.ptr = NULL; $$.patt = 1; }
 786  | TEXT { $$.ptr = $1; $$.patt = 1; }
 787  ;
 788
 789 dynamic_attr: IGP_METRIC { $$ = f_new_dynamic_attr(EAF_TYPE_INT, 0, T_INT, EA_GEN_IGP_METRIC); } ;
 790
 791
 792 CF_CODE
 793
 794 CF_END