configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012, 2014
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1"
 144
 145 # libgcj represents the runtime libraries only used by gcj.
 146 libgcj="target-libffi \
 147         target-zlib \
 148         target-libjava"
 149
 150 # these libraries are built for the target environment, and are built after
 151 # the host libraries and the host tools (which may be a cross compiler)
 152 # Note that libiberty is not a target library.
 153 target_libraries="target-libgcc \
 154                 target-libbacktrace \
 155                 target-libgloss \
 156                 target-newlib \
 157                 target-libgomp \
 158                 target-libcilkrts \
 159                 target-libatomic \
 160                 target-libitm \
 161                 target-libstdc++-v3 \
 162                 target-libsanitizer \
 163                 target-libvtv \
 164                 target-libssp \
 165                 target-libquadmath \
 166                 target-libgfortran \
 167                 target-boehm-gc \
 168                 ${libgcj} \
 169                 target-libobjc \
 170                 target-libada \
 171                 target-libgo"
 172
 173 # these tools are built using the target libraries, and are intended to
 174 # run only in the target environment
 175 #
 176 # note: any program that *uses* libraries that are in the "target_libraries"
 177 # list belongs in this list.
 178 #
 179 target_tools="target-rda"
 180
 181 ################################################################################
 182
 183 ## All tools belong in one of the four categories, and are assigned above
 184 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 185 ## is important because configure will choke if they ever get through.
 186 ## ${configdirs} is directories we build using the host tools.
 187 ## ${target_configdirs} is directories we build using the target tools.
 188 configdirs=`echo ${host_libs} ${host_tools}`
 189 target_configdirs=`echo ${target_libraries} ${target_tools}`
 190 build_configdirs=`echo ${build_libs} ${build_tools}`
 191
 192 m4_divert_text([PARSE_ARGS],
 193 [case $srcdir in
 194   *" "*)
 195 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 196     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 197 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 198     ;;
 199 esac
 200 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 201 ])
 202
 203 ################################################################################
 204
 205 srcname="gnu development package"
 206
 207 # This gets set non-empty for some net releases of packages.
 208 appdirs=""
 209
 210 # Define is_cross_compiler to save on calls to 'test'.
 211 is_cross_compiler=
 212 if test x"${host}" = x"${target}" ; then
 213   is_cross_compiler=no
 214 else
 215   is_cross_compiler=yes
 216 fi
 217
 218 # Find the build and target subdir names.
 219 GCC_TOPLEV_SUBDIRS
 220 # Be sure to cover against remnants of an in-tree build.
 221 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 222   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 223 Use a pristine source tree when building in a separate tree])
 224 fi
 225
 226 # Skipdirs are removed silently.
 227 skipdirs=
 228 # Noconfigdirs are removed loudly.
 229 noconfigdirs=""
 230
 231 use_gnu_ld=
 232 # Make sure we don't let GNU ld be added if we didn't want it.
 233 if test x$with_gnu_ld = xno ; then
 234   use_gnu_ld=no
 235   noconfigdirs="$noconfigdirs ld gold"
 236 fi
 237
 238 use_gnu_as=
 239 # Make sure we don't let GNU as be added if we didn't want it.
 240 if test x$with_gnu_as = xno ; then
 241   use_gnu_as=no
 242   noconfigdirs="$noconfigdirs gas"
 243 fi
 244
 245 use_included_zlib=
 246 # Make sure we don't let ZLIB be added if we didn't want it.
 247 if test x$with_system_zlib = xyes ; then
 248   use_included_zlib=no
 249   noconfigdirs="$noconfigdirs zlib"
 250 fi
 251
 252 # some tools are so dependent upon X11 that if we're not building with X,
 253 # it's not even worth trying to configure, much less build, that tool.
 254
 255 case ${with_x} in
 256   yes | "") ;; # the default value for this tree is that X11 is available
 257   no)
 258     skipdirs="${skipdirs} tk itcl libgui"
 259     # We won't be able to build gdbtk without X.
 260     enable_gdbtk=no
 261     ;;
 262   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 263 esac
 264
 265 # Some are only suitable for cross toolchains.
 266 # Remove these if host=target.
 267 cross_only="target-libgloss target-newlib target-opcodes"
 268
 269 case $is_cross_compiler in
 270   no) skipdirs="${skipdirs} ${cross_only}" ;;
 271 esac
 272
 273 # If both --with-headers and --with-libs are specified, default to
 274 # --without-newlib.
 275 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 276    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 277   if test x"${with_newlib}" = x ; then
 278     with_newlib=no
 279   fi
 280 fi
 281
 282 # Recognize --with-newlib/--without-newlib.
 283 case ${with_newlib} in
 284   no) skipdirs="${skipdirs} target-newlib" ;;
 285   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 286 esac
 287
 288 AC_ARG_ENABLE(as-accelerator-for,
 289 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 290                 [build as offload target compiler.
 291                 Specify offload host triple by ARG])],
 292 ENABLE_AS_ACCELERATOR_FOR=$enableval,
 293 ENABLE_AS_ACCELERATOR_FOR=no)
 294
 295 AC_ARG_ENABLE(offload-targets,
 296 [AS_HELP_STRING([--enable-offload-targets=LIST],
 297                 [enable offloading to devices from comma-separated LIST of
 298                 TARGET[=DIR]. Use optional path to find offload target compiler
 299                 during the build])],
 300 [
 301   if test x"$enable_offload_targets" = x; then
 302     AC_MSG_ERROR([no offload targets specified])
 303   fi
 304 ], [enable_offload_targets=])
 305
 306 # Handle --enable-gold, --enable-ld.
 307 # --disable-gold [--enable-ld]
 308 #     Build only ld.  Default option.
 309 # --enable-gold [--enable-ld]
 310 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 311 #     as "ld.bfd" and "ld".
 312 # --enable-gold=default [--enable-ld]
 313 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 314 #     install ld as "ld.bfd".
 315 # --enable-gold[=default] --disable-ld
 316 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 317 # --enable-gold --enable-ld=default
 318 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 319 #     and ld.bfd).
 320 #     In other words, ld is default
 321 # --enable-gold=default --enable-ld=default
 322 #     Error.
 323
 324 default_ld=
 325 AC_ARG_ENABLE(gold,
 326 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 327                 [build gold @<:@ARG={default,yes,no}@:>@])],
 328 ENABLE_GOLD=$enableval,
 329 ENABLE_GOLD=no)
 330 case "${ENABLE_GOLD}" in
 331   yes|default)
 332     # Check for ELF target.
 333     is_elf=no
 334     case "${target}" in
 335       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 336       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 337       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 338       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 339         case "${target}" in
 340           *-*-linux*aout* | *-*-linux*oldld*)
 341             ;;
 342           *)
 343             is_elf=yes
 344             ;;
 345         esac
 346     esac
 347
 348     if test "$is_elf" = "yes"; then
 349       # Check for target supported by gold.
 350       case "${target}" in
 351         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 352         | aarch64*-*-* | tilegx*-*-*)
 353           configdirs="$configdirs gold"
 354           if test x${ENABLE_GOLD} = xdefault; then
 355             default_ld=gold
 356           fi
 357           ENABLE_GOLD=yes
 358           ;;
 359       esac
 360     fi
 361     ;;
 362   no)
 363     ;;
 364   *)
 365     AC_MSG_ERROR([invalid --enable-gold argument])
 366     ;;
 367 esac
 368
 369 AC_ARG_ENABLE(ld,
 370 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 371                 [build ld @<:@ARG={default,yes,no}@:>@])],
 372 ENABLE_LD=$enableval,
 373 ENABLE_LD=yes)
 374
 375 case "${ENABLE_LD}" in
 376   default)
 377     if test x${default_ld} != x; then
 378       AC_MSG_ERROR([either gold or ld can be the default ld])
 379     fi
 380     ;;
 381   yes)
 382     ;;
 383   no)
 384     if test x${ENABLE_GOLD} != xyes; then
 385       AC_MSG_WARN([neither ld nor gold are enabled])
 386     fi
 387     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 388     ;;
 389   *)
 390     AC_MSG_ERROR([invalid --enable-ld argument])
 391     ;;
 392 esac
 393
 394 # Configure extra directories which are host specific
 395
 396 case "${host}" in
 397   *-cygwin*)
 398     configdirs="$configdirs libtermcap" ;;
 399 esac
 400
 401 # A target can indicate whether a language isn't supported for some reason.
 402 # Only spaces may be used in this macro; not newlines or tabs.
 403 unsupported_languages=
 404
 405 # Remove more programs from consideration, based on the host or
 406 # target this usually means that a port of the program doesn't
 407 # exist yet.
 408
 409 case "${host}" in
 410   i[[3456789]]86-*-msdosdjgpp*)
 411     noconfigdirs="$noconfigdirs tcl tk itcl"
 412     ;;
 413 esac
 414
 415
 416 AC_ARG_ENABLE(libquadmath,
 417 AS_HELP_STRING([--disable-libquadmath],
 418   [do not build libquadmath directory]),
 419 ENABLE_LIBQUADMATH=$enableval,
 420 ENABLE_LIBQUADMATH=yes)
 421 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 422   noconfigdirs="$noconfigdirs target-libquadmath"
 423 fi
 424
 425
 426 AC_ARG_ENABLE(libquadmath-support,
 427 AS_HELP_STRING([--disable-libquadmath-support],
 428   [disable libquadmath support for Fortran]),
 429 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 430 ENABLE_LIBQUADMATH_SUPPORT=yes)
 431 enable_libquadmath_support=
 432 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 433   enable_libquadmath_support=no
 434 fi
 435
 436
 437 AC_ARG_ENABLE(libada,
 438 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 439 ENABLE_LIBADA=$enableval,
 440 ENABLE_LIBADA=yes)
 441 if test "${ENABLE_LIBADA}" != "yes" ; then
 442   noconfigdirs="$noconfigdirs gnattools"
 443 fi
 444
 445 AC_ARG_ENABLE(libssp,
 446 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 447 ENABLE_LIBSSP=$enableval,
 448 ENABLE_LIBSSP=yes)
 449
 450 AC_ARG_ENABLE(libstdcxx,
 451 AS_HELP_STRING([--disable-libstdcxx],
 452   [do not build libstdc++-v3 directory]),
 453 ENABLE_LIBSTDCXX=$enableval,
 454 ENABLE_LIBSTDCXX=default)
 455 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 456   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 457 fi]
 458
 459 # Save it here so that, even in case of --enable-libgcj, if the Java
 460 # front-end isn't enabled, we still get libgcj disabled.
 461 libgcj_saved=$libgcj
 462 case $enable_libgcj in
 463 yes)
 464   # If we reset it here, it won't get added to noconfigdirs in the
 465   # target-specific build rules, so it will be forcibly enabled
 466   # (unless the Java language itself isn't enabled).
 467   libgcj=
 468   ;;
 469 no)
 470   # Make sure we get it printed in the list of not supported target libs.
 471   # Don't disable libffi, though, other languages use it.
 472   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 473   # Clear libgcj_saved so that even if java is enabled libffi won't be
 474   # built.
 475   libgcj_saved=
 476   ;;
 477 esac
 478
 479 AC_ARG_ENABLE(static-libjava,
 480 [AS_HELP_STRING([[--enable-static-libjava[=ARG]]],
 481                 [build static libjava @<:@default=no@:>@])],
 482 ENABLE_STATIC_LIBJAVA=$enableval,
 483 ENABLE_STATIC_LIBJAVA=no)
 484 enable_static_libjava=
 485 if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then
 486   enable_static_libjava=yes
 487 fi
 488
 489 if test x$enable_static_libjava != xyes ; then
 490   EXTRA_CONFIGARGS_LIBJAVA=--disable-static
 491 fi
 492 AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA)
 493
 494 # Disable libgomp on non POSIX hosted systems.
 495 if test x$enable_libgomp = x ; then
 496     # Enable libgomp by default on hosted POSIX systems.
 497     case "${target}" in
 498     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 499         ;;
 500     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 501         ;;
 502     *-*-solaris2* | *-*-hpux11*)
 503         ;;
 504     *-*-darwin* | *-*-aix*)
 505         ;;
 506     *)
 507         noconfigdirs="$noconfigdirs target-libgomp"
 508         ;;
 509     esac
 510 fi
 511
 512 # Disable libatomic on unsupported systems.
 513 if test -d ${srcdir}/libatomic; then
 514     if test x$enable_libatomic = x; then
 515         AC_MSG_CHECKING([for libatomic support])
 516         if (srcdir=${srcdir}/libatomic; \
 517                 . ${srcdir}/configure.tgt; \
 518                 test -n "$UNSUPPORTED")
 519         then
 520             AC_MSG_RESULT([no])
 521             noconfigdirs="$noconfigdirs target-libatomic"
 522         else
 523             AC_MSG_RESULT([yes])
 524         fi
 525     fi
 526 fi
 527
 528 # Disable libcilkrts on unsupported systems.
 529 if test -d ${srcdir}/libcilkrts; then
 530     if test x$enable_libcilkrts = x; then
 531         AC_MSG_CHECKING([for libcilkrts support])
 532         if (srcdir=${srcdir}/libcilkrts; \
 533                 . ${srcdir}/configure.tgt; \
 534                 test -n "$UNSUPPORTED")
 535         then
 536             AC_MSG_RESULT([no])
 537             noconfigdirs="$noconfigdirs target-libcilkrts"
 538         else
 539             AC_MSG_RESULT([yes])
 540         fi
 541     fi
 542 fi
 543
 544 # Disable libitm on unsupported systems.
 545 if test -d ${srcdir}/libitm; then
 546     if test x$enable_libitm = x; then
 547         AC_MSG_CHECKING([for libitm support])
 548         if (srcdir=${srcdir}/libitm; \
 549                 . ${srcdir}/configure.tgt; \
 550                 test -n "$UNSUPPORTED")
 551         then
 552             AC_MSG_RESULT([no])
 553             noconfigdirs="$noconfigdirs target-libitm"
 554         else
 555             AC_MSG_RESULT([yes])
 556         fi
 557     fi
 558 fi
 559
 560 # Disable libsanitizer on unsupported systems.
 561 if test -d ${srcdir}/libsanitizer; then
 562     if test x$enable_libsanitizer = x; then
 563         AC_MSG_CHECKING([for libsanitizer support])
 564         if (srcdir=${srcdir}/libsanitizer; \
 565                 . ${srcdir}/configure.tgt; \
 566                 test -n "$UNSUPPORTED")
 567         then
 568             AC_MSG_RESULT([no])
 569             noconfigdirs="$noconfigdirs target-libsanitizer"
 570         else
 571             AC_MSG_RESULT([yes])
 572         fi
 573     fi
 574 fi
 575
 576 # Disable libvtv on unsupported systems.
 577 if test -d ${srcdir}/libvtv; then
 578     if test x$enable_libvtv = x; then
 579         AC_MSG_CHECKING([for libvtv support])
 580         if (srcdir=${srcdir}/libvtv; \
 581                 . ${srcdir}/configure.tgt; \
 582                 test "$VTV_SUPPORTED" != "yes")
 583         then
 584             AC_MSG_RESULT([no])
 585             noconfigdirs="$noconfigdirs target-libvtv"
 586         else
 587             AC_MSG_RESULT([yes])
 588         fi
 589     fi
 590 fi
 591
 592 # Disable libquadmath for some systems.
 593 case "${target}" in
 594   avr-*-*)
 595     noconfigdirs="$noconfigdirs target-libquadmath"
 596     ;;
 597   # libquadmath is unused on AIX and libquadmath build process use of
 598   # LD_LIBRARY_PATH can break AIX bootstrap.
 599   powerpc-*-aix* | rs6000-*-aix*)
 600     noconfigdirs="$noconfigdirs target-libquadmath"
 601     ;;
 602 esac
 603
 604 # Disable libssp for some systems.
 605 case "${target}" in
 606   avr-*-*)
 607     # No hosted I/O support.
 608     noconfigdirs="$noconfigdirs target-libssp"
 609     ;;
 610   powerpc-*-aix* | rs6000-*-aix*)
 611     noconfigdirs="$noconfigdirs target-libssp"
 612     ;;
 613   rl78-*-*)
 614     # libssp uses a misaligned load to trigger a fault, but the RL78
 615     # doesn't fault for those - instead, it gives a build-time error
 616     # for explicit misaligned loads.
 617     noconfigdirs="$noconfigdirs target-libssp"
 618     ;;
 619 esac
 620
 621 # Disable libstdc++-v3 for some systems.
 622 # Allow user to override this if they pass --enable-libstdc++-v3
 623 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 624   case "${target}" in
 625     *-*-vxworks*)
 626       # VxWorks uses the Dinkumware C++ library.
 627       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 628       ;;
 629     arm*-wince-pe*)
 630       # the C++ libraries don't build on top of CE's C libraries
 631       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 632       ;;
 633     avr-*-*)
 634       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 635       ;;
 636   esac
 637 fi
 638
 639 # Disable Fortran for some systems.
 640 case "${target}" in
 641   mmix-*-*)
 642     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 643     unsupported_languages="$unsupported_languages fortran"
 644     ;;
 645 esac
 646
 647 # Disable Java if libffi is not supported.
 648 case "${target}" in
 649   aarch64-*-*)
 650     ;;
 651   alpha*-*-*)
 652     ;;
 653   arm*-*-*)
 654     ;;
 655   cris-*-*)
 656     ;;
 657   frv-*-*)
 658     ;;
 659   hppa*-*-linux*)
 660     ;;
 661   hppa*-*-hpux*)
 662     ;;
 663   i?86-*-*)
 664     ;;
 665   ia64*-*-*)
 666     ;;
 667   m32r*-*-*)
 668     ;;
 669   m68k-*-*)
 670     ;;
 671   mips*-*-rtems*)
 672     ;;
 673   mips*-*-linux*)
 674     ;;
 675   powerpc*-*-linux*)
 676     ;;
 677   powerpc-*-darwin*)
 678     ;;
 679   powerpc-*-aix* | rs6000-*-aix*)
 680     ;;
 681   powerpc-*-freebsd*)
 682     ;;
 683   powerpc64-*-freebsd*)
 684     ;;
 685   powerpc*-*-rtems*)
 686     ;;
 687   s390-*-* | s390x-*-*)
 688     ;;
 689   sh-*-* | sh[[34]]*-*-*)
 690     ;;
 691   sh64-*-* | sh5*-*-*)
 692     ;;
 693   sparc*-*-*)
 694     ;;
 695   x86_64-*-*)
 696     ;;
 697   *-*-*)
 698     unsupported_languages="$unsupported_languages java"
 699     ;;
 700 esac
 701
 702 # Disable Java, libgcj or related libraries for some systems.
 703 case "${target}" in
 704   powerpc-*-darwin*)
 705     ;;
 706   i[[3456789]]86-*-darwin*)
 707     ;;
 708   x86_64-*-darwin[[912]]*)
 709     ;;
 710   *-*-darwin*)
 711     noconfigdirs="$noconfigdirs ${libgcj}"
 712     ;;
 713   *-*-netware*)
 714     noconfigdirs="$noconfigdirs ${libgcj}"
 715     ;;
 716   *-*-rtems*)
 717     noconfigdirs="$noconfigdirs ${libgcj}"
 718     ;;
 719   *-*-tpf*)
 720     noconfigdirs="$noconfigdirs ${libgcj}"
 721     ;;
 722   *-*-uclinux*)
 723     noconfigdirs="$noconfigdirs ${libgcj}"
 724     ;;
 725   *-*-vxworks*)
 726     noconfigdirs="$noconfigdirs ${libgcj}"
 727     ;;
 728   alpha*-*-*vms*)
 729     noconfigdirs="$noconfigdirs ${libgcj}"
 730     ;;
 731   arm-wince-pe)
 732     noconfigdirs="$noconfigdirs ${libgcj}"
 733     ;;
 734   arm*-*-symbianelf*)
 735     noconfigdirs="$noconfigdirs ${libgcj}"
 736     ;;
 737   bfin-*-*)
 738     noconfigdirs="$noconfigdirs target-boehm-gc"
 739     ;;
 740   cris-*-* | crisv32-*-*)
 741     unsupported_languages="$unsupported_languages java"
 742     case "${target}" in
 743       *-*-linux*)
 744         ;;
 745       *) # See PR46792 regarding target-libffi.
 746         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 747     esac
 748     ;;
 749   hppa*64*-*-linux*)
 750     # In this case, it's because the hppa64-linux target is for
 751     # the kernel only at this point and has no libc, and thus no
 752     # headers, crt*.o, etc., all of which are needed by these.
 753     unsupported_languages="$unsupported_languages java"
 754     ;;
 755   hppa*64*-*-hpux*)
 756     noconfigdirs="$noconfigdirs ${libgcj}"
 757     ;;
 758   hppa*-hp-hpux11*)
 759     ;;
 760   hppa*-*-hpux*)
 761     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 762     # build on HP-UX 10.20.
 763     noconfigdirs="$noconfigdirs ${libgcj}"
 764     ;;
 765   ia64*-*-*vms*)
 766     noconfigdirs="$noconfigdirs ${libgcj}"
 767     ;;
 768   i[[3456789]]86-w64-mingw*)
 769     noconfigdirs="$noconfigdirs ${libgcj}"
 770     ;;
 771   i[[3456789]]86-*-mingw*)
 772     noconfigdirs="$noconfigdirs ${libgcj}"
 773     ;;
 774   x86_64-*-mingw*)
 775     noconfigdirs="$noconfigdirs ${libgcj}"
 776     ;;
 777   mmix-*-*)
 778     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 779     ;;
 780   powerpc-*-aix*)
 781     # copied from rs6000-*-* entry
 782     noconfigdirs="$noconfigdirs ${libgcj}"
 783     ;;
 784   rs6000-*-aix*)
 785     noconfigdirs="$noconfigdirs ${libgcj}"
 786     ;;
 787   *-*-lynxos*)
 788     noconfigdirs="$noconfigdirs ${libgcj}"
 789     ;;
 790 esac
 791
 792 # Disable the go frontend on systems where it is known to not work. Please keep
 793 # this in sync with contrib/config-list.mk.
 794 case "${target}" in
 795 *-*-darwin* | *-*-cygwin* | *-*-mingw* | *-*-aix*)
 796     unsupported_languages="$unsupported_languages go"
 797     ;;
 798 esac
 799
 800 # Disable libgo for some systems where it is known to not work.
 801 # For testing, you can easily override this with --enable-libgo.
 802 if test x$enable_libgo = x; then
 803     case "${target}" in
 804     *-*-darwin*)
 805         # PR 46986
 806         noconfigdirs="$noconfigdirs target-libgo"
 807         ;;
 808     *-*-cygwin* | *-*-mingw*)
 809         noconfigdirs="$noconfigdirs target-libgo"
 810         ;;
 811     *-*-aix*)
 812         noconfigdirs="$noconfigdirs target-libgo"
 813         ;;
 814     esac
 815 fi
 816
 817 # Default libgloss CPU subdirectory.
 818 libgloss_dir="$target_cpu"
 819
 820 case "${target}" in
 821   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 822     libgloss_dir=wince
 823     ;;
 824   aarch64*-*-* )
 825     libgloss_dir=aarch64
 826     ;;
 827   arm*-*-*)
 828     libgloss_dir=arm
 829     ;;
 830   cris-*-* | crisv32-*-*)
 831     libgloss_dir=cris
 832     ;;
 833   hppa*-*-*)
 834     libgloss_dir=pa
 835     ;;
 836   i[[3456789]]86-*-*)
 837     libgloss_dir=i386
 838     ;;
 839   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 840     libgloss_dir=m68hc11
 841     ;;
 842   m68*-*-* | fido-*-*)
 843     libgloss_dir=m68k
 844     ;;
 845   mips*-*-*)
 846     libgloss_dir=mips
 847     ;;
 848   powerpc*-*-*)
 849     libgloss_dir=rs6000
 850     ;;
 851   sparc*-*-*)
 852     libgloss_dir=sparc
 853     ;;
 854 esac
 855
 856 # Disable newlib and libgloss for various target OSes.
 857 case "${target}" in
 858   alpha*-dec-osf*)
 859     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 860     ;;
 861   i[[3456789]]86-*-linux*)
 862     # This section makes it possible to build newlib natively on linux.
 863     # If we are using a cross compiler then don't configure newlib.
 864     if test x${is_cross_compiler} != xno ; then
 865       noconfigdirs="$noconfigdirs target-newlib"
 866     fi
 867     noconfigdirs="$noconfigdirs target-libgloss"
 868     # If we are not using a cross compiler, do configure newlib.
 869     # Note however, that newlib will only be configured in this situation
 870     # if the --with-newlib option has been given, because otherwise
 871     # 'target-newlib' will appear in skipdirs.
 872     ;;
 873   i[[3456789]]86-*-rdos*)
 874     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 875     ;;
 876   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 877     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 878     ;;
 879   sparc-*-sunos4*)
 880     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 881     ;;
 882   *-*-aix*)
 883     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 884     ;;
 885   *-*-beos*)
 886     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 887     ;;
 888   *-*-chorusos)
 889     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 890     ;;
 891   *-*-dragonfly*)
 892     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 893     ;;
 894   *-*-freebsd*)
 895     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 896     ;;
 897   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 898     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 899     ;;
 900   *-*-lynxos*)
 901     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 902     ;;
 903   *-*-mingw*)
 904     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 905     ;;
 906   *-*-netbsd*)
 907     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 908     ;;
 909   *-*-netware*)
 910     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 911     ;;
 912   *-*-tpf*)
 913     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 914     ;;
 915   *-*-uclinux*)
 916     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 917     ;;
 918   *-*-vxworks*)
 919     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 920     ;;
 921 esac
 922
 923 case "${target}" in
 924   *-*-chorusos)
 925     ;;
 926   powerpc-*-darwin*)
 927     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 928     noconfigdirs="$noconfigdirs sim target-rda"
 929     ;;
 930   i[[3456789]]86-*-darwin*)
 931     noconfigdirs="$noconfigdirs ld gprof"
 932     noconfigdirs="$noconfigdirs sim target-rda"
 933     ;;
 934   x86_64-*-darwin[[912]]*)
 935     noconfigdirs="$noconfigdirs ld gas gprof"
 936     noconfigdirs="$noconfigdirs sim target-rda"
 937     ;;
 938   *-*-darwin*)
 939     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 940     noconfigdirs="$noconfigdirs sim target-rda"
 941     ;;
 942   *-*-dragonfly*)
 943     ;;
 944   *-*-freebsd*)
 945     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 946         && test -f /usr/local/include/gmp.h; then
 947       with_gmp=/usr/local
 948     fi
 949     ;;
 950   *-*-kaos*)
 951     # Remove unsupported stuff on all kaOS configurations.
 952     noconfigdirs="$noconfigdirs target-libgloss"
 953     ;;
 954   *-*-netbsd*)
 955     ;;
 956   *-*-netware*)
 957     ;;
 958   *-*-rtems*)
 959     noconfigdirs="$noconfigdirs target-libgloss"
 960     ;;
 961     # The tpf target doesn't support gdb yet.
 962   *-*-tpf*)
 963     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 964     ;;
 965   *-*-uclinux*)
 966     noconfigdirs="$noconfigdirs target-rda"
 967     ;;
 968   *-*-vxworks*)
 969     ;;
 970   alpha*-dec-osf*)
 971     # ld works, but does not support shared libraries.
 972     # gas doesn't generate exception information.
 973     noconfigdirs="$noconfigdirs gas ld"
 974     ;;
 975   alpha*-*-*vms*)
 976     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 977     ;;
 978   alpha*-*-*)
 979     # newlib is not 64 bit ready
 980     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 981     ;;
 982   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 983     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 984     ;;
 985   arc-*-*|arceb-*-*)
 986     noconfigdirs="$noconfigdirs target-libgloss"
 987     ;;
 988   arm-*-pe*)
 989     noconfigdirs="$noconfigdirs target-libgloss"
 990     ;;
 991   arm-*-riscix*)
 992     noconfigdirs="$noconfigdirs ld target-libgloss"
 993     ;;
 994   avr-*-rtems*)
 995     ;;
 996   avr-*-*)
 997     if test x${with_avrlibc} != xno; then
 998       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 999     fi
1000     ;;
1001   c4x-*-* | tic4x-*-*)
1002     noconfigdirs="$noconfigdirs target-libgloss"
1003     ;;
1004   tic54x-*-*)
1005     noconfigdirs="$noconfigdirs target-libgloss gdb"
1006     ;;
1007   d10v-*-*)
1008     noconfigdirs="$noconfigdirs target-libgloss"
1009     ;;
1010   d30v-*-*)
1011     noconfigdirs="$noconfigdirs gdb"
1012     ;;
1013   fr30-*-elf*)
1014     noconfigdirs="$noconfigdirs gdb"
1015     ;;
1016   moxie-*-*)
1017     noconfigdirs="$noconfigdirs gprof"
1018     ;;
1019   h8300*-*-*)
1020     noconfigdirs="$noconfigdirs target-libgloss"
1021     ;;
1022   h8500-*-*)
1023     noconfigdirs="$noconfigdirs target-libgloss"
1024     ;;
1025   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1026     ;;
1027   hppa*64*-*-linux*)
1028     ;;
1029   hppa*-*-linux*)
1030     ;;
1031   hppa*-*-*elf* | \
1032   hppa*-*-lites* | \
1033   hppa*-*-openbsd* | \
1034   hppa*64*-*-*)
1035     ;;
1036   hppa*-hp-hpux11*)
1037     noconfigdirs="$noconfigdirs ld"
1038     ;;
1039   hppa*-*-pro*)
1040     ;;
1041   hppa*-*-*)
1042     noconfigdirs="$noconfigdirs ld"
1043     ;;
1044   i960-*-*)
1045     noconfigdirs="$noconfigdirs gdb"
1046     ;;
1047   ia64*-*-elf*)
1048     # No gdb support yet.
1049     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1050     ;;
1051   ia64*-**-hpux*)
1052     # No ld support yet.
1053     noconfigdirs="$noconfigdirs libgui itcl ld"
1054     ;;
1055   ia64*-*-*vms*)
1056     # No ld support yet.
1057     noconfigdirs="$noconfigdirs libgui itcl ld"
1058     ;;
1059   i[[3456789]]86-w64-mingw*)
1060     ;;
1061   i[[3456789]]86-*-mingw*)
1062     target_configdirs="$target_configdirs target-winsup"
1063     ;;
1064   *-*-cygwin*)
1065     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1066     noconfigdirs="$noconfigdirs target-libgloss"
1067     # always build newlib if winsup directory is present.
1068     if test -d "$srcdir/winsup/cygwin"; then
1069       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1070     elif test -d "$srcdir/newlib"; then
1071       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1072     fi
1073     ;;
1074   i[[3456789]]86-*-pe)
1075     noconfigdirs="$noconfigdirs target-libgloss"
1076     ;;
1077   i[[3456789]]86-*-sco3.2v5*)
1078     # The linker does not yet know about weak symbols in COFF,
1079     # and is not configured to handle mixed ELF and COFF.
1080     noconfigdirs="$noconfigdirs ld target-libgloss"
1081     ;;
1082   i[[3456789]]86-*-sco*)
1083     noconfigdirs="$noconfigdirs gprof target-libgloss"
1084     ;;
1085   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1086     noconfigdirs="$noconfigdirs target-libgloss"
1087     ;;
1088   i[[3456789]]86-*-sysv4*)
1089     noconfigdirs="$noconfigdirs target-libgloss"
1090     ;;
1091   i[[3456789]]86-*-beos*)
1092     noconfigdirs="$noconfigdirs gdb"
1093     ;;
1094   i[[3456789]]86-*-rdos*)
1095     noconfigdirs="$noconfigdirs gdb"
1096     ;;
1097   mmix-*-*)
1098     noconfigdirs="$noconfigdirs gdb"
1099     ;;
1100   mt-*-*)
1101     noconfigdirs="$noconfigdirs sim"
1102     ;;
1103   powerpc-*-aix*)
1104     # copied from rs6000-*-* entry
1105     noconfigdirs="$noconfigdirs gprof"
1106     ;;
1107   powerpc*-*-winnt* | powerpc*-*-pe*)
1108     target_configdirs="$target_configdirs target-winsup"
1109     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1110     # always build newlib.
1111     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1112     ;;
1113     # This is temporary until we can link against shared libraries
1114   powerpcle-*-solaris*)
1115     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1116     ;;
1117   powerpc-*-beos*)
1118     noconfigdirs="$noconfigdirs gdb"
1119     ;;
1120   rs6000-*-lynxos*)
1121     noconfigdirs="$noconfigdirs gprof"
1122     ;;
1123   rs6000-*-aix*)
1124     noconfigdirs="$noconfigdirs gprof"
1125     ;;
1126   rs6000-*-*)
1127     noconfigdirs="$noconfigdirs gprof"
1128     ;;
1129   m68k-apollo-*)
1130     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1131     ;;
1132   microblaze*)
1133     noconfigdirs="$noconfigdirs gprof"
1134     ;;
1135   mips*-sde-elf* | mips*-mti-elf*)
1136     if test x$with_newlib = xyes; then
1137       noconfigdirs="$noconfigdirs gprof"
1138     fi
1139     ;;
1140   mips*-*-irix5*)
1141     noconfigdirs="$noconfigdirs gprof target-libgloss"
1142     ;;
1143   mips*-*-irix6*)
1144     noconfigdirs="$noconfigdirs gprof target-libgloss"
1145     ;;
1146   mips*-*-bsd*)
1147     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1148     ;;
1149   mips*-*-linux*)
1150     ;;
1151   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1152   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1153     noconfigdirs="$noconfigdirs ld gas gprof"
1154     ;;
1155   mips*-*-*)
1156     noconfigdirs="$noconfigdirs gprof"
1157     ;;
1158   nvptx*-*-*)
1159     # nvptx is just a compiler
1160     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1161     ;;
1162   sh-*-* | sh64-*-*)
1163     case "${target}" in
1164       sh*-*-elf)
1165          ;;
1166       *)
1167          noconfigdirs="$noconfigdirs target-libgloss" ;;
1168     esac
1169     ;;
1170   sparc-*-sunos4*)
1171     if test x${is_cross_compiler} = xno ; then
1172            use_gnu_ld=no
1173     fi
1174     ;;
1175   tic6x-*-*)
1176     noconfigdirs="$noconfigdirs sim"
1177     ;;
1178   tilepro*-*-* | tilegx*-*-*)
1179     noconfigdirs="$noconfigdirs sim"
1180     ;;
1181   v810-*-*)
1182     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1183     ;;
1184   vax-*-*)
1185     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1186     ;;
1187 esac
1188
1189 # If we aren't building newlib, then don't build libgloss, since libgloss
1190 # depends upon some newlib header files.
1191 case "${noconfigdirs}" in
1192   *target-libgloss*) ;;
1193   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1194 esac
1195
1196 # Work in distributions that contain no compiler tools, like Autoconf.
1197 host_makefile_frag=/dev/null
1198 if test -d ${srcdir}/config ; then
1199 case "${host}" in
1200   i[[3456789]]86-*-msdosdjgpp*)
1201     host_makefile_frag="config/mh-djgpp"
1202     ;;
1203   *-cygwin*)
1204     ACX_CHECK_CYGWIN_CAT_WORKS
1205     host_makefile_frag="config/mh-cygwin"
1206     ;;
1207   *-mingw*)
1208     host_makefile_frag="config/mh-mingw"
1209     ;;
1210   alpha*-*-linux*)
1211     host_makefile_frag="config/mh-alpha-linux"
1212     ;;
1213   hppa*-hp-hpux10*)
1214     host_makefile_frag="config/mh-pa-hpux10"
1215     ;;
1216   hppa*-hp-hpux*)
1217     host_makefile_frag="config/mh-pa"
1218     ;;
1219   hppa*-*)
1220     host_makefile_frag="config/mh-pa"
1221     ;;
1222   *-*-darwin*)
1223     host_makefile_frag="config/mh-darwin"
1224     ;;
1225   powerpc-*-aix*)
1226     host_makefile_frag="config/mh-ppc-aix"
1227     ;;
1228   rs6000-*-aix*)
1229     host_makefile_frag="config/mh-ppc-aix"
1230     ;;
1231 esac
1232 fi
1233
1234 if test "${build}" != "${host}" ; then
1235   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1236   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1237   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1238   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1239   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1240   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1241   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1242   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1243   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1244   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1245   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1246   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1247   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1248 else
1249   AR_FOR_BUILD="\$(AR)"
1250   AS_FOR_BUILD="\$(AS)"
1251   CC_FOR_BUILD="\$(CC)"
1252   CXX_FOR_BUILD="\$(CXX)"
1253   GCJ_FOR_BUILD="\$(GCJ)"
1254   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1255   GOC_FOR_BUILD="\$(GOC)"
1256   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1257   LD_FOR_BUILD="\$(LD)"
1258   NM_FOR_BUILD="\$(NM)"
1259   RANLIB_FOR_BUILD="\$(RANLIB)"
1260   WINDRES_FOR_BUILD="\$(WINDRES)"
1261   WINDMC_FOR_BUILD="\$(WINDMC)"
1262 fi
1263
1264 AC_PROG_CC
1265 AC_PROG_CXX
1266
1267 # We must set the default linker to the linker used by gcc for the correct
1268 # operation of libtool.  If LD is not defined and we are using gcc, try to
1269 # set the LD default to the ld used by gcc.
1270 if test -z "$LD"; then
1271   if test "$GCC" = yes; then
1272     case $build in
1273     *-*-mingw*)
1274       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1275     *)
1276       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1277     esac
1278     case $gcc_prog_ld in
1279     # Accept absolute paths.
1280     [[\\/]* | [A-Za-z]:[\\/]*)]
1281       LD="$gcc_prog_ld" ;;
1282     esac
1283   fi
1284 fi
1285
1286 # Check whether -static-libstdc++ -static-libgcc is supported.
1287 have_static_libs=no
1288 if test "$GCC" = yes; then
1289   saved_LDFLAGS="$LDFLAGS"
1290
1291   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1292   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1293   AC_LANG_PUSH(C++)
1294   AC_LINK_IFELSE([
1295 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1296 #error -static-libstdc++ not implemented
1297 #endif
1298 int main() {}],
1299     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1300     [AC_MSG_RESULT([no])])
1301   AC_LANG_POP(C++)
1302
1303   LDFLAGS="$saved_LDFLAGS"
1304 fi
1305
1306 ACX_PROG_GNAT
1307 ACX_PROG_CMP_IGNORE_INITIAL
1308
1309 AC_ARG_ENABLE([bootstrap],
1310 [AS_HELP_STRING([--enable-bootstrap],
1311                 [enable bootstrapping @<:@yes if native build@:>@])],,
1312 enable_bootstrap=default)
1313
1314 # Issue errors and warnings for invalid/strange bootstrap combinations.
1315 if test -r $srcdir/gcc/configure; then
1316   have_compiler=yes
1317 else
1318   have_compiler=no
1319 fi
1320
1321 case "$have_compiler:$host:$target:$enable_bootstrap" in
1322   *:*:*:no) ;;
1323
1324   # Default behavior.  Enable bootstrap if we have a compiler
1325   # and we are in a native configuration.
1326   yes:$build:$build:default)
1327     enable_bootstrap=yes ;;
1328
1329   *:*:*:default)
1330     enable_bootstrap=no ;;
1331
1332   # We have a compiler and we are in a native configuration, bootstrap is ok
1333   yes:$build:$build:yes)
1334     ;;
1335
1336   # Other configurations, but we have a compiler.  Assume the user knows
1337   # what he's doing.
1338   yes:*:*:yes)
1339     AC_MSG_WARN([trying to bootstrap a cross compiler])
1340     ;;
1341
1342   # No compiler: if they passed --enable-bootstrap explicitly, fail
1343   no:*:*:yes)
1344     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1345
1346   # Fail if wrong command line
1347   *)
1348     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1349     ;;
1350 esac
1351
1352 # Used for setting $lt_cv_objdir
1353 _LT_CHECK_OBJDIR
1354
1355 # Check for GMP, MPFR and MPC
1356 gmplibs="-lmpc -lmpfr -lgmp"
1357 gmpinc=
1358 have_gmp=no
1359
1360 # Specify a location for mpc
1361 # check for this first so it ends up on the link line before mpfr.
1362 AC_ARG_WITH(mpc,
1363 [AS_HELP_STRING([--with-mpc=PATH],
1364                 [specify prefix directory for installed MPC package.
1365                  Equivalent to --with-mpc-include=PATH/include
1366                  plus --with-mpc-lib=PATH/lib])])
1367 AC_ARG_WITH(mpc-include,
1368 [AS_HELP_STRING([--with-mpc-include=PATH],
1369                 [specify directory for installed MPC include files])])
1370 AC_ARG_WITH(mpc-lib,
1371 [AS_HELP_STRING([--with-mpc-lib=PATH],
1372                 [specify directory for the installed MPC library])])
1373
1374 if test "x$with_mpc" != x; then
1375   gmplibs="-L$with_mpc/lib $gmplibs"
1376   gmpinc="-I$with_mpc/include $gmpinc"
1377 fi
1378 if test "x$with_mpc_include" != x; then
1379   gmpinc="-I$with_mpc_include $gmpinc"
1380 fi
1381 if test "x$with_mpc_lib" != x; then
1382   gmplibs="-L$with_mpc_lib $gmplibs"
1383 fi
1384 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1385   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1386   gmpinc='-I$$s/mpc/src '"$gmpinc"
1387   # Do not test the mpc version.  Assume that it is sufficient, since
1388   # it is in the source tree, and the library has not been built yet
1389   # but it would be included on the link line in the version check below
1390   # hence making the test fail.
1391   have_gmp=yes
1392 fi
1393
1394 # Specify a location for mpfr
1395 # check for this first so it ends up on the link line before gmp.
1396 AC_ARG_WITH(mpfr-dir,
1397 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1398 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1399 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1400
1401 AC_ARG_WITH(mpfr,
1402 [AS_HELP_STRING([--with-mpfr=PATH],
1403                 [specify prefix directory for installed MPFR package.
1404                  Equivalent to --with-mpfr-include=PATH/include
1405                  plus --with-mpfr-lib=PATH/lib])])
1406 AC_ARG_WITH(mpfr-include,
1407 [AS_HELP_STRING([--with-mpfr-include=PATH],
1408                 [specify directory for installed MPFR include files])])
1409 AC_ARG_WITH(mpfr-lib,
1410 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1411                 [specify directory for the installed MPFR library])])
1412
1413 if test "x$with_mpfr" != x; then
1414   gmplibs="-L$with_mpfr/lib $gmplibs"
1415   gmpinc="-I$with_mpfr/include $gmpinc"
1416 fi
1417 if test "x$with_mpfr_include" != x; then
1418   gmpinc="-I$with_mpfr_include $gmpinc"
1419 fi
1420 if test "x$with_mpfr_lib" != x; then
1421   gmplibs="-L$with_mpfr_lib $gmplibs"
1422 fi
1423 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1424   # MPFR v3.1.0 moved the sources into a src sub-directory.
1425   if test -d ${srcdir}/mpfr/src; then
1426     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1427     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1428     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1429   else
1430     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1431     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1432     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1433   fi
1434   # Do not test the mpfr version.  Assume that it is sufficient, since
1435   # it is in the source tree, and the library has not been built yet
1436   # but it would be included on the link line in the version check below
1437   # hence making the test fail.
1438   have_gmp=yes
1439 fi
1440
1441 # Specify a location for gmp
1442 AC_ARG_WITH(gmp-dir,
1443 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1444 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1445 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1446
1447 AC_ARG_WITH(gmp,
1448 [AS_HELP_STRING([--with-gmp=PATH],
1449                 [specify prefix directory for the installed GMP package.
1450                  Equivalent to --with-gmp-include=PATH/include
1451                  plus --with-gmp-lib=PATH/lib])])
1452 AC_ARG_WITH(gmp-include,
1453 [AS_HELP_STRING([--with-gmp-include=PATH],
1454                 [specify directory for installed GMP include files])])
1455 AC_ARG_WITH(gmp-lib,
1456 [AS_HELP_STRING([--with-gmp-lib=PATH],
1457                 [specify directory for the installed GMP library])])
1458
1459
1460 if test "x$with_gmp" != x; then
1461   gmplibs="-L$with_gmp/lib $gmplibs"
1462   gmpinc="-I$with_gmp/include $gmpinc"
1463 fi
1464 if test "x$with_gmp_include" != x; then
1465   gmpinc="-I$with_gmp_include $gmpinc"
1466 fi
1467 if test "x$with_gmp_lib" != x; then
1468   gmplibs="-L$with_gmp_lib $gmplibs"
1469 fi
1470 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1471   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1472   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1473   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1474   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1475   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1476   # Do not test the gmp version.  Assume that it is sufficient, since
1477   # it is in the source tree, and the library has not been built yet
1478   # but it would be included on the link line in the version check below
1479   # hence making the test fail.
1480   have_gmp=yes
1481 fi
1482
1483 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1484   have_gmp=yes
1485   saved_CFLAGS="$CFLAGS"
1486   CFLAGS="$CFLAGS $gmpinc"
1487   # Check for the recommended and required versions of GMP.
1488   AC_MSG_CHECKING([for the correct version of gmp.h])
1489   AC_TRY_COMPILE([#include "gmp.h"],[
1490   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1491   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1492   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1493   choke me
1494   #endif
1495   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1496   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1497   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1498   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1499   choke me
1500   #endif
1501   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1502    [AC_MSG_RESULT([no]); have_gmp=no])
1503
1504   # If we have GMP, check the MPFR version.
1505   if test x"$have_gmp" = xyes; then
1506     # Check for the recommended and required versions of MPFR.
1507     AC_MSG_CHECKING([for the correct version of mpfr.h])
1508     AC_TRY_COMPILE([#include <gmp.h>
1509     #include <mpfr.h>],[
1510     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1511     choke me
1512     #endif
1513     ], [AC_TRY_COMPILE([#include <gmp.h>
1514     #include <mpfr.h>],[
1515     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1516     choke me
1517     #endif
1518     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1519      [AC_MSG_RESULT([no]); have_gmp=no])
1520   fi
1521
1522   # Check for the MPC header version.
1523   if test x"$have_gmp" = xyes ; then
1524     # Check for the recommended and required versions of MPC.
1525     AC_MSG_CHECKING([for the correct version of mpc.h])
1526     AC_TRY_COMPILE([#include <mpc.h>],[
1527     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1528     choke me
1529     #endif
1530     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1531     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1532     choke me
1533     #endif
1534     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1535      [AC_MSG_RESULT([no]); have_gmp=no])
1536   fi
1537
1538   # Now check the MPFR library.
1539   if test x"$have_gmp" = xyes; then
1540     saved_LIBS="$LIBS"
1541     LIBS="$LIBS $gmplibs"
1542     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1543     AC_TRY_LINK([#include <mpc.h>],[
1544     mpfr_t n;
1545     mpfr_t x;
1546     mpc_t c;
1547     int t;
1548     mpfr_init (n);
1549     mpfr_init (x);
1550     mpfr_atan2 (n, n, x, GMP_RNDN);
1551     mpfr_erfc (n, x, GMP_RNDN);
1552     mpfr_subnormalize (x, t, GMP_RNDN);
1553     mpfr_clear(n);
1554     mpfr_clear(x);
1555     mpc_init2 (c, 53);
1556     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1557     mpc_cosh (c, c, MPC_RNDNN);
1558     mpc_pow (c, c, c, MPC_RNDNN);
1559     mpc_acosh (c, c, MPC_RNDNN);
1560     mpc_clear (c);
1561     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1562     LIBS="$saved_LIBS"
1563   fi
1564
1565   CFLAGS="$saved_CFLAGS"
1566
1567 # The library versions listed in the error message below should match
1568 # the HARD-minimums enforced above.
1569   if test x$have_gmp != xyes; then
1570     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1571 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1572 their locations.  Source code for these libraries can be found at
1573 their respective hosting sites as well as at
1574 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1575 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1576 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1577 make sure that you have installed both the libraries and the header
1578 files.  They may be located in separate packages.])
1579   fi
1580 fi
1581
1582 # Flags needed for both GMP, MPFR and/or MPC.
1583 AC_SUBST(gmplibs)
1584 AC_SUBST(gmpinc)
1585 AC_SUBST(extra_mpfr_configure_flags)
1586 AC_SUBST(extra_mpc_gmp_configure_flags)
1587 AC_SUBST(extra_mpc_mpfr_configure_flags)
1588 AC_SUBST(extra_isl_gmp_configure_flags)
1589
1590 # Allow host libstdc++ to be specified for static linking with PPL.
1591 AC_ARG_WITH(host-libstdcxx,
1592 [AS_HELP_STRING([--with-host-libstdcxx=L],
1593                 [use linker arguments L to link with libstdc++
1594                  when linking with PPL])])
1595
1596 case $with_host_libstdcxx in
1597   no|yes)
1598     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1599     ;;
1600 esac
1601
1602 # Libraries to use for stage1 or when not bootstrapping.
1603 AC_ARG_WITH(stage1-libs,
1604 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1605 [if test "$withval" = "no" -o "$withval" = "yes"; then
1606    stage1_libs=
1607  else
1608    stage1_libs=$withval
1609  fi],
1610 [stage1_libs=$with_host_libstdcxx])
1611 AC_SUBST(stage1_libs)
1612
1613 # Linker flags to use for stage1 or when not bootstrapping.
1614 AC_ARG_WITH(stage1-ldflags,
1615 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1616 [if test "$withval" = "no" -o "$withval" = "yes"; then
1617    stage1_ldflags=
1618  else
1619    stage1_ldflags=$withval
1620  fi],
1621 [stage1_ldflags=
1622  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1623  # if supported.  But if the user explicitly specified the libraries to use,
1624  # trust that they are doing what they want.
1625  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1626    stage1_ldflags="-static-libstdc++ -static-libgcc"
1627  fi])
1628 AC_SUBST(stage1_ldflags)
1629
1630 # Libraries to use for stage2 and later builds.  This defaults to the
1631 # argument passed to --with-host-libstdcxx.
1632 AC_ARG_WITH(boot-libs,
1633 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1634 [if test "$withval" = "no" -o "$withval" = "yes"; then
1635    poststage1_libs=
1636  else
1637    poststage1_libs=$withval
1638  fi],
1639 [poststage1_libs=$with_host_libstdcxx])
1640 AC_SUBST(poststage1_libs)
1641
1642 # Linker flags to use for stage2 and later builds.
1643 AC_ARG_WITH(boot-ldflags,
1644 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1645                 [linker flags for stage2 and later])],
1646 [if test "$withval" = "no" -o "$withval" = "yes"; then
1647    poststage1_ldflags=
1648  else
1649    poststage1_ldflags=$withval
1650  fi],
1651 [poststage1_ldflags=
1652  # In stages 2 and 3, default to linking libstdc++ and libgcc
1653  # statically.  But if the user explicitly specified the libraries to
1654  # use, trust that they are doing what they want.
1655  if test "$poststage1_libs" = ""; then
1656    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1657  fi])
1658 AC_SUBST(poststage1_ldflags)
1659
1660 # GCC GRAPHITE dependency ISL.
1661 # Basic setup is inlined here, actual checks are in config/isl.m4
1662
1663 AC_ARG_WITH(isl,
1664   [AS_HELP_STRING(
1665    [--with-isl=PATH],
1666    [Specify prefix directory for the installed ISL package.
1667     Equivalent to --with-isl-include=PATH/include
1668     plus --with-isl-lib=PATH/lib])])
1669
1670 # Treat --without-isl as a request to disable
1671 # GRAPHITE support and skip all following checks.
1672 if test "x$with_isl" != "xno"; then
1673   # Check for ISL
1674   dnl Provide configure switches and initialize islinc & isllibs
1675   dnl with user input.
1676   ISL_INIT_FLAGS
1677   dnl The versions of ISL that work for Graphite
1678   ISL_CHECK_VERSION()
1679   dnl Only execute fail-action, if ISL has been requested.
1680   ISL_IF_FAILED([
1681     AC_MSG_ERROR([Unable to find a usable ISL.  See config.log for details.])])
1682 fi
1683
1684 # If the ISL check failed, disable builds of in-tree variant of ISL
1685 if test "x$with_isl" = xno ||
1686    test "x$gcc_cv_isl" = xno; then
1687   noconfigdirs="$noconfigdirs isl"
1688   islinc=
1689 fi
1690
1691 AC_SUBST(isllibs)
1692 AC_SUBST(islinc)
1693
1694 # Check for LTO support.
1695 AC_ARG_ENABLE(lto,
1696 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1697 enable_lto=$enableval,
1698 enable_lto=yes; default_enable_lto=yes)
1699
1700 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1701   build_lto_plugin=yes
1702 ],[if test x"$default_enable_lto" = x"yes" ; then
1703     case $target in
1704       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1705       # On other non-ELF platforms, LTO has yet to be validated.
1706       *) enable_lto=no ;;
1707     esac
1708   else
1709   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1710   # It would also be nice to check the binutils support, but we don't
1711   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1712   # warn during gcc/ subconfigure; unless you're bootstrapping with
1713   # -flto it won't be needed until after installation anyway.
1714     case $target in
1715       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1716       *) if test x"$enable_lto" = x"yes"; then
1717         AC_MSG_ERROR([LTO support is not enabled for this target.])
1718         fi
1719       ;;
1720     esac
1721   fi
1722   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1723   # Build it unless LTO was explicitly disabled.
1724   case $target in
1725     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1726     *) ;;
1727   esac
1728 ])
1729
1730 AC_ARG_ENABLE(linker-plugin-configure-flags,
1731   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1732     [additional flags for configuring linker plugins @<:@none@:>@])],
1733   extra_linker_plugin_configure_flags=$enableval,
1734   extra_linker_plugin_configure_flags=)
1735 AC_SUBST(extra_linker_plugin_configure_flags)
1736 AC_ARG_ENABLE(linker-plugin-flags,
1737   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1738     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1739   extra_linker_plugin_flags=$enableval,
1740   extra_linker_plugin_flags=)
1741 AC_SUBST(extra_linker_plugin_flags)
1742
1743
1744 # By default, C and C++ are the only stage 1 languages.
1745 stage1_languages=,c,
1746
1747 # Target libraries that we bootstrap.
1748 bootstrap_target_libs=,target-libgcc,
1749
1750 # Figure out what language subdirectories are present.
1751 # Look if the user specified --enable-languages="..."; if not, use
1752 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1753 # go away some day.
1754 # NB:  embedded tabs in this IF block -- do not untabify
1755 if test -d ${srcdir}/gcc; then
1756   if test x"${enable_languages+set}" != xset; then
1757     if test x"${LANGUAGES+set}" = xset; then
1758       enable_languages="${LANGUAGES}"
1759         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1760     else
1761       enable_languages=all
1762     fi
1763   else
1764     if test x"${enable_languages}" = x ||
1765        test x"${enable_languages}" = xyes;
1766        then
1767       echo configure.in: --enable-languages needs at least one language argument 1>&2
1768       exit 1
1769     fi
1770   fi
1771   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1772
1773   # 'f95' is the old name for the 'fortran' language. We issue a warning
1774   # and make the substitution.
1775   case ,${enable_languages}, in
1776     *,f95,*)
1777       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1778       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1779       ;;
1780   esac
1781
1782   # If bootstrapping, C++ must be enabled.
1783   case ",$enable_languages,:$enable_bootstrap" in
1784     *,c++,*:*) ;;
1785     *:yes)
1786       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1787         enable_languages="${enable_languages},c++"
1788       else
1789         AC_MSG_ERROR([bootstrapping requires c++ sources])
1790       fi
1791       ;;
1792   esac
1793
1794   # First scan to see if an enabled language requires some other language.
1795   # We assume that a given config-lang.in will list all the language
1796   # front ends it requires, even if some are required indirectly.
1797   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1798     case ${lang_frag} in
1799       ..) ;;
1800       # The odd quoting in the next line works around
1801       # an apparent bug in bash 1.12 on linux.
1802       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1803       *)
1804         # From the config-lang.in, get $language, $lang_requires, and
1805         # $lang_requires_boot_languages.
1806         language=
1807         lang_requires=
1808         lang_requires_boot_languages=
1809         . ${lang_frag}
1810         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1811           case ,${enable_languages}, in
1812             *,$other,*) ;;
1813             *,all,*) ;;
1814             *,$language,*)
1815               echo " \`$other' language required by \`$language'; enabling" 1>&2
1816               enable_languages="${enable_languages},${other}"
1817               ;;
1818           esac
1819         done
1820         for other in ${lang_requires_boot_languages} ; do
1821           if test "$other" != "c"; then
1822             case ,${enable_stage1_languages}, in
1823               *,$other,*) ;;
1824               *,all,*) ;;
1825               *)
1826                 case ,${enable_languages}, in
1827                   *,$language,*)
1828                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1829                     enable_stage1_languages="$enable_stage1_languages,${other}"
1830                     ;;
1831                 esac
1832                 ;;
1833             esac
1834           fi
1835         done
1836         ;;
1837     esac
1838   done
1839
1840   new_enable_languages=,c,
1841
1842   # If LTO is enabled, add the LTO front end.
1843   if test "$enable_lto" = "yes" ; then
1844     case ,${enable_languages}, in
1845       *,lto,*) ;;
1846       *) enable_languages="${enable_languages},lto" ;;
1847     esac
1848     if test "${build_lto_plugin}" = "yes" ; then
1849       configdirs="$configdirs lto-plugin"
1850     fi
1851   fi
1852
1853   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1854   potential_languages=,c,
1855
1856   enabled_target_libs=
1857   disabled_target_libs=
1858
1859   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1860     case ${lang_frag} in
1861       ..) ;;
1862       # The odd quoting in the next line works around
1863       # an apparent bug in bash 1.12 on linux.
1864       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1865       *)
1866         # From the config-lang.in, get $language, $target_libs,
1867         # $lang_dirs, $boot_language, and $build_by_default
1868         language=
1869         target_libs=
1870         lang_dirs=
1871         subdir_requires=
1872         boot_language=no
1873         build_by_default=yes
1874         . ${lang_frag}
1875         if test x${language} = x; then
1876           echo "${lang_frag} doesn't set \$language." 1>&2
1877           exit 1
1878         fi
1879
1880         if test "$language" = "c++"; then
1881           boot_language=yes
1882         fi
1883
1884         add_this_lang=no
1885         case ,${enable_languages}, in
1886           *,${language},*)
1887             # Language was explicitly selected; include it
1888             # unless it is C, which is enabled by default.
1889             if test "$language" != "c"; then
1890               add_this_lang=yes
1891             fi
1892             ;;
1893           *,all,*)
1894             # 'all' was selected, select it if it is a default language
1895             if test "$language" != "c"; then
1896               add_this_lang=${build_by_default}
1897             fi
1898             ;;
1899         esac
1900
1901         # Disable languages that need other directories if these aren't available.
1902         for i in $subdir_requires; do
1903           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1904           case ,${enable_languages}, in
1905             *,${language},*)
1906               # Specifically requested language; tell them.
1907               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1908               ;;
1909             *)
1910               # Silently disable.
1911               add_this_lang=unsupported
1912               ;;
1913           esac
1914         done
1915
1916         # Disable Ada if no preexisting GNAT is available.
1917         case ,${enable_languages},:${language}:${have_gnat} in
1918           *,${language},*:ada:no)
1919             # Specifically requested language; tell them.
1920             AC_MSG_ERROR([GNAT is required to build $language])
1921             ;;
1922           *:ada:no)
1923             # Silently disable.
1924             add_this_lang=unsupported
1925             ;;
1926         esac
1927
1928         # Disable a language that is unsupported by the target.
1929         case " $unsupported_languages " in
1930           *" $language "*)
1931             add_this_lang=unsupported
1932             ;;
1933         esac
1934
1935         case $add_this_lang in
1936           unsupported)
1937             # Remove language-dependent dirs.
1938             disabled_target_libs="$disabled_target_libs $target_libs"
1939             noconfigdirs="$noconfigdirs $lang_dirs"
1940             ;;
1941           no)
1942             # Remove language-dependent dirs; still show language as supported.
1943             disabled_target_libs="$disabled_target_libs $target_libs"
1944             noconfigdirs="$noconfigdirs $lang_dirs"
1945             potential_languages="${potential_languages}${language},"
1946             ;;
1947           yes)
1948             new_enable_languages="${new_enable_languages}${language},"
1949             potential_languages="${potential_languages}${language},"
1950             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1951             enabled_target_libs="$enabled_target_libs $target_libs"
1952             case "${boot_language}:,$enable_stage1_languages," in
1953               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1954                 # Add to (comma-separated) list of stage 1 languages.
1955                 case ",$stage1_languages," in
1956                   *,$language,* | ,yes, | ,all,) ;;
1957                   *) stage1_languages="${stage1_languages}${language}," ;;
1958                 esac
1959                 # We need to bootstrap any supporting libraries.
1960                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1961                 ;;
1962             esac
1963             ;;
1964         esac
1965         ;;
1966     esac
1967   done
1968
1969   # Add target libraries which are only needed for disabled languages
1970   # to noconfigdirs.
1971   if test -n "$disabled_target_libs"; then
1972     for dir in $disabled_target_libs; do
1973       case " $enabled_target_libs " in
1974       *" ${dir} "*) ;;
1975       *) noconfigdirs="$noconfigdirs $dir" ;;
1976       esac
1977     done
1978   fi
1979
1980   AC_ARG_ENABLE(stage1-languages,
1981   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1982                   [choose additional languages to build during
1983                   stage1.  Mostly useful for compiler development])],
1984   [case ,${enable_stage1_languages}, in
1985     ,no,|,,)
1986       # Set it to something that will have no effect in the loop below
1987       enable_stage1_languages=c ;;
1988     ,yes,)
1989       enable_stage1_languages=`echo $new_enable_languages | \
1990         sed -e "s/^,//" -e "s/,$//" ` ;;
1991     *,all,*)
1992       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1993         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1994   esac
1995
1996   # Add "good" languages from enable_stage1_languages to stage1_languages,
1997   # while "bad" languages go in missing_languages.  Leave no duplicates.
1998   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1999     case $potential_languages in
2000       *,$i,*)
2001         case $stage1_languages in
2002           *,$i,*) ;;
2003           *) stage1_languages="$stage1_languages$i," ;;
2004         esac ;;
2005       *)
2006         case $missing_languages in
2007           *,$i,*) ;;
2008           *) missing_languages="$missing_languages$i," ;;
2009         esac ;;
2010      esac
2011   done])
2012
2013   # Remove leading/trailing commas that were added for simplicity
2014   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2015   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2016   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2017   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2018
2019   if test "x$missing_languages" != x; then
2020     AC_MSG_ERROR([
2021 The following requested languages could not be built: ${missing_languages}
2022 Supported languages are: ${potential_languages}])
2023   fi
2024   if test "x$new_enable_languages" != "x$enable_languages"; then
2025     echo The following languages will be built: ${new_enable_languages}
2026     enable_languages="$new_enable_languages"
2027   fi
2028
2029   AC_SUBST(stage1_languages)
2030   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2031 fi
2032
2033 # Handle --disable-<component> generically.
2034 for dir in $configdirs $build_configdirs $target_configdirs ; do
2035   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2036   varname=`echo $dirname | sed -e s/+/_/g`
2037   if eval test x\${enable_${varname}} "=" xno ; then
2038     noconfigdirs="$noconfigdirs $dir"
2039   fi
2040 done
2041
2042 # Check for Boehm's garbage collector
2043 AC_ARG_ENABLE(objc-gc,
2044 [AS_HELP_STRING([--enable-objc-gc],
2045                 [enable use of Boehm's garbage collector with the
2046                  GNU Objective-C runtime])],
2047 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
2048   *,objc,*:*:yes:*target-boehm-gc*)
2049     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
2050     ;;
2051 esac])
2052
2053 # Make sure we only build Boehm's garbage collector if required.
2054 case ,${enable_languages},:${enable_objc_gc} in
2055   *,objc,*:yes)
2056     # Keep target-boehm-gc if requested for Objective-C.
2057     ;;
2058   *)
2059     # Otherwise remove target-boehm-gc depending on target-libjava.
2060     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
2061       noconfigdirs="$noconfigdirs target-boehm-gc"
2062     fi
2063     ;;
2064 esac
2065
2066 # Disable libcilkrts, libitm, libsanitizer, libvtv if we're not building C++
2067 case ,${enable_languages}, in
2068   *,c++,*)
2069     # Disable libcilkrts, libitm, libsanitizer if we're not building libstdc++
2070     case "${noconfigdirs}" in
2071       *target-libstdc++-v3*)
2072         noconfigdirs="$noconfigdirs target-libcilkrts target-libitm target-libsanitizer"
2073         ;;
2074       *) ;;
2075     esac
2076     ;;
2077   *)
2078     noconfigdirs="$noconfigdirs target-libcilkrts target-libitm target-libsanitizer target-libvtv"
2079     ;;
2080 esac
2081
2082 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2083 # $build_configdirs and $target_configdirs.
2084 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2085
2086 notsupp=""
2087 for dir in . $skipdirs $noconfigdirs ; do
2088   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2089   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2090     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2091     if test -r $srcdir/$dirname/configure ; then
2092       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2093         true
2094       else
2095         notsupp="$notsupp $dir"
2096       fi
2097     fi
2098   fi
2099   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2100     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2101     if test -r $srcdir/$dirname/configure ; then
2102       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2103         true
2104       else
2105         notsupp="$notsupp $dir"
2106       fi
2107     fi
2108   fi
2109   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2110     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2111     if test -r $srcdir/$dirname/configure ; then
2112       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2113         true
2114       else
2115         notsupp="$notsupp $dir"
2116       fi
2117     fi
2118   fi
2119 done
2120
2121 # Quietly strip out all directories which aren't configurable in this tree.
2122 # This relies on all configurable subdirectories being autoconfiscated, which
2123 # is now the case.
2124 build_configdirs_all="$build_configdirs"
2125 build_configdirs=
2126 for i in ${build_configdirs_all} ; do
2127   j=`echo $i | sed -e s/build-//g`
2128   if test -f ${srcdir}/$j/configure ; then
2129     build_configdirs="${build_configdirs} $i"
2130   fi
2131 done
2132
2133 configdirs_all="$configdirs"
2134 configdirs=
2135 for i in ${configdirs_all} ; do
2136   if test -f ${srcdir}/$i/configure ; then
2137     configdirs="${configdirs} $i"
2138   fi
2139 done
2140
2141 target_configdirs_all="$target_configdirs"
2142 target_configdirs=
2143 for i in ${target_configdirs_all} ; do
2144   j=`echo $i | sed -e s/target-//g`
2145   if test -f ${srcdir}/$j/configure ; then
2146     target_configdirs="${target_configdirs} $i"
2147   fi
2148 done
2149
2150 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2151 # so we have to add it after the preceding checks.
2152 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2153 then
2154   case " $configdirs " in
2155     *" libiberty "*)
2156       # If we can build libiberty, we can also build libiberty-linker-plugin.
2157       configdirs="$configdirs libiberty-linker-plugin"
2158       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2159         --with-libiberty=../libiberty-linker-plugin";;
2160     *)
2161       AC_MSG_ERROR([libiberty missing]);;
2162   esac
2163 fi
2164
2165 # Sometimes we have special requirements for the host libiberty.
2166 extra_host_libiberty_configure_flags=
2167 case " $configdirs " in
2168   *" lto-plugin "* | *" libcc1 "*)
2169     # When these are to be built as shared libraries, the same applies to
2170     # libiberty.
2171     extra_host_libiberty_configure_flags=--enable-shared
2172     ;;
2173 esac
2174 AC_SUBST(extra_host_libiberty_configure_flags)
2175
2176 # Produce a warning message for the subdirs we can't configure.
2177 # This isn't especially interesting in the Cygnus tree, but in the individual
2178 # FSF releases, it's important to let people know when their machine isn't
2179 # supported by the one or two programs in a package.
2180
2181 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2182   # If $appdirs is non-empty, at least one of those directories must still
2183   # be configured, or we error out.  (E.g., if the gas release supports a
2184   # specified target in some subdirs but not the gas subdir, we shouldn't
2185   # pretend that all is well.)
2186   if test -n "$appdirs" ; then
2187     for dir in $appdirs ; do
2188       if test -r $dir/Makefile.in ; then
2189         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2190           appdirs=""
2191           break
2192         fi
2193         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2194           appdirs=""
2195           break
2196         fi
2197       fi
2198     done
2199     if test -n "$appdirs" ; then
2200       echo "*** This configuration is not supported by this package." 1>&2
2201       exit 1
2202     fi
2203   fi
2204   # Okay, some application will build, or we don't care to check.  Still
2205   # notify of subdirs not getting built.
2206   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2207   echo "    ${notsupp}" 1>&2
2208   echo "    (Any other directories should still work fine.)" 1>&2
2209 fi
2210
2211 case "$host" in
2212   *msdosdjgpp*)
2213     enable_gdbtk=no ;;
2214 esac
2215
2216 # To find our prefix, in gcc_cv_tool_prefix.
2217 ACX_TOOL_DIRS
2218
2219 copy_dirs=
2220
2221 AC_ARG_WITH([build-sysroot],
2222   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2223                   [use sysroot as the system root during the build])],
2224   [if test x"$withval" != x ; then
2225      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2226    fi],
2227   [SYSROOT_CFLAGS_FOR_TARGET=])
2228 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2229
2230 AC_ARG_WITH([debug-prefix-map],
2231   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2232                   [map A to B, C to D ... in debug information])],
2233   [if test x"$withval" != x; then
2234      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2235      for debug_map in $withval; do
2236        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2237      done
2238    fi],
2239   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2240 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2241
2242 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2243 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2244 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2245 # We want to ensure that TARGET libraries (which we know are built with
2246 # gcc) are built with "-O2 -g", so include those options when setting
2247 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2248 if test "x$CFLAGS_FOR_TARGET" = x; then
2249   CFLAGS_FOR_TARGET=$CFLAGS
2250   case " $CFLAGS " in
2251     *" -O2 "*) ;;
2252     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2253   esac
2254   case " $CFLAGS " in
2255     *" -g "* | *" -g3 "*) ;;
2256     *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2257   esac
2258 fi
2259 AC_SUBST(CFLAGS_FOR_TARGET)
2260
2261 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2262   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2263   case " $CXXFLAGS " in
2264     *" -O2 "*) ;;
2265     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2266   esac
2267   case " $CXXFLAGS " in
2268     *" -g "* | *" -g3 "*) ;;
2269     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2270   esac
2271 fi
2272 AC_SUBST(CXXFLAGS_FOR_TARGET)
2273
2274 AC_SUBST(LDFLAGS_FOR_TARGET)
2275
2276 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2277 # the named directory are copied to $(tooldir)/sys-include.
2278 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2279   if test x${is_cross_compiler} = xno ; then
2280     echo 1>&2 '***' --with-headers is only supported when cross compiling
2281     exit 1
2282   fi
2283   if test x"${with_headers}" != xyes ; then
2284     x=${gcc_cv_tool_prefix}
2285     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2286   fi
2287 fi
2288
2289 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2290 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2291 # are permitted.
2292 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2293   if test x${is_cross_compiler} = xno ; then
2294     echo 1>&2 '***' --with-libs is only supported when cross compiling
2295     exit 1
2296   fi
2297   if test x"${with_libs}" != xyes ; then
2298     # Copy the libraries in reverse order, so that files in the first named
2299     # library override files in subsequent libraries.
2300     x=${gcc_cv_tool_prefix}
2301     for l in ${with_libs}; do
2302       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2303     done
2304   fi
2305 fi
2306
2307 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2308 #
2309 # This is done by determining whether or not the appropriate directory
2310 # is available, and by checking whether or not specific configurations
2311 # have requested that this magic not happen.
2312 #
2313 # The command line options always override the explicit settings in
2314 # configure.in, and the settings in configure.in override this magic.
2315 #
2316 # If the default for a toolchain is to use GNU as and ld, and you don't
2317 # want to do that, then you should use the --without-gnu-as and
2318 # --without-gnu-ld options for the configure script.  Similarly, if
2319 # the default is to use the included zlib and you don't want to do that,
2320 # you should use the --with-system-zlib option for the configure script.
2321
2322 if test x${use_gnu_as} = x &&
2323    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2324   with_gnu_as=yes
2325   extra_host_args="$extra_host_args --with-gnu-as"
2326 fi
2327
2328 if test x${use_gnu_ld} = x &&
2329    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2330   with_gnu_ld=yes
2331   extra_host_args="$extra_host_args --with-gnu-ld"
2332 fi
2333
2334 if test x${use_included_zlib} = x &&
2335    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2336   :
2337 else
2338   with_system_zlib=yes
2339   extra_host_args="$extra_host_args --with-system-zlib"
2340 fi
2341
2342 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2343 # can detect this case.
2344
2345 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2346   with_newlib=yes
2347   extra_host_args="$extra_host_args --with-newlib"
2348 fi
2349
2350 # Handle ${copy_dirs}
2351 set fnord ${copy_dirs}
2352 shift
2353 while test $# != 0 ; do
2354   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2355     :
2356   else
2357     echo Copying $1 to $2
2358
2359     # Use the install script to create the directory and all required
2360     # parent directories.
2361     if test -d $2 ; then
2362       :
2363     else
2364       echo >config.temp
2365       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2366     fi
2367
2368     # Copy the directory, assuming we have tar.
2369     # FIXME: Should we use B in the second tar?  Not all systems support it.
2370     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2371
2372     # It is the responsibility of the user to correctly adjust all
2373     # symlinks.  If somebody can figure out how to handle them correctly
2374     # here, feel free to add the code.
2375
2376     echo $1 > $2/COPIED
2377   fi
2378   shift; shift
2379 done
2380
2381 # Determine a target-dependent exec_prefix that the installed
2382 # gcc will search in.  Keep this list sorted by triplet, with
2383 # the *-*-osname triplets last.
2384 md_exec_prefix=
2385 case "${target}" in
2386   i[[34567]]86-pc-msdosdjgpp*)
2387     md_exec_prefix=/dev/env/DJDIR/bin
2388     ;;
2389   *-*-hpux* | \
2390   *-*-nto-qnx* | \
2391   *-*-solaris2*)
2392     md_exec_prefix=/usr/ccs/bin
2393     ;;
2394 esac
2395
2396 extra_arflags_for_target=
2397 extra_nmflags_for_target=
2398 extra_ranlibflags_for_target=
2399 target_makefile_frag=/dev/null
2400 case "${target}" in
2401   spu-*-*)
2402     target_makefile_frag="config/mt-spu"
2403     ;;
2404   mips*-sde-elf* | mips*-mti-elf*)
2405     target_makefile_frag="config/mt-sde"
2406     ;;
2407   mipsisa*-*-elfoabi*)
2408     target_makefile_frag="config/mt-mips-elfoabi"
2409     ;;
2410   mips*-*-*linux* | mips*-*-gnu*)
2411     target_makefile_frag="config/mt-mips-gnu"
2412     ;;
2413   nios2-*-elf*)
2414     target_makefile_frag="config/mt-nios2-elf"
2415     ;;
2416   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2417     target_makefile_frag="config/mt-gnu"
2418     ;;
2419   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2420     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2421     # commands to handle both 32-bit and 64-bit objects.  These flags are
2422     # harmless if we're using GNU nm or ar.
2423     extra_arflags_for_target=" -X32_64"
2424     extra_nmflags_for_target=" -B -X32_64"
2425     ;;
2426 esac
2427
2428 alphaieee_frag=/dev/null
2429 case $target in
2430   alpha*-*-*)
2431     # This just makes sure to use the -mieee option to build target libs.
2432     # This should probably be set individually by each library.
2433     alphaieee_frag="config/mt-alphaieee"
2434     ;;
2435 esac
2436
2437 # If --enable-target-optspace always use -Os instead of -O2 to build
2438 # the target libraries, similarly if it is not specified, use -Os
2439 # on selected platforms.
2440 ospace_frag=/dev/null
2441 case "${enable_target_optspace}:${target}" in
2442   yes:*)
2443     ospace_frag="config/mt-ospace"
2444     ;;
2445   :d30v-*)
2446     ospace_frag="config/mt-d30v"
2447     ;;
2448   :m32r-* | :d10v-* | :fr30-*)
2449     ospace_frag="config/mt-ospace"
2450     ;;
2451   no:* | :*)
2452     ;;
2453   *)
2454     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2455     ;;
2456 esac
2457
2458 # Some systems (e.g., one of the i386-aix systems the gas testers are
2459 # using) don't handle "\$" correctly, so don't use it here.
2460 tooldir='${exec_prefix}'/${target_noncanonical}
2461 build_tooldir=${tooldir}
2462
2463 # Create a .gdbinit file which runs the one in srcdir
2464 # and tells GDB to look there for source files.
2465
2466 if test -r ${srcdir}/.gdbinit ; then
2467   case ${srcdir} in
2468     .) ;;
2469     *) cat > ./.gdbinit <<EOF
2470 # ${NO_EDIT}
2471 dir ${srcdir}
2472 dir .
2473 source ${srcdir}/.gdbinit
2474 EOF
2475     ;;
2476   esac
2477 fi
2478
2479 # Make sure that the compiler is able to generate an executable.  If it
2480 # can't, we are probably in trouble.  We don't care whether we can run the
2481 # executable--we might be using a cross compiler--we only care whether it
2482 # can be created.  At this point the main configure script has set CC.
2483 we_are_ok=no
2484 echo "int main () { return 0; }" > conftest.c
2485 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2486 if test $? = 0 ; then
2487   if test -s conftest || test -s conftest.exe ; then
2488     we_are_ok=yes
2489   fi
2490 fi
2491 case $we_are_ok in
2492   no)
2493     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2494     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2495     rm -f conftest*
2496     exit 1
2497     ;;
2498 esac
2499 rm -f conftest*
2500
2501 # Decide which environment variable is used to find dynamic libraries.
2502 case "${host}" in
2503   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2504   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2505   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2506   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2507 esac
2508
2509 # On systems where the dynamic library environment variable is PATH,
2510 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2511 # built executables to PATH.
2512 if test "$RPATH_ENVVAR" = PATH; then
2513   GCC_SHLIB_SUBDIR=/shlib
2514 else
2515   GCC_SHLIB_SUBDIR=
2516 fi
2517
2518 # Adjust the toplevel makefile according to whether bootstrap was selected.
2519 case $enable_bootstrap in
2520   yes)
2521     bootstrap_suffix=bootstrap
2522     BUILD_CONFIG=bootstrap-debug
2523     ;;
2524   no)
2525     bootstrap_suffix=no-bootstrap
2526     BUILD_CONFIG=
2527     ;;
2528 esac
2529
2530 AC_MSG_CHECKING(for default BUILD_CONFIG)
2531
2532 AC_ARG_WITH([build-config],
2533   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2534                   [use config/NAME.mk build configuration])],
2535   [case $with_build_config in
2536    yes) with_build_config= ;;
2537    no) with_build_config= BUILD_CONFIG= ;;
2538    esac])
2539
2540 if test "x${with_build_config}" != x; then
2541   BUILD_CONFIG=$with_build_config
2542 else
2543   case $BUILD_CONFIG in
2544   bootstrap-debug)
2545     if echo "int f (void) { return 0; }" > conftest.c &&
2546        ${CC} -c conftest.c &&
2547        mv conftest.o conftest.o.g0 &&
2548        ${CC} -c -g conftest.c &&
2549        mv conftest.o conftest.o.g &&
2550        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2551       :
2552     else
2553       BUILD_CONFIG=
2554     fi
2555     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2556     ;;
2557   esac
2558 fi
2559 AC_MSG_RESULT($BUILD_CONFIG)
2560 AC_SUBST(BUILD_CONFIG)
2561
2562 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2563 AC_MSG_CHECKING([for --enable-vtable-verify])
2564 AC_ARG_ENABLE(vtable-verify,
2565 [  --enable-vtable-verify    Enable vtable verification feature ],
2566 [case "$enableval" in
2567  yes) enable_vtable_verify=yes ;;
2568  no)  enable_vtable_verify=no ;;
2569  *)   enable_vtable_verify=no;;
2570  esac],
2571 [enable_vtable_verify=no])
2572 AC_MSG_RESULT($enable_vtable_verify)
2573
2574 # Record target_configdirs and the configure arguments for target and
2575 # build configuration in Makefile.
2576 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2577 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2578 bootstrap_fixincludes=no
2579
2580 # If we are building libgomp, bootstrap it.
2581 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2582   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2583 fi
2584
2585 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2586 # or bootstrap-ubsan, bootstrap it.
2587 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2588   case "$BUILD_CONFIG" in
2589     *bootstrap-asan* | *bootstrap-ubsan* )
2590       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2591       bootstrap_fixincludes=yes
2592       ;;
2593   esac
2594 fi
2595
2596 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2597 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2598    test "$enable_vtable_verify" != no; then
2599   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2600 fi
2601
2602 # Determine whether gdb needs tk/tcl or not.
2603 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2604 # and in that case we want gdb to be built without tk.  Ugh!
2605 # In fact I believe gdb is the *only* package directly dependent on tk,
2606 # so we should be able to put the 'maybe's in unconditionally and
2607 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2608 # 100% sure that that's safe though.
2609
2610 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2611 case "$enable_gdbtk" in
2612   no)
2613     GDB_TK="" ;;
2614   yes)
2615     GDB_TK="${gdb_tk}" ;;
2616   *)
2617     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2618     # distro.  Eventually someone will fix this and move Insight, nee
2619     # gdbtk to a separate directory.
2620     if test -d ${srcdir}/gdb/gdbtk ; then
2621       GDB_TK="${gdb_tk}"
2622     else
2623       GDB_TK=""
2624     fi
2625     ;;
2626 esac
2627 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2628 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2629
2630 # Strip out unwanted targets.
2631
2632 # While at that, we remove Makefiles if we were started for recursive
2633 # configuration, so that the top-level Makefile reconfigures them,
2634 # like we used to do when configure itself was recursive.
2635
2636 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2637 # but now we're fixing up the Makefile ourselves with the additional
2638 # commands passed to AC_CONFIG_FILES.  Use separate variables
2639 # extrasub-{build,host,target} not because there is any reason to split
2640 # the substitutions up that way, but only to remain below the limit of
2641 # 99 commands in a script, for HP-UX sed.
2642 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2643
2644 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2645   yes:yes:*\ gold\ *:*,c++,*) ;;
2646   yes:yes:*\ gold\ *:*)
2647     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2648     ;;
2649 esac
2650
2651 extrasub_build=
2652 for module in ${build_configdirs} ; do
2653   if test -z "${no_recursion}" \
2654      && test -f ${build_subdir}/${module}/Makefile; then
2655     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2656     rm -f ${build_subdir}/${module}/Makefile
2657   fi
2658   extrasub_build="$extrasub_build
2659 /^@if build-$module\$/d
2660 /^@endif build-$module\$/d
2661 /^@if build-$module-$bootstrap_suffix\$/d
2662 /^@endif build-$module-$bootstrap_suffix\$/d"
2663 done
2664 extrasub_host=
2665 for module in ${configdirs} ; do
2666   if test -z "${no_recursion}"; then
2667     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2668       if test -f ${file}; then
2669         echo 1>&2 "*** removing ${file} to force reconfigure"
2670         rm -f ${file}
2671       fi
2672     done
2673   fi
2674   case ${module},${bootstrap_fixincludes} in
2675     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2676     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2677   esac
2678   extrasub_host="$extrasub_host
2679 /^@if $module\$/d
2680 /^@endif $module\$/d
2681 /^@if $module-$host_bootstrap_suffix\$/d
2682 /^@endif $module-$host_bootstrap_suffix\$/d"
2683 done
2684 extrasub_target=
2685 for module in ${target_configdirs} ; do
2686   if test -z "${no_recursion}" \
2687      && test -f ${target_subdir}/${module}/Makefile; then
2688     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2689     rm -f ${target_subdir}/${module}/Makefile
2690   fi
2691
2692   # We only bootstrap target libraries listed in bootstrap_target_libs.
2693   case $bootstrap_target_libs in
2694     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2695     *) target_bootstrap_suffix=no-bootstrap ;;
2696   esac
2697
2698   extrasub_target="$extrasub_target
2699 /^@if target-$module\$/d
2700 /^@endif target-$module\$/d
2701 /^@if target-$module-$target_bootstrap_suffix\$/d
2702 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2703 done
2704
2705 # Do the final fixup along with target modules.
2706 extrasub_target="$extrasub_target
2707 /^@if /,/^@endif /d"
2708
2709 # Create the serialization dependencies.  This uses a temporary file.
2710
2711 AC_ARG_ENABLE([serial-configure],
2712 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2713                 [force sequential configuration of
2714                  sub-packages for the host, target or build
2715                  machine, or all sub-packages])])
2716
2717 case ${enable_serial_configure} in
2718   yes)
2719     enable_serial_build_configure=yes
2720     enable_serial_host_configure=yes
2721     enable_serial_target_configure=yes
2722     ;;
2723 esac
2724
2725 # These force 'configure's to be done one at a time, to avoid problems
2726 # with contention over a shared config.cache.
2727 rm -f serdep.tmp
2728 echo '# serdep.tmp' > serdep.tmp
2729 olditem=
2730 test "x${enable_serial_build_configure}" = xyes &&
2731 for item in ${build_configdirs} ; do
2732   case ${olditem} in
2733     "") ;;
2734     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2735   esac
2736   olditem=${item}
2737 done
2738 olditem=
2739 test "x${enable_serial_host_configure}" = xyes &&
2740 for item in ${configdirs} ; do
2741   case ${olditem} in
2742     "") ;;
2743     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2744   esac
2745   olditem=${item}
2746 done
2747 olditem=
2748 test "x${enable_serial_target_configure}" = xyes &&
2749 for item in ${target_configdirs} ; do
2750   case ${olditem} in
2751     "") ;;
2752     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2753   esac
2754   olditem=${item}
2755 done
2756 serialization_dependencies=serdep.tmp
2757 AC_SUBST_FILE(serialization_dependencies)
2758
2759 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2760 # target, nonopt, and variable assignments.  These are the ones we
2761 # might not want to pass down to subconfigures.  The exception being
2762 # --cache-file=/dev/null, which is used to turn off the use of cache
2763 # files altogether, and which should be passed on to subconfigures.
2764 # Also strip program-prefix, program-suffix, and program-transform-name,
2765 # so that we can pass down a consistent program-transform-name.
2766 baseargs=
2767 tbaseargs=
2768 keep_next=no
2769 skip_next=no
2770 eval "set -- $ac_configure_args"
2771 for ac_arg
2772 do
2773   if test X"$skip_next" = X"yes"; then
2774     skip_next=no
2775     continue
2776   fi
2777   if test X"$keep_next" = X"yes"; then
2778     case $ac_arg in
2779       *\'*)
2780         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2781     esac
2782     baseargs="$baseargs '$ac_arg'"
2783     tbaseargs="$tbaseargs '$ac_arg'"
2784     keep_next=no
2785     continue
2786   fi
2787
2788   # Handle separated arguments.  Based on the logic generated by
2789   # autoconf 2.59.
2790   case $ac_arg in
2791     *=* | --config-cache | -C | -disable-* | --disable-* \
2792       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2793       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2794       | -with-* | --with-* | -without-* | --without-* | --x)
2795       separate_arg=no
2796       ;;
2797     -*)
2798       separate_arg=yes
2799       ;;
2800     *)
2801       separate_arg=no
2802       ;;
2803   esac
2804
2805   skip_targ=no
2806   case $ac_arg in
2807 changequote(,)
2808   --with-* | --without-*)
2809     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2810
2811     case $libopt in
2812     *[-_]include)
2813       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2814       ;;
2815     *[-_]lib)
2816       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2817       ;;
2818     *)
2819       lib=$libopt
2820       ;;
2821     esac
2822 changequote([,])
2823
2824     case $lib in
2825     mpc | mpfr | gmp | isl)
2826       # If we're processing --with-$lib, --with-$lib-include or
2827       # --with-$lib-lib, for one of the libs above, and target is
2828       # different from host, don't pass the current argument to any
2829       # target library's configure.
2830       if test x$is_cross_compiler = xyes; then
2831         skip_targ=yes
2832       fi
2833       ;;
2834     esac
2835     ;;
2836   esac
2837
2838   case "$ac_arg" in
2839     --cache-file=/dev/null | \
2840     -cache-file=/dev/null )
2841       # Handled here to avoid the test to skip args below.
2842       baseargs="$baseargs '$ac_arg'"
2843       tbaseargs="$tbaseargs '$ac_arg'"
2844       # Assert: $separate_arg should always be no.
2845       keep_next=$separate_arg
2846       ;;
2847     --no*)
2848       continue
2849       ;;
2850     --c* | \
2851     --sr* | \
2852     --ho* | \
2853     --bu* | \
2854     --t* | \
2855     --program-* | \
2856     -cache_file* | \
2857     -srcdir* | \
2858     -host* | \
2859     -build* | \
2860     -target* | \
2861     -program-prefix* | \
2862     -program-suffix* | \
2863     -program-transform-name* )
2864       skip_next=$separate_arg
2865       continue
2866       ;;
2867     -*)
2868       # An option.  Add it.
2869       case $ac_arg in
2870         *\'*)
2871           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2872       esac
2873       baseargs="$baseargs '$ac_arg'"
2874       if test X"$skip_targ" = Xno; then
2875         tbaseargs="$tbaseargs '$ac_arg'"
2876       fi
2877       keep_next=$separate_arg
2878       ;;
2879     *)
2880       # Either a variable assignment, or a nonopt (triplet).  Don't
2881       # pass it down; let the Makefile handle this.
2882       continue
2883       ;;
2884   esac
2885 done
2886 # Remove the initial space we just introduced and, as these will be
2887 # expanded by make, quote '$'.
2888 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2889
2890 # Add in --program-transform-name, after --program-prefix and
2891 # --program-suffix have been applied to it.  Autoconf has already
2892 # doubled dollar signs and backslashes in program_transform_name; we want
2893 # the backslashes un-doubled, and then the entire thing wrapped in single
2894 # quotes, because this will be expanded first by make and then by the shell.
2895 # Also, because we want to override the logic in subdir configure scripts to
2896 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2897 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2898 ${program_transform_name}
2899 EOF_SED
2900 gcc_transform_name=`cat conftestsed.out`
2901 rm -f conftestsed.out
2902 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2903 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2904 if test "$silent" = yes; then
2905   baseargs="$baseargs --silent"
2906   tbaseargs="$tbaseargs --silent"
2907 fi
2908 baseargs="$baseargs --disable-option-checking"
2909 tbaseargs="$tbaseargs --disable-option-checking"
2910
2911 # Record and document user additions to sub configure arguments.
2912 AC_ARG_VAR([build_configargs],
2913            [additional configure arguments for build directories])
2914 AC_ARG_VAR([host_configargs],
2915            [additional configure arguments for host directories])
2916 AC_ARG_VAR([target_configargs],
2917            [additional configure arguments for target directories])
2918
2919 # For the build-side libraries, we just need to pretend we're native,
2920 # and not use the same cache file.  Multilibs are neither needed nor
2921 # desired.  We can't even use the same cache file for all build-side
2922 # libraries, as they're compiled differently; some with C, some with
2923 # C++ or with different feature-enabling options.
2924 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
2925
2926 # For host modules, accept cache file option, or specification as blank.
2927 case "${cache_file}" in
2928 "") # empty
2929   cache_file_option="" ;;
2930 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2931   cache_file_option="--cache-file=${cache_file}" ;;
2932 *) # relative path
2933   cache_file_option="--cache-file=../${cache_file}" ;;
2934 esac
2935
2936 # Host dirs don't like to share a cache file either, horribly enough.
2937 # This seems to be due to autoconf 2.5x stupidity.
2938 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2939
2940 target_configargs="$target_configargs ${tbaseargs}"
2941
2942 # Passing a --with-cross-host argument lets the target libraries know
2943 # whether they are being built with a cross-compiler or being built
2944 # native.  However, it would be better to use other mechanisms to make the
2945 # sorts of decisions they want to make on this basis.  Please consider
2946 # this option to be deprecated.  FIXME.
2947 if test x${is_cross_compiler} = xyes ; then
2948   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2949 fi
2950
2951 # Special user-friendly check for native x86_64-linux build, if
2952 # multilib is not explicitly enabled.
2953 case "$target:$have_compiler:$host:$target:$enable_multilib" in
2954   x86_64-*linux*:yes:$build:$build:)
2955     # Make sure we have a developement environment that handles 32-bit
2956     dev64=no
2957     echo "int main () { return 0; }" > conftest.c
2958     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2959     if test $? = 0 ; then
2960       if test -s conftest || test -s conftest.exe ; then
2961         dev64=yes
2962       fi
2963     fi
2964     rm -f conftest*
2965     if test x${dev64} != xyes ; then
2966       AC_MSG_ERROR([I suspect your system does not have 32-bit developement libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
2967     fi
2968     ;;
2969 esac
2970
2971 # Default to --enable-multilib.
2972 if test x${enable_multilib} = x ; then
2973   target_configargs="--enable-multilib ${target_configargs}"
2974 fi
2975
2976 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2977 # changed from the earlier setting of with_newlib.
2978 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2979   target_configargs="--with-newlib ${target_configargs}"
2980 fi
2981
2982 # Different target subdirs use different values of certain variables
2983 # (notably CXX).  Worse, multilibs use *lots* of different values.
2984 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2985 # it doesn't automatically accept command-line overrides of them.
2986 # This means it's not safe for target subdirs to share a cache file,
2987 # which is disgusting, but there you have it.  Hopefully this can be
2988 # fixed in future.  It's still worthwhile to use a cache file for each
2989 # directory.  I think.
2990
2991 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2992 # We need to pass --target, as newer autoconf's requires consistency
2993 # for target_alias and gcc doesn't manage it consistently.
2994 target_configargs="--cache-file=./config.cache ${target_configargs}"
2995
2996 FLAGS_FOR_TARGET=
2997 case " $target_configdirs " in
2998  *" newlib "*)
2999   case " $target_configargs " in
3000   *" --with-newlib "*)
3001    case "$target" in
3002     *-cygwin*)
3003       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3004       ;;
3005    esac
3006
3007    # If we're not building GCC, don't discard standard headers.
3008    if test -d ${srcdir}/gcc; then
3009      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3010
3011      if test "${build}" != "${host}"; then
3012        # On Canadian crosses, CC_FOR_TARGET will have already been set
3013        # by `configure', so we won't have an opportunity to add -Bgcc/
3014        # to it.  This is right: we don't want to search that directory
3015        # for binaries, but we want the header files in there, so add
3016        # them explicitly.
3017        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3018
3019        # Someone might think of using the pre-installed headers on
3020        # Canadian crosses, in case the installed compiler is not fully
3021        # compatible with the compiler being built.  In this case, it
3022        # would be better to flag an error than risking having
3023        # incompatible object files being constructed.  We can't
3024        # guarantee that an error will be flagged, but let's hope the
3025        # compiler will do it, when presented with incompatible header
3026        # files.
3027      fi
3028    fi
3029
3030    case "${target}-${is_cross_compiler}" in
3031    i[[3456789]]86-*-linux*-no)
3032       # Here host == target, so we don't need to build gcc,
3033       # so we don't want to discard standard headers.
3034       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3035       ;;
3036    *)
3037       # If we're building newlib, use its generic headers last, but search
3038       # for any libc-related directories first (so make it the last -B
3039       # switch).
3040       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3041
3042       # If we're building libgloss, find the startup file, simulator library
3043       # and linker script.
3044       case " $target_configdirs " in
3045         *" libgloss "*)
3046         # Look for startup file, simulator library and maybe linker script.
3047         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3048         # Look for libnosys.a in case the target needs it.
3049         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3050         # Most targets have the linker script in the source directory.
3051         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3052         ;;
3053       esac
3054       ;;
3055    esac
3056    ;;
3057   esac
3058   ;;
3059 esac
3060
3061 case "$target" in
3062   x86_64-*mingw* | *-w64-mingw*)
3063   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3064   # however, use a symlink named 'mingw' in ${prefix} .
3065     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3066     ;;
3067   *-mingw*)
3068   # MinGW can't be handled as Cygwin above since it does not use newlib.
3069     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3070     ;;
3071 esac
3072
3073 # Allow the user to override the flags for
3074 # our build compiler if desired.
3075 if test x"${build}" = x"${host}" ; then
3076   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3077   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3078   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3079 fi
3080
3081 # On Canadian crosses, we'll be searching the right directories for
3082 # the previously-installed cross compiler, so don't bother to add
3083 # flags for directories within the install tree of the compiler
3084 # being built; programs in there won't even run.
3085 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3086   # Search for pre-installed headers if nothing else fits.
3087   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3088 fi
3089
3090 if test "x${use_gnu_ld}" = x &&
3091    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3092   # Arrange for us to find uninstalled linker scripts.
3093   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3094 fi
3095
3096 # Search for other target-specific linker scripts and such.
3097 case "${target}" in
3098   mep*)
3099     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3100     ;;
3101 esac
3102
3103 # Makefile fragments.
3104 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3105 do
3106   eval fragval=\$$frag
3107   if test $fragval != /dev/null; then
3108     eval $frag=${srcdir}/$fragval
3109   fi
3110 done
3111 AC_SUBST_FILE(host_makefile_frag)
3112 AC_SUBST_FILE(target_makefile_frag)
3113 AC_SUBST_FILE(alphaieee_frag)
3114 AC_SUBST_FILE(ospace_frag)
3115
3116 # Miscellanea: directories, flags, etc.
3117 AC_SUBST(RPATH_ENVVAR)
3118 AC_SUBST(GCC_SHLIB_SUBDIR)
3119 AC_SUBST(tooldir)
3120 AC_SUBST(build_tooldir)
3121 AC_SUBST(CONFIGURE_GDB_TK)
3122 AC_SUBST(GDB_TK)
3123 AC_SUBST(INSTALL_GDB_TK)
3124
3125 # Build module lists & subconfigure args.
3126 AC_SUBST(build_configargs)
3127 AC_SUBST(build_configdirs)
3128
3129 # Host module lists & subconfigure args.
3130 AC_SUBST(host_configargs)
3131 AC_SUBST(configdirs)
3132 AC_SUBST(target_configdirs)
3133
3134 # Target module lists & subconfigure args.
3135 AC_SUBST(target_configargs)
3136
3137
3138 # Build tools.
3139 AC_SUBST(AR_FOR_BUILD)
3140 AC_SUBST(AS_FOR_BUILD)
3141 AC_SUBST(CC_FOR_BUILD)
3142 AC_SUBST(CFLAGS_FOR_BUILD)
3143 AC_SUBST(CXXFLAGS_FOR_BUILD)
3144 AC_SUBST(CXX_FOR_BUILD)
3145 AC_SUBST(DLLTOOL_FOR_BUILD)
3146 AC_SUBST(GCJ_FOR_BUILD)
3147 AC_SUBST(GFORTRAN_FOR_BUILD)
3148 AC_SUBST(GOC_FOR_BUILD)
3149 AC_SUBST(LDFLAGS_FOR_BUILD)
3150 AC_SUBST(LD_FOR_BUILD)
3151 AC_SUBST(NM_FOR_BUILD)
3152 AC_SUBST(RANLIB_FOR_BUILD)
3153 AC_SUBST(WINDMC_FOR_BUILD)
3154 AC_SUBST(WINDRES_FOR_BUILD)
3155
3156 # Generate default definitions for YACC, M4, LEX and other programs that run
3157 # on the build machine.  These are used if the Makefile can't locate these
3158 # programs in objdir.
3159 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3160
3161 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3162 case " $build_configdirs " in
3163   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3164 esac
3165
3166 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3167 case " $build_configdirs " in
3168   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3169 esac
3170
3171 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3172 case " $build_configdirs " in
3173   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3174 esac
3175
3176 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3177 case " $build_configdirs " in
3178   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3179   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3180 esac
3181
3182 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3183 case " $build_configdirs " in
3184   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3185 esac
3186
3187 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3188 case " $build_configdirs " in
3189   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3190   *)
3191 changequote(,)
3192     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3193     # higher, else we use the "missing" dummy.
3194     if ${MAKEINFO} --version \
3195        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3196       :
3197     else
3198       MAKEINFO="$MISSING makeinfo"
3199     fi
3200     ;;
3201 changequote([,])
3202 esac
3203
3204 # FIXME: expect and dejagnu may become build tools?
3205
3206 AC_CHECK_PROGS(EXPECT, expect, expect)
3207 case " $configdirs " in
3208   *" expect "*)
3209     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3210     ;;
3211 esac
3212
3213 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3214 case " $configdirs " in
3215   *" dejagnu "*)
3216     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3217     ;;
3218 esac
3219
3220
3221 # Host tools.
3222 NCN_STRICT_CHECK_TOOLS(AR, ar)
3223 NCN_STRICT_CHECK_TOOLS(AS, as)
3224 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3225 NCN_STRICT_CHECK_TOOLS(LD, ld)
3226 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3227 NCN_STRICT_CHECK_TOOLS(NM, nm)
3228 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3229 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3230 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3231 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3232 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3233 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3234 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3235 AC_SUBST(CC)
3236 AC_SUBST(CXX)
3237 AC_SUBST(CFLAGS)
3238 AC_SUBST(CXXFLAGS)
3239
3240 # Target tools.
3241 AC_ARG_WITH([build-time-tools],
3242   [AS_HELP_STRING([--with-build-time-tools=PATH],
3243                   [use given path to find target tools during the build])],
3244   [case x"$withval" in
3245      x/*) ;;
3246      *)
3247        with_build_time_tools=
3248        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3249        ;;
3250    esac],
3251   [with_build_time_tools=])
3252
3253 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3254 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3255 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3256 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3257 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3258 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3259
3260 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3261 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3262 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3263 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3264 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3265 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3266 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3267 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3268 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3269 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3270 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3271 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3272
3273 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3274
3275 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3276 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3277 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3278 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3279 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3280                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3281                 c++)
3282 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3283                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3284                 c++)
3285 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3286 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3287 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3288                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3289 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3290                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3291 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3292                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3293 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3294 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3295 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3296 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3297 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3298 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3299 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3300 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3301 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3302
3303 AC_SUBST(FLAGS_FOR_TARGET)
3304 AC_SUBST(RAW_CXX_FOR_TARGET)
3305
3306 # Certain tools may need extra flags.
3307 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3308 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3309 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3310
3311 # When building target libraries, except in a Canadian cross, we use
3312 # the same toolchain as the compiler we just built.
3313 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3314 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3315 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3316 if test $host = $build; then
3317   case " $configdirs " in
3318     *" gcc "*)
3319       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3320       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3321       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3322       ;;
3323   esac
3324 fi
3325
3326 AC_SUBST(COMPILER_AS_FOR_TARGET)
3327 AC_SUBST(COMPILER_LD_FOR_TARGET)
3328 AC_SUBST(COMPILER_NM_FOR_TARGET)
3329
3330 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3331 AC_ARG_ENABLE(maintainer-mode,
3332 [AS_HELP_STRING([--enable-maintainer-mode],
3333                 [enable make rules and dependencies not useful
3334                  (and sometimes confusing) to the casual installer])],
3335       USE_MAINTAINER_MODE=$enableval,
3336       USE_MAINTAINER_MODE=no)
3337 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3338 AC_SUBST(MAINTAINER_MODE_TRUE)
3339 AC_SUBST(MAINTAINER_MODE_FALSE)
3340 if test "$USE_MAINTAINER_MODE" = yes; then
3341   MAINTAINER_MODE_TRUE=
3342   MAINTAINER_MODE_FALSE='#'
3343 else
3344   MAINTAINER_MODE_TRUE='#'
3345   MAINTAINER_MODE_FALSE=
3346 fi
3347 MAINT=$MAINTAINER_MODE_TRUE
3348 AC_SUBST(MAINT)dnl
3349
3350 # ---------------------
3351 # GCC bootstrap support
3352 # ---------------------
3353
3354 # Stage specific cflags for build.
3355 stage1_cflags="-g"
3356 case $build in
3357   vax-*-*)
3358     case ${GCC} in
3359       yes) stage1_cflags="-g -Wa,-J" ;;
3360       *) stage1_cflags="-g -J" ;;
3361     esac ;;
3362 esac
3363
3364 AC_SUBST(stage1_cflags)
3365
3366 # Enable --enable-checking in stage1 of the compiler.
3367 AC_ARG_ENABLE(stage1-checking,
3368 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3369                 [choose additional checking for stage1 of the compiler])],
3370 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3371 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3372   stage1_checking=--enable-checking=yes,types
3373 else
3374   stage1_checking=--enable-checking=$enable_checking,types
3375 fi])
3376 AC_SUBST(stage1_checking)
3377
3378 # Enable -Werror in bootstrap stage2 and later.
3379 AC_ARG_ENABLE(werror,
3380 [AS_HELP_STRING([--enable-werror],
3381                 [enable -Werror in bootstrap stage2 and later])], [],
3382 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3383   enable_werror=yes
3384 else
3385   enable_werror=no
3386 fi])
3387 case ${enable_werror} in
3388   yes) stage2_werror_flag="--enable-werror-always" ;;
3389   *) stage2_werror_flag="" ;;
3390 esac
3391 AC_SUBST(stage2_werror_flag)
3392
3393 # Enable --enable-host-shared.
3394 AC_ARG_ENABLE(host-shared,
3395 [AS_HELP_STRING([--enable-host-shared],
3396                 [build host code as shared libraries])],
3397 [host_shared=$enableval], [host_shared=no])
3398 AC_SUBST(host_shared)
3399
3400 # Specify what files to not compare during bootstrap.
3401
3402 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3403 case "$target" in
3404   hppa*64*-*-hpux*) ;;
3405   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3406   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3407 esac
3408 AC_SUBST(compare_exclusions)
3409
3410 AC_CONFIG_FILES([Makefile],
3411   [sed "$extrasub_build" Makefile |
3412    sed "$extrasub_host" |
3413    sed "$extrasub_target" > mf$$
3414    mv -f mf$$ Makefile],
3415   [extrasub_build="$extrasub_build"
3416    extrasub_host="$extrasub_host"
3417    extrasub_target="$extrasub_target"])
3418 AC_OUTPUT