configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2022 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libiconv libctf libsframe"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gm2tools gotools c++tools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-libatomic \
 154                 target-libitm \
 155                 target-libstdc++-v3 \
 156                 target-libsanitizer \
 157                 target-libvtv \
 158                 target-libssp \
 159                 target-libquadmath \
 160                 target-libgfortran \
 161                 target-libffi \
 162                 target-libobjc \
 163                 target-libada \
 164                 target-libgm2 \
 165                 target-libgo \
 166                 target-libphobos \
 167                 target-zlib"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 251 # is provided.
 252 if test x$with_system_readline = xyes ; then
 253   noconfigdirs="$noconfigdirs readline"
 254 fi
 255
 256 # some tools are so dependent upon X11 that if we're not building with X,
 257 # it's not even worth trying to configure, much less build, that tool.
 258
 259 case ${with_x} in
 260   yes | "") ;; # the default value for this tree is that X11 is available
 261   no)
 262     skipdirs="${skipdirs} tk itcl libgui"
 263     # We won't be able to build gdbtk without X.
 264     enable_gdbtk=no
 265     ;;
 266   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 267 esac
 268
 269 # Some are only suitable for cross toolchains.
 270 # Remove these if host=target.
 271 cross_only="target-libgloss target-newlib target-opcodes"
 272
 273 case $is_cross_compiler in
 274   no) skipdirs="${skipdirs} ${cross_only}" ;;
 275 esac
 276
 277 # If both --with-headers and --with-libs are specified, default to
 278 # --without-newlib.
 279 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 280    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 281   if test x"${with_newlib}" = x ; then
 282     with_newlib=no
 283   fi
 284 fi
 285
 286 # Recognize --with-newlib/--without-newlib.
 287 case ${with_newlib} in
 288   no) skipdirs="${skipdirs} target-newlib" ;;
 289   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 290 esac
 291
 292 AC_ARG_ENABLE(as-accelerator-for,
 293 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 294                 [build as offload target compiler.
 295                 Specify offload host triple by ARG])])
 296
 297 AC_ARG_ENABLE(offload-targets,
 298 [AS_HELP_STRING([--enable-offload-targets=LIST],
 299                 [enable offloading to devices from comma-separated LIST of
 300                 TARGET[=DIR]. Use optional path to find offload target compiler
 301                 during the build])],
 302 [
 303   if test x"$enable_offload_targets" = x; then
 304     AC_MSG_ERROR([no offload targets specified])
 305   fi
 306 ], [enable_offload_targets=])
 307
 308 AC_ARG_ENABLE(offload-defaulted,
 309 [AS_HELP_STRING([--enable-offload-defaulted]
 310                 [If enabled, configured but not installed offload compilers and
 311                 libgomp plugins are silently ignored.  Useful for distribution
 312                 compilers where those are in separate optional packages.])],
 313 [enable_offload_defaulted=$enableval],
 314 [enable_offload_defaulted=])
 315
 316 # Handle --enable-gold, --enable-ld.
 317 # --disable-gold [--enable-ld]
 318 #     Build only ld.  Default option.
 319 # --enable-gold [--enable-ld]
 320 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 321 #     as "ld.bfd" and "ld".
 322 # --enable-gold=default [--enable-ld]
 323 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 324 #     install ld as "ld.bfd".
 325 # --enable-gold[=default] --disable-ld
 326 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 327 # --enable-gold --enable-ld=default
 328 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 329 #     and ld.bfd).
 330 #     In other words, ld is default
 331 # --enable-gold=default --enable-ld=default
 332 #     Error.
 333
 334 default_ld=
 335 AC_ARG_ENABLE(gold,
 336 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 337                 [build gold @<:@ARG={default,yes,no}@:>@])],
 338 ENABLE_GOLD=$enableval,
 339 ENABLE_GOLD=no)
 340 case "${ENABLE_GOLD}" in
 341   yes|default)
 342     # Check for ELF target.
 343     is_elf=no
 344     case "${target}" in
 345       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 346       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 347       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 348       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 349         case "${target}" in
 350           *-*-linux*aout* | *-*-linux*oldld*)
 351             ;;
 352           *)
 353             is_elf=yes
 354             ;;
 355         esac
 356     esac
 357
 358     if test "$is_elf" = "yes"; then
 359       # Check for target supported by gold.
 360       case "${target}" in
 361         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 362         | aarch64*-*-* | mips*-*-* | s390*-*-* | loongarch*-*-*)
 363           configdirs="$configdirs gold"
 364           if test x${ENABLE_GOLD} = xdefault; then
 365             default_ld=gold
 366           fi
 367           ENABLE_GOLD=yes
 368           ;;
 369       esac
 370     fi
 371     ;;
 372   no)
 373     ;;
 374   *)
 375     AC_MSG_ERROR([invalid --enable-gold argument])
 376     ;;
 377 esac
 378
 379 AC_ARG_ENABLE(ld,
 380 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 381                 [build ld @<:@ARG={default,yes,no}@:>@])],
 382 ENABLE_LD=$enableval,
 383 ENABLE_LD=yes)
 384
 385 case "${ENABLE_LD}" in
 386   default)
 387     if test x${default_ld} != x; then
 388       AC_MSG_ERROR([either gold or ld can be the default ld])
 389     fi
 390     ;;
 391   yes)
 392     ;;
 393   no)
 394     if test x${ENABLE_GOLD} != xyes; then
 395       AC_MSG_WARN([neither ld nor gold are enabled])
 396     fi
 397     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 398     ;;
 399   *)
 400     AC_MSG_ERROR([invalid --enable-ld argument])
 401     ;;
 402 esac
 403
 404 # PR gas/19109
 405 # Decide the default method for compressing debug sections.
 406 # Provide a configure time option to override our default.
 407 AC_ARG_ENABLE(compressed_debug_sections,
 408 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 409                 [Enable compressed debug sections for gas, gold or ld by
 410                  default])],
 411 [
 412   if test x"$enable_compressed_debug_sections" = xyes; then
 413     AC_MSG_ERROR([no program with compressed debug sections specified])
 414   fi
 415 ], [enable_compressed_debug_sections=])
 416
 417 # Configure extra directories which are host specific
 418
 419 case "${host}" in
 420   *-cygwin*)
 421     configdirs="$configdirs libtermcap" ;;
 422 esac
 423
 424 # A target can indicate whether a language isn't supported for some reason.
 425 # Only spaces may be used in this macro; not newlines or tabs.
 426 unsupported_languages=
 427
 428 # Remove more programs from consideration, based on the host or
 429 # target this usually means that a port of the program doesn't
 430 # exist yet.
 431
 432 case "${host}" in
 433   i[[3456789]]86-*-msdosdjgpp*)
 434     noconfigdirs="$noconfigdirs tcl tk itcl"
 435     ;;
 436 esac
 437
 438
 439 AC_ARG_ENABLE(libquadmath,
 440 AS_HELP_STRING([--disable-libquadmath],
 441   [do not build libquadmath directory]),
 442 ENABLE_LIBQUADMATH=$enableval,
 443 ENABLE_LIBQUADMATH=yes)
 444 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 445   noconfigdirs="$noconfigdirs target-libquadmath"
 446 fi
 447
 448
 449 AC_ARG_ENABLE(libquadmath-support,
 450 AS_HELP_STRING([--disable-libquadmath-support],
 451   [disable libquadmath support for Fortran]),
 452 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 453 ENABLE_LIBQUADMATH_SUPPORT=yes)
 454 enable_libquadmath_support=
 455 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 456   enable_libquadmath_support=no
 457 fi
 458
 459
 460 AC_ARG_ENABLE(libada,
 461 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 462 ENABLE_LIBADA=$enableval,
 463 ENABLE_LIBADA=yes)
 464 if test "${ENABLE_LIBADA}" != "yes" ; then
 465   noconfigdirs="$noconfigdirs gnattools"
 466 fi
 467
 468 AC_ARG_ENABLE(libgm2,
 469 [AS_HELP_STRING([--enable-libgm2], [build libgm2 directory])],
 470 ENABLE_LIBGM2=$enableval,
 471 ENABLE_LIBGM2=no)
 472 if test "${ENABLE_LIBGM2}" != "yes" ; then
 473   noconfigdirs="$noconfigdirs gm2tools"
 474 fi
 475
 476 AC_ARG_ENABLE(libssp,
 477 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 478 ENABLE_LIBSSP=$enableval,
 479 ENABLE_LIBSSP=yes)
 480
 481 AC_ARG_ENABLE(libstdcxx,
 482 AS_HELP_STRING([--disable-libstdcxx],
 483   [do not build libstdc++-v3 directory]),
 484 ENABLE_LIBSTDCXX=$enableval,
 485 ENABLE_LIBSTDCXX=default)
 486 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 487   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 488 fi]
 489
 490 # Enable libgomp by default on hosted POSIX systems, and a few others.
 491 if test x$enable_libgomp = x ; then
 492     case "${target}" in
 493     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 494         ;;
 495     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 496         ;;
 497     *-*-solaris2* | *-*-hpux11*)
 498         ;;
 499     *-*-darwin* | *-*-aix*)
 500         ;;
 501     nvptx*-*-* | amdgcn*-*-*)
 502         ;;
 503     *)
 504         noconfigdirs="$noconfigdirs target-libgomp"
 505         ;;
 506     esac
 507 fi
 508
 509 # Disable libatomic on unsupported systems.
 510 if test -d ${srcdir}/libatomic; then
 511     if test x$enable_libatomic = x; then
 512         AC_MSG_CHECKING([for libatomic support])
 513         if (srcdir=${srcdir}/libatomic; \
 514                 . ${srcdir}/configure.tgt; \
 515                 test -n "$UNSUPPORTED")
 516         then
 517             AC_MSG_RESULT([no])
 518             noconfigdirs="$noconfigdirs target-libatomic"
 519         else
 520             AC_MSG_RESULT([yes])
 521         fi
 522     fi
 523 fi
 524
 525 # Disable libitm on unsupported systems.
 526 if test -d ${srcdir}/libitm; then
 527     if test x$enable_libitm = x; then
 528         AC_MSG_CHECKING([for libitm support])
 529         if (srcdir=${srcdir}/libitm; \
 530                 . ${srcdir}/configure.tgt; \
 531                 test -n "$UNSUPPORTED")
 532         then
 533             AC_MSG_RESULT([no])
 534             noconfigdirs="$noconfigdirs target-libitm"
 535         else
 536             AC_MSG_RESULT([yes])
 537         fi
 538     fi
 539 fi
 540
 541 # Disable libsanitizer on unsupported systems.
 542 if test -d ${srcdir}/libsanitizer; then
 543     if test x$enable_libsanitizer = x; then
 544         AC_MSG_CHECKING([for libsanitizer support])
 545         if (srcdir=${srcdir}/libsanitizer; \
 546                 . ${srcdir}/configure.tgt; \
 547                 test -n "$UNSUPPORTED")
 548         then
 549             AC_MSG_RESULT([no])
 550             noconfigdirs="$noconfigdirs target-libsanitizer"
 551         else
 552             AC_MSG_RESULT([yes])
 553         fi
 554     fi
 555 fi
 556
 557 # Disable libvtv on unsupported systems.
 558 if test -d ${srcdir}/libvtv; then
 559     if test x$enable_libvtv = x; then
 560         AC_MSG_CHECKING([for libvtv support])
 561         if (srcdir=${srcdir}/libvtv; \
 562                 . ${srcdir}/configure.tgt; \
 563                 test "$VTV_SUPPORTED" != "yes")
 564         then
 565             AC_MSG_RESULT([no])
 566             noconfigdirs="$noconfigdirs target-libvtv"
 567         else
 568             AC_MSG_RESULT([yes])
 569         fi
 570     fi
 571 fi
 572
 573 # Disable libquadmath for some systems.
 574 case "${target}" in
 575   avr-*-*)
 576     noconfigdirs="$noconfigdirs target-libquadmath"
 577     ;;
 578   # libquadmath is unused on AIX and libquadmath build process use of
 579   # LD_LIBRARY_PATH can break AIX bootstrap.
 580   powerpc-*-aix* | rs6000-*-aix*)
 581     noconfigdirs="$noconfigdirs target-libquadmath"
 582     ;;
 583 esac
 584
 585 # Disable libssp for some systems.
 586 case "${target}" in
 587   avr-*-*)
 588     # No hosted I/O support.
 589     noconfigdirs="$noconfigdirs target-libssp"
 590     ;;
 591   bpf-*-*)
 592     noconfigdirs="$noconfigdirs target-libssp"
 593     ;;
 594   powerpc-*-aix* | rs6000-*-aix*)
 595     noconfigdirs="$noconfigdirs target-libssp"
 596     ;;
 597   pru-*-*)
 598     # No hosted I/O support.
 599     noconfigdirs="$noconfigdirs target-libssp"
 600     ;;
 601   rl78-*-*)
 602     # libssp uses a misaligned load to trigger a fault, but the RL78
 603     # doesn't fault for those - instead, it gives a build-time error
 604     # for explicit misaligned loads.
 605     noconfigdirs="$noconfigdirs target-libssp"
 606     ;;
 607   visium-*-*)
 608     # No hosted I/O support.
 609     noconfigdirs="$noconfigdirs target-libssp"
 610     ;;
 611 esac
 612
 613 # Disable libstdc++-v3 for some systems.
 614 # Allow user to override this if they pass --enable-libstdcxx
 615 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 616   case "${target}" in
 617     *-*-vxworks*)
 618       # VxWorks uses the Dinkumware C++ library.
 619       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 620       ;;
 621     amdgcn*-*-*)
 622       # Not ported/fails to build when using newlib.
 623       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 624       ;;
 625     arm*-wince-pe*)
 626       # the C++ libraries don't build on top of CE's C libraries
 627       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 628       ;;
 629     avr-*-*)
 630       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 631       ;;
 632     bpf-*-*)
 633       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 634       ;;
 635     ft32-*-*)
 636       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 637       ;;
 638   esac
 639 fi
 640
 641 # Disable C++ on systems where it is known to not work.
 642 # For testing, you can override this with --enable-languages=c++.
 643 case ,${enable_languages}, in
 644   *,c++,*)
 645     ;;
 646   *)
 647       case "${target}" in
 648         bpf-*-*)
 649           unsupported_languages="$unsupported_languages c++"
 650           ;;
 651       esac
 652       ;;
 653 esac
 654
 655 # Disable Objc on systems where it is known to not work.
 656 # For testing, you can override this with --enable-languages=objc.
 657 case ,${enable_languages}, in
 658   *,objc,*)
 659     ;;
 660   *)
 661       case "${target}" in
 662         bpf-*-*)
 663           unsupported_languages="$unsupported_languages objc"
 664           ;;
 665       esac
 666       ;;
 667 esac
 668
 669 # Disable D on systems where it is known to not work.
 670 # For testing, you can override this with --enable-languages=d.
 671 case ,${enable_languages}, in
 672   *,d,*)
 673     ;;
 674   *)
 675     case "${target}" in
 676       bpf-*-*)
 677         unsupported_languages="$unsupported_languages d"
 678         ;;
 679     esac
 680     ;;
 681 esac
 682
 683 # Disable libphobos on unsupported systems.
 684 # For testing, you can override this with --enable-libphobos.
 685 if test -d ${srcdir}/libphobos; then
 686     if test x$enable_libphobos = x; then
 687         AC_MSG_CHECKING([for libphobos support])
 688         if (srcdir=${srcdir}/libphobos; \
 689                 . ${srcdir}/configure.tgt; \
 690                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 691         then
 692             AC_MSG_RESULT([no])
 693             noconfigdirs="$noconfigdirs target-libphobos"
 694         else
 695             AC_MSG_RESULT([yes])
 696         fi
 697     fi
 698 fi
 699
 700 # Disable Fortran for some systems.
 701 case "${target}" in
 702   mmix-*-*)
 703     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 704     unsupported_languages="$unsupported_languages fortran"
 705     ;;
 706   bpf-*-*)
 707     unsupported_languages="$unsupported_languages fortran"
 708     ;;
 709 esac
 710
 711 # Disable libffi for some systems.
 712 case "${target}" in
 713   powerpc-*-darwin*)
 714     ;;
 715   i[[3456789]]86-*-darwin*)
 716     ;;
 717   x86_64-*-darwin[[912]]*)
 718     ;;
 719   *-*-darwin*)
 720     noconfigdirs="$noconfigdirs target-libffi"
 721     ;;
 722   *-*-netware*)
 723     noconfigdirs="$noconfigdirs target-libffi"
 724     ;;
 725   *-*-phoenix*)
 726     noconfigdirs="$noconfigdirs target-libffi"
 727     ;;
 728   *-*-rtems*)
 729     noconfigdirs="$noconfigdirs target-libffi"
 730     ;;
 731   *-*-tpf*)
 732     noconfigdirs="$noconfigdirs target-libffi"
 733     ;;
 734   *-*-uclinux*)
 735     noconfigdirs="$noconfigdirs target-libffi"
 736     ;;
 737   *-*-vxworks*)
 738     noconfigdirs="$noconfigdirs target-libffi"
 739     ;;
 740   aarch64*-*-freebsd*)
 741     noconfigdirs="$noconfigdirs target-libffi"
 742     ;;
 743   alpha*-*-*vms*)
 744     noconfigdirs="$noconfigdirs target-libffi"
 745     ;;
 746   arm*-*-freebsd*)
 747     noconfigdirs="$noconfigdirs target-libffi"
 748     ;;
 749   arm-wince-pe)
 750     noconfigdirs="$noconfigdirs target-libffi"
 751     ;;
 752   arm*-*-symbianelf*)
 753     noconfigdirs="$noconfigdirs target-libffi"
 754     ;;
 755   bpf-*-*)
 756     noconfigdirs="$noconfigdirs target-libffi"
 757     ;;
 758   cris-*-* | crisv32-*-*)
 759     case "${target}" in
 760       *-*-linux*)
 761         ;;
 762       *) # See PR46792 regarding target-libffi.
 763         noconfigdirs="$noconfigdirs target-libffi";;
 764     esac
 765     ;;
 766   hppa*64*-*-hpux*)
 767     noconfigdirs="$noconfigdirs target-libffi"
 768     ;;
 769   ia64*-*-*vms*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772   i[[3456789]]86-w64-mingw*)
 773     noconfigdirs="$noconfigdirs target-libffi"
 774     ;;
 775   i[[3456789]]86-*-mingw*)
 776     noconfigdirs="$noconfigdirs target-libffi"
 777     ;;
 778   x86_64-*-mingw*)
 779     noconfigdirs="$noconfigdirs target-libffi"
 780     ;;
 781   mmix-*-*)
 782     noconfigdirs="$noconfigdirs target-libffi"
 783     ;;
 784   powerpc-*-aix*)
 785     ;;
 786   rs6000-*-aix*)
 787     ;;
 788   ft32-*-*)
 789     noconfigdirs="$noconfigdirs target-libffi"
 790     ;;
 791   *-*-lynxos*)
 792     noconfigdirs="$noconfigdirs target-libffi"
 793     ;;
 794 esac
 795
 796 # Disable the go frontend on systems where it is known to not work. Please keep
 797 # this in sync with contrib/config-list.mk.
 798 case "${target}" in
 799 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 800     unsupported_languages="$unsupported_languages go"
 801     ;;
 802 esac
 803
 804 # Only allow gdbserver on some systems.
 805 if test -d ${srcdir}/gdbserver; then
 806     if test x$enable_gdbserver = x; then
 807         AC_MSG_CHECKING([for gdbserver support])
 808         if (srcdir=${srcdir}/gdbserver; \
 809                 . ${srcdir}/configure.srv; \
 810                 test -n "$UNSUPPORTED")
 811         then
 812             AC_MSG_RESULT([no])
 813             noconfigdirs="$noconfigdirs gdbserver"
 814         else
 815             AC_MSG_RESULT([yes])
 816         fi
 817     fi
 818 fi
 819
 820 # Disable libgo for some systems where it is known to not work.
 821 # For testing, you can easily override this with --enable-libgo.
 822 if test x$enable_libgo = x; then
 823     case "${target}" in
 824     *-*-darwin*)
 825         # PR 46986
 826         noconfigdirs="$noconfigdirs target-libgo"
 827         ;;
 828     *-*-cygwin* | *-*-mingw*)
 829         noconfigdirs="$noconfigdirs target-libgo"
 830         ;;
 831     bpf-*-*)
 832         noconfigdirs="$noconfigdirs target-libgo"
 833         ;;
 834     esac
 835 fi
 836
 837 # Default libgloss CPU subdirectory.
 838 libgloss_dir="$target_cpu"
 839
 840 case "${target}" in
 841   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 842     libgloss_dir=wince
 843     ;;
 844   aarch64*-*-* )
 845     libgloss_dir=aarch64
 846     ;;
 847   arm*-*-*)
 848     libgloss_dir=arm
 849     ;;
 850   cris-*-* | crisv32-*-*)
 851     libgloss_dir=cris
 852     ;;
 853   hppa*-*-*)
 854     libgloss_dir=pa
 855     ;;
 856   i[[3456789]]86-*-*)
 857     libgloss_dir=i386
 858     ;;
 859   loongarch*-*-*)
 860     libgloss_dir=loongarch
 861     ;;
 862   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 863     libgloss_dir=m68hc11
 864     ;;
 865   m68*-*-* | fido-*-*)
 866     libgloss_dir=m68k
 867     ;;
 868   mips*-*-*)
 869     libgloss_dir=mips
 870     ;;
 871   powerpc*-*-*)
 872     libgloss_dir=rs6000
 873     ;;
 874   pru-*-*)
 875     libgloss_dir=pru
 876     ;;
 877   sparc*-*-*)
 878     libgloss_dir=sparc
 879     ;;
 880 esac
 881
 882 # Disable newlib and libgloss for various target OSes.
 883 case "${target}" in
 884   alpha*-dec-osf*)
 885     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 886     ;;
 887   i[[3456789]]86-*-linux*)
 888     # This section makes it possible to build newlib natively on linux.
 889     # If we are using a cross compiler then don't configure newlib.
 890     if test x${is_cross_compiler} != xno ; then
 891       noconfigdirs="$noconfigdirs target-newlib"
 892     fi
 893     noconfigdirs="$noconfigdirs target-libgloss"
 894     # If we are not using a cross compiler, do configure newlib.
 895     # Note however, that newlib will only be configured in this situation
 896     # if the --with-newlib option has been given, because otherwise
 897     # 'target-newlib' will appear in skipdirs.
 898     ;;
 899   i[[3456789]]86-*-rdos*)
 900     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 901     ;;
 902   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 903     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 904     ;;
 905   sparc-*-sunos4*)
 906     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 907     ;;
 908   bpf-*-*)
 909     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 910     ;;
 911   *-*-aix*)
 912     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 913     ;;
 914   *-*-beos*)
 915     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 916     ;;
 917   *-*-chorusos)
 918     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 919     ;;
 920   *-*-dragonfly*)
 921     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 922     ;;
 923   *-*-freebsd*)
 924     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 925     ;;
 926   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 927     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 928     ;;
 929   *-*-lynxos*)
 930     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 931     ;;
 932   *-*-mingw*)
 933     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 934     ;;
 935   *-*-netbsd*)
 936     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 937     ;;
 938   *-*-netware*)
 939     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 940     ;;
 941   *-*-tpf*)
 942     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 943     ;;
 944   *-*-uclinux*)
 945     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 946     ;;
 947   *-*-vxworks*)
 948     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 949     ;;
 950 esac
 951
 952 case "${target}" in
 953   *-*-chorusos)
 954     ;;
 955   aarch64-*-darwin*)
 956     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 957     noconfigdirs="$noconfigdirs sim target-rda"
 958     ;;
 959   amdgcn*-*-*)
 960     ;;
 961   arm-*-darwin*)
 962     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 963     noconfigdirs="$noconfigdirs sim target-rda"
 964     ;;
 965   powerpc-*-darwin*)
 966     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 967     noconfigdirs="$noconfigdirs sim target-rda"
 968     ;;
 969   i[[3456789]]86-*-darwin*)
 970     noconfigdirs="$noconfigdirs ld gprof"
 971     noconfigdirs="$noconfigdirs sim target-rda"
 972     ;;
 973   x86_64-*-darwin[[912]]*)
 974     noconfigdirs="$noconfigdirs ld gas gprof"
 975     noconfigdirs="$noconfigdirs sim target-rda"
 976     ;;
 977   *-*-darwin*)
 978     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 979     noconfigdirs="$noconfigdirs sim target-rda"
 980     ;;
 981   *-*-dragonfly*)
 982     ;;
 983   *-*-freebsd*)
 984     if test "x$with_gmp" = x \
 985         && ! test -d ${srcdir}/gmp \
 986         && test -f /usr/local/include/gmp.h; then
 987       with_gmp=/usr/local
 988     fi
 989     ;;
 990   *-*-kaos*)
 991     # Remove unsupported stuff on all kaOS configurations.
 992     noconfigdirs="$noconfigdirs target-libgloss"
 993     ;;
 994   *-*-netbsd*)
 995     ;;
 996   *-*-netware*)
 997     ;;
 998   *-*-phoenix*)
 999     noconfigdirs="$noconfigdirs target-libgloss"
1000     ;;
1001   *-*-rtems*)
1002     noconfigdirs="$noconfigdirs target-libgloss"
1003     ;;
1004     # The tpf target doesn't support gdb yet.
1005   *-*-tpf*)
1006     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1007     ;;
1008   *-*-uclinux*)
1009     noconfigdirs="$noconfigdirs target-rda"
1010     ;;
1011   *-*-vxworks*)
1012     ;;
1013   alpha*-dec-osf*)
1014     # ld works, but does not support shared libraries.
1015     # gas doesn't generate exception information.
1016     noconfigdirs="$noconfigdirs gas ld"
1017     ;;
1018   alpha*-*-*vms*)
1019     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1020     ;;
1021   alpha*-*-*)
1022     # newlib is not 64 bit ready
1023     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1024     ;;
1025   bpf-*-*)
1026     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1027     ;;
1028   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1029     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1030     ;;
1031   arc*-*-*)
1032     noconfigdirs="$noconfigdirs sim"
1033     ;;
1034   arm-*-pe*)
1035     noconfigdirs="$noconfigdirs target-libgloss"
1036     ;;
1037   arm-*-riscix*)
1038     noconfigdirs="$noconfigdirs ld target-libgloss"
1039     ;;
1040   avr-*-*)
1041     if test x${with_avrlibc} != xno; then
1042       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1043     fi
1044     ;;
1045   c4x-*-* | tic4x-*-*)
1046     noconfigdirs="$noconfigdirs target-libgloss"
1047     ;;
1048   tic54x-*-*)
1049     noconfigdirs="$noconfigdirs target-libgloss gdb"
1050     ;;
1051   d10v-*-*)
1052     noconfigdirs="$noconfigdirs target-libgloss"
1053     ;;
1054   d30v-*-*)
1055     noconfigdirs="$noconfigdirs gdb"
1056     ;;
1057   fr30-*-elf*)
1058     noconfigdirs="$noconfigdirs gdb"
1059     ;;
1060   ft32-*-*)
1061     noconfigdirs="$noconfigdirs target-rda gprof"
1062     ;;
1063   moxie-*-*)
1064     noconfigdirs="$noconfigdirs"
1065     ;;
1066   h8300*-*-*)
1067     noconfigdirs="$noconfigdirs target-libgloss"
1068     ;;
1069   h8500-*-*)
1070     noconfigdirs="$noconfigdirs target-libgloss"
1071     ;;
1072   hppa*64*-*-hpux*)
1073     noconfigdirs="$noconfigdirs gdb"
1074     ;;
1075   hppa*64*-*-linux*)
1076     ;;
1077   hppa*-*-linux*)
1078     ;;
1079   hppa*-*-*elf* | \
1080   hppa*-*-lites* | \
1081   hppa*-*-openbsd* | \
1082   hppa*64*-*-*)
1083     ;;
1084   hppa*-*-pro*)
1085     ;;
1086   hppa*-*-*)
1087     noconfigdirs="$noconfigdirs ld"
1088     ;;
1089   i960-*-*)
1090     noconfigdirs="$noconfigdirs gdb"
1091     ;;
1092   ia64*-*-elf*)
1093     # No gdb support yet.
1094     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1095     ;;
1096   ia64*-**-hpux*)
1097     # No ld support yet.
1098     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1099     ;;
1100   ia64*-*-*vms*)
1101     # No ld support yet.
1102     noconfigdirs="$noconfigdirs libgui itcl ld"
1103     ;;
1104   i[[3456789]]86-w64-mingw*)
1105     ;;
1106   i[[3456789]]86-*-mingw*)
1107     target_configdirs="$target_configdirs target-winsup"
1108     ;;
1109   *-*-cygwin*)
1110     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1111     noconfigdirs="$noconfigdirs target-libgloss"
1112     # always build newlib if winsup directory is present.
1113     if test -d "$srcdir/winsup/cygwin"; then
1114       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1115     elif test -d "$srcdir/newlib"; then
1116       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1117     fi
1118     ;;
1119   i[[3456789]]86-*-pe)
1120     noconfigdirs="$noconfigdirs target-libgloss"
1121     ;;
1122   i[[3456789]]86-*-sco3.2v5*)
1123     # The linker does not yet know about weak symbols in COFF,
1124     # and is not configured to handle mixed ELF and COFF.
1125     noconfigdirs="$noconfigdirs ld target-libgloss"
1126     ;;
1127   i[[3456789]]86-*-sco*)
1128     noconfigdirs="$noconfigdirs gprof target-libgloss"
1129     ;;
1130   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1131     noconfigdirs="$noconfigdirs target-libgloss"
1132     ;;
1133   i[[3456789]]86-*-sysv4*)
1134     noconfigdirs="$noconfigdirs target-libgloss"
1135     ;;
1136   i[[3456789]]86-*-beos*)
1137     noconfigdirs="$noconfigdirs gdb"
1138     ;;
1139   i[[3456789]]86-*-rdos*)
1140     noconfigdirs="$noconfigdirs gdb"
1141     ;;
1142   mmix-*-*)
1143     noconfigdirs="$noconfigdirs gdb"
1144     ;;
1145   mt-*-*)
1146     noconfigdirs="$noconfigdirs sim"
1147     ;;
1148   nfp-*-*)
1149     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1150     noconfigdirs="$noconfigdirs $target_libraries"
1151     ;;
1152   pdp11-*-*)
1153     noconfigdirs="$noconfigdirs gdb gprof"
1154     ;;
1155   powerpc-*-aix*)
1156     # copied from rs6000-*-* entry
1157     noconfigdirs="$noconfigdirs gprof"
1158     ;;
1159   powerpc*-*-winnt* | powerpc*-*-pe*)
1160     target_configdirs="$target_configdirs target-winsup"
1161     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1162     # always build newlib.
1163     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1164     ;;
1165     # This is temporary until we can link against shared libraries
1166   powerpcle-*-solaris*)
1167     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1168     ;;
1169   powerpc-*-beos*)
1170     noconfigdirs="$noconfigdirs gdb"
1171     ;;
1172   rs6000-*-lynxos*)
1173     noconfigdirs="$noconfigdirs gprof"
1174     ;;
1175   rs6000-*-aix*)
1176     noconfigdirs="$noconfigdirs gprof"
1177     ;;
1178   rs6000-*-*)
1179     noconfigdirs="$noconfigdirs gprof"
1180     ;;
1181   m68k-apollo-*)
1182     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1183     ;;
1184   microblaze*)
1185     noconfigdirs="$noconfigdirs gprof"
1186     ;;
1187   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1188     if test x$with_newlib = xyes; then
1189       noconfigdirs="$noconfigdirs gprof"
1190     fi
1191     ;;
1192   mips*-*-irix5*)
1193     noconfigdirs="$noconfigdirs gprof target-libgloss"
1194     ;;
1195   mips*-*-irix6*)
1196     noconfigdirs="$noconfigdirs gprof target-libgloss"
1197     ;;
1198   mips*-*-bsd*)
1199     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1200     ;;
1201   mips*-*-linux*)
1202     ;;
1203   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1204   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1205     noconfigdirs="$noconfigdirs ld gas gprof"
1206     ;;
1207   mips*-*-*)
1208     noconfigdirs="$noconfigdirs gprof"
1209     ;;
1210   nvptx*-*-*)
1211     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1212     ;;
1213   sh-*-*)
1214     case "${target}" in
1215       sh*-*-elf)
1216          ;;
1217       *)
1218          noconfigdirs="$noconfigdirs target-libgloss" ;;
1219     esac
1220     ;;
1221   sparc-*-sunos4*)
1222     if test x${is_cross_compiler} = xno ; then
1223            use_gnu_ld=no
1224     fi
1225     ;;
1226   tic6x-*-*)
1227     noconfigdirs="$noconfigdirs sim"
1228     ;;
1229   v810-*-*)
1230     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1231     ;;
1232   vax-*-*)
1233     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1234     ;;
1235   wasm32-*-*)
1236     noconfigdirs="$noconfigdirs ld"
1237     ;;
1238   loongarch*-*-linux*)
1239     ;;
1240   loongarch*-*-*)
1241     noconfigdirs="$noconfigdirs gprof"
1242     ;;
1243 esac
1244
1245 # If we aren't building newlib, then don't build libgloss, since libgloss
1246 # depends upon some newlib header files.
1247 case "${noconfigdirs}" in
1248   *target-libgloss*) ;;
1249   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1250 esac
1251
1252 # Work in distributions that contain no compiler tools, like Autoconf.
1253 host_makefile_frag=/dev/null
1254 if test -d ${srcdir}/config ; then
1255 case "${host}" in
1256   i[[3456789]]86-*-msdosdjgpp*)
1257     host_makefile_frag="config/mh-djgpp"
1258     ;;
1259   *-cygwin*)
1260     ACX_CHECK_CYGWIN_CAT_WORKS
1261     host_makefile_frag="config/mh-cygwin"
1262     ;;
1263   *-mingw*)
1264     host_makefile_frag="config/mh-mingw"
1265     ;;
1266   alpha*-linux*)
1267     host_makefile_frag="config/mh-alpha-linux"
1268     ;;
1269   hppa*-hp-hpux*)
1270     host_makefile_frag="config/mh-pa"
1271     ;;
1272   hppa*-*)
1273     host_makefile_frag="config/mh-pa"
1274     ;;
1275   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1276     host_makefile_frag="config/mh-darwin"
1277     ;;
1278   powerpc-*-aix*)
1279     host_makefile_frag="config/mh-ppc-aix"
1280     ;;
1281   rs6000-*-aix*)
1282     host_makefile_frag="config/mh-ppc-aix"
1283     ;;
1284 esac
1285 fi
1286
1287 if test "${build}" != "${host}" ; then
1288   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1289   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1290   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1291   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1292   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1293   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1294   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1295   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1296   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1297   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1298   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1299   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1300   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1301   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1302   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1303 else
1304   AR_FOR_BUILD="\$(AR)"
1305   AS_FOR_BUILD="\$(AS)"
1306   CC_FOR_BUILD="\$(CC)"
1307   CXX_FOR_BUILD="\$(CXX)"
1308   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1309   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1310   GOC_FOR_BUILD="\$(GOC)"
1311   GDC_FOR_BUILD="\$(GDC)"
1312   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1313   LD_FOR_BUILD="\$(LD)"
1314   NM_FOR_BUILD="\$(NM)"
1315   RANLIB_FOR_BUILD="\$(RANLIB)"
1316   WINDRES_FOR_BUILD="\$(WINDRES)"
1317   WINDMC_FOR_BUILD="\$(WINDMC)"
1318 fi
1319
1320 AC_PROG_CC_C99
1321 AC_PROG_CXX
1322
1323 # We must set the default linker to the linker used by gcc for the correct
1324 # operation of libtool.  If LD is not defined and we are using gcc, try to
1325 # set the LD default to the ld used by gcc.
1326 if test -z "$LD"; then
1327   if test "$GCC" = yes; then
1328     case $build in
1329     *-*-mingw*)
1330       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1331     *)
1332       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1333     esac
1334     case $gcc_prog_ld in
1335     # Accept absolute paths.
1336     [[\\/]* | [A-Za-z]:[\\/]*)]
1337       LD="$gcc_prog_ld" ;;
1338     esac
1339   fi
1340 fi
1341
1342 # Check whether -static-libstdc++ -static-libgcc is supported.
1343 have_static_libs=no
1344 if test "$GCC" = yes; then
1345   saved_LDFLAGS="$LDFLAGS"
1346
1347   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1348   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1349   AC_LANG_PUSH(C++)
1350   AC_LINK_IFELSE([AC_LANG_SOURCE([
1351 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1352 #error -static-libstdc++ not implemented
1353 #endif
1354 int main() {}])],
1355     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1356     [AC_MSG_RESULT([no])])
1357   AC_LANG_POP(C++)
1358
1359   LDFLAGS="$saved_LDFLAGS"
1360 fi
1361
1362 ACX_PROG_GNAT
1363 ACX_PROG_GDC
1364 ACX_PROG_CMP_IGNORE_INITIAL
1365
1366 AC_ARG_ENABLE([bootstrap],
1367 [AS_HELP_STRING([--enable-bootstrap],
1368                 [enable bootstrapping @<:@yes if native build@:>@])],,
1369 enable_bootstrap=default)
1370
1371 # Issue errors and warnings for invalid/strange bootstrap combinations.
1372 if test -r $srcdir/gcc/configure; then
1373   have_compiler=yes
1374 else
1375   have_compiler=no
1376 fi
1377
1378 case "$have_compiler:$host:$target:$enable_bootstrap" in
1379   *:*:*:no) ;;
1380
1381   # Default behavior.  Enable bootstrap if we have a compiler
1382   # and we are in a native configuration.
1383   yes:$build:$build:default)
1384     enable_bootstrap=yes ;;
1385
1386   *:*:*:default)
1387     enable_bootstrap=no ;;
1388
1389   # We have a compiler and we are in a native configuration, bootstrap is ok
1390   yes:$build:$build:yes)
1391     ;;
1392
1393   # Other configurations, but we have a compiler.  Assume the user knows
1394   # what he's doing.
1395   yes:*:*:yes)
1396     AC_MSG_WARN([trying to bootstrap a cross compiler])
1397     ;;
1398
1399   # No compiler: if they passed --enable-bootstrap explicitly, fail
1400   no:*:*:yes)
1401     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1402
1403   # Fail if wrong command line
1404   *)
1405     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1406     ;;
1407 esac
1408
1409 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1410 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1411 # require C++11 (or higher).
1412 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1413   CXX="$CXX -std=c++11"
1414 elif test "$have_compiler" = yes; then
1415   AX_CXX_COMPILE_STDCXX(11)
1416
1417   if test "${build}" != "${host}"; then
1418     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1419   fi
1420 fi
1421
1422 AC_ARG_ENABLE([pgo-build],
1423 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1424                 [enable the PGO build])],
1425 [enable_pgo_build=$enableval],
1426 [enable_pgo_build=no])
1427
1428 # Issue errors and warnings for invalid/strange PGO build combinations.
1429 case "$have_compiler:$host:$target:$enable_pgo_build" in
1430   *:*:*:no) ;;
1431
1432   # Allow the PGO build only if we aren't building a compiler and
1433   # we are in a native configuration.
1434   no:$build:$build:yes | no:$build:$build:lto) ;;
1435
1436   # Disallow the PGO bootstrap if we are building a compiler.
1437   yes:*:*:yes | yes:*:*:lto)
1438     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1439
1440   *)
1441     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1442     ;;
1443 esac
1444
1445 if test "$enable_pgo_build" != "no"; then
1446   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1447   old_CFLAGS="$CFLAGS"
1448   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1449   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1450   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1451                     [PGO_BUILD_GEN_CFLAGS=])
1452   CFLAGS="$old_CFLAGS"
1453   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1454     AC_MSG_RESULT([yes])
1455     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1456   else
1457     AC_MSG_RESULT([no])
1458     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1459   fi
1460
1461   if test "$enable_pgo_build" = "lto"; then
1462     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1463     old_CFLAGS="$CFLAGS"
1464     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1465     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1466     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1467                       [PGO_BUILD_LTO_CFLAGS=])
1468     CFLAGS="$old_CFLAGS"
1469     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1470       AC_MSG_RESULT([yes])
1471     else
1472       AC_MSG_RESULT([no])
1473       AC_MSG_WARN([LTO is disabled for the PGO build])
1474     fi
1475   fi
1476 fi
1477 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1478 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1479 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1480
1481 # Used for setting $lt_cv_objdir
1482 _LT_CHECK_OBJDIR
1483
1484 # Check for GMP, MPFR and MPC
1485 require_gmp=no
1486 require_mpc=no
1487 if test -d ${srcdir}/gcc ; then
1488   require_gmp=yes
1489   require_mpc=yes
1490 fi
1491 if test -d ${srcdir}/gdb ; then
1492   if test "x$enable_gdb" != xno; then
1493    require_gmp=yes
1494   fi
1495 fi
1496
1497 gmplibs="-lmpfr -lgmp"
1498 if test x"$require_mpc" = "xyes" ; then
1499   gmplibs="-lmpc $gmplibs"
1500 fi
1501 gmpinc=
1502 have_gmp=no
1503
1504 # Specify a location for mpc
1505 # check for this first so it ends up on the link line before mpfr.
1506 AC_ARG_WITH(mpc,
1507 [AS_HELP_STRING([--with-mpc=PATH],
1508                 [specify prefix directory for installed MPC package.
1509                  Equivalent to --with-mpc-include=PATH/include
1510                  plus --with-mpc-lib=PATH/lib])])
1511 AC_ARG_WITH(mpc-include,
1512 [AS_HELP_STRING([--with-mpc-include=PATH],
1513                 [specify directory for installed MPC include files])])
1514 AC_ARG_WITH(mpc-lib,
1515 [AS_HELP_STRING([--with-mpc-lib=PATH],
1516                 [specify directory for the installed MPC library])])
1517
1518 if test "x$with_mpc" != x; then
1519   gmplibs="-L$with_mpc/lib $gmplibs"
1520   gmpinc="-I$with_mpc/include $gmpinc"
1521 fi
1522 if test "x$with_mpc_include" != x; then
1523   gmpinc="-I$with_mpc_include $gmpinc"
1524 fi
1525 if test "x$with_mpc_lib" != x; then
1526   gmplibs="-L$with_mpc_lib $gmplibs"
1527 fi
1528 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1529   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1530   gmpinc='-I$$s/mpc/src '"$gmpinc"
1531   # Do not test the mpc version.  Assume that it is sufficient, since
1532   # it is in the source tree, and the library has not been built yet
1533   # but it would be included on the link line in the version check below
1534   # hence making the test fail.
1535   have_gmp=yes
1536 fi
1537
1538 # Specify a location for mpfr
1539 # check for this first so it ends up on the link line before gmp.
1540 AC_ARG_WITH(mpfr,
1541 [AS_HELP_STRING([--with-mpfr=PATH],
1542                 [specify prefix directory for installed MPFR package.
1543                  Equivalent to --with-mpfr-include=PATH/include
1544                  plus --with-mpfr-lib=PATH/lib])])
1545 AC_ARG_WITH(mpfr-include,
1546 [AS_HELP_STRING([--with-mpfr-include=PATH],
1547                 [specify directory for installed MPFR include files])])
1548 AC_ARG_WITH(mpfr-lib,
1549 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1550                 [specify directory for the installed MPFR library])])
1551
1552 if test "x$with_mpfr" != x; then
1553   gmplibs="-L$with_mpfr/lib $gmplibs"
1554   gmpinc="-I$with_mpfr/include $gmpinc"
1555 fi
1556 if test "x$with_mpfr_include" != x; then
1557   gmpinc="-I$with_mpfr_include $gmpinc"
1558 fi
1559 if test "x$with_mpfr_lib" != x; then
1560   gmplibs="-L$with_mpfr_lib $gmplibs"
1561 fi
1562 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1563   # MPFR v3.1.0 moved the sources into a src sub-directory.
1564   if ! test -d ${srcdir}/mpfr/src; then
1565     AC_MSG_ERROR([dnl
1566 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1567   fi
1568   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1569   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1570   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1571   # Do not test the mpfr version.  Assume that it is sufficient, since
1572   # it is in the source tree, and the library has not been built yet
1573   # but it would be included on the link line in the version check below
1574   # hence making the test fail.
1575   have_gmp=yes
1576 fi
1577
1578 # Specify a location for gmp
1579 AC_ARG_WITH(gmp,
1580 [AS_HELP_STRING([--with-gmp=PATH],
1581                 [specify prefix directory for the installed GMP package.
1582                  Equivalent to --with-gmp-include=PATH/include
1583                  plus --with-gmp-lib=PATH/lib])])
1584 AC_ARG_WITH(gmp-include,
1585 [AS_HELP_STRING([--with-gmp-include=PATH],
1586                 [specify directory for installed GMP include files])])
1587 AC_ARG_WITH(gmp-lib,
1588 [AS_HELP_STRING([--with-gmp-lib=PATH],
1589                 [specify directory for the installed GMP library])])
1590
1591
1592 if test "x$with_gmp" != x; then
1593   gmplibs="-L$with_gmp/lib $gmplibs"
1594   gmpinc="-I$with_gmp/include $gmpinc"
1595 fi
1596 if test "x$with_gmp_include" != x; then
1597   gmpinc="-I$with_gmp_include $gmpinc"
1598 fi
1599 if test "x$with_gmp_lib" != x; then
1600   gmplibs="-L$with_gmp_lib $gmplibs"
1601 fi
1602 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1603   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1604   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1605   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1606   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1607   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1608   # Do not test the gmp version.  Assume that it is sufficient, since
1609   # it is in the source tree, and the library has not been built yet
1610   # but it would be included on the link line in the version check below
1611   # hence making the test fail.
1612   have_gmp=yes
1613 fi
1614
1615 if test "x$require_gmp" = xyes && test "x$have_gmp" = xno; then
1616   have_gmp=yes
1617   saved_CFLAGS="$CFLAGS"
1618   CFLAGS="$CFLAGS $gmpinc"
1619   # Check for the recommended and required versions of GMP.
1620   AC_MSG_CHECKING([for the correct version of gmp.h])
1621   AC_TRY_COMPILE([#include "gmp.h"],[
1622   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1623   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1624   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1625   choke me
1626   #endif
1627   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1628   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1629   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1630   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1631   choke me
1632   #endif
1633   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1634    [AC_MSG_RESULT([no]); have_gmp=no])
1635
1636   # If we have GMP, check the MPFR version.
1637   if test x"$have_gmp" = xyes; then
1638     # Check for the recommended and required versions of MPFR.
1639     AC_MSG_CHECKING([for the correct version of mpfr.h])
1640     AC_TRY_COMPILE([#include <gmp.h>
1641     #include <mpfr.h>],[
1642     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1643     choke me
1644     #endif
1645     ], [AC_TRY_COMPILE([#include <gmp.h>
1646     #include <mpfr.h>],[
1647     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1648     choke me
1649     #endif
1650     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1651      [AC_MSG_RESULT([no]); have_gmp=no])
1652   fi
1653
1654   # Check for the MPC header version.
1655   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes ; then
1656     # Check for the recommended and required versions of MPC.
1657     AC_MSG_CHECKING([for the correct version of mpc.h])
1658     AC_TRY_COMPILE([#include <mpc.h>],[
1659     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1660     choke me
1661     #endif
1662     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1663     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1664     choke me
1665     #endif
1666     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1667      [AC_MSG_RESULT([no]); have_gmp=no])
1668   fi
1669
1670   # Now check the MPFR library.
1671   if test x"$have_gmp" = xyes; then
1672     saved_LIBS="$LIBS"
1673     LIBS="$LIBS $gmplibs"
1674     AC_MSG_CHECKING([for the correct version of the gmp/mpfr libraries])
1675     AC_TRY_LINK([#include <mpfr.h>],[
1676     mpfr_t n;
1677     mpfr_t x;
1678     int t;
1679     mpfr_init (n);
1680     mpfr_init (x);
1681     mpfr_atan2 (n, n, x, MPFR_RNDN);
1682     mpfr_erfc (n, x, MPFR_RNDN);
1683     mpfr_subnormalize (x, t, MPFR_RNDN);
1684     mpfr_clear(n);
1685     mpfr_clear(x);
1686     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1687     LIBS="$saved_LIBS"
1688   fi
1689
1690   # Now check the MPC library
1691   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes; then
1692     saved_LIBS="$LIBS"
1693     LIBS="$LIBS $gmplibs"
1694     AC_MSG_CHECKING([for the correct version of the mpc libraries])
1695     AC_TRY_LINK([#include <mpc.h>],[
1696     mpc_t c;
1697     mpc_init2 (c, 53);
1698     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1699     mpc_cosh (c, c, MPC_RNDNN);
1700     mpc_pow (c, c, c, MPC_RNDNN);
1701     mpc_acosh (c, c, MPC_RNDNN);
1702     mpc_clear (c);
1703     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1704     LIBS="$saved_LIBS"
1705   fi
1706
1707   CFLAGS="$saved_CFLAGS"
1708
1709 # The library versions listed in the error message below should match
1710 # the HARD-minimums enforced above.
1711   if test x$have_gmp != xyes; then
1712     if test -d ${srcdir}/gcc ; then
1713       AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1714 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1715 their locations.  Source code for these libraries can be found at
1716 their respective hosting sites as well as at
1717 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1718 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1719 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1720 make sure that you have installed both the libraries and the header
1721 files.  They may be located in separate packages.])
1722     else
1723       AC_MSG_ERROR([Building GDB requires GMP 4.2+, and MPFR 3.1.0+.
1724 Try the --with-gmp and/or --with-mpfr options to specify
1725 their locations.  If you obtained GMP and/or MPFR from a vendor
1726 distribution package, make sure that you have installed both the libraries
1727 and the header files.  They may be located in separate packages.])
1728     fi
1729   fi
1730 fi
1731
1732 # Flags needed for both GMP, MPFR and/or MPC.
1733 AC_SUBST(gmplibs)
1734 AC_SUBST(gmpinc)
1735 AC_SUBST(extra_mpfr_configure_flags)
1736 AC_SUBST(extra_mpc_gmp_configure_flags)
1737 AC_SUBST(extra_mpc_mpfr_configure_flags)
1738 AC_SUBST(extra_isl_gmp_configure_flags)
1739
1740 # Libraries to use for stage1 or when not bootstrapping.
1741 AC_ARG_WITH(stage1-libs,
1742 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1743 [if test "$withval" = "no" -o "$withval" = "yes"; then
1744    stage1_libs=
1745  else
1746    stage1_libs=$withval
1747  fi],
1748 [stage1_libs=])
1749 AC_SUBST(stage1_libs)
1750
1751 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1752 # default is yes if gcc is being built; no otherwise.  The reason for
1753 # this default is that gdb is sometimes linked against GNU Source
1754 # Highlight, which is a shared library that uses C++ exceptions.  In
1755 # this case, -static-libstdc++ will cause crashes.
1756 AC_ARG_WITH(static-standard-libraries,
1757 [AS_HELP_STRING([--with-static-standard-libraries],
1758                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1759 [], [with_static_standard_libraries=auto])
1760 if test "$with_static_standard_libraries" = auto; then
1761   with_static_standard_libraries=$have_compiler
1762 fi
1763
1764 # Linker flags to use for stage1 or when not bootstrapping.
1765 AC_ARG_WITH(stage1-ldflags,
1766 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1767 [if test "$withval" = "no" -o "$withval" = "yes"; then
1768    stage1_ldflags=
1769  else
1770    stage1_ldflags=$withval
1771  fi],
1772 [stage1_ldflags=
1773  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1774  # if supported.  But if the user explicitly specified the libraries to use,
1775  # trust that they are doing what they want.
1776  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1777      -a "$have_static_libs" = yes; then
1778    stage1_ldflags="-static-libstdc++ -static-libgcc"
1779  fi])
1780 AC_SUBST(stage1_ldflags)
1781
1782 # Libraries to use for stage2 and later builds.
1783 AC_ARG_WITH(boot-libs,
1784 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1785 [if test "$withval" = "no" -o "$withval" = "yes"; then
1786    poststage1_libs=
1787  else
1788    poststage1_libs=$withval
1789  fi],
1790 [poststage1_libs=])
1791 AC_SUBST(poststage1_libs)
1792
1793 # Linker flags to use for stage2 and later builds.
1794 AC_ARG_WITH(boot-ldflags,
1795 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1796                 [linker flags for stage2 and later])],
1797 [if test "$withval" = "no" -o "$withval" = "yes"; then
1798    poststage1_ldflags=
1799  else
1800    poststage1_ldflags=$withval
1801  fi],
1802 [poststage1_ldflags=
1803  # In stages 2 and 3, default to linking libstdc++ and libgcc
1804  # statically.  But if the user explicitly specified the libraries to
1805  # use, trust that they are doing what they want.
1806  if test "$poststage1_libs" = ""; then
1807    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1808  fi])
1809 AC_SUBST(poststage1_ldflags)
1810
1811 # GCC GRAPHITE dependency isl.
1812 # Basic setup is inlined here, actual checks are in config/isl.m4
1813
1814 AC_ARG_WITH(isl,
1815   [AS_HELP_STRING(
1816    [--with-isl=PATH],
1817    [Specify prefix directory for the installed isl package.
1818     Equivalent to --with-isl-include=PATH/include
1819     plus --with-isl-lib=PATH/lib])])
1820
1821 # Treat --without-isl as a request to disable
1822 # GRAPHITE support and skip all following checks.
1823 if test "x$with_isl" != "xno"; then
1824   # Check for isl
1825   dnl Provide configure switches and initialize islinc & isllibs
1826   dnl with user input.
1827   ISL_INIT_FLAGS
1828   dnl The versions of isl that work for Graphite
1829   ISL_CHECK_VERSION()
1830   dnl Only execute fail-action, if isl has been requested.
1831   ISL_IF_FAILED([
1832     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1833 fi
1834
1835 # If the isl check failed, disable builds of in-tree variant of isl
1836 if test "x$with_isl" = xno ||
1837    test "x$gcc_cv_isl" = xno; then
1838   noconfigdirs="$noconfigdirs isl"
1839   islinc=
1840 fi
1841
1842 AC_SUBST(isllibs)
1843 AC_SUBST(islinc)
1844
1845 # Check for LTO support.
1846 AC_ARG_ENABLE(lto,
1847 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1848 enable_lto=$enableval,
1849 enable_lto=yes; default_enable_lto=yes)
1850
1851 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1852   build_lto_plugin=yes
1853 ],[if test x"$default_enable_lto" = x"yes" ; then
1854     case $target in
1855       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1856       # On other non-ELF platforms, LTO has yet to be validated.
1857       *) enable_lto=no ;;
1858     esac
1859   else
1860   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1861   # It would also be nice to check the binutils support, but we don't
1862   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1863   # warn during gcc/ subconfigure; unless you're bootstrapping with
1864   # -flto it won't be needed until after installation anyway.
1865     case $target in
1866       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1867       *) if test x"$enable_lto" = x"yes"; then
1868         AC_MSG_ERROR([LTO support is not enabled for this target.])
1869         fi
1870       ;;
1871     esac
1872   fi
1873   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1874   # Build it unless LTO was explicitly disabled.
1875   case $target in
1876     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1877     *) ;;
1878   esac
1879 ])
1880
1881 AC_ARG_ENABLE(linker-plugin-configure-flags,
1882   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1883     [additional flags for configuring linker plugins @<:@none@:>@])],
1884   extra_linker_plugin_configure_flags=$enableval,
1885   extra_linker_plugin_configure_flags=)
1886 AC_SUBST(extra_linker_plugin_configure_flags)
1887 AC_ARG_ENABLE(linker-plugin-flags,
1888   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1889     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1890   extra_linker_plugin_flags=$enableval,
1891   extra_linker_plugin_flags=)
1892 AC_SUBST(extra_linker_plugin_flags)
1893
1894 # Enable --enable-host-shared.
1895 # Checked early to determine whether jit is an 'all' language
1896 AC_ARG_ENABLE(host-shared,
1897 [AS_HELP_STRING([--enable-host-shared],
1898                 [build host code as shared libraries])],
1899 [host_shared=$enableval
1900  case $host in
1901    x86_64-*-darwin* | aarch64-*-darwin*)
1902      if test x$host_shared != xyes ; then
1903        # PIC is the default, and actually cannot be switched off.
1904        echo configure.ac: warning: PIC code is required for the configured target, host-shared setting ignored. 1>&2
1905        host_shared=yes
1906      fi ;;
1907   *) ;;
1908  esac],
1909 [case $host in
1910   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
1911   *) host_shared=no ;;
1912  esac])
1913
1914 AC_SUBST(host_shared)
1915
1916 # If we are building PIC/PIE host executables, and we are building dependent
1917 # libs (e.g. GMP) in-tree those libs need to be configured to generate PIC
1918 # code.
1919 host_libs_picflag=
1920 if test "$host_shared" = "yes";then
1921 host_libs_picflag='--with-pic'
1922 fi
1923 AC_SUBST(host_libs_picflag)
1924
1925 # By default, C and C++ are the only stage 1 languages.
1926 stage1_languages=,c,
1927
1928 # Target libraries that we bootstrap.
1929 bootstrap_target_libs=,target-libgcc,
1930
1931 # Figure out what language subdirectories are present.
1932 # Look if the user specified --enable-languages="..."; if not, use
1933 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1934 # go away some day.
1935 # NB:  embedded tabs in this IF block -- do not untabify
1936 if test -d ${srcdir}/gcc; then
1937   if test x"${enable_languages+set}" != xset; then
1938     if test x"${LANGUAGES+set}" = xset; then
1939       enable_languages="${LANGUAGES}"
1940         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1941     else
1942       enable_languages=default
1943     fi
1944   else
1945     if test x"${enable_languages}" = x ||
1946        test x"${enable_languages}" = xyes;
1947        then
1948       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1949       exit 1
1950     fi
1951   fi
1952   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1953
1954   # 'f95' is the old name for the 'fortran' language. We issue a warning
1955   # and make the substitution.
1956   case ,${enable_languages}, in
1957     *,f95,*)
1958       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1959       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1960       ;;
1961   esac
1962
1963   # If bootstrapping, C++ must be enabled.
1964   case ",$enable_languages,:$enable_bootstrap" in
1965     *,c++,*:*) ;;
1966     *:yes)
1967       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1968         enable_languages="${enable_languages},c++"
1969       else
1970         AC_MSG_ERROR([bootstrapping requires c++ sources])
1971       fi
1972       ;;
1973   esac
1974
1975   # First scan to see if an enabled language requires some other language.
1976   # We assume that a given config-lang.in will list all the language
1977   # front ends it requires, even if some are required indirectly.
1978   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1979     case ${lang_frag} in
1980       ..) ;;
1981       # The odd quoting in the next line works around
1982       # an apparent bug in bash 1.12 on linux.
1983       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1984       *)
1985         # From the config-lang.in, get $language, $lang_requires, and
1986         # $lang_requires_boot_languages.
1987         language=
1988         lang_requires=
1989         lang_requires_boot_languages=
1990         # set srcdir during sourcing lang_frag to the gcc dir.
1991         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1992         # polutes this shell
1993         saved_srcdir=${srcdir}
1994         srcdir=${srcdir}/gcc . ${lang_frag}
1995         srcdir=${saved_srcdir}
1996         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1997           case ,${enable_languages}, in
1998             *,$other,*) ;;
1999             *,default,*) ;;
2000             *,all,*) ;;
2001             *,$language,*)
2002               echo " \`$other' language required by \`$language'; enabling" 1>&2
2003               enable_languages="${enable_languages},${other}"
2004               ;;
2005           esac
2006         done
2007         for other in ${lang_requires_boot_languages} ; do
2008           if test "$other" != "c"; then
2009             case ,${enable_stage1_languages}, in
2010               *,$other,*) ;;
2011               *,default,*) ;;
2012               *,all,*) ;;
2013               *)
2014                 case ,${enable_languages}, in
2015                   *,$language,*)
2016                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
2017                     enable_stage1_languages="$enable_stage1_languages,${other}"
2018                     ;;
2019                 esac
2020                 ;;
2021             esac
2022           fi
2023         done
2024         ;;
2025     esac
2026   done
2027
2028   new_enable_languages=,c,
2029
2030   # If LTO is enabled, add the LTO front end.
2031   if test "$enable_lto" = "yes" ; then
2032     case ,${enable_languages}, in
2033       *,lto,*) ;;
2034       *) enable_languages="${enable_languages},lto" ;;
2035     esac
2036     if test "${build_lto_plugin}" = "yes" ; then
2037       configdirs="$configdirs lto-plugin"
2038     fi
2039   fi
2040
2041   # If we're building an offloading compiler, add the LTO front end.
2042   if test x"$enable_as_accelerator_for" != x ; then
2043     case ,${enable_languages}, in
2044       *,lto,*) ;;
2045       *) enable_languages="${enable_languages},lto" ;;
2046     esac
2047   fi
2048
2049   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2050   potential_languages=,c,
2051
2052   enabled_target_libs=
2053   disabled_target_libs=
2054
2055   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2056     case ${lang_frag} in
2057       ..) ;;
2058       # The odd quoting in the next line works around
2059       # an apparent bug in bash 1.12 on linux.
2060       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2061       *)
2062         # From the config-lang.in, get $language, $target_libs,
2063         # $lang_dirs, $boot_language, and $build_by_default
2064         language=
2065         target_libs=
2066         lang_dirs=
2067         subdir_requires=
2068         boot_language=no
2069         build_by_default=yes
2070         # set srcdir during sourcing.  See above about save & restore
2071         saved_srcdir=${srcdir}
2072         srcdir=${srcdir}/gcc . ${lang_frag}
2073         srcdir=${saved_srcdir}
2074         if test x${language} = x; then
2075           echo "${lang_frag} doesn't set \$language." 1>&2
2076           exit 1
2077         fi
2078
2079         if test "$language" = "c++"; then
2080           boot_language=yes
2081         fi
2082
2083         add_this_lang=no
2084         # C is always enabled, so no need to add it again
2085         if test "$language" != "c"; then
2086           case ,${enable_languages}, in
2087             *,${language},*)
2088               # Language was explicitly selected; include it
2089               add_this_lang=yes
2090               ;;
2091             *,all,*)
2092               # All languages are enabled
2093               add_this_lang=all
2094               ;;
2095             *,default,*)
2096               # 'default' was selected, select it if it is a default language
2097               add_this_lang=${build_by_default}
2098               ;;
2099           esac
2100         fi
2101
2102         # Disable languages that need other directories if these aren't available.
2103         for i in $subdir_requires; do
2104           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2105           case ${add_this_lang} in
2106             yes)
2107               # Specifically requested language; tell them.
2108               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2109               ;;
2110             all)
2111               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2112               add_this_lang=unsupported
2113               ;;
2114             *)
2115               # Silently disable.
2116               add_this_lang=unsupported
2117               ;;
2118           esac
2119         done
2120
2121         # Disable Ada if no preexisting GNAT is available.
2122         case ${add_this_lang}:${language}:${have_gnat} in
2123           yes:ada:no)
2124             # Specifically requested language; tell them.
2125             AC_MSG_ERROR([GNAT is required to build $language])
2126             ;;
2127           all:ada:no)
2128             AC_MSG_WARN([GNAT is required to build $language])
2129             add_this_lang=unsupported
2130             ;;
2131           *:ada:no)
2132             # Silently disable.
2133             add_this_lang=unsupported
2134             ;;
2135         esac
2136
2137         # Disable D if no preexisting GDC is available.
2138         case ${add_this_lang}:${language}:${have_gdc} in
2139           yes:d:no)
2140             # Specifically requested language; tell them.
2141             AC_MSG_ERROR([GDC is required to build $language])
2142            ;;
2143           all:d:no)
2144             AC_MSG_WARN([GDC is required to build $language])
2145             add_this_lang=unsupported
2146             ;;
2147           *:d:no)
2148             # Silently disable.
2149             add_this_lang=unsupported
2150             ;;
2151         esac
2152
2153         # Disable jit if -enable-host-shared not specified
2154         # but not if building for Mingw. All code in Windows
2155         # is position independent code (PIC).
2156         case $target in
2157           *mingw*) ;;
2158           *)
2159           case ${add_this_lang}:${language}:${host_shared} in
2160             yes:jit:no)
2161                    # PR jit/64780: explicitly specify --enable-host-shared
2162             AC_MSG_ERROR([
2163 Enabling language "jit" requires --enable-host-shared.
2164
2165 --enable-host-shared typically slows the rest of the compiler down by
2166 a few %, so you must explicitly enable it.
2167
2168 If you want to build both the jit and the regular compiler, it is often
2169 best to do this via two separate configure/builds, in separate
2170 directories, to avoid imposing the performance cost of
2171 --enable-host-shared on the regular compiler.])
2172                     ;;
2173             all:jit:no)
2174               AC_MSG_WARN([--enable-host-shared required to build $language])
2175               add_this_lang=unsupported
2176               ;;
2177             *:jit:no)
2178               # Silently disable.
2179               add_this_lang=unsupported
2180               ;;
2181                 esac
2182           ;;
2183         esac
2184
2185         # Disable a language that is unsupported by the target.
2186         case "${add_this_lang}: $unsupported_languages " in
2187           no:*) ;;
2188           unsupported:*) ;;
2189           *:*" $language "*)
2190             AC_MSG_WARN([${language} not supported for this target])
2191             add_this_lang=unsupported
2192             ;;
2193         esac
2194
2195         case $add_this_lang in
2196           unsupported)
2197             # Remove language-dependent dirs.
2198             disabled_target_libs="$disabled_target_libs $target_libs"
2199             noconfigdirs="$noconfigdirs $lang_dirs"
2200             ;;
2201           no)
2202             # Remove language-dependent dirs; still show language as supported.
2203             disabled_target_libs="$disabled_target_libs $target_libs"
2204             noconfigdirs="$noconfigdirs $lang_dirs"
2205             potential_languages="${potential_languages}${language},"
2206             ;;
2207           all|yes)
2208             new_enable_languages="${new_enable_languages}${language},"
2209             potential_languages="${potential_languages}${language},"
2210             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2211             enabled_target_libs="$enabled_target_libs $target_libs"
2212             case "${boot_language}:,$enable_stage1_languages," in
2213               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2214                 # Add to (comma-separated) list of stage 1 languages.
2215                 case ",$stage1_languages," in
2216                   *,$language,* | ,yes, | ,all,) ;;
2217                   *) stage1_languages="${stage1_languages}${language}," ;;
2218                 esac
2219                 # We need to bootstrap any supporting libraries.
2220                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2221                 ;;
2222             esac
2223             ;;
2224         esac
2225         ;;
2226     esac
2227   done
2228
2229   # Add target libraries which are only needed for disabled languages
2230   # to noconfigdirs.
2231   if test -n "$disabled_target_libs"; then
2232     for dir in $disabled_target_libs; do
2233       case " $enabled_target_libs " in
2234       *" ${dir} "*) ;;
2235       *) noconfigdirs="$noconfigdirs $dir" ;;
2236       esac
2237     done
2238   fi
2239
2240   AC_ARG_ENABLE(stage1-languages,
2241   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2242                   [choose additional languages to build during
2243                   stage1.  Mostly useful for compiler development])],
2244   [case ,${enable_stage1_languages}, in
2245     ,no,|,,)
2246       # Set it to something that will have no effect in the loop below
2247       enable_stage1_languages=c ;;
2248     ,yes,)
2249       enable_stage1_languages=`echo $new_enable_languages | \
2250         sed -e "s/^,//" -e "s/,$//" ` ;;
2251     *,all,*)
2252       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2253         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2254   esac
2255
2256   # Add "good" languages from enable_stage1_languages to stage1_languages,
2257   # while "bad" languages go in missing_languages.  Leave no duplicates.
2258   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2259     case $potential_languages in
2260       *,$i,*)
2261         case $stage1_languages in
2262           *,$i,*) ;;
2263           *) stage1_languages="$stage1_languages$i," ;;
2264         esac ;;
2265       *)
2266         case $missing_languages in
2267           *,$i,*) ;;
2268           *) missing_languages="$missing_languages$i," ;;
2269         esac ;;
2270      esac
2271   done])
2272
2273   # Remove leading/trailing commas that were added for simplicity
2274   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2275   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2276   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2277   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2278
2279   if test "x$missing_languages" != x; then
2280     AC_MSG_ERROR([
2281 The following requested languages could not be built: ${missing_languages}
2282 Supported languages are: ${potential_languages}])
2283   fi
2284   if test "x$new_enable_languages" != "x$enable_languages"; then
2285     echo The following languages will be built: ${new_enable_languages}
2286     enable_languages="$new_enable_languages"
2287   fi
2288
2289   AC_SUBST(stage1_languages)
2290   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2291 fi
2292
2293 # Handle --disable-<component> generically.
2294 for dir in $configdirs $build_configdirs $target_configdirs ; do
2295   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2296   varname=`echo $dirname | sed -e s/+/_/g`
2297   if eval test x\${enable_${varname}} "=" xno ; then
2298     noconfigdirs="$noconfigdirs $dir"
2299   fi
2300 done
2301
2302 # Check for Boehm's garbage collector
2303 AC_ARG_ENABLE(objc-gc,
2304 [AS_HELP_STRING([--enable-objc-gc],
2305                 [enable use of Boehm's garbage collector with the
2306                  GNU Objective-C runtime])])
2307 AC_ARG_WITH([target-bdw-gc],
2308 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2309                 [specify prefix directory for installed bdw-gc package.
2310                  Equivalent to --with-target-bdw-gc-include=PATH/include
2311                  plus --with-target-bdw-gc-lib=PATH/lib])])
2312 AC_ARG_WITH([target-bdw-gc-include],
2313 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2314                 [specify directories for installed bdw-gc include files])])
2315 AC_ARG_WITH([target-bdw-gc-lib],
2316 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2317                 [specify directories for installed bdw-gc library])])
2318
2319 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2320   AC_MSG_CHECKING([for bdw garbage collector])
2321   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2322     dnl no bdw-gw options, assume default locations
2323     AC_MSG_RESULT([using bdw-gc in default locations])
2324   else
2325     dnl bdw-gw options, first error checking, complete checking in libobjc
2326     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2327       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2328     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2329       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2330     else
2331       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2332     fi
2333   fi
2334 esac
2335
2336 # Disable libitm, libsanitizer, libvtv if we're not building C++
2337 case ,${enable_languages}, in
2338   *,c++,*)
2339     # Disable libitm, libsanitizer if we're not building libstdc++
2340     case "${noconfigdirs}" in
2341       *target-libstdc++-v3*)
2342         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2343         ;;
2344       *) ;;
2345     esac
2346     ;;
2347   *)
2348     noconfigdirs="$noconfigdirs target-libitm target-libsanitizer target-libvtv"
2349     ;;
2350 esac
2351
2352 # If gcc/ is not in the source tree then we'll not be building a
2353 # target compiler, assume in that case we don't want to build any
2354 # target libraries or tools.
2355 #
2356 # This was added primarily for the benefit for binutils-gdb who reuse
2357 # this configure script, but don't always have target tools available.
2358 if test ! -d ${srcdir}/gcc; then
2359    skipdirs="${skipdirs} ${target_configdirs}"
2360 fi
2361
2362 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2363 # $build_configdirs and $target_configdirs.
2364 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2365
2366 notsupp=""
2367 for dir in . $skipdirs $noconfigdirs ; do
2368   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2369   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2370     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2371     if test -r $srcdir/$dirname/configure ; then
2372       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2373         true
2374       else
2375         notsupp="$notsupp $dir"
2376       fi
2377     fi
2378   fi
2379   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2380     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2381     if test -r $srcdir/$dirname/configure ; then
2382       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2383         true
2384       else
2385         notsupp="$notsupp $dir"
2386       fi
2387     fi
2388   fi
2389   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2390     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2391     if test -r $srcdir/$dirname/configure ; then
2392       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2393         true
2394       else
2395         notsupp="$notsupp $dir"
2396       fi
2397     fi
2398   fi
2399 done
2400
2401 # Quietly strip out all directories which aren't configurable in this tree.
2402 # This relies on all configurable subdirectories being autoconfiscated, which
2403 # is now the case.
2404 build_configdirs_all="$build_configdirs"
2405 build_configdirs=
2406 for i in ${build_configdirs_all} ; do
2407   j=`echo $i | sed -e s/build-//g`
2408   if test -f ${srcdir}/$j/configure ; then
2409     build_configdirs="${build_configdirs} $i"
2410   fi
2411 done
2412
2413 configdirs_all="$configdirs"
2414 configdirs=
2415 for i in ${configdirs_all} ; do
2416   if test -f ${srcdir}/$i/configure ; then
2417     configdirs="${configdirs} $i"
2418   fi
2419 done
2420
2421 target_configdirs_all="$target_configdirs"
2422 target_configdirs=
2423 for i in ${target_configdirs_all} ; do
2424   j=`echo $i | sed -e s/target-//g`
2425   if test -f ${srcdir}/$j/configure ; then
2426     target_configdirs="${target_configdirs} $i"
2427   fi
2428 done
2429
2430 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2431 # so we have to add it after the preceding checks.
2432 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2433 then
2434   case " $configdirs " in
2435     *" libiberty "*)
2436       # If we can build libiberty, we can also build libiberty-linker-plugin.
2437       configdirs="$configdirs libiberty-linker-plugin"
2438       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2439         --with-libiberty=../libiberty-linker-plugin";;
2440     *)
2441       AC_MSG_ERROR([libiberty missing]);;
2442   esac
2443 fi
2444
2445 # Sometimes we have special requirements for the host libiberty.
2446 extra_host_libiberty_configure_flags=
2447 case " $configdirs " in
2448   *" lto-plugin "* | *" libcc1 "* | *" gdbserver "*)
2449     # When these are to be built as shared libraries, the same applies to
2450     # libiberty.
2451     extra_host_libiberty_configure_flags=--enable-shared
2452     ;;
2453 esac
2454 AC_SUBST(extra_host_libiberty_configure_flags)
2455
2456 # Sometimes we have special requirements for the host zlib.
2457 extra_host_zlib_configure_flags=
2458 case " $configdirs " in
2459   *" bfd "*)
2460     # When bfd is to be built as a shared library, the same applies to
2461     # zlib.
2462     if test "$enable_shared" = "yes"; then
2463       extra_host_zlib_configure_flags=--enable-host-shared
2464     fi
2465     ;;
2466 esac
2467 AC_SUBST(extra_host_zlib_configure_flags)
2468
2469 # Produce a warning message for the subdirs we can't configure.
2470 # This isn't especially interesting in the Cygnus tree, but in the individual
2471 # FSF releases, it's important to let people know when their machine isn't
2472 # supported by the one or two programs in a package.
2473
2474 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2475   # If $appdirs is non-empty, at least one of those directories must still
2476   # be configured, or we error out.  (E.g., if the gas release supports a
2477   # specified target in some subdirs but not the gas subdir, we shouldn't
2478   # pretend that all is well.)
2479   if test -n "$appdirs" ; then
2480     for dir in $appdirs ; do
2481       if test -r $dir/Makefile.in ; then
2482         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2483           appdirs=""
2484           break
2485         fi
2486         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2487           appdirs=""
2488           break
2489         fi
2490       fi
2491     done
2492     if test -n "$appdirs" ; then
2493       echo "*** This configuration is not supported by this package." 1>&2
2494       exit 1
2495     fi
2496   fi
2497   # Okay, some application will build, or we don't care to check.  Still
2498   # notify of subdirs not getting built.
2499   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2500   echo "    ${notsupp}" 1>&2
2501   echo "    (Any other directories should still work fine.)" 1>&2
2502 fi
2503
2504 case "$host" in
2505   *msdosdjgpp*)
2506     enable_gdbtk=no ;;
2507 esac
2508
2509 # To find our prefix, in gcc_cv_tool_prefix.
2510 ACX_TOOL_DIRS
2511
2512 copy_dirs=
2513
2514 AC_ARG_WITH([build-sysroot],
2515   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2516                   [use sysroot as the system root during the build])],
2517   [if test x"$withval" != x ; then
2518      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2519    fi],
2520   [SYSROOT_CFLAGS_FOR_TARGET=])
2521 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2522
2523 AC_ARG_WITH([debug-prefix-map],
2524   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2525                   [map A to B, C to D ... in debug information])],
2526   [if test x"$withval" != x; then
2527      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2528      for debug_map in $withval; do
2529        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2530      done
2531    fi],
2532   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2533 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2534
2535 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2536 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2537 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2538 # We want to ensure that TARGET libraries (which we know are built with
2539 # gcc) are built with "-O2 -g", so include those options when setting
2540 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2541 if test "x$CFLAGS_FOR_TARGET" = x; then
2542   if test "x${is_cross_compiler}" = xyes; then
2543     CFLAGS_FOR_TARGET="-g -O2"
2544   else
2545     CFLAGS_FOR_TARGET=$CFLAGS
2546     case " $CFLAGS " in
2547       *" -O2 "*) ;;
2548       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2549     esac
2550     case " $CFLAGS " in
2551       *" -g "* | *" -g3 "*) ;;
2552       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2553     esac
2554   fi
2555 fi
2556 AC_SUBST(CFLAGS_FOR_TARGET)
2557
2558 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2559   if test "x${is_cross_compiler}" = xyes; then
2560     CXXFLAGS_FOR_TARGET="-g -O2"
2561   else
2562     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2563     case " $CXXFLAGS " in
2564       *" -O2 "*) ;;
2565       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2566     esac
2567     case " $CXXFLAGS " in
2568       *" -g "* | *" -g3 "*) ;;
2569       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2570     esac
2571   fi
2572 fi
2573 AC_SUBST(CXXFLAGS_FOR_TARGET)
2574
2575 AC_SUBST(LDFLAGS_FOR_TARGET)
2576
2577 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2578 # the named directory are copied to $(tooldir)/sys-include.
2579 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2580   if test x${is_cross_compiler} = xno ; then
2581     echo 1>&2 '***' --with-headers is only supported when cross compiling
2582     exit 1
2583   fi
2584   if test x"${with_headers}" != xyes ; then
2585     x=${gcc_cv_tool_prefix}
2586     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2587   fi
2588 fi
2589
2590 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2591 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2592 # are permitted.
2593 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2594   if test x${is_cross_compiler} = xno ; then
2595     echo 1>&2 '***' --with-libs is only supported when cross compiling
2596     exit 1
2597   fi
2598   if test x"${with_libs}" != xyes ; then
2599     # Copy the libraries in reverse order, so that files in the first named
2600     # library override files in subsequent libraries.
2601     x=${gcc_cv_tool_prefix}
2602     for l in ${with_libs}; do
2603       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2604     done
2605   fi
2606 fi
2607
2608 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2609 #
2610 # This is done by determining whether or not the appropriate directory
2611 # is available, and by checking whether or not specific configurations
2612 # have requested that this magic not happen.
2613 #
2614 # The command line options always override the explicit settings in
2615 # configure.ac, and the settings in configure.ac override this magic.
2616 #
2617 # If the default for a toolchain is to use GNU as and ld, and you don't
2618 # want to do that, then you should use the --without-gnu-as and
2619 # --without-gnu-ld options for the configure script.  Similarly, if
2620 # the default is to use the included zlib and you don't want to do that,
2621 # you should use the --with-system-zlib option for the configure script.
2622
2623 if test x${use_gnu_as} = x &&
2624    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2625   with_gnu_as=yes
2626   extra_host_args="$extra_host_args --with-gnu-as"
2627 fi
2628
2629 if test x${use_gnu_ld} = x &&
2630    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2631   with_gnu_ld=yes
2632   extra_host_args="$extra_host_args --with-gnu-ld"
2633 fi
2634
2635 if test x${use_included_zlib} = x &&
2636    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2637   :
2638 else
2639   with_system_zlib=yes
2640   extra_host_args="$extra_host_args --with-system-zlib"
2641 fi
2642
2643 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2644 # can detect this case.
2645
2646 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2647   with_newlib=yes
2648   extra_host_args="$extra_host_args --with-newlib"
2649 fi
2650
2651 # Handle ${copy_dirs}
2652 set fnord ${copy_dirs}
2653 shift
2654 while test $# != 0 ; do
2655   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2656     :
2657   else
2658     echo Copying $1 to $2
2659
2660     # Use the install script to create the directory and all required
2661     # parent directories.
2662     if test -d $2 ; then
2663       :
2664     else
2665       echo >config.temp
2666       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2667     fi
2668
2669     # Copy the directory, assuming we have tar.
2670     # FIXME: Should we use B in the second tar?  Not all systems support it.
2671     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2672
2673     # It is the responsibility of the user to correctly adjust all
2674     # symlinks.  If somebody can figure out how to handle them correctly
2675     # here, feel free to add the code.
2676
2677     echo $1 > $2/COPIED
2678   fi
2679   shift; shift
2680 done
2681
2682 # Determine a target-dependent exec_prefix that the installed
2683 # gcc will search in.  Keep this list sorted by triplet, with
2684 # the *-*-osname triplets last.
2685 md_exec_prefix=
2686 case "${target}" in
2687   i[[34567]]86-pc-msdosdjgpp*)
2688     md_exec_prefix=/dev/env/DJDIR/bin
2689     ;;
2690   *-*-hpux* | \
2691   *-*-nto-qnx* | \
2692   *-*-solaris2*)
2693     md_exec_prefix=/usr/ccs/bin
2694     ;;
2695 esac
2696
2697 extra_arflags_for_target=
2698 extra_nmflags_for_target=
2699 extra_ranlibflags_for_target=
2700 target_makefile_frag=/dev/null
2701 case "${target}" in
2702   spu-*-*)
2703     target_makefile_frag="config/mt-spu"
2704     ;;
2705   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2706     target_makefile_frag="config/mt-sde"
2707     ;;
2708   mipsisa*-*-elfoabi*)
2709     target_makefile_frag="config/mt-mips-elfoabi"
2710     ;;
2711   mips*-*-*linux* | mips*-*-gnu*)
2712     target_makefile_frag="config/mt-mips-gnu"
2713     ;;
2714   nios2-*-elf*)
2715     target_makefile_frag="config/mt-nios2-elf"
2716     ;;
2717   *-*-linux-android*)
2718     target_makefile_frag="config/mt-android"
2719     ;;
2720   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2721     target_makefile_frag="config/mt-gnu"
2722     ;;
2723   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2724     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2725     # commands to handle both 32-bit and 64-bit objects.  These flags are
2726     # harmless if we're using GNU nm or ar.
2727     extra_arflags_for_target=" -X32_64"
2728     extra_nmflags_for_target=" -B -X32_64"
2729     ;;
2730 esac
2731
2732 alphaieee_frag=/dev/null
2733 case $target in
2734   alpha*-*-*)
2735     # This just makes sure to use the -mieee option to build target libs.
2736     # This should probably be set individually by each library.
2737     alphaieee_frag="config/mt-alphaieee"
2738     ;;
2739 esac
2740
2741 # If --enable-target-optspace always use -Os instead of -O2 to build
2742 # the target libraries, similarly if it is not specified, use -Os
2743 # on selected platforms.
2744 ospace_frag=/dev/null
2745 case "${enable_target_optspace}:${target}" in
2746   yes:*)
2747     ospace_frag="config/mt-ospace"
2748     ;;
2749   :d30v-*)
2750     ospace_frag="config/mt-d30v"
2751     ;;
2752   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2753     ospace_frag="config/mt-ospace"
2754     ;;
2755   no:* | :*)
2756     ;;
2757   *)
2758     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2759     ;;
2760 esac
2761
2762 # Some systems (e.g., one of the i386-aix systems the gas testers are
2763 # using) don't handle "\$" correctly, so don't use it here.
2764 tooldir='${exec_prefix}'/${target_noncanonical}
2765 build_tooldir=${tooldir}
2766
2767 # Create a .gdbinit file which runs the one in srcdir
2768 # and tells GDB to look there for source files.
2769
2770 if test -r ${srcdir}/.gdbinit ; then
2771   case ${srcdir} in
2772     .) ;;
2773     *) cat > ./.gdbinit <<EOF
2774 # ${NO_EDIT}
2775 dir ${srcdir}
2776 dir .
2777 source ${srcdir}/.gdbinit
2778 EOF
2779     ;;
2780   esac
2781 fi
2782
2783 # Make sure that the compiler is able to generate an executable.  If it
2784 # can't, we are probably in trouble.  We don't care whether we can run the
2785 # executable--we might be using a cross compiler--we only care whether it
2786 # can be created.  At this point the main configure script has set CC.
2787 we_are_ok=no
2788 echo "int main () { return 0; }" > conftest.c
2789 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2790 if test $? = 0 ; then
2791   if test -s conftest || test -s conftest.exe ; then
2792     we_are_ok=yes
2793   fi
2794 fi
2795 case $we_are_ok in
2796   no)
2797     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2798     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2799     rm -f conftest*
2800     exit 1
2801     ;;
2802 esac
2803 rm -f conftest*
2804
2805 # Decide which environment variable is used to find dynamic libraries.
2806 case "${host}" in
2807   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2808   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2809   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2810   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2811 esac
2812
2813 # On systems where the dynamic library environment variable is PATH,
2814 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2815 # built executables to PATH.
2816 if test "$RPATH_ENVVAR" = PATH; then
2817   GCC_SHLIB_SUBDIR=/shlib
2818 else
2819   GCC_SHLIB_SUBDIR=
2820 fi
2821
2822 # Adjust the toplevel makefile according to whether bootstrap was selected.
2823 case $enable_bootstrap in
2824   yes)
2825     bootstrap_suffix=bootstrap
2826     BUILD_CONFIG=bootstrap-debug
2827     ;;
2828   no)
2829     bootstrap_suffix=no-bootstrap
2830     BUILD_CONFIG=
2831     ;;
2832 esac
2833
2834 AC_MSG_CHECKING(for default BUILD_CONFIG)
2835
2836 AC_ARG_WITH([build-config],
2837   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2838                   [use config/NAME.mk build configuration])],
2839   [case $with_build_config in
2840    yes) with_build_config= ;;
2841    no) with_build_config= BUILD_CONFIG= ;;
2842    esac])
2843
2844 if test "x${with_build_config}" != x; then
2845   BUILD_CONFIG=$with_build_config
2846 else
2847   case $BUILD_CONFIG in
2848   bootstrap-debug)
2849     if echo "int f (void) { return 0; }" > conftest.c &&
2850        ${CC} -c conftest.c &&
2851        mv conftest.o conftest.o.g0 &&
2852        ${CC} -c -g conftest.c &&
2853        mv conftest.o conftest.o.g &&
2854        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2855       :
2856     else
2857       BUILD_CONFIG=
2858     fi
2859     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2860     ;;
2861   esac
2862 fi
2863 AC_MSG_RESULT($BUILD_CONFIG)
2864 AC_SUBST(BUILD_CONFIG)
2865
2866 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2867 AC_MSG_CHECKING([for --enable-vtable-verify])
2868 AC_ARG_ENABLE(vtable-verify,
2869 [AS_HELP_STRING([--enable-vtable-verify],
2870                 [Enable vtable verification feature])],
2871 [case "$enableval" in
2872  yes) enable_vtable_verify=yes ;;
2873  no)  enable_vtable_verify=no ;;
2874  *)   enable_vtable_verify=no;;
2875  esac],
2876 [enable_vtable_verify=no])
2877 AC_MSG_RESULT($enable_vtable_verify)
2878
2879 # Record target_configdirs and the configure arguments for target and
2880 # build configuration in Makefile.
2881 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2882 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2883 bootstrap_fixincludes=no
2884
2885 # If we are building libgomp, bootstrap it.
2886 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2887   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2888 fi
2889
2890 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2891 # or bootstrap-ubsan, bootstrap it.
2892 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2893   case "$BUILD_CONFIG" in
2894     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
2895       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2896       bootstrap_fixincludes=yes
2897       ;;
2898   esac
2899 fi
2900
2901 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2902 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2903    test "$enable_vtable_verify" != no; then
2904   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2905 fi
2906
2907 # If we are building libatomic and the list of enabled languages includes the
2908 # D frontend, bootstrap it.
2909 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
2910   case ,${enable_languages}, in
2911     *,d,*)
2912       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
2913       ;;
2914   esac
2915 fi
2916
2917 # Determine whether gdb needs tk/tcl or not.
2918 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2919 # and in that case we want gdb to be built without tk.  Ugh!
2920 # In fact I believe gdb is the *only* package directly dependent on tk,
2921 # so we should be able to put the 'maybe's in unconditionally and
2922 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2923 # 100% sure that that's safe though.
2924
2925 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2926 case "$enable_gdbtk" in
2927   no)
2928     GDB_TK="" ;;
2929   yes)
2930     GDB_TK="${gdb_tk}" ;;
2931   *)
2932     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2933     # distro.  Eventually someone will fix this and move Insight, nee
2934     # gdbtk to a separate directory.
2935     if test -d ${srcdir}/gdb/gdbtk ; then
2936       GDB_TK="${gdb_tk}"
2937     else
2938       GDB_TK=""
2939     fi
2940     ;;
2941 esac
2942 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2943 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2944
2945 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2946 # else does, only include them if one of these is built.  The Makefile
2947 # provides the ordering, so it's enough here to add to the list.
2948 case " ${configdirs} " in
2949   *\ gdb\ *)
2950     configdirs="${configdirs} gnulib gdbsupport"
2951     ;;
2952   *\ gdbserver\ *)
2953     configdirs="${configdirs} gnulib gdbsupport"
2954     ;;
2955   *\ sim\ *)
2956     configdirs="${configdirs} gnulib"
2957     ;;
2958 esac
2959
2960 # Strip out unwanted targets.
2961
2962 # While at that, we remove Makefiles if we were started for recursive
2963 # configuration, so that the top-level Makefile reconfigures them,
2964 # like we used to do when configure itself was recursive.
2965
2966 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2967 # but now we're fixing up the Makefile ourselves with the additional
2968 # commands passed to AC_CONFIG_FILES.  Use separate variables
2969 # extrasub-{build,host,target} not because there is any reason to split
2970 # the substitutions up that way, but only to remain below the limit of
2971 # 99 commands in a script, for HP-UX sed.
2972
2973 # Do not nest @if/@endif or @unless/@endunless pairs, because
2974 # configure will not warn you at all.
2975
2976 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2977   yes:yes:*\ gold\ *:*,c++,*) ;;
2978   yes:yes:*\ gold\ *:*)
2979     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2980     ;;
2981 esac
2982
2983 extrasub_build=
2984 for module in ${build_configdirs} ; do
2985   if test -z "${no_recursion}" \
2986      && test -f ${build_subdir}/${module}/Makefile; then
2987     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2988     rm -f ${build_subdir}/${module}/Makefile
2989   fi
2990   extrasub_build="$extrasub_build
2991 /^@if build-$module\$/d
2992 /^@endif build-$module\$/d
2993 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2994 /^@if build-$module-$bootstrap_suffix\$/d
2995 /^@endif build-$module-$bootstrap_suffix\$/d
2996 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2997 done
2998 extrasub_host=
2999 for module in ${configdirs} ; do
3000   if test -z "${no_recursion}"; then
3001     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
3002       if test -f ${file}; then
3003         echo 1>&2 "*** removing ${file} to force reconfigure"
3004         rm -f ${file}
3005       fi
3006     done
3007   fi
3008   case ${module},${bootstrap_fixincludes} in
3009     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
3010     *) host_bootstrap_suffix=$bootstrap_suffix ;;
3011   esac
3012   extrasub_host="$extrasub_host
3013 /^@if $module\$/d
3014 /^@endif $module\$/d
3015 /^@unless $module\$/,/^@endunless $module\$/d
3016 /^@if $module-$host_bootstrap_suffix\$/d
3017 /^@endif $module-$host_bootstrap_suffix\$/d
3018 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
3019 done
3020 extrasub_target=
3021 for module in ${target_configdirs} ; do
3022   if test -z "${no_recursion}" \
3023      && test -f ${target_subdir}/${module}/Makefile; then
3024     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
3025     rm -f ${target_subdir}/${module}/Makefile
3026   fi
3027
3028   # We only bootstrap target libraries listed in bootstrap_target_libs.
3029   case $bootstrap_target_libs in
3030     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
3031     *) target_bootstrap_suffix=no-bootstrap ;;
3032   esac
3033
3034   extrasub_target="$extrasub_target
3035 /^@if target-$module\$/d
3036 /^@endif target-$module\$/d
3037 /^@unless target-$module\$/,/^@endunless target-$module\$/d
3038 /^@if target-$module-$target_bootstrap_suffix\$/d
3039 /^@endif target-$module-$target_bootstrap_suffix\$/d
3040 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
3041 done
3042
3043 # Do the final fixup along with target modules.
3044 extrasub_target="$extrasub_target
3045 /^@if /,/^@endif /d
3046 /^@unless /d
3047 /^@endunless /d"
3048
3049 if test "$enable_pgo_build" != "no"; then
3050   extrasub_build="$extrasub_build
3051 /^@if pgo-build\$/d
3052 /^@endif pgo-build\$/d"
3053 fi
3054
3055 # Create the serialization dependencies.  This uses a temporary file.
3056
3057 AC_ARG_ENABLE([serial-configure],
3058 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3059                 [force sequential configuration of
3060                  sub-packages for the host, target or build
3061                  machine, or all sub-packages])])
3062
3063 case ${enable_serial_configure} in
3064   yes)
3065     enable_serial_build_configure=yes
3066     enable_serial_host_configure=yes
3067     enable_serial_target_configure=yes
3068     ;;
3069 esac
3070
3071 # These force 'configure's to be done one at a time, to avoid problems
3072 # with contention over a shared config.cache.
3073 rm -f serdep.tmp
3074 echo '# serdep.tmp' > serdep.tmp
3075 olditem=
3076 test "x${enable_serial_build_configure}" = xyes &&
3077 for item in ${build_configdirs} ; do
3078   case ${olditem} in
3079     "") ;;
3080     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3081   esac
3082   olditem=${item}
3083 done
3084 olditem=
3085 test "x${enable_serial_host_configure}" = xyes &&
3086 for item in ${configdirs} ; do
3087   case ${olditem} in
3088     "") ;;
3089     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3090   esac
3091   olditem=${item}
3092 done
3093 olditem=
3094 test "x${enable_serial_target_configure}" = xyes &&
3095 for item in ${target_configdirs} ; do
3096   case ${olditem} in
3097     "") ;;
3098     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3099   esac
3100   olditem=${item}
3101 done
3102 serialization_dependencies=serdep.tmp
3103 AC_SUBST_FILE(serialization_dependencies)
3104
3105 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3106 # target, nonopt, and variable assignments.  These are the ones we
3107 # might not want to pass down to subconfigures.  The exception being
3108 # --cache-file=/dev/null, which is used to turn off the use of cache
3109 # files altogether, and which should be passed on to subconfigures.
3110 # Also strip program-prefix, program-suffix, and program-transform-name,
3111 # so that we can pass down a consistent program-transform-name.
3112 baseargs=
3113 tbaseargs=
3114 keep_next=no
3115 skip_next=no
3116 eval "set -- $ac_configure_args"
3117 for ac_arg
3118 do
3119   if test X"$skip_next" = X"yes"; then
3120     skip_next=no
3121     continue
3122   fi
3123   if test X"$keep_next" = X"yes"; then
3124     case $ac_arg in
3125       *\'*)
3126         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3127     esac
3128     baseargs="$baseargs '$ac_arg'"
3129     tbaseargs="$tbaseargs '$ac_arg'"
3130     keep_next=no
3131     continue
3132   fi
3133
3134   # Handle separated arguments.  Based on the logic generated by
3135   # autoconf 2.59.
3136   case $ac_arg in
3137     *=* | --config-cache | -C | -disable-* | --disable-* \
3138       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3139       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3140       | -with-* | --with-* | -without-* | --without-* | --x)
3141       separate_arg=no
3142       ;;
3143     -*)
3144       separate_arg=yes
3145       ;;
3146     *)
3147       separate_arg=no
3148       ;;
3149   esac
3150
3151   skip_targ=no
3152   case $ac_arg in
3153 changequote(,)
3154   --with-* | --without-*)
3155     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3156
3157     case $libopt in
3158     *[-_]include)
3159       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3160       ;;
3161     *[-_]lib)
3162       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3163       ;;
3164     *)
3165       lib=$libopt
3166       ;;
3167     esac
3168 changequote([,])
3169
3170     case $lib in
3171     mpc | mpfr | gmp | isl)
3172       # If we're processing --with-$lib, --with-$lib-include or
3173       # --with-$lib-lib, for one of the libs above, and target is
3174       # different from host, don't pass the current argument to any
3175       # target library's configure.
3176       if test x$is_cross_compiler = xyes; then
3177         skip_targ=yes
3178       fi
3179       ;;
3180     esac
3181     ;;
3182   esac
3183
3184   case "$ac_arg" in
3185     --cache-file=/dev/null | \
3186     -cache-file=/dev/null )
3187       # Handled here to avoid the test to skip args below.
3188       baseargs="$baseargs '$ac_arg'"
3189       tbaseargs="$tbaseargs '$ac_arg'"
3190       # Assert: $separate_arg should always be no.
3191       keep_next=$separate_arg
3192       ;;
3193     --no*)
3194       continue
3195       ;;
3196     --c* | \
3197     --sr* | \
3198     --ho* | \
3199     --bu* | \
3200     --t* | \
3201     --program-* | \
3202     -cache_file* | \
3203     -srcdir* | \
3204     -host* | \
3205     -build* | \
3206     -target* | \
3207     -program-prefix* | \
3208     -program-suffix* | \
3209     -program-transform-name* )
3210       skip_next=$separate_arg
3211       continue
3212       ;;
3213     -*)
3214       # An option.  Add it.
3215       case $ac_arg in
3216         *\'*)
3217           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3218       esac
3219       baseargs="$baseargs '$ac_arg'"
3220       if test X"$skip_targ" = Xno; then
3221         tbaseargs="$tbaseargs '$ac_arg'"
3222       fi
3223       keep_next=$separate_arg
3224       ;;
3225     *)
3226       # Either a variable assignment, or a nonopt (triplet).  Don't
3227       # pass it down; let the Makefile handle this.
3228       continue
3229       ;;
3230   esac
3231 done
3232 # Remove the initial space we just introduced and, as these will be
3233 # expanded by make, quote '$'.
3234 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3235
3236 # Add in --program-transform-name, after --program-prefix and
3237 # --program-suffix have been applied to it.  Autoconf has already
3238 # doubled dollar signs and backslashes in program_transform_name; we want
3239 # the backslashes un-doubled, and then the entire thing wrapped in single
3240 # quotes, because this will be expanded first by make and then by the shell.
3241 # Also, because we want to override the logic in subdir configure scripts to
3242 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3243 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3244 ${program_transform_name}
3245 EOF_SED
3246 gcc_transform_name=`cat conftestsed.out`
3247 rm -f conftestsed.out
3248 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3249 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3250 if test "$silent" = yes; then
3251   baseargs="$baseargs --silent"
3252   tbaseargs="$tbaseargs --silent"
3253 fi
3254 baseargs="$baseargs --disable-option-checking"
3255 tbaseargs="$tbaseargs --disable-option-checking"
3256
3257 # Record and document user additions to sub configure arguments.
3258 AC_ARG_VAR([build_configargs],
3259            [additional configure arguments for build directories])
3260 AC_ARG_VAR([host_configargs],
3261            [additional configure arguments for host directories])
3262 AC_ARG_VAR([target_configargs],
3263            [additional configure arguments for target directories])
3264
3265 # For the build-side libraries, we just need to pretend we're native,
3266 # and not use the same cache file.  Multilibs are neither needed nor
3267 # desired.  We can't even use the same cache file for all build-side
3268 # libraries, as they're compiled differently; some with C, some with
3269 # C++ or with different feature-enabling options.
3270 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3271
3272 # For host modules, accept cache file option, or specification as blank.
3273 case "${cache_file}" in
3274 "") # empty
3275   cache_file_option="" ;;
3276 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3277   cache_file_option="--cache-file=${cache_file}" ;;
3278 *) # relative path
3279   cache_file_option="--cache-file=../${cache_file}" ;;
3280 esac
3281
3282 # Host dirs don't like to share a cache file either, horribly enough.
3283 # This seems to be due to autoconf 2.5x stupidity.
3284 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3285
3286 target_configargs="$target_configargs ${tbaseargs}"
3287
3288 # Passing a --with-cross-host argument lets the target libraries know
3289 # whether they are being built with a cross-compiler or being built
3290 # native.  However, it would be better to use other mechanisms to make the
3291 # sorts of decisions they want to make on this basis.  Please consider
3292 # this option to be deprecated.  FIXME.
3293 if test x${is_cross_compiler} = xyes ; then
3294   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3295 fi
3296
3297 # Special user-friendly check for native x86_64-linux build, if
3298 # multilib is not explicitly enabled.
3299 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3300   x86_64-*linux*:yes:$build:$build:)
3301     # Make sure we have a development environment that handles 32-bit
3302     dev64=no
3303     echo "int main () { return 0; }" > conftest.c
3304     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3305     if test $? = 0 ; then
3306       if test -s conftest || test -s conftest.exe ; then
3307         dev64=yes
3308       fi
3309     fi
3310     rm -f conftest*
3311     if test x${dev64} != xyes ; then
3312       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3313     fi
3314     ;;
3315 esac
3316
3317 # Default to --enable-multilib.
3318 if test x${enable_multilib} = x ; then
3319   target_configargs="--enable-multilib ${target_configargs}"
3320 fi
3321
3322 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3323 # changed from the earlier setting of with_newlib.
3324 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3325   target_configargs="--with-newlib ${target_configargs}"
3326 fi
3327
3328 # Different target subdirs use different values of certain variables
3329 # (notably CXX).  Worse, multilibs use *lots* of different values.
3330 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3331 # it doesn't automatically accept command-line overrides of them.
3332 # This means it's not safe for target subdirs to share a cache file,
3333 # which is disgusting, but there you have it.  Hopefully this can be
3334 # fixed in future.  It's still worthwhile to use a cache file for each
3335 # directory.  I think.
3336
3337 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3338 # We need to pass --target, as newer autoconf's requires consistency
3339 # for target_alias and gcc doesn't manage it consistently.
3340 target_configargs="--cache-file=./config.cache ${target_configargs}"
3341
3342 FLAGS_FOR_TARGET=
3343 case " $target_configdirs " in
3344  *" newlib "*)
3345   case " $target_configargs " in
3346   *" --with-newlib "*)
3347    case "$target" in
3348     *-cygwin*)
3349       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3350       ;;
3351    esac
3352
3353    # If we're not building GCC, don't discard standard headers.
3354    if test -d ${srcdir}/gcc; then
3355      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3356
3357      if test "${build}" != "${host}"; then
3358        # On Canadian crosses, CC_FOR_TARGET will have already been set
3359        # by `configure', so we won't have an opportunity to add -Bgcc/
3360        # to it.  This is right: we don't want to search that directory
3361        # for binaries, but we want the header files in there, so add
3362        # them explicitly.
3363        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3364
3365        # Someone might think of using the pre-installed headers on
3366        # Canadian crosses, in case the installed compiler is not fully
3367        # compatible with the compiler being built.  In this case, it
3368        # would be better to flag an error than risking having
3369        # incompatible object files being constructed.  We can't
3370        # guarantee that an error will be flagged, but let's hope the
3371        # compiler will do it, when presented with incompatible header
3372        # files.
3373      fi
3374    fi
3375
3376    case "${target}-${is_cross_compiler}" in
3377    i[[3456789]]86-*-linux*-no)
3378       # Here host == target, so we don't need to build gcc,
3379       # so we don't want to discard standard headers.
3380       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3381       ;;
3382    *)
3383       # If we're building newlib, use its generic headers last, but search
3384       # for any libc-related directories first (so make it the last -B
3385       # switch).
3386       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3387
3388       # If we're building libgloss, find the startup file, simulator library
3389       # and linker script.
3390       case " $target_configdirs " in
3391         *" libgloss "*)
3392         # Look for startup file, simulator library and maybe linker script.
3393         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3394         # Look for libnosys.a in case the target needs it.
3395         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3396         # Most targets have the linker script in the source directory.
3397         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3398         ;;
3399       esac
3400       ;;
3401    esac
3402    ;;
3403   esac
3404   ;;
3405 esac
3406
3407 case "$target" in
3408   x86_64-*mingw* | *-w64-mingw*)
3409   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3410   # however, use a symlink named 'mingw' in ${prefix} .
3411     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3412     ;;
3413   *-mingw*)
3414   # MinGW can't be handled as Cygwin above since it does not use newlib.
3415     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3416     ;;
3417 esac
3418
3419 # Allow the user to override the flags for
3420 # our build compiler if desired.
3421 if test x"${build}" = x"${host}" ; then
3422   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3423   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3424   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3425   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3426 fi
3427
3428 # On Canadian crosses, we'll be searching the right directories for
3429 # the previously-installed cross compiler, so don't bother to add
3430 # flags for directories within the install tree of the compiler
3431 # being built; programs in there won't even run.
3432 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3433   # Search for pre-installed headers if nothing else fits.
3434   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3435 fi
3436
3437 if test "x${use_gnu_ld}" = x &&
3438    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3439   # Arrange for us to find uninstalled linker scripts.
3440   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3441 fi
3442
3443 # Search for other target-specific linker scripts and such.
3444 case "${target}" in
3445   mep*)
3446     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3447     ;;
3448   # The VxWorks support for shared libraries is getting in
3449   # incrementally.  Make sure it doesn't get activated implicitly:
3450   *vxworks*)
3451     if test "${enable_shared-unset}" = unset ; then
3452       enable_shared=no
3453       # So the build of libraries knows ...
3454       target_configargs="${target_configargs} --disable-shared"
3455       # So gcc knows ...
3456       host_configargs="${host_configargs} --disable-shared"
3457     fi
3458     ;;
3459 esac
3460
3461 # Makefile fragments.
3462 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3463 do
3464   eval fragval=\$$frag
3465   if test $fragval != /dev/null; then
3466     eval $frag=${srcdir}/$fragval
3467   fi
3468 done
3469 AC_SUBST_FILE(host_makefile_frag)
3470 AC_SUBST_FILE(target_makefile_frag)
3471 AC_SUBST_FILE(alphaieee_frag)
3472 AC_SUBST_FILE(ospace_frag)
3473
3474 # Miscellanea: directories, flags, etc.
3475 AC_SUBST(RPATH_ENVVAR)
3476 AC_SUBST(GCC_SHLIB_SUBDIR)
3477 AC_SUBST(tooldir)
3478 AC_SUBST(build_tooldir)
3479 AC_SUBST(CONFIGURE_GDB_TK)
3480 AC_SUBST(GDB_TK)
3481 AC_SUBST(INSTALL_GDB_TK)
3482
3483 # Build module lists & subconfigure args.
3484 AC_SUBST(build_configargs)
3485 AC_SUBST(build_configdirs)
3486
3487 # Host module lists & subconfigure args.
3488 AC_SUBST(host_configargs)
3489 AC_SUBST(configdirs)
3490 AC_SUBST(target_configdirs)
3491
3492 # Target module lists & subconfigure args.
3493 AC_SUBST(target_configargs)
3494
3495
3496 # Build tools.
3497 AC_SUBST(AR_FOR_BUILD)
3498 AC_SUBST(AS_FOR_BUILD)
3499 AC_SUBST(CC_FOR_BUILD)
3500 AC_SUBST(CFLAGS_FOR_BUILD)
3501 AC_SUBST(CPP_FOR_BUILD)
3502 AC_SUBST(CPPFLAGS_FOR_BUILD)
3503 AC_SUBST(CXXFLAGS_FOR_BUILD)
3504 AC_SUBST(CXX_FOR_BUILD)
3505 AC_SUBST(DLLTOOL_FOR_BUILD)
3506 AC_SUBST(DSYMUTIL_FOR_BUILD)
3507 AC_SUBST(GFORTRAN_FOR_BUILD)
3508 AC_SUBST(GOC_FOR_BUILD)
3509 AC_SUBST(GDC_FOR_BUILD)
3510 AC_SUBST(LDFLAGS_FOR_BUILD)
3511 AC_SUBST(LD_FOR_BUILD)
3512 AC_SUBST(NM_FOR_BUILD)
3513 AC_SUBST(RANLIB_FOR_BUILD)
3514 AC_SUBST(WINDMC_FOR_BUILD)
3515 AC_SUBST(WINDRES_FOR_BUILD)
3516
3517 # Generate default definitions for YACC, M4, LEX and other programs that run
3518 # on the build machine.  These are used if the Makefile can't locate these
3519 # programs in objdir.
3520 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3521
3522 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3523 case " $build_configdirs " in
3524   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3525 esac
3526
3527 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3528 case " $build_configdirs " in
3529   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3530 esac
3531
3532 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3533 case " $build_configdirs " in
3534   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3535 esac
3536
3537 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3538 case " $build_configdirs " in
3539   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3540   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3541 esac
3542
3543 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3544 case " $build_configdirs " in
3545   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3546 esac
3547
3548 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3549 case " $build_configdirs " in
3550   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3551   *)
3552 changequote(,)
3553     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3554     # higher, else we use the "missing" dummy.
3555     if ${MAKEINFO} --version \
3556        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3557       :
3558     else
3559       MAKEINFO="$MISSING makeinfo"
3560     fi
3561     ;;
3562 changequote([,])
3563 esac
3564
3565 # FIXME: expect and dejagnu may become build tools?
3566
3567 AC_CHECK_PROGS(EXPECT, expect, expect)
3568 case " $configdirs " in
3569   *" expect "*)
3570     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3571     ;;
3572 esac
3573
3574 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3575 case " $configdirs " in
3576   *" dejagnu "*)
3577     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3578     ;;
3579 esac
3580
3581
3582 # Host tools.
3583 NCN_STRICT_CHECK_TOOLS(AR, ar)
3584 NCN_STRICT_CHECK_TOOLS(AS, as)
3585 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3586 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3587 NCN_STRICT_CHECK_TOOLS(LD, ld)
3588 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3589 NCN_STRICT_CHECK_TOOLS(NM, nm)
3590 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3591 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3592 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3593 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3594 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3595 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3596 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3597 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3598 AC_SUBST(CC)
3599 AC_SUBST(CXX)
3600 AC_SUBST(CFLAGS)
3601 AC_SUBST(CXXFLAGS)
3602 AC_SUBST(GDC)
3603 AC_SUBST(GDCFLAGS)
3604
3605 # Target tools.
3606 AC_ARG_WITH([build-time-tools],
3607   [AS_HELP_STRING([--with-build-time-tools=PATH],
3608                   [use given path to find target tools during the build])],
3609   [case x"$withval" in
3610      x/*) ;;
3611      *)
3612        with_build_time_tools=
3613        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3614        ;;
3615    esac],
3616   [with_build_time_tools=])
3617
3618 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3619 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3620 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3621 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3622 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3623 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3624 NCN_STRICT_CHECK_TARGET_TOOLS(GM2_FOR_TARGET, gm2)
3625
3626 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3627 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3628 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3629 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3630 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3631 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3632 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3633 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3634 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3635 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3636 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3637 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3638 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3639 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3640 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3641
3642 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3643
3644 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3645 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3646 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3647 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3648 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3649                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3650                 c++)
3651 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3652                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3653                 c++)
3654 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3655 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3656 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3657 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3658                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3659 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3660                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3661 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3662                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3663 GCC_TARGET_TOOL(gm2, GM2_FOR_TARGET, GM2,
3664                 [gcc/gm2 -B$$r/$(HOST_SUBDIR)/gcc/], m2)
3665 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3666 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3667 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3668 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3669 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3670 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3671 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3672 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3673 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3674 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3675 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3676
3677 AC_SUBST(FLAGS_FOR_TARGET)
3678 AC_SUBST(RAW_CXX_FOR_TARGET)
3679
3680 # Certain tools may need extra flags.
3681 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3682 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3683 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3684
3685 # When building target libraries, except in a Canadian cross, we use
3686 # the same toolchain as the compiler we just built.
3687 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3688 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3689 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3690 if test $host = $build; then
3691   case " $configdirs " in
3692     *" gcc "*)
3693       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3694       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3695       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3696       ;;
3697   esac
3698 fi
3699
3700 AC_SUBST(COMPILER_AS_FOR_TARGET)
3701 AC_SUBST(COMPILER_LD_FOR_TARGET)
3702 AC_SUBST(COMPILER_NM_FOR_TARGET)
3703
3704 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3705 AC_ARG_ENABLE(maintainer-mode,
3706 [AS_HELP_STRING([--enable-maintainer-mode],
3707                 [enable make rules and dependencies not useful
3708                  (and sometimes confusing) to the casual installer])],
3709       USE_MAINTAINER_MODE=$enableval,
3710       USE_MAINTAINER_MODE=no)
3711 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3712 AC_SUBST(MAINTAINER_MODE_TRUE)
3713 AC_SUBST(MAINTAINER_MODE_FALSE)
3714 if test "$USE_MAINTAINER_MODE" = yes; then
3715   MAINTAINER_MODE_TRUE=
3716   MAINTAINER_MODE_FALSE='#'
3717 else
3718   MAINTAINER_MODE_TRUE='#'
3719   MAINTAINER_MODE_FALSE=
3720 fi
3721 MAINT=$MAINTAINER_MODE_TRUE
3722 AC_SUBST(MAINT)dnl
3723
3724 # ---------------------
3725 # GCC bootstrap support
3726 # ---------------------
3727
3728 # Stage specific cflags for build.
3729 stage1_cflags="-g"
3730 case $build in
3731   vax-*-*)
3732     case ${GCC} in
3733       yes) stage1_cflags="-g -Wa,-J" ;;
3734       *) stage1_cflags="-g -J" ;;
3735     esac ;;
3736 esac
3737
3738 AC_SUBST(stage1_cflags)
3739
3740 # Enable --enable-checking in stage1 of the compiler.
3741 AC_ARG_ENABLE(stage1-checking,
3742 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3743                 [choose additional checking for stage1 of the compiler])],
3744 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3745 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3746   # For --disable-checking or implicit --enable-checking=release, avoid
3747   # setting --enable-checking=gc in the default stage1 checking for LTO
3748   # bootstraps.  See PR62077.
3749   case $BUILD_CONFIG in
3750     *lto*)
3751       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3752     *)
3753       stage1_checking=--enable-checking=yes,types;;
3754   esac
3755   if test "x$enable_checking" = x && \
3756      test -d ${srcdir}/gcc && \
3757      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3758     stage1_checking=--enable-checking=yes,types,extra
3759   fi
3760 else
3761   stage1_checking=--enable-checking=$enable_checking,types
3762 fi])
3763 AC_SUBST(stage1_checking)
3764
3765 # Enable -Werror in bootstrap stage2 and later.
3766 AC_ARG_ENABLE(werror,
3767 [AS_HELP_STRING([--enable-werror],
3768                 [enable -Werror in bootstrap stage2 and later])],
3769 [
3770 case ${enable_werror} in
3771   yes) stage2_werror_flag="--enable-werror-always" ;;
3772   *) stage2_werror_flag="" ;;
3773 esac
3774 ],
3775 [
3776 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3777   case $BUILD_CONFIG in
3778   bootstrap-debug)
3779       stage2_werror_flag="--enable-werror-always" ;;
3780   "")
3781       stage2_werror_flag="--enable-werror-always" ;;
3782   esac
3783 fi
3784 ])
3785
3786 AC_SUBST(stage2_werror_flag)
3787
3788 # Specify what files to not compare during bootstrap.
3789
3790 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3791 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/M2Version*"
3792 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/SYSTEM*"
3793 compare_exclusions="$compare_exclusions | gcc/m2/gm2version*"
3794 case "$target" in
3795   hppa*64*-*-hpux*) ;;
3796   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3797 esac
3798 AC_SUBST(compare_exclusions)
3799
3800 AC_CONFIG_FILES([Makefile],
3801   [sed "$extrasub_build" Makefile |
3802    sed "$extrasub_host" |
3803    sed "$extrasub_target" > mf$$
3804    mv -f mf$$ Makefile],
3805   [extrasub_build="$extrasub_build"
3806    extrasub_host="$extrasub_host"
3807    extrasub_target="$extrasub_target"])
3808 AC_OUTPUT