configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libhsail-rt \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo \
 167                 target-libphobos \
 168                 target-zlib"
 169
 170 # these tools are built using the target libraries, and are intended to
 171 # run only in the target environment
 172 #
 173 # note: any program that *uses* libraries that are in the "target_libraries"
 174 # list belongs in this list.
 175 #
 176 target_tools="target-rda"
 177
 178 ################################################################################
 179
 180 ## All tools belong in one of the four categories, and are assigned above
 181 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 182 ## is important because configure will choke if they ever get through.
 183 ## ${configdirs} is directories we build using the host tools.
 184 ## ${target_configdirs} is directories we build using the target tools.
 185 configdirs=`echo ${host_libs} ${host_tools}`
 186 target_configdirs=`echo ${target_libraries} ${target_tools}`
 187 build_configdirs=`echo ${build_libs} ${build_tools}`
 188
 189 m4_divert_text([PARSE_ARGS],
 190 [case $srcdir in
 191   *" "*)
 192 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 193     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 194 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 195     ;;
 196 esac
 197 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 198 ])
 199
 200 ################################################################################
 201
 202 srcname="gnu development package"
 203
 204 # This gets set non-empty for some net releases of packages.
 205 appdirs=""
 206
 207 # Define is_cross_compiler to save on calls to 'test'.
 208 is_cross_compiler=
 209 if test x"${host}" = x"${target}" ; then
 210   is_cross_compiler=no
 211 else
 212   is_cross_compiler=yes
 213 fi
 214
 215 # Find the build and target subdir names.
 216 GCC_TOPLEV_SUBDIRS
 217 # Be sure to cover against remnants of an in-tree build.
 218 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 219   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 220 Use a pristine source tree when building in a separate tree])
 221 fi
 222
 223 # Skipdirs are removed silently.
 224 skipdirs=
 225 # Noconfigdirs are removed loudly.
 226 noconfigdirs=""
 227
 228 use_gnu_ld=
 229 # Make sure we don't let GNU ld be added if we didn't want it.
 230 if test x$with_gnu_ld = xno ; then
 231   use_gnu_ld=no
 232   noconfigdirs="$noconfigdirs ld gold"
 233 fi
 234
 235 use_gnu_as=
 236 # Make sure we don't let GNU as be added if we didn't want it.
 237 if test x$with_gnu_as = xno ; then
 238   use_gnu_as=no
 239   noconfigdirs="$noconfigdirs gas"
 240 fi
 241
 242 use_included_zlib=
 243 AC_ARG_WITH(system-zlib,
 244 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 245 # Make sure we don't let ZLIB be added if we didn't want it.
 246 if test x$with_system_zlib = xyes ; then
 247   use_included_zlib=no
 248   noconfigdirs="$noconfigdirs zlib"
 249 fi
 250
 251 # some tools are so dependent upon X11 that if we're not building with X,
 252 # it's not even worth trying to configure, much less build, that tool.
 253
 254 case ${with_x} in
 255   yes | "") ;; # the default value for this tree is that X11 is available
 256   no)
 257     skipdirs="${skipdirs} tk itcl libgui"
 258     # We won't be able to build gdbtk without X.
 259     enable_gdbtk=no
 260     ;;
 261   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 262 esac
 263
 264 # Some are only suitable for cross toolchains.
 265 # Remove these if host=target.
 266 cross_only="target-libgloss target-newlib target-opcodes"
 267
 268 case $is_cross_compiler in
 269   no) skipdirs="${skipdirs} ${cross_only}" ;;
 270 esac
 271
 272 # If both --with-headers and --with-libs are specified, default to
 273 # --without-newlib.
 274 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 275    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 276   if test x"${with_newlib}" = x ; then
 277     with_newlib=no
 278   fi
 279 fi
 280
 281 # Recognize --with-newlib/--without-newlib.
 282 case ${with_newlib} in
 283   no) skipdirs="${skipdirs} target-newlib" ;;
 284   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 285 esac
 286
 287 AC_ARG_ENABLE(as-accelerator-for,
 288 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 289                 [build as offload target compiler.
 290                 Specify offload host triple by ARG])])
 291
 292 AC_ARG_ENABLE(offload-targets,
 293 [AS_HELP_STRING([--enable-offload-targets=LIST],
 294                 [enable offloading to devices from comma-separated LIST of
 295                 TARGET[=DIR]. Use optional path to find offload target compiler
 296                 during the build])],
 297 [
 298   if test x"$enable_offload_targets" = x; then
 299     AC_MSG_ERROR([no offload targets specified])
 300   fi
 301 ], [enable_offload_targets=])
 302
 303 # Handle --enable-gold, --enable-ld.
 304 # --disable-gold [--enable-ld]
 305 #     Build only ld.  Default option.
 306 # --enable-gold [--enable-ld]
 307 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 308 #     as "ld.bfd" and "ld".
 309 # --enable-gold=default [--enable-ld]
 310 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 311 #     install ld as "ld.bfd".
 312 # --enable-gold[=default] --disable-ld
 313 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 314 # --enable-gold --enable-ld=default
 315 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 316 #     and ld.bfd).
 317 #     In other words, ld is default
 318 # --enable-gold=default --enable-ld=default
 319 #     Error.
 320
 321 default_ld=
 322 AC_ARG_ENABLE(gold,
 323 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 324                 [build gold @<:@ARG={default,yes,no}@:>@])],
 325 ENABLE_GOLD=$enableval,
 326 ENABLE_GOLD=no)
 327 case "${ENABLE_GOLD}" in
 328   yes|default)
 329     # Check for ELF target.
 330     is_elf=no
 331     case "${target}" in
 332       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 333       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 334       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 335       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 336         case "${target}" in
 337           *-*-linux*aout* | *-*-linux*oldld*)
 338             ;;
 339           *)
 340             is_elf=yes
 341             ;;
 342         esac
 343     esac
 344
 345     if test "$is_elf" = "yes"; then
 346       # Check for target supported by gold.
 347       case "${target}" in
 348         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 349         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 350           configdirs="$configdirs gold"
 351           if test x${ENABLE_GOLD} = xdefault; then
 352             default_ld=gold
 353           fi
 354           ENABLE_GOLD=yes
 355           ;;
 356       esac
 357     fi
 358     ;;
 359   no)
 360     ;;
 361   *)
 362     AC_MSG_ERROR([invalid --enable-gold argument])
 363     ;;
 364 esac
 365
 366 AC_ARG_ENABLE(ld,
 367 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 368                 [build ld @<:@ARG={default,yes,no}@:>@])],
 369 ENABLE_LD=$enableval,
 370 ENABLE_LD=yes)
 371
 372 case "${ENABLE_LD}" in
 373   default)
 374     if test x${default_ld} != x; then
 375       AC_MSG_ERROR([either gold or ld can be the default ld])
 376     fi
 377     ;;
 378   yes)
 379     ;;
 380   no)
 381     if test x${ENABLE_GOLD} != xyes; then
 382       AC_MSG_WARN([neither ld nor gold are enabled])
 383     fi
 384     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 385     ;;
 386   *)
 387     AC_MSG_ERROR([invalid --enable-ld argument])
 388     ;;
 389 esac
 390
 391 # PR gas/19109
 392 # Decide the default method for compressing debug sections.
 393 # Provide a configure time option to override our default.
 394 AC_ARG_ENABLE(compressed_debug_sections,
 395 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 396                 [Enable compressed debug sections for gas, gold or ld by
 397                  default])],
 398 [
 399   if test x"$enable_compressed_debug_sections" = xyes; then
 400     AC_MSG_ERROR([no program with compressed debug sections specified])
 401   fi
 402 ], [enable_compressed_debug_sections=])
 403
 404 # Configure extra directories which are host specific
 405
 406 case "${host}" in
 407   *-cygwin*)
 408     configdirs="$configdirs libtermcap" ;;
 409 esac
 410
 411 # A target can indicate whether a language isn't supported for some reason.
 412 # Only spaces may be used in this macro; not newlines or tabs.
 413 unsupported_languages=
 414
 415 # Remove more programs from consideration, based on the host or
 416 # target this usually means that a port of the program doesn't
 417 # exist yet.
 418
 419 case "${host}" in
 420   i[[3456789]]86-*-msdosdjgpp*)
 421     noconfigdirs="$noconfigdirs tcl tk itcl"
 422     ;;
 423 esac
 424
 425
 426 AC_ARG_ENABLE(libquadmath,
 427 AS_HELP_STRING([--disable-libquadmath],
 428   [do not build libquadmath directory]),
 429 ENABLE_LIBQUADMATH=$enableval,
 430 ENABLE_LIBQUADMATH=yes)
 431 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 432   noconfigdirs="$noconfigdirs target-libquadmath"
 433 fi
 434
 435
 436 AC_ARG_ENABLE(libquadmath-support,
 437 AS_HELP_STRING([--disable-libquadmath-support],
 438   [disable libquadmath support for Fortran]),
 439 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 440 ENABLE_LIBQUADMATH_SUPPORT=yes)
 441 enable_libquadmath_support=
 442 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 443   enable_libquadmath_support=no
 444 fi
 445
 446
 447 AC_ARG_ENABLE(libada,
 448 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 449 ENABLE_LIBADA=$enableval,
 450 ENABLE_LIBADA=yes)
 451 if test "${ENABLE_LIBADA}" != "yes" ; then
 452   noconfigdirs="$noconfigdirs gnattools"
 453 fi
 454
 455 AC_ARG_ENABLE(libssp,
 456 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 457 ENABLE_LIBSSP=$enableval,
 458 ENABLE_LIBSSP=yes)
 459
 460 AC_ARG_ENABLE(libstdcxx,
 461 AS_HELP_STRING([--disable-libstdcxx],
 462   [do not build libstdc++-v3 directory]),
 463 ENABLE_LIBSTDCXX=$enableval,
 464 ENABLE_LIBSTDCXX=default)
 465 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 466   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 467 fi]
 468
 469 # If this is accelerator compiler and its target is intelmic we enable
 470 # target liboffloadmic by default.  If this is compiler with offloading
 471 # for intelmic we enable host liboffloadmic by default.  Otherwise
 472 # liboffloadmic is disabled by default.
 473 AC_ARG_ENABLE([liboffloadmic],
 474 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 475                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 476 [case "$enableval" in
 477   no | host | target)
 478     enable_liboffloadmic=$enableval ;;
 479   *)
 480     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 481 esac],
 482 [if test x"$enable_as_accelerator_for" != x; then
 483   case "${target}" in
 484     *-intelmic-* | *-intelmicemul-*)
 485       enable_liboffloadmic=target
 486       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 487       ;;
 488     *)
 489       enable_liboffloadmic=no
 490       ;;
 491   esac
 492 else
 493   case "${enable_offload_targets}" in
 494     *-intelmic-* | *-intelmicemul-*)
 495       enable_liboffloadmic=host
 496       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 497       ;;
 498     *)
 499       enable_liboffloadmic=no
 500       ;;
 501     esac
 502 fi])
 503 AC_SUBST(extra_liboffloadmic_configure_flags)
 504
 505 # Enable libgomp by default on hosted POSIX systems, and a few others.
 506 if test x$enable_libgomp = x ; then
 507     case "${target}" in
 508     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 509         ;;
 510     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 511         ;;
 512     *-*-solaris2* | *-*-hpux11*)
 513         ;;
 514     *-*-darwin* | *-*-aix*)
 515         ;;
 516     nvptx*-*-* | amdgcn*-*-*)
 517         ;;
 518     *)
 519         noconfigdirs="$noconfigdirs target-libgomp"
 520         ;;
 521     esac
 522 fi
 523
 524 # Disable libatomic on unsupported systems.
 525 if test -d ${srcdir}/libatomic; then
 526     if test x$enable_libatomic = x; then
 527         AC_MSG_CHECKING([for libatomic support])
 528         if (srcdir=${srcdir}/libatomic; \
 529                 . ${srcdir}/configure.tgt; \
 530                 test -n "$UNSUPPORTED")
 531         then
 532             AC_MSG_RESULT([no])
 533             noconfigdirs="$noconfigdirs target-libatomic"
 534         else
 535             AC_MSG_RESULT([yes])
 536         fi
 537     fi
 538 fi
 539
 540 # Disable liboffloadmic on unsupported systems.
 541 if test -d ${srcdir}/liboffloadmic; then
 542     if test x$enable_liboffloadmic != xno; then
 543         AC_MSG_CHECKING([for liboffloadmic support])
 544         if (srcdir=${srcdir}/liboffloadmic; \
 545                 . ${srcdir}/configure.tgt; \
 546                 test -n "$UNSUPPORTED")
 547         then
 548             AC_MSG_RESULT([no])
 549             noconfigdirs="$noconfigdirs target-liboffloadmic"
 550         else
 551             AC_MSG_RESULT([yes])
 552         fi
 553     fi
 554 fi
 555
 556 # Disable libitm on unsupported systems.
 557 if test -d ${srcdir}/libitm; then
 558     if test x$enable_libitm = x; then
 559         AC_MSG_CHECKING([for libitm support])
 560         if (srcdir=${srcdir}/libitm; \
 561                 . ${srcdir}/configure.tgt; \
 562                 test -n "$UNSUPPORTED")
 563         then
 564             AC_MSG_RESULT([no])
 565             noconfigdirs="$noconfigdirs target-libitm"
 566         else
 567             AC_MSG_RESULT([yes])
 568         fi
 569     fi
 570 fi
 571
 572 # Disable libsanitizer on unsupported systems.
 573 if test -d ${srcdir}/libsanitizer; then
 574     if test x$enable_libsanitizer = x; then
 575         AC_MSG_CHECKING([for libsanitizer support])
 576         if (srcdir=${srcdir}/libsanitizer; \
 577                 . ${srcdir}/configure.tgt; \
 578                 test -n "$UNSUPPORTED")
 579         then
 580             AC_MSG_RESULT([no])
 581             noconfigdirs="$noconfigdirs target-libsanitizer"
 582         else
 583             AC_MSG_RESULT([yes])
 584         fi
 585     fi
 586 fi
 587
 588 # Disable libvtv on unsupported systems.
 589 if test -d ${srcdir}/libvtv; then
 590     if test x$enable_libvtv = x; then
 591         AC_MSG_CHECKING([for libvtv support])
 592         if (srcdir=${srcdir}/libvtv; \
 593                 . ${srcdir}/configure.tgt; \
 594                 test "$VTV_SUPPORTED" != "yes")
 595         then
 596             AC_MSG_RESULT([no])
 597             noconfigdirs="$noconfigdirs target-libvtv"
 598         else
 599             AC_MSG_RESULT([yes])
 600         fi
 601     fi
 602 fi
 603
 604
 605 # Disable libhsail-rt on unsupported systems.
 606 if test -d ${srcdir}/libhsail-rt; then
 607     if test x$enable_libhsail_rt = x; then
 608         AC_MSG_CHECKING([for libhsail-rt support])
 609         if (srcdir=${srcdir}/libhsail-rt; \
 610                 . ${srcdir}/configure.tgt; \
 611                 test -n "$UNSUPPORTED")
 612         then
 613             AC_MSG_RESULT([no])
 614             unsupported_languages="$unsupported_languages brig"
 615             # This implicitly disables also target-libhsail-rt as it won't
 616             # get added to the build without BRIG FE.
 617         else
 618             AC_MSG_RESULT([yes])
 619         fi
 620     fi
 621 fi
 622
 623
 624 # Disable libquadmath for some systems.
 625 case "${target}" in
 626   avr-*-*)
 627     noconfigdirs="$noconfigdirs target-libquadmath"
 628     ;;
 629   # libquadmath is unused on AIX and libquadmath build process use of
 630   # LD_LIBRARY_PATH can break AIX bootstrap.
 631   powerpc-*-aix* | rs6000-*-aix*)
 632     noconfigdirs="$noconfigdirs target-libquadmath"
 633     ;;
 634 esac
 635
 636 # Disable libssp for some systems.
 637 case "${target}" in
 638   avr-*-*)
 639     # No hosted I/O support.
 640     noconfigdirs="$noconfigdirs target-libssp"
 641     ;;
 642   bpf-*-*)
 643     noconfigdirs="$noconfigdirs target-libssp"
 644     ;;
 645   powerpc-*-aix* | rs6000-*-aix*)
 646     noconfigdirs="$noconfigdirs target-libssp"
 647     ;;
 648   pru-*-*)
 649     # No hosted I/O support.
 650     noconfigdirs="$noconfigdirs target-libssp"
 651     ;;
 652   rl78-*-*)
 653     # libssp uses a misaligned load to trigger a fault, but the RL78
 654     # doesn't fault for those - instead, it gives a build-time error
 655     # for explicit misaligned loads.
 656     noconfigdirs="$noconfigdirs target-libssp"
 657     ;;
 658   visium-*-*)
 659     # No hosted I/O support.
 660     noconfigdirs="$noconfigdirs target-libssp"
 661     ;;
 662 esac
 663
 664 # Disable libstdc++-v3 for some systems.
 665 # Allow user to override this if they pass --enable-libstdc++-v3
 666 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 667   case "${target}" in
 668     *-*-vxworks*)
 669       # VxWorks uses the Dinkumware C++ library.
 670       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 671       ;;
 672     amdgcn*-*-*)
 673       # Not ported/fails to build when using newlib.
 674       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 675       ;;
 676     arm*-wince-pe*)
 677       # the C++ libraries don't build on top of CE's C libraries
 678       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 679       ;;
 680     avr-*-*)
 681       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 682       ;;
 683     bpf-*-*)
 684       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 685       ;;
 686     ft32-*-*)
 687       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 688       ;;
 689   esac
 690 fi
 691
 692 # Disable C++ on systems where it is known to not work.
 693 # For testing, you can override this with --enable-languages=c++.
 694 case ,${enable_languages}, in
 695   *,c++,*)
 696     ;;
 697   *)
 698       case "${target}" in
 699         bpf-*-*)
 700           unsupported_languages="$unsupported_languages c++"
 701           ;;
 702       esac
 703       ;;
 704 esac
 705
 706 # Disable Objc on systems where it is known to not work.
 707 # For testing, you can override this with --enable-languages=objc.
 708 case ,${enable_languages}, in
 709   *,objc,*)
 710     ;;
 711   *)
 712       case "${target}" in
 713         bpf-*-*)
 714           unsupported_languages="$unsupported_languages objc"
 715           ;;
 716       esac
 717       ;;
 718 esac
 719
 720 # Disable D on systems where it is known to not work.
 721 # For testing, you can override this with --enable-languages=d.
 722 case ,${enable_languages}, in
 723   *,d,*)
 724     ;;
 725   *)
 726     case "${target}" in
 727       *-*-darwin*)
 728         unsupported_languages="$unsupported_languages d"
 729         ;;
 730       bpf-*-*)
 731         unsupported_languages="$unsupported_languages d"
 732         ;;
 733     esac
 734     ;;
 735 esac
 736
 737 # Disable libphobos on unsupported systems.
 738 # For testing, you can override this with --enable-libphobos.
 739 if test -d ${srcdir}/libphobos; then
 740     if test x$enable_libphobos = x; then
 741         AC_MSG_CHECKING([for libphobos support])
 742         if (srcdir=${srcdir}/libphobos; \
 743                 . ${srcdir}/configure.tgt; \
 744                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 745         then
 746             AC_MSG_RESULT([no])
 747             noconfigdirs="$noconfigdirs target-libphobos"
 748         else
 749             AC_MSG_RESULT([yes])
 750         fi
 751     fi
 752 fi
 753
 754 # Disable Fortran for some systems.
 755 case "${target}" in
 756   mmix-*-*)
 757     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 758     unsupported_languages="$unsupported_languages fortran"
 759     ;;
 760   bpf-*-*)
 761     unsupported_languages="$unsupported_languages fortran"
 762     ;;
 763 esac
 764
 765 # Disable libffi for some systems.
 766 case "${target}" in
 767   powerpc-*-darwin*)
 768     ;;
 769   i[[3456789]]86-*-darwin*)
 770     ;;
 771   x86_64-*-darwin[[912]]*)
 772     ;;
 773   *-*-darwin*)
 774     noconfigdirs="$noconfigdirs target-libffi"
 775     ;;
 776   *-*-netware*)
 777     noconfigdirs="$noconfigdirs target-libffi"
 778     ;;
 779   *-*-phoenix*)
 780     noconfigdirs="$noconfigdirs target-libffi"
 781     ;;
 782   *-*-rtems*)
 783     noconfigdirs="$noconfigdirs target-libffi"
 784     ;;
 785   *-*-tpf*)
 786     noconfigdirs="$noconfigdirs target-libffi"
 787     ;;
 788   *-*-uclinux*)
 789     noconfigdirs="$noconfigdirs target-libffi"
 790     ;;
 791   *-*-vxworks*)
 792     noconfigdirs="$noconfigdirs target-libffi"
 793     ;;
 794   aarch64*-*-freebsd*)
 795     noconfigdirs="$noconfigdirs target-libffi"
 796     ;;
 797   alpha*-*-*vms*)
 798     noconfigdirs="$noconfigdirs target-libffi"
 799     ;;
 800   arm*-*-freebsd*)
 801     noconfigdirs="$noconfigdirs target-libffi"
 802     ;;
 803   arm-wince-pe)
 804     noconfigdirs="$noconfigdirs target-libffi"
 805     ;;
 806   arm*-*-symbianelf*)
 807     noconfigdirs="$noconfigdirs target-libffi"
 808     ;;
 809   bpf-*-*)
 810     noconfigdirs="$noconfigdirs target-libffi"
 811     ;;
 812   cris-*-* | crisv32-*-*)
 813     case "${target}" in
 814       *-*-linux*)
 815         ;;
 816       *) # See PR46792 regarding target-libffi.
 817         noconfigdirs="$noconfigdirs target-libffi";;
 818     esac
 819     ;;
 820   hppa*64*-*-hpux*)
 821     noconfigdirs="$noconfigdirs target-libffi"
 822     ;;
 823   hppa*-hp-hpux11*)
 824     ;;
 825   hppa*-*-hpux*)
 826     noconfigdirs="$noconfigdirs target-libffi"
 827     ;;
 828   ia64*-*-*vms*)
 829     noconfigdirs="$noconfigdirs target-libffi"
 830     ;;
 831   i[[3456789]]86-w64-mingw*)
 832     noconfigdirs="$noconfigdirs target-libffi"
 833     ;;
 834   i[[3456789]]86-*-mingw*)
 835     noconfigdirs="$noconfigdirs target-libffi"
 836     ;;
 837   x86_64-*-mingw*)
 838     noconfigdirs="$noconfigdirs target-libffi"
 839     ;;
 840   mmix-*-*)
 841     noconfigdirs="$noconfigdirs target-libffi"
 842     ;;
 843   powerpc-*-aix*)
 844     ;;
 845   rs6000-*-aix*)
 846     ;;
 847   ft32-*-*)
 848     noconfigdirs="$noconfigdirs target-libffi"
 849     ;;
 850   *-*-lynxos*)
 851     noconfigdirs="$noconfigdirs target-libffi"
 852     ;;
 853 esac
 854
 855 # Disable the go frontend on systems where it is known to not work. Please keep
 856 # this in sync with contrib/config-list.mk.
 857 case "${target}" in
 858 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 859     unsupported_languages="$unsupported_languages go"
 860     ;;
 861 esac
 862
 863 # Only allow gdbserver on some systems.
 864 if test -d ${srcdir}/gdbserver; then
 865     if test x$enable_gdbserver = x; then
 866         AC_MSG_CHECKING([for gdbserver support])
 867         if (srcdir=${srcdir}/gdbserver; \
 868                 . ${srcdir}/configure.srv; \
 869                 test -n "$UNSUPPORTED")
 870         then
 871             AC_MSG_RESULT([no])
 872             noconfigdirs="$noconfigdirs gdbserver"
 873         else
 874             AC_MSG_RESULT([yes])
 875         fi
 876     fi
 877 fi
 878
 879 # Disable libgo for some systems where it is known to not work.
 880 # For testing, you can easily override this with --enable-libgo.
 881 if test x$enable_libgo = x; then
 882     case "${target}" in
 883     *-*-darwin*)
 884         # PR 46986
 885         noconfigdirs="$noconfigdirs target-libgo"
 886         ;;
 887     *-*-cygwin* | *-*-mingw*)
 888         noconfigdirs="$noconfigdirs target-libgo"
 889         ;;
 890     bpf-*-*)
 891         noconfigdirs="$noconfigdirs target-libgo"
 892         ;;
 893     esac
 894 fi
 895
 896 # Default libgloss CPU subdirectory.
 897 libgloss_dir="$target_cpu"
 898
 899 case "${target}" in
 900   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 901     libgloss_dir=wince
 902     ;;
 903   aarch64*-*-* )
 904     libgloss_dir=aarch64
 905     ;;
 906   arm*-*-*)
 907     libgloss_dir=arm
 908     ;;
 909   cris-*-* | crisv32-*-*)
 910     libgloss_dir=cris
 911     ;;
 912   hppa*-*-*)
 913     libgloss_dir=pa
 914     ;;
 915   i[[3456789]]86-*-*)
 916     libgloss_dir=i386
 917     ;;
 918   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 919     libgloss_dir=m68hc11
 920     ;;
 921   m68*-*-* | fido-*-*)
 922     libgloss_dir=m68k
 923     ;;
 924   mips*-*-*)
 925     libgloss_dir=mips
 926     ;;
 927   powerpc*-*-*)
 928     libgloss_dir=rs6000
 929     ;;
 930   pru-*-*)
 931     libgloss_dir=pru
 932     ;;
 933   sparc*-*-*)
 934     libgloss_dir=sparc
 935     ;;
 936 esac
 937
 938 # Disable newlib and libgloss for various target OSes.
 939 case "${target}" in
 940   alpha*-dec-osf*)
 941     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 942     ;;
 943   i[[3456789]]86-*-linux*)
 944     # This section makes it possible to build newlib natively on linux.
 945     # If we are using a cross compiler then don't configure newlib.
 946     if test x${is_cross_compiler} != xno ; then
 947       noconfigdirs="$noconfigdirs target-newlib"
 948     fi
 949     noconfigdirs="$noconfigdirs target-libgloss"
 950     # If we are not using a cross compiler, do configure newlib.
 951     # Note however, that newlib will only be configured in this situation
 952     # if the --with-newlib option has been given, because otherwise
 953     # 'target-newlib' will appear in skipdirs.
 954     ;;
 955   i[[3456789]]86-*-rdos*)
 956     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 957     ;;
 958   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 959     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 960     ;;
 961   sparc-*-sunos4*)
 962     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 963     ;;
 964   bpf-*-*)
 965     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 966     ;;
 967   *-*-aix*)
 968     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 969     ;;
 970   *-*-beos*)
 971     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 972     ;;
 973   *-*-chorusos)
 974     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 975     ;;
 976   *-*-dragonfly*)
 977     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 978     ;;
 979   *-*-freebsd*)
 980     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 981     ;;
 982   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 983     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 984     ;;
 985   *-*-lynxos*)
 986     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 987     ;;
 988   *-*-mingw*)
 989     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 990     ;;
 991   *-*-netbsd*)
 992     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 993     ;;
 994   *-*-netware*)
 995     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 996     ;;
 997   *-*-tpf*)
 998     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 999     ;;
1000   *-*-uclinux*)
1001     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1002     ;;
1003   *-*-vxworks*)
1004     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1005     ;;
1006 esac
1007
1008 case "${target}" in
1009   *-*-chorusos)
1010     ;;
1011   aarch64-*-darwin*)
1012     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1013     noconfigdirs="$noconfigdirs sim target-rda"
1014     ;;
1015   amdgcn*-*-*)
1016     ;;
1017   arm-*-darwin*)
1018     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1019     noconfigdirs="$noconfigdirs sim target-rda"
1020     ;;
1021   powerpc-*-darwin*)
1022     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1023     noconfigdirs="$noconfigdirs sim target-rda"
1024     ;;
1025   i[[3456789]]86-*-darwin*)
1026     noconfigdirs="$noconfigdirs ld gprof"
1027     noconfigdirs="$noconfigdirs sim target-rda"
1028     ;;
1029   x86_64-*-darwin[[912]]*)
1030     noconfigdirs="$noconfigdirs ld gas gprof"
1031     noconfigdirs="$noconfigdirs sim target-rda"
1032     ;;
1033   *-*-darwin*)
1034     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1035     noconfigdirs="$noconfigdirs sim target-rda"
1036     ;;
1037   *-*-dragonfly*)
1038     ;;
1039   *-*-freebsd*)
1040     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
1041         && ! test -d ${srcdir}/gmp \
1042         && test -f /usr/local/include/gmp.h; then
1043       with_gmp=/usr/local
1044     fi
1045     ;;
1046   *-*-kaos*)
1047     # Remove unsupported stuff on all kaOS configurations.
1048     noconfigdirs="$noconfigdirs target-libgloss"
1049     ;;
1050   *-*-netbsd*)
1051     ;;
1052   *-*-netware*)
1053     ;;
1054   *-*-phoenix*)
1055     noconfigdirs="$noconfigdirs target-libgloss"
1056     ;;
1057   *-*-rtems*)
1058     noconfigdirs="$noconfigdirs target-libgloss"
1059     ;;
1060     # The tpf target doesn't support gdb yet.
1061   *-*-tpf*)
1062     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1063     ;;
1064   *-*-uclinux*)
1065     noconfigdirs="$noconfigdirs target-rda"
1066     ;;
1067   *-*-vxworks*)
1068     ;;
1069   alpha*-dec-osf*)
1070     # ld works, but does not support shared libraries.
1071     # gas doesn't generate exception information.
1072     noconfigdirs="$noconfigdirs gas ld"
1073     ;;
1074   alpha*-*-*vms*)
1075     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1076     ;;
1077   alpha*-*-*)
1078     # newlib is not 64 bit ready
1079     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1080     ;;
1081   bpf-*-*)
1082     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1083     ;;
1084   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1085     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1086     ;;
1087   arc*-*-*)
1088     noconfigdirs="$noconfigdirs sim"
1089     ;;
1090   arm-*-pe*)
1091     noconfigdirs="$noconfigdirs target-libgloss"
1092     ;;
1093   arm-*-riscix*)
1094     noconfigdirs="$noconfigdirs ld target-libgloss"
1095     ;;
1096   avr-*-*)
1097     if test x${with_avrlibc} != xno; then
1098       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1099     fi
1100     ;;
1101   c4x-*-* | tic4x-*-*)
1102     noconfigdirs="$noconfigdirs target-libgloss"
1103     ;;
1104   tic54x-*-*)
1105     noconfigdirs="$noconfigdirs target-libgloss gdb"
1106     ;;
1107   d10v-*-*)
1108     noconfigdirs="$noconfigdirs target-libgloss"
1109     ;;
1110   d30v-*-*)
1111     noconfigdirs="$noconfigdirs gdb"
1112     ;;
1113   fr30-*-elf*)
1114     noconfigdirs="$noconfigdirs gdb"
1115     ;;
1116   ft32-*-*)
1117     noconfigdirs="$noconfigdirs target-rda gprof"
1118     ;;
1119   moxie-*-*)
1120     noconfigdirs="$noconfigdirs"
1121     ;;
1122   h8300*-*-*)
1123     noconfigdirs="$noconfigdirs target-libgloss"
1124     ;;
1125   h8500-*-*)
1126     noconfigdirs="$noconfigdirs target-libgloss"
1127     ;;
1128   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1129     ;;
1130   hppa*64*-*-hpux*)
1131     noconfigdirs="$noconfigdirs gdb"
1132     ;;
1133   hppa*-*-hpux11*)
1134     noconfigdirs="$noconfigdirs gdb ld"
1135     ;;
1136   hppa*64*-*-linux*)
1137     ;;
1138   hppa*-*-linux*)
1139     ;;
1140   hppa*-*-*elf* | \
1141   hppa*-*-lites* | \
1142   hppa*-*-openbsd* | \
1143   hppa*64*-*-*)
1144     ;;
1145   hppa*-*-pro*)
1146     ;;
1147   hppa*-*-*)
1148     noconfigdirs="$noconfigdirs ld"
1149     ;;
1150   i960-*-*)
1151     noconfigdirs="$noconfigdirs gdb"
1152     ;;
1153   ia64*-*-elf*)
1154     # No gdb support yet.
1155     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1156     ;;
1157   ia64*-**-hpux*)
1158     # No ld support yet.
1159     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1160     ;;
1161   ia64*-*-*vms*)
1162     # No ld support yet.
1163     noconfigdirs="$noconfigdirs libgui itcl ld"
1164     ;;
1165   i[[3456789]]86-w64-mingw*)
1166     ;;
1167   i[[3456789]]86-*-mingw*)
1168     target_configdirs="$target_configdirs target-winsup"
1169     ;;
1170   *-*-cygwin*)
1171     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1172     noconfigdirs="$noconfigdirs target-libgloss"
1173     # always build newlib if winsup directory is present.
1174     if test -d "$srcdir/winsup/cygwin"; then
1175       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1176     elif test -d "$srcdir/newlib"; then
1177       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1178     fi
1179     ;;
1180   i[[3456789]]86-*-pe)
1181     noconfigdirs="$noconfigdirs target-libgloss"
1182     ;;
1183   i[[3456789]]86-*-sco3.2v5*)
1184     # The linker does not yet know about weak symbols in COFF,
1185     # and is not configured to handle mixed ELF and COFF.
1186     noconfigdirs="$noconfigdirs ld target-libgloss"
1187     ;;
1188   i[[3456789]]86-*-sco*)
1189     noconfigdirs="$noconfigdirs gprof target-libgloss"
1190     ;;
1191   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1192     noconfigdirs="$noconfigdirs target-libgloss"
1193     ;;
1194   i[[3456789]]86-*-sysv4*)
1195     noconfigdirs="$noconfigdirs target-libgloss"
1196     ;;
1197   i[[3456789]]86-*-beos*)
1198     noconfigdirs="$noconfigdirs gdb"
1199     ;;
1200   i[[3456789]]86-*-rdos*)
1201     noconfigdirs="$noconfigdirs gdb"
1202     ;;
1203   mmix-*-*)
1204     noconfigdirs="$noconfigdirs gdb"
1205     ;;
1206   mt-*-*)
1207     noconfigdirs="$noconfigdirs sim"
1208     ;;
1209   nfp-*-*)
1210     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1211     noconfigdirs="$noconfigdirs $target_libraries"
1212     ;;
1213   pdp11-*-*)
1214     noconfigdirs="$noconfigdirs gdb gprof"
1215     ;;
1216   powerpc-*-aix*)
1217     # copied from rs6000-*-* entry
1218     noconfigdirs="$noconfigdirs gprof"
1219     ;;
1220   powerpc*-*-winnt* | powerpc*-*-pe*)
1221     target_configdirs="$target_configdirs target-winsup"
1222     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1223     # always build newlib.
1224     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1225     ;;
1226     # This is temporary until we can link against shared libraries
1227   powerpcle-*-solaris*)
1228     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1229     ;;
1230   powerpc-*-beos*)
1231     noconfigdirs="$noconfigdirs gdb"
1232     ;;
1233   rs6000-*-lynxos*)
1234     noconfigdirs="$noconfigdirs gprof"
1235     ;;
1236   rs6000-*-aix*)
1237     noconfigdirs="$noconfigdirs gprof"
1238     ;;
1239   rs6000-*-*)
1240     noconfigdirs="$noconfigdirs gprof"
1241     ;;
1242   m68k-apollo-*)
1243     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1244     ;;
1245   microblaze*)
1246     noconfigdirs="$noconfigdirs gprof"
1247     ;;
1248   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1249     if test x$with_newlib = xyes; then
1250       noconfigdirs="$noconfigdirs gprof"
1251     fi
1252     ;;
1253   mips*-*-irix5*)
1254     noconfigdirs="$noconfigdirs gprof target-libgloss"
1255     ;;
1256   mips*-*-irix6*)
1257     noconfigdirs="$noconfigdirs gprof target-libgloss"
1258     ;;
1259   mips*-*-bsd*)
1260     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1261     ;;
1262   mips*-*-linux*)
1263     ;;
1264   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1265   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1266     noconfigdirs="$noconfigdirs ld gas gprof"
1267     ;;
1268   mips*-*-*)
1269     noconfigdirs="$noconfigdirs gprof"
1270     ;;
1271   nvptx*-*-*)
1272     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1273     ;;
1274   sh-*-*)
1275     case "${target}" in
1276       sh*-*-elf)
1277          ;;
1278       *)
1279          noconfigdirs="$noconfigdirs target-libgloss" ;;
1280     esac
1281     ;;
1282   sparc-*-sunos4*)
1283     if test x${is_cross_compiler} = xno ; then
1284            use_gnu_ld=no
1285     fi
1286     ;;
1287   tic6x-*-*)
1288     noconfigdirs="$noconfigdirs sim"
1289     ;;
1290   tilepro*-*-* | tilegx*-*-*)
1291     noconfigdirs="$noconfigdirs sim"
1292     ;;
1293   v810-*-*)
1294     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1295     ;;
1296   vax-*-*)
1297     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1298     ;;
1299   wasm32-*-*)
1300     noconfigdirs="$noconfigdirs ld"
1301     ;;
1302 esac
1303
1304 # If we aren't building newlib, then don't build libgloss, since libgloss
1305 # depends upon some newlib header files.
1306 case "${noconfigdirs}" in
1307   *target-libgloss*) ;;
1308   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1309 esac
1310
1311 # Work in distributions that contain no compiler tools, like Autoconf.
1312 host_makefile_frag=/dev/null
1313 if test -d ${srcdir}/config ; then
1314 case "${host}" in
1315   i[[3456789]]86-*-msdosdjgpp*)
1316     host_makefile_frag="config/mh-djgpp"
1317     ;;
1318   *-cygwin*)
1319     ACX_CHECK_CYGWIN_CAT_WORKS
1320     host_makefile_frag="config/mh-cygwin"
1321     ;;
1322   *-mingw*)
1323     host_makefile_frag="config/mh-mingw"
1324     ;;
1325   alpha*-linux*)
1326     host_makefile_frag="config/mh-alpha-linux"
1327     ;;
1328   hppa*-hp-hpux10*)
1329     host_makefile_frag="config/mh-pa-hpux10"
1330     ;;
1331   hppa*-hp-hpux*)
1332     host_makefile_frag="config/mh-pa"
1333     ;;
1334   hppa*-*)
1335     host_makefile_frag="config/mh-pa"
1336     ;;
1337   *-*-darwin*)
1338     host_makefile_frag="config/mh-darwin"
1339     ;;
1340   powerpc-*-aix*)
1341     host_makefile_frag="config/mh-ppc-aix"
1342     ;;
1343   rs6000-*-aix*)
1344     host_makefile_frag="config/mh-ppc-aix"
1345     ;;
1346 esac
1347 fi
1348
1349 if test "${build}" != "${host}" ; then
1350   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1351   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1352   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1353   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1354   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1355   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1356   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1357   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1358   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1359   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1360   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1361   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1362   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1363 else
1364   AR_FOR_BUILD="\$(AR)"
1365   AS_FOR_BUILD="\$(AS)"
1366   CC_FOR_BUILD="\$(CC)"
1367   CXX_FOR_BUILD="\$(CXX)"
1368   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1369   GOC_FOR_BUILD="\$(GOC)"
1370   GDC_FOR_BUILD="\$(GDC)"
1371   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1372   LD_FOR_BUILD="\$(LD)"
1373   NM_FOR_BUILD="\$(NM)"
1374   RANLIB_FOR_BUILD="\$(RANLIB)"
1375   WINDRES_FOR_BUILD="\$(WINDRES)"
1376   WINDMC_FOR_BUILD="\$(WINDMC)"
1377 fi
1378
1379 AC_PROG_CC
1380 AC_PROG_CXX
1381
1382 # We must set the default linker to the linker used by gcc for the correct
1383 # operation of libtool.  If LD is not defined and we are using gcc, try to
1384 # set the LD default to the ld used by gcc.
1385 if test -z "$LD"; then
1386   if test "$GCC" = yes; then
1387     case $build in
1388     *-*-mingw*)
1389       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1390     *)
1391       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1392     esac
1393     case $gcc_prog_ld in
1394     # Accept absolute paths.
1395     [[\\/]* | [A-Za-z]:[\\/]*)]
1396       LD="$gcc_prog_ld" ;;
1397     esac
1398   fi
1399 fi
1400
1401 # Check whether -static-libstdc++ -static-libgcc is supported.
1402 have_static_libs=no
1403 if test "$GCC" = yes; then
1404   saved_LDFLAGS="$LDFLAGS"
1405
1406   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1407   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1408   AC_LANG_PUSH(C++)
1409   AC_LINK_IFELSE([AC_LANG_SOURCE([
1410 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1411 #error -static-libstdc++ not implemented
1412 #endif
1413 int main() {}])],
1414     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1415     [AC_MSG_RESULT([no])])
1416   AC_LANG_POP(C++)
1417
1418   LDFLAGS="$saved_LDFLAGS"
1419 fi
1420
1421 ACX_PROG_GNAT
1422 ACX_PROG_CMP_IGNORE_INITIAL
1423
1424 AC_ARG_ENABLE([bootstrap],
1425 [AS_HELP_STRING([--enable-bootstrap],
1426                 [enable bootstrapping @<:@yes if native build@:>@])],,
1427 enable_bootstrap=default)
1428
1429 # Issue errors and warnings for invalid/strange bootstrap combinations.
1430 if test -r $srcdir/gcc/configure; then
1431   have_compiler=yes
1432 else
1433   have_compiler=no
1434 fi
1435
1436 case "$have_compiler:$host:$target:$enable_bootstrap" in
1437   *:*:*:no) ;;
1438
1439   # Default behavior.  Enable bootstrap if we have a compiler
1440   # and we are in a native configuration.
1441   yes:$build:$build:default)
1442     enable_bootstrap=yes ;;
1443
1444   *:*:*:default)
1445     enable_bootstrap=no ;;
1446
1447   # We have a compiler and we are in a native configuration, bootstrap is ok
1448   yes:$build:$build:yes)
1449     ;;
1450
1451   # Other configurations, but we have a compiler.  Assume the user knows
1452   # what he's doing.
1453   yes:*:*:yes)
1454     AC_MSG_WARN([trying to bootstrap a cross compiler])
1455     ;;
1456
1457   # No compiler: if they passed --enable-bootstrap explicitly, fail
1458   no:*:*:yes)
1459     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1460
1461   # Fail if wrong command line
1462   *)
1463     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1464     ;;
1465 esac
1466
1467 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1468 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1469 # require C++11 (or higher).
1470 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1471   CXX="$CXX -std=c++11"
1472 elif test "$have_compiler" = yes; then
1473   AX_CXX_COMPILE_STDCXX(11)
1474
1475   if test "${build}" != "${host}"; then
1476     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1477   fi
1478 fi
1479
1480 # Used for setting $lt_cv_objdir
1481 _LT_CHECK_OBJDIR
1482
1483 # Check for GMP, MPFR and MPC
1484 gmplibs="-lmpc -lmpfr -lgmp"
1485 gmpinc=
1486 have_gmp=no
1487
1488 # Specify a location for mpc
1489 # check for this first so it ends up on the link line before mpfr.
1490 AC_ARG_WITH(mpc,
1491 [AS_HELP_STRING([--with-mpc=PATH],
1492                 [specify prefix directory for installed MPC package.
1493                  Equivalent to --with-mpc-include=PATH/include
1494                  plus --with-mpc-lib=PATH/lib])])
1495 AC_ARG_WITH(mpc-include,
1496 [AS_HELP_STRING([--with-mpc-include=PATH],
1497                 [specify directory for installed MPC include files])])
1498 AC_ARG_WITH(mpc-lib,
1499 [AS_HELP_STRING([--with-mpc-lib=PATH],
1500                 [specify directory for the installed MPC library])])
1501
1502 if test "x$with_mpc" != x; then
1503   gmplibs="-L$with_mpc/lib $gmplibs"
1504   gmpinc="-I$with_mpc/include $gmpinc"
1505 fi
1506 if test "x$with_mpc_include" != x; then
1507   gmpinc="-I$with_mpc_include $gmpinc"
1508 fi
1509 if test "x$with_mpc_lib" != x; then
1510   gmplibs="-L$with_mpc_lib $gmplibs"
1511 fi
1512 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1513   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1514   gmpinc='-I$$s/mpc/src '"$gmpinc"
1515   # Do not test the mpc version.  Assume that it is sufficient, since
1516   # it is in the source tree, and the library has not been built yet
1517   # but it would be included on the link line in the version check below
1518   # hence making the test fail.
1519   have_gmp=yes
1520 fi
1521
1522 # Specify a location for mpfr
1523 # check for this first so it ends up on the link line before gmp.
1524 AC_ARG_WITH(mpfr-dir,
1525 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1526 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1527 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1528
1529 AC_ARG_WITH(mpfr,
1530 [AS_HELP_STRING([--with-mpfr=PATH],
1531                 [specify prefix directory for installed MPFR package.
1532                  Equivalent to --with-mpfr-include=PATH/include
1533                  plus --with-mpfr-lib=PATH/lib])])
1534 AC_ARG_WITH(mpfr-include,
1535 [AS_HELP_STRING([--with-mpfr-include=PATH],
1536                 [specify directory for installed MPFR include files])])
1537 AC_ARG_WITH(mpfr-lib,
1538 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1539                 [specify directory for the installed MPFR library])])
1540
1541 if test "x$with_mpfr" != x; then
1542   gmplibs="-L$with_mpfr/lib $gmplibs"
1543   gmpinc="-I$with_mpfr/include $gmpinc"
1544 fi
1545 if test "x$with_mpfr_include" != x; then
1546   gmpinc="-I$with_mpfr_include $gmpinc"
1547 fi
1548 if test "x$with_mpfr_lib" != x; then
1549   gmplibs="-L$with_mpfr_lib $gmplibs"
1550 fi
1551 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1552   # MPFR v3.1.0 moved the sources into a src sub-directory.
1553   if ! test -d ${srcdir}/mpfr/src; then
1554     AC_MSG_ERROR([dnl
1555 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1556   fi
1557   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1558   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1559   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1560   # Do not test the mpfr version.  Assume that it is sufficient, since
1561   # it is in the source tree, and the library has not been built yet
1562   # but it would be included on the link line in the version check below
1563   # hence making the test fail.
1564   have_gmp=yes
1565 fi
1566
1567 # Specify a location for gmp
1568 AC_ARG_WITH(gmp-dir,
1569 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1570 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1571 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1572
1573 AC_ARG_WITH(gmp,
1574 [AS_HELP_STRING([--with-gmp=PATH],
1575                 [specify prefix directory for the installed GMP package.
1576                  Equivalent to --with-gmp-include=PATH/include
1577                  plus --with-gmp-lib=PATH/lib])])
1578 AC_ARG_WITH(gmp-include,
1579 [AS_HELP_STRING([--with-gmp-include=PATH],
1580                 [specify directory for installed GMP include files])])
1581 AC_ARG_WITH(gmp-lib,
1582 [AS_HELP_STRING([--with-gmp-lib=PATH],
1583                 [specify directory for the installed GMP library])])
1584
1585
1586 if test "x$with_gmp" != x; then
1587   gmplibs="-L$with_gmp/lib $gmplibs"
1588   gmpinc="-I$with_gmp/include $gmpinc"
1589 fi
1590 if test "x$with_gmp_include" != x; then
1591   gmpinc="-I$with_gmp_include $gmpinc"
1592 fi
1593 if test "x$with_gmp_lib" != x; then
1594   gmplibs="-L$with_gmp_lib $gmplibs"
1595 fi
1596 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1597   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1598   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1599   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1600   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1601   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1602   # Do not test the gmp version.  Assume that it is sufficient, since
1603   # it is in the source tree, and the library has not been built yet
1604   # but it would be included on the link line in the version check below
1605   # hence making the test fail.
1606   have_gmp=yes
1607 fi
1608
1609 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1610   have_gmp=yes
1611   saved_CFLAGS="$CFLAGS"
1612   CFLAGS="$CFLAGS $gmpinc"
1613   # Check for the recommended and required versions of GMP.
1614   AC_MSG_CHECKING([for the correct version of gmp.h])
1615   AC_TRY_COMPILE([#include "gmp.h"],[
1616   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1617   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1618   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1619   choke me
1620   #endif
1621   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1622   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1623   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1624   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1625   choke me
1626   #endif
1627   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1628    [AC_MSG_RESULT([no]); have_gmp=no])
1629
1630   # If we have GMP, check the MPFR version.
1631   if test x"$have_gmp" = xyes; then
1632     # Check for the recommended and required versions of MPFR.
1633     AC_MSG_CHECKING([for the correct version of mpfr.h])
1634     AC_TRY_COMPILE([#include <gmp.h>
1635     #include <mpfr.h>],[
1636     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1637     choke me
1638     #endif
1639     ], [AC_TRY_COMPILE([#include <gmp.h>
1640     #include <mpfr.h>],[
1641     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1642     choke me
1643     #endif
1644     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1645      [AC_MSG_RESULT([no]); have_gmp=no])
1646   fi
1647
1648   # Check for the MPC header version.
1649   if test x"$have_gmp" = xyes ; then
1650     # Check for the recommended and required versions of MPC.
1651     AC_MSG_CHECKING([for the correct version of mpc.h])
1652     AC_TRY_COMPILE([#include <mpc.h>],[
1653     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1654     choke me
1655     #endif
1656     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1657     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1658     choke me
1659     #endif
1660     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1661      [AC_MSG_RESULT([no]); have_gmp=no])
1662   fi
1663
1664   # Now check the MPFR library.
1665   if test x"$have_gmp" = xyes; then
1666     saved_LIBS="$LIBS"
1667     LIBS="$LIBS $gmplibs"
1668     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1669     AC_TRY_LINK([#include <mpc.h>],[
1670     mpfr_t n;
1671     mpfr_t x;
1672     mpc_t c;
1673     int t;
1674     mpfr_init (n);
1675     mpfr_init (x);
1676     mpfr_atan2 (n, n, x, MPFR_RNDN);
1677     mpfr_erfc (n, x, MPFR_RNDN);
1678     mpfr_subnormalize (x, t, MPFR_RNDN);
1679     mpfr_clear(n);
1680     mpfr_clear(x);
1681     mpc_init2 (c, 53);
1682     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1683     mpc_cosh (c, c, MPC_RNDNN);
1684     mpc_pow (c, c, c, MPC_RNDNN);
1685     mpc_acosh (c, c, MPC_RNDNN);
1686     mpc_clear (c);
1687     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1688     LIBS="$saved_LIBS"
1689   fi
1690
1691   CFLAGS="$saved_CFLAGS"
1692
1693 # The library versions listed in the error message below should match
1694 # the HARD-minimums enforced above.
1695   if test x$have_gmp != xyes; then
1696     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1697 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1698 their locations.  Source code for these libraries can be found at
1699 their respective hosting sites as well as at
1700 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1701 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1702 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1703 make sure that you have installed both the libraries and the header
1704 files.  They may be located in separate packages.])
1705   fi
1706 fi
1707
1708 # Flags needed for both GMP, MPFR and/or MPC.
1709 AC_SUBST(gmplibs)
1710 AC_SUBST(gmpinc)
1711 AC_SUBST(extra_mpfr_configure_flags)
1712 AC_SUBST(extra_mpc_gmp_configure_flags)
1713 AC_SUBST(extra_mpc_mpfr_configure_flags)
1714 AC_SUBST(extra_isl_gmp_configure_flags)
1715
1716 # Libraries to use for stage1 or when not bootstrapping.
1717 AC_ARG_WITH(stage1-libs,
1718 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1719 [if test "$withval" = "no" -o "$withval" = "yes"; then
1720    stage1_libs=
1721  else
1722    stage1_libs=$withval
1723  fi],
1724 [stage1_libs=])
1725 AC_SUBST(stage1_libs)
1726
1727 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1728 # default is yes if gcc is being built; no otherwise.  The reason for
1729 # this default is that gdb is sometimes linked against GNU Source
1730 # Highlight, which is a shared library that uses C++ exceptions.  In
1731 # this case, -static-libstdc++ will cause crashes.
1732 AC_ARG_WITH(static-standard-libraries,
1733 [AS_HELP_STRING([--with-static-standard-libraries],
1734                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1735 [], [with_static_standard_libraries=auto])
1736 if test "$with_static_standard_libraries" = auto; then
1737   with_static_standard_libraries=$have_compiler
1738 fi
1739
1740 # Linker flags to use for stage1 or when not bootstrapping.
1741 AC_ARG_WITH(stage1-ldflags,
1742 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1743 [if test "$withval" = "no" -o "$withval" = "yes"; then
1744    stage1_ldflags=
1745  else
1746    stage1_ldflags=$withval
1747  fi],
1748 [stage1_ldflags=
1749  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1750  # if supported.  But if the user explicitly specified the libraries to use,
1751  # trust that they are doing what they want.
1752  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1753      -a "$have_static_libs" = yes; then
1754    stage1_ldflags="-static-libstdc++ -static-libgcc"
1755  fi])
1756 AC_SUBST(stage1_ldflags)
1757
1758 # Libraries to use for stage2 and later builds.
1759 AC_ARG_WITH(boot-libs,
1760 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1761 [if test "$withval" = "no" -o "$withval" = "yes"; then
1762    poststage1_libs=
1763  else
1764    poststage1_libs=$withval
1765  fi],
1766 [poststage1_libs=])
1767 AC_SUBST(poststage1_libs)
1768
1769 # Linker flags to use for stage2 and later builds.
1770 AC_ARG_WITH(boot-ldflags,
1771 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1772                 [linker flags for stage2 and later])],
1773 [if test "$withval" = "no" -o "$withval" = "yes"; then
1774    poststage1_ldflags=
1775  else
1776    poststage1_ldflags=$withval
1777  fi],
1778 [poststage1_ldflags=
1779  # In stages 2 and 3, default to linking libstdc++ and libgcc
1780  # statically.  But if the user explicitly specified the libraries to
1781  # use, trust that they are doing what they want.
1782  if test "$poststage1_libs" = ""; then
1783    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1784  fi])
1785 AC_SUBST(poststage1_ldflags)
1786
1787 # GCC GRAPHITE dependency isl.
1788 # Basic setup is inlined here, actual checks are in config/isl.m4
1789
1790 AC_ARG_WITH(isl,
1791   [AS_HELP_STRING(
1792    [--with-isl=PATH],
1793    [Specify prefix directory for the installed isl package.
1794     Equivalent to --with-isl-include=PATH/include
1795     plus --with-isl-lib=PATH/lib])])
1796
1797 # Treat --without-isl as a request to disable
1798 # GRAPHITE support and skip all following checks.
1799 if test "x$with_isl" != "xno"; then
1800   # Check for isl
1801   dnl Provide configure switches and initialize islinc & isllibs
1802   dnl with user input.
1803   ISL_INIT_FLAGS
1804   dnl The versions of isl that work for Graphite
1805   ISL_CHECK_VERSION()
1806   dnl Only execute fail-action, if isl has been requested.
1807   ISL_IF_FAILED([
1808     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1809 fi
1810
1811 # If the isl check failed, disable builds of in-tree variant of isl
1812 if test "x$with_isl" = xno ||
1813    test "x$gcc_cv_isl" = xno; then
1814   noconfigdirs="$noconfigdirs isl"
1815   islinc=
1816 fi
1817
1818 AC_SUBST(isllibs)
1819 AC_SUBST(islinc)
1820
1821 # Check for LTO support.
1822 AC_ARG_ENABLE(lto,
1823 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1824 enable_lto=$enableval,
1825 enable_lto=yes; default_enable_lto=yes)
1826
1827 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1828   build_lto_plugin=yes
1829 ],[if test x"$default_enable_lto" = x"yes" ; then
1830     case $target in
1831       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1832       # On other non-ELF platforms, LTO has yet to be validated.
1833       *) enable_lto=no ;;
1834     esac
1835   else
1836   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1837   # It would also be nice to check the binutils support, but we don't
1838   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1839   # warn during gcc/ subconfigure; unless you're bootstrapping with
1840   # -flto it won't be needed until after installation anyway.
1841     case $target in
1842       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1843       *) if test x"$enable_lto" = x"yes"; then
1844         AC_MSG_ERROR([LTO support is not enabled for this target.])
1845         fi
1846       ;;
1847     esac
1848   fi
1849   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1850   # Build it unless LTO was explicitly disabled.
1851   case $target in
1852     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1853     *) ;;
1854   esac
1855 ])
1856
1857 AC_ARG_ENABLE(linker-plugin-configure-flags,
1858   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1859     [additional flags for configuring linker plugins @<:@none@:>@])],
1860   extra_linker_plugin_configure_flags=$enableval,
1861   extra_linker_plugin_configure_flags=)
1862 AC_SUBST(extra_linker_plugin_configure_flags)
1863 AC_ARG_ENABLE(linker-plugin-flags,
1864   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1865     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1866   extra_linker_plugin_flags=$enableval,
1867   extra_linker_plugin_flags=)
1868 AC_SUBST(extra_linker_plugin_flags)
1869
1870 # Enable --enable-host-shared.
1871 # Checked early to determine whether jit is an 'all' language
1872 AC_ARG_ENABLE(host-shared,
1873 [AS_HELP_STRING([--enable-host-shared],
1874                 [build host code as shared libraries])],
1875 [host_shared=$enableval], [host_shared=no])
1876 AC_SUBST(host_shared)
1877
1878 # By default, C and C++ are the only stage 1 languages.
1879 stage1_languages=,c,
1880
1881 # Target libraries that we bootstrap.
1882 bootstrap_target_libs=,target-libgcc,
1883
1884 # Figure out what language subdirectories are present.
1885 # Look if the user specified --enable-languages="..."; if not, use
1886 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1887 # go away some day.
1888 # NB:  embedded tabs in this IF block -- do not untabify
1889 if test -d ${srcdir}/gcc; then
1890   if test x"${enable_languages+set}" != xset; then
1891     if test x"${LANGUAGES+set}" = xset; then
1892       enable_languages="${LANGUAGES}"
1893         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1894     else
1895       enable_languages=default
1896     fi
1897   else
1898     if test x"${enable_languages}" = x ||
1899        test x"${enable_languages}" = xyes;
1900        then
1901       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1902       exit 1
1903     fi
1904   fi
1905   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1906
1907   # 'f95' is the old name for the 'fortran' language. We issue a warning
1908   # and make the substitution.
1909   case ,${enable_languages}, in
1910     *,f95,*)
1911       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1912       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1913       ;;
1914   esac
1915
1916   # If bootstrapping, C++ must be enabled.
1917   case ",$enable_languages,:$enable_bootstrap" in
1918     *,c++,*:*) ;;
1919     *:yes)
1920       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1921         enable_languages="${enable_languages},c++"
1922       else
1923         AC_MSG_ERROR([bootstrapping requires c++ sources])
1924       fi
1925       ;;
1926   esac
1927
1928   # First scan to see if an enabled language requires some other language.
1929   # We assume that a given config-lang.in will list all the language
1930   # front ends it requires, even if some are required indirectly.
1931   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1932     case ${lang_frag} in
1933       ..) ;;
1934       # The odd quoting in the next line works around
1935       # an apparent bug in bash 1.12 on linux.
1936       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1937       *)
1938         # From the config-lang.in, get $language, $lang_requires, and
1939         # $lang_requires_boot_languages.
1940         language=
1941         lang_requires=
1942         lang_requires_boot_languages=
1943         # set srcdir during sourcing lang_frag to the gcc dir.
1944         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1945         # polutes this shell
1946         saved_srcdir=${srcdir}
1947         srcdir=${srcdir}/gcc . ${lang_frag}
1948         srcdir=${saved_srcdir}
1949         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1950           case ,${enable_languages}, in
1951             *,$other,*) ;;
1952             *,default,*) ;;
1953             *,all,*) ;;
1954             *,$language,*)
1955               echo " \`$other' language required by \`$language'; enabling" 1>&2
1956               enable_languages="${enable_languages},${other}"
1957               ;;
1958           esac
1959         done
1960         for other in ${lang_requires_boot_languages} ; do
1961           if test "$other" != "c"; then
1962             case ,${enable_stage1_languages}, in
1963               *,$other,*) ;;
1964               *,default,*) ;;
1965               *,all,*) ;;
1966               *)
1967                 case ,${enable_languages}, in
1968                   *,$language,*)
1969                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1970                     enable_stage1_languages="$enable_stage1_languages,${other}"
1971                     ;;
1972                 esac
1973                 ;;
1974             esac
1975           fi
1976         done
1977         ;;
1978     esac
1979   done
1980
1981   new_enable_languages=,c,
1982
1983   # If LTO is enabled, add the LTO front end.
1984   if test "$enable_lto" = "yes" ; then
1985     case ,${enable_languages}, in
1986       *,lto,*) ;;
1987       *) enable_languages="${enable_languages},lto" ;;
1988     esac
1989     if test "${build_lto_plugin}" = "yes" ; then
1990       configdirs="$configdirs lto-plugin"
1991     fi
1992   fi
1993
1994   # If we're building an offloading compiler, add the LTO front end.
1995   if test x"$enable_as_accelerator_for" != x ; then
1996     case ,${enable_languages}, in
1997       *,lto,*) ;;
1998       *) enable_languages="${enable_languages},lto" ;;
1999     esac
2000   fi
2001
2002   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2003   potential_languages=,c,
2004
2005   enabled_target_libs=
2006   disabled_target_libs=
2007
2008   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2009     case ${lang_frag} in
2010       ..) ;;
2011       # The odd quoting in the next line works around
2012       # an apparent bug in bash 1.12 on linux.
2013       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2014       *)
2015         # From the config-lang.in, get $language, $target_libs,
2016         # $lang_dirs, $boot_language, and $build_by_default
2017         language=
2018         target_libs=
2019         lang_dirs=
2020         subdir_requires=
2021         boot_language=no
2022         build_by_default=yes
2023         # set srcdir during sourcing.  See above about save & restore
2024         saved_srcdir=${srcdir}
2025         srcdir=${srcdir}/gcc . ${lang_frag}
2026         srcdir=${saved_srcdir}
2027         if test x${language} = x; then
2028           echo "${lang_frag} doesn't set \$language." 1>&2
2029           exit 1
2030         fi
2031
2032         if test "$language" = "c++"; then
2033           boot_language=yes
2034         fi
2035
2036         add_this_lang=no
2037         # C is always enabled, so no need to add it again
2038         if test "$language" != "c"; then
2039           case ,${enable_languages}, in
2040             *,${language},*)
2041               # Language was explicitly selected; include it
2042               add_this_lang=yes
2043               ;;
2044             *,all,*)
2045               # All languages are enabled
2046               add_this_lang=all
2047               ;;
2048             *,default,*)
2049               # 'default' was selected, select it if it is a default language
2050               add_this_lang=${build_by_default}
2051               ;;
2052           esac
2053         fi
2054
2055         # Disable languages that need other directories if these aren't available.
2056         for i in $subdir_requires; do
2057           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2058           case ${add_this_lang} in
2059             yes)
2060               # Specifically requested language; tell them.
2061               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2062               ;;
2063             all)
2064               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2065               add_this_lang=unsupported
2066               ;;
2067             *)
2068               # Silently disable.
2069               add_this_lang=unsupported
2070               ;;
2071           esac
2072         done
2073
2074         # Disable Ada if no preexisting GNAT is available.
2075         case ${add_this_lang}:${language}:${have_gnat} in
2076           yes:ada:no)
2077             # Specifically requested language; tell them.
2078             AC_MSG_ERROR([GNAT is required to build $language])
2079             ;;
2080           all:ada:no)
2081             AC_MSG_WARN([GNAT is required to build $language])
2082             add_this_lang=unsupported
2083             ;;
2084           *:ada:no)
2085             # Silently disable.
2086             add_this_lang=unsupported
2087             ;;
2088         esac
2089
2090         # Disable jit if -enable-host-shared not specified
2091         # but not if building for Mingw. All code in Windows
2092         # is position independent code (PIC).
2093         case $target in
2094           *mingw*) ;;
2095           *)
2096           case ${add_this_lang}:${language}:${host_shared} in
2097             yes:jit:no)
2098                    # PR jit/64780: explicitly specify --enable-host-shared
2099             AC_MSG_ERROR([
2100 Enabling language "jit" requires --enable-host-shared.
2101
2102 --enable-host-shared typically slows the rest of the compiler down by
2103 a few %, so you must explicitly enable it.
2104
2105 If you want to build both the jit and the regular compiler, it is often
2106 best to do this via two separate configure/builds, in separate
2107 directories, to avoid imposing the performance cost of
2108 --enable-host-shared on the regular compiler.])
2109                     ;;
2110             all:jit:no)
2111               AC_MSG_WARN([--enable-host-shared required to build $language])
2112               add_this_lang=unsupported
2113               ;;
2114             *:jit:no)
2115               # Silently disable.
2116               add_this_lang=unsupported
2117               ;;
2118                 esac
2119           ;;
2120         esac
2121
2122         # Disable a language that is unsupported by the target.
2123         case "${add_this_lang}: $unsupported_languages " in
2124           no:*) ;;
2125           unsupported:*) ;;
2126           *:*" $language "*)
2127             AC_MSG_WARN([${language} not supported for this target])
2128             add_this_lang=unsupported
2129             ;;
2130         esac
2131
2132         case $add_this_lang in
2133           unsupported)
2134             # Remove language-dependent dirs.
2135             disabled_target_libs="$disabled_target_libs $target_libs"
2136             noconfigdirs="$noconfigdirs $lang_dirs"
2137             ;;
2138           no)
2139             # Remove language-dependent dirs; still show language as supported.
2140             disabled_target_libs="$disabled_target_libs $target_libs"
2141             noconfigdirs="$noconfigdirs $lang_dirs"
2142             potential_languages="${potential_languages}${language},"
2143             ;;
2144           all|yes)
2145             new_enable_languages="${new_enable_languages}${language},"
2146             potential_languages="${potential_languages}${language},"
2147             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2148             enabled_target_libs="$enabled_target_libs $target_libs"
2149             case "${boot_language}:,$enable_stage1_languages," in
2150               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2151                 # Add to (comma-separated) list of stage 1 languages.
2152                 case ",$stage1_languages," in
2153                   *,$language,* | ,yes, | ,all,) ;;
2154                   *) stage1_languages="${stage1_languages}${language}," ;;
2155                 esac
2156                 # We need to bootstrap any supporting libraries.
2157                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2158                 ;;
2159             esac
2160             ;;
2161         esac
2162         ;;
2163     esac
2164   done
2165
2166   # Add target libraries which are only needed for disabled languages
2167   # to noconfigdirs.
2168   if test -n "$disabled_target_libs"; then
2169     for dir in $disabled_target_libs; do
2170       case " $enabled_target_libs " in
2171       *" ${dir} "*) ;;
2172       *) noconfigdirs="$noconfigdirs $dir" ;;
2173       esac
2174     done
2175   fi
2176
2177   AC_ARG_ENABLE(stage1-languages,
2178   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2179                   [choose additional languages to build during
2180                   stage1.  Mostly useful for compiler development])],
2181   [case ,${enable_stage1_languages}, in
2182     ,no,|,,)
2183       # Set it to something that will have no effect in the loop below
2184       enable_stage1_languages=c ;;
2185     ,yes,)
2186       enable_stage1_languages=`echo $new_enable_languages | \
2187         sed -e "s/^,//" -e "s/,$//" ` ;;
2188     *,all,*)
2189       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2190         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2191   esac
2192
2193   # Add "good" languages from enable_stage1_languages to stage1_languages,
2194   # while "bad" languages go in missing_languages.  Leave no duplicates.
2195   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2196     case $potential_languages in
2197       *,$i,*)
2198         case $stage1_languages in
2199           *,$i,*) ;;
2200           *) stage1_languages="$stage1_languages$i," ;;
2201         esac ;;
2202       *)
2203         case $missing_languages in
2204           *,$i,*) ;;
2205           *) missing_languages="$missing_languages$i," ;;
2206         esac ;;
2207      esac
2208   done])
2209
2210   # Remove leading/trailing commas that were added for simplicity
2211   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2212   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2213   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2214   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2215
2216   if test "x$missing_languages" != x; then
2217     AC_MSG_ERROR([
2218 The following requested languages could not be built: ${missing_languages}
2219 Supported languages are: ${potential_languages}])
2220   fi
2221   if test "x$new_enable_languages" != "x$enable_languages"; then
2222     echo The following languages will be built: ${new_enable_languages}
2223     enable_languages="$new_enable_languages"
2224   fi
2225
2226   AC_SUBST(stage1_languages)
2227   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2228 fi
2229
2230 # Handle --disable-<component> generically.
2231 for dir in $configdirs $build_configdirs $target_configdirs ; do
2232   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2233   varname=`echo $dirname | sed -e s/+/_/g`
2234   if eval test x\${enable_${varname}} "=" xno ; then
2235     noconfigdirs="$noconfigdirs $dir"
2236   fi
2237 done
2238
2239 # Check for Boehm's garbage collector
2240 AC_ARG_ENABLE(objc-gc,
2241 [AS_HELP_STRING([--enable-objc-gc],
2242                 [enable use of Boehm's garbage collector with the
2243                  GNU Objective-C runtime])])
2244 AC_ARG_WITH([target-bdw-gc],
2245 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2246                 [specify prefix directory for installed bdw-gc package.
2247                  Equivalent to --with-target-bdw-gc-include=PATH/include
2248                  plus --with-target-bdw-gc-lib=PATH/lib])])
2249 AC_ARG_WITH([target-bdw-gc-include],
2250 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2251                 [specify directories for installed bdw-gc include files])])
2252 AC_ARG_WITH([target-bdw-gc-lib],
2253 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2254                 [specify directories for installed bdw-gc library])])
2255
2256 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2257   AC_MSG_CHECKING([for bdw garbage collector])
2258   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2259     dnl no bdw-gw options, assume default locations
2260     AC_MSG_RESULT([using bdw-gc in default locations])
2261   else
2262     dnl bdw-gw options, first error checking, complete checking in libobjc
2263     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2264       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2265     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2266       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2267     else
2268       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2269     fi
2270   fi
2271 esac
2272
2273 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2274 case ,${enable_languages}, in
2275   *,c++,*)
2276     # Disable libitm, libsanitizer if we're not building libstdc++
2277     case "${noconfigdirs}" in
2278       *target-libstdc++-v3*)
2279         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2280         ;;
2281       *) ;;
2282     esac
2283     ;;
2284   *)
2285     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2286     ;;
2287 esac
2288
2289 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2290 # $build_configdirs and $target_configdirs.
2291 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2292
2293 notsupp=""
2294 for dir in . $skipdirs $noconfigdirs ; do
2295   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2296   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2297     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2298     if test -r $srcdir/$dirname/configure ; then
2299       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2300         true
2301       else
2302         notsupp="$notsupp $dir"
2303       fi
2304     fi
2305   fi
2306   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2307     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2308     if test -r $srcdir/$dirname/configure ; then
2309       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2310         true
2311       else
2312         notsupp="$notsupp $dir"
2313       fi
2314     fi
2315   fi
2316   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2317     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2318     if test -r $srcdir/$dirname/configure ; then
2319       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2320         true
2321       else
2322         notsupp="$notsupp $dir"
2323       fi
2324     fi
2325   fi
2326 done
2327
2328 # Quietly strip out all directories which aren't configurable in this tree.
2329 # This relies on all configurable subdirectories being autoconfiscated, which
2330 # is now the case.
2331 build_configdirs_all="$build_configdirs"
2332 build_configdirs=
2333 for i in ${build_configdirs_all} ; do
2334   j=`echo $i | sed -e s/build-//g`
2335   if test -f ${srcdir}/$j/configure ; then
2336     build_configdirs="${build_configdirs} $i"
2337   fi
2338 done
2339
2340 configdirs_all="$configdirs"
2341 configdirs=
2342 for i in ${configdirs_all} ; do
2343   if test -f ${srcdir}/$i/configure ; then
2344     configdirs="${configdirs} $i"
2345   fi
2346 done
2347
2348 target_configdirs_all="$target_configdirs"
2349 target_configdirs=
2350 for i in ${target_configdirs_all} ; do
2351   j=`echo $i | sed -e s/target-//g`
2352   if test -f ${srcdir}/$j/configure ; then
2353     target_configdirs="${target_configdirs} $i"
2354   fi
2355 done
2356
2357 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2358 # so we have to add it after the preceding checks.
2359 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2360 then
2361   case " $configdirs " in
2362     *" libiberty "*)
2363       # If we can build libiberty, we can also build libiberty-linker-plugin.
2364       configdirs="$configdirs libiberty-linker-plugin"
2365       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2366         --with-libiberty=../libiberty-linker-plugin";;
2367     *)
2368       AC_MSG_ERROR([libiberty missing]);;
2369   esac
2370 fi
2371
2372 # Sometimes we have special requirements for the host libiberty.
2373 extra_host_libiberty_configure_flags=
2374 extra_host_zlib_configure_flags=
2375 case " $configdirs " in
2376   *" lto-plugin "* | *" libcc1 "*)
2377     # When these are to be built as shared libraries, the same applies to
2378     # libiberty.
2379     extra_host_libiberty_configure_flags=--enable-shared
2380     ;;
2381   *" bfd "*)
2382     # When bfd is to be built as a shared library, the same applies to
2383     # zlib.
2384     if test "$enable_shared" = "yes"; then
2385       extra_host_zlib_configure_flags=--enable-host-shared
2386     fi
2387     ;;
2388 esac
2389 AC_SUBST(extra_host_libiberty_configure_flags)
2390 AC_SUBST(extra_host_zlib_configure_flags)
2391
2392 # Produce a warning message for the subdirs we can't configure.
2393 # This isn't especially interesting in the Cygnus tree, but in the individual
2394 # FSF releases, it's important to let people know when their machine isn't
2395 # supported by the one or two programs in a package.
2396
2397 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2398   # If $appdirs is non-empty, at least one of those directories must still
2399   # be configured, or we error out.  (E.g., if the gas release supports a
2400   # specified target in some subdirs but not the gas subdir, we shouldn't
2401   # pretend that all is well.)
2402   if test -n "$appdirs" ; then
2403     for dir in $appdirs ; do
2404       if test -r $dir/Makefile.in ; then
2405         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2406           appdirs=""
2407           break
2408         fi
2409         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2410           appdirs=""
2411           break
2412         fi
2413       fi
2414     done
2415     if test -n "$appdirs" ; then
2416       echo "*** This configuration is not supported by this package." 1>&2
2417       exit 1
2418     fi
2419   fi
2420   # Okay, some application will build, or we don't care to check.  Still
2421   # notify of subdirs not getting built.
2422   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2423   echo "    ${notsupp}" 1>&2
2424   echo "    (Any other directories should still work fine.)" 1>&2
2425 fi
2426
2427 case "$host" in
2428   *msdosdjgpp*)
2429     enable_gdbtk=no ;;
2430 esac
2431
2432 # To find our prefix, in gcc_cv_tool_prefix.
2433 ACX_TOOL_DIRS
2434
2435 copy_dirs=
2436
2437 AC_ARG_WITH([build-sysroot],
2438   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2439                   [use sysroot as the system root during the build])],
2440   [if test x"$withval" != x ; then
2441      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2442    fi],
2443   [SYSROOT_CFLAGS_FOR_TARGET=])
2444 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2445
2446 AC_ARG_WITH([debug-prefix-map],
2447   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2448                   [map A to B, C to D ... in debug information])],
2449   [if test x"$withval" != x; then
2450      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2451      for debug_map in $withval; do
2452        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2453      done
2454    fi],
2455   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2456 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2457
2458 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2459 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2460 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2461 # We want to ensure that TARGET libraries (which we know are built with
2462 # gcc) are built with "-O2 -g", so include those options when setting
2463 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2464 if test "x$CFLAGS_FOR_TARGET" = x; then
2465   if test "x${is_cross_compiler}" = xyes; then
2466     CFLAGS_FOR_TARGET="-g -O2"
2467   else
2468     CFLAGS_FOR_TARGET=$CFLAGS
2469     case " $CFLAGS " in
2470       *" -O2 "*) ;;
2471       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2472     esac
2473     case " $CFLAGS " in
2474       *" -g "* | *" -g3 "*) ;;
2475       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2476     esac
2477   fi
2478 fi
2479 AC_SUBST(CFLAGS_FOR_TARGET)
2480
2481 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2482   if test "x${is_cross_compiler}" = xyes; then
2483     CXXFLAGS_FOR_TARGET="-g -O2"
2484   else
2485     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2486     case " $CXXFLAGS " in
2487       *" -O2 "*) ;;
2488       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2489     esac
2490     case " $CXXFLAGS " in
2491       *" -g "* | *" -g3 "*) ;;
2492       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2493     esac
2494   fi
2495 fi
2496 AC_SUBST(CXXFLAGS_FOR_TARGET)
2497
2498 AC_SUBST(LDFLAGS_FOR_TARGET)
2499
2500 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2501 # the named directory are copied to $(tooldir)/sys-include.
2502 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2503   if test x${is_cross_compiler} = xno ; then
2504     echo 1>&2 '***' --with-headers is only supported when cross compiling
2505     exit 1
2506   fi
2507   if test x"${with_headers}" != xyes ; then
2508     x=${gcc_cv_tool_prefix}
2509     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2510   fi
2511 fi
2512
2513 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2514 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2515 # are permitted.
2516 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2517   if test x${is_cross_compiler} = xno ; then
2518     echo 1>&2 '***' --with-libs is only supported when cross compiling
2519     exit 1
2520   fi
2521   if test x"${with_libs}" != xyes ; then
2522     # Copy the libraries in reverse order, so that files in the first named
2523     # library override files in subsequent libraries.
2524     x=${gcc_cv_tool_prefix}
2525     for l in ${with_libs}; do
2526       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2527     done
2528   fi
2529 fi
2530
2531 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2532 #
2533 # This is done by determining whether or not the appropriate directory
2534 # is available, and by checking whether or not specific configurations
2535 # have requested that this magic not happen.
2536 #
2537 # The command line options always override the explicit settings in
2538 # configure.ac, and the settings in configure.ac override this magic.
2539 #
2540 # If the default for a toolchain is to use GNU as and ld, and you don't
2541 # want to do that, then you should use the --without-gnu-as and
2542 # --without-gnu-ld options for the configure script.  Similarly, if
2543 # the default is to use the included zlib and you don't want to do that,
2544 # you should use the --with-system-zlib option for the configure script.
2545
2546 if test x${use_gnu_as} = x &&
2547    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2548   with_gnu_as=yes
2549   extra_host_args="$extra_host_args --with-gnu-as"
2550 fi
2551
2552 if test x${use_gnu_ld} = x &&
2553    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2554   with_gnu_ld=yes
2555   extra_host_args="$extra_host_args --with-gnu-ld"
2556 fi
2557
2558 if test x${use_included_zlib} = x &&
2559    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2560   :
2561 else
2562   with_system_zlib=yes
2563   extra_host_args="$extra_host_args --with-system-zlib"
2564 fi
2565
2566 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2567 # can detect this case.
2568
2569 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2570   with_newlib=yes
2571   extra_host_args="$extra_host_args --with-newlib"
2572 fi
2573
2574 # Handle ${copy_dirs}
2575 set fnord ${copy_dirs}
2576 shift
2577 while test $# != 0 ; do
2578   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2579     :
2580   else
2581     echo Copying $1 to $2
2582
2583     # Use the install script to create the directory and all required
2584     # parent directories.
2585     if test -d $2 ; then
2586       :
2587     else
2588       echo >config.temp
2589       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2590     fi
2591
2592     # Copy the directory, assuming we have tar.
2593     # FIXME: Should we use B in the second tar?  Not all systems support it.
2594     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2595
2596     # It is the responsibility of the user to correctly adjust all
2597     # symlinks.  If somebody can figure out how to handle them correctly
2598     # here, feel free to add the code.
2599
2600     echo $1 > $2/COPIED
2601   fi
2602   shift; shift
2603 done
2604
2605 # Determine a target-dependent exec_prefix that the installed
2606 # gcc will search in.  Keep this list sorted by triplet, with
2607 # the *-*-osname triplets last.
2608 md_exec_prefix=
2609 case "${target}" in
2610   i[[34567]]86-pc-msdosdjgpp*)
2611     md_exec_prefix=/dev/env/DJDIR/bin
2612     ;;
2613   *-*-hpux* | \
2614   *-*-nto-qnx* | \
2615   *-*-solaris2*)
2616     md_exec_prefix=/usr/ccs/bin
2617     ;;
2618 esac
2619
2620 extra_arflags_for_target=
2621 extra_nmflags_for_target=
2622 extra_ranlibflags_for_target=
2623 target_makefile_frag=/dev/null
2624 case "${target}" in
2625   spu-*-*)
2626     target_makefile_frag="config/mt-spu"
2627     ;;
2628   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2629     target_makefile_frag="config/mt-sde"
2630     ;;
2631   mipsisa*-*-elfoabi*)
2632     target_makefile_frag="config/mt-mips-elfoabi"
2633     ;;
2634   mips*-*-*linux* | mips*-*-gnu*)
2635     target_makefile_frag="config/mt-mips-gnu"
2636     ;;
2637   nios2-*-elf*)
2638     target_makefile_frag="config/mt-nios2-elf"
2639     ;;
2640   *-*-linux-android*)
2641     target_makefile_frag="config/mt-android"
2642     ;;
2643   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2644     target_makefile_frag="config/mt-gnu"
2645     ;;
2646   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2647     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2648     # commands to handle both 32-bit and 64-bit objects.  These flags are
2649     # harmless if we're using GNU nm or ar.
2650     extra_arflags_for_target=" -X32_64"
2651     extra_nmflags_for_target=" -B -X32_64"
2652     ;;
2653 esac
2654
2655 alphaieee_frag=/dev/null
2656 case $target in
2657   alpha*-*-*)
2658     # This just makes sure to use the -mieee option to build target libs.
2659     # This should probably be set individually by each library.
2660     alphaieee_frag="config/mt-alphaieee"
2661     ;;
2662 esac
2663
2664 # If --enable-target-optspace always use -Os instead of -O2 to build
2665 # the target libraries, similarly if it is not specified, use -Os
2666 # on selected platforms.
2667 ospace_frag=/dev/null
2668 case "${enable_target_optspace}:${target}" in
2669   yes:*)
2670     ospace_frag="config/mt-ospace"
2671     ;;
2672   :d30v-*)
2673     ospace_frag="config/mt-d30v"
2674     ;;
2675   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2676     ospace_frag="config/mt-ospace"
2677     ;;
2678   no:* | :*)
2679     ;;
2680   *)
2681     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2682     ;;
2683 esac
2684
2685 # Some systems (e.g., one of the i386-aix systems the gas testers are
2686 # using) don't handle "\$" correctly, so don't use it here.
2687 tooldir='${exec_prefix}'/${target_noncanonical}
2688 build_tooldir=${tooldir}
2689
2690 # Create a .gdbinit file which runs the one in srcdir
2691 # and tells GDB to look there for source files.
2692
2693 if test -r ${srcdir}/.gdbinit ; then
2694   case ${srcdir} in
2695     .) ;;
2696     *) cat > ./.gdbinit <<EOF
2697 # ${NO_EDIT}
2698 dir ${srcdir}
2699 dir .
2700 source ${srcdir}/.gdbinit
2701 EOF
2702     ;;
2703   esac
2704 fi
2705
2706 # Make sure that the compiler is able to generate an executable.  If it
2707 # can't, we are probably in trouble.  We don't care whether we can run the
2708 # executable--we might be using a cross compiler--we only care whether it
2709 # can be created.  At this point the main configure script has set CC.
2710 we_are_ok=no
2711 echo "int main () { return 0; }" > conftest.c
2712 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2713 if test $? = 0 ; then
2714   if test -s conftest || test -s conftest.exe ; then
2715     we_are_ok=yes
2716   fi
2717 fi
2718 case $we_are_ok in
2719   no)
2720     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2721     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2722     rm -f conftest*
2723     exit 1
2724     ;;
2725 esac
2726 rm -f conftest*
2727
2728 # Decide which environment variable is used to find dynamic libraries.
2729 case "${host}" in
2730   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2731   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2732   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2733   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2734 esac
2735
2736 # On systems where the dynamic library environment variable is PATH,
2737 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2738 # built executables to PATH.
2739 if test "$RPATH_ENVVAR" = PATH; then
2740   GCC_SHLIB_SUBDIR=/shlib
2741 else
2742   GCC_SHLIB_SUBDIR=
2743 fi
2744
2745 # Adjust the toplevel makefile according to whether bootstrap was selected.
2746 case $enable_bootstrap in
2747   yes)
2748     bootstrap_suffix=bootstrap
2749     BUILD_CONFIG=bootstrap-debug
2750     ;;
2751   no)
2752     bootstrap_suffix=no-bootstrap
2753     BUILD_CONFIG=
2754     ;;
2755 esac
2756
2757 AC_MSG_CHECKING(for default BUILD_CONFIG)
2758
2759 AC_ARG_WITH([build-config],
2760   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2761                   [use config/NAME.mk build configuration])],
2762   [case $with_build_config in
2763    yes) with_build_config= ;;
2764    no) with_build_config= BUILD_CONFIG= ;;
2765    esac])
2766
2767 if test "x${with_build_config}" != x; then
2768   BUILD_CONFIG=$with_build_config
2769 else
2770   case $BUILD_CONFIG in
2771   bootstrap-debug)
2772     if echo "int f (void) { return 0; }" > conftest.c &&
2773        ${CC} -c conftest.c &&
2774        mv conftest.o conftest.o.g0 &&
2775        ${CC} -c -g conftest.c &&
2776        mv conftest.o conftest.o.g &&
2777        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2778       :
2779     else
2780       BUILD_CONFIG=
2781     fi
2782     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2783     ;;
2784   esac
2785 fi
2786 AC_MSG_RESULT($BUILD_CONFIG)
2787 AC_SUBST(BUILD_CONFIG)
2788
2789 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2790 AC_MSG_CHECKING([for --enable-vtable-verify])
2791 AC_ARG_ENABLE(vtable-verify,
2792 [AS_HELP_STRING([--enable-vtable-verify],
2793                 [Enable vtable verification feature])],
2794 [case "$enableval" in
2795  yes) enable_vtable_verify=yes ;;
2796  no)  enable_vtable_verify=no ;;
2797  *)   enable_vtable_verify=no;;
2798  esac],
2799 [enable_vtable_verify=no])
2800 AC_MSG_RESULT($enable_vtable_verify)
2801
2802 # Record target_configdirs and the configure arguments for target and
2803 # build configuration in Makefile.
2804 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2805 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2806 bootstrap_fixincludes=no
2807
2808 # If we are building libgomp, bootstrap it.
2809 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2810   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2811 fi
2812
2813 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2814 # or bootstrap-ubsan, bootstrap it.
2815 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2816   case "$BUILD_CONFIG" in
2817     *bootstrap-asan* | *bootstrap-ubsan* )
2818       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2819       bootstrap_fixincludes=yes
2820       ;;
2821   esac
2822 fi
2823
2824 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2825 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2826    test "$enable_vtable_verify" != no; then
2827   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2828 fi
2829
2830 # Determine whether gdb needs tk/tcl or not.
2831 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2832 # and in that case we want gdb to be built without tk.  Ugh!
2833 # In fact I believe gdb is the *only* package directly dependent on tk,
2834 # so we should be able to put the 'maybe's in unconditionally and
2835 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2836 # 100% sure that that's safe though.
2837
2838 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2839 case "$enable_gdbtk" in
2840   no)
2841     GDB_TK="" ;;
2842   yes)
2843     GDB_TK="${gdb_tk}" ;;
2844   *)
2845     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2846     # distro.  Eventually someone will fix this and move Insight, nee
2847     # gdbtk to a separate directory.
2848     if test -d ${srcdir}/gdb/gdbtk ; then
2849       GDB_TK="${gdb_tk}"
2850     else
2851       GDB_TK=""
2852     fi
2853     ;;
2854 esac
2855 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2856 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2857
2858 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2859 # else does, only include them if one of these is built.  The Makefile
2860 # provides the ordering, so it's enough here to add to the list.
2861 case " ${configdirs} " in
2862   *\ gdb\ *)
2863     configdirs="${configdirs} gnulib gdbsupport"
2864     ;;
2865   *\ gdbserver\ *)
2866     configdirs="${configdirs} gnulib gdbsupport"
2867     ;;
2868 esac
2869
2870 # Strip out unwanted targets.
2871
2872 # While at that, we remove Makefiles if we were started for recursive
2873 # configuration, so that the top-level Makefile reconfigures them,
2874 # like we used to do when configure itself was recursive.
2875
2876 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2877 # but now we're fixing up the Makefile ourselves with the additional
2878 # commands passed to AC_CONFIG_FILES.  Use separate variables
2879 # extrasub-{build,host,target} not because there is any reason to split
2880 # the substitutions up that way, but only to remain below the limit of
2881 # 99 commands in a script, for HP-UX sed.
2882
2883 # Do not nest @if/@endif or @unless/@endunless pairs, because
2884 # configure will not warn you at all.
2885
2886 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2887   yes:yes:*\ gold\ *:*,c++,*) ;;
2888   yes:yes:*\ gold\ *:*)
2889     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2890     ;;
2891 esac
2892
2893 extrasub_build=
2894 for module in ${build_configdirs} ; do
2895   if test -z "${no_recursion}" \
2896      && test -f ${build_subdir}/${module}/Makefile; then
2897     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2898     rm -f ${build_subdir}/${module}/Makefile
2899   fi
2900   extrasub_build="$extrasub_build
2901 /^@if build-$module\$/d
2902 /^@endif build-$module\$/d
2903 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2904 /^@if build-$module-$bootstrap_suffix\$/d
2905 /^@endif build-$module-$bootstrap_suffix\$/d
2906 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2907 done
2908 extrasub_host=
2909 for module in ${configdirs} ; do
2910   if test -z "${no_recursion}"; then
2911     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2912       if test -f ${file}; then
2913         echo 1>&2 "*** removing ${file} to force reconfigure"
2914         rm -f ${file}
2915       fi
2916     done
2917   fi
2918   case ${module},${bootstrap_fixincludes} in
2919     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2920     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2921   esac
2922   extrasub_host="$extrasub_host
2923 /^@if $module\$/d
2924 /^@endif $module\$/d
2925 /^@unless $module\$/,/^@endunless $module\$/d
2926 /^@if $module-$host_bootstrap_suffix\$/d
2927 /^@endif $module-$host_bootstrap_suffix\$/d
2928 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2929 done
2930 extrasub_target=
2931 for module in ${target_configdirs} ; do
2932   if test -z "${no_recursion}" \
2933      && test -f ${target_subdir}/${module}/Makefile; then
2934     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2935     rm -f ${target_subdir}/${module}/Makefile
2936   fi
2937
2938   # We only bootstrap target libraries listed in bootstrap_target_libs.
2939   case $bootstrap_target_libs in
2940     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2941     *) target_bootstrap_suffix=no-bootstrap ;;
2942   esac
2943
2944   extrasub_target="$extrasub_target
2945 /^@if target-$module\$/d
2946 /^@endif target-$module\$/d
2947 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2948 /^@if target-$module-$target_bootstrap_suffix\$/d
2949 /^@endif target-$module-$target_bootstrap_suffix\$/d
2950 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2951 done
2952
2953 # Do the final fixup along with target modules.
2954 extrasub_target="$extrasub_target
2955 /^@if /,/^@endif /d
2956 /^@unless /d
2957 /^@endunless /d"
2958
2959 # Create the serialization dependencies.  This uses a temporary file.
2960
2961 AC_ARG_ENABLE([serial-configure],
2962 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2963                 [force sequential configuration of
2964                  sub-packages for the host, target or build
2965                  machine, or all sub-packages])])
2966
2967 case ${enable_serial_configure} in
2968   yes)
2969     enable_serial_build_configure=yes
2970     enable_serial_host_configure=yes
2971     enable_serial_target_configure=yes
2972     ;;
2973 esac
2974
2975 # These force 'configure's to be done one at a time, to avoid problems
2976 # with contention over a shared config.cache.
2977 rm -f serdep.tmp
2978 echo '# serdep.tmp' > serdep.tmp
2979 olditem=
2980 test "x${enable_serial_build_configure}" = xyes &&
2981 for item in ${build_configdirs} ; do
2982   case ${olditem} in
2983     "") ;;
2984     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2985   esac
2986   olditem=${item}
2987 done
2988 olditem=
2989 test "x${enable_serial_host_configure}" = xyes &&
2990 for item in ${configdirs} ; do
2991   case ${olditem} in
2992     "") ;;
2993     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2994   esac
2995   olditem=${item}
2996 done
2997 olditem=
2998 test "x${enable_serial_target_configure}" = xyes &&
2999 for item in ${target_configdirs} ; do
3000   case ${olditem} in
3001     "") ;;
3002     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3003   esac
3004   olditem=${item}
3005 done
3006 serialization_dependencies=serdep.tmp
3007 AC_SUBST_FILE(serialization_dependencies)
3008
3009 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3010 # target, nonopt, and variable assignments.  These are the ones we
3011 # might not want to pass down to subconfigures.  The exception being
3012 # --cache-file=/dev/null, which is used to turn off the use of cache
3013 # files altogether, and which should be passed on to subconfigures.
3014 # Also strip program-prefix, program-suffix, and program-transform-name,
3015 # so that we can pass down a consistent program-transform-name.
3016 baseargs=
3017 tbaseargs=
3018 keep_next=no
3019 skip_next=no
3020 eval "set -- $ac_configure_args"
3021 for ac_arg
3022 do
3023   if test X"$skip_next" = X"yes"; then
3024     skip_next=no
3025     continue
3026   fi
3027   if test X"$keep_next" = X"yes"; then
3028     case $ac_arg in
3029       *\'*)
3030         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3031     esac
3032     baseargs="$baseargs '$ac_arg'"
3033     tbaseargs="$tbaseargs '$ac_arg'"
3034     keep_next=no
3035     continue
3036   fi
3037
3038   # Handle separated arguments.  Based on the logic generated by
3039   # autoconf 2.59.
3040   case $ac_arg in
3041     *=* | --config-cache | -C | -disable-* | --disable-* \
3042       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3043       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3044       | -with-* | --with-* | -without-* | --without-* | --x)
3045       separate_arg=no
3046       ;;
3047     -*)
3048       separate_arg=yes
3049       ;;
3050     *)
3051       separate_arg=no
3052       ;;
3053   esac
3054
3055   skip_targ=no
3056   case $ac_arg in
3057 changequote(,)
3058   --with-* | --without-*)
3059     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3060
3061     case $libopt in
3062     *[-_]include)
3063       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3064       ;;
3065     *[-_]lib)
3066       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3067       ;;
3068     *)
3069       lib=$libopt
3070       ;;
3071     esac
3072 changequote([,])
3073
3074     case $lib in
3075     mpc | mpfr | gmp | isl)
3076       # If we're processing --with-$lib, --with-$lib-include or
3077       # --with-$lib-lib, for one of the libs above, and target is
3078       # different from host, don't pass the current argument to any
3079       # target library's configure.
3080       if test x$is_cross_compiler = xyes; then
3081         skip_targ=yes
3082       fi
3083       ;;
3084     esac
3085     ;;
3086   esac
3087
3088   case "$ac_arg" in
3089     --cache-file=/dev/null | \
3090     -cache-file=/dev/null )
3091       # Handled here to avoid the test to skip args below.
3092       baseargs="$baseargs '$ac_arg'"
3093       tbaseargs="$tbaseargs '$ac_arg'"
3094       # Assert: $separate_arg should always be no.
3095       keep_next=$separate_arg
3096       ;;
3097     --no*)
3098       continue
3099       ;;
3100     --c* | \
3101     --sr* | \
3102     --ho* | \
3103     --bu* | \
3104     --t* | \
3105     --program-* | \
3106     -cache_file* | \
3107     -srcdir* | \
3108     -host* | \
3109     -build* | \
3110     -target* | \
3111     -program-prefix* | \
3112     -program-suffix* | \
3113     -program-transform-name* )
3114       skip_next=$separate_arg
3115       continue
3116       ;;
3117     -*)
3118       # An option.  Add it.
3119       case $ac_arg in
3120         *\'*)
3121           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3122       esac
3123       baseargs="$baseargs '$ac_arg'"
3124       if test X"$skip_targ" = Xno; then
3125         tbaseargs="$tbaseargs '$ac_arg'"
3126       fi
3127       keep_next=$separate_arg
3128       ;;
3129     *)
3130       # Either a variable assignment, or a nonopt (triplet).  Don't
3131       # pass it down; let the Makefile handle this.
3132       continue
3133       ;;
3134   esac
3135 done
3136 # Remove the initial space we just introduced and, as these will be
3137 # expanded by make, quote '$'.
3138 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3139
3140 # Add in --program-transform-name, after --program-prefix and
3141 # --program-suffix have been applied to it.  Autoconf has already
3142 # doubled dollar signs and backslashes in program_transform_name; we want
3143 # the backslashes un-doubled, and then the entire thing wrapped in single
3144 # quotes, because this will be expanded first by make and then by the shell.
3145 # Also, because we want to override the logic in subdir configure scripts to
3146 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3147 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3148 ${program_transform_name}
3149 EOF_SED
3150 gcc_transform_name=`cat conftestsed.out`
3151 rm -f conftestsed.out
3152 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3153 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3154 if test "$silent" = yes; then
3155   baseargs="$baseargs --silent"
3156   tbaseargs="$tbaseargs --silent"
3157 fi
3158 baseargs="$baseargs --disable-option-checking"
3159 tbaseargs="$tbaseargs --disable-option-checking"
3160
3161 # Record and document user additions to sub configure arguments.
3162 AC_ARG_VAR([build_configargs],
3163            [additional configure arguments for build directories])
3164 AC_ARG_VAR([host_configargs],
3165            [additional configure arguments for host directories])
3166 AC_ARG_VAR([target_configargs],
3167            [additional configure arguments for target directories])
3168
3169 # For the build-side libraries, we just need to pretend we're native,
3170 # and not use the same cache file.  Multilibs are neither needed nor
3171 # desired.  We can't even use the same cache file for all build-side
3172 # libraries, as they're compiled differently; some with C, some with
3173 # C++ or with different feature-enabling options.
3174 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3175
3176 # For host modules, accept cache file option, or specification as blank.
3177 case "${cache_file}" in
3178 "") # empty
3179   cache_file_option="" ;;
3180 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3181   cache_file_option="--cache-file=${cache_file}" ;;
3182 *) # relative path
3183   cache_file_option="--cache-file=../${cache_file}" ;;
3184 esac
3185
3186 # Host dirs don't like to share a cache file either, horribly enough.
3187 # This seems to be due to autoconf 2.5x stupidity.
3188 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3189
3190 target_configargs="$target_configargs ${tbaseargs}"
3191
3192 # Passing a --with-cross-host argument lets the target libraries know
3193 # whether they are being built with a cross-compiler or being built
3194 # native.  However, it would be better to use other mechanisms to make the
3195 # sorts of decisions they want to make on this basis.  Please consider
3196 # this option to be deprecated.  FIXME.
3197 if test x${is_cross_compiler} = xyes ; then
3198   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3199 fi
3200
3201 # Special user-friendly check for native x86_64-linux build, if
3202 # multilib is not explicitly enabled.
3203 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3204   x86_64-*linux*:yes:$build:$build:)
3205     # Make sure we have a development environment that handles 32-bit
3206     dev64=no
3207     echo "int main () { return 0; }" > conftest.c
3208     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3209     if test $? = 0 ; then
3210       if test -s conftest || test -s conftest.exe ; then
3211         dev64=yes
3212       fi
3213     fi
3214     rm -f conftest*
3215     if test x${dev64} != xyes ; then
3216       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3217     fi
3218     ;;
3219 esac
3220
3221 # Default to --enable-multilib.
3222 if test x${enable_multilib} = x ; then
3223   target_configargs="--enable-multilib ${target_configargs}"
3224 fi
3225
3226 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3227 # changed from the earlier setting of with_newlib.
3228 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3229   target_configargs="--with-newlib ${target_configargs}"
3230 fi
3231
3232 # Different target subdirs use different values of certain variables
3233 # (notably CXX).  Worse, multilibs use *lots* of different values.
3234 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3235 # it doesn't automatically accept command-line overrides of them.
3236 # This means it's not safe for target subdirs to share a cache file,
3237 # which is disgusting, but there you have it.  Hopefully this can be
3238 # fixed in future.  It's still worthwhile to use a cache file for each
3239 # directory.  I think.
3240
3241 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3242 # We need to pass --target, as newer autoconf's requires consistency
3243 # for target_alias and gcc doesn't manage it consistently.
3244 target_configargs="--cache-file=./config.cache ${target_configargs}"
3245
3246 FLAGS_FOR_TARGET=
3247 case " $target_configdirs " in
3248  *" newlib "*)
3249   case " $target_configargs " in
3250   *" --with-newlib "*)
3251    case "$target" in
3252     *-cygwin*)
3253       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3254       ;;
3255    esac
3256
3257    # If we're not building GCC, don't discard standard headers.
3258    if test -d ${srcdir}/gcc; then
3259      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3260
3261      if test "${build}" != "${host}"; then
3262        # On Canadian crosses, CC_FOR_TARGET will have already been set
3263        # by `configure', so we won't have an opportunity to add -Bgcc/
3264        # to it.  This is right: we don't want to search that directory
3265        # for binaries, but we want the header files in there, so add
3266        # them explicitly.
3267        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3268
3269        # Someone might think of using the pre-installed headers on
3270        # Canadian crosses, in case the installed compiler is not fully
3271        # compatible with the compiler being built.  In this case, it
3272        # would be better to flag an error than risking having
3273        # incompatible object files being constructed.  We can't
3274        # guarantee that an error will be flagged, but let's hope the
3275        # compiler will do it, when presented with incompatible header
3276        # files.
3277      fi
3278    fi
3279
3280    case "${target}-${is_cross_compiler}" in
3281    i[[3456789]]86-*-linux*-no)
3282       # Here host == target, so we don't need to build gcc,
3283       # so we don't want to discard standard headers.
3284       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3285       ;;
3286    *)
3287       # If we're building newlib, use its generic headers last, but search
3288       # for any libc-related directories first (so make it the last -B
3289       # switch).
3290       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3291
3292       # If we're building libgloss, find the startup file, simulator library
3293       # and linker script.
3294       case " $target_configdirs " in
3295         *" libgloss "*)
3296         # Look for startup file, simulator library and maybe linker script.
3297         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3298         # Look for libnosys.a in case the target needs it.
3299         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3300         # Most targets have the linker script in the source directory.
3301         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3302         ;;
3303       esac
3304       ;;
3305    esac
3306    ;;
3307   esac
3308   ;;
3309 esac
3310
3311 case "$target" in
3312   x86_64-*mingw* | *-w64-mingw*)
3313   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3314   # however, use a symlink named 'mingw' in ${prefix} .
3315     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3316     ;;
3317   *-mingw*)
3318   # MinGW can't be handled as Cygwin above since it does not use newlib.
3319     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3320     ;;
3321 esac
3322
3323 # Allow the user to override the flags for
3324 # our build compiler if desired.
3325 if test x"${build}" = x"${host}" ; then
3326   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3327   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3328   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3329 fi
3330
3331 # On Canadian crosses, we'll be searching the right directories for
3332 # the previously-installed cross compiler, so don't bother to add
3333 # flags for directories within the install tree of the compiler
3334 # being built; programs in there won't even run.
3335 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3336   # Search for pre-installed headers if nothing else fits.
3337   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3338 fi
3339
3340 if test "x${use_gnu_ld}" = x &&
3341    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3342   # Arrange for us to find uninstalled linker scripts.
3343   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3344 fi
3345
3346 # Search for other target-specific linker scripts and such.
3347 case "${target}" in
3348   mep*)
3349     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3350     ;;
3351 esac
3352
3353 # Makefile fragments.
3354 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3355 do
3356   eval fragval=\$$frag
3357   if test $fragval != /dev/null; then
3358     eval $frag=${srcdir}/$fragval
3359   fi
3360 done
3361 AC_SUBST_FILE(host_makefile_frag)
3362 AC_SUBST_FILE(target_makefile_frag)
3363 AC_SUBST_FILE(alphaieee_frag)
3364 AC_SUBST_FILE(ospace_frag)
3365
3366 # Miscellanea: directories, flags, etc.
3367 AC_SUBST(RPATH_ENVVAR)
3368 AC_SUBST(GCC_SHLIB_SUBDIR)
3369 AC_SUBST(tooldir)
3370 AC_SUBST(build_tooldir)
3371 AC_SUBST(CONFIGURE_GDB_TK)
3372 AC_SUBST(GDB_TK)
3373 AC_SUBST(INSTALL_GDB_TK)
3374
3375 # Build module lists & subconfigure args.
3376 AC_SUBST(build_configargs)
3377 AC_SUBST(build_configdirs)
3378
3379 # Host module lists & subconfigure args.
3380 AC_SUBST(host_configargs)
3381 AC_SUBST(configdirs)
3382 AC_SUBST(target_configdirs)
3383
3384 # Target module lists & subconfigure args.
3385 AC_SUBST(target_configargs)
3386
3387
3388 # Build tools.
3389 AC_SUBST(AR_FOR_BUILD)
3390 AC_SUBST(AS_FOR_BUILD)
3391 AC_SUBST(CC_FOR_BUILD)
3392 AC_SUBST(CFLAGS_FOR_BUILD)
3393 AC_SUBST(CXXFLAGS_FOR_BUILD)
3394 AC_SUBST(CXX_FOR_BUILD)
3395 AC_SUBST(DLLTOOL_FOR_BUILD)
3396 AC_SUBST(GFORTRAN_FOR_BUILD)
3397 AC_SUBST(GOC_FOR_BUILD)
3398 AC_SUBST(GDC_FOR_BUILD)
3399 AC_SUBST(LDFLAGS_FOR_BUILD)
3400 AC_SUBST(LD_FOR_BUILD)
3401 AC_SUBST(NM_FOR_BUILD)
3402 AC_SUBST(RANLIB_FOR_BUILD)
3403 AC_SUBST(WINDMC_FOR_BUILD)
3404 AC_SUBST(WINDRES_FOR_BUILD)
3405
3406 # Generate default definitions for YACC, M4, LEX and other programs that run
3407 # on the build machine.  These are used if the Makefile can't locate these
3408 # programs in objdir.
3409 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3410
3411 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3412 case " $build_configdirs " in
3413   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3414 esac
3415
3416 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3417 case " $build_configdirs " in
3418   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3419 esac
3420
3421 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3422 case " $build_configdirs " in
3423   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3424 esac
3425
3426 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3427 case " $build_configdirs " in
3428   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3429   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3430 esac
3431
3432 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3433 case " $build_configdirs " in
3434   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3435 esac
3436
3437 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3438 case " $build_configdirs " in
3439   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3440   *)
3441 changequote(,)
3442     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3443     # higher, else we use the "missing" dummy.
3444     if ${MAKEINFO} --version \
3445        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3446       :
3447     else
3448       MAKEINFO="$MISSING makeinfo"
3449     fi
3450     ;;
3451 changequote([,])
3452 esac
3453
3454 # FIXME: expect and dejagnu may become build tools?
3455
3456 AC_CHECK_PROGS(EXPECT, expect, expect)
3457 case " $configdirs " in
3458   *" expect "*)
3459     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3460     ;;
3461 esac
3462
3463 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3464 case " $configdirs " in
3465   *" dejagnu "*)
3466     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3467     ;;
3468 esac
3469
3470
3471 # Host tools.
3472 NCN_STRICT_CHECK_TOOLS(AR, ar)
3473 NCN_STRICT_CHECK_TOOLS(AS, as)
3474 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3475 NCN_STRICT_CHECK_TOOLS(LD, ld)
3476 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3477 NCN_STRICT_CHECK_TOOLS(NM, nm)
3478 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3479 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3480 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3481 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3482 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3483 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3484 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3485 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3486 AC_SUBST(CC)
3487 AC_SUBST(CXX)
3488 AC_SUBST(CFLAGS)
3489 AC_SUBST(CXXFLAGS)
3490
3491 # Target tools.
3492 AC_ARG_WITH([build-time-tools],
3493   [AS_HELP_STRING([--with-build-time-tools=PATH],
3494                   [use given path to find target tools during the build])],
3495   [case x"$withval" in
3496      x/*) ;;
3497      *)
3498        with_build_time_tools=
3499        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3500        ;;
3501    esac],
3502   [with_build_time_tools=])
3503
3504 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3505 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3506 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3507 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3508 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3509 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3510
3511 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3512 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3513 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3514 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3515 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3516 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3517 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3518 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3519 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3520 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3521 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3522 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3523 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3524 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3525
3526 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3527
3528 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3529 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3530 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3531 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3532 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3533                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3534                 c++)
3535 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3536                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3537                 c++)
3538 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3539 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3540 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3541                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3542 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3543                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3544 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3545                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3546 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3547 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3548 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3549 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3550 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3551 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3552 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3553 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3554 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3555 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3556 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3557
3558 AC_SUBST(FLAGS_FOR_TARGET)
3559 AC_SUBST(RAW_CXX_FOR_TARGET)
3560
3561 # Certain tools may need extra flags.
3562 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3563 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3564 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3565
3566 # When building target libraries, except in a Canadian cross, we use
3567 # the same toolchain as the compiler we just built.
3568 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3569 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3570 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3571 if test $host = $build; then
3572   case " $configdirs " in
3573     *" gcc "*)
3574       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3575       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3576       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3577       ;;
3578   esac
3579 fi
3580
3581 AC_SUBST(COMPILER_AS_FOR_TARGET)
3582 AC_SUBST(COMPILER_LD_FOR_TARGET)
3583 AC_SUBST(COMPILER_NM_FOR_TARGET)
3584
3585 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3586 AC_ARG_ENABLE(maintainer-mode,
3587 [AS_HELP_STRING([--enable-maintainer-mode],
3588                 [enable make rules and dependencies not useful
3589                  (and sometimes confusing) to the casual installer])],
3590       USE_MAINTAINER_MODE=$enableval,
3591       USE_MAINTAINER_MODE=no)
3592 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3593 AC_SUBST(MAINTAINER_MODE_TRUE)
3594 AC_SUBST(MAINTAINER_MODE_FALSE)
3595 if test "$USE_MAINTAINER_MODE" = yes; then
3596   MAINTAINER_MODE_TRUE=
3597   MAINTAINER_MODE_FALSE='#'
3598 else
3599   MAINTAINER_MODE_TRUE='#'
3600   MAINTAINER_MODE_FALSE=
3601 fi
3602 MAINT=$MAINTAINER_MODE_TRUE
3603 AC_SUBST(MAINT)dnl
3604
3605 # ---------------------
3606 # GCC bootstrap support
3607 # ---------------------
3608
3609 # Stage specific cflags for build.
3610 stage1_cflags="-g"
3611 case $build in
3612   vax-*-*)
3613     case ${GCC} in
3614       yes) stage1_cflags="-g -Wa,-J" ;;
3615       *) stage1_cflags="-g -J" ;;
3616     esac ;;
3617 esac
3618
3619 AC_SUBST(stage1_cflags)
3620
3621 # Enable --enable-checking in stage1 of the compiler.
3622 AC_ARG_ENABLE(stage1-checking,
3623 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3624                 [choose additional checking for stage1 of the compiler])],
3625 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3626 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3627   # For --disable-checking or implicit --enable-checking=release, avoid
3628   # setting --enable-checking=gc in the default stage1 checking for LTO
3629   # bootstraps.  See PR62077.
3630   case $BUILD_CONFIG in
3631     *lto*)
3632       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3633     *)
3634       stage1_checking=--enable-checking=yes,types;;
3635   esac
3636   if test "x$enable_checking" = x && \
3637      test -d ${srcdir}/gcc && \
3638      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3639     stage1_checking=--enable-checking=yes,types,extra
3640   fi
3641 else
3642   stage1_checking=--enable-checking=$enable_checking,types
3643 fi])
3644 AC_SUBST(stage1_checking)
3645
3646 # Enable -Werror in bootstrap stage2 and later.
3647 AC_ARG_ENABLE(werror,
3648 [AS_HELP_STRING([--enable-werror],
3649                 [enable -Werror in bootstrap stage2 and later])],
3650 [
3651 case ${enable_werror} in
3652   yes) stage2_werror_flag="--enable-werror-always" ;;
3653   *) stage2_werror_flag="" ;;
3654 esac
3655 ],
3656 [
3657 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3658   case $BUILD_CONFIG in
3659   bootstrap-debug)
3660       stage2_werror_flag="--enable-werror-always" ;;
3661   "")
3662       stage2_werror_flag="--enable-werror-always" ;;
3663   esac
3664 fi
3665 ])
3666
3667 AC_SUBST(stage2_werror_flag)
3668
3669 # Specify what files to not compare during bootstrap.
3670
3671 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3672 case "$target" in
3673   hppa*64*-*-hpux*) ;;
3674   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3675   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3676 esac
3677 AC_SUBST(compare_exclusions)
3678
3679 AC_CONFIG_FILES([Makefile],
3680   [sed "$extrasub_build" Makefile |
3681    sed "$extrasub_host" |
3682    sed "$extrasub_target" > mf$$
3683    mv -f mf$$ Makefile],
3684   [extrasub_build="$extrasub_build"
3685    extrasub_host="$extrasub_host"
3686    extrasub_target="$extrasub_target"])
3687 AC_OUTPUT