configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools c++tools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libatomic \
 155                 target-libitm \
 156                 target-libstdc++-v3 \
 157                 target-libsanitizer \
 158                 target-libvtv \
 159                 target-libssp \
 160                 target-libquadmath \
 161                 target-libgfortran \
 162                 target-libffi \
 163                 target-libobjc \
 164                 target-libada \
 165                 target-libgo \
 166                 target-libphobos \
 167                 target-zlib"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # some tools are so dependent upon X11 that if we're not building with X,
 251 # it's not even worth trying to configure, much less build, that tool.
 252
 253 case ${with_x} in
 254   yes | "") ;; # the default value for this tree is that X11 is available
 255   no)
 256     skipdirs="${skipdirs} tk itcl libgui"
 257     # We won't be able to build gdbtk without X.
 258     enable_gdbtk=no
 259     ;;
 260   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 261 esac
 262
 263 # Some are only suitable for cross toolchains.
 264 # Remove these if host=target.
 265 cross_only="target-libgloss target-newlib target-opcodes"
 266
 267 case $is_cross_compiler in
 268   no) skipdirs="${skipdirs} ${cross_only}" ;;
 269 esac
 270
 271 # If both --with-headers and --with-libs are specified, default to
 272 # --without-newlib.
 273 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 274    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 275   if test x"${with_newlib}" = x ; then
 276     with_newlib=no
 277   fi
 278 fi
 279
 280 # Recognize --with-newlib/--without-newlib.
 281 case ${with_newlib} in
 282   no) skipdirs="${skipdirs} target-newlib" ;;
 283   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 284 esac
 285
 286 AC_ARG_ENABLE(as-accelerator-for,
 287 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 288                 [build as offload target compiler.
 289                 Specify offload host triple by ARG])])
 290
 291 AC_ARG_ENABLE(offload-targets,
 292 [AS_HELP_STRING([--enable-offload-targets=LIST],
 293                 [enable offloading to devices from comma-separated LIST of
 294                 TARGET[=DIR]. Use optional path to find offload target compiler
 295                 during the build])],
 296 [
 297   if test x"$enable_offload_targets" = x; then
 298     AC_MSG_ERROR([no offload targets specified])
 299   fi
 300 ], [enable_offload_targets=])
 301
 302 AC_ARG_ENABLE(offload-defaulted,
 303 [AS_HELP_STRING([--enable-offload-defaulted]
 304                 [If enabled, configured but not installed offload compilers and
 305                 libgomp plugins are silently ignored.  Useful for distribution
 306                 compilers where those are in separate optional packages.])],
 307 [enable_offload_defaulted=$enableval],
 308 [enable_offload_defaulted=])
 309
 310 # Handle --enable-gold, --enable-ld.
 311 # --disable-gold [--enable-ld]
 312 #     Build only ld.  Default option.
 313 # --enable-gold [--enable-ld]
 314 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 315 #     as "ld.bfd" and "ld".
 316 # --enable-gold=default [--enable-ld]
 317 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 318 #     install ld as "ld.bfd".
 319 # --enable-gold[=default] --disable-ld
 320 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 321 # --enable-gold --enable-ld=default
 322 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 323 #     and ld.bfd).
 324 #     In other words, ld is default
 325 # --enable-gold=default --enable-ld=default
 326 #     Error.
 327
 328 default_ld=
 329 AC_ARG_ENABLE(gold,
 330 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 331                 [build gold @<:@ARG={default,yes,no}@:>@])],
 332 ENABLE_GOLD=$enableval,
 333 ENABLE_GOLD=no)
 334 case "${ENABLE_GOLD}" in
 335   yes|default)
 336     # Check for ELF target.
 337     is_elf=no
 338     case "${target}" in
 339       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 340       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 341       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 342       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 343         case "${target}" in
 344           *-*-linux*aout* | *-*-linux*oldld*)
 345             ;;
 346           *)
 347             is_elf=yes
 348             ;;
 349         esac
 350     esac
 351
 352     if test "$is_elf" = "yes"; then
 353       # Check for target supported by gold.
 354       case "${target}" in
 355         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 356         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 357           configdirs="$configdirs gold"
 358           if test x${ENABLE_GOLD} = xdefault; then
 359             default_ld=gold
 360           fi
 361           ENABLE_GOLD=yes
 362           ;;
 363       esac
 364     fi
 365     ;;
 366   no)
 367     ;;
 368   *)
 369     AC_MSG_ERROR([invalid --enable-gold argument])
 370     ;;
 371 esac
 372
 373 AC_ARG_ENABLE(ld,
 374 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 375                 [build ld @<:@ARG={default,yes,no}@:>@])],
 376 ENABLE_LD=$enableval,
 377 ENABLE_LD=yes)
 378
 379 case "${ENABLE_LD}" in
 380   default)
 381     if test x${default_ld} != x; then
 382       AC_MSG_ERROR([either gold or ld can be the default ld])
 383     fi
 384     ;;
 385   yes)
 386     ;;
 387   no)
 388     if test x${ENABLE_GOLD} != xyes; then
 389       AC_MSG_WARN([neither ld nor gold are enabled])
 390     fi
 391     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 392     ;;
 393   *)
 394     AC_MSG_ERROR([invalid --enable-ld argument])
 395     ;;
 396 esac
 397
 398 # PR gas/19109
 399 # Decide the default method for compressing debug sections.
 400 # Provide a configure time option to override our default.
 401 AC_ARG_ENABLE(compressed_debug_sections,
 402 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 403                 [Enable compressed debug sections for gas, gold or ld by
 404                  default])],
 405 [
 406   if test x"$enable_compressed_debug_sections" = xyes; then
 407     AC_MSG_ERROR([no program with compressed debug sections specified])
 408   fi
 409 ], [enable_compressed_debug_sections=])
 410
 411 # Configure extra directories which are host specific
 412
 413 case "${host}" in
 414   *-cygwin*)
 415     configdirs="$configdirs libtermcap" ;;
 416 esac
 417
 418 # A target can indicate whether a language isn't supported for some reason.
 419 # Only spaces may be used in this macro; not newlines or tabs.
 420 unsupported_languages=
 421
 422 # Remove more programs from consideration, based on the host or
 423 # target this usually means that a port of the program doesn't
 424 # exist yet.
 425
 426 case "${host}" in
 427   i[[3456789]]86-*-msdosdjgpp*)
 428     noconfigdirs="$noconfigdirs tcl tk itcl"
 429     ;;
 430 esac
 431
 432
 433 AC_ARG_ENABLE(libquadmath,
 434 AS_HELP_STRING([--disable-libquadmath],
 435   [do not build libquadmath directory]),
 436 ENABLE_LIBQUADMATH=$enableval,
 437 ENABLE_LIBQUADMATH=yes)
 438 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 439   noconfigdirs="$noconfigdirs target-libquadmath"
 440 fi
 441
 442
 443 AC_ARG_ENABLE(libquadmath-support,
 444 AS_HELP_STRING([--disable-libquadmath-support],
 445   [disable libquadmath support for Fortran]),
 446 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 447 ENABLE_LIBQUADMATH_SUPPORT=yes)
 448 enable_libquadmath_support=
 449 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 450   enable_libquadmath_support=no
 451 fi
 452
 453
 454 AC_ARG_ENABLE(libada,
 455 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 456 ENABLE_LIBADA=$enableval,
 457 ENABLE_LIBADA=yes)
 458 if test "${ENABLE_LIBADA}" != "yes" ; then
 459   noconfigdirs="$noconfigdirs gnattools"
 460 fi
 461
 462 AC_ARG_ENABLE(libssp,
 463 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 464 ENABLE_LIBSSP=$enableval,
 465 ENABLE_LIBSSP=yes)
 466
 467 AC_ARG_ENABLE(libstdcxx,
 468 AS_HELP_STRING([--disable-libstdcxx],
 469   [do not build libstdc++-v3 directory]),
 470 ENABLE_LIBSTDCXX=$enableval,
 471 ENABLE_LIBSTDCXX=default)
 472 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 473   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 474 fi]
 475
 476 # If this is accelerator compiler and its target is intelmic we enable
 477 # target liboffloadmic by default.  If this is compiler with offloading
 478 # for intelmic we enable host liboffloadmic by default.  Otherwise
 479 # liboffloadmic is disabled by default.
 480 AC_ARG_ENABLE([liboffloadmic],
 481 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 482                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 483 [case "$enableval" in
 484   no | host | target)
 485     enable_liboffloadmic=$enableval ;;
 486   *)
 487     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 488 esac],
 489 [if test x"$enable_as_accelerator_for" != x; then
 490   case "${target}" in
 491     *-intelmic-* | *-intelmicemul-*)
 492       enable_liboffloadmic=target
 493       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 494       ;;
 495     *)
 496       enable_liboffloadmic=no
 497       ;;
 498   esac
 499 else
 500   case "${enable_offload_targets}" in
 501     *-intelmic-* | *-intelmicemul-*)
 502       enable_liboffloadmic=host
 503       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 504       ;;
 505     *)
 506       enable_liboffloadmic=no
 507       ;;
 508     esac
 509 fi])
 510 AC_SUBST(extra_liboffloadmic_configure_flags)
 511
 512 # Enable libgomp by default on hosted POSIX systems, and a few others.
 513 if test x$enable_libgomp = x ; then
 514     case "${target}" in
 515     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 516         ;;
 517     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 518         ;;
 519     *-*-solaris2* | *-*-hpux11*)
 520         ;;
 521     *-*-darwin* | *-*-aix*)
 522         ;;
 523     nvptx*-*-* | amdgcn*-*-*)
 524         ;;
 525     *)
 526         noconfigdirs="$noconfigdirs target-libgomp"
 527         ;;
 528     esac
 529 fi
 530
 531 # Disable libatomic on unsupported systems.
 532 if test -d ${srcdir}/libatomic; then
 533     if test x$enable_libatomic = x; then
 534         AC_MSG_CHECKING([for libatomic support])
 535         if (srcdir=${srcdir}/libatomic; \
 536                 . ${srcdir}/configure.tgt; \
 537                 test -n "$UNSUPPORTED")
 538         then
 539             AC_MSG_RESULT([no])
 540             noconfigdirs="$noconfigdirs target-libatomic"
 541         else
 542             AC_MSG_RESULT([yes])
 543         fi
 544     fi
 545 fi
 546
 547 # Disable liboffloadmic on unsupported systems.
 548 if test -d ${srcdir}/liboffloadmic; then
 549     if test x$enable_liboffloadmic != xno; then
 550         AC_MSG_CHECKING([for liboffloadmic support])
 551         if (srcdir=${srcdir}/liboffloadmic; \
 552                 . ${srcdir}/configure.tgt; \
 553                 test -n "$UNSUPPORTED")
 554         then
 555             AC_MSG_RESULT([no])
 556             noconfigdirs="$noconfigdirs target-liboffloadmic"
 557         else
 558             AC_MSG_RESULT([yes])
 559         fi
 560     fi
 561 fi
 562
 563 # Disable libitm on unsupported systems.
 564 if test -d ${srcdir}/libitm; then
 565     if test x$enable_libitm = x; then
 566         AC_MSG_CHECKING([for libitm support])
 567         if (srcdir=${srcdir}/libitm; \
 568                 . ${srcdir}/configure.tgt; \
 569                 test -n "$UNSUPPORTED")
 570         then
 571             AC_MSG_RESULT([no])
 572             noconfigdirs="$noconfigdirs target-libitm"
 573         else
 574             AC_MSG_RESULT([yes])
 575         fi
 576     fi
 577 fi
 578
 579 # Disable libsanitizer on unsupported systems.
 580 if test -d ${srcdir}/libsanitizer; then
 581     if test x$enable_libsanitizer = x; then
 582         AC_MSG_CHECKING([for libsanitizer support])
 583         if (srcdir=${srcdir}/libsanitizer; \
 584                 . ${srcdir}/configure.tgt; \
 585                 test -n "$UNSUPPORTED")
 586         then
 587             AC_MSG_RESULT([no])
 588             noconfigdirs="$noconfigdirs target-libsanitizer"
 589         else
 590             AC_MSG_RESULT([yes])
 591         fi
 592     fi
 593 fi
 594
 595 # Disable libvtv on unsupported systems.
 596 if test -d ${srcdir}/libvtv; then
 597     if test x$enable_libvtv = x; then
 598         AC_MSG_CHECKING([for libvtv support])
 599         if (srcdir=${srcdir}/libvtv; \
 600                 . ${srcdir}/configure.tgt; \
 601                 test "$VTV_SUPPORTED" != "yes")
 602         then
 603             AC_MSG_RESULT([no])
 604             noconfigdirs="$noconfigdirs target-libvtv"
 605         else
 606             AC_MSG_RESULT([yes])
 607         fi
 608     fi
 609 fi
 610
 611 # Disable libquadmath for some systems.
 612 case "${target}" in
 613   avr-*-*)
 614     noconfigdirs="$noconfigdirs target-libquadmath"
 615     ;;
 616   # libquadmath is unused on AIX and libquadmath build process use of
 617   # LD_LIBRARY_PATH can break AIX bootstrap.
 618   powerpc-*-aix* | rs6000-*-aix*)
 619     noconfigdirs="$noconfigdirs target-libquadmath"
 620     ;;
 621 esac
 622
 623 # Disable libssp for some systems.
 624 case "${target}" in
 625   avr-*-*)
 626     # No hosted I/O support.
 627     noconfigdirs="$noconfigdirs target-libssp"
 628     ;;
 629   bpf-*-*)
 630     noconfigdirs="$noconfigdirs target-libssp"
 631     ;;
 632   powerpc-*-aix* | rs6000-*-aix*)
 633     noconfigdirs="$noconfigdirs target-libssp"
 634     ;;
 635   pru-*-*)
 636     # No hosted I/O support.
 637     noconfigdirs="$noconfigdirs target-libssp"
 638     ;;
 639   rl78-*-*)
 640     # libssp uses a misaligned load to trigger a fault, but the RL78
 641     # doesn't fault for those - instead, it gives a build-time error
 642     # for explicit misaligned loads.
 643     noconfigdirs="$noconfigdirs target-libssp"
 644     ;;
 645   visium-*-*)
 646     # No hosted I/O support.
 647     noconfigdirs="$noconfigdirs target-libssp"
 648     ;;
 649 esac
 650
 651 # Disable libstdc++-v3 for some systems.
 652 # Allow user to override this if they pass --enable-libstdc++-v3
 653 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 654   case "${target}" in
 655     *-*-vxworks*)
 656       # VxWorks uses the Dinkumware C++ library.
 657       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 658       ;;
 659     amdgcn*-*-*)
 660       # Not ported/fails to build when using newlib.
 661       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 662       ;;
 663     arm*-wince-pe*)
 664       # the C++ libraries don't build on top of CE's C libraries
 665       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 666       ;;
 667     avr-*-*)
 668       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 669       ;;
 670     bpf-*-*)
 671       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 672       ;;
 673     ft32-*-*)
 674       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 675       ;;
 676   esac
 677 fi
 678
 679 # Disable C++ on systems where it is known to not work.
 680 # For testing, you can override this with --enable-languages=c++.
 681 case ,${enable_languages}, in
 682   *,c++,*)
 683     ;;
 684   *)
 685       case "${target}" in
 686         bpf-*-*)
 687           unsupported_languages="$unsupported_languages c++"
 688           ;;
 689       esac
 690       ;;
 691 esac
 692
 693 # Disable Objc on systems where it is known to not work.
 694 # For testing, you can override this with --enable-languages=objc.
 695 case ,${enable_languages}, in
 696   *,objc,*)
 697     ;;
 698   *)
 699       case "${target}" in
 700         bpf-*-*)
 701           unsupported_languages="$unsupported_languages objc"
 702           ;;
 703       esac
 704       ;;
 705 esac
 706
 707 # Disable D on systems where it is known to not work.
 708 # For testing, you can override this with --enable-languages=d.
 709 case ,${enable_languages}, in
 710   *,d,*)
 711     ;;
 712   *)
 713     case "${target}" in
 714       bpf-*-*)
 715         unsupported_languages="$unsupported_languages d"
 716         ;;
 717     esac
 718     ;;
 719 esac
 720
 721 # Disable libphobos on unsupported systems.
 722 # For testing, you can override this with --enable-libphobos.
 723 if test -d ${srcdir}/libphobos; then
 724     if test x$enable_libphobos = x; then
 725         AC_MSG_CHECKING([for libphobos support])
 726         if (srcdir=${srcdir}/libphobos; \
 727                 . ${srcdir}/configure.tgt; \
 728                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 729         then
 730             AC_MSG_RESULT([no])
 731             noconfigdirs="$noconfigdirs target-libphobos"
 732         else
 733             AC_MSG_RESULT([yes])
 734         fi
 735     fi
 736 fi
 737
 738 # Disable Fortran for some systems.
 739 case "${target}" in
 740   mmix-*-*)
 741     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 742     unsupported_languages="$unsupported_languages fortran"
 743     ;;
 744   bpf-*-*)
 745     unsupported_languages="$unsupported_languages fortran"
 746     ;;
 747 esac
 748
 749 # Disable libffi for some systems.
 750 case "${target}" in
 751   powerpc-*-darwin*)
 752     ;;
 753   i[[3456789]]86-*-darwin*)
 754     ;;
 755   x86_64-*-darwin[[912]]*)
 756     ;;
 757   *-*-darwin*)
 758     noconfigdirs="$noconfigdirs target-libffi"
 759     ;;
 760   *-*-netware*)
 761     noconfigdirs="$noconfigdirs target-libffi"
 762     ;;
 763   *-*-phoenix*)
 764     noconfigdirs="$noconfigdirs target-libffi"
 765     ;;
 766   *-*-rtems*)
 767     noconfigdirs="$noconfigdirs target-libffi"
 768     ;;
 769   *-*-tpf*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772   *-*-uclinux*)
 773     noconfigdirs="$noconfigdirs target-libffi"
 774     ;;
 775   *-*-vxworks*)
 776     noconfigdirs="$noconfigdirs target-libffi"
 777     ;;
 778   aarch64*-*-freebsd*)
 779     noconfigdirs="$noconfigdirs target-libffi"
 780     ;;
 781   alpha*-*-*vms*)
 782     noconfigdirs="$noconfigdirs target-libffi"
 783     ;;
 784   arm*-*-freebsd*)
 785     noconfigdirs="$noconfigdirs target-libffi"
 786     ;;
 787   arm-wince-pe)
 788     noconfigdirs="$noconfigdirs target-libffi"
 789     ;;
 790   arm*-*-symbianelf*)
 791     noconfigdirs="$noconfigdirs target-libffi"
 792     ;;
 793   bpf-*-*)
 794     noconfigdirs="$noconfigdirs target-libffi"
 795     ;;
 796   cris-*-* | crisv32-*-*)
 797     case "${target}" in
 798       *-*-linux*)
 799         ;;
 800       *) # See PR46792 regarding target-libffi.
 801         noconfigdirs="$noconfigdirs target-libffi";;
 802     esac
 803     ;;
 804   hppa*64*-*-hpux*)
 805     noconfigdirs="$noconfigdirs target-libffi"
 806     ;;
 807   hppa*-hp-hpux11*)
 808     ;;
 809   hppa*-*-hpux*)
 810     noconfigdirs="$noconfigdirs target-libffi"
 811     ;;
 812   ia64*-*-*vms*)
 813     noconfigdirs="$noconfigdirs target-libffi"
 814     ;;
 815   i[[3456789]]86-w64-mingw*)
 816     noconfigdirs="$noconfigdirs target-libffi"
 817     ;;
 818   i[[3456789]]86-*-mingw*)
 819     noconfigdirs="$noconfigdirs target-libffi"
 820     ;;
 821   x86_64-*-mingw*)
 822     noconfigdirs="$noconfigdirs target-libffi"
 823     ;;
 824   mmix-*-*)
 825     noconfigdirs="$noconfigdirs target-libffi"
 826     ;;
 827   powerpc-*-aix*)
 828     ;;
 829   rs6000-*-aix*)
 830     ;;
 831   ft32-*-*)
 832     noconfigdirs="$noconfigdirs target-libffi"
 833     ;;
 834   *-*-lynxos*)
 835     noconfigdirs="$noconfigdirs target-libffi"
 836     ;;
 837 esac
 838
 839 # Disable the go frontend on systems where it is known to not work. Please keep
 840 # this in sync with contrib/config-list.mk.
 841 case "${target}" in
 842 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 843     unsupported_languages="$unsupported_languages go"
 844     ;;
 845 esac
 846
 847 # Only allow gdbserver on some systems.
 848 if test -d ${srcdir}/gdbserver; then
 849     if test x$enable_gdbserver = x; then
 850         AC_MSG_CHECKING([for gdbserver support])
 851         if (srcdir=${srcdir}/gdbserver; \
 852                 . ${srcdir}/configure.srv; \
 853                 test -n "$UNSUPPORTED")
 854         then
 855             AC_MSG_RESULT([no])
 856             noconfigdirs="$noconfigdirs gdbserver"
 857         else
 858             AC_MSG_RESULT([yes])
 859         fi
 860     fi
 861 fi
 862
 863 # Disable libgo for some systems where it is known to not work.
 864 # For testing, you can easily override this with --enable-libgo.
 865 if test x$enable_libgo = x; then
 866     case "${target}" in
 867     *-*-darwin*)
 868         # PR 46986
 869         noconfigdirs="$noconfigdirs target-libgo"
 870         ;;
 871     *-*-cygwin* | *-*-mingw*)
 872         noconfigdirs="$noconfigdirs target-libgo"
 873         ;;
 874     bpf-*-*)
 875         noconfigdirs="$noconfigdirs target-libgo"
 876         ;;
 877     esac
 878 fi
 879
 880 # Default libgloss CPU subdirectory.
 881 libgloss_dir="$target_cpu"
 882
 883 case "${target}" in
 884   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 885     libgloss_dir=wince
 886     ;;
 887   aarch64*-*-* )
 888     libgloss_dir=aarch64
 889     ;;
 890   arm*-*-*)
 891     libgloss_dir=arm
 892     ;;
 893   cris-*-* | crisv32-*-*)
 894     libgloss_dir=cris
 895     ;;
 896   hppa*-*-*)
 897     libgloss_dir=pa
 898     ;;
 899   i[[3456789]]86-*-*)
 900     libgloss_dir=i386
 901     ;;
 902   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 903     libgloss_dir=m68hc11
 904     ;;
 905   m68*-*-* | fido-*-*)
 906     libgloss_dir=m68k
 907     ;;
 908   mips*-*-*)
 909     libgloss_dir=mips
 910     ;;
 911   powerpc*-*-*)
 912     libgloss_dir=rs6000
 913     ;;
 914   pru-*-*)
 915     libgloss_dir=pru
 916     ;;
 917   sparc*-*-*)
 918     libgloss_dir=sparc
 919     ;;
 920 esac
 921
 922 # Disable newlib and libgloss for various target OSes.
 923 case "${target}" in
 924   alpha*-dec-osf*)
 925     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 926     ;;
 927   i[[3456789]]86-*-linux*)
 928     # This section makes it possible to build newlib natively on linux.
 929     # If we are using a cross compiler then don't configure newlib.
 930     if test x${is_cross_compiler} != xno ; then
 931       noconfigdirs="$noconfigdirs target-newlib"
 932     fi
 933     noconfigdirs="$noconfigdirs target-libgloss"
 934     # If we are not using a cross compiler, do configure newlib.
 935     # Note however, that newlib will only be configured in this situation
 936     # if the --with-newlib option has been given, because otherwise
 937     # 'target-newlib' will appear in skipdirs.
 938     ;;
 939   i[[3456789]]86-*-rdos*)
 940     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 941     ;;
 942   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 943     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 944     ;;
 945   sparc-*-sunos4*)
 946     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 947     ;;
 948   bpf-*-*)
 949     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 950     ;;
 951   *-*-aix*)
 952     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 953     ;;
 954   *-*-beos*)
 955     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 956     ;;
 957   *-*-chorusos)
 958     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 959     ;;
 960   *-*-dragonfly*)
 961     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 962     ;;
 963   *-*-freebsd*)
 964     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 965     ;;
 966   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 967     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 968     ;;
 969   *-*-lynxos*)
 970     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 971     ;;
 972   *-*-mingw*)
 973     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 974     ;;
 975   *-*-netbsd*)
 976     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 977     ;;
 978   *-*-netware*)
 979     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 980     ;;
 981   *-*-tpf*)
 982     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 983     ;;
 984   *-*-uclinux*)
 985     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 986     ;;
 987   *-*-vxworks*)
 988     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 989     ;;
 990 esac
 991
 992 case "${target}" in
 993   *-*-chorusos)
 994     ;;
 995   aarch64-*-darwin*)
 996     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 997     noconfigdirs="$noconfigdirs sim target-rda"
 998     ;;
 999   amdgcn*-*-*)
1000     ;;
1001   arm-*-darwin*)
1002     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1003     noconfigdirs="$noconfigdirs sim target-rda"
1004     ;;
1005   powerpc-*-darwin*)
1006     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1007     noconfigdirs="$noconfigdirs sim target-rda"
1008     ;;
1009   i[[3456789]]86-*-darwin*)
1010     noconfigdirs="$noconfigdirs ld gprof"
1011     noconfigdirs="$noconfigdirs sim target-rda"
1012     ;;
1013   x86_64-*-darwin[[912]]*)
1014     noconfigdirs="$noconfigdirs ld gas gprof"
1015     noconfigdirs="$noconfigdirs sim target-rda"
1016     ;;
1017   *-*-darwin*)
1018     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1019     noconfigdirs="$noconfigdirs sim target-rda"
1020     ;;
1021   *-*-dragonfly*)
1022     ;;
1023   *-*-freebsd*)
1024     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
1025         && ! test -d ${srcdir}/gmp \
1026         && test -f /usr/local/include/gmp.h; then
1027       with_gmp=/usr/local
1028     fi
1029     ;;
1030   *-*-kaos*)
1031     # Remove unsupported stuff on all kaOS configurations.
1032     noconfigdirs="$noconfigdirs target-libgloss"
1033     ;;
1034   *-*-netbsd*)
1035     ;;
1036   *-*-netware*)
1037     ;;
1038   *-*-phoenix*)
1039     noconfigdirs="$noconfigdirs target-libgloss"
1040     ;;
1041   *-*-rtems*)
1042     noconfigdirs="$noconfigdirs target-libgloss"
1043     ;;
1044     # The tpf target doesn't support gdb yet.
1045   *-*-tpf*)
1046     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1047     ;;
1048   *-*-uclinux*)
1049     noconfigdirs="$noconfigdirs target-rda"
1050     ;;
1051   *-*-vxworks*)
1052     ;;
1053   alpha*-dec-osf*)
1054     # ld works, but does not support shared libraries.
1055     # gas doesn't generate exception information.
1056     noconfigdirs="$noconfigdirs gas ld"
1057     ;;
1058   alpha*-*-*vms*)
1059     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1060     ;;
1061   alpha*-*-*)
1062     # newlib is not 64 bit ready
1063     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1064     ;;
1065   bpf-*-*)
1066     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1067     ;;
1068   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1069     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1070     ;;
1071   arc*-*-*)
1072     noconfigdirs="$noconfigdirs sim"
1073     ;;
1074   arm-*-pe*)
1075     noconfigdirs="$noconfigdirs target-libgloss"
1076     ;;
1077   arm-*-riscix*)
1078     noconfigdirs="$noconfigdirs ld target-libgloss"
1079     ;;
1080   avr-*-*)
1081     if test x${with_avrlibc} != xno; then
1082       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1083     fi
1084     ;;
1085   c4x-*-* | tic4x-*-*)
1086     noconfigdirs="$noconfigdirs target-libgloss"
1087     ;;
1088   tic54x-*-*)
1089     noconfigdirs="$noconfigdirs target-libgloss gdb"
1090     ;;
1091   d10v-*-*)
1092     noconfigdirs="$noconfigdirs target-libgloss"
1093     ;;
1094   d30v-*-*)
1095     noconfigdirs="$noconfigdirs gdb"
1096     ;;
1097   fr30-*-elf*)
1098     noconfigdirs="$noconfigdirs gdb"
1099     ;;
1100   ft32-*-*)
1101     noconfigdirs="$noconfigdirs target-rda gprof"
1102     ;;
1103   moxie-*-*)
1104     noconfigdirs="$noconfigdirs"
1105     ;;
1106   h8300*-*-*)
1107     noconfigdirs="$noconfigdirs target-libgloss"
1108     ;;
1109   h8500-*-*)
1110     noconfigdirs="$noconfigdirs target-libgloss"
1111     ;;
1112   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1113     ;;
1114   hppa*64*-*-hpux*)
1115     noconfigdirs="$noconfigdirs gdb"
1116     ;;
1117   hppa*-*-hpux11*)
1118     noconfigdirs="$noconfigdirs gdb ld"
1119     ;;
1120   hppa*64*-*-linux*)
1121     ;;
1122   hppa*-*-linux*)
1123     ;;
1124   hppa*-*-*elf* | \
1125   hppa*-*-lites* | \
1126   hppa*-*-openbsd* | \
1127   hppa*64*-*-*)
1128     ;;
1129   hppa*-*-pro*)
1130     ;;
1131   hppa*-*-*)
1132     noconfigdirs="$noconfigdirs ld"
1133     ;;
1134   i960-*-*)
1135     noconfigdirs="$noconfigdirs gdb"
1136     ;;
1137   ia64*-*-elf*)
1138     # No gdb support yet.
1139     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1140     ;;
1141   ia64*-**-hpux*)
1142     # No ld support yet.
1143     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1144     ;;
1145   ia64*-*-*vms*)
1146     # No ld support yet.
1147     noconfigdirs="$noconfigdirs libgui itcl ld"
1148     ;;
1149   i[[3456789]]86-w64-mingw*)
1150     ;;
1151   i[[3456789]]86-*-mingw*)
1152     target_configdirs="$target_configdirs target-winsup"
1153     ;;
1154   *-*-cygwin*)
1155     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1156     noconfigdirs="$noconfigdirs target-libgloss"
1157     # always build newlib if winsup directory is present.
1158     if test -d "$srcdir/winsup/cygwin"; then
1159       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1160     elif test -d "$srcdir/newlib"; then
1161       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1162     fi
1163     ;;
1164   i[[3456789]]86-*-pe)
1165     noconfigdirs="$noconfigdirs target-libgloss"
1166     ;;
1167   i[[3456789]]86-*-sco3.2v5*)
1168     # The linker does not yet know about weak symbols in COFF,
1169     # and is not configured to handle mixed ELF and COFF.
1170     noconfigdirs="$noconfigdirs ld target-libgloss"
1171     ;;
1172   i[[3456789]]86-*-sco*)
1173     noconfigdirs="$noconfigdirs gprof target-libgloss"
1174     ;;
1175   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1176     noconfigdirs="$noconfigdirs target-libgloss"
1177     ;;
1178   i[[3456789]]86-*-sysv4*)
1179     noconfigdirs="$noconfigdirs target-libgloss"
1180     ;;
1181   i[[3456789]]86-*-beos*)
1182     noconfigdirs="$noconfigdirs gdb"
1183     ;;
1184   i[[3456789]]86-*-rdos*)
1185     noconfigdirs="$noconfigdirs gdb"
1186     ;;
1187   mmix-*-*)
1188     noconfigdirs="$noconfigdirs gdb"
1189     ;;
1190   mt-*-*)
1191     noconfigdirs="$noconfigdirs sim"
1192     ;;
1193   nfp-*-*)
1194     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1195     noconfigdirs="$noconfigdirs $target_libraries"
1196     ;;
1197   pdp11-*-*)
1198     noconfigdirs="$noconfigdirs gdb gprof"
1199     ;;
1200   powerpc-*-aix*)
1201     # copied from rs6000-*-* entry
1202     noconfigdirs="$noconfigdirs gprof"
1203     ;;
1204   powerpc*-*-winnt* | powerpc*-*-pe*)
1205     target_configdirs="$target_configdirs target-winsup"
1206     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1207     # always build newlib.
1208     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1209     ;;
1210     # This is temporary until we can link against shared libraries
1211   powerpcle-*-solaris*)
1212     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1213     ;;
1214   powerpc-*-beos*)
1215     noconfigdirs="$noconfigdirs gdb"
1216     ;;
1217   rs6000-*-lynxos*)
1218     noconfigdirs="$noconfigdirs gprof"
1219     ;;
1220   rs6000-*-aix*)
1221     noconfigdirs="$noconfigdirs gprof"
1222     ;;
1223   rs6000-*-*)
1224     noconfigdirs="$noconfigdirs gprof"
1225     ;;
1226   m68k-apollo-*)
1227     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1228     ;;
1229   microblaze*)
1230     noconfigdirs="$noconfigdirs gprof"
1231     ;;
1232   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1233     if test x$with_newlib = xyes; then
1234       noconfigdirs="$noconfigdirs gprof"
1235     fi
1236     ;;
1237   mips*-*-irix5*)
1238     noconfigdirs="$noconfigdirs gprof target-libgloss"
1239     ;;
1240   mips*-*-irix6*)
1241     noconfigdirs="$noconfigdirs gprof target-libgloss"
1242     ;;
1243   mips*-*-bsd*)
1244     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1245     ;;
1246   mips*-*-linux*)
1247     ;;
1248   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1249   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1250     noconfigdirs="$noconfigdirs ld gas gprof"
1251     ;;
1252   mips*-*-*)
1253     noconfigdirs="$noconfigdirs gprof"
1254     ;;
1255   nvptx*-*-*)
1256     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1257     ;;
1258   sh-*-*)
1259     case "${target}" in
1260       sh*-*-elf)
1261          ;;
1262       *)
1263          noconfigdirs="$noconfigdirs target-libgloss" ;;
1264     esac
1265     ;;
1266   sparc-*-sunos4*)
1267     if test x${is_cross_compiler} = xno ; then
1268            use_gnu_ld=no
1269     fi
1270     ;;
1271   tic6x-*-*)
1272     noconfigdirs="$noconfigdirs sim"
1273     ;;
1274   tilepro*-*-* | tilegx*-*-*)
1275     noconfigdirs="$noconfigdirs sim"
1276     ;;
1277   v810-*-*)
1278     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1279     ;;
1280   vax-*-*)
1281     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1282     ;;
1283   wasm32-*-*)
1284     noconfigdirs="$noconfigdirs ld"
1285     ;;
1286 esac
1287
1288 # If we aren't building newlib, then don't build libgloss, since libgloss
1289 # depends upon some newlib header files.
1290 case "${noconfigdirs}" in
1291   *target-libgloss*) ;;
1292   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1293 esac
1294
1295 # Work in distributions that contain no compiler tools, like Autoconf.
1296 host_makefile_frag=/dev/null
1297 if test -d ${srcdir}/config ; then
1298 case "${host}" in
1299   i[[3456789]]86-*-msdosdjgpp*)
1300     host_makefile_frag="config/mh-djgpp"
1301     ;;
1302   *-cygwin*)
1303     ACX_CHECK_CYGWIN_CAT_WORKS
1304     host_makefile_frag="config/mh-cygwin"
1305     ;;
1306   *-mingw*)
1307     host_makefile_frag="config/mh-mingw"
1308     ;;
1309   alpha*-linux*)
1310     host_makefile_frag="config/mh-alpha-linux"
1311     ;;
1312   hppa*-hp-hpux10*)
1313     host_makefile_frag="config/mh-pa-hpux10"
1314     ;;
1315   hppa*-hp-hpux*)
1316     host_makefile_frag="config/mh-pa"
1317     ;;
1318   hppa*-*)
1319     host_makefile_frag="config/mh-pa"
1320     ;;
1321   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1322     host_makefile_frag="config/mh-darwin"
1323     ;;
1324   powerpc-*-aix*)
1325     host_makefile_frag="config/mh-ppc-aix"
1326     ;;
1327   rs6000-*-aix*)
1328     host_makefile_frag="config/mh-ppc-aix"
1329     ;;
1330 esac
1331 fi
1332
1333 if test "${build}" != "${host}" ; then
1334   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1335   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1336   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1337   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CPP)}"
1338   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1339   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1340   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1341   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1342   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1343   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1344   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1345   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1346   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1347   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1348   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1349 else
1350   AR_FOR_BUILD="\$(AR)"
1351   AS_FOR_BUILD="\$(AS)"
1352   CC_FOR_BUILD="\$(CC)"
1353   CXX_FOR_BUILD="\$(CXX)"
1354   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1355   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1356   GOC_FOR_BUILD="\$(GOC)"
1357   GDC_FOR_BUILD="\$(GDC)"
1358   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1359   LD_FOR_BUILD="\$(LD)"
1360   NM_FOR_BUILD="\$(NM)"
1361   RANLIB_FOR_BUILD="\$(RANLIB)"
1362   WINDRES_FOR_BUILD="\$(WINDRES)"
1363   WINDMC_FOR_BUILD="\$(WINDMC)"
1364 fi
1365
1366 AC_PROG_CC_C99
1367 AC_PROG_CXX
1368
1369 # We must set the default linker to the linker used by gcc for the correct
1370 # operation of libtool.  If LD is not defined and we are using gcc, try to
1371 # set the LD default to the ld used by gcc.
1372 if test -z "$LD"; then
1373   if test "$GCC" = yes; then
1374     case $build in
1375     *-*-mingw*)
1376       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1377     *)
1378       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1379     esac
1380     case $gcc_prog_ld in
1381     # Accept absolute paths.
1382     [[\\/]* | [A-Za-z]:[\\/]*)]
1383       LD="$gcc_prog_ld" ;;
1384     esac
1385   fi
1386 fi
1387
1388 # Check whether -static-libstdc++ -static-libgcc is supported.
1389 have_static_libs=no
1390 if test "$GCC" = yes; then
1391   saved_LDFLAGS="$LDFLAGS"
1392
1393   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1394   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1395   AC_LANG_PUSH(C++)
1396   AC_LINK_IFELSE([AC_LANG_SOURCE([
1397 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1398 #error -static-libstdc++ not implemented
1399 #endif
1400 int main() {}])],
1401     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1402     [AC_MSG_RESULT([no])])
1403   AC_LANG_POP(C++)
1404
1405   LDFLAGS="$saved_LDFLAGS"
1406 fi
1407
1408 ACX_PROG_GNAT
1409 ACX_PROG_CMP_IGNORE_INITIAL
1410
1411 AC_ARG_ENABLE([bootstrap],
1412 [AS_HELP_STRING([--enable-bootstrap],
1413                 [enable bootstrapping @<:@yes if native build@:>@])],,
1414 enable_bootstrap=default)
1415
1416 # Issue errors and warnings for invalid/strange bootstrap combinations.
1417 if test -r $srcdir/gcc/configure; then
1418   have_compiler=yes
1419 else
1420   have_compiler=no
1421 fi
1422
1423 case "$have_compiler:$host:$target:$enable_bootstrap" in
1424   *:*:*:no) ;;
1425
1426   # Default behavior.  Enable bootstrap if we have a compiler
1427   # and we are in a native configuration.
1428   yes:$build:$build:default)
1429     enable_bootstrap=yes ;;
1430
1431   *:*:*:default)
1432     enable_bootstrap=no ;;
1433
1434   # We have a compiler and we are in a native configuration, bootstrap is ok
1435   yes:$build:$build:yes)
1436     ;;
1437
1438   # Other configurations, but we have a compiler.  Assume the user knows
1439   # what he's doing.
1440   yes:*:*:yes)
1441     AC_MSG_WARN([trying to bootstrap a cross compiler])
1442     ;;
1443
1444   # No compiler: if they passed --enable-bootstrap explicitly, fail
1445   no:*:*:yes)
1446     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1447
1448   # Fail if wrong command line
1449   *)
1450     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1451     ;;
1452 esac
1453
1454 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1455 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1456 # require C++11 (or higher).
1457 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1458   CXX="$CXX -std=c++11"
1459 elif test "$have_compiler" = yes; then
1460   AX_CXX_COMPILE_STDCXX(11)
1461
1462   if test "${build}" != "${host}"; then
1463     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1464   fi
1465 fi
1466
1467 # Used for setting $lt_cv_objdir
1468 _LT_CHECK_OBJDIR
1469
1470 # Check for GMP, MPFR and MPC
1471 gmplibs="-lmpc -lmpfr -lgmp"
1472 gmpinc=
1473 have_gmp=no
1474
1475 # Specify a location for mpc
1476 # check for this first so it ends up on the link line before mpfr.
1477 AC_ARG_WITH(mpc,
1478 [AS_HELP_STRING([--with-mpc=PATH],
1479                 [specify prefix directory for installed MPC package.
1480                  Equivalent to --with-mpc-include=PATH/include
1481                  plus --with-mpc-lib=PATH/lib])])
1482 AC_ARG_WITH(mpc-include,
1483 [AS_HELP_STRING([--with-mpc-include=PATH],
1484                 [specify directory for installed MPC include files])])
1485 AC_ARG_WITH(mpc-lib,
1486 [AS_HELP_STRING([--with-mpc-lib=PATH],
1487                 [specify directory for the installed MPC library])])
1488
1489 if test "x$with_mpc" != x; then
1490   gmplibs="-L$with_mpc/lib $gmplibs"
1491   gmpinc="-I$with_mpc/include $gmpinc"
1492 fi
1493 if test "x$with_mpc_include" != x; then
1494   gmpinc="-I$with_mpc_include $gmpinc"
1495 fi
1496 if test "x$with_mpc_lib" != x; then
1497   gmplibs="-L$with_mpc_lib $gmplibs"
1498 fi
1499 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1500   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1501   gmpinc='-I$$s/mpc/src '"$gmpinc"
1502   # Do not test the mpc version.  Assume that it is sufficient, since
1503   # it is in the source tree, and the library has not been built yet
1504   # but it would be included on the link line in the version check below
1505   # hence making the test fail.
1506   have_gmp=yes
1507 fi
1508
1509 # Specify a location for mpfr
1510 # check for this first so it ends up on the link line before gmp.
1511 AC_ARG_WITH(mpfr-dir,
1512 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1513 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1514 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1515
1516 AC_ARG_WITH(mpfr,
1517 [AS_HELP_STRING([--with-mpfr=PATH],
1518                 [specify prefix directory for installed MPFR package.
1519                  Equivalent to --with-mpfr-include=PATH/include
1520                  plus --with-mpfr-lib=PATH/lib])])
1521 AC_ARG_WITH(mpfr-include,
1522 [AS_HELP_STRING([--with-mpfr-include=PATH],
1523                 [specify directory for installed MPFR include files])])
1524 AC_ARG_WITH(mpfr-lib,
1525 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1526                 [specify directory for the installed MPFR library])])
1527
1528 if test "x$with_mpfr" != x; then
1529   gmplibs="-L$with_mpfr/lib $gmplibs"
1530   gmpinc="-I$with_mpfr/include $gmpinc"
1531 fi
1532 if test "x$with_mpfr_include" != x; then
1533   gmpinc="-I$with_mpfr_include $gmpinc"
1534 fi
1535 if test "x$with_mpfr_lib" != x; then
1536   gmplibs="-L$with_mpfr_lib $gmplibs"
1537 fi
1538 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1539   # MPFR v3.1.0 moved the sources into a src sub-directory.
1540   if ! test -d ${srcdir}/mpfr/src; then
1541     AC_MSG_ERROR([dnl
1542 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1543   fi
1544   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1545   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1546   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1547   # Do not test the mpfr version.  Assume that it is sufficient, since
1548   # it is in the source tree, and the library has not been built yet
1549   # but it would be included on the link line in the version check below
1550   # hence making the test fail.
1551   have_gmp=yes
1552 fi
1553
1554 # Specify a location for gmp
1555 AC_ARG_WITH(gmp-dir,
1556 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1557 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1558 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1559
1560 AC_ARG_WITH(gmp,
1561 [AS_HELP_STRING([--with-gmp=PATH],
1562                 [specify prefix directory for the installed GMP package.
1563                  Equivalent to --with-gmp-include=PATH/include
1564                  plus --with-gmp-lib=PATH/lib])])
1565 AC_ARG_WITH(gmp-include,
1566 [AS_HELP_STRING([--with-gmp-include=PATH],
1567                 [specify directory for installed GMP include files])])
1568 AC_ARG_WITH(gmp-lib,
1569 [AS_HELP_STRING([--with-gmp-lib=PATH],
1570                 [specify directory for the installed GMP library])])
1571
1572
1573 if test "x$with_gmp" != x; then
1574   gmplibs="-L$with_gmp/lib $gmplibs"
1575   gmpinc="-I$with_gmp/include $gmpinc"
1576 fi
1577 if test "x$with_gmp_include" != x; then
1578   gmpinc="-I$with_gmp_include $gmpinc"
1579 fi
1580 if test "x$with_gmp_lib" != x; then
1581   gmplibs="-L$with_gmp_lib $gmplibs"
1582 fi
1583 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1584   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1585   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1586   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1587   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1588   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1589   # Do not test the gmp version.  Assume that it is sufficient, since
1590   # it is in the source tree, and the library has not been built yet
1591   # but it would be included on the link line in the version check below
1592   # hence making the test fail.
1593   have_gmp=yes
1594 fi
1595
1596 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1597   have_gmp=yes
1598   saved_CFLAGS="$CFLAGS"
1599   CFLAGS="$CFLAGS $gmpinc"
1600   # Check for the recommended and required versions of GMP.
1601   AC_MSG_CHECKING([for the correct version of gmp.h])
1602   AC_TRY_COMPILE([#include "gmp.h"],[
1603   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1604   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1605   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1606   choke me
1607   #endif
1608   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1609   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1610   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1611   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1612   choke me
1613   #endif
1614   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1615    [AC_MSG_RESULT([no]); have_gmp=no])
1616
1617   # If we have GMP, check the MPFR version.
1618   if test x"$have_gmp" = xyes; then
1619     # Check for the recommended and required versions of MPFR.
1620     AC_MSG_CHECKING([for the correct version of mpfr.h])
1621     AC_TRY_COMPILE([#include <gmp.h>
1622     #include <mpfr.h>],[
1623     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1624     choke me
1625     #endif
1626     ], [AC_TRY_COMPILE([#include <gmp.h>
1627     #include <mpfr.h>],[
1628     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1629     choke me
1630     #endif
1631     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1632      [AC_MSG_RESULT([no]); have_gmp=no])
1633   fi
1634
1635   # Check for the MPC header version.
1636   if test x"$have_gmp" = xyes ; then
1637     # Check for the recommended and required versions of MPC.
1638     AC_MSG_CHECKING([for the correct version of mpc.h])
1639     AC_TRY_COMPILE([#include <mpc.h>],[
1640     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1641     choke me
1642     #endif
1643     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1644     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1645     choke me
1646     #endif
1647     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1648      [AC_MSG_RESULT([no]); have_gmp=no])
1649   fi
1650
1651   # Now check the MPFR library.
1652   if test x"$have_gmp" = xyes; then
1653     saved_LIBS="$LIBS"
1654     LIBS="$LIBS $gmplibs"
1655     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1656     AC_TRY_LINK([#include <mpc.h>],[
1657     mpfr_t n;
1658     mpfr_t x;
1659     mpc_t c;
1660     int t;
1661     mpfr_init (n);
1662     mpfr_init (x);
1663     mpfr_atan2 (n, n, x, MPFR_RNDN);
1664     mpfr_erfc (n, x, MPFR_RNDN);
1665     mpfr_subnormalize (x, t, MPFR_RNDN);
1666     mpfr_clear(n);
1667     mpfr_clear(x);
1668     mpc_init2 (c, 53);
1669     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1670     mpc_cosh (c, c, MPC_RNDNN);
1671     mpc_pow (c, c, c, MPC_RNDNN);
1672     mpc_acosh (c, c, MPC_RNDNN);
1673     mpc_clear (c);
1674     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1675     LIBS="$saved_LIBS"
1676   fi
1677
1678   CFLAGS="$saved_CFLAGS"
1679
1680 # The library versions listed in the error message below should match
1681 # the HARD-minimums enforced above.
1682   if test x$have_gmp != xyes; then
1683     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1684 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1685 their locations.  Source code for these libraries can be found at
1686 their respective hosting sites as well as at
1687 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1688 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1689 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1690 make sure that you have installed both the libraries and the header
1691 files.  They may be located in separate packages.])
1692   fi
1693 fi
1694
1695 # Flags needed for both GMP, MPFR and/or MPC.
1696 AC_SUBST(gmplibs)
1697 AC_SUBST(gmpinc)
1698 AC_SUBST(extra_mpfr_configure_flags)
1699 AC_SUBST(extra_mpc_gmp_configure_flags)
1700 AC_SUBST(extra_mpc_mpfr_configure_flags)
1701 AC_SUBST(extra_isl_gmp_configure_flags)
1702
1703 # Libraries to use for stage1 or when not bootstrapping.
1704 AC_ARG_WITH(stage1-libs,
1705 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1706 [if test "$withval" = "no" -o "$withval" = "yes"; then
1707    stage1_libs=
1708  else
1709    stage1_libs=$withval
1710  fi],
1711 [stage1_libs=])
1712 AC_SUBST(stage1_libs)
1713
1714 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1715 # default is yes if gcc is being built; no otherwise.  The reason for
1716 # this default is that gdb is sometimes linked against GNU Source
1717 # Highlight, which is a shared library that uses C++ exceptions.  In
1718 # this case, -static-libstdc++ will cause crashes.
1719 AC_ARG_WITH(static-standard-libraries,
1720 [AS_HELP_STRING([--with-static-standard-libraries],
1721                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1722 [], [with_static_standard_libraries=auto])
1723 if test "$with_static_standard_libraries" = auto; then
1724   with_static_standard_libraries=$have_compiler
1725 fi
1726
1727 # Linker flags to use for stage1 or when not bootstrapping.
1728 AC_ARG_WITH(stage1-ldflags,
1729 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1730 [if test "$withval" = "no" -o "$withval" = "yes"; then
1731    stage1_ldflags=
1732  else
1733    stage1_ldflags=$withval
1734  fi],
1735 [stage1_ldflags=
1736  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1737  # if supported.  But if the user explicitly specified the libraries to use,
1738  # trust that they are doing what they want.
1739  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1740      -a "$have_static_libs" = yes; then
1741    stage1_ldflags="-static-libstdc++ -static-libgcc"
1742  fi])
1743 AC_SUBST(stage1_ldflags)
1744
1745 # Libraries to use for stage2 and later builds.
1746 AC_ARG_WITH(boot-libs,
1747 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1748 [if test "$withval" = "no" -o "$withval" = "yes"; then
1749    poststage1_libs=
1750  else
1751    poststage1_libs=$withval
1752  fi],
1753 [poststage1_libs=])
1754 AC_SUBST(poststage1_libs)
1755
1756 # Linker flags to use for stage2 and later builds.
1757 AC_ARG_WITH(boot-ldflags,
1758 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1759                 [linker flags for stage2 and later])],
1760 [if test "$withval" = "no" -o "$withval" = "yes"; then
1761    poststage1_ldflags=
1762  else
1763    poststage1_ldflags=$withval
1764  fi],
1765 [poststage1_ldflags=
1766  # In stages 2 and 3, default to linking libstdc++ and libgcc
1767  # statically.  But if the user explicitly specified the libraries to
1768  # use, trust that they are doing what they want.
1769  if test "$poststage1_libs" = ""; then
1770    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1771  fi])
1772 AC_SUBST(poststage1_ldflags)
1773
1774 # GCC GRAPHITE dependency isl.
1775 # Basic setup is inlined here, actual checks are in config/isl.m4
1776
1777 AC_ARG_WITH(isl,
1778   [AS_HELP_STRING(
1779    [--with-isl=PATH],
1780    [Specify prefix directory for the installed isl package.
1781     Equivalent to --with-isl-include=PATH/include
1782     plus --with-isl-lib=PATH/lib])])
1783
1784 # Treat --without-isl as a request to disable
1785 # GRAPHITE support and skip all following checks.
1786 if test "x$with_isl" != "xno"; then
1787   # Check for isl
1788   dnl Provide configure switches and initialize islinc & isllibs
1789   dnl with user input.
1790   ISL_INIT_FLAGS
1791   dnl The versions of isl that work for Graphite
1792   ISL_CHECK_VERSION()
1793   dnl Only execute fail-action, if isl has been requested.
1794   ISL_IF_FAILED([
1795     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1796 fi
1797
1798 # If the isl check failed, disable builds of in-tree variant of isl
1799 if test "x$with_isl" = xno ||
1800    test "x$gcc_cv_isl" = xno; then
1801   noconfigdirs="$noconfigdirs isl"
1802   islinc=
1803 fi
1804
1805 AC_SUBST(isllibs)
1806 AC_SUBST(islinc)
1807
1808 # Check for LTO support.
1809 AC_ARG_ENABLE(lto,
1810 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1811 enable_lto=$enableval,
1812 enable_lto=yes; default_enable_lto=yes)
1813
1814 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1815   build_lto_plugin=yes
1816 ],[if test x"$default_enable_lto" = x"yes" ; then
1817     case $target in
1818       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1819       # On other non-ELF platforms, LTO has yet to be validated.
1820       *) enable_lto=no ;;
1821     esac
1822   else
1823   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1824   # It would also be nice to check the binutils support, but we don't
1825   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1826   # warn during gcc/ subconfigure; unless you're bootstrapping with
1827   # -flto it won't be needed until after installation anyway.
1828     case $target in
1829       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1830       *) if test x"$enable_lto" = x"yes"; then
1831         AC_MSG_ERROR([LTO support is not enabled for this target.])
1832         fi
1833       ;;
1834     esac
1835   fi
1836   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1837   # Build it unless LTO was explicitly disabled.
1838   case $target in
1839     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1840     *) ;;
1841   esac
1842 ])
1843
1844 AC_ARG_ENABLE(linker-plugin-configure-flags,
1845   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1846     [additional flags for configuring linker plugins @<:@none@:>@])],
1847   extra_linker_plugin_configure_flags=$enableval,
1848   extra_linker_plugin_configure_flags=)
1849 AC_SUBST(extra_linker_plugin_configure_flags)
1850 AC_ARG_ENABLE(linker-plugin-flags,
1851   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1852     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1853   extra_linker_plugin_flags=$enableval,
1854   extra_linker_plugin_flags=)
1855 AC_SUBST(extra_linker_plugin_flags)
1856
1857 # Enable --enable-host-shared.
1858 # Checked early to determine whether jit is an 'all' language
1859 AC_ARG_ENABLE(host-shared,
1860 [AS_HELP_STRING([--enable-host-shared],
1861                 [build host code as shared libraries])],
1862 [host_shared=$enableval], [host_shared=no])
1863 AC_SUBST(host_shared)
1864
1865 # By default, C and C++ are the only stage 1 languages.
1866 stage1_languages=,c,
1867
1868 # Target libraries that we bootstrap.
1869 bootstrap_target_libs=,target-libgcc,
1870
1871 # Figure out what language subdirectories are present.
1872 # Look if the user specified --enable-languages="..."; if not, use
1873 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1874 # go away some day.
1875 # NB:  embedded tabs in this IF block -- do not untabify
1876 if test -d ${srcdir}/gcc; then
1877   if test x"${enable_languages+set}" != xset; then
1878     if test x"${LANGUAGES+set}" = xset; then
1879       enable_languages="${LANGUAGES}"
1880         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1881     else
1882       enable_languages=default
1883     fi
1884   else
1885     if test x"${enable_languages}" = x ||
1886        test x"${enable_languages}" = xyes;
1887        then
1888       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1889       exit 1
1890     fi
1891   fi
1892   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1893
1894   # 'f95' is the old name for the 'fortran' language. We issue a warning
1895   # and make the substitution.
1896   case ,${enable_languages}, in
1897     *,f95,*)
1898       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1899       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1900       ;;
1901   esac
1902
1903   # If bootstrapping, C++ must be enabled.
1904   case ",$enable_languages,:$enable_bootstrap" in
1905     *,c++,*:*) ;;
1906     *:yes)
1907       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1908         enable_languages="${enable_languages},c++"
1909       else
1910         AC_MSG_ERROR([bootstrapping requires c++ sources])
1911       fi
1912       ;;
1913   esac
1914
1915   # First scan to see if an enabled language requires some other language.
1916   # We assume that a given config-lang.in will list all the language
1917   # front ends it requires, even if some are required indirectly.
1918   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1919     case ${lang_frag} in
1920       ..) ;;
1921       # The odd quoting in the next line works around
1922       # an apparent bug in bash 1.12 on linux.
1923       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1924       *)
1925         # From the config-lang.in, get $language, $lang_requires, and
1926         # $lang_requires_boot_languages.
1927         language=
1928         lang_requires=
1929         lang_requires_boot_languages=
1930         # set srcdir during sourcing lang_frag to the gcc dir.
1931         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1932         # polutes this shell
1933         saved_srcdir=${srcdir}
1934         srcdir=${srcdir}/gcc . ${lang_frag}
1935         srcdir=${saved_srcdir}
1936         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1937           case ,${enable_languages}, in
1938             *,$other,*) ;;
1939             *,default,*) ;;
1940             *,all,*) ;;
1941             *,$language,*)
1942               echo " \`$other' language required by \`$language'; enabling" 1>&2
1943               enable_languages="${enable_languages},${other}"
1944               ;;
1945           esac
1946         done
1947         for other in ${lang_requires_boot_languages} ; do
1948           if test "$other" != "c"; then
1949             case ,${enable_stage1_languages}, in
1950               *,$other,*) ;;
1951               *,default,*) ;;
1952               *,all,*) ;;
1953               *)
1954                 case ,${enable_languages}, in
1955                   *,$language,*)
1956                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1957                     enable_stage1_languages="$enable_stage1_languages,${other}"
1958                     ;;
1959                 esac
1960                 ;;
1961             esac
1962           fi
1963         done
1964         ;;
1965     esac
1966   done
1967
1968   new_enable_languages=,c,
1969
1970   # If LTO is enabled, add the LTO front end.
1971   if test "$enable_lto" = "yes" ; then
1972     case ,${enable_languages}, in
1973       *,lto,*) ;;
1974       *) enable_languages="${enable_languages},lto" ;;
1975     esac
1976     if test "${build_lto_plugin}" = "yes" ; then
1977       configdirs="$configdirs lto-plugin"
1978     fi
1979   fi
1980
1981   # If we're building an offloading compiler, add the LTO front end.
1982   if test x"$enable_as_accelerator_for" != x ; then
1983     case ,${enable_languages}, in
1984       *,lto,*) ;;
1985       *) enable_languages="${enable_languages},lto" ;;
1986     esac
1987   fi
1988
1989   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1990   potential_languages=,c,
1991
1992   enabled_target_libs=
1993   disabled_target_libs=
1994
1995   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1996     case ${lang_frag} in
1997       ..) ;;
1998       # The odd quoting in the next line works around
1999       # an apparent bug in bash 1.12 on linux.
2000       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2001       *)
2002         # From the config-lang.in, get $language, $target_libs,
2003         # $lang_dirs, $boot_language, and $build_by_default
2004         language=
2005         target_libs=
2006         lang_dirs=
2007         subdir_requires=
2008         boot_language=no
2009         build_by_default=yes
2010         # set srcdir during sourcing.  See above about save & restore
2011         saved_srcdir=${srcdir}
2012         srcdir=${srcdir}/gcc . ${lang_frag}
2013         srcdir=${saved_srcdir}
2014         if test x${language} = x; then
2015           echo "${lang_frag} doesn't set \$language." 1>&2
2016           exit 1
2017         fi
2018
2019         if test "$language" = "c++"; then
2020           boot_language=yes
2021         fi
2022
2023         add_this_lang=no
2024         # C is always enabled, so no need to add it again
2025         if test "$language" != "c"; then
2026           case ,${enable_languages}, in
2027             *,${language},*)
2028               # Language was explicitly selected; include it
2029               add_this_lang=yes
2030               ;;
2031             *,all,*)
2032               # All languages are enabled
2033               add_this_lang=all
2034               ;;
2035             *,default,*)
2036               # 'default' was selected, select it if it is a default language
2037               add_this_lang=${build_by_default}
2038               ;;
2039           esac
2040         fi
2041
2042         # Disable languages that need other directories if these aren't available.
2043         for i in $subdir_requires; do
2044           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2045           case ${add_this_lang} in
2046             yes)
2047               # Specifically requested language; tell them.
2048               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2049               ;;
2050             all)
2051               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2052               add_this_lang=unsupported
2053               ;;
2054             *)
2055               # Silently disable.
2056               add_this_lang=unsupported
2057               ;;
2058           esac
2059         done
2060
2061         # Disable Ada if no preexisting GNAT is available.
2062         case ${add_this_lang}:${language}:${have_gnat} in
2063           yes:ada:no)
2064             # Specifically requested language; tell them.
2065             AC_MSG_ERROR([GNAT is required to build $language])
2066             ;;
2067           all:ada:no)
2068             AC_MSG_WARN([GNAT is required to build $language])
2069             add_this_lang=unsupported
2070             ;;
2071           *:ada:no)
2072             # Silently disable.
2073             add_this_lang=unsupported
2074             ;;
2075         esac
2076
2077         # Disable jit if -enable-host-shared not specified
2078         # but not if building for Mingw. All code in Windows
2079         # is position independent code (PIC).
2080         case $target in
2081           *mingw*) ;;
2082           *)
2083           case ${add_this_lang}:${language}:${host_shared} in
2084             yes:jit:no)
2085                    # PR jit/64780: explicitly specify --enable-host-shared
2086             AC_MSG_ERROR([
2087 Enabling language "jit" requires --enable-host-shared.
2088
2089 --enable-host-shared typically slows the rest of the compiler down by
2090 a few %, so you must explicitly enable it.
2091
2092 If you want to build both the jit and the regular compiler, it is often
2093 best to do this via two separate configure/builds, in separate
2094 directories, to avoid imposing the performance cost of
2095 --enable-host-shared on the regular compiler.])
2096                     ;;
2097             all:jit:no)
2098               AC_MSG_WARN([--enable-host-shared required to build $language])
2099               add_this_lang=unsupported
2100               ;;
2101             *:jit:no)
2102               # Silently disable.
2103               add_this_lang=unsupported
2104               ;;
2105                 esac
2106           ;;
2107         esac
2108
2109         # Disable a language that is unsupported by the target.
2110         case "${add_this_lang}: $unsupported_languages " in
2111           no:*) ;;
2112           unsupported:*) ;;
2113           *:*" $language "*)
2114             AC_MSG_WARN([${language} not supported for this target])
2115             add_this_lang=unsupported
2116             ;;
2117         esac
2118
2119         case $add_this_lang in
2120           unsupported)
2121             # Remove language-dependent dirs.
2122             disabled_target_libs="$disabled_target_libs $target_libs"
2123             noconfigdirs="$noconfigdirs $lang_dirs"
2124             ;;
2125           no)
2126             # Remove language-dependent dirs; still show language as supported.
2127             disabled_target_libs="$disabled_target_libs $target_libs"
2128             noconfigdirs="$noconfigdirs $lang_dirs"
2129             potential_languages="${potential_languages}${language},"
2130             ;;
2131           all|yes)
2132             new_enable_languages="${new_enable_languages}${language},"
2133             potential_languages="${potential_languages}${language},"
2134             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2135             enabled_target_libs="$enabled_target_libs $target_libs"
2136             case "${boot_language}:,$enable_stage1_languages," in
2137               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2138                 # Add to (comma-separated) list of stage 1 languages.
2139                 case ",$stage1_languages," in
2140                   *,$language,* | ,yes, | ,all,) ;;
2141                   *) stage1_languages="${stage1_languages}${language}," ;;
2142                 esac
2143                 # We need to bootstrap any supporting libraries.
2144                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2145                 ;;
2146             esac
2147             ;;
2148         esac
2149         ;;
2150     esac
2151   done
2152
2153   # Add target libraries which are only needed for disabled languages
2154   # to noconfigdirs.
2155   if test -n "$disabled_target_libs"; then
2156     for dir in $disabled_target_libs; do
2157       case " $enabled_target_libs " in
2158       *" ${dir} "*) ;;
2159       *) noconfigdirs="$noconfigdirs $dir" ;;
2160       esac
2161     done
2162   fi
2163
2164   AC_ARG_ENABLE(stage1-languages,
2165   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2166                   [choose additional languages to build during
2167                   stage1.  Mostly useful for compiler development])],
2168   [case ,${enable_stage1_languages}, in
2169     ,no,|,,)
2170       # Set it to something that will have no effect in the loop below
2171       enable_stage1_languages=c ;;
2172     ,yes,)
2173       enable_stage1_languages=`echo $new_enable_languages | \
2174         sed -e "s/^,//" -e "s/,$//" ` ;;
2175     *,all,*)
2176       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2177         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2178   esac
2179
2180   # Add "good" languages from enable_stage1_languages to stage1_languages,
2181   # while "bad" languages go in missing_languages.  Leave no duplicates.
2182   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2183     case $potential_languages in
2184       *,$i,*)
2185         case $stage1_languages in
2186           *,$i,*) ;;
2187           *) stage1_languages="$stage1_languages$i," ;;
2188         esac ;;
2189       *)
2190         case $missing_languages in
2191           *,$i,*) ;;
2192           *) missing_languages="$missing_languages$i," ;;
2193         esac ;;
2194      esac
2195   done])
2196
2197   # Remove leading/trailing commas that were added for simplicity
2198   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2199   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2200   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2201   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2202
2203   if test "x$missing_languages" != x; then
2204     AC_MSG_ERROR([
2205 The following requested languages could not be built: ${missing_languages}
2206 Supported languages are: ${potential_languages}])
2207   fi
2208   if test "x$new_enable_languages" != "x$enable_languages"; then
2209     echo The following languages will be built: ${new_enable_languages}
2210     enable_languages="$new_enable_languages"
2211   fi
2212
2213   AC_SUBST(stage1_languages)
2214   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2215 fi
2216
2217 # Handle --disable-<component> generically.
2218 for dir in $configdirs $build_configdirs $target_configdirs ; do
2219   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2220   varname=`echo $dirname | sed -e s/+/_/g`
2221   if eval test x\${enable_${varname}} "=" xno ; then
2222     noconfigdirs="$noconfigdirs $dir"
2223   fi
2224 done
2225
2226 # Check for Boehm's garbage collector
2227 AC_ARG_ENABLE(objc-gc,
2228 [AS_HELP_STRING([--enable-objc-gc],
2229                 [enable use of Boehm's garbage collector with the
2230                  GNU Objective-C runtime])])
2231 AC_ARG_WITH([target-bdw-gc],
2232 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2233                 [specify prefix directory for installed bdw-gc package.
2234                  Equivalent to --with-target-bdw-gc-include=PATH/include
2235                  plus --with-target-bdw-gc-lib=PATH/lib])])
2236 AC_ARG_WITH([target-bdw-gc-include],
2237 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2238                 [specify directories for installed bdw-gc include files])])
2239 AC_ARG_WITH([target-bdw-gc-lib],
2240 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2241                 [specify directories for installed bdw-gc library])])
2242
2243 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2244   AC_MSG_CHECKING([for bdw garbage collector])
2245   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2246     dnl no bdw-gw options, assume default locations
2247     AC_MSG_RESULT([using bdw-gc in default locations])
2248   else
2249     dnl bdw-gw options, first error checking, complete checking in libobjc
2250     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2251       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2252     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2253       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2254     else
2255       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2256     fi
2257   fi
2258 esac
2259
2260 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2261 case ,${enable_languages}, in
2262   *,c++,*)
2263     # Disable libitm, libsanitizer if we're not building libstdc++
2264     case "${noconfigdirs}" in
2265       *target-libstdc++-v3*)
2266         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2267         ;;
2268       *) ;;
2269     esac
2270     ;;
2271   *)
2272     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2273     ;;
2274 esac
2275
2276 # If gcc/ is not in the source tree then we'll not be building a
2277 # target compiler, assume in that case we don't want to build any
2278 # target libraries or tools.
2279 #
2280 # This was added primarily for the benefit for binutils-gdb who reuse
2281 # this configure script, but don't always have target tools available.
2282 if test ! -d ${srcdir}/gcc; then
2283    skipdirs="${skipdirs} ${target_configdirs}"
2284 fi
2285
2286 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2287 # $build_configdirs and $target_configdirs.
2288 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2289
2290 notsupp=""
2291 for dir in . $skipdirs $noconfigdirs ; do
2292   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2293   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2294     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2295     if test -r $srcdir/$dirname/configure ; then
2296       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2297         true
2298       else
2299         notsupp="$notsupp $dir"
2300       fi
2301     fi
2302   fi
2303   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2304     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2305     if test -r $srcdir/$dirname/configure ; then
2306       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2307         true
2308       else
2309         notsupp="$notsupp $dir"
2310       fi
2311     fi
2312   fi
2313   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2314     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2315     if test -r $srcdir/$dirname/configure ; then
2316       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2317         true
2318       else
2319         notsupp="$notsupp $dir"
2320       fi
2321     fi
2322   fi
2323 done
2324
2325 # Quietly strip out all directories which aren't configurable in this tree.
2326 # This relies on all configurable subdirectories being autoconfiscated, which
2327 # is now the case.
2328 build_configdirs_all="$build_configdirs"
2329 build_configdirs=
2330 for i in ${build_configdirs_all} ; do
2331   j=`echo $i | sed -e s/build-//g`
2332   if test -f ${srcdir}/$j/configure ; then
2333     build_configdirs="${build_configdirs} $i"
2334   fi
2335 done
2336
2337 configdirs_all="$configdirs"
2338 configdirs=
2339 for i in ${configdirs_all} ; do
2340   if test -f ${srcdir}/$i/configure ; then
2341     configdirs="${configdirs} $i"
2342   fi
2343 done
2344
2345 target_configdirs_all="$target_configdirs"
2346 target_configdirs=
2347 for i in ${target_configdirs_all} ; do
2348   j=`echo $i | sed -e s/target-//g`
2349   if test -f ${srcdir}/$j/configure ; then
2350     target_configdirs="${target_configdirs} $i"
2351   fi
2352 done
2353
2354 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2355 # so we have to add it after the preceding checks.
2356 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2357 then
2358   case " $configdirs " in
2359     *" libiberty "*)
2360       # If we can build libiberty, we can also build libiberty-linker-plugin.
2361       configdirs="$configdirs libiberty-linker-plugin"
2362       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2363         --with-libiberty=../libiberty-linker-plugin";;
2364     *)
2365       AC_MSG_ERROR([libiberty missing]);;
2366   esac
2367 fi
2368
2369 # Sometimes we have special requirements for the host libiberty.
2370 extra_host_libiberty_configure_flags=
2371 extra_host_zlib_configure_flags=
2372 case " $configdirs " in
2373   *" lto-plugin "* | *" libcc1 "*)
2374     # When these are to be built as shared libraries, the same applies to
2375     # libiberty.
2376     extra_host_libiberty_configure_flags=--enable-shared
2377     ;;
2378   *" bfd "*)
2379     # When bfd is to be built as a shared library, the same applies to
2380     # zlib.
2381     if test "$enable_shared" = "yes"; then
2382       extra_host_zlib_configure_flags=--enable-host-shared
2383     fi
2384     ;;
2385 esac
2386 AC_SUBST(extra_host_libiberty_configure_flags)
2387 AC_SUBST(extra_host_zlib_configure_flags)
2388
2389 # Produce a warning message for the subdirs we can't configure.
2390 # This isn't especially interesting in the Cygnus tree, but in the individual
2391 # FSF releases, it's important to let people know when their machine isn't
2392 # supported by the one or two programs in a package.
2393
2394 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2395   # If $appdirs is non-empty, at least one of those directories must still
2396   # be configured, or we error out.  (E.g., if the gas release supports a
2397   # specified target in some subdirs but not the gas subdir, we shouldn't
2398   # pretend that all is well.)
2399   if test -n "$appdirs" ; then
2400     for dir in $appdirs ; do
2401       if test -r $dir/Makefile.in ; then
2402         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2403           appdirs=""
2404           break
2405         fi
2406         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2407           appdirs=""
2408           break
2409         fi
2410       fi
2411     done
2412     if test -n "$appdirs" ; then
2413       echo "*** This configuration is not supported by this package." 1>&2
2414       exit 1
2415     fi
2416   fi
2417   # Okay, some application will build, or we don't care to check.  Still
2418   # notify of subdirs not getting built.
2419   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2420   echo "    ${notsupp}" 1>&2
2421   echo "    (Any other directories should still work fine.)" 1>&2
2422 fi
2423
2424 case "$host" in
2425   *msdosdjgpp*)
2426     enable_gdbtk=no ;;
2427 esac
2428
2429 # To find our prefix, in gcc_cv_tool_prefix.
2430 ACX_TOOL_DIRS
2431
2432 copy_dirs=
2433
2434 AC_ARG_WITH([build-sysroot],
2435   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2436                   [use sysroot as the system root during the build])],
2437   [if test x"$withval" != x ; then
2438      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2439    fi],
2440   [SYSROOT_CFLAGS_FOR_TARGET=])
2441 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2442
2443 AC_ARG_WITH([debug-prefix-map],
2444   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2445                   [map A to B, C to D ... in debug information])],
2446   [if test x"$withval" != x; then
2447      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2448      for debug_map in $withval; do
2449        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2450      done
2451    fi],
2452   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2453 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2454
2455 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2456 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2457 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2458 # We want to ensure that TARGET libraries (which we know are built with
2459 # gcc) are built with "-O2 -g", so include those options when setting
2460 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2461 if test "x$CFLAGS_FOR_TARGET" = x; then
2462   if test "x${is_cross_compiler}" = xyes; then
2463     CFLAGS_FOR_TARGET="-g -O2"
2464   else
2465     CFLAGS_FOR_TARGET=$CFLAGS
2466     case " $CFLAGS " in
2467       *" -O2 "*) ;;
2468       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2469     esac
2470     case " $CFLAGS " in
2471       *" -g "* | *" -g3 "*) ;;
2472       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2473     esac
2474   fi
2475 fi
2476 AC_SUBST(CFLAGS_FOR_TARGET)
2477
2478 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2479   if test "x${is_cross_compiler}" = xyes; then
2480     CXXFLAGS_FOR_TARGET="-g -O2"
2481   else
2482     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2483     case " $CXXFLAGS " in
2484       *" -O2 "*) ;;
2485       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2486     esac
2487     case " $CXXFLAGS " in
2488       *" -g "* | *" -g3 "*) ;;
2489       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2490     esac
2491   fi
2492 fi
2493 AC_SUBST(CXXFLAGS_FOR_TARGET)
2494
2495 AC_SUBST(LDFLAGS_FOR_TARGET)
2496
2497 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2498 # the named directory are copied to $(tooldir)/sys-include.
2499 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2500   if test x${is_cross_compiler} = xno ; then
2501     echo 1>&2 '***' --with-headers is only supported when cross compiling
2502     exit 1
2503   fi
2504   if test x"${with_headers}" != xyes ; then
2505     x=${gcc_cv_tool_prefix}
2506     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2507   fi
2508 fi
2509
2510 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2511 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2512 # are permitted.
2513 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2514   if test x${is_cross_compiler} = xno ; then
2515     echo 1>&2 '***' --with-libs is only supported when cross compiling
2516     exit 1
2517   fi
2518   if test x"${with_libs}" != xyes ; then
2519     # Copy the libraries in reverse order, so that files in the first named
2520     # library override files in subsequent libraries.
2521     x=${gcc_cv_tool_prefix}
2522     for l in ${with_libs}; do
2523       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2524     done
2525   fi
2526 fi
2527
2528 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2529 #
2530 # This is done by determining whether or not the appropriate directory
2531 # is available, and by checking whether or not specific configurations
2532 # have requested that this magic not happen.
2533 #
2534 # The command line options always override the explicit settings in
2535 # configure.ac, and the settings in configure.ac override this magic.
2536 #
2537 # If the default for a toolchain is to use GNU as and ld, and you don't
2538 # want to do that, then you should use the --without-gnu-as and
2539 # --without-gnu-ld options for the configure script.  Similarly, if
2540 # the default is to use the included zlib and you don't want to do that,
2541 # you should use the --with-system-zlib option for the configure script.
2542
2543 if test x${use_gnu_as} = x &&
2544    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2545   with_gnu_as=yes
2546   extra_host_args="$extra_host_args --with-gnu-as"
2547 fi
2548
2549 if test x${use_gnu_ld} = x &&
2550    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2551   with_gnu_ld=yes
2552   extra_host_args="$extra_host_args --with-gnu-ld"
2553 fi
2554
2555 if test x${use_included_zlib} = x &&
2556    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2557   :
2558 else
2559   with_system_zlib=yes
2560   extra_host_args="$extra_host_args --with-system-zlib"
2561 fi
2562
2563 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2564 # can detect this case.
2565
2566 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2567   with_newlib=yes
2568   extra_host_args="$extra_host_args --with-newlib"
2569 fi
2570
2571 # Handle ${copy_dirs}
2572 set fnord ${copy_dirs}
2573 shift
2574 while test $# != 0 ; do
2575   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2576     :
2577   else
2578     echo Copying $1 to $2
2579
2580     # Use the install script to create the directory and all required
2581     # parent directories.
2582     if test -d $2 ; then
2583       :
2584     else
2585       echo >config.temp
2586       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2587     fi
2588
2589     # Copy the directory, assuming we have tar.
2590     # FIXME: Should we use B in the second tar?  Not all systems support it.
2591     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2592
2593     # It is the responsibility of the user to correctly adjust all
2594     # symlinks.  If somebody can figure out how to handle them correctly
2595     # here, feel free to add the code.
2596
2597     echo $1 > $2/COPIED
2598   fi
2599   shift; shift
2600 done
2601
2602 # Determine a target-dependent exec_prefix that the installed
2603 # gcc will search in.  Keep this list sorted by triplet, with
2604 # the *-*-osname triplets last.
2605 md_exec_prefix=
2606 case "${target}" in
2607   i[[34567]]86-pc-msdosdjgpp*)
2608     md_exec_prefix=/dev/env/DJDIR/bin
2609     ;;
2610   *-*-hpux* | \
2611   *-*-nto-qnx* | \
2612   *-*-solaris2*)
2613     md_exec_prefix=/usr/ccs/bin
2614     ;;
2615 esac
2616
2617 extra_arflags_for_target=
2618 extra_nmflags_for_target=
2619 extra_ranlibflags_for_target=
2620 target_makefile_frag=/dev/null
2621 case "${target}" in
2622   spu-*-*)
2623     target_makefile_frag="config/mt-spu"
2624     ;;
2625   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2626     target_makefile_frag="config/mt-sde"
2627     ;;
2628   mipsisa*-*-elfoabi*)
2629     target_makefile_frag="config/mt-mips-elfoabi"
2630     ;;
2631   mips*-*-*linux* | mips*-*-gnu*)
2632     target_makefile_frag="config/mt-mips-gnu"
2633     ;;
2634   nios2-*-elf*)
2635     target_makefile_frag="config/mt-nios2-elf"
2636     ;;
2637   *-*-linux-android*)
2638     target_makefile_frag="config/mt-android"
2639     ;;
2640   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2641     target_makefile_frag="config/mt-gnu"
2642     ;;
2643   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2644     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2645     # commands to handle both 32-bit and 64-bit objects.  These flags are
2646     # harmless if we're using GNU nm or ar.
2647     extra_arflags_for_target=" -X32_64"
2648     extra_nmflags_for_target=" -B -X32_64"
2649     ;;
2650 esac
2651
2652 alphaieee_frag=/dev/null
2653 case $target in
2654   alpha*-*-*)
2655     # This just makes sure to use the -mieee option to build target libs.
2656     # This should probably be set individually by each library.
2657     alphaieee_frag="config/mt-alphaieee"
2658     ;;
2659 esac
2660
2661 # If --enable-target-optspace always use -Os instead of -O2 to build
2662 # the target libraries, similarly if it is not specified, use -Os
2663 # on selected platforms.
2664 ospace_frag=/dev/null
2665 case "${enable_target_optspace}:${target}" in
2666   yes:*)
2667     ospace_frag="config/mt-ospace"
2668     ;;
2669   :d30v-*)
2670     ospace_frag="config/mt-d30v"
2671     ;;
2672   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2673     ospace_frag="config/mt-ospace"
2674     ;;
2675   no:* | :*)
2676     ;;
2677   *)
2678     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2679     ;;
2680 esac
2681
2682 # Some systems (e.g., one of the i386-aix systems the gas testers are
2683 # using) don't handle "\$" correctly, so don't use it here.
2684 tooldir='${exec_prefix}'/${target_noncanonical}
2685 build_tooldir=${tooldir}
2686
2687 # Create a .gdbinit file which runs the one in srcdir
2688 # and tells GDB to look there for source files.
2689
2690 if test -r ${srcdir}/.gdbinit ; then
2691   case ${srcdir} in
2692     .) ;;
2693     *) cat > ./.gdbinit <<EOF
2694 # ${NO_EDIT}
2695 dir ${srcdir}
2696 dir .
2697 source ${srcdir}/.gdbinit
2698 EOF
2699     ;;
2700   esac
2701 fi
2702
2703 # Make sure that the compiler is able to generate an executable.  If it
2704 # can't, we are probably in trouble.  We don't care whether we can run the
2705 # executable--we might be using a cross compiler--we only care whether it
2706 # can be created.  At this point the main configure script has set CC.
2707 we_are_ok=no
2708 echo "int main () { return 0; }" > conftest.c
2709 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2710 if test $? = 0 ; then
2711   if test -s conftest || test -s conftest.exe ; then
2712     we_are_ok=yes
2713   fi
2714 fi
2715 case $we_are_ok in
2716   no)
2717     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2718     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2719     rm -f conftest*
2720     exit 1
2721     ;;
2722 esac
2723 rm -f conftest*
2724
2725 # Decide which environment variable is used to find dynamic libraries.
2726 case "${host}" in
2727   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2728   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2729   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2730   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2731 esac
2732
2733 # On systems where the dynamic library environment variable is PATH,
2734 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2735 # built executables to PATH.
2736 if test "$RPATH_ENVVAR" = PATH; then
2737   GCC_SHLIB_SUBDIR=/shlib
2738 else
2739   GCC_SHLIB_SUBDIR=
2740 fi
2741
2742 # Adjust the toplevel makefile according to whether bootstrap was selected.
2743 case $enable_bootstrap in
2744   yes)
2745     bootstrap_suffix=bootstrap
2746     BUILD_CONFIG=bootstrap-debug
2747     ;;
2748   no)
2749     bootstrap_suffix=no-bootstrap
2750     BUILD_CONFIG=
2751     ;;
2752 esac
2753
2754 AC_MSG_CHECKING(for default BUILD_CONFIG)
2755
2756 AC_ARG_WITH([build-config],
2757   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2758                   [use config/NAME.mk build configuration])],
2759   [case $with_build_config in
2760    yes) with_build_config= ;;
2761    no) with_build_config= BUILD_CONFIG= ;;
2762    esac])
2763
2764 if test "x${with_build_config}" != x; then
2765   BUILD_CONFIG=$with_build_config
2766 else
2767   case $BUILD_CONFIG in
2768   bootstrap-debug)
2769     if echo "int f (void) { return 0; }" > conftest.c &&
2770        ${CC} -c conftest.c &&
2771        mv conftest.o conftest.o.g0 &&
2772        ${CC} -c -g conftest.c &&
2773        mv conftest.o conftest.o.g &&
2774        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2775       :
2776     else
2777       BUILD_CONFIG=
2778     fi
2779     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2780     ;;
2781   esac
2782 fi
2783 AC_MSG_RESULT($BUILD_CONFIG)
2784 AC_SUBST(BUILD_CONFIG)
2785
2786 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2787 AC_MSG_CHECKING([for --enable-vtable-verify])
2788 AC_ARG_ENABLE(vtable-verify,
2789 [AS_HELP_STRING([--enable-vtable-verify],
2790                 [Enable vtable verification feature])],
2791 [case "$enableval" in
2792  yes) enable_vtable_verify=yes ;;
2793  no)  enable_vtable_verify=no ;;
2794  *)   enable_vtable_verify=no;;
2795  esac],
2796 [enable_vtable_verify=no])
2797 AC_MSG_RESULT($enable_vtable_verify)
2798
2799 # Record target_configdirs and the configure arguments for target and
2800 # build configuration in Makefile.
2801 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2802 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2803 bootstrap_fixincludes=no
2804
2805 # If we are building libgomp, bootstrap it.
2806 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2807   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2808 fi
2809
2810 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2811 # or bootstrap-ubsan, bootstrap it.
2812 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2813   case "$BUILD_CONFIG" in
2814     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
2815       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2816       bootstrap_fixincludes=yes
2817       ;;
2818   esac
2819 fi
2820
2821 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2822 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2823    test "$enable_vtable_verify" != no; then
2824   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2825 fi
2826
2827 # Determine whether gdb needs tk/tcl or not.
2828 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2829 # and in that case we want gdb to be built without tk.  Ugh!
2830 # In fact I believe gdb is the *only* package directly dependent on tk,
2831 # so we should be able to put the 'maybe's in unconditionally and
2832 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2833 # 100% sure that that's safe though.
2834
2835 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2836 case "$enable_gdbtk" in
2837   no)
2838     GDB_TK="" ;;
2839   yes)
2840     GDB_TK="${gdb_tk}" ;;
2841   *)
2842     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2843     # distro.  Eventually someone will fix this and move Insight, nee
2844     # gdbtk to a separate directory.
2845     if test -d ${srcdir}/gdb/gdbtk ; then
2846       GDB_TK="${gdb_tk}"
2847     else
2848       GDB_TK=""
2849     fi
2850     ;;
2851 esac
2852 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2853 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2854
2855 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2856 # else does, only include them if one of these is built.  The Makefile
2857 # provides the ordering, so it's enough here to add to the list.
2858 case " ${configdirs} " in
2859   *\ gdb\ *)
2860     configdirs="${configdirs} gnulib gdbsupport"
2861     ;;
2862   *\ gdbserver\ *)
2863     configdirs="${configdirs} gnulib gdbsupport"
2864     ;;
2865   *\ sim\ *)
2866     configdirs="${configdirs} gnulib"
2867     ;;
2868 esac
2869
2870 # Strip out unwanted targets.
2871
2872 # While at that, we remove Makefiles if we were started for recursive
2873 # configuration, so that the top-level Makefile reconfigures them,
2874 # like we used to do when configure itself was recursive.
2875
2876 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2877 # but now we're fixing up the Makefile ourselves with the additional
2878 # commands passed to AC_CONFIG_FILES.  Use separate variables
2879 # extrasub-{build,host,target} not because there is any reason to split
2880 # the substitutions up that way, but only to remain below the limit of
2881 # 99 commands in a script, for HP-UX sed.
2882
2883 # Do not nest @if/@endif or @unless/@endunless pairs, because
2884 # configure will not warn you at all.
2885
2886 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2887   yes:yes:*\ gold\ *:*,c++,*) ;;
2888   yes:yes:*\ gold\ *:*)
2889     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2890     ;;
2891 esac
2892
2893 extrasub_build=
2894 for module in ${build_configdirs} ; do
2895   if test -z "${no_recursion}" \
2896      && test -f ${build_subdir}/${module}/Makefile; then
2897     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2898     rm -f ${build_subdir}/${module}/Makefile
2899   fi
2900   extrasub_build="$extrasub_build
2901 /^@if build-$module\$/d
2902 /^@endif build-$module\$/d
2903 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2904 /^@if build-$module-$bootstrap_suffix\$/d
2905 /^@endif build-$module-$bootstrap_suffix\$/d
2906 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2907 done
2908 extrasub_host=
2909 for module in ${configdirs} ; do
2910   if test -z "${no_recursion}"; then
2911     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2912       if test -f ${file}; then
2913         echo 1>&2 "*** removing ${file} to force reconfigure"
2914         rm -f ${file}
2915       fi
2916     done
2917   fi
2918   case ${module},${bootstrap_fixincludes} in
2919     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2920     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2921   esac
2922   extrasub_host="$extrasub_host
2923 /^@if $module\$/d
2924 /^@endif $module\$/d
2925 /^@unless $module\$/,/^@endunless $module\$/d
2926 /^@if $module-$host_bootstrap_suffix\$/d
2927 /^@endif $module-$host_bootstrap_suffix\$/d
2928 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2929 done
2930 extrasub_target=
2931 for module in ${target_configdirs} ; do
2932   if test -z "${no_recursion}" \
2933      && test -f ${target_subdir}/${module}/Makefile; then
2934     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2935     rm -f ${target_subdir}/${module}/Makefile
2936   fi
2937
2938   # We only bootstrap target libraries listed in bootstrap_target_libs.
2939   case $bootstrap_target_libs in
2940     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2941     *) target_bootstrap_suffix=no-bootstrap ;;
2942   esac
2943
2944   extrasub_target="$extrasub_target
2945 /^@if target-$module\$/d
2946 /^@endif target-$module\$/d
2947 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2948 /^@if target-$module-$target_bootstrap_suffix\$/d
2949 /^@endif target-$module-$target_bootstrap_suffix\$/d
2950 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2951 done
2952
2953 # Do the final fixup along with target modules.
2954 extrasub_target="$extrasub_target
2955 /^@if /,/^@endif /d
2956 /^@unless /d
2957 /^@endunless /d"
2958
2959 # Create the serialization dependencies.  This uses a temporary file.
2960
2961 AC_ARG_ENABLE([serial-configure],
2962 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2963                 [force sequential configuration of
2964                  sub-packages for the host, target or build
2965                  machine, or all sub-packages])])
2966
2967 case ${enable_serial_configure} in
2968   yes)
2969     enable_serial_build_configure=yes
2970     enable_serial_host_configure=yes
2971     enable_serial_target_configure=yes
2972     ;;
2973 esac
2974
2975 # These force 'configure's to be done one at a time, to avoid problems
2976 # with contention over a shared config.cache.
2977 rm -f serdep.tmp
2978 echo '# serdep.tmp' > serdep.tmp
2979 olditem=
2980 test "x${enable_serial_build_configure}" = xyes &&
2981 for item in ${build_configdirs} ; do
2982   case ${olditem} in
2983     "") ;;
2984     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2985   esac
2986   olditem=${item}
2987 done
2988 olditem=
2989 test "x${enable_serial_host_configure}" = xyes &&
2990 for item in ${configdirs} ; do
2991   case ${olditem} in
2992     "") ;;
2993     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2994   esac
2995   olditem=${item}
2996 done
2997 olditem=
2998 test "x${enable_serial_target_configure}" = xyes &&
2999 for item in ${target_configdirs} ; do
3000   case ${olditem} in
3001     "") ;;
3002     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3003   esac
3004   olditem=${item}
3005 done
3006 serialization_dependencies=serdep.tmp
3007 AC_SUBST_FILE(serialization_dependencies)
3008
3009 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3010 # target, nonopt, and variable assignments.  These are the ones we
3011 # might not want to pass down to subconfigures.  The exception being
3012 # --cache-file=/dev/null, which is used to turn off the use of cache
3013 # files altogether, and which should be passed on to subconfigures.
3014 # Also strip program-prefix, program-suffix, and program-transform-name,
3015 # so that we can pass down a consistent program-transform-name.
3016 baseargs=
3017 tbaseargs=
3018 keep_next=no
3019 skip_next=no
3020 eval "set -- $ac_configure_args"
3021 for ac_arg
3022 do
3023   if test X"$skip_next" = X"yes"; then
3024     skip_next=no
3025     continue
3026   fi
3027   if test X"$keep_next" = X"yes"; then
3028     case $ac_arg in
3029       *\'*)
3030         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3031     esac
3032     baseargs="$baseargs '$ac_arg'"
3033     tbaseargs="$tbaseargs '$ac_arg'"
3034     keep_next=no
3035     continue
3036   fi
3037
3038   # Handle separated arguments.  Based on the logic generated by
3039   # autoconf 2.59.
3040   case $ac_arg in
3041     *=* | --config-cache | -C | -disable-* | --disable-* \
3042       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3043       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3044       | -with-* | --with-* | -without-* | --without-* | --x)
3045       separate_arg=no
3046       ;;
3047     -*)
3048       separate_arg=yes
3049       ;;
3050     *)
3051       separate_arg=no
3052       ;;
3053   esac
3054
3055   skip_targ=no
3056   case $ac_arg in
3057 changequote(,)
3058   --with-* | --without-*)
3059     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3060
3061     case $libopt in
3062     *[-_]include)
3063       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3064       ;;
3065     *[-_]lib)
3066       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3067       ;;
3068     *)
3069       lib=$libopt
3070       ;;
3071     esac
3072 changequote([,])
3073
3074     case $lib in
3075     mpc | mpfr | gmp | isl)
3076       # If we're processing --with-$lib, --with-$lib-include or
3077       # --with-$lib-lib, for one of the libs above, and target is
3078       # different from host, don't pass the current argument to any
3079       # target library's configure.
3080       if test x$is_cross_compiler = xyes; then
3081         skip_targ=yes
3082       fi
3083       ;;
3084     esac
3085     ;;
3086   esac
3087
3088   case "$ac_arg" in
3089     --cache-file=/dev/null | \
3090     -cache-file=/dev/null )
3091       # Handled here to avoid the test to skip args below.
3092       baseargs="$baseargs '$ac_arg'"
3093       tbaseargs="$tbaseargs '$ac_arg'"
3094       # Assert: $separate_arg should always be no.
3095       keep_next=$separate_arg
3096       ;;
3097     --no*)
3098       continue
3099       ;;
3100     --c* | \
3101     --sr* | \
3102     --ho* | \
3103     --bu* | \
3104     --t* | \
3105     --program-* | \
3106     -cache_file* | \
3107     -srcdir* | \
3108     -host* | \
3109     -build* | \
3110     -target* | \
3111     -program-prefix* | \
3112     -program-suffix* | \
3113     -program-transform-name* )
3114       skip_next=$separate_arg
3115       continue
3116       ;;
3117     -*)
3118       # An option.  Add it.
3119       case $ac_arg in
3120         *\'*)
3121           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3122       esac
3123       baseargs="$baseargs '$ac_arg'"
3124       if test X"$skip_targ" = Xno; then
3125         tbaseargs="$tbaseargs '$ac_arg'"
3126       fi
3127       keep_next=$separate_arg
3128       ;;
3129     *)
3130       # Either a variable assignment, or a nonopt (triplet).  Don't
3131       # pass it down; let the Makefile handle this.
3132       continue
3133       ;;
3134   esac
3135 done
3136 # Remove the initial space we just introduced and, as these will be
3137 # expanded by make, quote '$'.
3138 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3139
3140 # Add in --program-transform-name, after --program-prefix and
3141 # --program-suffix have been applied to it.  Autoconf has already
3142 # doubled dollar signs and backslashes in program_transform_name; we want
3143 # the backslashes un-doubled, and then the entire thing wrapped in single
3144 # quotes, because this will be expanded first by make and then by the shell.
3145 # Also, because we want to override the logic in subdir configure scripts to
3146 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3147 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3148 ${program_transform_name}
3149 EOF_SED
3150 gcc_transform_name=`cat conftestsed.out`
3151 rm -f conftestsed.out
3152 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3153 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3154 if test "$silent" = yes; then
3155   baseargs="$baseargs --silent"
3156   tbaseargs="$tbaseargs --silent"
3157 fi
3158 baseargs="$baseargs --disable-option-checking"
3159 tbaseargs="$tbaseargs --disable-option-checking"
3160
3161 # Record and document user additions to sub configure arguments.
3162 AC_ARG_VAR([build_configargs],
3163            [additional configure arguments for build directories])
3164 AC_ARG_VAR([host_configargs],
3165            [additional configure arguments for host directories])
3166 AC_ARG_VAR([target_configargs],
3167            [additional configure arguments for target directories])
3168
3169 # For the build-side libraries, we just need to pretend we're native,
3170 # and not use the same cache file.  Multilibs are neither needed nor
3171 # desired.  We can't even use the same cache file for all build-side
3172 # libraries, as they're compiled differently; some with C, some with
3173 # C++ or with different feature-enabling options.
3174 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3175
3176 # For host modules, accept cache file option, or specification as blank.
3177 case "${cache_file}" in
3178 "") # empty
3179   cache_file_option="" ;;
3180 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3181   cache_file_option="--cache-file=${cache_file}" ;;
3182 *) # relative path
3183   cache_file_option="--cache-file=../${cache_file}" ;;
3184 esac
3185
3186 # Host dirs don't like to share a cache file either, horribly enough.
3187 # This seems to be due to autoconf 2.5x stupidity.
3188 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3189
3190 target_configargs="$target_configargs ${tbaseargs}"
3191
3192 # Passing a --with-cross-host argument lets the target libraries know
3193 # whether they are being built with a cross-compiler or being built
3194 # native.  However, it would be better to use other mechanisms to make the
3195 # sorts of decisions they want to make on this basis.  Please consider
3196 # this option to be deprecated.  FIXME.
3197 if test x${is_cross_compiler} = xyes ; then
3198   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3199 fi
3200
3201 # Special user-friendly check for native x86_64-linux build, if
3202 # multilib is not explicitly enabled.
3203 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3204   x86_64-*linux*:yes:$build:$build:)
3205     # Make sure we have a development environment that handles 32-bit
3206     dev64=no
3207     echo "int main () { return 0; }" > conftest.c
3208     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3209     if test $? = 0 ; then
3210       if test -s conftest || test -s conftest.exe ; then
3211         dev64=yes
3212       fi
3213     fi
3214     rm -f conftest*
3215     if test x${dev64} != xyes ; then
3216       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3217     fi
3218     ;;
3219 esac
3220
3221 # Default to --enable-multilib.
3222 if test x${enable_multilib} = x ; then
3223   target_configargs="--enable-multilib ${target_configargs}"
3224 fi
3225
3226 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3227 # changed from the earlier setting of with_newlib.
3228 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3229   target_configargs="--with-newlib ${target_configargs}"
3230 fi
3231
3232 # Different target subdirs use different values of certain variables
3233 # (notably CXX).  Worse, multilibs use *lots* of different values.
3234 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3235 # it doesn't automatically accept command-line overrides of them.
3236 # This means it's not safe for target subdirs to share a cache file,
3237 # which is disgusting, but there you have it.  Hopefully this can be
3238 # fixed in future.  It's still worthwhile to use a cache file for each
3239 # directory.  I think.
3240
3241 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3242 # We need to pass --target, as newer autoconf's requires consistency
3243 # for target_alias and gcc doesn't manage it consistently.
3244 target_configargs="--cache-file=./config.cache ${target_configargs}"
3245
3246 FLAGS_FOR_TARGET=
3247 case " $target_configdirs " in
3248  *" newlib "*)
3249   case " $target_configargs " in
3250   *" --with-newlib "*)
3251    case "$target" in
3252     *-cygwin*)
3253       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3254       ;;
3255    esac
3256
3257    # If we're not building GCC, don't discard standard headers.
3258    if test -d ${srcdir}/gcc; then
3259      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3260
3261      if test "${build}" != "${host}"; then
3262        # On Canadian crosses, CC_FOR_TARGET will have already been set
3263        # by `configure', so we won't have an opportunity to add -Bgcc/
3264        # to it.  This is right: we don't want to search that directory
3265        # for binaries, but we want the header files in there, so add
3266        # them explicitly.
3267        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3268
3269        # Someone might think of using the pre-installed headers on
3270        # Canadian crosses, in case the installed compiler is not fully
3271        # compatible with the compiler being built.  In this case, it
3272        # would be better to flag an error than risking having
3273        # incompatible object files being constructed.  We can't
3274        # guarantee that an error will be flagged, but let's hope the
3275        # compiler will do it, when presented with incompatible header
3276        # files.
3277      fi
3278    fi
3279
3280    case "${target}-${is_cross_compiler}" in
3281    i[[3456789]]86-*-linux*-no)
3282       # Here host == target, so we don't need to build gcc,
3283       # so we don't want to discard standard headers.
3284       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3285       ;;
3286    *)
3287       # If we're building newlib, use its generic headers last, but search
3288       # for any libc-related directories first (so make it the last -B
3289       # switch).
3290       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3291
3292       # If we're building libgloss, find the startup file, simulator library
3293       # and linker script.
3294       case " $target_configdirs " in
3295         *" libgloss "*)
3296         # Look for startup file, simulator library and maybe linker script.
3297         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3298         # Look for libnosys.a in case the target needs it.
3299         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3300         # Most targets have the linker script in the source directory.
3301         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3302         ;;
3303       esac
3304       ;;
3305    esac
3306    ;;
3307   esac
3308   ;;
3309 esac
3310
3311 case "$target" in
3312   x86_64-*mingw* | *-w64-mingw*)
3313   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3314   # however, use a symlink named 'mingw' in ${prefix} .
3315     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3316     ;;
3317   *-mingw*)
3318   # MinGW can't be handled as Cygwin above since it does not use newlib.
3319     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3320     ;;
3321 esac
3322
3323 # Allow the user to override the flags for
3324 # our build compiler if desired.
3325 if test x"${build}" = x"${host}" ; then
3326   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3327   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3328   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3329   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3330 fi
3331
3332 # On Canadian crosses, we'll be searching the right directories for
3333 # the previously-installed cross compiler, so don't bother to add
3334 # flags for directories within the install tree of the compiler
3335 # being built; programs in there won't even run.
3336 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3337   # Search for pre-installed headers if nothing else fits.
3338   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3339 fi
3340
3341 if test "x${use_gnu_ld}" = x &&
3342    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3343   # Arrange for us to find uninstalled linker scripts.
3344   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3345 fi
3346
3347 # Search for other target-specific linker scripts and such.
3348 case "${target}" in
3349   mep*)
3350     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3351     ;;
3352 esac
3353
3354 # Makefile fragments.
3355 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3356 do
3357   eval fragval=\$$frag
3358   if test $fragval != /dev/null; then
3359     eval $frag=${srcdir}/$fragval
3360   fi
3361 done
3362 AC_SUBST_FILE(host_makefile_frag)
3363 AC_SUBST_FILE(target_makefile_frag)
3364 AC_SUBST_FILE(alphaieee_frag)
3365 AC_SUBST_FILE(ospace_frag)
3366
3367 # Miscellanea: directories, flags, etc.
3368 AC_SUBST(RPATH_ENVVAR)
3369 AC_SUBST(GCC_SHLIB_SUBDIR)
3370 AC_SUBST(tooldir)
3371 AC_SUBST(build_tooldir)
3372 AC_SUBST(CONFIGURE_GDB_TK)
3373 AC_SUBST(GDB_TK)
3374 AC_SUBST(INSTALL_GDB_TK)
3375
3376 # Build module lists & subconfigure args.
3377 AC_SUBST(build_configargs)
3378 AC_SUBST(build_configdirs)
3379
3380 # Host module lists & subconfigure args.
3381 AC_SUBST(host_configargs)
3382 AC_SUBST(configdirs)
3383 AC_SUBST(target_configdirs)
3384
3385 # Target module lists & subconfigure args.
3386 AC_SUBST(target_configargs)
3387
3388
3389 # Build tools.
3390 AC_SUBST(AR_FOR_BUILD)
3391 AC_SUBST(AS_FOR_BUILD)
3392 AC_SUBST(CC_FOR_BUILD)
3393 AC_SUBST(CFLAGS_FOR_BUILD)
3394 AC_SUBST(CPP_FOR_BUILD)
3395 AC_SUBST(CPPFLAGS_FOR_BUILD)
3396 AC_SUBST(CXXFLAGS_FOR_BUILD)
3397 AC_SUBST(CXX_FOR_BUILD)
3398 AC_SUBST(DLLTOOL_FOR_BUILD)
3399 AC_SUBST(DSYMUTIL_FOR_BUILD)
3400 AC_SUBST(GFORTRAN_FOR_BUILD)
3401 AC_SUBST(GOC_FOR_BUILD)
3402 AC_SUBST(GDC_FOR_BUILD)
3403 AC_SUBST(LDFLAGS_FOR_BUILD)
3404 AC_SUBST(LD_FOR_BUILD)
3405 AC_SUBST(NM_FOR_BUILD)
3406 AC_SUBST(RANLIB_FOR_BUILD)
3407 AC_SUBST(WINDMC_FOR_BUILD)
3408 AC_SUBST(WINDRES_FOR_BUILD)
3409
3410 # Generate default definitions for YACC, M4, LEX and other programs that run
3411 # on the build machine.  These are used if the Makefile can't locate these
3412 # programs in objdir.
3413 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3414
3415 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3416 case " $build_configdirs " in
3417   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3418 esac
3419
3420 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3421 case " $build_configdirs " in
3422   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3423 esac
3424
3425 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3426 case " $build_configdirs " in
3427   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3428 esac
3429
3430 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3431 case " $build_configdirs " in
3432   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3433   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3434 esac
3435
3436 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3437 case " $build_configdirs " in
3438   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3439 esac
3440
3441 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3442 case " $build_configdirs " in
3443   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3444   *)
3445 changequote(,)
3446     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3447     # higher, else we use the "missing" dummy.
3448     if ${MAKEINFO} --version \
3449        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3450       :
3451     else
3452       MAKEINFO="$MISSING makeinfo"
3453     fi
3454     ;;
3455 changequote([,])
3456 esac
3457
3458 # FIXME: expect and dejagnu may become build tools?
3459
3460 AC_CHECK_PROGS(EXPECT, expect, expect)
3461 case " $configdirs " in
3462   *" expect "*)
3463     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3464     ;;
3465 esac
3466
3467 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3468 case " $configdirs " in
3469   *" dejagnu "*)
3470     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3471     ;;
3472 esac
3473
3474
3475 # Host tools.
3476 NCN_STRICT_CHECK_TOOLS(AR, ar)
3477 NCN_STRICT_CHECK_TOOLS(AS, as)
3478 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3479 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3480 NCN_STRICT_CHECK_TOOLS(LD, ld)
3481 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3482 NCN_STRICT_CHECK_TOOLS(NM, nm)
3483 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3484 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3485 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3486 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3487 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3488 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3489 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3490 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3491 AC_SUBST(CC)
3492 AC_SUBST(CXX)
3493 AC_SUBST(CFLAGS)
3494 AC_SUBST(CXXFLAGS)
3495
3496 # Target tools.
3497 AC_ARG_WITH([build-time-tools],
3498   [AS_HELP_STRING([--with-build-time-tools=PATH],
3499                   [use given path to find target tools during the build])],
3500   [case x"$withval" in
3501      x/*) ;;
3502      *)
3503        with_build_time_tools=
3504        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3505        ;;
3506    esac],
3507   [with_build_time_tools=])
3508
3509 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3510 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3511 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3512 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3513 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3514 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3515
3516 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3517 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3518 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3519 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3520 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3521 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3522 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3523 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3524 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3525 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3526 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3527 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3528 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3529 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3530 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3531
3532 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3533
3534 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3535 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3536 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3537 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3538 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3539                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3540                 c++)
3541 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3542                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3543                 c++)
3544 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3545 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3546 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3547 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3548                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3549 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3550                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3551 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3552                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3553 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3554 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3555 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3556 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3557 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3558 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3559 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3560 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3561 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3562 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3563 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3564
3565 AC_SUBST(FLAGS_FOR_TARGET)
3566 AC_SUBST(RAW_CXX_FOR_TARGET)
3567
3568 # Certain tools may need extra flags.
3569 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3570 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3571 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3572
3573 # When building target libraries, except in a Canadian cross, we use
3574 # the same toolchain as the compiler we just built.
3575 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3576 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3577 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3578 if test $host = $build; then
3579   case " $configdirs " in
3580     *" gcc "*)
3581       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3582       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3583       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3584       ;;
3585   esac
3586 fi
3587
3588 AC_SUBST(COMPILER_AS_FOR_TARGET)
3589 AC_SUBST(COMPILER_LD_FOR_TARGET)
3590 AC_SUBST(COMPILER_NM_FOR_TARGET)
3591
3592 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3593 AC_ARG_ENABLE(maintainer-mode,
3594 [AS_HELP_STRING([--enable-maintainer-mode],
3595                 [enable make rules and dependencies not useful
3596                  (and sometimes confusing) to the casual installer])],
3597       USE_MAINTAINER_MODE=$enableval,
3598       USE_MAINTAINER_MODE=no)
3599 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3600 AC_SUBST(MAINTAINER_MODE_TRUE)
3601 AC_SUBST(MAINTAINER_MODE_FALSE)
3602 if test "$USE_MAINTAINER_MODE" = yes; then
3603   MAINTAINER_MODE_TRUE=
3604   MAINTAINER_MODE_FALSE='#'
3605 else
3606   MAINTAINER_MODE_TRUE='#'
3607   MAINTAINER_MODE_FALSE=
3608 fi
3609 MAINT=$MAINTAINER_MODE_TRUE
3610 AC_SUBST(MAINT)dnl
3611
3612 # ---------------------
3613 # GCC bootstrap support
3614 # ---------------------
3615
3616 # Stage specific cflags for build.
3617 stage1_cflags="-g"
3618 case $build in
3619   vax-*-*)
3620     case ${GCC} in
3621       yes) stage1_cflags="-g -Wa,-J" ;;
3622       *) stage1_cflags="-g -J" ;;
3623     esac ;;
3624 esac
3625
3626 AC_SUBST(stage1_cflags)
3627
3628 # Enable --enable-checking in stage1 of the compiler.
3629 AC_ARG_ENABLE(stage1-checking,
3630 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3631                 [choose additional checking for stage1 of the compiler])],
3632 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3633 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3634   # For --disable-checking or implicit --enable-checking=release, avoid
3635   # setting --enable-checking=gc in the default stage1 checking for LTO
3636   # bootstraps.  See PR62077.
3637   case $BUILD_CONFIG in
3638     *lto*)
3639       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3640     *)
3641       stage1_checking=--enable-checking=yes,types;;
3642   esac
3643   if test "x$enable_checking" = x && \
3644      test -d ${srcdir}/gcc && \
3645      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3646     stage1_checking=--enable-checking=yes,types,extra
3647   fi
3648 else
3649   stage1_checking=--enable-checking=$enable_checking,types
3650 fi])
3651 AC_SUBST(stage1_checking)
3652
3653 # Enable -Werror in bootstrap stage2 and later.
3654 AC_ARG_ENABLE(werror,
3655 [AS_HELP_STRING([--enable-werror],
3656                 [enable -Werror in bootstrap stage2 and later])],
3657 [
3658 case ${enable_werror} in
3659   yes) stage2_werror_flag="--enable-werror-always" ;;
3660   *) stage2_werror_flag="" ;;
3661 esac
3662 ],
3663 [
3664 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3665   case $BUILD_CONFIG in
3666   bootstrap-debug)
3667       stage2_werror_flag="--enable-werror-always" ;;
3668   "")
3669       stage2_werror_flag="--enable-werror-always" ;;
3670   esac
3671 fi
3672 ])
3673
3674 AC_SUBST(stage2_werror_flag)
3675
3676 # Specify what files to not compare during bootstrap.
3677
3678 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3679 case "$target" in
3680   hppa*64*-*-hpux*) ;;
3681   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3682   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3683 esac
3684 AC_SUBST(compare_exclusions)
3685
3686 AC_CONFIG_FILES([Makefile],
3687   [sed "$extrasub_build" Makefile |
3688    sed "$extrasub_host" |
3689    sed "$extrasub_target" > mf$$
3690    mv -f mf$$ Makefile],
3691   [extrasub_build="$extrasub_build"
3692    extrasub_host="$extrasub_host"
3693    extrasub_target="$extrasub_target"])
3694 AC_OUTPUT