proto/bgp/config.Y

   1 /*
   2  *      BIRD -- Border Gateway Protocol Configuration
   3  *
   4  *      (c) 2000 Martin Mares <mj@ucw.cz>
   5  *
   6  *      Can be freely distributed and used under the terms of the GNU GPL.
   7  */
   8
   9 CF_HDR
  10
  11 #include "proto/bgp/bgp.h"
  12
  13 CF_DEFINES
  14
  15 #define BGP_CFG ((struct bgp_config *) this_proto)
  16 #define BGP_CC ((struct bgp_channel_config *) this_channel)
  17
  18 CF_DECLS
  19
  20 CF_KEYWORDS(BGP, LOCAL, NEIGHBOR, AS, HOLD, TIME, CONNECT, RETRY, KEEPALIVE,
  21         MULTIHOP, STARTUP, VIA, NEXT, HOP, SELF, DEFAULT, PATH, METRIC, ERROR,
  22         START, DELAY, FORGET, WAIT, ENABLE, DISABLE, AFTER, BGP_PATH,
  23         BGP_LOCAL_PREF, BGP_MED, BGP_ORIGIN, BGP_NEXT_HOP, BGP_ATOMIC_AGGR,
  24         BGP_AGGREGATOR, BGP_COMMUNITY, BGP_EXT_COMMUNITY, BGP_LARGE_COMMUNITY,
  25         SOURCE, ADDRESS, PASSWORD, RR, RS, CLIENT, CLUSTER, ID, AS4, ADVERTISE,
  26         IPV4, CAPABILITIES, LIMIT, PASSIVE, PREFER, OLDER, MISSING, LLADDR,
  27         DROP, IGNORE, ROUTE, REFRESH, INTERPRET, COMMUNITIES, BGP_ORIGINATOR_ID,
  28         BGP_CLUSTER_LIST, IGP, TABLE, GATEWAY, DIRECT, RECURSIVE, MED, TTL,
  29         SECURITY, DETERMINISTIC, SECONDARY, ALLOW, BFD, ADD, PATHS, RX, TX,
  30         GRACEFUL, RESTART, AWARE, CHECK, LINK, PORT, EXTENDED, MESSAGES, SETKEY,
  31         STRICT, BIND, CONFEDERATION, MEMBER, MULTICAST, FLOW4, FLOW6, LONG,
  32         LIVED, STALE, IMPORT, IBGP, EBGP, MANDATORY, INTERNAL, EXTERNAL, SETS,
  33         DYNAMIC, RANGE, NAME, DIGITS, BGP_AIGP, AIGP, ORIGINATE, COST, ENFORCE,
  34         FIRST)
  35
  36 %type <i> bgp_nh
  37 %type <i32> bgp_afi
  38
  39 CF_KEYWORDS(CEASE, PREFIX, LIMIT, HIT, ADMINISTRATIVE, SHUTDOWN, RESET, PEER,
  40         CONFIGURATION, CHANGE, DECONFIGURED, CONNECTION, REJECTED, COLLISION,
  41         OUT, OF, RESOURCES)
  42
  43 %type<i> bgp_cease_mask bgp_cease_list bgp_cease_flag
  44
  45 CF_GRAMMAR
  46
  47 proto: bgp_proto '}'  ;
  48
  49 bgp_proto_start: proto_start BGP {
  50      this_proto = proto_config_new(&proto_bgp, $1);
  51      BGP_CFG->local_port = BGP_PORT;
  52      BGP_CFG->remote_port = BGP_PORT;
  53      BGP_CFG->multihop = -1;    /* undefined */
  54      BGP_CFG->hold_time = 240;
  55      BGP_CFG->initial_hold_time = 240;
  56      BGP_CFG->compare_path_lengths = 1;
  57      BGP_CFG->igp_metric = 1;
  58      BGP_CFG->connect_delay_time = 5;
  59      BGP_CFG->connect_retry_time = 120;
  60      BGP_CFG->error_amnesia_time = 300;
  61      BGP_CFG->error_delay_time_min = 60;
  62      BGP_CFG->error_delay_time_max = 300;
  63      BGP_CFG->enable_refresh = 1;
  64      BGP_CFG->enable_as4 = 1;
  65      BGP_CFG->capabilities = 2;
  66      BGP_CFG->interpret_communities = 1;
  67      BGP_CFG->allow_as_sets = 1;
  68      BGP_CFG->default_local_pref = 100;
  69      BGP_CFG->gr_mode = BGP_GR_AWARE;
  70      BGP_CFG->gr_time = 120;
  71      BGP_CFG->llgr_mode = -1;
  72      BGP_CFG->llgr_time = 3600;
  73      BGP_CFG->setkey = 1;
  74      BGP_CFG->dynamic_name = "dynbgp";
  75      BGP_CFG->check_link = -1;
  76    }
  77  ;
  78
  79 bgp_loc_opts:
  80    /* empty */
  81  | bgp_loc_opts PORT expr { BGP_CFG->local_port = $3; if (($3<1) || ($3>65535)) cf_error("Invalid port number"); }
  82  | bgp_loc_opts AS expr { BGP_CFG->local_as = $3; }
  83  ;
  84
  85 bgp_nbr_opts:
  86    /* empty */
  87  | bgp_nbr_opts PORT expr { BGP_CFG->remote_port = $3; if (($3<1) || ($3>65535)) cf_error("Invalid port number"); }
  88  | bgp_nbr_opts AS expr { BGP_CFG->remote_as = $3; }
  89  | bgp_nbr_opts INTERNAL { BGP_CFG->peer_type = BGP_PT_INTERNAL; }
  90  | bgp_nbr_opts EXTERNAL { BGP_CFG->peer_type = BGP_PT_EXTERNAL; }
  91  ;
  92
  93 bgp_cease_mask:
  94    /* true -> all except connection collision */
  95    bool { $$ = $1 ? ~(1 << 7) : 0; }
  96  | '{' bgp_cease_list '}' { $$ = $2; }
  97  ;
  98
  99 bgp_cease_list:
 100    bgp_cease_flag
 101  | bgp_cease_list ',' bgp_cease_flag { $$ = $1 | $3; }
 102  ;
 103
 104 bgp_cease_flag:
 105    CEASE                        { $$ = 1 << 0; }
 106  | PREFIX LIMIT HIT             { $$ = 1 << 1; }
 107  | ADMINISTRATIVE SHUTDOWN      { $$ = 1 << 2; }
 108  | PEER DECONFIGURED            { $$ = 1 << 3; }
 109  | ADMINISTRATIVE RESET         { $$ = 1 << 4; }
 110  | CONNECTION REJECTED          { $$ = 1 << 5; }
 111  | CONFIGURATION CHANGE         { $$ = 1 << 6; }
 112  | CONNECTION COLLISION         { $$ = 1 << 7; }
 113  | OUT OF RESOURCES             { $$ = 1 << 8; }
 114  ;
 115
 116 bgp_proto:
 117    bgp_proto_start proto_name '{'
 118  | bgp_proto proto_item ';'
 119  | bgp_proto bgp_proto_channel ';'
 120  | bgp_proto LOCAL bgp_loc_opts ';'
 121  | bgp_proto LOCAL ipa ipa_scope bgp_loc_opts ';' {
 122      BGP_CFG->local_ip = $3;
 123      if ($4) BGP_CFG->iface = $4;
 124    }
 125  | bgp_proto NEIGHBOR bgp_nbr_opts ';'
 126  | bgp_proto NEIGHBOR ipa ipa_scope bgp_nbr_opts ';' {
 127      if (ipa_nonzero(BGP_CFG->remote_ip) || BGP_CFG->remote_range)
 128        cf_error("Only one neighbor per BGP instance is allowed");
 129      BGP_CFG->remote_ip = $3;
 130      if ($4) BGP_CFG->iface = $4;
 131    }
 132  | bgp_proto NEIGHBOR RANGE net_ip bgp_nbr_opts ';' {
 133      if (ipa_nonzero(BGP_CFG->remote_ip) || BGP_CFG->remote_range)
 134        cf_error("Only one neighbor per BGP instance is allowed");
 135      net_addr *n = cfg_alloc($4.length);
 136      net_copy(n, &($4));
 137      BGP_CFG->remote_range = n;
 138    }
 139  | bgp_proto INTERFACE TEXT ';' { BGP_CFG->iface = if_get_by_name($3); }
 140  | bgp_proto RR CLUSTER ID idval ';' { BGP_CFG->rr_cluster_id = $5; }
 141  | bgp_proto RR CLIENT bool ';' { BGP_CFG->rr_client = $4; }
 142  | bgp_proto RS CLIENT bool ';' { BGP_CFG->rs_client = $4; }
 143  | bgp_proto CONFEDERATION expr ';' { BGP_CFG->confederation = $3; }
 144  | bgp_proto CONFEDERATION MEMBER bool ';' { BGP_CFG->confederation_member = $4; }
 145  | bgp_proto HOLD TIME expr ';' { BGP_CFG->hold_time = $4; }
 146  | bgp_proto STARTUP HOLD TIME expr ';' { BGP_CFG->initial_hold_time = $5; }
 147  | bgp_proto DIRECT ';' { BGP_CFG->multihop = 0; }
 148  | bgp_proto MULTIHOP ';' { BGP_CFG->multihop = 64; }
 149  | bgp_proto MULTIHOP expr ';' { BGP_CFG->multihop = $3; if (($3<1) || ($3>255)) cf_error("Multihop must be in range 1-255"); }
 150  | bgp_proto DYNAMIC NAME text ';' {
 151      if (strchr($4, '%')) cf_error("Forbidden character '%%' in dynamic name");
 152      if (strlen($4) > (SYM_MAX_LEN - 16)) cf_error("Dynamic name too long");
 153      BGP_CFG->dynamic_name = $4;
 154    }
 155  | bgp_proto DYNAMIC NAME DIGITS expr ';' { BGP_CFG->dynamic_name_digits = $5; if ($5>10) cf_error("Dynamic name digits must be at most 10"); }
 156  | bgp_proto STRICT BIND bool ';' { BGP_CFG->strict_bind = $4; }
 157  | bgp_proto PATH METRIC bool ';' { BGP_CFG->compare_path_lengths = $4; }
 158  | bgp_proto MED METRIC bool ';' { BGP_CFG->med_metric = $4; }
 159  | bgp_proto IGP METRIC bool ';' { BGP_CFG->igp_metric = $4; }
 160  | bgp_proto PREFER OLDER bool ';' { BGP_CFG->prefer_older = $4; }
 161  | bgp_proto DETERMINISTIC MED bool ';' { BGP_CFG->deterministic_med = $4; }
 162  | bgp_proto DEFAULT BGP_MED expr ';' { BGP_CFG->default_med = $4; }
 163  | bgp_proto DEFAULT BGP_LOCAL_PREF expr ';' { BGP_CFG->default_local_pref = $4; }
 164  | bgp_proto SOURCE ADDRESS ipa ';' { BGP_CFG->local_ip = $4; }
 165  | bgp_proto START DELAY TIME expr ';' { BGP_CFG->connect_delay_time = $5; log(L_WARN "%s: Start delay time option is deprecated, use connect delay time", this_proto->name); }
 166  | bgp_proto CONNECT DELAY TIME expr ';' { BGP_CFG->connect_delay_time = $5; }
 167  | bgp_proto CONNECT RETRY TIME expr ';' { BGP_CFG->connect_retry_time = $5; }
 168  | bgp_proto KEEPALIVE TIME expr ';' { BGP_CFG->keepalive_time = $4; }
 169  | bgp_proto ERROR FORGET TIME expr ';' { BGP_CFG->error_amnesia_time = $5; }
 170  | bgp_proto ERROR WAIT TIME expr ',' expr ';' { BGP_CFG->error_delay_time_min = $5; BGP_CFG->error_delay_time_max = $7; }
 171  | bgp_proto DISABLE AFTER ERROR bool ';' { BGP_CFG->disable_after_error = $5; }
 172  | bgp_proto DISABLE AFTER CEASE bgp_cease_mask ';' { BGP_CFG->disable_after_cease = $5; }
 173  | bgp_proto ENABLE ROUTE REFRESH bool ';' { BGP_CFG->enable_refresh = $5; }
 174  | bgp_proto ENABLE AS4 bool ';' { BGP_CFG->enable_as4 = $4; }
 175  | bgp_proto ENABLE EXTENDED MESSAGES bool ';' { BGP_CFG->enable_extended_messages = $5; }
 176  | bgp_proto CAPABILITIES bool ';' { BGP_CFG->capabilities = $3; }
 177  | bgp_proto PASSWORD text ';' { BGP_CFG->password = $3; }
 178  | bgp_proto SETKEY bool ';' { BGP_CFG->setkey = $3; }
 179  | bgp_proto PASSIVE bool ';' { BGP_CFG->passive = $3; }
 180  | bgp_proto INTERPRET COMMUNITIES bool ';' { BGP_CFG->interpret_communities = $4; }
 181  | bgp_proto ALLOW LOCAL AS ';' { BGP_CFG->allow_local_as = -1; }
 182  | bgp_proto ALLOW LOCAL AS expr ';' { BGP_CFG->allow_local_as = $5; }
 183  | bgp_proto ALLOW BGP_LOCAL_PREF bool ';' { BGP_CFG->allow_local_pref = $4; }
 184  | bgp_proto ALLOW AS SETS bool ';' { BGP_CFG->allow_as_sets = $5; }
 185  | bgp_proto GRACEFUL RESTART bool ';' { BGP_CFG->gr_mode = $4; }
 186  | bgp_proto GRACEFUL RESTART AWARE ';' { BGP_CFG->gr_mode = BGP_GR_AWARE; }
 187  | bgp_proto GRACEFUL RESTART TIME expr ';' { BGP_CFG->gr_time = $5; }
 188  | bgp_proto LONG LIVED GRACEFUL RESTART bool ';' { BGP_CFG->llgr_mode = $6; }
 189  | bgp_proto LONG LIVED GRACEFUL RESTART AWARE ';' { BGP_CFG->llgr_mode = BGP_LLGR_AWARE; }
 190  | bgp_proto LONG LIVED STALE TIME expr ';' { BGP_CFG->llgr_time = $6; }
 191  | bgp_proto TTL SECURITY bool ';' { BGP_CFG->ttl_security = $4; }
 192  | bgp_proto CHECK LINK bool ';' { BGP_CFG->check_link = $4; }
 193  | bgp_proto BFD bool ';' { BGP_CFG->bfd = $3; cf_check_bfd($3); }
 194  | bgp_proto BFD GRACEFUL ';' { BGP_CFG->bfd = BGP_BFD_GRACEFUL; cf_check_bfd(1); }
 195  | bgp_proto ENFORCE FIRST AS bool ';' { BGP_CFG->enforce_first_as = $5; }
 196  ;
 197
 198 bgp_afi:
 199    IPV4                 { $$ = BGP_AF_IPV4; }
 200  | IPV6                 { $$ = BGP_AF_IPV6; }
 201  | IPV4 MULTICAST       { $$ = BGP_AF_IPV4_MC; }
 202  | IPV6 MULTICAST       { $$ = BGP_AF_IPV6_MC; }
 203  | IPV4 MPLS            { $$ = BGP_AF_IPV4_MPLS; }
 204  | IPV6 MPLS            { $$ = BGP_AF_IPV6_MPLS; }
 205  | VPN4 MPLS            { $$ = BGP_AF_VPN4_MPLS; }
 206  | VPN6 MPLS            { $$ = BGP_AF_VPN6_MPLS; }
 207  | VPN4 MULTICAST       { $$ = BGP_AF_VPN4_MC; }
 208  | VPN6 MULTICAST       { $$ = BGP_AF_VPN6_MC; }
 209  | FLOW4                { $$ = BGP_AF_FLOW4; }
 210  | FLOW6                { $$ = BGP_AF_FLOW6; }
 211  ;
 212
 213 bgp_channel_start: bgp_afi
 214 {
 215   const struct bgp_af_desc *desc = bgp_get_af_desc($1);
 216
 217   if (!desc)
 218     cf_error("Unknown AFI/SAFI");
 219
 220   this_channel = channel_config_get(&channel_bgp, desc->name, desc->net, this_proto);
 221
 222   /* New channel */
 223   if (!BGP_CC->desc)
 224   {
 225     BGP_CC->c.in_filter = FILTER_UNDEF;
 226     BGP_CC->c.out_filter = FILTER_UNDEF;
 227     BGP_CC->c.ra_mode = RA_UNDEF;
 228     BGP_CC->afi = $1;
 229     BGP_CC->desc = desc;
 230     BGP_CC->next_hop_keep = 0xff; /* undefined */
 231     BGP_CC->gr_able = 0xff;     /* undefined */
 232     BGP_CC->llgr_able = 0xff;   /* undefined */
 233     BGP_CC->llgr_time = ~0U;    /* undefined */
 234     BGP_CC->aigp = 0xff;        /* undefined */
 235   }
 236 };
 237
 238 bgp_nh:
 239    bool { $$ = $1; }
 240  | IBGP { $$ = NH_IBGP; }
 241  | EBGP { $$ = NH_EBGP; }
 242
 243 bgp_channel_item:
 244    channel_item
 245  | NEXT HOP ADDRESS ipa { BGP_CC->next_hop_addr = $4; }
 246  | NEXT HOP SELF bgp_nh { BGP_CC->next_hop_self = $4; }
 247  | NEXT HOP KEEP bgp_nh { BGP_CC->next_hop_keep = $4; }
 248  | MANDATORY bool { BGP_CC->mandatory = $2; }
 249  | MISSING LLADDR SELF { BGP_CC->missing_lladdr = MLL_SELF; }
 250  | MISSING LLADDR DROP { BGP_CC->missing_lladdr = MLL_DROP; }
 251  | MISSING LLADDR IGNORE { BGP_CC->missing_lladdr = MLL_IGNORE; }
 252  | GATEWAY DIRECT { BGP_CC->gw_mode = GW_DIRECT; }
 253  | GATEWAY RECURSIVE { BGP_CC->gw_mode = GW_RECURSIVE; }
 254  | SECONDARY bool { BGP_CC->secondary = $2; }
 255  | GRACEFUL RESTART bool { BGP_CC->gr_able = $3; }
 256  | LONG LIVED GRACEFUL RESTART bool { BGP_CC->llgr_able = $5; }
 257  | LONG LIVED STALE TIME expr { BGP_CC->llgr_time = $5; }
 258  | EXTENDED NEXT HOP bool { BGP_CC->ext_next_hop = $4; }
 259  | ADD PATHS RX { BGP_CC->add_path = BGP_ADD_PATH_RX; }
 260  | ADD PATHS TX { BGP_CC->add_path = BGP_ADD_PATH_TX; }
 261  | ADD PATHS bool { BGP_CC->add_path = $3 ? BGP_ADD_PATH_FULL : 0; }
 262  | IMPORT TABLE bool { BGP_CC->import_table = $3; }
 263  | EXPORT TABLE bool { BGP_CC->export_table = $3; }
 264  | AIGP bool { BGP_CC->aigp = $2; BGP_CC->aigp_originate = 0; }
 265  | AIGP ORIGINATE { BGP_CC->aigp = 1; BGP_CC->aigp_originate = 1; }
 266  | COST expr { BGP_CC->cost = $2; if ($2 < 1) cf_error("Cost must be positive"); }
 267  | IGP TABLE rtable {
 268     if (BGP_CC->desc->no_igp)
 269       cf_error("IGP table not allowed here");
 270
 271     if ($3->addr_type == NET_IP4)
 272       BGP_CC->igp_table_ip4 = $3;
 273     else if ($3->addr_type == NET_IP6)
 274       BGP_CC->igp_table_ip6 = $3;
 275     else
 276       cf_error("Mismatched IGP table type");
 277    }
 278  ;
 279
 280 bgp_channel_opts:
 281    /* empty */
 282  | bgp_channel_opts bgp_channel_item ';'
 283  ;
 284
 285 bgp_channel_opt_list:
 286    /* empty */
 287  | '{' bgp_channel_opts '}'
 288  ;
 289
 290 bgp_channel_end:
 291 {
 292   if (!this_channel->table)
 293     cf_error("Routing table not specified");
 294
 295   this_channel = NULL;
 296 };
 297
 298 bgp_proto_channel: bgp_channel_start bgp_channel_opt_list bgp_channel_end;
 299
 300
 301 dynamic_attr: BGP_ORIGIN
 302         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_ENUM_BGP_ORIGIN, EA_CODE(PROTOCOL_BGP, BA_ORIGIN)); } ;
 303 dynamic_attr: BGP_PATH
 304         { $$ = f_new_dynamic_attr(EAF_TYPE_AS_PATH, T_PATH, EA_CODE(PROTOCOL_BGP, BA_AS_PATH)); } ;
 305 dynamic_attr: BGP_NEXT_HOP
 306         { $$ = f_new_dynamic_attr(EAF_TYPE_IP_ADDRESS, T_IP, EA_CODE(PROTOCOL_BGP, BA_NEXT_HOP)); } ;
 307 dynamic_attr: BGP_MED
 308         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_INT, EA_CODE(PROTOCOL_BGP, BA_MULTI_EXIT_DISC)); } ;
 309 dynamic_attr: BGP_LOCAL_PREF
 310         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_INT, EA_CODE(PROTOCOL_BGP, BA_LOCAL_PREF)); } ;
 311 dynamic_attr: BGP_ATOMIC_AGGR
 312         { $$ = f_new_dynamic_attr(EAF_TYPE_OPAQUE, T_ENUM_EMPTY, EA_CODE(PROTOCOL_BGP, BA_ATOMIC_AGGR)); } ;
 313 dynamic_attr: BGP_AGGREGATOR
 314         { $$ = f_new_dynamic_attr(EAF_TYPE_OPAQUE, T_ENUM_EMPTY, EA_CODE(PROTOCOL_BGP, BA_AGGREGATOR)); } ;
 315 dynamic_attr: BGP_COMMUNITY
 316         { $$ = f_new_dynamic_attr(EAF_TYPE_INT_SET, T_CLIST, EA_CODE(PROTOCOL_BGP, BA_COMMUNITY)); } ;
 317 dynamic_attr: BGP_ORIGINATOR_ID
 318         { $$ = f_new_dynamic_attr(EAF_TYPE_ROUTER_ID, T_QUAD, EA_CODE(PROTOCOL_BGP, BA_ORIGINATOR_ID)); } ;
 319 dynamic_attr: BGP_CLUSTER_LIST
 320         { $$ = f_new_dynamic_attr(EAF_TYPE_INT_SET, T_CLIST, EA_CODE(PROTOCOL_BGP, BA_CLUSTER_LIST)); } ;
 321 dynamic_attr: BGP_EXT_COMMUNITY
 322         { $$ = f_new_dynamic_attr(EAF_TYPE_EC_SET, T_ECLIST, EA_CODE(PROTOCOL_BGP, BA_EXT_COMMUNITY)); } ;
 323 dynamic_attr: BGP_AIGP
 324         { $$ = f_new_dynamic_attr(EAF_TYPE_OPAQUE, T_ENUM_EMPTY, EA_CODE(PROTOCOL_BGP, BA_AIGP)); } ;
 325 dynamic_attr: BGP_LARGE_COMMUNITY
 326         { $$ = f_new_dynamic_attr(EAF_TYPE_LC_SET, T_LCLIST, EA_CODE(PROTOCOL_BGP, BA_LARGE_COMMUNITY)); } ;
 327
 328
 329
 330 CF_ENUM(T_ENUM_BGP_ORIGIN, ORIGIN_, IGP, EGP, INCOMPLETE)
 331
 332 CF_CODE
 333
 334 CF_END