configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2022 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libiconv libctf libsframe"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools c++tools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-libatomic \
 154                 target-libitm \
 155                 target-libstdc++-v3 \
 156                 target-libsanitizer \
 157                 target-libvtv \
 158                 target-libssp \
 159                 target-libquadmath \
 160                 target-libgfortran \
 161                 target-libffi \
 162                 target-libobjc \
 163                 target-libada \
 164                 target-libgo \
 165                 target-libphobos \
 166                 target-zlib"
 167
 168 # these tools are built using the target libraries, and are intended to
 169 # run only in the target environment
 170 #
 171 # note: any program that *uses* libraries that are in the "target_libraries"
 172 # list belongs in this list.
 173 #
 174 target_tools="target-rda"
 175
 176 ################################################################################
 177
 178 ## All tools belong in one of the four categories, and are assigned above
 179 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 180 ## is important because configure will choke if they ever get through.
 181 ## ${configdirs} is directories we build using the host tools.
 182 ## ${target_configdirs} is directories we build using the target tools.
 183 configdirs=`echo ${host_libs} ${host_tools}`
 184 target_configdirs=`echo ${target_libraries} ${target_tools}`
 185 build_configdirs=`echo ${build_libs} ${build_tools}`
 186
 187 m4_divert_text([PARSE_ARGS],
 188 [case $srcdir in
 189   *" "*)
 190 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 191     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 192 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 193     ;;
 194 esac
 195 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 196 ])
 197
 198 ################################################################################
 199
 200 srcname="gnu development package"
 201
 202 # This gets set non-empty for some net releases of packages.
 203 appdirs=""
 204
 205 # Define is_cross_compiler to save on calls to 'test'.
 206 is_cross_compiler=
 207 if test x"${host}" = x"${target}" ; then
 208   is_cross_compiler=no
 209 else
 210   is_cross_compiler=yes
 211 fi
 212
 213 # Find the build and target subdir names.
 214 GCC_TOPLEV_SUBDIRS
 215 # Be sure to cover against remnants of an in-tree build.
 216 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 217   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 218 Use a pristine source tree when building in a separate tree])
 219 fi
 220
 221 # Skipdirs are removed silently.
 222 skipdirs=
 223 # Noconfigdirs are removed loudly.
 224 noconfigdirs=""
 225
 226 use_gnu_ld=
 227 # Make sure we don't let GNU ld be added if we didn't want it.
 228 if test x$with_gnu_ld = xno ; then
 229   use_gnu_ld=no
 230   noconfigdirs="$noconfigdirs ld gold"
 231 fi
 232
 233 use_gnu_as=
 234 # Make sure we don't let GNU as be added if we didn't want it.
 235 if test x$with_gnu_as = xno ; then
 236   use_gnu_as=no
 237   noconfigdirs="$noconfigdirs gas"
 238 fi
 239
 240 use_included_zlib=
 241 AC_ARG_WITH(system-zlib,
 242 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 243 # Make sure we don't let ZLIB be added if we didn't want it.
 244 if test x$with_system_zlib = xyes ; then
 245   use_included_zlib=no
 246   noconfigdirs="$noconfigdirs zlib"
 247 fi
 248
 249 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 250 # is provided.
 251 if test x$with_system_readline = xyes ; then
 252   noconfigdirs="$noconfigdirs readline"
 253 fi
 254
 255 # some tools are so dependent upon X11 that if we're not building with X,
 256 # it's not even worth trying to configure, much less build, that tool.
 257
 258 case ${with_x} in
 259   yes | "") ;; # the default value for this tree is that X11 is available
 260   no)
 261     skipdirs="${skipdirs} tk itcl libgui"
 262     # We won't be able to build gdbtk without X.
 263     enable_gdbtk=no
 264     ;;
 265   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 266 esac
 267
 268 # Some are only suitable for cross toolchains.
 269 # Remove these if host=target.
 270 cross_only="target-libgloss target-newlib target-opcodes"
 271
 272 case $is_cross_compiler in
 273   no) skipdirs="${skipdirs} ${cross_only}" ;;
 274 esac
 275
 276 # If both --with-headers and --with-libs are specified, default to
 277 # --without-newlib.
 278 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 279    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 280   if test x"${with_newlib}" = x ; then
 281     with_newlib=no
 282   fi
 283 fi
 284
 285 # Recognize --with-newlib/--without-newlib.
 286 case ${with_newlib} in
 287   no) skipdirs="${skipdirs} target-newlib" ;;
 288   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 289 esac
 290
 291 AC_ARG_ENABLE(as-accelerator-for,
 292 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 293                 [build as offload target compiler.
 294                 Specify offload host triple by ARG])])
 295
 296 AC_ARG_ENABLE(offload-targets,
 297 [AS_HELP_STRING([--enable-offload-targets=LIST],
 298                 [enable offloading to devices from comma-separated LIST of
 299                 TARGET[=DIR]. Use optional path to find offload target compiler
 300                 during the build])],
 301 [
 302   if test x"$enable_offload_targets" = x; then
 303     AC_MSG_ERROR([no offload targets specified])
 304   fi
 305 ], [enable_offload_targets=])
 306
 307 AC_ARG_ENABLE(offload-defaulted,
 308 [AS_HELP_STRING([--enable-offload-defaulted]
 309                 [If enabled, configured but not installed offload compilers and
 310                 libgomp plugins are silently ignored.  Useful for distribution
 311                 compilers where those are in separate optional packages.])],
 312 [enable_offload_defaulted=$enableval],
 313 [enable_offload_defaulted=])
 314
 315 # Handle --enable-gold, --enable-ld.
 316 # --disable-gold [--enable-ld]
 317 #     Build only ld.  Default option.
 318 # --enable-gold [--enable-ld]
 319 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 320 #     as "ld.bfd" and "ld".
 321 # --enable-gold=default [--enable-ld]
 322 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 323 #     install ld as "ld.bfd".
 324 # --enable-gold[=default] --disable-ld
 325 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 326 # --enable-gold --enable-ld=default
 327 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 328 #     and ld.bfd).
 329 #     In other words, ld is default
 330 # --enable-gold=default --enable-ld=default
 331 #     Error.
 332
 333 default_ld=
 334 AC_ARG_ENABLE(gold,
 335 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 336                 [build gold @<:@ARG={default,yes,no}@:>@])],
 337 ENABLE_GOLD=$enableval,
 338 ENABLE_GOLD=no)
 339 case "${ENABLE_GOLD}" in
 340   yes|default)
 341     # Check for ELF target.
 342     is_elf=no
 343     case "${target}" in
 344       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 345       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 346       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 347       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 348         case "${target}" in
 349           *-*-linux*aout* | *-*-linux*oldld*)
 350             ;;
 351           *)
 352             is_elf=yes
 353             ;;
 354         esac
 355     esac
 356
 357     if test "$is_elf" = "yes"; then
 358       # Check for target supported by gold.
 359       case "${target}" in
 360         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 361         | aarch64*-*-* | mips*-*-* | s390*-*-* | loongarch*-*-*)
 362           configdirs="$configdirs gold"
 363           if test x${ENABLE_GOLD} = xdefault; then
 364             default_ld=gold
 365           fi
 366           ENABLE_GOLD=yes
 367           ;;
 368       esac
 369     fi
 370     ;;
 371   no)
 372     ;;
 373   *)
 374     AC_MSG_ERROR([invalid --enable-gold argument])
 375     ;;
 376 esac
 377
 378 AC_ARG_ENABLE(ld,
 379 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 380                 [build ld @<:@ARG={default,yes,no}@:>@])],
 381 ENABLE_LD=$enableval,
 382 ENABLE_LD=yes)
 383
 384 case "${ENABLE_LD}" in
 385   default)
 386     if test x${default_ld} != x; then
 387       AC_MSG_ERROR([either gold or ld can be the default ld])
 388     fi
 389     ;;
 390   yes)
 391     ;;
 392   no)
 393     if test x${ENABLE_GOLD} != xyes; then
 394       AC_MSG_WARN([neither ld nor gold are enabled])
 395     fi
 396     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 397     ;;
 398   *)
 399     AC_MSG_ERROR([invalid --enable-ld argument])
 400     ;;
 401 esac
 402
 403 # PR gas/19109
 404 # Decide the default method for compressing debug sections.
 405 # Provide a configure time option to override our default.
 406 AC_ARG_ENABLE(compressed_debug_sections,
 407 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 408                 [Enable compressed debug sections for gas, gold or ld by
 409                  default])],
 410 [
 411   if test x"$enable_compressed_debug_sections" = xyes; then
 412     AC_MSG_ERROR([no program with compressed debug sections specified])
 413   fi
 414 ], [enable_compressed_debug_sections=])
 415
 416 # Configure extra directories which are host specific
 417
 418 case "${host}" in
 419   *-cygwin*)
 420     configdirs="$configdirs libtermcap" ;;
 421 esac
 422
 423 # A target can indicate whether a language isn't supported for some reason.
 424 # Only spaces may be used in this macro; not newlines or tabs.
 425 unsupported_languages=
 426
 427 # Remove more programs from consideration, based on the host or
 428 # target this usually means that a port of the program doesn't
 429 # exist yet.
 430
 431 case "${host}" in
 432   i[[3456789]]86-*-msdosdjgpp*)
 433     noconfigdirs="$noconfigdirs tcl tk itcl"
 434     ;;
 435 esac
 436
 437
 438 AC_ARG_ENABLE(libquadmath,
 439 AS_HELP_STRING([--disable-libquadmath],
 440   [do not build libquadmath directory]),
 441 ENABLE_LIBQUADMATH=$enableval,
 442 ENABLE_LIBQUADMATH=yes)
 443 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 444   noconfigdirs="$noconfigdirs target-libquadmath"
 445 fi
 446
 447
 448 AC_ARG_ENABLE(libquadmath-support,
 449 AS_HELP_STRING([--disable-libquadmath-support],
 450   [disable libquadmath support for Fortran]),
 451 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 452 ENABLE_LIBQUADMATH_SUPPORT=yes)
 453 enable_libquadmath_support=
 454 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 455   enable_libquadmath_support=no
 456 fi
 457
 458
 459 AC_ARG_ENABLE(libada,
 460 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 461 ENABLE_LIBADA=$enableval,
 462 ENABLE_LIBADA=yes)
 463 if test "${ENABLE_LIBADA}" != "yes" ; then
 464   noconfigdirs="$noconfigdirs gnattools"
 465 fi
 466
 467 AC_ARG_ENABLE(libssp,
 468 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 469 ENABLE_LIBSSP=$enableval,
 470 ENABLE_LIBSSP=yes)
 471
 472 AC_ARG_ENABLE(libstdcxx,
 473 AS_HELP_STRING([--disable-libstdcxx],
 474   [do not build libstdc++-v3 directory]),
 475 ENABLE_LIBSTDCXX=$enableval,
 476 ENABLE_LIBSTDCXX=default)
 477 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 478   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 479 fi]
 480
 481 # Enable libgomp by default on hosted POSIX systems, and a few others.
 482 if test x$enable_libgomp = x ; then
 483     case "${target}" in
 484     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 485         ;;
 486     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 487         ;;
 488     *-*-solaris2* | *-*-hpux11*)
 489         ;;
 490     *-*-darwin* | *-*-aix*)
 491         ;;
 492     nvptx*-*-* | amdgcn*-*-*)
 493         ;;
 494     *)
 495         noconfigdirs="$noconfigdirs target-libgomp"
 496         ;;
 497     esac
 498 fi
 499
 500 # Disable libatomic on unsupported systems.
 501 if test -d ${srcdir}/libatomic; then
 502     if test x$enable_libatomic = x; then
 503         AC_MSG_CHECKING([for libatomic support])
 504         if (srcdir=${srcdir}/libatomic; \
 505                 . ${srcdir}/configure.tgt; \
 506                 test -n "$UNSUPPORTED")
 507         then
 508             AC_MSG_RESULT([no])
 509             noconfigdirs="$noconfigdirs target-libatomic"
 510         else
 511             AC_MSG_RESULT([yes])
 512         fi
 513     fi
 514 fi
 515
 516 # Disable libitm on unsupported systems.
 517 if test -d ${srcdir}/libitm; then
 518     if test x$enable_libitm = x; then
 519         AC_MSG_CHECKING([for libitm support])
 520         if (srcdir=${srcdir}/libitm; \
 521                 . ${srcdir}/configure.tgt; \
 522                 test -n "$UNSUPPORTED")
 523         then
 524             AC_MSG_RESULT([no])
 525             noconfigdirs="$noconfigdirs target-libitm"
 526         else
 527             AC_MSG_RESULT([yes])
 528         fi
 529     fi
 530 fi
 531
 532 # Disable libsanitizer on unsupported systems.
 533 if test -d ${srcdir}/libsanitizer; then
 534     if test x$enable_libsanitizer = x; then
 535         AC_MSG_CHECKING([for libsanitizer support])
 536         if (srcdir=${srcdir}/libsanitizer; \
 537                 . ${srcdir}/configure.tgt; \
 538                 test -n "$UNSUPPORTED")
 539         then
 540             AC_MSG_RESULT([no])
 541             noconfigdirs="$noconfigdirs target-libsanitizer"
 542         else
 543             AC_MSG_RESULT([yes])
 544         fi
 545     fi
 546 fi
 547
 548 # Disable libvtv on unsupported systems.
 549 if test -d ${srcdir}/libvtv; then
 550     if test x$enable_libvtv = x; then
 551         AC_MSG_CHECKING([for libvtv support])
 552         if (srcdir=${srcdir}/libvtv; \
 553                 . ${srcdir}/configure.tgt; \
 554                 test "$VTV_SUPPORTED" != "yes")
 555         then
 556             AC_MSG_RESULT([no])
 557             noconfigdirs="$noconfigdirs target-libvtv"
 558         else
 559             AC_MSG_RESULT([yes])
 560         fi
 561     fi
 562 fi
 563
 564 # Disable libquadmath for some systems.
 565 case "${target}" in
 566   avr-*-*)
 567     noconfigdirs="$noconfigdirs target-libquadmath"
 568     ;;
 569   # libquadmath is unused on AIX and libquadmath build process use of
 570   # LD_LIBRARY_PATH can break AIX bootstrap.
 571   powerpc-*-aix* | rs6000-*-aix*)
 572     noconfigdirs="$noconfigdirs target-libquadmath"
 573     ;;
 574 esac
 575
 576 # Disable libssp for some systems.
 577 case "${target}" in
 578   avr-*-*)
 579     # No hosted I/O support.
 580     noconfigdirs="$noconfigdirs target-libssp"
 581     ;;
 582   bpf-*-*)
 583     noconfigdirs="$noconfigdirs target-libssp"
 584     ;;
 585   powerpc-*-aix* | rs6000-*-aix*)
 586     noconfigdirs="$noconfigdirs target-libssp"
 587     ;;
 588   pru-*-*)
 589     # No hosted I/O support.
 590     noconfigdirs="$noconfigdirs target-libssp"
 591     ;;
 592   rl78-*-*)
 593     # libssp uses a misaligned load to trigger a fault, but the RL78
 594     # doesn't fault for those - instead, it gives a build-time error
 595     # for explicit misaligned loads.
 596     noconfigdirs="$noconfigdirs target-libssp"
 597     ;;
 598   visium-*-*)
 599     # No hosted I/O support.
 600     noconfigdirs="$noconfigdirs target-libssp"
 601     ;;
 602 esac
 603
 604 # Disable libstdc++-v3 for some systems.
 605 # Allow user to override this if they pass --enable-libstdcxx
 606 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 607   case "${target}" in
 608     *-*-vxworks*)
 609       # VxWorks uses the Dinkumware C++ library.
 610       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 611       ;;
 612     amdgcn*-*-*)
 613       # Not ported/fails to build when using newlib.
 614       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 615       ;;
 616     arm*-wince-pe*)
 617       # the C++ libraries don't build on top of CE's C libraries
 618       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 619       ;;
 620     avr-*-*)
 621       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 622       ;;
 623     bpf-*-*)
 624       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 625       ;;
 626     ft32-*-*)
 627       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 628       ;;
 629   esac
 630 fi
 631
 632 # Disable C++ on systems where it is known to not work.
 633 # For testing, you can override this with --enable-languages=c++.
 634 case ,${enable_languages}, in
 635   *,c++,*)
 636     ;;
 637   *)
 638       case "${target}" in
 639         bpf-*-*)
 640           unsupported_languages="$unsupported_languages c++"
 641           ;;
 642       esac
 643       ;;
 644 esac
 645
 646 # Disable Objc on systems where it is known to not work.
 647 # For testing, you can override this with --enable-languages=objc.
 648 case ,${enable_languages}, in
 649   *,objc,*)
 650     ;;
 651   *)
 652       case "${target}" in
 653         bpf-*-*)
 654           unsupported_languages="$unsupported_languages objc"
 655           ;;
 656       esac
 657       ;;
 658 esac
 659
 660 # Disable D on systems where it is known to not work.
 661 # For testing, you can override this with --enable-languages=d.
 662 case ,${enable_languages}, in
 663   *,d,*)
 664     ;;
 665   *)
 666     case "${target}" in
 667       bpf-*-*)
 668         unsupported_languages="$unsupported_languages d"
 669         ;;
 670     esac
 671     ;;
 672 esac
 673
 674 # Disable libphobos on unsupported systems.
 675 # For testing, you can override this with --enable-libphobos.
 676 if test -d ${srcdir}/libphobos; then
 677     if test x$enable_libphobos = x; then
 678         AC_MSG_CHECKING([for libphobos support])
 679         if (srcdir=${srcdir}/libphobos; \
 680                 . ${srcdir}/configure.tgt; \
 681                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 682         then
 683             AC_MSG_RESULT([no])
 684             noconfigdirs="$noconfigdirs target-libphobos"
 685         else
 686             AC_MSG_RESULT([yes])
 687         fi
 688     fi
 689 fi
 690
 691 # Disable Fortran for some systems.
 692 case "${target}" in
 693   mmix-*-*)
 694     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 695     unsupported_languages="$unsupported_languages fortran"
 696     ;;
 697   bpf-*-*)
 698     unsupported_languages="$unsupported_languages fortran"
 699     ;;
 700 esac
 701
 702 # Disable libffi for some systems.
 703 case "${target}" in
 704   powerpc-*-darwin*)
 705     ;;
 706   i[[3456789]]86-*-darwin*)
 707     ;;
 708   x86_64-*-darwin[[912]]*)
 709     ;;
 710   *-*-darwin*)
 711     noconfigdirs="$noconfigdirs target-libffi"
 712     ;;
 713   *-*-netware*)
 714     noconfigdirs="$noconfigdirs target-libffi"
 715     ;;
 716   *-*-phoenix*)
 717     noconfigdirs="$noconfigdirs target-libffi"
 718     ;;
 719   *-*-rtems*)
 720     noconfigdirs="$noconfigdirs target-libffi"
 721     ;;
 722   *-*-tpf*)
 723     noconfigdirs="$noconfigdirs target-libffi"
 724     ;;
 725   *-*-uclinux*)
 726     noconfigdirs="$noconfigdirs target-libffi"
 727     ;;
 728   *-*-vxworks*)
 729     noconfigdirs="$noconfigdirs target-libffi"
 730     ;;
 731   aarch64*-*-freebsd*)
 732     noconfigdirs="$noconfigdirs target-libffi"
 733     ;;
 734   alpha*-*-*vms*)
 735     noconfigdirs="$noconfigdirs target-libffi"
 736     ;;
 737   arm*-*-freebsd*)
 738     noconfigdirs="$noconfigdirs target-libffi"
 739     ;;
 740   arm-wince-pe)
 741     noconfigdirs="$noconfigdirs target-libffi"
 742     ;;
 743   arm*-*-symbianelf*)
 744     noconfigdirs="$noconfigdirs target-libffi"
 745     ;;
 746   bpf-*-*)
 747     noconfigdirs="$noconfigdirs target-libffi"
 748     ;;
 749   cris-*-* | crisv32-*-*)
 750     case "${target}" in
 751       *-*-linux*)
 752         ;;
 753       *) # See PR46792 regarding target-libffi.
 754         noconfigdirs="$noconfigdirs target-libffi";;
 755     esac
 756     ;;
 757   hppa*64*-*-hpux*)
 758     noconfigdirs="$noconfigdirs target-libffi"
 759     ;;
 760   ia64*-*-*vms*)
 761     noconfigdirs="$noconfigdirs target-libffi"
 762     ;;
 763   i[[3456789]]86-w64-mingw*)
 764     noconfigdirs="$noconfigdirs target-libffi"
 765     ;;
 766   i[[3456789]]86-*-mingw*)
 767     noconfigdirs="$noconfigdirs target-libffi"
 768     ;;
 769   x86_64-*-mingw*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772   mmix-*-*)
 773     noconfigdirs="$noconfigdirs target-libffi"
 774     ;;
 775   powerpc-*-aix*)
 776     ;;
 777   rs6000-*-aix*)
 778     ;;
 779   ft32-*-*)
 780     noconfigdirs="$noconfigdirs target-libffi"
 781     ;;
 782   *-*-lynxos*)
 783     noconfigdirs="$noconfigdirs target-libffi"
 784     ;;
 785 esac
 786
 787 # Disable the go frontend on systems where it is known to not work. Please keep
 788 # this in sync with contrib/config-list.mk.
 789 case "${target}" in
 790 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 791     unsupported_languages="$unsupported_languages go"
 792     ;;
 793 esac
 794
 795 # Only allow gdbserver on some systems.
 796 if test -d ${srcdir}/gdbserver; then
 797     if test x$enable_gdbserver = x; then
 798         AC_MSG_CHECKING([for gdbserver support])
 799         if (srcdir=${srcdir}/gdbserver; \
 800                 . ${srcdir}/configure.srv; \
 801                 test -n "$UNSUPPORTED")
 802         then
 803             AC_MSG_RESULT([no])
 804             noconfigdirs="$noconfigdirs gdbserver"
 805         else
 806             AC_MSG_RESULT([yes])
 807         fi
 808     fi
 809 fi
 810
 811 # Disable libgo for some systems where it is known to not work.
 812 # For testing, you can easily override this with --enable-libgo.
 813 if test x$enable_libgo = x; then
 814     case "${target}" in
 815     *-*-darwin*)
 816         # PR 46986
 817         noconfigdirs="$noconfigdirs target-libgo"
 818         ;;
 819     *-*-cygwin* | *-*-mingw*)
 820         noconfigdirs="$noconfigdirs target-libgo"
 821         ;;
 822     bpf-*-*)
 823         noconfigdirs="$noconfigdirs target-libgo"
 824         ;;
 825     esac
 826 fi
 827
 828 # Default libgloss CPU subdirectory.
 829 libgloss_dir="$target_cpu"
 830
 831 case "${target}" in
 832   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 833     libgloss_dir=wince
 834     ;;
 835   aarch64*-*-* )
 836     libgloss_dir=aarch64
 837     ;;
 838   arm*-*-*)
 839     libgloss_dir=arm
 840     ;;
 841   cris-*-* | crisv32-*-*)
 842     libgloss_dir=cris
 843     ;;
 844   hppa*-*-*)
 845     libgloss_dir=pa
 846     ;;
 847   i[[3456789]]86-*-*)
 848     libgloss_dir=i386
 849     ;;
 850   loongarch*-*-*)
 851     libgloss_dir=loongarch
 852     ;;
 853   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 854     libgloss_dir=m68hc11
 855     ;;
 856   m68*-*-* | fido-*-*)
 857     libgloss_dir=m68k
 858     ;;
 859   mips*-*-*)
 860     libgloss_dir=mips
 861     ;;
 862   powerpc*-*-*)
 863     libgloss_dir=rs6000
 864     ;;
 865   pru-*-*)
 866     libgloss_dir=pru
 867     ;;
 868   sparc*-*-*)
 869     libgloss_dir=sparc
 870     ;;
 871 esac
 872
 873 # Disable newlib and libgloss for various target OSes.
 874 case "${target}" in
 875   alpha*-dec-osf*)
 876     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 877     ;;
 878   i[[3456789]]86-*-linux*)
 879     # This section makes it possible to build newlib natively on linux.
 880     # If we are using a cross compiler then don't configure newlib.
 881     if test x${is_cross_compiler} != xno ; then
 882       noconfigdirs="$noconfigdirs target-newlib"
 883     fi
 884     noconfigdirs="$noconfigdirs target-libgloss"
 885     # If we are not using a cross compiler, do configure newlib.
 886     # Note however, that newlib will only be configured in this situation
 887     # if the --with-newlib option has been given, because otherwise
 888     # 'target-newlib' will appear in skipdirs.
 889     ;;
 890   i[[3456789]]86-*-rdos*)
 891     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 892     ;;
 893   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 894     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 895     ;;
 896   sparc-*-sunos4*)
 897     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 898     ;;
 899   bpf-*-*)
 900     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 901     ;;
 902   *-*-aix*)
 903     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 904     ;;
 905   *-*-beos*)
 906     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 907     ;;
 908   *-*-chorusos)
 909     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 910     ;;
 911   *-*-dragonfly*)
 912     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 913     ;;
 914   *-*-freebsd*)
 915     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 916     ;;
 917   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 918     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 919     ;;
 920   *-*-lynxos*)
 921     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 922     ;;
 923   *-*-mingw*)
 924     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 925     ;;
 926   *-*-netbsd*)
 927     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 928     ;;
 929   *-*-netware*)
 930     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 931     ;;
 932   *-*-tpf*)
 933     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 934     ;;
 935   *-*-uclinux*)
 936     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 937     ;;
 938   *-*-vxworks*)
 939     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 940     ;;
 941 esac
 942
 943 case "${target}" in
 944   *-*-chorusos)
 945     ;;
 946   aarch64-*-darwin*)
 947     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 948     noconfigdirs="$noconfigdirs sim target-rda"
 949     ;;
 950   amdgcn*-*-*)
 951     ;;
 952   arm-*-darwin*)
 953     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 954     noconfigdirs="$noconfigdirs sim target-rda"
 955     ;;
 956   powerpc-*-darwin*)
 957     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 958     noconfigdirs="$noconfigdirs sim target-rda"
 959     ;;
 960   i[[3456789]]86-*-darwin*)
 961     noconfigdirs="$noconfigdirs ld gprof"
 962     noconfigdirs="$noconfigdirs sim target-rda"
 963     ;;
 964   x86_64-*-darwin[[912]]*)
 965     noconfigdirs="$noconfigdirs ld gas gprof"
 966     noconfigdirs="$noconfigdirs sim target-rda"
 967     ;;
 968   *-*-darwin*)
 969     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 970     noconfigdirs="$noconfigdirs sim target-rda"
 971     ;;
 972   *-*-dragonfly*)
 973     ;;
 974   *-*-freebsd*)
 975     if test "x$with_gmp" = x \
 976         && ! test -d ${srcdir}/gmp \
 977         && test -f /usr/local/include/gmp.h; then
 978       with_gmp=/usr/local
 979     fi
 980     ;;
 981   *-*-kaos*)
 982     # Remove unsupported stuff on all kaOS configurations.
 983     noconfigdirs="$noconfigdirs target-libgloss"
 984     ;;
 985   *-*-netbsd*)
 986     ;;
 987   *-*-netware*)
 988     ;;
 989   *-*-phoenix*)
 990     noconfigdirs="$noconfigdirs target-libgloss"
 991     ;;
 992   *-*-rtems*)
 993     noconfigdirs="$noconfigdirs target-libgloss"
 994     ;;
 995     # The tpf target doesn't support gdb yet.
 996   *-*-tpf*)
 997     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 998     ;;
 999   *-*-uclinux*)
1000     noconfigdirs="$noconfigdirs target-rda"
1001     ;;
1002   *-*-vxworks*)
1003     ;;
1004   alpha*-dec-osf*)
1005     # ld works, but does not support shared libraries.
1006     # gas doesn't generate exception information.
1007     noconfigdirs="$noconfigdirs gas ld"
1008     ;;
1009   alpha*-*-*vms*)
1010     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1011     ;;
1012   alpha*-*-*)
1013     # newlib is not 64 bit ready
1014     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1015     ;;
1016   bpf-*-*)
1017     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1018     ;;
1019   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1020     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1021     ;;
1022   arc*-*-*)
1023     noconfigdirs="$noconfigdirs sim"
1024     ;;
1025   arm-*-pe*)
1026     noconfigdirs="$noconfigdirs target-libgloss"
1027     ;;
1028   arm-*-riscix*)
1029     noconfigdirs="$noconfigdirs ld target-libgloss"
1030     ;;
1031   avr-*-*)
1032     if test x${with_avrlibc} != xno; then
1033       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1034     fi
1035     ;;
1036   c4x-*-* | tic4x-*-*)
1037     noconfigdirs="$noconfigdirs target-libgloss"
1038     ;;
1039   tic54x-*-*)
1040     noconfigdirs="$noconfigdirs target-libgloss gdb"
1041     ;;
1042   d10v-*-*)
1043     noconfigdirs="$noconfigdirs target-libgloss"
1044     ;;
1045   d30v-*-*)
1046     noconfigdirs="$noconfigdirs gdb"
1047     ;;
1048   fr30-*-elf*)
1049     noconfigdirs="$noconfigdirs gdb"
1050     ;;
1051   ft32-*-*)
1052     noconfigdirs="$noconfigdirs target-rda gprof"
1053     ;;
1054   moxie-*-*)
1055     noconfigdirs="$noconfigdirs"
1056     ;;
1057   h8300*-*-*)
1058     noconfigdirs="$noconfigdirs target-libgloss"
1059     ;;
1060   h8500-*-*)
1061     noconfigdirs="$noconfigdirs target-libgloss"
1062     ;;
1063   hppa*64*-*-hpux*)
1064     noconfigdirs="$noconfigdirs gdb"
1065     ;;
1066   hppa*64*-*-linux*)
1067     ;;
1068   hppa*-*-linux*)
1069     ;;
1070   hppa*-*-*elf* | \
1071   hppa*-*-lites* | \
1072   hppa*-*-openbsd* | \
1073   hppa*64*-*-*)
1074     ;;
1075   hppa*-*-pro*)
1076     ;;
1077   hppa*-*-*)
1078     noconfigdirs="$noconfigdirs ld"
1079     ;;
1080   i960-*-*)
1081     noconfigdirs="$noconfigdirs gdb"
1082     ;;
1083   ia64*-*-elf*)
1084     # No gdb support yet.
1085     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1086     ;;
1087   ia64*-**-hpux*)
1088     # No ld support yet.
1089     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1090     ;;
1091   ia64*-*-*vms*)
1092     # No ld support yet.
1093     noconfigdirs="$noconfigdirs libgui itcl ld"
1094     ;;
1095   i[[3456789]]86-w64-mingw*)
1096     ;;
1097   i[[3456789]]86-*-mingw*)
1098     target_configdirs="$target_configdirs target-winsup"
1099     ;;
1100   *-*-cygwin*)
1101     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1102     noconfigdirs="$noconfigdirs target-libgloss"
1103     # always build newlib if winsup directory is present.
1104     if test -d "$srcdir/winsup/cygwin"; then
1105       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1106     elif test -d "$srcdir/newlib"; then
1107       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1108     fi
1109     ;;
1110   i[[3456789]]86-*-pe)
1111     noconfigdirs="$noconfigdirs target-libgloss"
1112     ;;
1113   i[[3456789]]86-*-sco3.2v5*)
1114     # The linker does not yet know about weak symbols in COFF,
1115     # and is not configured to handle mixed ELF and COFF.
1116     noconfigdirs="$noconfigdirs ld target-libgloss"
1117     ;;
1118   i[[3456789]]86-*-sco*)
1119     noconfigdirs="$noconfigdirs gprof target-libgloss"
1120     ;;
1121   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1122     noconfigdirs="$noconfigdirs target-libgloss"
1123     ;;
1124   i[[3456789]]86-*-sysv4*)
1125     noconfigdirs="$noconfigdirs target-libgloss"
1126     ;;
1127   i[[3456789]]86-*-beos*)
1128     noconfigdirs="$noconfigdirs gdb"
1129     ;;
1130   i[[3456789]]86-*-rdos*)
1131     noconfigdirs="$noconfigdirs gdb"
1132     ;;
1133   mmix-*-*)
1134     noconfigdirs="$noconfigdirs gdb"
1135     ;;
1136   mt-*-*)
1137     noconfigdirs="$noconfigdirs sim"
1138     ;;
1139   nfp-*-*)
1140     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1141     noconfigdirs="$noconfigdirs $target_libraries"
1142     ;;
1143   pdp11-*-*)
1144     noconfigdirs="$noconfigdirs gdb gprof"
1145     ;;
1146   powerpc-*-aix*)
1147     # copied from rs6000-*-* entry
1148     noconfigdirs="$noconfigdirs gprof"
1149     ;;
1150   powerpc*-*-winnt* | powerpc*-*-pe*)
1151     target_configdirs="$target_configdirs target-winsup"
1152     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1153     # always build newlib.
1154     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1155     ;;
1156     # This is temporary until we can link against shared libraries
1157   powerpcle-*-solaris*)
1158     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1159     ;;
1160   powerpc-*-beos*)
1161     noconfigdirs="$noconfigdirs gdb"
1162     ;;
1163   rs6000-*-lynxos*)
1164     noconfigdirs="$noconfigdirs gprof"
1165     ;;
1166   rs6000-*-aix*)
1167     noconfigdirs="$noconfigdirs gprof"
1168     ;;
1169   rs6000-*-*)
1170     noconfigdirs="$noconfigdirs gprof"
1171     ;;
1172   m68k-apollo-*)
1173     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1174     ;;
1175   microblaze*)
1176     noconfigdirs="$noconfigdirs gprof"
1177     ;;
1178   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1179     if test x$with_newlib = xyes; then
1180       noconfigdirs="$noconfigdirs gprof"
1181     fi
1182     ;;
1183   mips*-*-irix5*)
1184     noconfigdirs="$noconfigdirs gprof target-libgloss"
1185     ;;
1186   mips*-*-irix6*)
1187     noconfigdirs="$noconfigdirs gprof target-libgloss"
1188     ;;
1189   mips*-*-bsd*)
1190     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1191     ;;
1192   mips*-*-linux*)
1193     ;;
1194   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1195   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1196     noconfigdirs="$noconfigdirs ld gas gprof"
1197     ;;
1198   mips*-*-*)
1199     noconfigdirs="$noconfigdirs gprof"
1200     ;;
1201   nvptx*-*-*)
1202     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1203     ;;
1204   sh-*-*)
1205     case "${target}" in
1206       sh*-*-elf)
1207          ;;
1208       *)
1209          noconfigdirs="$noconfigdirs target-libgloss" ;;
1210     esac
1211     ;;
1212   sparc-*-sunos4*)
1213     if test x${is_cross_compiler} = xno ; then
1214            use_gnu_ld=no
1215     fi
1216     ;;
1217   tic6x-*-*)
1218     noconfigdirs="$noconfigdirs sim"
1219     ;;
1220   v810-*-*)
1221     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1222     ;;
1223   vax-*-*)
1224     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1225     ;;
1226   wasm32-*-*)
1227     noconfigdirs="$noconfigdirs ld"
1228     ;;
1229   loongarch*-*-linux*)
1230     ;;
1231   loongarch*-*-*)
1232     noconfigdirs="$noconfigdirs gprof"
1233     ;;
1234 esac
1235
1236 # If we aren't building newlib, then don't build libgloss, since libgloss
1237 # depends upon some newlib header files.
1238 case "${noconfigdirs}" in
1239   *target-libgloss*) ;;
1240   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1241 esac
1242
1243 # Work in distributions that contain no compiler tools, like Autoconf.
1244 host_makefile_frag=/dev/null
1245 if test -d ${srcdir}/config ; then
1246 case "${host}" in
1247   i[[3456789]]86-*-msdosdjgpp*)
1248     host_makefile_frag="config/mh-djgpp"
1249     ;;
1250   *-cygwin*)
1251     ACX_CHECK_CYGWIN_CAT_WORKS
1252     host_makefile_frag="config/mh-cygwin"
1253     ;;
1254   *-mingw*)
1255     host_makefile_frag="config/mh-mingw"
1256     ;;
1257   alpha*-linux*)
1258     host_makefile_frag="config/mh-alpha-linux"
1259     ;;
1260   hppa*-hp-hpux*)
1261     host_makefile_frag="config/mh-pa"
1262     ;;
1263   hppa*-*)
1264     host_makefile_frag="config/mh-pa"
1265     ;;
1266   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1267     host_makefile_frag="config/mh-darwin"
1268     ;;
1269   powerpc-*-aix*)
1270     host_makefile_frag="config/mh-ppc-aix"
1271     ;;
1272   rs6000-*-aix*)
1273     host_makefile_frag="config/mh-ppc-aix"
1274     ;;
1275 esac
1276 fi
1277
1278 if test "${build}" != "${host}" ; then
1279   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1280   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1281   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1282   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1283   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1284   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1285   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1286   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1287   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1288   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1289   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1290   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1291   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1292   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1293   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1294 else
1295   AR_FOR_BUILD="\$(AR)"
1296   AS_FOR_BUILD="\$(AS)"
1297   CC_FOR_BUILD="\$(CC)"
1298   CXX_FOR_BUILD="\$(CXX)"
1299   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1300   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1301   GOC_FOR_BUILD="\$(GOC)"
1302   GDC_FOR_BUILD="\$(GDC)"
1303   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1304   LD_FOR_BUILD="\$(LD)"
1305   NM_FOR_BUILD="\$(NM)"
1306   RANLIB_FOR_BUILD="\$(RANLIB)"
1307   WINDRES_FOR_BUILD="\$(WINDRES)"
1308   WINDMC_FOR_BUILD="\$(WINDMC)"
1309 fi
1310
1311 AC_PROG_CC_C99
1312 AC_PROG_CXX
1313
1314 # We must set the default linker to the linker used by gcc for the correct
1315 # operation of libtool.  If LD is not defined and we are using gcc, try to
1316 # set the LD default to the ld used by gcc.
1317 if test -z "$LD"; then
1318   if test "$GCC" = yes; then
1319     case $build in
1320     *-*-mingw*)
1321       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1322     *)
1323       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1324     esac
1325     case $gcc_prog_ld in
1326     # Accept absolute paths.
1327     [[\\/]* | [A-Za-z]:[\\/]*)]
1328       LD="$gcc_prog_ld" ;;
1329     esac
1330   fi
1331 fi
1332
1333 # Check whether -static-libstdc++ -static-libgcc is supported.
1334 have_static_libs=no
1335 if test "$GCC" = yes; then
1336   saved_LDFLAGS="$LDFLAGS"
1337
1338   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1339   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1340   AC_LANG_PUSH(C++)
1341   AC_LINK_IFELSE([AC_LANG_SOURCE([
1342 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1343 #error -static-libstdc++ not implemented
1344 #endif
1345 int main() {}])],
1346     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1347     [AC_MSG_RESULT([no])])
1348   AC_LANG_POP(C++)
1349
1350   LDFLAGS="$saved_LDFLAGS"
1351 fi
1352
1353 ACX_PROG_GNAT
1354 ACX_PROG_GDC
1355 ACX_PROG_CMP_IGNORE_INITIAL
1356
1357 AC_ARG_ENABLE([bootstrap],
1358 [AS_HELP_STRING([--enable-bootstrap],
1359                 [enable bootstrapping @<:@yes if native build@:>@])],,
1360 enable_bootstrap=default)
1361
1362 # Issue errors and warnings for invalid/strange bootstrap combinations.
1363 if test -r $srcdir/gcc/configure; then
1364   have_compiler=yes
1365 else
1366   have_compiler=no
1367 fi
1368
1369 case "$have_compiler:$host:$target:$enable_bootstrap" in
1370   *:*:*:no) ;;
1371
1372   # Default behavior.  Enable bootstrap if we have a compiler
1373   # and we are in a native configuration.
1374   yes:$build:$build:default)
1375     enable_bootstrap=yes ;;
1376
1377   *:*:*:default)
1378     enable_bootstrap=no ;;
1379
1380   # We have a compiler and we are in a native configuration, bootstrap is ok
1381   yes:$build:$build:yes)
1382     ;;
1383
1384   # Other configurations, but we have a compiler.  Assume the user knows
1385   # what he's doing.
1386   yes:*:*:yes)
1387     AC_MSG_WARN([trying to bootstrap a cross compiler])
1388     ;;
1389
1390   # No compiler: if they passed --enable-bootstrap explicitly, fail
1391   no:*:*:yes)
1392     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1393
1394   # Fail if wrong command line
1395   *)
1396     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1397     ;;
1398 esac
1399
1400 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1401 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1402 # require C++11 (or higher).
1403 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1404   CXX="$CXX -std=c++11"
1405 elif test "$have_compiler" = yes; then
1406   AX_CXX_COMPILE_STDCXX(11)
1407
1408   if test "${build}" != "${host}"; then
1409     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1410   fi
1411 fi
1412
1413 AC_ARG_ENABLE([pgo-build],
1414 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1415                 [enable the PGO build])],
1416 [enable_pgo_build=$enableval],
1417 [enable_pgo_build=no])
1418
1419 # Issue errors and warnings for invalid/strange PGO build combinations.
1420 case "$have_compiler:$host:$target:$enable_pgo_build" in
1421   *:*:*:no) ;;
1422
1423   # Allow the PGO build only if we aren't building a compiler and
1424   # we are in a native configuration.
1425   no:$build:$build:yes | no:$build:$build:lto) ;;
1426
1427   # Disallow the PGO bootstrap if we are building a compiler.
1428   yes:*:*:yes | yes:*:*:lto)
1429     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1430
1431   *)
1432     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1433     ;;
1434 esac
1435
1436 if test "$enable_pgo_build" != "no"; then
1437   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1438   old_CFLAGS="$CFLAGS"
1439   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1440   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1441   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1442                     [PGO_BUILD_GEN_CFLAGS=])
1443   CFLAGS="$old_CFLAGS"
1444   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1445     AC_MSG_RESULT([yes])
1446     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1447   else
1448     AC_MSG_RESULT([no])
1449     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1450   fi
1451
1452   if test "$enable_pgo_build" = "lto"; then
1453     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1454     old_CFLAGS="$CFLAGS"
1455     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1456     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1457     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1458                       [PGO_BUILD_LTO_CFLAGS=])
1459     CFLAGS="$old_CFLAGS"
1460     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1461       AC_MSG_RESULT([yes])
1462     else
1463       AC_MSG_RESULT([no])
1464       AC_MSG_WARN([LTO is disabled for the PGO build])
1465     fi
1466   fi
1467 fi
1468 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1469 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1470 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1471
1472 # Used for setting $lt_cv_objdir
1473 _LT_CHECK_OBJDIR
1474
1475 # Check for GMP, MPFR and MPC
1476 gmplibs="-lmpc -lmpfr -lgmp"
1477 gmpinc=
1478 have_gmp=no
1479
1480 # Specify a location for mpc
1481 # check for this first so it ends up on the link line before mpfr.
1482 AC_ARG_WITH(mpc,
1483 [AS_HELP_STRING([--with-mpc=PATH],
1484                 [specify prefix directory for installed MPC package.
1485                  Equivalent to --with-mpc-include=PATH/include
1486                  plus --with-mpc-lib=PATH/lib])])
1487 AC_ARG_WITH(mpc-include,
1488 [AS_HELP_STRING([--with-mpc-include=PATH],
1489                 [specify directory for installed MPC include files])])
1490 AC_ARG_WITH(mpc-lib,
1491 [AS_HELP_STRING([--with-mpc-lib=PATH],
1492                 [specify directory for the installed MPC library])])
1493
1494 if test "x$with_mpc" != x; then
1495   gmplibs="-L$with_mpc/lib $gmplibs"
1496   gmpinc="-I$with_mpc/include $gmpinc"
1497 fi
1498 if test "x$with_mpc_include" != x; then
1499   gmpinc="-I$with_mpc_include $gmpinc"
1500 fi
1501 if test "x$with_mpc_lib" != x; then
1502   gmplibs="-L$with_mpc_lib $gmplibs"
1503 fi
1504 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1505   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1506   gmpinc='-I$$s/mpc/src '"$gmpinc"
1507   # Do not test the mpc version.  Assume that it is sufficient, since
1508   # it is in the source tree, and the library has not been built yet
1509   # but it would be included on the link line in the version check below
1510   # hence making the test fail.
1511   have_gmp=yes
1512 fi
1513
1514 # Specify a location for mpfr
1515 # check for this first so it ends up on the link line before gmp.
1516 AC_ARG_WITH(mpfr,
1517 [AS_HELP_STRING([--with-mpfr=PATH],
1518                 [specify prefix directory for installed MPFR package.
1519                  Equivalent to --with-mpfr-include=PATH/include
1520                  plus --with-mpfr-lib=PATH/lib])])
1521 AC_ARG_WITH(mpfr-include,
1522 [AS_HELP_STRING([--with-mpfr-include=PATH],
1523                 [specify directory for installed MPFR include files])])
1524 AC_ARG_WITH(mpfr-lib,
1525 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1526                 [specify directory for the installed MPFR library])])
1527
1528 if test "x$with_mpfr" != x; then
1529   gmplibs="-L$with_mpfr/lib $gmplibs"
1530   gmpinc="-I$with_mpfr/include $gmpinc"
1531 fi
1532 if test "x$with_mpfr_include" != x; then
1533   gmpinc="-I$with_mpfr_include $gmpinc"
1534 fi
1535 if test "x$with_mpfr_lib" != x; then
1536   gmplibs="-L$with_mpfr_lib $gmplibs"
1537 fi
1538 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1539   # MPFR v3.1.0 moved the sources into a src sub-directory.
1540   if ! test -d ${srcdir}/mpfr/src; then
1541     AC_MSG_ERROR([dnl
1542 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1543   fi
1544   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1545   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1546   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1547   # Do not test the mpfr version.  Assume that it is sufficient, since
1548   # it is in the source tree, and the library has not been built yet
1549   # but it would be included on the link line in the version check below
1550   # hence making the test fail.
1551   have_gmp=yes
1552 fi
1553
1554 # Specify a location for gmp
1555 AC_ARG_WITH(gmp,
1556 [AS_HELP_STRING([--with-gmp=PATH],
1557                 [specify prefix directory for the installed GMP package.
1558                  Equivalent to --with-gmp-include=PATH/include
1559                  plus --with-gmp-lib=PATH/lib])])
1560 AC_ARG_WITH(gmp-include,
1561 [AS_HELP_STRING([--with-gmp-include=PATH],
1562                 [specify directory for installed GMP include files])])
1563 AC_ARG_WITH(gmp-lib,
1564 [AS_HELP_STRING([--with-gmp-lib=PATH],
1565                 [specify directory for the installed GMP library])])
1566
1567
1568 if test "x$with_gmp" != x; then
1569   gmplibs="-L$with_gmp/lib $gmplibs"
1570   gmpinc="-I$with_gmp/include $gmpinc"
1571 fi
1572 if test "x$with_gmp_include" != x; then
1573   gmpinc="-I$with_gmp_include $gmpinc"
1574 fi
1575 if test "x$with_gmp_lib" != x; then
1576   gmplibs="-L$with_gmp_lib $gmplibs"
1577 fi
1578 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1579   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1580   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1581   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1582   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1583   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1584   # Do not test the gmp version.  Assume that it is sufficient, since
1585   # it is in the source tree, and the library has not been built yet
1586   # but it would be included on the link line in the version check below
1587   # hence making the test fail.
1588   have_gmp=yes
1589 fi
1590
1591 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1592   have_gmp=yes
1593   saved_CFLAGS="$CFLAGS"
1594   CFLAGS="$CFLAGS $gmpinc"
1595   # Check for the recommended and required versions of GMP.
1596   AC_MSG_CHECKING([for the correct version of gmp.h])
1597   AC_TRY_COMPILE([#include "gmp.h"],[
1598   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1599   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1600   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1601   choke me
1602   #endif
1603   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1604   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1605   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1606   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1607   choke me
1608   #endif
1609   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1610    [AC_MSG_RESULT([no]); have_gmp=no])
1611
1612   # If we have GMP, check the MPFR version.
1613   if test x"$have_gmp" = xyes; then
1614     # Check for the recommended and required versions of MPFR.
1615     AC_MSG_CHECKING([for the correct version of mpfr.h])
1616     AC_TRY_COMPILE([#include <gmp.h>
1617     #include <mpfr.h>],[
1618     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1619     choke me
1620     #endif
1621     ], [AC_TRY_COMPILE([#include <gmp.h>
1622     #include <mpfr.h>],[
1623     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1624     choke me
1625     #endif
1626     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1627      [AC_MSG_RESULT([no]); have_gmp=no])
1628   fi
1629
1630   # Check for the MPC header version.
1631   if test x"$have_gmp" = xyes ; then
1632     # Check for the recommended and required versions of MPC.
1633     AC_MSG_CHECKING([for the correct version of mpc.h])
1634     AC_TRY_COMPILE([#include <mpc.h>],[
1635     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1636     choke me
1637     #endif
1638     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1639     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1640     choke me
1641     #endif
1642     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1643      [AC_MSG_RESULT([no]); have_gmp=no])
1644   fi
1645
1646   # Now check the MPFR library.
1647   if test x"$have_gmp" = xyes; then
1648     saved_LIBS="$LIBS"
1649     LIBS="$LIBS $gmplibs"
1650     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1651     AC_TRY_LINK([#include <mpc.h>],[
1652     mpfr_t n;
1653     mpfr_t x;
1654     mpc_t c;
1655     int t;
1656     mpfr_init (n);
1657     mpfr_init (x);
1658     mpfr_atan2 (n, n, x, MPFR_RNDN);
1659     mpfr_erfc (n, x, MPFR_RNDN);
1660     mpfr_subnormalize (x, t, MPFR_RNDN);
1661     mpfr_clear(n);
1662     mpfr_clear(x);
1663     mpc_init2 (c, 53);
1664     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1665     mpc_cosh (c, c, MPC_RNDNN);
1666     mpc_pow (c, c, c, MPC_RNDNN);
1667     mpc_acosh (c, c, MPC_RNDNN);
1668     mpc_clear (c);
1669     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1670     LIBS="$saved_LIBS"
1671   fi
1672
1673   CFLAGS="$saved_CFLAGS"
1674
1675 # The library versions listed in the error message below should match
1676 # the HARD-minimums enforced above.
1677   if test x$have_gmp != xyes; then
1678     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1679 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1680 their locations.  Source code for these libraries can be found at
1681 their respective hosting sites as well as at
1682 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1683 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1684 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1685 make sure that you have installed both the libraries and the header
1686 files.  They may be located in separate packages.])
1687   fi
1688 fi
1689
1690 # Flags needed for both GMP, MPFR and/or MPC.
1691 AC_SUBST(gmplibs)
1692 AC_SUBST(gmpinc)
1693 AC_SUBST(extra_mpfr_configure_flags)
1694 AC_SUBST(extra_mpc_gmp_configure_flags)
1695 AC_SUBST(extra_mpc_mpfr_configure_flags)
1696 AC_SUBST(extra_isl_gmp_configure_flags)
1697
1698 # Libraries to use for stage1 or when not bootstrapping.
1699 AC_ARG_WITH(stage1-libs,
1700 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1701 [if test "$withval" = "no" -o "$withval" = "yes"; then
1702    stage1_libs=
1703  else
1704    stage1_libs=$withval
1705  fi],
1706 [stage1_libs=])
1707 AC_SUBST(stage1_libs)
1708
1709 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1710 # default is yes if gcc is being built; no otherwise.  The reason for
1711 # this default is that gdb is sometimes linked against GNU Source
1712 # Highlight, which is a shared library that uses C++ exceptions.  In
1713 # this case, -static-libstdc++ will cause crashes.
1714 AC_ARG_WITH(static-standard-libraries,
1715 [AS_HELP_STRING([--with-static-standard-libraries],
1716                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1717 [], [with_static_standard_libraries=auto])
1718 if test "$with_static_standard_libraries" = auto; then
1719   with_static_standard_libraries=$have_compiler
1720 fi
1721
1722 # Linker flags to use for stage1 or when not bootstrapping.
1723 AC_ARG_WITH(stage1-ldflags,
1724 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1725 [if test "$withval" = "no" -o "$withval" = "yes"; then
1726    stage1_ldflags=
1727  else
1728    stage1_ldflags=$withval
1729  fi],
1730 [stage1_ldflags=
1731  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1732  # if supported.  But if the user explicitly specified the libraries to use,
1733  # trust that they are doing what they want.
1734  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1735      -a "$have_static_libs" = yes; then
1736    stage1_ldflags="-static-libstdc++ -static-libgcc"
1737  fi])
1738 AC_SUBST(stage1_ldflags)
1739
1740 # Libraries to use for stage2 and later builds.
1741 AC_ARG_WITH(boot-libs,
1742 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1743 [if test "$withval" = "no" -o "$withval" = "yes"; then
1744    poststage1_libs=
1745  else
1746    poststage1_libs=$withval
1747  fi],
1748 [poststage1_libs=])
1749 AC_SUBST(poststage1_libs)
1750
1751 # Linker flags to use for stage2 and later builds.
1752 AC_ARG_WITH(boot-ldflags,
1753 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1754                 [linker flags for stage2 and later])],
1755 [if test "$withval" = "no" -o "$withval" = "yes"; then
1756    poststage1_ldflags=
1757  else
1758    poststage1_ldflags=$withval
1759  fi],
1760 [poststage1_ldflags=
1761  # In stages 2 and 3, default to linking libstdc++ and libgcc
1762  # statically.  But if the user explicitly specified the libraries to
1763  # use, trust that they are doing what they want.
1764  if test "$poststage1_libs" = ""; then
1765    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1766  fi])
1767 AC_SUBST(poststage1_ldflags)
1768
1769 # GCC GRAPHITE dependency isl.
1770 # Basic setup is inlined here, actual checks are in config/isl.m4
1771
1772 AC_ARG_WITH(isl,
1773   [AS_HELP_STRING(
1774    [--with-isl=PATH],
1775    [Specify prefix directory for the installed isl package.
1776     Equivalent to --with-isl-include=PATH/include
1777     plus --with-isl-lib=PATH/lib])])
1778
1779 # Treat --without-isl as a request to disable
1780 # GRAPHITE support and skip all following checks.
1781 if test "x$with_isl" != "xno"; then
1782   # Check for isl
1783   dnl Provide configure switches and initialize islinc & isllibs
1784   dnl with user input.
1785   ISL_INIT_FLAGS
1786   dnl The versions of isl that work for Graphite
1787   ISL_CHECK_VERSION()
1788   dnl Only execute fail-action, if isl has been requested.
1789   ISL_IF_FAILED([
1790     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1791 fi
1792
1793 # If the isl check failed, disable builds of in-tree variant of isl
1794 if test "x$with_isl" = xno ||
1795    test "x$gcc_cv_isl" = xno; then
1796   noconfigdirs="$noconfigdirs isl"
1797   islinc=
1798 fi
1799
1800 AC_SUBST(isllibs)
1801 AC_SUBST(islinc)
1802
1803 # Check for LTO support.
1804 AC_ARG_ENABLE(lto,
1805 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1806 enable_lto=$enableval,
1807 enable_lto=yes; default_enable_lto=yes)
1808
1809 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1810   build_lto_plugin=yes
1811 ],[if test x"$default_enable_lto" = x"yes" ; then
1812     case $target in
1813       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1814       # On other non-ELF platforms, LTO has yet to be validated.
1815       *) enable_lto=no ;;
1816     esac
1817   else
1818   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1819   # It would also be nice to check the binutils support, but we don't
1820   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1821   # warn during gcc/ subconfigure; unless you're bootstrapping with
1822   # -flto it won't be needed until after installation anyway.
1823     case $target in
1824       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1825       *) if test x"$enable_lto" = x"yes"; then
1826         AC_MSG_ERROR([LTO support is not enabled for this target.])
1827         fi
1828       ;;
1829     esac
1830   fi
1831   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1832   # Build it unless LTO was explicitly disabled.
1833   case $target in
1834     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1835     *) ;;
1836   esac
1837 ])
1838
1839 AC_ARG_ENABLE(linker-plugin-configure-flags,
1840   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1841     [additional flags for configuring linker plugins @<:@none@:>@])],
1842   extra_linker_plugin_configure_flags=$enableval,
1843   extra_linker_plugin_configure_flags=)
1844 AC_SUBST(extra_linker_plugin_configure_flags)
1845 AC_ARG_ENABLE(linker-plugin-flags,
1846   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1847     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1848   extra_linker_plugin_flags=$enableval,
1849   extra_linker_plugin_flags=)
1850 AC_SUBST(extra_linker_plugin_flags)
1851
1852 # Enable --enable-host-shared.
1853 # Checked early to determine whether jit is an 'all' language
1854 AC_ARG_ENABLE(host-shared,
1855 [AS_HELP_STRING([--enable-host-shared],
1856                 [build host code as shared libraries])],
1857 [host_shared=$enableval
1858  case $host in
1859    x86_64-*-darwin* | aarch64-*-darwin*)
1860      if test x$host_shared != xyes ; then
1861        # PIC is the default, and actually cannot be switched off.
1862        echo configure.ac: warning: PIC code is required for the configured target, host-shared setting ignored. 1>&2
1863        host_shared=yes
1864      fi ;;
1865   *) ;;
1866  esac],
1867 [case $host in
1868   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
1869   *) host_shared=no ;;
1870  esac])
1871
1872 AC_SUBST(host_shared)
1873
1874 # If we are building PIC/PIE host executables, and we are building dependent
1875 # libs (e.g. GMP) in-tree those libs need to be configured to generate PIC
1876 # code.
1877 host_libs_picflag=
1878 if test "$host_shared" = "yes";then
1879 host_libs_picflag='--with-pic'
1880 fi
1881 AC_SUBST(host_libs_picflag)
1882
1883 # By default, C and C++ are the only stage 1 languages.
1884 stage1_languages=,c,
1885
1886 # Target libraries that we bootstrap.
1887 bootstrap_target_libs=,target-libgcc,
1888
1889 # Figure out what language subdirectories are present.
1890 # Look if the user specified --enable-languages="..."; if not, use
1891 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1892 # go away some day.
1893 # NB:  embedded tabs in this IF block -- do not untabify
1894 if test -d ${srcdir}/gcc; then
1895   if test x"${enable_languages+set}" != xset; then
1896     if test x"${LANGUAGES+set}" = xset; then
1897       enable_languages="${LANGUAGES}"
1898         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1899     else
1900       enable_languages=default
1901     fi
1902   else
1903     if test x"${enable_languages}" = x ||
1904        test x"${enable_languages}" = xyes;
1905        then
1906       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1907       exit 1
1908     fi
1909   fi
1910   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1911
1912   # 'f95' is the old name for the 'fortran' language. We issue a warning
1913   # and make the substitution.
1914   case ,${enable_languages}, in
1915     *,f95,*)
1916       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1917       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1918       ;;
1919   esac
1920
1921   # If bootstrapping, C++ must be enabled.
1922   case ",$enable_languages,:$enable_bootstrap" in
1923     *,c++,*:*) ;;
1924     *:yes)
1925       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1926         enable_languages="${enable_languages},c++"
1927       else
1928         AC_MSG_ERROR([bootstrapping requires c++ sources])
1929       fi
1930       ;;
1931   esac
1932
1933   # First scan to see if an enabled language requires some other language.
1934   # We assume that a given config-lang.in will list all the language
1935   # front ends it requires, even if some are required indirectly.
1936   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1937     case ${lang_frag} in
1938       ..) ;;
1939       # The odd quoting in the next line works around
1940       # an apparent bug in bash 1.12 on linux.
1941       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1942       *)
1943         # From the config-lang.in, get $language, $lang_requires, and
1944         # $lang_requires_boot_languages.
1945         language=
1946         lang_requires=
1947         lang_requires_boot_languages=
1948         # set srcdir during sourcing lang_frag to the gcc dir.
1949         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1950         # polutes this shell
1951         saved_srcdir=${srcdir}
1952         srcdir=${srcdir}/gcc . ${lang_frag}
1953         srcdir=${saved_srcdir}
1954         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1955           case ,${enable_languages}, in
1956             *,$other,*) ;;
1957             *,default,*) ;;
1958             *,all,*) ;;
1959             *,$language,*)
1960               echo " \`$other' language required by \`$language'; enabling" 1>&2
1961               enable_languages="${enable_languages},${other}"
1962               ;;
1963           esac
1964         done
1965         for other in ${lang_requires_boot_languages} ; do
1966           if test "$other" != "c"; then
1967             case ,${enable_stage1_languages}, in
1968               *,$other,*) ;;
1969               *,default,*) ;;
1970               *,all,*) ;;
1971               *)
1972                 case ,${enable_languages}, in
1973                   *,$language,*)
1974                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1975                     enable_stage1_languages="$enable_stage1_languages,${other}"
1976                     ;;
1977                 esac
1978                 ;;
1979             esac
1980           fi
1981         done
1982         ;;
1983     esac
1984   done
1985
1986   new_enable_languages=,c,
1987
1988   # If LTO is enabled, add the LTO front end.
1989   if test "$enable_lto" = "yes" ; then
1990     case ,${enable_languages}, in
1991       *,lto,*) ;;
1992       *) enable_languages="${enable_languages},lto" ;;
1993     esac
1994     if test "${build_lto_plugin}" = "yes" ; then
1995       configdirs="$configdirs lto-plugin"
1996     fi
1997   fi
1998
1999   # If we're building an offloading compiler, add the LTO front end.
2000   if test x"$enable_as_accelerator_for" != x ; then
2001     case ,${enable_languages}, in
2002       *,lto,*) ;;
2003       *) enable_languages="${enable_languages},lto" ;;
2004     esac
2005   fi
2006
2007   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2008   potential_languages=,c,
2009
2010   enabled_target_libs=
2011   disabled_target_libs=
2012
2013   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2014     case ${lang_frag} in
2015       ..) ;;
2016       # The odd quoting in the next line works around
2017       # an apparent bug in bash 1.12 on linux.
2018       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2019       *)
2020         # From the config-lang.in, get $language, $target_libs,
2021         # $lang_dirs, $boot_language, and $build_by_default
2022         language=
2023         target_libs=
2024         lang_dirs=
2025         subdir_requires=
2026         boot_language=no
2027         build_by_default=yes
2028         # set srcdir during sourcing.  See above about save & restore
2029         saved_srcdir=${srcdir}
2030         srcdir=${srcdir}/gcc . ${lang_frag}
2031         srcdir=${saved_srcdir}
2032         if test x${language} = x; then
2033           echo "${lang_frag} doesn't set \$language." 1>&2
2034           exit 1
2035         fi
2036
2037         if test "$language" = "c++"; then
2038           boot_language=yes
2039         fi
2040
2041         add_this_lang=no
2042         # C is always enabled, so no need to add it again
2043         if test "$language" != "c"; then
2044           case ,${enable_languages}, in
2045             *,${language},*)
2046               # Language was explicitly selected; include it
2047               add_this_lang=yes
2048               ;;
2049             *,all,*)
2050               # All languages are enabled
2051               add_this_lang=all
2052               ;;
2053             *,default,*)
2054               # 'default' was selected, select it if it is a default language
2055               add_this_lang=${build_by_default}
2056               ;;
2057           esac
2058         fi
2059
2060         # Disable languages that need other directories if these aren't available.
2061         for i in $subdir_requires; do
2062           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2063           case ${add_this_lang} in
2064             yes)
2065               # Specifically requested language; tell them.
2066               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2067               ;;
2068             all)
2069               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2070               add_this_lang=unsupported
2071               ;;
2072             *)
2073               # Silently disable.
2074               add_this_lang=unsupported
2075               ;;
2076           esac
2077         done
2078
2079         # Disable Ada if no preexisting GNAT is available.
2080         case ${add_this_lang}:${language}:${have_gnat} in
2081           yes:ada:no)
2082             # Specifically requested language; tell them.
2083             AC_MSG_ERROR([GNAT is required to build $language])
2084             ;;
2085           all:ada:no)
2086             AC_MSG_WARN([GNAT is required to build $language])
2087             add_this_lang=unsupported
2088             ;;
2089           *:ada:no)
2090             # Silently disable.
2091             add_this_lang=unsupported
2092             ;;
2093         esac
2094
2095         # Disable D if no preexisting GDC is available.
2096         case ${add_this_lang}:${language}:${have_gdc} in
2097           yes:d:no)
2098             # Specifically requested language; tell them.
2099             AC_MSG_ERROR([GDC is required to build $language])
2100            ;;
2101           all:d:no)
2102             AC_MSG_WARN([GDC is required to build $language])
2103             add_this_lang=unsupported
2104             ;;
2105           *:d:no)
2106             # Silently disable.
2107             add_this_lang=unsupported
2108             ;;
2109         esac
2110
2111         # Disable jit if -enable-host-shared not specified
2112         # but not if building for Mingw. All code in Windows
2113         # is position independent code (PIC).
2114         case $target in
2115           *mingw*) ;;
2116           *)
2117           case ${add_this_lang}:${language}:${host_shared} in
2118             yes:jit:no)
2119                    # PR jit/64780: explicitly specify --enable-host-shared
2120             AC_MSG_ERROR([
2121 Enabling language "jit" requires --enable-host-shared.
2122
2123 --enable-host-shared typically slows the rest of the compiler down by
2124 a few %, so you must explicitly enable it.
2125
2126 If you want to build both the jit and the regular compiler, it is often
2127 best to do this via two separate configure/builds, in separate
2128 directories, to avoid imposing the performance cost of
2129 --enable-host-shared on the regular compiler.])
2130                     ;;
2131             all:jit:no)
2132               AC_MSG_WARN([--enable-host-shared required to build $language])
2133               add_this_lang=unsupported
2134               ;;
2135             *:jit:no)
2136               # Silently disable.
2137               add_this_lang=unsupported
2138               ;;
2139                 esac
2140           ;;
2141         esac
2142
2143         # Disable a language that is unsupported by the target.
2144         case "${add_this_lang}: $unsupported_languages " in
2145           no:*) ;;
2146           unsupported:*) ;;
2147           *:*" $language "*)
2148             AC_MSG_WARN([${language} not supported for this target])
2149             add_this_lang=unsupported
2150             ;;
2151         esac
2152
2153         case $add_this_lang in
2154           unsupported)
2155             # Remove language-dependent dirs.
2156             disabled_target_libs="$disabled_target_libs $target_libs"
2157             noconfigdirs="$noconfigdirs $lang_dirs"
2158             ;;
2159           no)
2160             # Remove language-dependent dirs; still show language as supported.
2161             disabled_target_libs="$disabled_target_libs $target_libs"
2162             noconfigdirs="$noconfigdirs $lang_dirs"
2163             potential_languages="${potential_languages}${language},"
2164             ;;
2165           all|yes)
2166             new_enable_languages="${new_enable_languages}${language},"
2167             potential_languages="${potential_languages}${language},"
2168             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2169             enabled_target_libs="$enabled_target_libs $target_libs"
2170             case "${boot_language}:,$enable_stage1_languages," in
2171               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2172                 # Add to (comma-separated) list of stage 1 languages.
2173                 case ",$stage1_languages," in
2174                   *,$language,* | ,yes, | ,all,) ;;
2175                   *) stage1_languages="${stage1_languages}${language}," ;;
2176                 esac
2177                 # We need to bootstrap any supporting libraries.
2178                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2179                 ;;
2180             esac
2181             ;;
2182         esac
2183         ;;
2184     esac
2185   done
2186
2187   # Add target libraries which are only needed for disabled languages
2188   # to noconfigdirs.
2189   if test -n "$disabled_target_libs"; then
2190     for dir in $disabled_target_libs; do
2191       case " $enabled_target_libs " in
2192       *" ${dir} "*) ;;
2193       *) noconfigdirs="$noconfigdirs $dir" ;;
2194       esac
2195     done
2196   fi
2197
2198   AC_ARG_ENABLE(stage1-languages,
2199   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2200                   [choose additional languages to build during
2201                   stage1.  Mostly useful for compiler development])],
2202   [case ,${enable_stage1_languages}, in
2203     ,no,|,,)
2204       # Set it to something that will have no effect in the loop below
2205       enable_stage1_languages=c ;;
2206     ,yes,)
2207       enable_stage1_languages=`echo $new_enable_languages | \
2208         sed -e "s/^,//" -e "s/,$//" ` ;;
2209     *,all,*)
2210       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2211         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2212   esac
2213
2214   # Add "good" languages from enable_stage1_languages to stage1_languages,
2215   # while "bad" languages go in missing_languages.  Leave no duplicates.
2216   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2217     case $potential_languages in
2218       *,$i,*)
2219         case $stage1_languages in
2220           *,$i,*) ;;
2221           *) stage1_languages="$stage1_languages$i," ;;
2222         esac ;;
2223       *)
2224         case $missing_languages in
2225           *,$i,*) ;;
2226           *) missing_languages="$missing_languages$i," ;;
2227         esac ;;
2228      esac
2229   done])
2230
2231   # Remove leading/trailing commas that were added for simplicity
2232   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2233   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2234   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2235   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2236
2237   if test "x$missing_languages" != x; then
2238     AC_MSG_ERROR([
2239 The following requested languages could not be built: ${missing_languages}
2240 Supported languages are: ${potential_languages}])
2241   fi
2242   if test "x$new_enable_languages" != "x$enable_languages"; then
2243     echo The following languages will be built: ${new_enable_languages}
2244     enable_languages="$new_enable_languages"
2245   fi
2246
2247   AC_SUBST(stage1_languages)
2248   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2249 fi
2250
2251 # Handle --disable-<component> generically.
2252 for dir in $configdirs $build_configdirs $target_configdirs ; do
2253   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2254   varname=`echo $dirname | sed -e s/+/_/g`
2255   if eval test x\${enable_${varname}} "=" xno ; then
2256     noconfigdirs="$noconfigdirs $dir"
2257   fi
2258 done
2259
2260 # Check for Boehm's garbage collector
2261 AC_ARG_ENABLE(objc-gc,
2262 [AS_HELP_STRING([--enable-objc-gc],
2263                 [enable use of Boehm's garbage collector with the
2264                  GNU Objective-C runtime])])
2265 AC_ARG_WITH([target-bdw-gc],
2266 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2267                 [specify prefix directory for installed bdw-gc package.
2268                  Equivalent to --with-target-bdw-gc-include=PATH/include
2269                  plus --with-target-bdw-gc-lib=PATH/lib])])
2270 AC_ARG_WITH([target-bdw-gc-include],
2271 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2272                 [specify directories for installed bdw-gc include files])])
2273 AC_ARG_WITH([target-bdw-gc-lib],
2274 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2275                 [specify directories for installed bdw-gc library])])
2276
2277 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2278   AC_MSG_CHECKING([for bdw garbage collector])
2279   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2280     dnl no bdw-gw options, assume default locations
2281     AC_MSG_RESULT([using bdw-gc in default locations])
2282   else
2283     dnl bdw-gw options, first error checking, complete checking in libobjc
2284     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2285       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2286     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2287       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2288     else
2289       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2290     fi
2291   fi
2292 esac
2293
2294 # Disable libitm, libsanitizer, libvtv if we're not building C++
2295 case ,${enable_languages}, in
2296   *,c++,*)
2297     # Disable libitm, libsanitizer if we're not building libstdc++
2298     case "${noconfigdirs}" in
2299       *target-libstdc++-v3*)
2300         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2301         ;;
2302       *) ;;
2303     esac
2304     ;;
2305   *)
2306     noconfigdirs="$noconfigdirs target-libitm target-libsanitizer target-libvtv"
2307     ;;
2308 esac
2309
2310 # If gcc/ is not in the source tree then we'll not be building a
2311 # target compiler, assume in that case we don't want to build any
2312 # target libraries or tools.
2313 #
2314 # This was added primarily for the benefit for binutils-gdb who reuse
2315 # this configure script, but don't always have target tools available.
2316 if test ! -d ${srcdir}/gcc; then
2317    skipdirs="${skipdirs} ${target_configdirs}"
2318 fi
2319
2320 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2321 # $build_configdirs and $target_configdirs.
2322 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2323
2324 notsupp=""
2325 for dir in . $skipdirs $noconfigdirs ; do
2326   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2327   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2328     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2329     if test -r $srcdir/$dirname/configure ; then
2330       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2331         true
2332       else
2333         notsupp="$notsupp $dir"
2334       fi
2335     fi
2336   fi
2337   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2338     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2339     if test -r $srcdir/$dirname/configure ; then
2340       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2341         true
2342       else
2343         notsupp="$notsupp $dir"
2344       fi
2345     fi
2346   fi
2347   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2348     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2349     if test -r $srcdir/$dirname/configure ; then
2350       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2351         true
2352       else
2353         notsupp="$notsupp $dir"
2354       fi
2355     fi
2356   fi
2357 done
2358
2359 # Quietly strip out all directories which aren't configurable in this tree.
2360 # This relies on all configurable subdirectories being autoconfiscated, which
2361 # is now the case.
2362 build_configdirs_all="$build_configdirs"
2363 build_configdirs=
2364 for i in ${build_configdirs_all} ; do
2365   j=`echo $i | sed -e s/build-//g`
2366   if test -f ${srcdir}/$j/configure ; then
2367     build_configdirs="${build_configdirs} $i"
2368   fi
2369 done
2370
2371 configdirs_all="$configdirs"
2372 configdirs=
2373 for i in ${configdirs_all} ; do
2374   if test -f ${srcdir}/$i/configure ; then
2375     configdirs="${configdirs} $i"
2376   fi
2377 done
2378
2379 target_configdirs_all="$target_configdirs"
2380 target_configdirs=
2381 for i in ${target_configdirs_all} ; do
2382   j=`echo $i | sed -e s/target-//g`
2383   if test -f ${srcdir}/$j/configure ; then
2384     target_configdirs="${target_configdirs} $i"
2385   fi
2386 done
2387
2388 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2389 # so we have to add it after the preceding checks.
2390 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2391 then
2392   case " $configdirs " in
2393     *" libiberty "*)
2394       # If we can build libiberty, we can also build libiberty-linker-plugin.
2395       configdirs="$configdirs libiberty-linker-plugin"
2396       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2397         --with-libiberty=../libiberty-linker-plugin";;
2398     *)
2399       AC_MSG_ERROR([libiberty missing]);;
2400   esac
2401 fi
2402
2403 # Sometimes we have special requirements for the host libiberty.
2404 extra_host_libiberty_configure_flags=
2405 case " $configdirs " in
2406   *" lto-plugin "* | *" libcc1 "* | *" gdbserver "*)
2407     # When these are to be built as shared libraries, the same applies to
2408     # libiberty.
2409     extra_host_libiberty_configure_flags=--enable-shared
2410     ;;
2411 esac
2412 AC_SUBST(extra_host_libiberty_configure_flags)
2413
2414 # Sometimes we have special requirements for the host zlib.
2415 extra_host_zlib_configure_flags=
2416 case " $configdirs " in
2417   *" bfd "*)
2418     # When bfd is to be built as a shared library, the same applies to
2419     # zlib.
2420     if test "$enable_shared" = "yes"; then
2421       extra_host_zlib_configure_flags=--enable-host-shared
2422     fi
2423     ;;
2424 esac
2425 AC_SUBST(extra_host_zlib_configure_flags)
2426
2427 # Produce a warning message for the subdirs we can't configure.
2428 # This isn't especially interesting in the Cygnus tree, but in the individual
2429 # FSF releases, it's important to let people know when their machine isn't
2430 # supported by the one or two programs in a package.
2431
2432 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2433   # If $appdirs is non-empty, at least one of those directories must still
2434   # be configured, or we error out.  (E.g., if the gas release supports a
2435   # specified target in some subdirs but not the gas subdir, we shouldn't
2436   # pretend that all is well.)
2437   if test -n "$appdirs" ; then
2438     for dir in $appdirs ; do
2439       if test -r $dir/Makefile.in ; then
2440         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2441           appdirs=""
2442           break
2443         fi
2444         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2445           appdirs=""
2446           break
2447         fi
2448       fi
2449     done
2450     if test -n "$appdirs" ; then
2451       echo "*** This configuration is not supported by this package." 1>&2
2452       exit 1
2453     fi
2454   fi
2455   # Okay, some application will build, or we don't care to check.  Still
2456   # notify of subdirs not getting built.
2457   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2458   echo "    ${notsupp}" 1>&2
2459   echo "    (Any other directories should still work fine.)" 1>&2
2460 fi
2461
2462 case "$host" in
2463   *msdosdjgpp*)
2464     enable_gdbtk=no ;;
2465 esac
2466
2467 # To find our prefix, in gcc_cv_tool_prefix.
2468 ACX_TOOL_DIRS
2469
2470 copy_dirs=
2471
2472 AC_ARG_WITH([build-sysroot],
2473   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2474                   [use sysroot as the system root during the build])],
2475   [if test x"$withval" != x ; then
2476      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2477    fi],
2478   [SYSROOT_CFLAGS_FOR_TARGET=])
2479 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2480
2481 AC_ARG_WITH([debug-prefix-map],
2482   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2483                   [map A to B, C to D ... in debug information])],
2484   [if test x"$withval" != x; then
2485      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2486      for debug_map in $withval; do
2487        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2488      done
2489    fi],
2490   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2491 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2492
2493 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2494 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2495 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2496 # We want to ensure that TARGET libraries (which we know are built with
2497 # gcc) are built with "-O2 -g", so include those options when setting
2498 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2499 if test "x$CFLAGS_FOR_TARGET" = x; then
2500   if test "x${is_cross_compiler}" = xyes; then
2501     CFLAGS_FOR_TARGET="-g -O2"
2502   else
2503     CFLAGS_FOR_TARGET=$CFLAGS
2504     case " $CFLAGS " in
2505       *" -O2 "*) ;;
2506       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2507     esac
2508     case " $CFLAGS " in
2509       *" -g "* | *" -g3 "*) ;;
2510       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2511     esac
2512   fi
2513 fi
2514 AC_SUBST(CFLAGS_FOR_TARGET)
2515
2516 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2517   if test "x${is_cross_compiler}" = xyes; then
2518     CXXFLAGS_FOR_TARGET="-g -O2"
2519   else
2520     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2521     case " $CXXFLAGS " in
2522       *" -O2 "*) ;;
2523       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2524     esac
2525     case " $CXXFLAGS " in
2526       *" -g "* | *" -g3 "*) ;;
2527       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2528     esac
2529   fi
2530 fi
2531 AC_SUBST(CXXFLAGS_FOR_TARGET)
2532
2533 AC_SUBST(LDFLAGS_FOR_TARGET)
2534
2535 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2536 # the named directory are copied to $(tooldir)/sys-include.
2537 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2538   if test x${is_cross_compiler} = xno ; then
2539     echo 1>&2 '***' --with-headers is only supported when cross compiling
2540     exit 1
2541   fi
2542   if test x"${with_headers}" != xyes ; then
2543     x=${gcc_cv_tool_prefix}
2544     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2545   fi
2546 fi
2547
2548 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2549 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2550 # are permitted.
2551 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2552   if test x${is_cross_compiler} = xno ; then
2553     echo 1>&2 '***' --with-libs is only supported when cross compiling
2554     exit 1
2555   fi
2556   if test x"${with_libs}" != xyes ; then
2557     # Copy the libraries in reverse order, so that files in the first named
2558     # library override files in subsequent libraries.
2559     x=${gcc_cv_tool_prefix}
2560     for l in ${with_libs}; do
2561       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2562     done
2563   fi
2564 fi
2565
2566 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2567 #
2568 # This is done by determining whether or not the appropriate directory
2569 # is available, and by checking whether or not specific configurations
2570 # have requested that this magic not happen.
2571 #
2572 # The command line options always override the explicit settings in
2573 # configure.ac, and the settings in configure.ac override this magic.
2574 #
2575 # If the default for a toolchain is to use GNU as and ld, and you don't
2576 # want to do that, then you should use the --without-gnu-as and
2577 # --without-gnu-ld options for the configure script.  Similarly, if
2578 # the default is to use the included zlib and you don't want to do that,
2579 # you should use the --with-system-zlib option for the configure script.
2580
2581 if test x${use_gnu_as} = x &&
2582    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2583   with_gnu_as=yes
2584   extra_host_args="$extra_host_args --with-gnu-as"
2585 fi
2586
2587 if test x${use_gnu_ld} = x &&
2588    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2589   with_gnu_ld=yes
2590   extra_host_args="$extra_host_args --with-gnu-ld"
2591 fi
2592
2593 if test x${use_included_zlib} = x &&
2594    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2595   :
2596 else
2597   with_system_zlib=yes
2598   extra_host_args="$extra_host_args --with-system-zlib"
2599 fi
2600
2601 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2602 # can detect this case.
2603
2604 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2605   with_newlib=yes
2606   extra_host_args="$extra_host_args --with-newlib"
2607 fi
2608
2609 # Handle ${copy_dirs}
2610 set fnord ${copy_dirs}
2611 shift
2612 while test $# != 0 ; do
2613   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2614     :
2615   else
2616     echo Copying $1 to $2
2617
2618     # Use the install script to create the directory and all required
2619     # parent directories.
2620     if test -d $2 ; then
2621       :
2622     else
2623       echo >config.temp
2624       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2625     fi
2626
2627     # Copy the directory, assuming we have tar.
2628     # FIXME: Should we use B in the second tar?  Not all systems support it.
2629     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2630
2631     # It is the responsibility of the user to correctly adjust all
2632     # symlinks.  If somebody can figure out how to handle them correctly
2633     # here, feel free to add the code.
2634
2635     echo $1 > $2/COPIED
2636   fi
2637   shift; shift
2638 done
2639
2640 # Determine a target-dependent exec_prefix that the installed
2641 # gcc will search in.  Keep this list sorted by triplet, with
2642 # the *-*-osname triplets last.
2643 md_exec_prefix=
2644 case "${target}" in
2645   i[[34567]]86-pc-msdosdjgpp*)
2646     md_exec_prefix=/dev/env/DJDIR/bin
2647     ;;
2648   *-*-hpux* | \
2649   *-*-nto-qnx* | \
2650   *-*-solaris2*)
2651     md_exec_prefix=/usr/ccs/bin
2652     ;;
2653 esac
2654
2655 extra_arflags_for_target=
2656 extra_nmflags_for_target=
2657 extra_ranlibflags_for_target=
2658 target_makefile_frag=/dev/null
2659 case "${target}" in
2660   spu-*-*)
2661     target_makefile_frag="config/mt-spu"
2662     ;;
2663   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2664     target_makefile_frag="config/mt-sde"
2665     ;;
2666   mipsisa*-*-elfoabi*)
2667     target_makefile_frag="config/mt-mips-elfoabi"
2668     ;;
2669   mips*-*-*linux* | mips*-*-gnu*)
2670     target_makefile_frag="config/mt-mips-gnu"
2671     ;;
2672   nios2-*-elf*)
2673     target_makefile_frag="config/mt-nios2-elf"
2674     ;;
2675   *-*-linux-android*)
2676     target_makefile_frag="config/mt-android"
2677     ;;
2678   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2679     target_makefile_frag="config/mt-gnu"
2680     ;;
2681   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2682     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2683     # commands to handle both 32-bit and 64-bit objects.  These flags are
2684     # harmless if we're using GNU nm or ar.
2685     extra_arflags_for_target=" -X32_64"
2686     extra_nmflags_for_target=" -B -X32_64"
2687     ;;
2688 esac
2689
2690 alphaieee_frag=/dev/null
2691 case $target in
2692   alpha*-*-*)
2693     # This just makes sure to use the -mieee option to build target libs.
2694     # This should probably be set individually by each library.
2695     alphaieee_frag="config/mt-alphaieee"
2696     ;;
2697 esac
2698
2699 # If --enable-target-optspace always use -Os instead of -O2 to build
2700 # the target libraries, similarly if it is not specified, use -Os
2701 # on selected platforms.
2702 ospace_frag=/dev/null
2703 case "${enable_target_optspace}:${target}" in
2704   yes:*)
2705     ospace_frag="config/mt-ospace"
2706     ;;
2707   :d30v-*)
2708     ospace_frag="config/mt-d30v"
2709     ;;
2710   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2711     ospace_frag="config/mt-ospace"
2712     ;;
2713   no:* | :*)
2714     ;;
2715   *)
2716     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2717     ;;
2718 esac
2719
2720 # Some systems (e.g., one of the i386-aix systems the gas testers are
2721 # using) don't handle "\$" correctly, so don't use it here.
2722 tooldir='${exec_prefix}'/${target_noncanonical}
2723 build_tooldir=${tooldir}
2724
2725 # Create a .gdbinit file which runs the one in srcdir
2726 # and tells GDB to look there for source files.
2727
2728 if test -r ${srcdir}/.gdbinit ; then
2729   case ${srcdir} in
2730     .) ;;
2731     *) cat > ./.gdbinit <<EOF
2732 # ${NO_EDIT}
2733 dir ${srcdir}
2734 dir .
2735 source ${srcdir}/.gdbinit
2736 EOF
2737     ;;
2738   esac
2739 fi
2740
2741 # Make sure that the compiler is able to generate an executable.  If it
2742 # can't, we are probably in trouble.  We don't care whether we can run the
2743 # executable--we might be using a cross compiler--we only care whether it
2744 # can be created.  At this point the main configure script has set CC.
2745 we_are_ok=no
2746 echo "int main () { return 0; }" > conftest.c
2747 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2748 if test $? = 0 ; then
2749   if test -s conftest || test -s conftest.exe ; then
2750     we_are_ok=yes
2751   fi
2752 fi
2753 case $we_are_ok in
2754   no)
2755     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2756     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2757     rm -f conftest*
2758     exit 1
2759     ;;
2760 esac
2761 rm -f conftest*
2762
2763 # Decide which environment variable is used to find dynamic libraries.
2764 case "${host}" in
2765   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2766   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2767   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2768   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2769 esac
2770
2771 # On systems where the dynamic library environment variable is PATH,
2772 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2773 # built executables to PATH.
2774 if test "$RPATH_ENVVAR" = PATH; then
2775   GCC_SHLIB_SUBDIR=/shlib
2776 else
2777   GCC_SHLIB_SUBDIR=
2778 fi
2779
2780 # Adjust the toplevel makefile according to whether bootstrap was selected.
2781 case $enable_bootstrap in
2782   yes)
2783     bootstrap_suffix=bootstrap
2784     BUILD_CONFIG=bootstrap-debug
2785     ;;
2786   no)
2787     bootstrap_suffix=no-bootstrap
2788     BUILD_CONFIG=
2789     ;;
2790 esac
2791
2792 AC_MSG_CHECKING(for default BUILD_CONFIG)
2793
2794 AC_ARG_WITH([build-config],
2795   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2796                   [use config/NAME.mk build configuration])],
2797   [case $with_build_config in
2798    yes) with_build_config= ;;
2799    no) with_build_config= BUILD_CONFIG= ;;
2800    esac])
2801
2802 if test "x${with_build_config}" != x; then
2803   BUILD_CONFIG=$with_build_config
2804 else
2805   case $BUILD_CONFIG in
2806   bootstrap-debug)
2807     if echo "int f (void) { return 0; }" > conftest.c &&
2808        ${CC} -c conftest.c &&
2809        mv conftest.o conftest.o.g0 &&
2810        ${CC} -c -g conftest.c &&
2811        mv conftest.o conftest.o.g &&
2812        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2813       :
2814     else
2815       BUILD_CONFIG=
2816     fi
2817     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2818     ;;
2819   esac
2820 fi
2821 AC_MSG_RESULT($BUILD_CONFIG)
2822 AC_SUBST(BUILD_CONFIG)
2823
2824 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2825 AC_MSG_CHECKING([for --enable-vtable-verify])
2826 AC_ARG_ENABLE(vtable-verify,
2827 [AS_HELP_STRING([--enable-vtable-verify],
2828                 [Enable vtable verification feature])],
2829 [case "$enableval" in
2830  yes) enable_vtable_verify=yes ;;
2831  no)  enable_vtable_verify=no ;;
2832  *)   enable_vtable_verify=no;;
2833  esac],
2834 [enable_vtable_verify=no])
2835 AC_MSG_RESULT($enable_vtable_verify)
2836
2837 # Record target_configdirs and the configure arguments for target and
2838 # build configuration in Makefile.
2839 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2840 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2841 bootstrap_fixincludes=no
2842
2843 # If we are building libgomp, bootstrap it.
2844 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2845   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2846 fi
2847
2848 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2849 # or bootstrap-ubsan, bootstrap it.
2850 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2851   case "$BUILD_CONFIG" in
2852     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
2853       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2854       bootstrap_fixincludes=yes
2855       ;;
2856   esac
2857 fi
2858
2859 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2860 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2861    test "$enable_vtable_verify" != no; then
2862   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2863 fi
2864
2865 # If we are building libatomic and the list of enabled languages includes the
2866 # D frontend, bootstrap it.
2867 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
2868   case ,${enable_languages}, in
2869     *,d,*)
2870       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
2871       ;;
2872   esac
2873 fi
2874
2875 # Determine whether gdb needs tk/tcl or not.
2876 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2877 # and in that case we want gdb to be built without tk.  Ugh!
2878 # In fact I believe gdb is the *only* package directly dependent on tk,
2879 # so we should be able to put the 'maybe's in unconditionally and
2880 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2881 # 100% sure that that's safe though.
2882
2883 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2884 case "$enable_gdbtk" in
2885   no)
2886     GDB_TK="" ;;
2887   yes)
2888     GDB_TK="${gdb_tk}" ;;
2889   *)
2890     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2891     # distro.  Eventually someone will fix this and move Insight, nee
2892     # gdbtk to a separate directory.
2893     if test -d ${srcdir}/gdb/gdbtk ; then
2894       GDB_TK="${gdb_tk}"
2895     else
2896       GDB_TK=""
2897     fi
2898     ;;
2899 esac
2900 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2901 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2902
2903 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2904 # else does, only include them if one of these is built.  The Makefile
2905 # provides the ordering, so it's enough here to add to the list.
2906 case " ${configdirs} " in
2907   *\ gdb\ *)
2908     configdirs="${configdirs} gnulib gdbsupport"
2909     ;;
2910   *\ gdbserver\ *)
2911     configdirs="${configdirs} gnulib gdbsupport"
2912     ;;
2913   *\ sim\ *)
2914     configdirs="${configdirs} gnulib"
2915     ;;
2916 esac
2917
2918 # Strip out unwanted targets.
2919
2920 # While at that, we remove Makefiles if we were started for recursive
2921 # configuration, so that the top-level Makefile reconfigures them,
2922 # like we used to do when configure itself was recursive.
2923
2924 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2925 # but now we're fixing up the Makefile ourselves with the additional
2926 # commands passed to AC_CONFIG_FILES.  Use separate variables
2927 # extrasub-{build,host,target} not because there is any reason to split
2928 # the substitutions up that way, but only to remain below the limit of
2929 # 99 commands in a script, for HP-UX sed.
2930
2931 # Do not nest @if/@endif or @unless/@endunless pairs, because
2932 # configure will not warn you at all.
2933
2934 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2935   yes:yes:*\ gold\ *:*,c++,*) ;;
2936   yes:yes:*\ gold\ *:*)
2937     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2938     ;;
2939 esac
2940
2941 extrasub_build=
2942 for module in ${build_configdirs} ; do
2943   if test -z "${no_recursion}" \
2944      && test -f ${build_subdir}/${module}/Makefile; then
2945     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2946     rm -f ${build_subdir}/${module}/Makefile
2947   fi
2948   extrasub_build="$extrasub_build
2949 /^@if build-$module\$/d
2950 /^@endif build-$module\$/d
2951 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2952 /^@if build-$module-$bootstrap_suffix\$/d
2953 /^@endif build-$module-$bootstrap_suffix\$/d
2954 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2955 done
2956 extrasub_host=
2957 for module in ${configdirs} ; do
2958   if test -z "${no_recursion}"; then
2959     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2960       if test -f ${file}; then
2961         echo 1>&2 "*** removing ${file} to force reconfigure"
2962         rm -f ${file}
2963       fi
2964     done
2965   fi
2966   case ${module},${bootstrap_fixincludes} in
2967     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2968     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2969   esac
2970   extrasub_host="$extrasub_host
2971 /^@if $module\$/d
2972 /^@endif $module\$/d
2973 /^@unless $module\$/,/^@endunless $module\$/d
2974 /^@if $module-$host_bootstrap_suffix\$/d
2975 /^@endif $module-$host_bootstrap_suffix\$/d
2976 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2977 done
2978 extrasub_target=
2979 for module in ${target_configdirs} ; do
2980   if test -z "${no_recursion}" \
2981      && test -f ${target_subdir}/${module}/Makefile; then
2982     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2983     rm -f ${target_subdir}/${module}/Makefile
2984   fi
2985
2986   # We only bootstrap target libraries listed in bootstrap_target_libs.
2987   case $bootstrap_target_libs in
2988     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2989     *) target_bootstrap_suffix=no-bootstrap ;;
2990   esac
2991
2992   extrasub_target="$extrasub_target
2993 /^@if target-$module\$/d
2994 /^@endif target-$module\$/d
2995 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2996 /^@if target-$module-$target_bootstrap_suffix\$/d
2997 /^@endif target-$module-$target_bootstrap_suffix\$/d
2998 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2999 done
3000
3001 # Do the final fixup along with target modules.
3002 extrasub_target="$extrasub_target
3003 /^@if /,/^@endif /d
3004 /^@unless /d
3005 /^@endunless /d"
3006
3007 if test "$enable_pgo_build" != "no"; then
3008   extrasub_build="$extrasub_build
3009 /^@if pgo-build\$/d
3010 /^@endif pgo-build\$/d"
3011 fi
3012
3013 # Create the serialization dependencies.  This uses a temporary file.
3014
3015 AC_ARG_ENABLE([serial-configure],
3016 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3017                 [force sequential configuration of
3018                  sub-packages for the host, target or build
3019                  machine, or all sub-packages])])
3020
3021 case ${enable_serial_configure} in
3022   yes)
3023     enable_serial_build_configure=yes
3024     enable_serial_host_configure=yes
3025     enable_serial_target_configure=yes
3026     ;;
3027 esac
3028
3029 # These force 'configure's to be done one at a time, to avoid problems
3030 # with contention over a shared config.cache.
3031 rm -f serdep.tmp
3032 echo '# serdep.tmp' > serdep.tmp
3033 olditem=
3034 test "x${enable_serial_build_configure}" = xyes &&
3035 for item in ${build_configdirs} ; do
3036   case ${olditem} in
3037     "") ;;
3038     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3039   esac
3040   olditem=${item}
3041 done
3042 olditem=
3043 test "x${enable_serial_host_configure}" = xyes &&
3044 for item in ${configdirs} ; do
3045   case ${olditem} in
3046     "") ;;
3047     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3048   esac
3049   olditem=${item}
3050 done
3051 olditem=
3052 test "x${enable_serial_target_configure}" = xyes &&
3053 for item in ${target_configdirs} ; do
3054   case ${olditem} in
3055     "") ;;
3056     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3057   esac
3058   olditem=${item}
3059 done
3060 serialization_dependencies=serdep.tmp
3061 AC_SUBST_FILE(serialization_dependencies)
3062
3063 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3064 # target, nonopt, and variable assignments.  These are the ones we
3065 # might not want to pass down to subconfigures.  The exception being
3066 # --cache-file=/dev/null, which is used to turn off the use of cache
3067 # files altogether, and which should be passed on to subconfigures.
3068 # Also strip program-prefix, program-suffix, and program-transform-name,
3069 # so that we can pass down a consistent program-transform-name.
3070 baseargs=
3071 tbaseargs=
3072 keep_next=no
3073 skip_next=no
3074 eval "set -- $ac_configure_args"
3075 for ac_arg
3076 do
3077   if test X"$skip_next" = X"yes"; then
3078     skip_next=no
3079     continue
3080   fi
3081   if test X"$keep_next" = X"yes"; then
3082     case $ac_arg in
3083       *\'*)
3084         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3085     esac
3086     baseargs="$baseargs '$ac_arg'"
3087     tbaseargs="$tbaseargs '$ac_arg'"
3088     keep_next=no
3089     continue
3090   fi
3091
3092   # Handle separated arguments.  Based on the logic generated by
3093   # autoconf 2.59.
3094   case $ac_arg in
3095     *=* | --config-cache | -C | -disable-* | --disable-* \
3096       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3097       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3098       | -with-* | --with-* | -without-* | --without-* | --x)
3099       separate_arg=no
3100       ;;
3101     -*)
3102       separate_arg=yes
3103       ;;
3104     *)
3105       separate_arg=no
3106       ;;
3107   esac
3108
3109   skip_targ=no
3110   case $ac_arg in
3111 changequote(,)
3112   --with-* | --without-*)
3113     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3114
3115     case $libopt in
3116     *[-_]include)
3117       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3118       ;;
3119     *[-_]lib)
3120       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3121       ;;
3122     *)
3123       lib=$libopt
3124       ;;
3125     esac
3126 changequote([,])
3127
3128     case $lib in
3129     mpc | mpfr | gmp | isl)
3130       # If we're processing --with-$lib, --with-$lib-include or
3131       # --with-$lib-lib, for one of the libs above, and target is
3132       # different from host, don't pass the current argument to any
3133       # target library's configure.
3134       if test x$is_cross_compiler = xyes; then
3135         skip_targ=yes
3136       fi
3137       ;;
3138     esac
3139     ;;
3140   esac
3141
3142   case "$ac_arg" in
3143     --cache-file=/dev/null | \
3144     -cache-file=/dev/null )
3145       # Handled here to avoid the test to skip args below.
3146       baseargs="$baseargs '$ac_arg'"
3147       tbaseargs="$tbaseargs '$ac_arg'"
3148       # Assert: $separate_arg should always be no.
3149       keep_next=$separate_arg
3150       ;;
3151     --no*)
3152       continue
3153       ;;
3154     --c* | \
3155     --sr* | \
3156     --ho* | \
3157     --bu* | \
3158     --t* | \
3159     --program-* | \
3160     -cache_file* | \
3161     -srcdir* | \
3162     -host* | \
3163     -build* | \
3164     -target* | \
3165     -program-prefix* | \
3166     -program-suffix* | \
3167     -program-transform-name* )
3168       skip_next=$separate_arg
3169       continue
3170       ;;
3171     -*)
3172       # An option.  Add it.
3173       case $ac_arg in
3174         *\'*)
3175           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3176       esac
3177       baseargs="$baseargs '$ac_arg'"
3178       if test X"$skip_targ" = Xno; then
3179         tbaseargs="$tbaseargs '$ac_arg'"
3180       fi
3181       keep_next=$separate_arg
3182       ;;
3183     *)
3184       # Either a variable assignment, or a nonopt (triplet).  Don't
3185       # pass it down; let the Makefile handle this.
3186       continue
3187       ;;
3188   esac
3189 done
3190 # Remove the initial space we just introduced and, as these will be
3191 # expanded by make, quote '$'.
3192 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3193
3194 # Add in --program-transform-name, after --program-prefix and
3195 # --program-suffix have been applied to it.  Autoconf has already
3196 # doubled dollar signs and backslashes in program_transform_name; we want
3197 # the backslashes un-doubled, and then the entire thing wrapped in single
3198 # quotes, because this will be expanded first by make and then by the shell.
3199 # Also, because we want to override the logic in subdir configure scripts to
3200 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3201 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3202 ${program_transform_name}
3203 EOF_SED
3204 gcc_transform_name=`cat conftestsed.out`
3205 rm -f conftestsed.out
3206 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3207 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3208 if test "$silent" = yes; then
3209   baseargs="$baseargs --silent"
3210   tbaseargs="$tbaseargs --silent"
3211 fi
3212 baseargs="$baseargs --disable-option-checking"
3213 tbaseargs="$tbaseargs --disable-option-checking"
3214
3215 # Record and document user additions to sub configure arguments.
3216 AC_ARG_VAR([build_configargs],
3217            [additional configure arguments for build directories])
3218 AC_ARG_VAR([host_configargs],
3219            [additional configure arguments for host directories])
3220 AC_ARG_VAR([target_configargs],
3221            [additional configure arguments for target directories])
3222
3223 # For the build-side libraries, we just need to pretend we're native,
3224 # and not use the same cache file.  Multilibs are neither needed nor
3225 # desired.  We can't even use the same cache file for all build-side
3226 # libraries, as they're compiled differently; some with C, some with
3227 # C++ or with different feature-enabling options.
3228 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3229
3230 # For host modules, accept cache file option, or specification as blank.
3231 case "${cache_file}" in
3232 "") # empty
3233   cache_file_option="" ;;
3234 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3235   cache_file_option="--cache-file=${cache_file}" ;;
3236 *) # relative path
3237   cache_file_option="--cache-file=../${cache_file}" ;;
3238 esac
3239
3240 # Host dirs don't like to share a cache file either, horribly enough.
3241 # This seems to be due to autoconf 2.5x stupidity.
3242 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3243
3244 target_configargs="$target_configargs ${tbaseargs}"
3245
3246 # Passing a --with-cross-host argument lets the target libraries know
3247 # whether they are being built with a cross-compiler or being built
3248 # native.  However, it would be better to use other mechanisms to make the
3249 # sorts of decisions they want to make on this basis.  Please consider
3250 # this option to be deprecated.  FIXME.
3251 if test x${is_cross_compiler} = xyes ; then
3252   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3253 fi
3254
3255 # Special user-friendly check for native x86_64-linux build, if
3256 # multilib is not explicitly enabled.
3257 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3258   x86_64-*linux*:yes:$build:$build:)
3259     # Make sure we have a development environment that handles 32-bit
3260     dev64=no
3261     echo "int main () { return 0; }" > conftest.c
3262     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3263     if test $? = 0 ; then
3264       if test -s conftest || test -s conftest.exe ; then
3265         dev64=yes
3266       fi
3267     fi
3268     rm -f conftest*
3269     if test x${dev64} != xyes ; then
3270       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3271     fi
3272     ;;
3273 esac
3274
3275 # Default to --enable-multilib.
3276 if test x${enable_multilib} = x ; then
3277   target_configargs="--enable-multilib ${target_configargs}"
3278 fi
3279
3280 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3281 # changed from the earlier setting of with_newlib.
3282 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3283   target_configargs="--with-newlib ${target_configargs}"
3284 fi
3285
3286 # Different target subdirs use different values of certain variables
3287 # (notably CXX).  Worse, multilibs use *lots* of different values.
3288 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3289 # it doesn't automatically accept command-line overrides of them.
3290 # This means it's not safe for target subdirs to share a cache file,
3291 # which is disgusting, but there you have it.  Hopefully this can be
3292 # fixed in future.  It's still worthwhile to use a cache file for each
3293 # directory.  I think.
3294
3295 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3296 # We need to pass --target, as newer autoconf's requires consistency
3297 # for target_alias and gcc doesn't manage it consistently.
3298 target_configargs="--cache-file=./config.cache ${target_configargs}"
3299
3300 FLAGS_FOR_TARGET=
3301 case " $target_configdirs " in
3302  *" newlib "*)
3303   case " $target_configargs " in
3304   *" --with-newlib "*)
3305    case "$target" in
3306     *-cygwin*)
3307       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3308       ;;
3309    esac
3310
3311    # If we're not building GCC, don't discard standard headers.
3312    if test -d ${srcdir}/gcc; then
3313      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3314
3315      if test "${build}" != "${host}"; then
3316        # On Canadian crosses, CC_FOR_TARGET will have already been set
3317        # by `configure', so we won't have an opportunity to add -Bgcc/
3318        # to it.  This is right: we don't want to search that directory
3319        # for binaries, but we want the header files in there, so add
3320        # them explicitly.
3321        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3322
3323        # Someone might think of using the pre-installed headers on
3324        # Canadian crosses, in case the installed compiler is not fully
3325        # compatible with the compiler being built.  In this case, it
3326        # would be better to flag an error than risking having
3327        # incompatible object files being constructed.  We can't
3328        # guarantee that an error will be flagged, but let's hope the
3329        # compiler will do it, when presented with incompatible header
3330        # files.
3331      fi
3332    fi
3333
3334    case "${target}-${is_cross_compiler}" in
3335    i[[3456789]]86-*-linux*-no)
3336       # Here host == target, so we don't need to build gcc,
3337       # so we don't want to discard standard headers.
3338       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3339       ;;
3340    *)
3341       # If we're building newlib, use its generic headers last, but search
3342       # for any libc-related directories first (so make it the last -B
3343       # switch).
3344       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3345
3346       # If we're building libgloss, find the startup file, simulator library
3347       # and linker script.
3348       case " $target_configdirs " in
3349         *" libgloss "*)
3350         # Look for startup file, simulator library and maybe linker script.
3351         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3352         # Look for libnosys.a in case the target needs it.
3353         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3354         # Most targets have the linker script in the source directory.
3355         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3356         ;;
3357       esac
3358       ;;
3359    esac
3360    ;;
3361   esac
3362   ;;
3363 esac
3364
3365 case "$target" in
3366   x86_64-*mingw* | *-w64-mingw*)
3367   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3368   # however, use a symlink named 'mingw' in ${prefix} .
3369     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3370     ;;
3371   *-mingw*)
3372   # MinGW can't be handled as Cygwin above since it does not use newlib.
3373     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3374     ;;
3375 esac
3376
3377 # Allow the user to override the flags for
3378 # our build compiler if desired.
3379 if test x"${build}" = x"${host}" ; then
3380   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3381   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3382   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3383   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3384 fi
3385
3386 # On Canadian crosses, we'll be searching the right directories for
3387 # the previously-installed cross compiler, so don't bother to add
3388 # flags for directories within the install tree of the compiler
3389 # being built; programs in there won't even run.
3390 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3391   # Search for pre-installed headers if nothing else fits.
3392   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3393 fi
3394
3395 if test "x${use_gnu_ld}" = x &&
3396    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3397   # Arrange for us to find uninstalled linker scripts.
3398   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3399 fi
3400
3401 # Search for other target-specific linker scripts and such.
3402 case "${target}" in
3403   mep*)
3404     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3405     ;;
3406   # The VxWorks support for shared libraries is getting in
3407   # incrementally.  Make sure it doesn't get activated implicitly:
3408   *vxworks*)
3409     if test "${enable_shared-unset}" = unset ; then
3410       enable_shared=no
3411       # So the build of libraries knows ...
3412       target_configargs="${target_configargs} --disable-shared"
3413       # So gcc knows ...
3414       host_configargs="${host_configargs} --disable-shared"
3415     fi
3416     ;;
3417 esac
3418
3419 # Makefile fragments.
3420 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3421 do
3422   eval fragval=\$$frag
3423   if test $fragval != /dev/null; then
3424     eval $frag=${srcdir}/$fragval
3425   fi
3426 done
3427 AC_SUBST_FILE(host_makefile_frag)
3428 AC_SUBST_FILE(target_makefile_frag)
3429 AC_SUBST_FILE(alphaieee_frag)
3430 AC_SUBST_FILE(ospace_frag)
3431
3432 # Miscellanea: directories, flags, etc.
3433 AC_SUBST(RPATH_ENVVAR)
3434 AC_SUBST(GCC_SHLIB_SUBDIR)
3435 AC_SUBST(tooldir)
3436 AC_SUBST(build_tooldir)
3437 AC_SUBST(CONFIGURE_GDB_TK)
3438 AC_SUBST(GDB_TK)
3439 AC_SUBST(INSTALL_GDB_TK)
3440
3441 # Build module lists & subconfigure args.
3442 AC_SUBST(build_configargs)
3443 AC_SUBST(build_configdirs)
3444
3445 # Host module lists & subconfigure args.
3446 AC_SUBST(host_configargs)
3447 AC_SUBST(configdirs)
3448 AC_SUBST(target_configdirs)
3449
3450 # Target module lists & subconfigure args.
3451 AC_SUBST(target_configargs)
3452
3453
3454 # Build tools.
3455 AC_SUBST(AR_FOR_BUILD)
3456 AC_SUBST(AS_FOR_BUILD)
3457 AC_SUBST(CC_FOR_BUILD)
3458 AC_SUBST(CFLAGS_FOR_BUILD)
3459 AC_SUBST(CPP_FOR_BUILD)
3460 AC_SUBST(CPPFLAGS_FOR_BUILD)
3461 AC_SUBST(CXXFLAGS_FOR_BUILD)
3462 AC_SUBST(CXX_FOR_BUILD)
3463 AC_SUBST(DLLTOOL_FOR_BUILD)
3464 AC_SUBST(DSYMUTIL_FOR_BUILD)
3465 AC_SUBST(GFORTRAN_FOR_BUILD)
3466 AC_SUBST(GOC_FOR_BUILD)
3467 AC_SUBST(GDC_FOR_BUILD)
3468 AC_SUBST(LDFLAGS_FOR_BUILD)
3469 AC_SUBST(LD_FOR_BUILD)
3470 AC_SUBST(NM_FOR_BUILD)
3471 AC_SUBST(RANLIB_FOR_BUILD)
3472 AC_SUBST(WINDMC_FOR_BUILD)
3473 AC_SUBST(WINDRES_FOR_BUILD)
3474
3475 # Generate default definitions for YACC, M4, LEX and other programs that run
3476 # on the build machine.  These are used if the Makefile can't locate these
3477 # programs in objdir.
3478 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3479
3480 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3481 case " $build_configdirs " in
3482   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3483 esac
3484
3485 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3486 case " $build_configdirs " in
3487   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3488 esac
3489
3490 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3491 case " $build_configdirs " in
3492   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3493 esac
3494
3495 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3496 case " $build_configdirs " in
3497   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3498   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3499 esac
3500
3501 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3502 case " $build_configdirs " in
3503   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3504 esac
3505
3506 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3507 case " $build_configdirs " in
3508   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3509   *)
3510 changequote(,)
3511     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3512     # higher, else we use the "missing" dummy.
3513     if ${MAKEINFO} --version \
3514        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3515       :
3516     else
3517       MAKEINFO="$MISSING makeinfo"
3518     fi
3519     ;;
3520 changequote([,])
3521 esac
3522
3523 # FIXME: expect and dejagnu may become build tools?
3524
3525 AC_CHECK_PROGS(EXPECT, expect, expect)
3526 case " $configdirs " in
3527   *" expect "*)
3528     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3529     ;;
3530 esac
3531
3532 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3533 case " $configdirs " in
3534   *" dejagnu "*)
3535     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3536     ;;
3537 esac
3538
3539
3540 # Host tools.
3541 NCN_STRICT_CHECK_TOOLS(AR, ar)
3542 NCN_STRICT_CHECK_TOOLS(AS, as)
3543 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3544 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3545 NCN_STRICT_CHECK_TOOLS(LD, ld)
3546 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3547 NCN_STRICT_CHECK_TOOLS(NM, nm)
3548 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3549 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3550 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3551 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3552 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3553 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3554 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3555 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3556 AC_SUBST(CC)
3557 AC_SUBST(CXX)
3558 AC_SUBST(CFLAGS)
3559 AC_SUBST(CXXFLAGS)
3560 AC_SUBST(GDC)
3561 AC_SUBST(GDCFLAGS)
3562
3563 # Target tools.
3564 AC_ARG_WITH([build-time-tools],
3565   [AS_HELP_STRING([--with-build-time-tools=PATH],
3566                   [use given path to find target tools during the build])],
3567   [case x"$withval" in
3568      x/*) ;;
3569      *)
3570        with_build_time_tools=
3571        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3572        ;;
3573    esac],
3574   [with_build_time_tools=])
3575
3576 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3577 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3578 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3579 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3580 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3581 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3582
3583 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3584 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3585 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3586 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3587 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3588 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3589 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3590 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3591 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3592 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3593 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3594 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3595 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3596 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3597 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3598
3599 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3600
3601 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3602 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3603 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3604 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3605 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3606                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3607                 c++)
3608 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3609                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3610                 c++)
3611 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3612 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3613 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3614 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3615                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3616 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3617                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3618 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3619                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3620 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3621 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3622 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3623 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3624 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3625 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3626 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3627 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3628 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3629 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3630 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3631
3632 AC_SUBST(FLAGS_FOR_TARGET)
3633 AC_SUBST(RAW_CXX_FOR_TARGET)
3634
3635 # Certain tools may need extra flags.
3636 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3637 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3638 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3639
3640 # When building target libraries, except in a Canadian cross, we use
3641 # the same toolchain as the compiler we just built.
3642 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3643 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3644 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3645 if test $host = $build; then
3646   case " $configdirs " in
3647     *" gcc "*)
3648       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3649       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3650       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3651       ;;
3652   esac
3653 fi
3654
3655 AC_SUBST(COMPILER_AS_FOR_TARGET)
3656 AC_SUBST(COMPILER_LD_FOR_TARGET)
3657 AC_SUBST(COMPILER_NM_FOR_TARGET)
3658
3659 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3660 AC_ARG_ENABLE(maintainer-mode,
3661 [AS_HELP_STRING([--enable-maintainer-mode],
3662                 [enable make rules and dependencies not useful
3663                  (and sometimes confusing) to the casual installer])],
3664       USE_MAINTAINER_MODE=$enableval,
3665       USE_MAINTAINER_MODE=no)
3666 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3667 AC_SUBST(MAINTAINER_MODE_TRUE)
3668 AC_SUBST(MAINTAINER_MODE_FALSE)
3669 if test "$USE_MAINTAINER_MODE" = yes; then
3670   MAINTAINER_MODE_TRUE=
3671   MAINTAINER_MODE_FALSE='#'
3672 else
3673   MAINTAINER_MODE_TRUE='#'
3674   MAINTAINER_MODE_FALSE=
3675 fi
3676 MAINT=$MAINTAINER_MODE_TRUE
3677 AC_SUBST(MAINT)dnl
3678
3679 # ---------------------
3680 # GCC bootstrap support
3681 # ---------------------
3682
3683 # Stage specific cflags for build.
3684 stage1_cflags="-g"
3685 case $build in
3686   vax-*-*)
3687     case ${GCC} in
3688       yes) stage1_cflags="-g -Wa,-J" ;;
3689       *) stage1_cflags="-g -J" ;;
3690     esac ;;
3691 esac
3692
3693 AC_SUBST(stage1_cflags)
3694
3695 # Enable --enable-checking in stage1 of the compiler.
3696 AC_ARG_ENABLE(stage1-checking,
3697 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3698                 [choose additional checking for stage1 of the compiler])],
3699 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3700 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3701   # For --disable-checking or implicit --enable-checking=release, avoid
3702   # setting --enable-checking=gc in the default stage1 checking for LTO
3703   # bootstraps.  See PR62077.
3704   case $BUILD_CONFIG in
3705     *lto*)
3706       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3707     *)
3708       stage1_checking=--enable-checking=yes,types;;
3709   esac
3710   if test "x$enable_checking" = x && \
3711      test -d ${srcdir}/gcc && \
3712      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3713     stage1_checking=--enable-checking=yes,types,extra
3714   fi
3715 else
3716   stage1_checking=--enable-checking=$enable_checking,types
3717 fi])
3718 AC_SUBST(stage1_checking)
3719
3720 # Enable -Werror in bootstrap stage2 and later.
3721 AC_ARG_ENABLE(werror,
3722 [AS_HELP_STRING([--enable-werror],
3723                 [enable -Werror in bootstrap stage2 and later])],
3724 [
3725 case ${enable_werror} in
3726   yes) stage2_werror_flag="--enable-werror-always" ;;
3727   *) stage2_werror_flag="" ;;
3728 esac
3729 ],
3730 [
3731 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3732   case $BUILD_CONFIG in
3733   bootstrap-debug)
3734       stage2_werror_flag="--enable-werror-always" ;;
3735   "")
3736       stage2_werror_flag="--enable-werror-always" ;;
3737   esac
3738 fi
3739 ])
3740
3741 AC_SUBST(stage2_werror_flag)
3742
3743 # Specify what files to not compare during bootstrap.
3744
3745 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3746 case "$target" in
3747   hppa*64*-*-hpux*) ;;
3748   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3749 esac
3750 AC_SUBST(compare_exclusions)
3751
3752 AC_CONFIG_FILES([Makefile],
3753   [sed "$extrasub_build" Makefile |
3754    sed "$extrasub_host" |
3755    sed "$extrasub_target" > mf$$
3756    mv -f mf$$ Makefile],
3757   [extrasub_build="$extrasub_build"
3758    extrasub_host="$extrasub_host"
3759    extrasub_target="$extrasub_target"])
3760 AC_OUTPUT