configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools c++tools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libhsail-rt \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo \
 167                 target-libphobos \
 168                 target-zlib"
 169
 170 # these tools are built using the target libraries, and are intended to
 171 # run only in the target environment
 172 #
 173 # note: any program that *uses* libraries that are in the "target_libraries"
 174 # list belongs in this list.
 175 #
 176 target_tools="target-rda"
 177
 178 ################################################################################
 179
 180 ## All tools belong in one of the four categories, and are assigned above
 181 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 182 ## is important because configure will choke if they ever get through.
 183 ## ${configdirs} is directories we build using the host tools.
 184 ## ${target_configdirs} is directories we build using the target tools.
 185 configdirs=`echo ${host_libs} ${host_tools}`
 186 target_configdirs=`echo ${target_libraries} ${target_tools}`
 187 build_configdirs=`echo ${build_libs} ${build_tools}`
 188
 189 m4_divert_text([PARSE_ARGS],
 190 [case $srcdir in
 191   *" "*)
 192 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 193     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 194 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 195     ;;
 196 esac
 197 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 198 ])
 199
 200 ################################################################################
 201
 202 srcname="gnu development package"
 203
 204 # This gets set non-empty for some net releases of packages.
 205 appdirs=""
 206
 207 # Define is_cross_compiler to save on calls to 'test'.
 208 is_cross_compiler=
 209 if test x"${host}" = x"${target}" ; then
 210   is_cross_compiler=no
 211 else
 212   is_cross_compiler=yes
 213 fi
 214
 215 # Find the build and target subdir names.
 216 GCC_TOPLEV_SUBDIRS
 217 # Be sure to cover against remnants of an in-tree build.
 218 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 219   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 220 Use a pristine source tree when building in a separate tree])
 221 fi
 222
 223 # Skipdirs are removed silently.
 224 skipdirs=
 225 # Noconfigdirs are removed loudly.
 226 noconfigdirs=""
 227
 228 use_gnu_ld=
 229 # Make sure we don't let GNU ld be added if we didn't want it.
 230 if test x$with_gnu_ld = xno ; then
 231   use_gnu_ld=no
 232   noconfigdirs="$noconfigdirs ld gold"
 233 fi
 234
 235 use_gnu_as=
 236 # Make sure we don't let GNU as be added if we didn't want it.
 237 if test x$with_gnu_as = xno ; then
 238   use_gnu_as=no
 239   noconfigdirs="$noconfigdirs gas"
 240 fi
 241
 242 use_included_zlib=
 243 AC_ARG_WITH(system-zlib,
 244 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 245 # Make sure we don't let ZLIB be added if we didn't want it.
 246 if test x$with_system_zlib = xyes ; then
 247   use_included_zlib=no
 248   noconfigdirs="$noconfigdirs zlib"
 249 fi
 250
 251 # some tools are so dependent upon X11 that if we're not building with X,
 252 # it's not even worth trying to configure, much less build, that tool.
 253
 254 case ${with_x} in
 255   yes | "") ;; # the default value for this tree is that X11 is available
 256   no)
 257     skipdirs="${skipdirs} tk itcl libgui"
 258     # We won't be able to build gdbtk without X.
 259     enable_gdbtk=no
 260     ;;
 261   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 262 esac
 263
 264 # Some are only suitable for cross toolchains.
 265 # Remove these if host=target.
 266 cross_only="target-libgloss target-newlib target-opcodes"
 267
 268 case $is_cross_compiler in
 269   no) skipdirs="${skipdirs} ${cross_only}" ;;
 270 esac
 271
 272 # If both --with-headers and --with-libs are specified, default to
 273 # --without-newlib.
 274 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 275    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 276   if test x"${with_newlib}" = x ; then
 277     with_newlib=no
 278   fi
 279 fi
 280
 281 # Recognize --with-newlib/--without-newlib.
 282 case ${with_newlib} in
 283   no) skipdirs="${skipdirs} target-newlib" ;;
 284   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 285 esac
 286
 287 AC_ARG_ENABLE(as-accelerator-for,
 288 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 289                 [build as offload target compiler.
 290                 Specify offload host triple by ARG])])
 291
 292 AC_ARG_ENABLE(offload-targets,
 293 [AS_HELP_STRING([--enable-offload-targets=LIST],
 294                 [enable offloading to devices from comma-separated LIST of
 295                 TARGET[=DIR]. Use optional path to find offload target compiler
 296                 during the build])],
 297 [
 298   if test x"$enable_offload_targets" = x; then
 299     AC_MSG_ERROR([no offload targets specified])
 300   fi
 301 ], [enable_offload_targets=])
 302
 303 # Handle --enable-gold, --enable-ld.
 304 # --disable-gold [--enable-ld]
 305 #     Build only ld.  Default option.
 306 # --enable-gold [--enable-ld]
 307 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 308 #     as "ld.bfd" and "ld".
 309 # --enable-gold=default [--enable-ld]
 310 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 311 #     install ld as "ld.bfd".
 312 # --enable-gold[=default] --disable-ld
 313 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 314 # --enable-gold --enable-ld=default
 315 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 316 #     and ld.bfd).
 317 #     In other words, ld is default
 318 # --enable-gold=default --enable-ld=default
 319 #     Error.
 320
 321 default_ld=
 322 AC_ARG_ENABLE(gold,
 323 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 324                 [build gold @<:@ARG={default,yes,no}@:>@])],
 325 ENABLE_GOLD=$enableval,
 326 ENABLE_GOLD=no)
 327 case "${ENABLE_GOLD}" in
 328   yes|default)
 329     # Check for ELF target.
 330     is_elf=no
 331     case "${target}" in
 332       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 333       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 334       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 335       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 336         case "${target}" in
 337           *-*-linux*aout* | *-*-linux*oldld*)
 338             ;;
 339           *)
 340             is_elf=yes
 341             ;;
 342         esac
 343     esac
 344
 345     if test "$is_elf" = "yes"; then
 346       # Check for target supported by gold.
 347       case "${target}" in
 348         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 349         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 350           configdirs="$configdirs gold"
 351           if test x${ENABLE_GOLD} = xdefault; then
 352             default_ld=gold
 353           fi
 354           ENABLE_GOLD=yes
 355           ;;
 356       esac
 357     fi
 358     ;;
 359   no)
 360     ;;
 361   *)
 362     AC_MSG_ERROR([invalid --enable-gold argument])
 363     ;;
 364 esac
 365
 366 AC_ARG_ENABLE(ld,
 367 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 368                 [build ld @<:@ARG={default,yes,no}@:>@])],
 369 ENABLE_LD=$enableval,
 370 ENABLE_LD=yes)
 371
 372 case "${ENABLE_LD}" in
 373   default)
 374     if test x${default_ld} != x; then
 375       AC_MSG_ERROR([either gold or ld can be the default ld])
 376     fi
 377     ;;
 378   yes)
 379     ;;
 380   no)
 381     if test x${ENABLE_GOLD} != xyes; then
 382       AC_MSG_WARN([neither ld nor gold are enabled])
 383     fi
 384     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 385     ;;
 386   *)
 387     AC_MSG_ERROR([invalid --enable-ld argument])
 388     ;;
 389 esac
 390
 391 # PR gas/19109
 392 # Decide the default method for compressing debug sections.
 393 # Provide a configure time option to override our default.
 394 AC_ARG_ENABLE(compressed_debug_sections,
 395 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 396                 [Enable compressed debug sections for gas, gold or ld by
 397                  default])],
 398 [
 399   if test x"$enable_compressed_debug_sections" = xyes; then
 400     AC_MSG_ERROR([no program with compressed debug sections specified])
 401   fi
 402 ], [enable_compressed_debug_sections=])
 403
 404 # Configure extra directories which are host specific
 405
 406 case "${host}" in
 407   *-cygwin*)
 408     configdirs="$configdirs libtermcap" ;;
 409 esac
 410
 411 # A target can indicate whether a language isn't supported for some reason.
 412 # Only spaces may be used in this macro; not newlines or tabs.
 413 unsupported_languages=
 414
 415 # Remove more programs from consideration, based on the host or
 416 # target this usually means that a port of the program doesn't
 417 # exist yet.
 418
 419 case "${host}" in
 420   i[[3456789]]86-*-msdosdjgpp*)
 421     noconfigdirs="$noconfigdirs tcl tk itcl"
 422     ;;
 423 esac
 424
 425
 426 AC_ARG_ENABLE(libquadmath,
 427 AS_HELP_STRING([--disable-libquadmath],
 428   [do not build libquadmath directory]),
 429 ENABLE_LIBQUADMATH=$enableval,
 430 ENABLE_LIBQUADMATH=yes)
 431 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 432   noconfigdirs="$noconfigdirs target-libquadmath"
 433 fi
 434
 435
 436 AC_ARG_ENABLE(libquadmath-support,
 437 AS_HELP_STRING([--disable-libquadmath-support],
 438   [disable libquadmath support for Fortran]),
 439 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 440 ENABLE_LIBQUADMATH_SUPPORT=yes)
 441 enable_libquadmath_support=
 442 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 443   enable_libquadmath_support=no
 444 fi
 445
 446
 447 AC_ARG_ENABLE(libada,
 448 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 449 ENABLE_LIBADA=$enableval,
 450 ENABLE_LIBADA=yes)
 451 if test "${ENABLE_LIBADA}" != "yes" ; then
 452   noconfigdirs="$noconfigdirs gnattools"
 453 fi
 454
 455 AC_ARG_ENABLE(libssp,
 456 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 457 ENABLE_LIBSSP=$enableval,
 458 ENABLE_LIBSSP=yes)
 459
 460 AC_ARG_ENABLE(libstdcxx,
 461 AS_HELP_STRING([--disable-libstdcxx],
 462   [do not build libstdc++-v3 directory]),
 463 ENABLE_LIBSTDCXX=$enableval,
 464 ENABLE_LIBSTDCXX=default)
 465 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 466   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 467 fi]
 468
 469 # If this is accelerator compiler and its target is intelmic we enable
 470 # target liboffloadmic by default.  If this is compiler with offloading
 471 # for intelmic we enable host liboffloadmic by default.  Otherwise
 472 # liboffloadmic is disabled by default.
 473 AC_ARG_ENABLE([liboffloadmic],
 474 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 475                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 476 [case "$enableval" in
 477   no | host | target)
 478     enable_liboffloadmic=$enableval ;;
 479   *)
 480     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 481 esac],
 482 [if test x"$enable_as_accelerator_for" != x; then
 483   case "${target}" in
 484     *-intelmic-* | *-intelmicemul-*)
 485       enable_liboffloadmic=target
 486       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 487       ;;
 488     *)
 489       enable_liboffloadmic=no
 490       ;;
 491   esac
 492 else
 493   case "${enable_offload_targets}" in
 494     *-intelmic-* | *-intelmicemul-*)
 495       enable_liboffloadmic=host
 496       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 497       ;;
 498     *)
 499       enable_liboffloadmic=no
 500       ;;
 501     esac
 502 fi])
 503 AC_SUBST(extra_liboffloadmic_configure_flags)
 504
 505 # Enable libgomp by default on hosted POSIX systems, and a few others.
 506 if test x$enable_libgomp = x ; then
 507     case "${target}" in
 508     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 509         ;;
 510     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 511         ;;
 512     *-*-solaris2* | *-*-hpux11*)
 513         ;;
 514     *-*-darwin* | *-*-aix*)
 515         ;;
 516     nvptx*-*-* | amdgcn*-*-*)
 517         ;;
 518     *)
 519         noconfigdirs="$noconfigdirs target-libgomp"
 520         ;;
 521     esac
 522 fi
 523
 524 # Disable libatomic on unsupported systems.
 525 if test -d ${srcdir}/libatomic; then
 526     if test x$enable_libatomic = x; then
 527         AC_MSG_CHECKING([for libatomic support])
 528         if (srcdir=${srcdir}/libatomic; \
 529                 . ${srcdir}/configure.tgt; \
 530                 test -n "$UNSUPPORTED")
 531         then
 532             AC_MSG_RESULT([no])
 533             noconfigdirs="$noconfigdirs target-libatomic"
 534         else
 535             AC_MSG_RESULT([yes])
 536         fi
 537     fi
 538 fi
 539
 540 # Disable liboffloadmic on unsupported systems.
 541 if test -d ${srcdir}/liboffloadmic; then
 542     if test x$enable_liboffloadmic != xno; then
 543         AC_MSG_CHECKING([for liboffloadmic support])
 544         if (srcdir=${srcdir}/liboffloadmic; \
 545                 . ${srcdir}/configure.tgt; \
 546                 test -n "$UNSUPPORTED")
 547         then
 548             AC_MSG_RESULT([no])
 549             noconfigdirs="$noconfigdirs target-liboffloadmic"
 550         else
 551             AC_MSG_RESULT([yes])
 552         fi
 553     fi
 554 fi
 555
 556 # Disable libitm on unsupported systems.
 557 if test -d ${srcdir}/libitm; then
 558     if test x$enable_libitm = x; then
 559         AC_MSG_CHECKING([for libitm support])
 560         if (srcdir=${srcdir}/libitm; \
 561                 . ${srcdir}/configure.tgt; \
 562                 test -n "$UNSUPPORTED")
 563         then
 564             AC_MSG_RESULT([no])
 565             noconfigdirs="$noconfigdirs target-libitm"
 566         else
 567             AC_MSG_RESULT([yes])
 568         fi
 569     fi
 570 fi
 571
 572 # Disable libsanitizer on unsupported systems.
 573 if test -d ${srcdir}/libsanitizer; then
 574     if test x$enable_libsanitizer = x; then
 575         AC_MSG_CHECKING([for libsanitizer support])
 576         if (srcdir=${srcdir}/libsanitizer; \
 577                 . ${srcdir}/configure.tgt; \
 578                 test -n "$UNSUPPORTED")
 579         then
 580             AC_MSG_RESULT([no])
 581             noconfigdirs="$noconfigdirs target-libsanitizer"
 582         else
 583             AC_MSG_RESULT([yes])
 584         fi
 585     fi
 586 fi
 587
 588 # Disable libvtv on unsupported systems.
 589 if test -d ${srcdir}/libvtv; then
 590     if test x$enable_libvtv = x; then
 591         AC_MSG_CHECKING([for libvtv support])
 592         if (srcdir=${srcdir}/libvtv; \
 593                 . ${srcdir}/configure.tgt; \
 594                 test "$VTV_SUPPORTED" != "yes")
 595         then
 596             AC_MSG_RESULT([no])
 597             noconfigdirs="$noconfigdirs target-libvtv"
 598         else
 599             AC_MSG_RESULT([yes])
 600         fi
 601     fi
 602 fi
 603
 604
 605 # Disable libhsail-rt on unsupported systems.
 606 if test -d ${srcdir}/libhsail-rt; then
 607     if test x$enable_libhsail_rt = x; then
 608         AC_MSG_CHECKING([for libhsail-rt support])
 609         if (srcdir=${srcdir}/libhsail-rt; \
 610                 . ${srcdir}/configure.tgt; \
 611                 test -n "$UNSUPPORTED")
 612         then
 613             AC_MSG_RESULT([no])
 614             unsupported_languages="$unsupported_languages brig"
 615             # This implicitly disables also target-libhsail-rt as it won't
 616             # get added to the build without BRIG FE.
 617         else
 618             AC_MSG_RESULT([yes])
 619         fi
 620     fi
 621 fi
 622
 623
 624 # Disable libquadmath for some systems.
 625 case "${target}" in
 626   avr-*-*)
 627     noconfigdirs="$noconfigdirs target-libquadmath"
 628     ;;
 629   # libquadmath is unused on AIX and libquadmath build process use of
 630   # LD_LIBRARY_PATH can break AIX bootstrap.
 631   powerpc-*-aix* | rs6000-*-aix*)
 632     noconfigdirs="$noconfigdirs target-libquadmath"
 633     ;;
 634 esac
 635
 636 # Disable libssp for some systems.
 637 case "${target}" in
 638   avr-*-*)
 639     # No hosted I/O support.
 640     noconfigdirs="$noconfigdirs target-libssp"
 641     ;;
 642   bpf-*-*)
 643     noconfigdirs="$noconfigdirs target-libssp"
 644     ;;
 645   powerpc-*-aix* | rs6000-*-aix*)
 646     noconfigdirs="$noconfigdirs target-libssp"
 647     ;;
 648   pru-*-*)
 649     # No hosted I/O support.
 650     noconfigdirs="$noconfigdirs target-libssp"
 651     ;;
 652   rl78-*-*)
 653     # libssp uses a misaligned load to trigger a fault, but the RL78
 654     # doesn't fault for those - instead, it gives a build-time error
 655     # for explicit misaligned loads.
 656     noconfigdirs="$noconfigdirs target-libssp"
 657     ;;
 658   visium-*-*)
 659     # No hosted I/O support.
 660     noconfigdirs="$noconfigdirs target-libssp"
 661     ;;
 662 esac
 663
 664 # Disable libstdc++-v3 for some systems.
 665 # Allow user to override this if they pass --enable-libstdc++-v3
 666 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 667   case "${target}" in
 668     *-*-vxworks*)
 669       # VxWorks uses the Dinkumware C++ library.
 670       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 671       ;;
 672     amdgcn*-*-*)
 673       # Not ported/fails to build when using newlib.
 674       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 675       ;;
 676     arm*-wince-pe*)
 677       # the C++ libraries don't build on top of CE's C libraries
 678       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 679       ;;
 680     avr-*-*)
 681       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 682       ;;
 683     bpf-*-*)
 684       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 685       ;;
 686     ft32-*-*)
 687       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 688       ;;
 689   esac
 690 fi
 691
 692 # Disable C++ on systems where it is known to not work.
 693 # For testing, you can override this with --enable-languages=c++.
 694 case ,${enable_languages}, in
 695   *,c++,*)
 696     ;;
 697   *)
 698       case "${target}" in
 699         bpf-*-*)
 700           unsupported_languages="$unsupported_languages c++"
 701           ;;
 702       esac
 703       ;;
 704 esac
 705
 706 # Disable Objc on systems where it is known to not work.
 707 # For testing, you can override this with --enable-languages=objc.
 708 case ,${enable_languages}, in
 709   *,objc,*)
 710     ;;
 711   *)
 712       case "${target}" in
 713         bpf-*-*)
 714           unsupported_languages="$unsupported_languages objc"
 715           ;;
 716       esac
 717       ;;
 718 esac
 719
 720 # Disable D on systems where it is known to not work.
 721 # For testing, you can override this with --enable-languages=d.
 722 case ,${enable_languages}, in
 723   *,d,*)
 724     ;;
 725   *)
 726     case "${target}" in
 727       bpf-*-*)
 728         unsupported_languages="$unsupported_languages d"
 729         ;;
 730     esac
 731     ;;
 732 esac
 733
 734 # Disable libphobos on unsupported systems.
 735 # For testing, you can override this with --enable-libphobos.
 736 if test -d ${srcdir}/libphobos; then
 737     if test x$enable_libphobos = x; then
 738         AC_MSG_CHECKING([for libphobos support])
 739         if (srcdir=${srcdir}/libphobos; \
 740                 . ${srcdir}/configure.tgt; \
 741                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 742         then
 743             AC_MSG_RESULT([no])
 744             noconfigdirs="$noconfigdirs target-libphobos"
 745         else
 746             AC_MSG_RESULT([yes])
 747         fi
 748     fi
 749 fi
 750
 751 # Disable Fortran for some systems.
 752 case "${target}" in
 753   mmix-*-*)
 754     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 755     unsupported_languages="$unsupported_languages fortran"
 756     ;;
 757   bpf-*-*)
 758     unsupported_languages="$unsupported_languages fortran"
 759     ;;
 760 esac
 761
 762 # Disable libffi for some systems.
 763 case "${target}" in
 764   powerpc-*-darwin*)
 765     ;;
 766   i[[3456789]]86-*-darwin*)
 767     ;;
 768   x86_64-*-darwin[[912]]*)
 769     ;;
 770   *-*-darwin*)
 771     noconfigdirs="$noconfigdirs target-libffi"
 772     ;;
 773   *-*-netware*)
 774     noconfigdirs="$noconfigdirs target-libffi"
 775     ;;
 776   *-*-phoenix*)
 777     noconfigdirs="$noconfigdirs target-libffi"
 778     ;;
 779   *-*-rtems*)
 780     noconfigdirs="$noconfigdirs target-libffi"
 781     ;;
 782   *-*-tpf*)
 783     noconfigdirs="$noconfigdirs target-libffi"
 784     ;;
 785   *-*-uclinux*)
 786     noconfigdirs="$noconfigdirs target-libffi"
 787     ;;
 788   *-*-vxworks*)
 789     noconfigdirs="$noconfigdirs target-libffi"
 790     ;;
 791   aarch64*-*-freebsd*)
 792     noconfigdirs="$noconfigdirs target-libffi"
 793     ;;
 794   alpha*-*-*vms*)
 795     noconfigdirs="$noconfigdirs target-libffi"
 796     ;;
 797   arm*-*-freebsd*)
 798     noconfigdirs="$noconfigdirs target-libffi"
 799     ;;
 800   arm-wince-pe)
 801     noconfigdirs="$noconfigdirs target-libffi"
 802     ;;
 803   arm*-*-symbianelf*)
 804     noconfigdirs="$noconfigdirs target-libffi"
 805     ;;
 806   bpf-*-*)
 807     noconfigdirs="$noconfigdirs target-libffi"
 808     ;;
 809   cris-*-* | crisv32-*-*)
 810     case "${target}" in
 811       *-*-linux*)
 812         ;;
 813       *) # See PR46792 regarding target-libffi.
 814         noconfigdirs="$noconfigdirs target-libffi";;
 815     esac
 816     ;;
 817   hppa*64*-*-hpux*)
 818     noconfigdirs="$noconfigdirs target-libffi"
 819     ;;
 820   hppa*-hp-hpux11*)
 821     ;;
 822   hppa*-*-hpux*)
 823     noconfigdirs="$noconfigdirs target-libffi"
 824     ;;
 825   ia64*-*-*vms*)
 826     noconfigdirs="$noconfigdirs target-libffi"
 827     ;;
 828   i[[3456789]]86-w64-mingw*)
 829     noconfigdirs="$noconfigdirs target-libffi"
 830     ;;
 831   i[[3456789]]86-*-mingw*)
 832     noconfigdirs="$noconfigdirs target-libffi"
 833     ;;
 834   x86_64-*-mingw*)
 835     noconfigdirs="$noconfigdirs target-libffi"
 836     ;;
 837   mmix-*-*)
 838     noconfigdirs="$noconfigdirs target-libffi"
 839     ;;
 840   powerpc-*-aix*)
 841     ;;
 842   rs6000-*-aix*)
 843     ;;
 844   ft32-*-*)
 845     noconfigdirs="$noconfigdirs target-libffi"
 846     ;;
 847   *-*-lynxos*)
 848     noconfigdirs="$noconfigdirs target-libffi"
 849     ;;
 850 esac
 851
 852 # Disable the go frontend on systems where it is known to not work. Please keep
 853 # this in sync with contrib/config-list.mk.
 854 case "${target}" in
 855 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 856     unsupported_languages="$unsupported_languages go"
 857     ;;
 858 esac
 859
 860 # Only allow gdbserver on some systems.
 861 if test -d ${srcdir}/gdbserver; then
 862     if test x$enable_gdbserver = x; then
 863         AC_MSG_CHECKING([for gdbserver support])
 864         if (srcdir=${srcdir}/gdbserver; \
 865                 . ${srcdir}/configure.srv; \
 866                 test -n "$UNSUPPORTED")
 867         then
 868             AC_MSG_RESULT([no])
 869             noconfigdirs="$noconfigdirs gdbserver"
 870         else
 871             AC_MSG_RESULT([yes])
 872         fi
 873     fi
 874 fi
 875
 876 # Disable libgo for some systems where it is known to not work.
 877 # For testing, you can easily override this with --enable-libgo.
 878 if test x$enable_libgo = x; then
 879     case "${target}" in
 880     *-*-darwin*)
 881         # PR 46986
 882         noconfigdirs="$noconfigdirs target-libgo"
 883         ;;
 884     *-*-cygwin* | *-*-mingw*)
 885         noconfigdirs="$noconfigdirs target-libgo"
 886         ;;
 887     bpf-*-*)
 888         noconfigdirs="$noconfigdirs target-libgo"
 889         ;;
 890     esac
 891 fi
 892
 893 # Default libgloss CPU subdirectory.
 894 libgloss_dir="$target_cpu"
 895
 896 case "${target}" in
 897   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 898     libgloss_dir=wince
 899     ;;
 900   aarch64*-*-* )
 901     libgloss_dir=aarch64
 902     ;;
 903   arm*-*-*)
 904     libgloss_dir=arm
 905     ;;
 906   cris-*-* | crisv32-*-*)
 907     libgloss_dir=cris
 908     ;;
 909   hppa*-*-*)
 910     libgloss_dir=pa
 911     ;;
 912   i[[3456789]]86-*-*)
 913     libgloss_dir=i386
 914     ;;
 915   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 916     libgloss_dir=m68hc11
 917     ;;
 918   m68*-*-* | fido-*-*)
 919     libgloss_dir=m68k
 920     ;;
 921   mips*-*-*)
 922     libgloss_dir=mips
 923     ;;
 924   powerpc*-*-*)
 925     libgloss_dir=rs6000
 926     ;;
 927   pru-*-*)
 928     libgloss_dir=pru
 929     ;;
 930   sparc*-*-*)
 931     libgloss_dir=sparc
 932     ;;
 933 esac
 934
 935 # Disable newlib and libgloss for various target OSes.
 936 case "${target}" in
 937   alpha*-dec-osf*)
 938     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 939     ;;
 940   i[[3456789]]86-*-linux*)
 941     # This section makes it possible to build newlib natively on linux.
 942     # If we are using a cross compiler then don't configure newlib.
 943     if test x${is_cross_compiler} != xno ; then
 944       noconfigdirs="$noconfigdirs target-newlib"
 945     fi
 946     noconfigdirs="$noconfigdirs target-libgloss"
 947     # If we are not using a cross compiler, do configure newlib.
 948     # Note however, that newlib will only be configured in this situation
 949     # if the --with-newlib option has been given, because otherwise
 950     # 'target-newlib' will appear in skipdirs.
 951     ;;
 952   i[[3456789]]86-*-rdos*)
 953     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 954     ;;
 955   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 956     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 957     ;;
 958   sparc-*-sunos4*)
 959     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 960     ;;
 961   bpf-*-*)
 962     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 963     ;;
 964   *-*-aix*)
 965     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 966     ;;
 967   *-*-beos*)
 968     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 969     ;;
 970   *-*-chorusos)
 971     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 972     ;;
 973   *-*-dragonfly*)
 974     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 975     ;;
 976   *-*-freebsd*)
 977     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 978     ;;
 979   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 980     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 981     ;;
 982   *-*-lynxos*)
 983     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 984     ;;
 985   *-*-mingw*)
 986     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 987     ;;
 988   *-*-netbsd*)
 989     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 990     ;;
 991   *-*-netware*)
 992     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 993     ;;
 994   *-*-tpf*)
 995     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 996     ;;
 997   *-*-uclinux*)
 998     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 999     ;;
1000   *-*-vxworks*)
1001     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1002     ;;
1003 esac
1004
1005 case "${target}" in
1006   *-*-chorusos)
1007     ;;
1008   aarch64-*-darwin*)
1009     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1010     noconfigdirs="$noconfigdirs sim target-rda"
1011     ;;
1012   amdgcn*-*-*)
1013     ;;
1014   arm-*-darwin*)
1015     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1016     noconfigdirs="$noconfigdirs sim target-rda"
1017     ;;
1018   powerpc-*-darwin*)
1019     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1020     noconfigdirs="$noconfigdirs sim target-rda"
1021     ;;
1022   i[[3456789]]86-*-darwin*)
1023     noconfigdirs="$noconfigdirs ld gprof"
1024     noconfigdirs="$noconfigdirs sim target-rda"
1025     ;;
1026   x86_64-*-darwin[[912]]*)
1027     noconfigdirs="$noconfigdirs ld gas gprof"
1028     noconfigdirs="$noconfigdirs sim target-rda"
1029     ;;
1030   *-*-darwin*)
1031     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1032     noconfigdirs="$noconfigdirs sim target-rda"
1033     ;;
1034   *-*-dragonfly*)
1035     ;;
1036   *-*-freebsd*)
1037     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
1038         && ! test -d ${srcdir}/gmp \
1039         && test -f /usr/local/include/gmp.h; then
1040       with_gmp=/usr/local
1041     fi
1042     ;;
1043   *-*-kaos*)
1044     # Remove unsupported stuff on all kaOS configurations.
1045     noconfigdirs="$noconfigdirs target-libgloss"
1046     ;;
1047   *-*-netbsd*)
1048     ;;
1049   *-*-netware*)
1050     ;;
1051   *-*-phoenix*)
1052     noconfigdirs="$noconfigdirs target-libgloss"
1053     ;;
1054   *-*-rtems*)
1055     noconfigdirs="$noconfigdirs target-libgloss"
1056     ;;
1057     # The tpf target doesn't support gdb yet.
1058   *-*-tpf*)
1059     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1060     ;;
1061   *-*-uclinux*)
1062     noconfigdirs="$noconfigdirs target-rda"
1063     ;;
1064   *-*-vxworks*)
1065     ;;
1066   alpha*-dec-osf*)
1067     # ld works, but does not support shared libraries.
1068     # gas doesn't generate exception information.
1069     noconfigdirs="$noconfigdirs gas ld"
1070     ;;
1071   alpha*-*-*vms*)
1072     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1073     ;;
1074   alpha*-*-*)
1075     # newlib is not 64 bit ready
1076     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1077     ;;
1078   bpf-*-*)
1079     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1080     ;;
1081   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1082     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1083     ;;
1084   arc*-*-*)
1085     noconfigdirs="$noconfigdirs sim"
1086     ;;
1087   arm-*-pe*)
1088     noconfigdirs="$noconfigdirs target-libgloss"
1089     ;;
1090   arm-*-riscix*)
1091     noconfigdirs="$noconfigdirs ld target-libgloss"
1092     ;;
1093   avr-*-*)
1094     if test x${with_avrlibc} != xno; then
1095       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1096     fi
1097     ;;
1098   c4x-*-* | tic4x-*-*)
1099     noconfigdirs="$noconfigdirs target-libgloss"
1100     ;;
1101   tic54x-*-*)
1102     noconfigdirs="$noconfigdirs target-libgloss gdb"
1103     ;;
1104   d10v-*-*)
1105     noconfigdirs="$noconfigdirs target-libgloss"
1106     ;;
1107   d30v-*-*)
1108     noconfigdirs="$noconfigdirs gdb"
1109     ;;
1110   fr30-*-elf*)
1111     noconfigdirs="$noconfigdirs gdb"
1112     ;;
1113   ft32-*-*)
1114     noconfigdirs="$noconfigdirs target-rda gprof"
1115     ;;
1116   moxie-*-*)
1117     noconfigdirs="$noconfigdirs"
1118     ;;
1119   h8300*-*-*)
1120     noconfigdirs="$noconfigdirs target-libgloss"
1121     ;;
1122   h8500-*-*)
1123     noconfigdirs="$noconfigdirs target-libgloss"
1124     ;;
1125   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1126     ;;
1127   hppa*64*-*-hpux*)
1128     noconfigdirs="$noconfigdirs gdb"
1129     ;;
1130   hppa*-*-hpux11*)
1131     noconfigdirs="$noconfigdirs gdb ld"
1132     ;;
1133   hppa*64*-*-linux*)
1134     ;;
1135   hppa*-*-linux*)
1136     ;;
1137   hppa*-*-*elf* | \
1138   hppa*-*-lites* | \
1139   hppa*-*-openbsd* | \
1140   hppa*64*-*-*)
1141     ;;
1142   hppa*-*-pro*)
1143     ;;
1144   hppa*-*-*)
1145     noconfigdirs="$noconfigdirs ld"
1146     ;;
1147   i960-*-*)
1148     noconfigdirs="$noconfigdirs gdb"
1149     ;;
1150   ia64*-*-elf*)
1151     # No gdb support yet.
1152     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1153     ;;
1154   ia64*-**-hpux*)
1155     # No ld support yet.
1156     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1157     ;;
1158   ia64*-*-*vms*)
1159     # No ld support yet.
1160     noconfigdirs="$noconfigdirs libgui itcl ld"
1161     ;;
1162   i[[3456789]]86-w64-mingw*)
1163     ;;
1164   i[[3456789]]86-*-mingw*)
1165     target_configdirs="$target_configdirs target-winsup"
1166     ;;
1167   *-*-cygwin*)
1168     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1169     noconfigdirs="$noconfigdirs target-libgloss"
1170     # always build newlib if winsup directory is present.
1171     if test -d "$srcdir/winsup/cygwin"; then
1172       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1173     elif test -d "$srcdir/newlib"; then
1174       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1175     fi
1176     ;;
1177   i[[3456789]]86-*-pe)
1178     noconfigdirs="$noconfigdirs target-libgloss"
1179     ;;
1180   i[[3456789]]86-*-sco3.2v5*)
1181     # The linker does not yet know about weak symbols in COFF,
1182     # and is not configured to handle mixed ELF and COFF.
1183     noconfigdirs="$noconfigdirs ld target-libgloss"
1184     ;;
1185   i[[3456789]]86-*-sco*)
1186     noconfigdirs="$noconfigdirs gprof target-libgloss"
1187     ;;
1188   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1189     noconfigdirs="$noconfigdirs target-libgloss"
1190     ;;
1191   i[[3456789]]86-*-sysv4*)
1192     noconfigdirs="$noconfigdirs target-libgloss"
1193     ;;
1194   i[[3456789]]86-*-beos*)
1195     noconfigdirs="$noconfigdirs gdb"
1196     ;;
1197   i[[3456789]]86-*-rdos*)
1198     noconfigdirs="$noconfigdirs gdb"
1199     ;;
1200   mmix-*-*)
1201     noconfigdirs="$noconfigdirs gdb"
1202     ;;
1203   mt-*-*)
1204     noconfigdirs="$noconfigdirs sim"
1205     ;;
1206   nfp-*-*)
1207     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1208     noconfigdirs="$noconfigdirs $target_libraries"
1209     ;;
1210   pdp11-*-*)
1211     noconfigdirs="$noconfigdirs gdb gprof"
1212     ;;
1213   powerpc-*-aix*)
1214     # copied from rs6000-*-* entry
1215     noconfigdirs="$noconfigdirs gprof"
1216     ;;
1217   powerpc*-*-winnt* | powerpc*-*-pe*)
1218     target_configdirs="$target_configdirs target-winsup"
1219     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1220     # always build newlib.
1221     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1222     ;;
1223     # This is temporary until we can link against shared libraries
1224   powerpcle-*-solaris*)
1225     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1226     ;;
1227   powerpc-*-beos*)
1228     noconfigdirs="$noconfigdirs gdb"
1229     ;;
1230   rs6000-*-lynxos*)
1231     noconfigdirs="$noconfigdirs gprof"
1232     ;;
1233   rs6000-*-aix*)
1234     noconfigdirs="$noconfigdirs gprof"
1235     ;;
1236   rs6000-*-*)
1237     noconfigdirs="$noconfigdirs gprof"
1238     ;;
1239   m68k-apollo-*)
1240     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1241     ;;
1242   microblaze*)
1243     noconfigdirs="$noconfigdirs gprof"
1244     ;;
1245   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1246     if test x$with_newlib = xyes; then
1247       noconfigdirs="$noconfigdirs gprof"
1248     fi
1249     ;;
1250   mips*-*-irix5*)
1251     noconfigdirs="$noconfigdirs gprof target-libgloss"
1252     ;;
1253   mips*-*-irix6*)
1254     noconfigdirs="$noconfigdirs gprof target-libgloss"
1255     ;;
1256   mips*-*-bsd*)
1257     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1258     ;;
1259   mips*-*-linux*)
1260     ;;
1261   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1262   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1263     noconfigdirs="$noconfigdirs ld gas gprof"
1264     ;;
1265   mips*-*-*)
1266     noconfigdirs="$noconfigdirs gprof"
1267     ;;
1268   nvptx*-*-*)
1269     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1270     ;;
1271   sh-*-*)
1272     case "${target}" in
1273       sh*-*-elf)
1274          ;;
1275       *)
1276          noconfigdirs="$noconfigdirs target-libgloss" ;;
1277     esac
1278     ;;
1279   sparc-*-sunos4*)
1280     if test x${is_cross_compiler} = xno ; then
1281            use_gnu_ld=no
1282     fi
1283     ;;
1284   tic6x-*-*)
1285     noconfigdirs="$noconfigdirs sim"
1286     ;;
1287   tilepro*-*-* | tilegx*-*-*)
1288     noconfigdirs="$noconfigdirs sim"
1289     ;;
1290   v810-*-*)
1291     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1292     ;;
1293   vax-*-*)
1294     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1295     ;;
1296   wasm32-*-*)
1297     noconfigdirs="$noconfigdirs ld"
1298     ;;
1299 esac
1300
1301 # If we aren't building newlib, then don't build libgloss, since libgloss
1302 # depends upon some newlib header files.
1303 case "${noconfigdirs}" in
1304   *target-libgloss*) ;;
1305   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1306 esac
1307
1308 # Work in distributions that contain no compiler tools, like Autoconf.
1309 host_makefile_frag=/dev/null
1310 if test -d ${srcdir}/config ; then
1311 case "${host}" in
1312   i[[3456789]]86-*-msdosdjgpp*)
1313     host_makefile_frag="config/mh-djgpp"
1314     ;;
1315   *-cygwin*)
1316     ACX_CHECK_CYGWIN_CAT_WORKS
1317     host_makefile_frag="config/mh-cygwin"
1318     ;;
1319   *-mingw*)
1320     host_makefile_frag="config/mh-mingw"
1321     ;;
1322   alpha*-linux*)
1323     host_makefile_frag="config/mh-alpha-linux"
1324     ;;
1325   hppa*-hp-hpux10*)
1326     host_makefile_frag="config/mh-pa-hpux10"
1327     ;;
1328   hppa*-hp-hpux*)
1329     host_makefile_frag="config/mh-pa"
1330     ;;
1331   hppa*-*)
1332     host_makefile_frag="config/mh-pa"
1333     ;;
1334   *-*-darwin*)
1335     host_makefile_frag="config/mh-darwin"
1336     ;;
1337   powerpc-*-aix*)
1338     host_makefile_frag="config/mh-ppc-aix"
1339     ;;
1340   rs6000-*-aix*)
1341     host_makefile_frag="config/mh-ppc-aix"
1342     ;;
1343 esac
1344 fi
1345
1346 if test "${build}" != "${host}" ; then
1347   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1348   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1349   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1350   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1351   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1352   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1353   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1354   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1355   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1356   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1357   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1358   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1359   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1360 else
1361   AR_FOR_BUILD="\$(AR)"
1362   AS_FOR_BUILD="\$(AS)"
1363   CC_FOR_BUILD="\$(CC)"
1364   CXX_FOR_BUILD="\$(CXX)"
1365   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1366   GOC_FOR_BUILD="\$(GOC)"
1367   GDC_FOR_BUILD="\$(GDC)"
1368   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1369   LD_FOR_BUILD="\$(LD)"
1370   NM_FOR_BUILD="\$(NM)"
1371   RANLIB_FOR_BUILD="\$(RANLIB)"
1372   WINDRES_FOR_BUILD="\$(WINDRES)"
1373   WINDMC_FOR_BUILD="\$(WINDMC)"
1374 fi
1375
1376 AC_PROG_CC
1377 AC_PROG_CXX
1378
1379 # We must set the default linker to the linker used by gcc for the correct
1380 # operation of libtool.  If LD is not defined and we are using gcc, try to
1381 # set the LD default to the ld used by gcc.
1382 if test -z "$LD"; then
1383   if test "$GCC" = yes; then
1384     case $build in
1385     *-*-mingw*)
1386       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1387     *)
1388       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1389     esac
1390     case $gcc_prog_ld in
1391     # Accept absolute paths.
1392     [[\\/]* | [A-Za-z]:[\\/]*)]
1393       LD="$gcc_prog_ld" ;;
1394     esac
1395   fi
1396 fi
1397
1398 # Check whether -static-libstdc++ -static-libgcc is supported.
1399 have_static_libs=no
1400 if test "$GCC" = yes; then
1401   saved_LDFLAGS="$LDFLAGS"
1402
1403   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1404   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1405   AC_LANG_PUSH(C++)
1406   AC_LINK_IFELSE([AC_LANG_SOURCE([
1407 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1408 #error -static-libstdc++ not implemented
1409 #endif
1410 int main() {}])],
1411     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1412     [AC_MSG_RESULT([no])])
1413   AC_LANG_POP(C++)
1414
1415   LDFLAGS="$saved_LDFLAGS"
1416 fi
1417
1418 ACX_PROG_GNAT
1419 ACX_PROG_CMP_IGNORE_INITIAL
1420
1421 AC_ARG_ENABLE([bootstrap],
1422 [AS_HELP_STRING([--enable-bootstrap],
1423                 [enable bootstrapping @<:@yes if native build@:>@])],,
1424 enable_bootstrap=default)
1425
1426 # Issue errors and warnings for invalid/strange bootstrap combinations.
1427 if test -r $srcdir/gcc/configure; then
1428   have_compiler=yes
1429 else
1430   have_compiler=no
1431 fi
1432
1433 case "$have_compiler:$host:$target:$enable_bootstrap" in
1434   *:*:*:no) ;;
1435
1436   # Default behavior.  Enable bootstrap if we have a compiler
1437   # and we are in a native configuration.
1438   yes:$build:$build:default)
1439     enable_bootstrap=yes ;;
1440
1441   *:*:*:default)
1442     enable_bootstrap=no ;;
1443
1444   # We have a compiler and we are in a native configuration, bootstrap is ok
1445   yes:$build:$build:yes)
1446     ;;
1447
1448   # Other configurations, but we have a compiler.  Assume the user knows
1449   # what he's doing.
1450   yes:*:*:yes)
1451     AC_MSG_WARN([trying to bootstrap a cross compiler])
1452     ;;
1453
1454   # No compiler: if they passed --enable-bootstrap explicitly, fail
1455   no:*:*:yes)
1456     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1457
1458   # Fail if wrong command line
1459   *)
1460     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1461     ;;
1462 esac
1463
1464 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1465 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1466 # require C++11 (or higher).
1467 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1468   CXX="$CXX -std=c++11"
1469 elif test "$have_compiler" = yes; then
1470   AX_CXX_COMPILE_STDCXX(11)
1471
1472   if test "${build}" != "${host}"; then
1473     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1474   fi
1475 fi
1476
1477 # Used for setting $lt_cv_objdir
1478 _LT_CHECK_OBJDIR
1479
1480 # Check for GMP, MPFR and MPC
1481 gmplibs="-lmpc -lmpfr -lgmp"
1482 gmpinc=
1483 have_gmp=no
1484
1485 # Specify a location for mpc
1486 # check for this first so it ends up on the link line before mpfr.
1487 AC_ARG_WITH(mpc,
1488 [AS_HELP_STRING([--with-mpc=PATH],
1489                 [specify prefix directory for installed MPC package.
1490                  Equivalent to --with-mpc-include=PATH/include
1491                  plus --with-mpc-lib=PATH/lib])])
1492 AC_ARG_WITH(mpc-include,
1493 [AS_HELP_STRING([--with-mpc-include=PATH],
1494                 [specify directory for installed MPC include files])])
1495 AC_ARG_WITH(mpc-lib,
1496 [AS_HELP_STRING([--with-mpc-lib=PATH],
1497                 [specify directory for the installed MPC library])])
1498
1499 if test "x$with_mpc" != x; then
1500   gmplibs="-L$with_mpc/lib $gmplibs"
1501   gmpinc="-I$with_mpc/include $gmpinc"
1502 fi
1503 if test "x$with_mpc_include" != x; then
1504   gmpinc="-I$with_mpc_include $gmpinc"
1505 fi
1506 if test "x$with_mpc_lib" != x; then
1507   gmplibs="-L$with_mpc_lib $gmplibs"
1508 fi
1509 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1510   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1511   gmpinc='-I$$s/mpc/src '"$gmpinc"
1512   # Do not test the mpc version.  Assume that it is sufficient, since
1513   # it is in the source tree, and the library has not been built yet
1514   # but it would be included on the link line in the version check below
1515   # hence making the test fail.
1516   have_gmp=yes
1517 fi
1518
1519 # Specify a location for mpfr
1520 # check for this first so it ends up on the link line before gmp.
1521 AC_ARG_WITH(mpfr-dir,
1522 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1523 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1524 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1525
1526 AC_ARG_WITH(mpfr,
1527 [AS_HELP_STRING([--with-mpfr=PATH],
1528                 [specify prefix directory for installed MPFR package.
1529                  Equivalent to --with-mpfr-include=PATH/include
1530                  plus --with-mpfr-lib=PATH/lib])])
1531 AC_ARG_WITH(mpfr-include,
1532 [AS_HELP_STRING([--with-mpfr-include=PATH],
1533                 [specify directory for installed MPFR include files])])
1534 AC_ARG_WITH(mpfr-lib,
1535 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1536                 [specify directory for the installed MPFR library])])
1537
1538 if test "x$with_mpfr" != x; then
1539   gmplibs="-L$with_mpfr/lib $gmplibs"
1540   gmpinc="-I$with_mpfr/include $gmpinc"
1541 fi
1542 if test "x$with_mpfr_include" != x; then
1543   gmpinc="-I$with_mpfr_include $gmpinc"
1544 fi
1545 if test "x$with_mpfr_lib" != x; then
1546   gmplibs="-L$with_mpfr_lib $gmplibs"
1547 fi
1548 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1549   # MPFR v3.1.0 moved the sources into a src sub-directory.
1550   if ! test -d ${srcdir}/mpfr/src; then
1551     AC_MSG_ERROR([dnl
1552 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1553   fi
1554   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1555   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1556   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1557   # Do not test the mpfr version.  Assume that it is sufficient, since
1558   # it is in the source tree, and the library has not been built yet
1559   # but it would be included on the link line in the version check below
1560   # hence making the test fail.
1561   have_gmp=yes
1562 fi
1563
1564 # Specify a location for gmp
1565 AC_ARG_WITH(gmp-dir,
1566 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1567 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1568 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1569
1570 AC_ARG_WITH(gmp,
1571 [AS_HELP_STRING([--with-gmp=PATH],
1572                 [specify prefix directory for the installed GMP package.
1573                  Equivalent to --with-gmp-include=PATH/include
1574                  plus --with-gmp-lib=PATH/lib])])
1575 AC_ARG_WITH(gmp-include,
1576 [AS_HELP_STRING([--with-gmp-include=PATH],
1577                 [specify directory for installed GMP include files])])
1578 AC_ARG_WITH(gmp-lib,
1579 [AS_HELP_STRING([--with-gmp-lib=PATH],
1580                 [specify directory for the installed GMP library])])
1581
1582
1583 if test "x$with_gmp" != x; then
1584   gmplibs="-L$with_gmp/lib $gmplibs"
1585   gmpinc="-I$with_gmp/include $gmpinc"
1586 fi
1587 if test "x$with_gmp_include" != x; then
1588   gmpinc="-I$with_gmp_include $gmpinc"
1589 fi
1590 if test "x$with_gmp_lib" != x; then
1591   gmplibs="-L$with_gmp_lib $gmplibs"
1592 fi
1593 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1594   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1595   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1596   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1597   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1598   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1599   # Do not test the gmp version.  Assume that it is sufficient, since
1600   # it is in the source tree, and the library has not been built yet
1601   # but it would be included on the link line in the version check below
1602   # hence making the test fail.
1603   have_gmp=yes
1604 fi
1605
1606 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1607   have_gmp=yes
1608   saved_CFLAGS="$CFLAGS"
1609   CFLAGS="$CFLAGS $gmpinc"
1610   # Check for the recommended and required versions of GMP.
1611   AC_MSG_CHECKING([for the correct version of gmp.h])
1612   AC_TRY_COMPILE([#include "gmp.h"],[
1613   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1614   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1615   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1616   choke me
1617   #endif
1618   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1619   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1620   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1621   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1622   choke me
1623   #endif
1624   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1625    [AC_MSG_RESULT([no]); have_gmp=no])
1626
1627   # If we have GMP, check the MPFR version.
1628   if test x"$have_gmp" = xyes; then
1629     # Check for the recommended and required versions of MPFR.
1630     AC_MSG_CHECKING([for the correct version of mpfr.h])
1631     AC_TRY_COMPILE([#include <gmp.h>
1632     #include <mpfr.h>],[
1633     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1634     choke me
1635     #endif
1636     ], [AC_TRY_COMPILE([#include <gmp.h>
1637     #include <mpfr.h>],[
1638     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1639     choke me
1640     #endif
1641     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1642      [AC_MSG_RESULT([no]); have_gmp=no])
1643   fi
1644
1645   # Check for the MPC header version.
1646   if test x"$have_gmp" = xyes ; then
1647     # Check for the recommended and required versions of MPC.
1648     AC_MSG_CHECKING([for the correct version of mpc.h])
1649     AC_TRY_COMPILE([#include <mpc.h>],[
1650     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1651     choke me
1652     #endif
1653     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1654     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1655     choke me
1656     #endif
1657     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1658      [AC_MSG_RESULT([no]); have_gmp=no])
1659   fi
1660
1661   # Now check the MPFR library.
1662   if test x"$have_gmp" = xyes; then
1663     saved_LIBS="$LIBS"
1664     LIBS="$LIBS $gmplibs"
1665     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1666     AC_TRY_LINK([#include <mpc.h>],[
1667     mpfr_t n;
1668     mpfr_t x;
1669     mpc_t c;
1670     int t;
1671     mpfr_init (n);
1672     mpfr_init (x);
1673     mpfr_atan2 (n, n, x, MPFR_RNDN);
1674     mpfr_erfc (n, x, MPFR_RNDN);
1675     mpfr_subnormalize (x, t, MPFR_RNDN);
1676     mpfr_clear(n);
1677     mpfr_clear(x);
1678     mpc_init2 (c, 53);
1679     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1680     mpc_cosh (c, c, MPC_RNDNN);
1681     mpc_pow (c, c, c, MPC_RNDNN);
1682     mpc_acosh (c, c, MPC_RNDNN);
1683     mpc_clear (c);
1684     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1685     LIBS="$saved_LIBS"
1686   fi
1687
1688   CFLAGS="$saved_CFLAGS"
1689
1690 # The library versions listed in the error message below should match
1691 # the HARD-minimums enforced above.
1692   if test x$have_gmp != xyes; then
1693     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1694 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1695 their locations.  Source code for these libraries can be found at
1696 their respective hosting sites as well as at
1697 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1698 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1699 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1700 make sure that you have installed both the libraries and the header
1701 files.  They may be located in separate packages.])
1702   fi
1703 fi
1704
1705 # Flags needed for both GMP, MPFR and/or MPC.
1706 AC_SUBST(gmplibs)
1707 AC_SUBST(gmpinc)
1708 AC_SUBST(extra_mpfr_configure_flags)
1709 AC_SUBST(extra_mpc_gmp_configure_flags)
1710 AC_SUBST(extra_mpc_mpfr_configure_flags)
1711 AC_SUBST(extra_isl_gmp_configure_flags)
1712
1713 # Libraries to use for stage1 or when not bootstrapping.
1714 AC_ARG_WITH(stage1-libs,
1715 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1716 [if test "$withval" = "no" -o "$withval" = "yes"; then
1717    stage1_libs=
1718  else
1719    stage1_libs=$withval
1720  fi],
1721 [stage1_libs=])
1722 AC_SUBST(stage1_libs)
1723
1724 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1725 # default is yes if gcc is being built; no otherwise.  The reason for
1726 # this default is that gdb is sometimes linked against GNU Source
1727 # Highlight, which is a shared library that uses C++ exceptions.  In
1728 # this case, -static-libstdc++ will cause crashes.
1729 AC_ARG_WITH(static-standard-libraries,
1730 [AS_HELP_STRING([--with-static-standard-libraries],
1731                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1732 [], [with_static_standard_libraries=auto])
1733 if test "$with_static_standard_libraries" = auto; then
1734   with_static_standard_libraries=$have_compiler
1735 fi
1736
1737 # Linker flags to use for stage1 or when not bootstrapping.
1738 AC_ARG_WITH(stage1-ldflags,
1739 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1740 [if test "$withval" = "no" -o "$withval" = "yes"; then
1741    stage1_ldflags=
1742  else
1743    stage1_ldflags=$withval
1744  fi],
1745 [stage1_ldflags=
1746  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1747  # if supported.  But if the user explicitly specified the libraries to use,
1748  # trust that they are doing what they want.
1749  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1750      -a "$have_static_libs" = yes; then
1751    stage1_ldflags="-static-libstdc++ -static-libgcc"
1752  fi])
1753 AC_SUBST(stage1_ldflags)
1754
1755 # Libraries to use for stage2 and later builds.
1756 AC_ARG_WITH(boot-libs,
1757 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1758 [if test "$withval" = "no" -o "$withval" = "yes"; then
1759    poststage1_libs=
1760  else
1761    poststage1_libs=$withval
1762  fi],
1763 [poststage1_libs=])
1764 AC_SUBST(poststage1_libs)
1765
1766 # Linker flags to use for stage2 and later builds.
1767 AC_ARG_WITH(boot-ldflags,
1768 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1769                 [linker flags for stage2 and later])],
1770 [if test "$withval" = "no" -o "$withval" = "yes"; then
1771    poststage1_ldflags=
1772  else
1773    poststage1_ldflags=$withval
1774  fi],
1775 [poststage1_ldflags=
1776  # In stages 2 and 3, default to linking libstdc++ and libgcc
1777  # statically.  But if the user explicitly specified the libraries to
1778  # use, trust that they are doing what they want.
1779  if test "$poststage1_libs" = ""; then
1780    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1781  fi])
1782 AC_SUBST(poststage1_ldflags)
1783
1784 # GCC GRAPHITE dependency isl.
1785 # Basic setup is inlined here, actual checks are in config/isl.m4
1786
1787 AC_ARG_WITH(isl,
1788   [AS_HELP_STRING(
1789    [--with-isl=PATH],
1790    [Specify prefix directory for the installed isl package.
1791     Equivalent to --with-isl-include=PATH/include
1792     plus --with-isl-lib=PATH/lib])])
1793
1794 # Treat --without-isl as a request to disable
1795 # GRAPHITE support and skip all following checks.
1796 if test "x$with_isl" != "xno"; then
1797   # Check for isl
1798   dnl Provide configure switches and initialize islinc & isllibs
1799   dnl with user input.
1800   ISL_INIT_FLAGS
1801   dnl The versions of isl that work for Graphite
1802   ISL_CHECK_VERSION()
1803   dnl Only execute fail-action, if isl has been requested.
1804   ISL_IF_FAILED([
1805     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1806 fi
1807
1808 # If the isl check failed, disable builds of in-tree variant of isl
1809 if test "x$with_isl" = xno ||
1810    test "x$gcc_cv_isl" = xno; then
1811   noconfigdirs="$noconfigdirs isl"
1812   islinc=
1813 fi
1814
1815 AC_SUBST(isllibs)
1816 AC_SUBST(islinc)
1817
1818 # Check for LTO support.
1819 AC_ARG_ENABLE(lto,
1820 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1821 enable_lto=$enableval,
1822 enable_lto=yes; default_enable_lto=yes)
1823
1824 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1825   build_lto_plugin=yes
1826 ],[if test x"$default_enable_lto" = x"yes" ; then
1827     case $target in
1828       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1829       # On other non-ELF platforms, LTO has yet to be validated.
1830       *) enable_lto=no ;;
1831     esac
1832   else
1833   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1834   # It would also be nice to check the binutils support, but we don't
1835   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1836   # warn during gcc/ subconfigure; unless you're bootstrapping with
1837   # -flto it won't be needed until after installation anyway.
1838     case $target in
1839       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1840       *) if test x"$enable_lto" = x"yes"; then
1841         AC_MSG_ERROR([LTO support is not enabled for this target.])
1842         fi
1843       ;;
1844     esac
1845   fi
1846   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1847   # Build it unless LTO was explicitly disabled.
1848   case $target in
1849     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1850     *) ;;
1851   esac
1852 ])
1853
1854 AC_ARG_ENABLE(linker-plugin-configure-flags,
1855   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1856     [additional flags for configuring linker plugins @<:@none@:>@])],
1857   extra_linker_plugin_configure_flags=$enableval,
1858   extra_linker_plugin_configure_flags=)
1859 AC_SUBST(extra_linker_plugin_configure_flags)
1860 AC_ARG_ENABLE(linker-plugin-flags,
1861   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1862     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1863   extra_linker_plugin_flags=$enableval,
1864   extra_linker_plugin_flags=)
1865 AC_SUBST(extra_linker_plugin_flags)
1866
1867 # Enable --enable-host-shared.
1868 # Checked early to determine whether jit is an 'all' language
1869 AC_ARG_ENABLE(host-shared,
1870 [AS_HELP_STRING([--enable-host-shared],
1871                 [build host code as shared libraries])],
1872 [host_shared=$enableval], [host_shared=no])
1873 AC_SUBST(host_shared)
1874
1875 # By default, C and C++ are the only stage 1 languages.
1876 stage1_languages=,c,
1877
1878 # Target libraries that we bootstrap.
1879 bootstrap_target_libs=,target-libgcc,
1880
1881 # Figure out what language subdirectories are present.
1882 # Look if the user specified --enable-languages="..."; if not, use
1883 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1884 # go away some day.
1885 # NB:  embedded tabs in this IF block -- do not untabify
1886 if test -d ${srcdir}/gcc; then
1887   if test x"${enable_languages+set}" != xset; then
1888     if test x"${LANGUAGES+set}" = xset; then
1889       enable_languages="${LANGUAGES}"
1890         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1891     else
1892       enable_languages=default
1893     fi
1894   else
1895     if test x"${enable_languages}" = x ||
1896        test x"${enable_languages}" = xyes;
1897        then
1898       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1899       exit 1
1900     fi
1901   fi
1902   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1903
1904   # 'f95' is the old name for the 'fortran' language. We issue a warning
1905   # and make the substitution.
1906   case ,${enable_languages}, in
1907     *,f95,*)
1908       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1909       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1910       ;;
1911   esac
1912
1913   # If bootstrapping, C++ must be enabled.
1914   case ",$enable_languages,:$enable_bootstrap" in
1915     *,c++,*:*) ;;
1916     *:yes)
1917       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1918         enable_languages="${enable_languages},c++"
1919       else
1920         AC_MSG_ERROR([bootstrapping requires c++ sources])
1921       fi
1922       ;;
1923   esac
1924
1925   # First scan to see if an enabled language requires some other language.
1926   # We assume that a given config-lang.in will list all the language
1927   # front ends it requires, even if some are required indirectly.
1928   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1929     case ${lang_frag} in
1930       ..) ;;
1931       # The odd quoting in the next line works around
1932       # an apparent bug in bash 1.12 on linux.
1933       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1934       *)
1935         # From the config-lang.in, get $language, $lang_requires, and
1936         # $lang_requires_boot_languages.
1937         language=
1938         lang_requires=
1939         lang_requires_boot_languages=
1940         # set srcdir during sourcing lang_frag to the gcc dir.
1941         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1942         # polutes this shell
1943         saved_srcdir=${srcdir}
1944         srcdir=${srcdir}/gcc . ${lang_frag}
1945         srcdir=${saved_srcdir}
1946         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1947           case ,${enable_languages}, in
1948             *,$other,*) ;;
1949             *,default,*) ;;
1950             *,all,*) ;;
1951             *,$language,*)
1952               echo " \`$other' language required by \`$language'; enabling" 1>&2
1953               enable_languages="${enable_languages},${other}"
1954               ;;
1955           esac
1956         done
1957         for other in ${lang_requires_boot_languages} ; do
1958           if test "$other" != "c"; then
1959             case ,${enable_stage1_languages}, in
1960               *,$other,*) ;;
1961               *,default,*) ;;
1962               *,all,*) ;;
1963               *)
1964                 case ,${enable_languages}, in
1965                   *,$language,*)
1966                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1967                     enable_stage1_languages="$enable_stage1_languages,${other}"
1968                     ;;
1969                 esac
1970                 ;;
1971             esac
1972           fi
1973         done
1974         ;;
1975     esac
1976   done
1977
1978   new_enable_languages=,c,
1979
1980   # If LTO is enabled, add the LTO front end.
1981   if test "$enable_lto" = "yes" ; then
1982     case ,${enable_languages}, in
1983       *,lto,*) ;;
1984       *) enable_languages="${enable_languages},lto" ;;
1985     esac
1986     if test "${build_lto_plugin}" = "yes" ; then
1987       configdirs="$configdirs lto-plugin"
1988     fi
1989   fi
1990
1991   # If we're building an offloading compiler, add the LTO front end.
1992   if test x"$enable_as_accelerator_for" != x ; then
1993     case ,${enable_languages}, in
1994       *,lto,*) ;;
1995       *) enable_languages="${enable_languages},lto" ;;
1996     esac
1997   fi
1998
1999   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2000   potential_languages=,c,
2001
2002   enabled_target_libs=
2003   disabled_target_libs=
2004
2005   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2006     case ${lang_frag} in
2007       ..) ;;
2008       # The odd quoting in the next line works around
2009       # an apparent bug in bash 1.12 on linux.
2010       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2011       *)
2012         # From the config-lang.in, get $language, $target_libs,
2013         # $lang_dirs, $boot_language, and $build_by_default
2014         language=
2015         target_libs=
2016         lang_dirs=
2017         subdir_requires=
2018         boot_language=no
2019         build_by_default=yes
2020         # set srcdir during sourcing.  See above about save & restore
2021         saved_srcdir=${srcdir}
2022         srcdir=${srcdir}/gcc . ${lang_frag}
2023         srcdir=${saved_srcdir}
2024         if test x${language} = x; then
2025           echo "${lang_frag} doesn't set \$language." 1>&2
2026           exit 1
2027         fi
2028
2029         if test "$language" = "c++"; then
2030           boot_language=yes
2031         fi
2032
2033         add_this_lang=no
2034         # C is always enabled, so no need to add it again
2035         if test "$language" != "c"; then
2036           case ,${enable_languages}, in
2037             *,${language},*)
2038               # Language was explicitly selected; include it
2039               add_this_lang=yes
2040               ;;
2041             *,all,*)
2042               # All languages are enabled
2043               add_this_lang=all
2044               ;;
2045             *,default,*)
2046               # 'default' was selected, select it if it is a default language
2047               add_this_lang=${build_by_default}
2048               ;;
2049           esac
2050         fi
2051
2052         # Disable languages that need other directories if these aren't available.
2053         for i in $subdir_requires; do
2054           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2055           case ${add_this_lang} in
2056             yes)
2057               # Specifically requested language; tell them.
2058               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2059               ;;
2060             all)
2061               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2062               add_this_lang=unsupported
2063               ;;
2064             *)
2065               # Silently disable.
2066               add_this_lang=unsupported
2067               ;;
2068           esac
2069         done
2070
2071         # Disable Ada if no preexisting GNAT is available.
2072         case ${add_this_lang}:${language}:${have_gnat} in
2073           yes:ada:no)
2074             # Specifically requested language; tell them.
2075             AC_MSG_ERROR([GNAT is required to build $language])
2076             ;;
2077           all:ada:no)
2078             AC_MSG_WARN([GNAT is required to build $language])
2079             add_this_lang=unsupported
2080             ;;
2081           *:ada:no)
2082             # Silently disable.
2083             add_this_lang=unsupported
2084             ;;
2085         esac
2086
2087         # Disable jit if -enable-host-shared not specified
2088         # but not if building for Mingw. All code in Windows
2089         # is position independent code (PIC).
2090         case $target in
2091           *mingw*) ;;
2092           *)
2093           case ${add_this_lang}:${language}:${host_shared} in
2094             yes:jit:no)
2095                    # PR jit/64780: explicitly specify --enable-host-shared
2096             AC_MSG_ERROR([
2097 Enabling language "jit" requires --enable-host-shared.
2098
2099 --enable-host-shared typically slows the rest of the compiler down by
2100 a few %, so you must explicitly enable it.
2101
2102 If you want to build both the jit and the regular compiler, it is often
2103 best to do this via two separate configure/builds, in separate
2104 directories, to avoid imposing the performance cost of
2105 --enable-host-shared on the regular compiler.])
2106                     ;;
2107             all:jit:no)
2108               AC_MSG_WARN([--enable-host-shared required to build $language])
2109               add_this_lang=unsupported
2110               ;;
2111             *:jit:no)
2112               # Silently disable.
2113               add_this_lang=unsupported
2114               ;;
2115                 esac
2116           ;;
2117         esac
2118
2119         # Disable a language that is unsupported by the target.
2120         case "${add_this_lang}: $unsupported_languages " in
2121           no:*) ;;
2122           unsupported:*) ;;
2123           *:*" $language "*)
2124             AC_MSG_WARN([${language} not supported for this target])
2125             add_this_lang=unsupported
2126             ;;
2127         esac
2128
2129         case $add_this_lang in
2130           unsupported)
2131             # Remove language-dependent dirs.
2132             disabled_target_libs="$disabled_target_libs $target_libs"
2133             noconfigdirs="$noconfigdirs $lang_dirs"
2134             ;;
2135           no)
2136             # Remove language-dependent dirs; still show language as supported.
2137             disabled_target_libs="$disabled_target_libs $target_libs"
2138             noconfigdirs="$noconfigdirs $lang_dirs"
2139             potential_languages="${potential_languages}${language},"
2140             ;;
2141           all|yes)
2142             new_enable_languages="${new_enable_languages}${language},"
2143             potential_languages="${potential_languages}${language},"
2144             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2145             enabled_target_libs="$enabled_target_libs $target_libs"
2146             case "${boot_language}:,$enable_stage1_languages," in
2147               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2148                 # Add to (comma-separated) list of stage 1 languages.
2149                 case ",$stage1_languages," in
2150                   *,$language,* | ,yes, | ,all,) ;;
2151                   *) stage1_languages="${stage1_languages}${language}," ;;
2152                 esac
2153                 # We need to bootstrap any supporting libraries.
2154                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2155                 ;;
2156             esac
2157             ;;
2158         esac
2159         ;;
2160     esac
2161   done
2162
2163   # Add target libraries which are only needed for disabled languages
2164   # to noconfigdirs.
2165   if test -n "$disabled_target_libs"; then
2166     for dir in $disabled_target_libs; do
2167       case " $enabled_target_libs " in
2168       *" ${dir} "*) ;;
2169       *) noconfigdirs="$noconfigdirs $dir" ;;
2170       esac
2171     done
2172   fi
2173
2174   AC_ARG_ENABLE(stage1-languages,
2175   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2176                   [choose additional languages to build during
2177                   stage1.  Mostly useful for compiler development])],
2178   [case ,${enable_stage1_languages}, in
2179     ,no,|,,)
2180       # Set it to something that will have no effect in the loop below
2181       enable_stage1_languages=c ;;
2182     ,yes,)
2183       enable_stage1_languages=`echo $new_enable_languages | \
2184         sed -e "s/^,//" -e "s/,$//" ` ;;
2185     *,all,*)
2186       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2187         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2188   esac
2189
2190   # Add "good" languages from enable_stage1_languages to stage1_languages,
2191   # while "bad" languages go in missing_languages.  Leave no duplicates.
2192   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2193     case $potential_languages in
2194       *,$i,*)
2195         case $stage1_languages in
2196           *,$i,*) ;;
2197           *) stage1_languages="$stage1_languages$i," ;;
2198         esac ;;
2199       *)
2200         case $missing_languages in
2201           *,$i,*) ;;
2202           *) missing_languages="$missing_languages$i," ;;
2203         esac ;;
2204      esac
2205   done])
2206
2207   # Remove leading/trailing commas that were added for simplicity
2208   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2209   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2210   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2211   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2212
2213   if test "x$missing_languages" != x; then
2214     AC_MSG_ERROR([
2215 The following requested languages could not be built: ${missing_languages}
2216 Supported languages are: ${potential_languages}])
2217   fi
2218   if test "x$new_enable_languages" != "x$enable_languages"; then
2219     echo The following languages will be built: ${new_enable_languages}
2220     enable_languages="$new_enable_languages"
2221   fi
2222
2223   AC_SUBST(stage1_languages)
2224   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2225 fi
2226
2227 # Handle --disable-<component> generically.
2228 for dir in $configdirs $build_configdirs $target_configdirs ; do
2229   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2230   varname=`echo $dirname | sed -e s/+/_/g`
2231   if eval test x\${enable_${varname}} "=" xno ; then
2232     noconfigdirs="$noconfigdirs $dir"
2233   fi
2234 done
2235
2236 # Check for Boehm's garbage collector
2237 AC_ARG_ENABLE(objc-gc,
2238 [AS_HELP_STRING([--enable-objc-gc],
2239                 [enable use of Boehm's garbage collector with the
2240                  GNU Objective-C runtime])])
2241 AC_ARG_WITH([target-bdw-gc],
2242 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2243                 [specify prefix directory for installed bdw-gc package.
2244                  Equivalent to --with-target-bdw-gc-include=PATH/include
2245                  plus --with-target-bdw-gc-lib=PATH/lib])])
2246 AC_ARG_WITH([target-bdw-gc-include],
2247 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2248                 [specify directories for installed bdw-gc include files])])
2249 AC_ARG_WITH([target-bdw-gc-lib],
2250 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2251                 [specify directories for installed bdw-gc library])])
2252
2253 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2254   AC_MSG_CHECKING([for bdw garbage collector])
2255   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2256     dnl no bdw-gw options, assume default locations
2257     AC_MSG_RESULT([using bdw-gc in default locations])
2258   else
2259     dnl bdw-gw options, first error checking, complete checking in libobjc
2260     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2261       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2262     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2263       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2264     else
2265       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2266     fi
2267   fi
2268 esac
2269
2270 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2271 case ,${enable_languages}, in
2272   *,c++,*)
2273     # Disable libitm, libsanitizer if we're not building libstdc++
2274     case "${noconfigdirs}" in
2275       *target-libstdc++-v3*)
2276         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2277         ;;
2278       *) ;;
2279     esac
2280     ;;
2281   *)
2282     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2283     ;;
2284 esac
2285
2286 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2287 # $build_configdirs and $target_configdirs.
2288 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2289
2290 notsupp=""
2291 for dir in . $skipdirs $noconfigdirs ; do
2292   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2293   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2294     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2295     if test -r $srcdir/$dirname/configure ; then
2296       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2297         true
2298       else
2299         notsupp="$notsupp $dir"
2300       fi
2301     fi
2302   fi
2303   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2304     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2305     if test -r $srcdir/$dirname/configure ; then
2306       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2307         true
2308       else
2309         notsupp="$notsupp $dir"
2310       fi
2311     fi
2312   fi
2313   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2314     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2315     if test -r $srcdir/$dirname/configure ; then
2316       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2317         true
2318       else
2319         notsupp="$notsupp $dir"
2320       fi
2321     fi
2322   fi
2323 done
2324
2325 # Quietly strip out all directories which aren't configurable in this tree.
2326 # This relies on all configurable subdirectories being autoconfiscated, which
2327 # is now the case.
2328 build_configdirs_all="$build_configdirs"
2329 build_configdirs=
2330 for i in ${build_configdirs_all} ; do
2331   j=`echo $i | sed -e s/build-//g`
2332   if test -f ${srcdir}/$j/configure ; then
2333     build_configdirs="${build_configdirs} $i"
2334   fi
2335 done
2336
2337 configdirs_all="$configdirs"
2338 configdirs=
2339 for i in ${configdirs_all} ; do
2340   if test -f ${srcdir}/$i/configure ; then
2341     configdirs="${configdirs} $i"
2342   fi
2343 done
2344
2345 target_configdirs_all="$target_configdirs"
2346 target_configdirs=
2347 for i in ${target_configdirs_all} ; do
2348   j=`echo $i | sed -e s/target-//g`
2349   if test -f ${srcdir}/$j/configure ; then
2350     target_configdirs="${target_configdirs} $i"
2351   fi
2352 done
2353
2354 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2355 # so we have to add it after the preceding checks.
2356 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2357 then
2358   case " $configdirs " in
2359     *" libiberty "*)
2360       # If we can build libiberty, we can also build libiberty-linker-plugin.
2361       configdirs="$configdirs libiberty-linker-plugin"
2362       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2363         --with-libiberty=../libiberty-linker-plugin";;
2364     *)
2365       AC_MSG_ERROR([libiberty missing]);;
2366   esac
2367 fi
2368
2369 # Sometimes we have special requirements for the host libiberty.
2370 extra_host_libiberty_configure_flags=
2371 extra_host_zlib_configure_flags=
2372 case " $configdirs " in
2373   *" lto-plugin "* | *" libcc1 "*)
2374     # When these are to be built as shared libraries, the same applies to
2375     # libiberty.
2376     extra_host_libiberty_configure_flags=--enable-shared
2377     ;;
2378   *" bfd "*)
2379     # When bfd is to be built as a shared library, the same applies to
2380     # zlib.
2381     if test "$enable_shared" = "yes"; then
2382       extra_host_zlib_configure_flags=--enable-host-shared
2383     fi
2384     ;;
2385 esac
2386 AC_SUBST(extra_host_libiberty_configure_flags)
2387 AC_SUBST(extra_host_zlib_configure_flags)
2388
2389 # Produce a warning message for the subdirs we can't configure.
2390 # This isn't especially interesting in the Cygnus tree, but in the individual
2391 # FSF releases, it's important to let people know when their machine isn't
2392 # supported by the one or two programs in a package.
2393
2394 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2395   # If $appdirs is non-empty, at least one of those directories must still
2396   # be configured, or we error out.  (E.g., if the gas release supports a
2397   # specified target in some subdirs but not the gas subdir, we shouldn't
2398   # pretend that all is well.)
2399   if test -n "$appdirs" ; then
2400     for dir in $appdirs ; do
2401       if test -r $dir/Makefile.in ; then
2402         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2403           appdirs=""
2404           break
2405         fi
2406         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2407           appdirs=""
2408           break
2409         fi
2410       fi
2411     done
2412     if test -n "$appdirs" ; then
2413       echo "*** This configuration is not supported by this package." 1>&2
2414       exit 1
2415     fi
2416   fi
2417   # Okay, some application will build, or we don't care to check.  Still
2418   # notify of subdirs not getting built.
2419   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2420   echo "    ${notsupp}" 1>&2
2421   echo "    (Any other directories should still work fine.)" 1>&2
2422 fi
2423
2424 case "$host" in
2425   *msdosdjgpp*)
2426     enable_gdbtk=no ;;
2427 esac
2428
2429 # To find our prefix, in gcc_cv_tool_prefix.
2430 ACX_TOOL_DIRS
2431
2432 copy_dirs=
2433
2434 AC_ARG_WITH([build-sysroot],
2435   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2436                   [use sysroot as the system root during the build])],
2437   [if test x"$withval" != x ; then
2438      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2439    fi],
2440   [SYSROOT_CFLAGS_FOR_TARGET=])
2441 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2442
2443 AC_ARG_WITH([debug-prefix-map],
2444   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2445                   [map A to B, C to D ... in debug information])],
2446   [if test x"$withval" != x; then
2447      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2448      for debug_map in $withval; do
2449        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2450      done
2451    fi],
2452   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2453 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2454
2455 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2456 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2457 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2458 # We want to ensure that TARGET libraries (which we know are built with
2459 # gcc) are built with "-O2 -g", so include those options when setting
2460 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2461 if test "x$CFLAGS_FOR_TARGET" = x; then
2462   if test "x${is_cross_compiler}" = xyes; then
2463     CFLAGS_FOR_TARGET="-g -O2"
2464   else
2465     CFLAGS_FOR_TARGET=$CFLAGS
2466     case " $CFLAGS " in
2467       *" -O2 "*) ;;
2468       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2469     esac
2470     case " $CFLAGS " in
2471       *" -g "* | *" -g3 "*) ;;
2472       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2473     esac
2474   fi
2475 fi
2476 AC_SUBST(CFLAGS_FOR_TARGET)
2477
2478 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2479   if test "x${is_cross_compiler}" = xyes; then
2480     CXXFLAGS_FOR_TARGET="-g -O2"
2481   else
2482     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2483     case " $CXXFLAGS " in
2484       *" -O2 "*) ;;
2485       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2486     esac
2487     case " $CXXFLAGS " in
2488       *" -g "* | *" -g3 "*) ;;
2489       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2490     esac
2491   fi
2492 fi
2493 AC_SUBST(CXXFLAGS_FOR_TARGET)
2494
2495 AC_SUBST(LDFLAGS_FOR_TARGET)
2496
2497 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2498 # the named directory are copied to $(tooldir)/sys-include.
2499 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2500   if test x${is_cross_compiler} = xno ; then
2501     echo 1>&2 '***' --with-headers is only supported when cross compiling
2502     exit 1
2503   fi
2504   if test x"${with_headers}" != xyes ; then
2505     x=${gcc_cv_tool_prefix}
2506     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2507   fi
2508 fi
2509
2510 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2511 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2512 # are permitted.
2513 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2514   if test x${is_cross_compiler} = xno ; then
2515     echo 1>&2 '***' --with-libs is only supported when cross compiling
2516     exit 1
2517   fi
2518   if test x"${with_libs}" != xyes ; then
2519     # Copy the libraries in reverse order, so that files in the first named
2520     # library override files in subsequent libraries.
2521     x=${gcc_cv_tool_prefix}
2522     for l in ${with_libs}; do
2523       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2524     done
2525   fi
2526 fi
2527
2528 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2529 #
2530 # This is done by determining whether or not the appropriate directory
2531 # is available, and by checking whether or not specific configurations
2532 # have requested that this magic not happen.
2533 #
2534 # The command line options always override the explicit settings in
2535 # configure.ac, and the settings in configure.ac override this magic.
2536 #
2537 # If the default for a toolchain is to use GNU as and ld, and you don't
2538 # want to do that, then you should use the --without-gnu-as and
2539 # --without-gnu-ld options for the configure script.  Similarly, if
2540 # the default is to use the included zlib and you don't want to do that,
2541 # you should use the --with-system-zlib option for the configure script.
2542
2543 if test x${use_gnu_as} = x &&
2544    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2545   with_gnu_as=yes
2546   extra_host_args="$extra_host_args --with-gnu-as"
2547 fi
2548
2549 if test x${use_gnu_ld} = x &&
2550    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2551   with_gnu_ld=yes
2552   extra_host_args="$extra_host_args --with-gnu-ld"
2553 fi
2554
2555 if test x${use_included_zlib} = x &&
2556    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2557   :
2558 else
2559   with_system_zlib=yes
2560   extra_host_args="$extra_host_args --with-system-zlib"
2561 fi
2562
2563 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2564 # can detect this case.
2565
2566 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2567   with_newlib=yes
2568   extra_host_args="$extra_host_args --with-newlib"
2569 fi
2570
2571 # Handle ${copy_dirs}
2572 set fnord ${copy_dirs}
2573 shift
2574 while test $# != 0 ; do
2575   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2576     :
2577   else
2578     echo Copying $1 to $2
2579
2580     # Use the install script to create the directory and all required
2581     # parent directories.
2582     if test -d $2 ; then
2583       :
2584     else
2585       echo >config.temp
2586       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2587     fi
2588
2589     # Copy the directory, assuming we have tar.
2590     # FIXME: Should we use B in the second tar?  Not all systems support it.
2591     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2592
2593     # It is the responsibility of the user to correctly adjust all
2594     # symlinks.  If somebody can figure out how to handle them correctly
2595     # here, feel free to add the code.
2596
2597     echo $1 > $2/COPIED
2598   fi
2599   shift; shift
2600 done
2601
2602 # Determine a target-dependent exec_prefix that the installed
2603 # gcc will search in.  Keep this list sorted by triplet, with
2604 # the *-*-osname triplets last.
2605 md_exec_prefix=
2606 case "${target}" in
2607   i[[34567]]86-pc-msdosdjgpp*)
2608     md_exec_prefix=/dev/env/DJDIR/bin
2609     ;;
2610   *-*-hpux* | \
2611   *-*-nto-qnx* | \
2612   *-*-solaris2*)
2613     md_exec_prefix=/usr/ccs/bin
2614     ;;
2615 esac
2616
2617 extra_arflags_for_target=
2618 extra_nmflags_for_target=
2619 extra_ranlibflags_for_target=
2620 target_makefile_frag=/dev/null
2621 case "${target}" in
2622   spu-*-*)
2623     target_makefile_frag="config/mt-spu"
2624     ;;
2625   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2626     target_makefile_frag="config/mt-sde"
2627     ;;
2628   mipsisa*-*-elfoabi*)
2629     target_makefile_frag="config/mt-mips-elfoabi"
2630     ;;
2631   mips*-*-*linux* | mips*-*-gnu*)
2632     target_makefile_frag="config/mt-mips-gnu"
2633     ;;
2634   nios2-*-elf*)
2635     target_makefile_frag="config/mt-nios2-elf"
2636     ;;
2637   *-*-linux-android*)
2638     target_makefile_frag="config/mt-android"
2639     ;;
2640   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2641     target_makefile_frag="config/mt-gnu"
2642     ;;
2643   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2644     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2645     # commands to handle both 32-bit and 64-bit objects.  These flags are
2646     # harmless if we're using GNU nm or ar.
2647     extra_arflags_for_target=" -X32_64"
2648     extra_nmflags_for_target=" -B -X32_64"
2649     ;;
2650 esac
2651
2652 alphaieee_frag=/dev/null
2653 case $target in
2654   alpha*-*-*)
2655     # This just makes sure to use the -mieee option to build target libs.
2656     # This should probably be set individually by each library.
2657     alphaieee_frag="config/mt-alphaieee"
2658     ;;
2659 esac
2660
2661 # If --enable-target-optspace always use -Os instead of -O2 to build
2662 # the target libraries, similarly if it is not specified, use -Os
2663 # on selected platforms.
2664 ospace_frag=/dev/null
2665 case "${enable_target_optspace}:${target}" in
2666   yes:*)
2667     ospace_frag="config/mt-ospace"
2668     ;;
2669   :d30v-*)
2670     ospace_frag="config/mt-d30v"
2671     ;;
2672   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2673     ospace_frag="config/mt-ospace"
2674     ;;
2675   no:* | :*)
2676     ;;
2677   *)
2678     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2679     ;;
2680 esac
2681
2682 # Some systems (e.g., one of the i386-aix systems the gas testers are
2683 # using) don't handle "\$" correctly, so don't use it here.
2684 tooldir='${exec_prefix}'/${target_noncanonical}
2685 build_tooldir=${tooldir}
2686
2687 # Create a .gdbinit file which runs the one in srcdir
2688 # and tells GDB to look there for source files.
2689
2690 if test -r ${srcdir}/.gdbinit ; then
2691   case ${srcdir} in
2692     .) ;;
2693     *) cat > ./.gdbinit <<EOF
2694 # ${NO_EDIT}
2695 dir ${srcdir}
2696 dir .
2697 source ${srcdir}/.gdbinit
2698 EOF
2699     ;;
2700   esac
2701 fi
2702
2703 # Make sure that the compiler is able to generate an executable.  If it
2704 # can't, we are probably in trouble.  We don't care whether we can run the
2705 # executable--we might be using a cross compiler--we only care whether it
2706 # can be created.  At this point the main configure script has set CC.
2707 we_are_ok=no
2708 echo "int main () { return 0; }" > conftest.c
2709 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2710 if test $? = 0 ; then
2711   if test -s conftest || test -s conftest.exe ; then
2712     we_are_ok=yes
2713   fi
2714 fi
2715 case $we_are_ok in
2716   no)
2717     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2718     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2719     rm -f conftest*
2720     exit 1
2721     ;;
2722 esac
2723 rm -f conftest*
2724
2725 # Decide which environment variable is used to find dynamic libraries.
2726 case "${host}" in
2727   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2728   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2729   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2730   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2731 esac
2732
2733 # On systems where the dynamic library environment variable is PATH,
2734 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2735 # built executables to PATH.
2736 if test "$RPATH_ENVVAR" = PATH; then
2737   GCC_SHLIB_SUBDIR=/shlib
2738 else
2739   GCC_SHLIB_SUBDIR=
2740 fi
2741
2742 # Adjust the toplevel makefile according to whether bootstrap was selected.
2743 case $enable_bootstrap in
2744   yes)
2745     bootstrap_suffix=bootstrap
2746     BUILD_CONFIG=bootstrap-debug
2747     ;;
2748   no)
2749     bootstrap_suffix=no-bootstrap
2750     BUILD_CONFIG=
2751     ;;
2752 esac
2753
2754 AC_MSG_CHECKING(for default BUILD_CONFIG)
2755
2756 AC_ARG_WITH([build-config],
2757   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2758                   [use config/NAME.mk build configuration])],
2759   [case $with_build_config in
2760    yes) with_build_config= ;;
2761    no) with_build_config= BUILD_CONFIG= ;;
2762    esac])
2763
2764 if test "x${with_build_config}" != x; then
2765   BUILD_CONFIG=$with_build_config
2766 else
2767   case $BUILD_CONFIG in
2768   bootstrap-debug)
2769     if echo "int f (void) { return 0; }" > conftest.c &&
2770        ${CC} -c conftest.c &&
2771        mv conftest.o conftest.o.g0 &&
2772        ${CC} -c -g conftest.c &&
2773        mv conftest.o conftest.o.g &&
2774        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2775       :
2776     else
2777       BUILD_CONFIG=
2778     fi
2779     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2780     ;;
2781   esac
2782 fi
2783 AC_MSG_RESULT($BUILD_CONFIG)
2784 AC_SUBST(BUILD_CONFIG)
2785
2786 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2787 AC_MSG_CHECKING([for --enable-vtable-verify])
2788 AC_ARG_ENABLE(vtable-verify,
2789 [AS_HELP_STRING([--enable-vtable-verify],
2790                 [Enable vtable verification feature])],
2791 [case "$enableval" in
2792  yes) enable_vtable_verify=yes ;;
2793  no)  enable_vtable_verify=no ;;
2794  *)   enable_vtable_verify=no;;
2795  esac],
2796 [enable_vtable_verify=no])
2797 AC_MSG_RESULT($enable_vtable_verify)
2798
2799 # Record target_configdirs and the configure arguments for target and
2800 # build configuration in Makefile.
2801 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2802 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2803 bootstrap_fixincludes=no
2804
2805 # If we are building libgomp, bootstrap it.
2806 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2807   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2808 fi
2809
2810 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2811 # or bootstrap-ubsan, bootstrap it.
2812 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2813   case "$BUILD_CONFIG" in
2814     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
2815       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2816       bootstrap_fixincludes=yes
2817       ;;
2818   esac
2819 fi
2820
2821 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2822 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2823    test "$enable_vtable_verify" != no; then
2824   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2825 fi
2826
2827 # Determine whether gdb needs tk/tcl or not.
2828 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2829 # and in that case we want gdb to be built without tk.  Ugh!
2830 # In fact I believe gdb is the *only* package directly dependent on tk,
2831 # so we should be able to put the 'maybe's in unconditionally and
2832 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2833 # 100% sure that that's safe though.
2834
2835 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2836 case "$enable_gdbtk" in
2837   no)
2838     GDB_TK="" ;;
2839   yes)
2840     GDB_TK="${gdb_tk}" ;;
2841   *)
2842     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2843     # distro.  Eventually someone will fix this and move Insight, nee
2844     # gdbtk to a separate directory.
2845     if test -d ${srcdir}/gdb/gdbtk ; then
2846       GDB_TK="${gdb_tk}"
2847     else
2848       GDB_TK=""
2849     fi
2850     ;;
2851 esac
2852 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2853 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2854
2855 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2856 # else does, only include them if one of these is built.  The Makefile
2857 # provides the ordering, so it's enough here to add to the list.
2858 case " ${configdirs} " in
2859   *\ gdb\ *)
2860     configdirs="${configdirs} gnulib gdbsupport"
2861     ;;
2862   *\ gdbserver\ *)
2863     configdirs="${configdirs} gnulib gdbsupport"
2864     ;;
2865 esac
2866
2867 # Strip out unwanted targets.
2868
2869 # While at that, we remove Makefiles if we were started for recursive
2870 # configuration, so that the top-level Makefile reconfigures them,
2871 # like we used to do when configure itself was recursive.
2872
2873 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2874 # but now we're fixing up the Makefile ourselves with the additional
2875 # commands passed to AC_CONFIG_FILES.  Use separate variables
2876 # extrasub-{build,host,target} not because there is any reason to split
2877 # the substitutions up that way, but only to remain below the limit of
2878 # 99 commands in a script, for HP-UX sed.
2879
2880 # Do not nest @if/@endif or @unless/@endunless pairs, because
2881 # configure will not warn you at all.
2882
2883 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2884   yes:yes:*\ gold\ *:*,c++,*) ;;
2885   yes:yes:*\ gold\ *:*)
2886     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2887     ;;
2888 esac
2889
2890 extrasub_build=
2891 for module in ${build_configdirs} ; do
2892   if test -z "${no_recursion}" \
2893      && test -f ${build_subdir}/${module}/Makefile; then
2894     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2895     rm -f ${build_subdir}/${module}/Makefile
2896   fi
2897   extrasub_build="$extrasub_build
2898 /^@if build-$module\$/d
2899 /^@endif build-$module\$/d
2900 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2901 /^@if build-$module-$bootstrap_suffix\$/d
2902 /^@endif build-$module-$bootstrap_suffix\$/d
2903 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2904 done
2905 extrasub_host=
2906 for module in ${configdirs} ; do
2907   if test -z "${no_recursion}"; then
2908     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2909       if test -f ${file}; then
2910         echo 1>&2 "*** removing ${file} to force reconfigure"
2911         rm -f ${file}
2912       fi
2913     done
2914   fi
2915   case ${module},${bootstrap_fixincludes} in
2916     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2917     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2918   esac
2919   extrasub_host="$extrasub_host
2920 /^@if $module\$/d
2921 /^@endif $module\$/d
2922 /^@unless $module\$/,/^@endunless $module\$/d
2923 /^@if $module-$host_bootstrap_suffix\$/d
2924 /^@endif $module-$host_bootstrap_suffix\$/d
2925 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2926 done
2927 extrasub_target=
2928 for module in ${target_configdirs} ; do
2929   if test -z "${no_recursion}" \
2930      && test -f ${target_subdir}/${module}/Makefile; then
2931     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2932     rm -f ${target_subdir}/${module}/Makefile
2933   fi
2934
2935   # We only bootstrap target libraries listed in bootstrap_target_libs.
2936   case $bootstrap_target_libs in
2937     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2938     *) target_bootstrap_suffix=no-bootstrap ;;
2939   esac
2940
2941   extrasub_target="$extrasub_target
2942 /^@if target-$module\$/d
2943 /^@endif target-$module\$/d
2944 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2945 /^@if target-$module-$target_bootstrap_suffix\$/d
2946 /^@endif target-$module-$target_bootstrap_suffix\$/d
2947 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2948 done
2949
2950 # Do the final fixup along with target modules.
2951 extrasub_target="$extrasub_target
2952 /^@if /,/^@endif /d
2953 /^@unless /d
2954 /^@endunless /d"
2955
2956 # Create the serialization dependencies.  This uses a temporary file.
2957
2958 AC_ARG_ENABLE([serial-configure],
2959 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2960                 [force sequential configuration of
2961                  sub-packages for the host, target or build
2962                  machine, or all sub-packages])])
2963
2964 case ${enable_serial_configure} in
2965   yes)
2966     enable_serial_build_configure=yes
2967     enable_serial_host_configure=yes
2968     enable_serial_target_configure=yes
2969     ;;
2970 esac
2971
2972 # These force 'configure's to be done one at a time, to avoid problems
2973 # with contention over a shared config.cache.
2974 rm -f serdep.tmp
2975 echo '# serdep.tmp' > serdep.tmp
2976 olditem=
2977 test "x${enable_serial_build_configure}" = xyes &&
2978 for item in ${build_configdirs} ; do
2979   case ${olditem} in
2980     "") ;;
2981     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2982   esac
2983   olditem=${item}
2984 done
2985 olditem=
2986 test "x${enable_serial_host_configure}" = xyes &&
2987 for item in ${configdirs} ; do
2988   case ${olditem} in
2989     "") ;;
2990     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2991   esac
2992   olditem=${item}
2993 done
2994 olditem=
2995 test "x${enable_serial_target_configure}" = xyes &&
2996 for item in ${target_configdirs} ; do
2997   case ${olditem} in
2998     "") ;;
2999     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3000   esac
3001   olditem=${item}
3002 done
3003 serialization_dependencies=serdep.tmp
3004 AC_SUBST_FILE(serialization_dependencies)
3005
3006 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3007 # target, nonopt, and variable assignments.  These are the ones we
3008 # might not want to pass down to subconfigures.  The exception being
3009 # --cache-file=/dev/null, which is used to turn off the use of cache
3010 # files altogether, and which should be passed on to subconfigures.
3011 # Also strip program-prefix, program-suffix, and program-transform-name,
3012 # so that we can pass down a consistent program-transform-name.
3013 baseargs=
3014 tbaseargs=
3015 keep_next=no
3016 skip_next=no
3017 eval "set -- $ac_configure_args"
3018 for ac_arg
3019 do
3020   if test X"$skip_next" = X"yes"; then
3021     skip_next=no
3022     continue
3023   fi
3024   if test X"$keep_next" = X"yes"; then
3025     case $ac_arg in
3026       *\'*)
3027         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3028     esac
3029     baseargs="$baseargs '$ac_arg'"
3030     tbaseargs="$tbaseargs '$ac_arg'"
3031     keep_next=no
3032     continue
3033   fi
3034
3035   # Handle separated arguments.  Based on the logic generated by
3036   # autoconf 2.59.
3037   case $ac_arg in
3038     *=* | --config-cache | -C | -disable-* | --disable-* \
3039       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3040       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3041       | -with-* | --with-* | -without-* | --without-* | --x)
3042       separate_arg=no
3043       ;;
3044     -*)
3045       separate_arg=yes
3046       ;;
3047     *)
3048       separate_arg=no
3049       ;;
3050   esac
3051
3052   skip_targ=no
3053   case $ac_arg in
3054 changequote(,)
3055   --with-* | --without-*)
3056     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3057
3058     case $libopt in
3059     *[-_]include)
3060       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3061       ;;
3062     *[-_]lib)
3063       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3064       ;;
3065     *)
3066       lib=$libopt
3067       ;;
3068     esac
3069 changequote([,])
3070
3071     case $lib in
3072     mpc | mpfr | gmp | isl)
3073       # If we're processing --with-$lib, --with-$lib-include or
3074       # --with-$lib-lib, for one of the libs above, and target is
3075       # different from host, don't pass the current argument to any
3076       # target library's configure.
3077       if test x$is_cross_compiler = xyes; then
3078         skip_targ=yes
3079       fi
3080       ;;
3081     esac
3082     ;;
3083   esac
3084
3085   case "$ac_arg" in
3086     --cache-file=/dev/null | \
3087     -cache-file=/dev/null )
3088       # Handled here to avoid the test to skip args below.
3089       baseargs="$baseargs '$ac_arg'"
3090       tbaseargs="$tbaseargs '$ac_arg'"
3091       # Assert: $separate_arg should always be no.
3092       keep_next=$separate_arg
3093       ;;
3094     --no*)
3095       continue
3096       ;;
3097     --c* | \
3098     --sr* | \
3099     --ho* | \
3100     --bu* | \
3101     --t* | \
3102     --program-* | \
3103     -cache_file* | \
3104     -srcdir* | \
3105     -host* | \
3106     -build* | \
3107     -target* | \
3108     -program-prefix* | \
3109     -program-suffix* | \
3110     -program-transform-name* )
3111       skip_next=$separate_arg
3112       continue
3113       ;;
3114     -*)
3115       # An option.  Add it.
3116       case $ac_arg in
3117         *\'*)
3118           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3119       esac
3120       baseargs="$baseargs '$ac_arg'"
3121       if test X"$skip_targ" = Xno; then
3122         tbaseargs="$tbaseargs '$ac_arg'"
3123       fi
3124       keep_next=$separate_arg
3125       ;;
3126     *)
3127       # Either a variable assignment, or a nonopt (triplet).  Don't
3128       # pass it down; let the Makefile handle this.
3129       continue
3130       ;;
3131   esac
3132 done
3133 # Remove the initial space we just introduced and, as these will be
3134 # expanded by make, quote '$'.
3135 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3136
3137 # Add in --program-transform-name, after --program-prefix and
3138 # --program-suffix have been applied to it.  Autoconf has already
3139 # doubled dollar signs and backslashes in program_transform_name; we want
3140 # the backslashes un-doubled, and then the entire thing wrapped in single
3141 # quotes, because this will be expanded first by make and then by the shell.
3142 # Also, because we want to override the logic in subdir configure scripts to
3143 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3144 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3145 ${program_transform_name}
3146 EOF_SED
3147 gcc_transform_name=`cat conftestsed.out`
3148 rm -f conftestsed.out
3149 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3150 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3151 if test "$silent" = yes; then
3152   baseargs="$baseargs --silent"
3153   tbaseargs="$tbaseargs --silent"
3154 fi
3155 baseargs="$baseargs --disable-option-checking"
3156 tbaseargs="$tbaseargs --disable-option-checking"
3157
3158 # Record and document user additions to sub configure arguments.
3159 AC_ARG_VAR([build_configargs],
3160            [additional configure arguments for build directories])
3161 AC_ARG_VAR([host_configargs],
3162            [additional configure arguments for host directories])
3163 AC_ARG_VAR([target_configargs],
3164            [additional configure arguments for target directories])
3165
3166 # For the build-side libraries, we just need to pretend we're native,
3167 # and not use the same cache file.  Multilibs are neither needed nor
3168 # desired.  We can't even use the same cache file for all build-side
3169 # libraries, as they're compiled differently; some with C, some with
3170 # C++ or with different feature-enabling options.
3171 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3172
3173 # For host modules, accept cache file option, or specification as blank.
3174 case "${cache_file}" in
3175 "") # empty
3176   cache_file_option="" ;;
3177 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3178   cache_file_option="--cache-file=${cache_file}" ;;
3179 *) # relative path
3180   cache_file_option="--cache-file=../${cache_file}" ;;
3181 esac
3182
3183 # Host dirs don't like to share a cache file either, horribly enough.
3184 # This seems to be due to autoconf 2.5x stupidity.
3185 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3186
3187 target_configargs="$target_configargs ${tbaseargs}"
3188
3189 # Passing a --with-cross-host argument lets the target libraries know
3190 # whether they are being built with a cross-compiler or being built
3191 # native.  However, it would be better to use other mechanisms to make the
3192 # sorts of decisions they want to make on this basis.  Please consider
3193 # this option to be deprecated.  FIXME.
3194 if test x${is_cross_compiler} = xyes ; then
3195   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3196 fi
3197
3198 # Special user-friendly check for native x86_64-linux build, if
3199 # multilib is not explicitly enabled.
3200 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3201   x86_64-*linux*:yes:$build:$build:)
3202     # Make sure we have a development environment that handles 32-bit
3203     dev64=no
3204     echo "int main () { return 0; }" > conftest.c
3205     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3206     if test $? = 0 ; then
3207       if test -s conftest || test -s conftest.exe ; then
3208         dev64=yes
3209       fi
3210     fi
3211     rm -f conftest*
3212     if test x${dev64} != xyes ; then
3213       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3214     fi
3215     ;;
3216 esac
3217
3218 # Default to --enable-multilib.
3219 if test x${enable_multilib} = x ; then
3220   target_configargs="--enable-multilib ${target_configargs}"
3221 fi
3222
3223 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3224 # changed from the earlier setting of with_newlib.
3225 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3226   target_configargs="--with-newlib ${target_configargs}"
3227 fi
3228
3229 # Different target subdirs use different values of certain variables
3230 # (notably CXX).  Worse, multilibs use *lots* of different values.
3231 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3232 # it doesn't automatically accept command-line overrides of them.
3233 # This means it's not safe for target subdirs to share a cache file,
3234 # which is disgusting, but there you have it.  Hopefully this can be
3235 # fixed in future.  It's still worthwhile to use a cache file for each
3236 # directory.  I think.
3237
3238 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3239 # We need to pass --target, as newer autoconf's requires consistency
3240 # for target_alias and gcc doesn't manage it consistently.
3241 target_configargs="--cache-file=./config.cache ${target_configargs}"
3242
3243 FLAGS_FOR_TARGET=
3244 case " $target_configdirs " in
3245  *" newlib "*)
3246   case " $target_configargs " in
3247   *" --with-newlib "*)
3248    case "$target" in
3249     *-cygwin*)
3250       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3251       ;;
3252    esac
3253
3254    # If we're not building GCC, don't discard standard headers.
3255    if test -d ${srcdir}/gcc; then
3256      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3257
3258      if test "${build}" != "${host}"; then
3259        # On Canadian crosses, CC_FOR_TARGET will have already been set
3260        # by `configure', so we won't have an opportunity to add -Bgcc/
3261        # to it.  This is right: we don't want to search that directory
3262        # for binaries, but we want the header files in there, so add
3263        # them explicitly.
3264        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3265
3266        # Someone might think of using the pre-installed headers on
3267        # Canadian crosses, in case the installed compiler is not fully
3268        # compatible with the compiler being built.  In this case, it
3269        # would be better to flag an error than risking having
3270        # incompatible object files being constructed.  We can't
3271        # guarantee that an error will be flagged, but let's hope the
3272        # compiler will do it, when presented with incompatible header
3273        # files.
3274      fi
3275    fi
3276
3277    case "${target}-${is_cross_compiler}" in
3278    i[[3456789]]86-*-linux*-no)
3279       # Here host == target, so we don't need to build gcc,
3280       # so we don't want to discard standard headers.
3281       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3282       ;;
3283    *)
3284       # If we're building newlib, use its generic headers last, but search
3285       # for any libc-related directories first (so make it the last -B
3286       # switch).
3287       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3288
3289       # If we're building libgloss, find the startup file, simulator library
3290       # and linker script.
3291       case " $target_configdirs " in
3292         *" libgloss "*)
3293         # Look for startup file, simulator library and maybe linker script.
3294         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3295         # Look for libnosys.a in case the target needs it.
3296         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3297         # Most targets have the linker script in the source directory.
3298         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3299         ;;
3300       esac
3301       ;;
3302    esac
3303    ;;
3304   esac
3305   ;;
3306 esac
3307
3308 case "$target" in
3309   x86_64-*mingw* | *-w64-mingw*)
3310   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3311   # however, use a symlink named 'mingw' in ${prefix} .
3312     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3313     ;;
3314   *-mingw*)
3315   # MinGW can't be handled as Cygwin above since it does not use newlib.
3316     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3317     ;;
3318 esac
3319
3320 # Allow the user to override the flags for
3321 # our build compiler if desired.
3322 if test x"${build}" = x"${host}" ; then
3323   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3324   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3325   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3326 fi
3327
3328 # On Canadian crosses, we'll be searching the right directories for
3329 # the previously-installed cross compiler, so don't bother to add
3330 # flags for directories within the install tree of the compiler
3331 # being built; programs in there won't even run.
3332 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3333   # Search for pre-installed headers if nothing else fits.
3334   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3335 fi
3336
3337 if test "x${use_gnu_ld}" = x &&
3338    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3339   # Arrange for us to find uninstalled linker scripts.
3340   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3341 fi
3342
3343 # Search for other target-specific linker scripts and such.
3344 case "${target}" in
3345   mep*)
3346     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3347     ;;
3348 esac
3349
3350 # Makefile fragments.
3351 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3352 do
3353   eval fragval=\$$frag
3354   if test $fragval != /dev/null; then
3355     eval $frag=${srcdir}/$fragval
3356   fi
3357 done
3358 AC_SUBST_FILE(host_makefile_frag)
3359 AC_SUBST_FILE(target_makefile_frag)
3360 AC_SUBST_FILE(alphaieee_frag)
3361 AC_SUBST_FILE(ospace_frag)
3362
3363 # Miscellanea: directories, flags, etc.
3364 AC_SUBST(RPATH_ENVVAR)
3365 AC_SUBST(GCC_SHLIB_SUBDIR)
3366 AC_SUBST(tooldir)
3367 AC_SUBST(build_tooldir)
3368 AC_SUBST(CONFIGURE_GDB_TK)
3369 AC_SUBST(GDB_TK)
3370 AC_SUBST(INSTALL_GDB_TK)
3371
3372 # Build module lists & subconfigure args.
3373 AC_SUBST(build_configargs)
3374 AC_SUBST(build_configdirs)
3375
3376 # Host module lists & subconfigure args.
3377 AC_SUBST(host_configargs)
3378 AC_SUBST(configdirs)
3379 AC_SUBST(target_configdirs)
3380
3381 # Target module lists & subconfigure args.
3382 AC_SUBST(target_configargs)
3383
3384
3385 # Build tools.
3386 AC_SUBST(AR_FOR_BUILD)
3387 AC_SUBST(AS_FOR_BUILD)
3388 AC_SUBST(CC_FOR_BUILD)
3389 AC_SUBST(CFLAGS_FOR_BUILD)
3390 AC_SUBST(CXXFLAGS_FOR_BUILD)
3391 AC_SUBST(CXX_FOR_BUILD)
3392 AC_SUBST(DLLTOOL_FOR_BUILD)
3393 AC_SUBST(GFORTRAN_FOR_BUILD)
3394 AC_SUBST(GOC_FOR_BUILD)
3395 AC_SUBST(GDC_FOR_BUILD)
3396 AC_SUBST(LDFLAGS_FOR_BUILD)
3397 AC_SUBST(LD_FOR_BUILD)
3398 AC_SUBST(NM_FOR_BUILD)
3399 AC_SUBST(RANLIB_FOR_BUILD)
3400 AC_SUBST(WINDMC_FOR_BUILD)
3401 AC_SUBST(WINDRES_FOR_BUILD)
3402
3403 # Generate default definitions for YACC, M4, LEX and other programs that run
3404 # on the build machine.  These are used if the Makefile can't locate these
3405 # programs in objdir.
3406 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3407
3408 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3409 case " $build_configdirs " in
3410   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3411 esac
3412
3413 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3414 case " $build_configdirs " in
3415   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3416 esac
3417
3418 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3419 case " $build_configdirs " in
3420   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3421 esac
3422
3423 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3424 case " $build_configdirs " in
3425   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3426   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3427 esac
3428
3429 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3430 case " $build_configdirs " in
3431   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3432 esac
3433
3434 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3435 case " $build_configdirs " in
3436   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3437   *)
3438 changequote(,)
3439     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3440     # higher, else we use the "missing" dummy.
3441     if ${MAKEINFO} --version \
3442        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3443       :
3444     else
3445       MAKEINFO="$MISSING makeinfo"
3446     fi
3447     ;;
3448 changequote([,])
3449 esac
3450
3451 # FIXME: expect and dejagnu may become build tools?
3452
3453 AC_CHECK_PROGS(EXPECT, expect, expect)
3454 case " $configdirs " in
3455   *" expect "*)
3456     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3457     ;;
3458 esac
3459
3460 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3461 case " $configdirs " in
3462   *" dejagnu "*)
3463     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3464     ;;
3465 esac
3466
3467
3468 # Host tools.
3469 NCN_STRICT_CHECK_TOOLS(AR, ar)
3470 NCN_STRICT_CHECK_TOOLS(AS, as)
3471 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3472 NCN_STRICT_CHECK_TOOLS(LD, ld)
3473 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3474 NCN_STRICT_CHECK_TOOLS(NM, nm)
3475 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3476 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3477 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3478 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3479 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3480 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3481 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3482 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3483 AC_SUBST(CC)
3484 AC_SUBST(CXX)
3485 AC_SUBST(CFLAGS)
3486 AC_SUBST(CXXFLAGS)
3487
3488 # Target tools.
3489 AC_ARG_WITH([build-time-tools],
3490   [AS_HELP_STRING([--with-build-time-tools=PATH],
3491                   [use given path to find target tools during the build])],
3492   [case x"$withval" in
3493      x/*) ;;
3494      *)
3495        with_build_time_tools=
3496        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3497        ;;
3498    esac],
3499   [with_build_time_tools=])
3500
3501 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3502 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3503 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3504 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3505 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3506 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3507
3508 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3509 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3510 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3511 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3512 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3513 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3514 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3515 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3516 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3517 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3518 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3519 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3520 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3521 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3522
3523 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3524
3525 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3526 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3527 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3528 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3529 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3530                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3531                 c++)
3532 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3533                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3534                 c++)
3535 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3536 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3537 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3538                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3539 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3540                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3541 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3542                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3543 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3544 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3545 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3546 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3547 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3548 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3549 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3550 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3551 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3552 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3553 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3554
3555 AC_SUBST(FLAGS_FOR_TARGET)
3556 AC_SUBST(RAW_CXX_FOR_TARGET)
3557
3558 # Certain tools may need extra flags.
3559 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3560 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3561 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3562
3563 # When building target libraries, except in a Canadian cross, we use
3564 # the same toolchain as the compiler we just built.
3565 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3566 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3567 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3568 if test $host = $build; then
3569   case " $configdirs " in
3570     *" gcc "*)
3571       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3572       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3573       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3574       ;;
3575   esac
3576 fi
3577
3578 AC_SUBST(COMPILER_AS_FOR_TARGET)
3579 AC_SUBST(COMPILER_LD_FOR_TARGET)
3580 AC_SUBST(COMPILER_NM_FOR_TARGET)
3581
3582 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3583 AC_ARG_ENABLE(maintainer-mode,
3584 [AS_HELP_STRING([--enable-maintainer-mode],
3585                 [enable make rules and dependencies not useful
3586                  (and sometimes confusing) to the casual installer])],
3587       USE_MAINTAINER_MODE=$enableval,
3588       USE_MAINTAINER_MODE=no)
3589 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3590 AC_SUBST(MAINTAINER_MODE_TRUE)
3591 AC_SUBST(MAINTAINER_MODE_FALSE)
3592 if test "$USE_MAINTAINER_MODE" = yes; then
3593   MAINTAINER_MODE_TRUE=
3594   MAINTAINER_MODE_FALSE='#'
3595 else
3596   MAINTAINER_MODE_TRUE='#'
3597   MAINTAINER_MODE_FALSE=
3598 fi
3599 MAINT=$MAINTAINER_MODE_TRUE
3600 AC_SUBST(MAINT)dnl
3601
3602 # ---------------------
3603 # GCC bootstrap support
3604 # ---------------------
3605
3606 # Stage specific cflags for build.
3607 stage1_cflags="-g"
3608 case $build in
3609   vax-*-*)
3610     case ${GCC} in
3611       yes) stage1_cflags="-g -Wa,-J" ;;
3612       *) stage1_cflags="-g -J" ;;
3613     esac ;;
3614 esac
3615
3616 AC_SUBST(stage1_cflags)
3617
3618 # Enable --enable-checking in stage1 of the compiler.
3619 AC_ARG_ENABLE(stage1-checking,
3620 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3621                 [choose additional checking for stage1 of the compiler])],
3622 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3623 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3624   # For --disable-checking or implicit --enable-checking=release, avoid
3625   # setting --enable-checking=gc in the default stage1 checking for LTO
3626   # bootstraps.  See PR62077.
3627   case $BUILD_CONFIG in
3628     *lto*)
3629       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3630     *)
3631       stage1_checking=--enable-checking=yes,types;;
3632   esac
3633   if test "x$enable_checking" = x && \
3634      test -d ${srcdir}/gcc && \
3635      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3636     stage1_checking=--enable-checking=yes,types,extra
3637   fi
3638 else
3639   stage1_checking=--enable-checking=$enable_checking,types
3640 fi])
3641 AC_SUBST(stage1_checking)
3642
3643 # Enable -Werror in bootstrap stage2 and later.
3644 AC_ARG_ENABLE(werror,
3645 [AS_HELP_STRING([--enable-werror],
3646                 [enable -Werror in bootstrap stage2 and later])],
3647 [
3648 case ${enable_werror} in
3649   yes) stage2_werror_flag="--enable-werror-always" ;;
3650   *) stage2_werror_flag="" ;;
3651 esac
3652 ],
3653 [
3654 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3655   case $BUILD_CONFIG in
3656   bootstrap-debug)
3657       stage2_werror_flag="--enable-werror-always" ;;
3658   "")
3659       stage2_werror_flag="--enable-werror-always" ;;
3660   esac
3661 fi
3662 ])
3663
3664 AC_SUBST(stage2_werror_flag)
3665
3666 # Specify what files to not compare during bootstrap.
3667
3668 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3669 case "$target" in
3670   hppa*64*-*-hpux*) ;;
3671   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3672   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3673 esac
3674 AC_SUBST(compare_exclusions)
3675
3676 AC_CONFIG_FILES([Makefile],
3677   [sed "$extrasub_build" Makefile |
3678    sed "$extrasub_host" |
3679    sed "$extrasub_target" > mf$$
3680    mv -f mf$$ Makefile],
3681   [extrasub_build="$extrasub_build"
3682    extrasub_host="$extrasub_host"
3683    extrasub_target="$extrasub_target"])
3684 AC_OUTPUT