configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools c++tools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libatomic \
 155                 target-libitm \
 156                 target-libstdc++-v3 \
 157                 target-libsanitizer \
 158                 target-libvtv \
 159                 target-libssp \
 160                 target-libquadmath \
 161                 target-libgfortran \
 162                 target-libffi \
 163                 target-libobjc \
 164                 target-libada \
 165                 target-libgo \
 166                 target-libphobos \
 167                 target-zlib"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # some tools are so dependent upon X11 that if we're not building with X,
 251 # it's not even worth trying to configure, much less build, that tool.
 252
 253 case ${with_x} in
 254   yes | "") ;; # the default value for this tree is that X11 is available
 255   no)
 256     skipdirs="${skipdirs} tk itcl libgui"
 257     # We won't be able to build gdbtk without X.
 258     enable_gdbtk=no
 259     ;;
 260   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 261 esac
 262
 263 # Some are only suitable for cross toolchains.
 264 # Remove these if host=target.
 265 cross_only="target-libgloss target-newlib target-opcodes"
 266
 267 case $is_cross_compiler in
 268   no) skipdirs="${skipdirs} ${cross_only}" ;;
 269 esac
 270
 271 # If both --with-headers and --with-libs are specified, default to
 272 # --without-newlib.
 273 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 274    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 275   if test x"${with_newlib}" = x ; then
 276     with_newlib=no
 277   fi
 278 fi
 279
 280 # Recognize --with-newlib/--without-newlib.
 281 case ${with_newlib} in
 282   no) skipdirs="${skipdirs} target-newlib" ;;
 283   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 284 esac
 285
 286 AC_ARG_ENABLE(as-accelerator-for,
 287 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 288                 [build as offload target compiler.
 289                 Specify offload host triple by ARG])])
 290
 291 AC_ARG_ENABLE(offload-targets,
 292 [AS_HELP_STRING([--enable-offload-targets=LIST],
 293                 [enable offloading to devices from comma-separated LIST of
 294                 TARGET[=DIR]. Use optional path to find offload target compiler
 295                 during the build])],
 296 [
 297   if test x"$enable_offload_targets" = x; then
 298     AC_MSG_ERROR([no offload targets specified])
 299   fi
 300 ], [enable_offload_targets=])
 301
 302 AC_ARG_ENABLE(offload-defaulted,
 303 [AS_HELP_STRING([--enable-offload-defaulted]
 304                 [If enabled, configured but not installed offload compilers and
 305                 libgomp plugins are silently ignored.  Useful for distribution
 306                 compilers where those are in separate optional packages.])],
 307 [enable_offload_defaulted=$enableval],
 308 [enable_offload_defaulted=])
 309
 310 # Handle --enable-gold, --enable-ld.
 311 # --disable-gold [--enable-ld]
 312 #     Build only ld.  Default option.
 313 # --enable-gold [--enable-ld]
 314 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 315 #     as "ld.bfd" and "ld".
 316 # --enable-gold=default [--enable-ld]
 317 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 318 #     install ld as "ld.bfd".
 319 # --enable-gold[=default] --disable-ld
 320 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 321 # --enable-gold --enable-ld=default
 322 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 323 #     and ld.bfd).
 324 #     In other words, ld is default
 325 # --enable-gold=default --enable-ld=default
 326 #     Error.
 327
 328 default_ld=
 329 AC_ARG_ENABLE(gold,
 330 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 331                 [build gold @<:@ARG={default,yes,no}@:>@])],
 332 ENABLE_GOLD=$enableval,
 333 ENABLE_GOLD=no)
 334 case "${ENABLE_GOLD}" in
 335   yes|default)
 336     # Check for ELF target.
 337     is_elf=no
 338     case "${target}" in
 339       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 340       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 341       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 342       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 343         case "${target}" in
 344           *-*-linux*aout* | *-*-linux*oldld*)
 345             ;;
 346           *)
 347             is_elf=yes
 348             ;;
 349         esac
 350     esac
 351
 352     if test "$is_elf" = "yes"; then
 353       # Check for target supported by gold.
 354       case "${target}" in
 355         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 356         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 357           configdirs="$configdirs gold"
 358           if test x${ENABLE_GOLD} = xdefault; then
 359             default_ld=gold
 360           fi
 361           ENABLE_GOLD=yes
 362           ;;
 363       esac
 364     fi
 365     ;;
 366   no)
 367     ;;
 368   *)
 369     AC_MSG_ERROR([invalid --enable-gold argument])
 370     ;;
 371 esac
 372
 373 AC_ARG_ENABLE(ld,
 374 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 375                 [build ld @<:@ARG={default,yes,no}@:>@])],
 376 ENABLE_LD=$enableval,
 377 ENABLE_LD=yes)
 378
 379 case "${ENABLE_LD}" in
 380   default)
 381     if test x${default_ld} != x; then
 382       AC_MSG_ERROR([either gold or ld can be the default ld])
 383     fi
 384     ;;
 385   yes)
 386     ;;
 387   no)
 388     if test x${ENABLE_GOLD} != xyes; then
 389       AC_MSG_WARN([neither ld nor gold are enabled])
 390     fi
 391     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 392     ;;
 393   *)
 394     AC_MSG_ERROR([invalid --enable-ld argument])
 395     ;;
 396 esac
 397
 398 # PR gas/19109
 399 # Decide the default method for compressing debug sections.
 400 # Provide a configure time option to override our default.
 401 AC_ARG_ENABLE(compressed_debug_sections,
 402 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 403                 [Enable compressed debug sections for gas, gold or ld by
 404                  default])],
 405 [
 406   if test x"$enable_compressed_debug_sections" = xyes; then
 407     AC_MSG_ERROR([no program with compressed debug sections specified])
 408   fi
 409 ], [enable_compressed_debug_sections=])
 410
 411 # Configure extra directories which are host specific
 412
 413 case "${host}" in
 414   *-cygwin*)
 415     configdirs="$configdirs libtermcap" ;;
 416 esac
 417
 418 # A target can indicate whether a language isn't supported for some reason.
 419 # Only spaces may be used in this macro; not newlines or tabs.
 420 unsupported_languages=
 421
 422 # Remove more programs from consideration, based on the host or
 423 # target this usually means that a port of the program doesn't
 424 # exist yet.
 425
 426 case "${host}" in
 427   i[[3456789]]86-*-msdosdjgpp*)
 428     noconfigdirs="$noconfigdirs tcl tk itcl"
 429     ;;
 430 esac
 431
 432
 433 AC_ARG_ENABLE(libquadmath,
 434 AS_HELP_STRING([--disable-libquadmath],
 435   [do not build libquadmath directory]),
 436 ENABLE_LIBQUADMATH=$enableval,
 437 ENABLE_LIBQUADMATH=yes)
 438 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 439   noconfigdirs="$noconfigdirs target-libquadmath"
 440 fi
 441
 442
 443 AC_ARG_ENABLE(libquadmath-support,
 444 AS_HELP_STRING([--disable-libquadmath-support],
 445   [disable libquadmath support for Fortran]),
 446 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 447 ENABLE_LIBQUADMATH_SUPPORT=yes)
 448 enable_libquadmath_support=
 449 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 450   enable_libquadmath_support=no
 451 fi
 452
 453
 454 AC_ARG_ENABLE(libada,
 455 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 456 ENABLE_LIBADA=$enableval,
 457 ENABLE_LIBADA=yes)
 458 if test "${ENABLE_LIBADA}" != "yes" ; then
 459   noconfigdirs="$noconfigdirs gnattools"
 460 fi
 461
 462 AC_ARG_ENABLE(libssp,
 463 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 464 ENABLE_LIBSSP=$enableval,
 465 ENABLE_LIBSSP=yes)
 466
 467 AC_ARG_ENABLE(libstdcxx,
 468 AS_HELP_STRING([--disable-libstdcxx],
 469   [do not build libstdc++-v3 directory]),
 470 ENABLE_LIBSTDCXX=$enableval,
 471 ENABLE_LIBSTDCXX=default)
 472 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 473   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 474 fi]
 475
 476 # If this is accelerator compiler and its target is intelmic we enable
 477 # target liboffloadmic by default.  If this is compiler with offloading
 478 # for intelmic we enable host liboffloadmic by default.  Otherwise
 479 # liboffloadmic is disabled by default.
 480 AC_ARG_ENABLE([liboffloadmic],
 481 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 482                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 483 [case "$enableval" in
 484   no | host | target)
 485     enable_liboffloadmic=$enableval ;;
 486   *)
 487     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 488 esac],
 489 [if test x"$enable_as_accelerator_for" != x; then
 490   case "${target}" in
 491     *-intelmic-* | *-intelmicemul-*)
 492       enable_liboffloadmic=target
 493       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 494       ;;
 495     *)
 496       enable_liboffloadmic=no
 497       ;;
 498   esac
 499 else
 500   case "${enable_offload_targets}" in
 501     *-intelmic-* | *-intelmicemul-*)
 502       enable_liboffloadmic=host
 503       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 504       ;;
 505     *)
 506       enable_liboffloadmic=no
 507       ;;
 508     esac
 509 fi])
 510 AC_SUBST(extra_liboffloadmic_configure_flags)
 511
 512 # Enable libgomp by default on hosted POSIX systems, and a few others.
 513 if test x$enable_libgomp = x ; then
 514     case "${target}" in
 515     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 516         ;;
 517     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 518         ;;
 519     *-*-solaris2* | *-*-hpux11*)
 520         ;;
 521     *-*-darwin* | *-*-aix*)
 522         ;;
 523     nvptx*-*-* | amdgcn*-*-*)
 524         ;;
 525     *)
 526         noconfigdirs="$noconfigdirs target-libgomp"
 527         ;;
 528     esac
 529 fi
 530
 531 # Disable libatomic on unsupported systems.
 532 if test -d ${srcdir}/libatomic; then
 533     if test x$enable_libatomic = x; then
 534         AC_MSG_CHECKING([for libatomic support])
 535         if (srcdir=${srcdir}/libatomic; \
 536                 . ${srcdir}/configure.tgt; \
 537                 test -n "$UNSUPPORTED")
 538         then
 539             AC_MSG_RESULT([no])
 540             noconfigdirs="$noconfigdirs target-libatomic"
 541         else
 542             AC_MSG_RESULT([yes])
 543         fi
 544     fi
 545 fi
 546
 547 # Disable liboffloadmic on unsupported systems.
 548 if test -d ${srcdir}/liboffloadmic; then
 549     if test x$enable_liboffloadmic != xno; then
 550         AC_MSG_CHECKING([for liboffloadmic support])
 551         if (srcdir=${srcdir}/liboffloadmic; \
 552                 . ${srcdir}/configure.tgt; \
 553                 test -n "$UNSUPPORTED")
 554         then
 555             AC_MSG_RESULT([no])
 556             noconfigdirs="$noconfigdirs target-liboffloadmic"
 557         else
 558             AC_MSG_RESULT([yes])
 559         fi
 560     fi
 561 fi
 562
 563 # Disable libitm on unsupported systems.
 564 if test -d ${srcdir}/libitm; then
 565     if test x$enable_libitm = x; then
 566         AC_MSG_CHECKING([for libitm support])
 567         if (srcdir=${srcdir}/libitm; \
 568                 . ${srcdir}/configure.tgt; \
 569                 test -n "$UNSUPPORTED")
 570         then
 571             AC_MSG_RESULT([no])
 572             noconfigdirs="$noconfigdirs target-libitm"
 573         else
 574             AC_MSG_RESULT([yes])
 575         fi
 576     fi
 577 fi
 578
 579 # Disable libsanitizer on unsupported systems.
 580 if test -d ${srcdir}/libsanitizer; then
 581     if test x$enable_libsanitizer = x; then
 582         AC_MSG_CHECKING([for libsanitizer support])
 583         if (srcdir=${srcdir}/libsanitizer; \
 584                 . ${srcdir}/configure.tgt; \
 585                 test -n "$UNSUPPORTED")
 586         then
 587             AC_MSG_RESULT([no])
 588             noconfigdirs="$noconfigdirs target-libsanitizer"
 589         else
 590             AC_MSG_RESULT([yes])
 591         fi
 592     fi
 593 fi
 594
 595 # Disable libvtv on unsupported systems.
 596 if test -d ${srcdir}/libvtv; then
 597     if test x$enable_libvtv = x; then
 598         AC_MSG_CHECKING([for libvtv support])
 599         if (srcdir=${srcdir}/libvtv; \
 600                 . ${srcdir}/configure.tgt; \
 601                 test "$VTV_SUPPORTED" != "yes")
 602         then
 603             AC_MSG_RESULT([no])
 604             noconfigdirs="$noconfigdirs target-libvtv"
 605         else
 606             AC_MSG_RESULT([yes])
 607         fi
 608     fi
 609 fi
 610
 611 # Disable libquadmath for some systems.
 612 case "${target}" in
 613   avr-*-*)
 614     noconfigdirs="$noconfigdirs target-libquadmath"
 615     ;;
 616   # libquadmath is unused on AIX and libquadmath build process use of
 617   # LD_LIBRARY_PATH can break AIX bootstrap.
 618   powerpc-*-aix* | rs6000-*-aix*)
 619     noconfigdirs="$noconfigdirs target-libquadmath"
 620     ;;
 621 esac
 622
 623 # Disable libssp for some systems.
 624 case "${target}" in
 625   avr-*-*)
 626     # No hosted I/O support.
 627     noconfigdirs="$noconfigdirs target-libssp"
 628     ;;
 629   bpf-*-*)
 630     noconfigdirs="$noconfigdirs target-libssp"
 631     ;;
 632   powerpc-*-aix* | rs6000-*-aix*)
 633     noconfigdirs="$noconfigdirs target-libssp"
 634     ;;
 635   pru-*-*)
 636     # No hosted I/O support.
 637     noconfigdirs="$noconfigdirs target-libssp"
 638     ;;
 639   rl78-*-*)
 640     # libssp uses a misaligned load to trigger a fault, but the RL78
 641     # doesn't fault for those - instead, it gives a build-time error
 642     # for explicit misaligned loads.
 643     noconfigdirs="$noconfigdirs target-libssp"
 644     ;;
 645   visium-*-*)
 646     # No hosted I/O support.
 647     noconfigdirs="$noconfigdirs target-libssp"
 648     ;;
 649 esac
 650
 651 # Disable libstdc++-v3 for some systems.
 652 # Allow user to override this if they pass --enable-libstdc++-v3
 653 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 654   case "${target}" in
 655     *-*-vxworks*)
 656       # VxWorks uses the Dinkumware C++ library.
 657       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 658       ;;
 659     amdgcn*-*-*)
 660       # Not ported/fails to build when using newlib.
 661       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 662       ;;
 663     arm*-wince-pe*)
 664       # the C++ libraries don't build on top of CE's C libraries
 665       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 666       ;;
 667     avr-*-*)
 668       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 669       ;;
 670     bpf-*-*)
 671       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 672       ;;
 673     ft32-*-*)
 674       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 675       ;;
 676   esac
 677 fi
 678
 679 # Disable C++ on systems where it is known to not work.
 680 # For testing, you can override this with --enable-languages=c++.
 681 case ,${enable_languages}, in
 682   *,c++,*)
 683     ;;
 684   *)
 685       case "${target}" in
 686         bpf-*-*)
 687           unsupported_languages="$unsupported_languages c++"
 688           ;;
 689       esac
 690       ;;
 691 esac
 692
 693 # Disable Objc on systems where it is known to not work.
 694 # For testing, you can override this with --enable-languages=objc.
 695 case ,${enable_languages}, in
 696   *,objc,*)
 697     ;;
 698   *)
 699       case "${target}" in
 700         bpf-*-*)
 701           unsupported_languages="$unsupported_languages objc"
 702           ;;
 703       esac
 704       ;;
 705 esac
 706
 707 # Disable D on systems where it is known to not work.
 708 # For testing, you can override this with --enable-languages=d.
 709 case ,${enable_languages}, in
 710   *,d,*)
 711     ;;
 712   *)
 713     case "${target}" in
 714       bpf-*-*)
 715         unsupported_languages="$unsupported_languages d"
 716         ;;
 717     esac
 718     ;;
 719 esac
 720
 721 # Disable libphobos on unsupported systems.
 722 # For testing, you can override this with --enable-libphobos.
 723 if test -d ${srcdir}/libphobos; then
 724     if test x$enable_libphobos = x; then
 725         AC_MSG_CHECKING([for libphobos support])
 726         if (srcdir=${srcdir}/libphobos; \
 727                 . ${srcdir}/configure.tgt; \
 728                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 729         then
 730             AC_MSG_RESULT([no])
 731             noconfigdirs="$noconfigdirs target-libphobos"
 732         else
 733             AC_MSG_RESULT([yes])
 734         fi
 735     fi
 736 fi
 737
 738 # Disable Fortran for some systems.
 739 case "${target}" in
 740   mmix-*-*)
 741     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 742     unsupported_languages="$unsupported_languages fortran"
 743     ;;
 744   bpf-*-*)
 745     unsupported_languages="$unsupported_languages fortran"
 746     ;;
 747 esac
 748
 749 # Disable libffi for some systems.
 750 case "${target}" in
 751   powerpc-*-darwin*)
 752     ;;
 753   i[[3456789]]86-*-darwin*)
 754     ;;
 755   x86_64-*-darwin[[912]]*)
 756     ;;
 757   *-*-darwin*)
 758     noconfigdirs="$noconfigdirs target-libffi"
 759     ;;
 760   *-*-netware*)
 761     noconfigdirs="$noconfigdirs target-libffi"
 762     ;;
 763   *-*-phoenix*)
 764     noconfigdirs="$noconfigdirs target-libffi"
 765     ;;
 766   *-*-rtems*)
 767     noconfigdirs="$noconfigdirs target-libffi"
 768     ;;
 769   *-*-tpf*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772   *-*-uclinux*)
 773     noconfigdirs="$noconfigdirs target-libffi"
 774     ;;
 775   *-*-vxworks*)
 776     noconfigdirs="$noconfigdirs target-libffi"
 777     ;;
 778   aarch64*-*-freebsd*)
 779     noconfigdirs="$noconfigdirs target-libffi"
 780     ;;
 781   alpha*-*-*vms*)
 782     noconfigdirs="$noconfigdirs target-libffi"
 783     ;;
 784   arm*-*-freebsd*)
 785     noconfigdirs="$noconfigdirs target-libffi"
 786     ;;
 787   arm-wince-pe)
 788     noconfigdirs="$noconfigdirs target-libffi"
 789     ;;
 790   arm*-*-symbianelf*)
 791     noconfigdirs="$noconfigdirs target-libffi"
 792     ;;
 793   bpf-*-*)
 794     noconfigdirs="$noconfigdirs target-libffi"
 795     ;;
 796   cris-*-* | crisv32-*-*)
 797     case "${target}" in
 798       *-*-linux*)
 799         ;;
 800       *) # See PR46792 regarding target-libffi.
 801         noconfigdirs="$noconfigdirs target-libffi";;
 802     esac
 803     ;;
 804   hppa*64*-*-hpux*)
 805     noconfigdirs="$noconfigdirs target-libffi"
 806     ;;
 807   hppa*-hp-hpux11*)
 808     ;;
 809   hppa*-*-hpux*)
 810     noconfigdirs="$noconfigdirs target-libffi"
 811     ;;
 812   ia64*-*-*vms*)
 813     noconfigdirs="$noconfigdirs target-libffi"
 814     ;;
 815   i[[3456789]]86-w64-mingw*)
 816     noconfigdirs="$noconfigdirs target-libffi"
 817     ;;
 818   i[[3456789]]86-*-mingw*)
 819     noconfigdirs="$noconfigdirs target-libffi"
 820     ;;
 821   x86_64-*-mingw*)
 822     noconfigdirs="$noconfigdirs target-libffi"
 823     ;;
 824   mmix-*-*)
 825     noconfigdirs="$noconfigdirs target-libffi"
 826     ;;
 827   powerpc-*-aix*)
 828     ;;
 829   rs6000-*-aix*)
 830     ;;
 831   ft32-*-*)
 832     noconfigdirs="$noconfigdirs target-libffi"
 833     ;;
 834   *-*-lynxos*)
 835     noconfigdirs="$noconfigdirs target-libffi"
 836     ;;
 837 esac
 838
 839 # Disable the go frontend on systems where it is known to not work. Please keep
 840 # this in sync with contrib/config-list.mk.
 841 case "${target}" in
 842 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 843     unsupported_languages="$unsupported_languages go"
 844     ;;
 845 esac
 846
 847 # Only allow gdbserver on some systems.
 848 if test -d ${srcdir}/gdbserver; then
 849     if test x$enable_gdbserver = x; then
 850         AC_MSG_CHECKING([for gdbserver support])
 851         if (srcdir=${srcdir}/gdbserver; \
 852                 . ${srcdir}/configure.srv; \
 853                 test -n "$UNSUPPORTED")
 854         then
 855             AC_MSG_RESULT([no])
 856             noconfigdirs="$noconfigdirs gdbserver"
 857         else
 858             AC_MSG_RESULT([yes])
 859         fi
 860     fi
 861 fi
 862
 863 # Disable libgo for some systems where it is known to not work.
 864 # For testing, you can easily override this with --enable-libgo.
 865 if test x$enable_libgo = x; then
 866     case "${target}" in
 867     *-*-darwin*)
 868         # PR 46986
 869         noconfigdirs="$noconfigdirs target-libgo"
 870         ;;
 871     *-*-cygwin* | *-*-mingw*)
 872         noconfigdirs="$noconfigdirs target-libgo"
 873         ;;
 874     bpf-*-*)
 875         noconfigdirs="$noconfigdirs target-libgo"
 876         ;;
 877     esac
 878 fi
 879
 880 # Default libgloss CPU subdirectory.
 881 libgloss_dir="$target_cpu"
 882
 883 case "${target}" in
 884   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 885     libgloss_dir=wince
 886     ;;
 887   aarch64*-*-* )
 888     libgloss_dir=aarch64
 889     ;;
 890   arm*-*-*)
 891     libgloss_dir=arm
 892     ;;
 893   cris-*-* | crisv32-*-*)
 894     libgloss_dir=cris
 895     ;;
 896   hppa*-*-*)
 897     libgloss_dir=pa
 898     ;;
 899   i[[3456789]]86-*-*)
 900     libgloss_dir=i386
 901     ;;
 902   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 903     libgloss_dir=m68hc11
 904     ;;
 905   m68*-*-* | fido-*-*)
 906     libgloss_dir=m68k
 907     ;;
 908   mips*-*-*)
 909     libgloss_dir=mips
 910     ;;
 911   powerpc*-*-*)
 912     libgloss_dir=rs6000
 913     ;;
 914   pru-*-*)
 915     libgloss_dir=pru
 916     ;;
 917   sparc*-*-*)
 918     libgloss_dir=sparc
 919     ;;
 920 esac
 921
 922 # Disable newlib and libgloss for various target OSes.
 923 case "${target}" in
 924   alpha*-dec-osf*)
 925     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 926     ;;
 927   i[[3456789]]86-*-linux*)
 928     # This section makes it possible to build newlib natively on linux.
 929     # If we are using a cross compiler then don't configure newlib.
 930     if test x${is_cross_compiler} != xno ; then
 931       noconfigdirs="$noconfigdirs target-newlib"
 932     fi
 933     noconfigdirs="$noconfigdirs target-libgloss"
 934     # If we are not using a cross compiler, do configure newlib.
 935     # Note however, that newlib will only be configured in this situation
 936     # if the --with-newlib option has been given, because otherwise
 937     # 'target-newlib' will appear in skipdirs.
 938     ;;
 939   i[[3456789]]86-*-rdos*)
 940     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 941     ;;
 942   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 943     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 944     ;;
 945   sparc-*-sunos4*)
 946     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 947     ;;
 948   bpf-*-*)
 949     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 950     ;;
 951   *-*-aix*)
 952     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 953     ;;
 954   *-*-beos*)
 955     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 956     ;;
 957   *-*-chorusos)
 958     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 959     ;;
 960   *-*-dragonfly*)
 961     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 962     ;;
 963   *-*-freebsd*)
 964     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 965     ;;
 966   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 967     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 968     ;;
 969   *-*-lynxos*)
 970     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 971     ;;
 972   *-*-mingw*)
 973     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 974     ;;
 975   *-*-netbsd*)
 976     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 977     ;;
 978   *-*-netware*)
 979     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 980     ;;
 981   *-*-tpf*)
 982     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 983     ;;
 984   *-*-uclinux*)
 985     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 986     ;;
 987   *-*-vxworks*)
 988     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 989     ;;
 990 esac
 991
 992 case "${target}" in
 993   *-*-chorusos)
 994     ;;
 995   aarch64-*-darwin*)
 996     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 997     noconfigdirs="$noconfigdirs sim target-rda"
 998     ;;
 999   amdgcn*-*-*)
1000     ;;
1001   arm-*-darwin*)
1002     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1003     noconfigdirs="$noconfigdirs sim target-rda"
1004     ;;
1005   powerpc-*-darwin*)
1006     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1007     noconfigdirs="$noconfigdirs sim target-rda"
1008     ;;
1009   i[[3456789]]86-*-darwin*)
1010     noconfigdirs="$noconfigdirs ld gprof"
1011     noconfigdirs="$noconfigdirs sim target-rda"
1012     ;;
1013   x86_64-*-darwin[[912]]*)
1014     noconfigdirs="$noconfigdirs ld gas gprof"
1015     noconfigdirs="$noconfigdirs sim target-rda"
1016     ;;
1017   *-*-darwin*)
1018     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1019     noconfigdirs="$noconfigdirs sim target-rda"
1020     ;;
1021   *-*-dragonfly*)
1022     ;;
1023   *-*-freebsd*)
1024     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
1025         && ! test -d ${srcdir}/gmp \
1026         && test -f /usr/local/include/gmp.h; then
1027       with_gmp=/usr/local
1028     fi
1029     ;;
1030   *-*-kaos*)
1031     # Remove unsupported stuff on all kaOS configurations.
1032     noconfigdirs="$noconfigdirs target-libgloss"
1033     ;;
1034   *-*-netbsd*)
1035     ;;
1036   *-*-netware*)
1037     ;;
1038   *-*-phoenix*)
1039     noconfigdirs="$noconfigdirs target-libgloss"
1040     ;;
1041   *-*-rtems*)
1042     noconfigdirs="$noconfigdirs target-libgloss"
1043     ;;
1044     # The tpf target doesn't support gdb yet.
1045   *-*-tpf*)
1046     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1047     ;;
1048   *-*-uclinux*)
1049     noconfigdirs="$noconfigdirs target-rda"
1050     ;;
1051   *-*-vxworks*)
1052     ;;
1053   alpha*-dec-osf*)
1054     # ld works, but does not support shared libraries.
1055     # gas doesn't generate exception information.
1056     noconfigdirs="$noconfigdirs gas ld"
1057     ;;
1058   alpha*-*-*vms*)
1059     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1060     ;;
1061   alpha*-*-*)
1062     # newlib is not 64 bit ready
1063     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1064     ;;
1065   bpf-*-*)
1066     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1067     ;;
1068   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1069     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1070     ;;
1071   arc*-*-*)
1072     noconfigdirs="$noconfigdirs sim"
1073     ;;
1074   arm-*-pe*)
1075     noconfigdirs="$noconfigdirs target-libgloss"
1076     ;;
1077   arm-*-riscix*)
1078     noconfigdirs="$noconfigdirs ld target-libgloss"
1079     ;;
1080   avr-*-*)
1081     if test x${with_avrlibc} != xno; then
1082       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1083     fi
1084     ;;
1085   c4x-*-* | tic4x-*-*)
1086     noconfigdirs="$noconfigdirs target-libgloss"
1087     ;;
1088   tic54x-*-*)
1089     noconfigdirs="$noconfigdirs target-libgloss gdb"
1090     ;;
1091   d10v-*-*)
1092     noconfigdirs="$noconfigdirs target-libgloss"
1093     ;;
1094   d30v-*-*)
1095     noconfigdirs="$noconfigdirs gdb"
1096     ;;
1097   fr30-*-elf*)
1098     noconfigdirs="$noconfigdirs gdb"
1099     ;;
1100   ft32-*-*)
1101     noconfigdirs="$noconfigdirs target-rda gprof"
1102     ;;
1103   moxie-*-*)
1104     noconfigdirs="$noconfigdirs"
1105     ;;
1106   h8300*-*-*)
1107     noconfigdirs="$noconfigdirs target-libgloss"
1108     ;;
1109   h8500-*-*)
1110     noconfigdirs="$noconfigdirs target-libgloss"
1111     ;;
1112   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1113     ;;
1114   hppa*64*-*-hpux*)
1115     noconfigdirs="$noconfigdirs gdb"
1116     ;;
1117   hppa*-*-hpux11*)
1118     noconfigdirs="$noconfigdirs gdb ld"
1119     ;;
1120   hppa*64*-*-linux*)
1121     ;;
1122   hppa*-*-linux*)
1123     ;;
1124   hppa*-*-*elf* | \
1125   hppa*-*-lites* | \
1126   hppa*-*-openbsd* | \
1127   hppa*64*-*-*)
1128     ;;
1129   hppa*-*-pro*)
1130     ;;
1131   hppa*-*-*)
1132     noconfigdirs="$noconfigdirs ld"
1133     ;;
1134   i960-*-*)
1135     noconfigdirs="$noconfigdirs gdb"
1136     ;;
1137   ia64*-*-elf*)
1138     # No gdb support yet.
1139     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1140     ;;
1141   ia64*-**-hpux*)
1142     # No ld support yet.
1143     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1144     ;;
1145   ia64*-*-*vms*)
1146     # No ld support yet.
1147     noconfigdirs="$noconfigdirs libgui itcl ld"
1148     ;;
1149   i[[3456789]]86-w64-mingw*)
1150     ;;
1151   i[[3456789]]86-*-mingw*)
1152     target_configdirs="$target_configdirs target-winsup"
1153     ;;
1154   *-*-cygwin*)
1155     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1156     noconfigdirs="$noconfigdirs target-libgloss"
1157     # always build newlib if winsup directory is present.
1158     if test -d "$srcdir/winsup/cygwin"; then
1159       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1160     elif test -d "$srcdir/newlib"; then
1161       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1162     fi
1163     ;;
1164   i[[3456789]]86-*-pe)
1165     noconfigdirs="$noconfigdirs target-libgloss"
1166     ;;
1167   i[[3456789]]86-*-sco3.2v5*)
1168     # The linker does not yet know about weak symbols in COFF,
1169     # and is not configured to handle mixed ELF and COFF.
1170     noconfigdirs="$noconfigdirs ld target-libgloss"
1171     ;;
1172   i[[3456789]]86-*-sco*)
1173     noconfigdirs="$noconfigdirs gprof target-libgloss"
1174     ;;
1175   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1176     noconfigdirs="$noconfigdirs target-libgloss"
1177     ;;
1178   i[[3456789]]86-*-sysv4*)
1179     noconfigdirs="$noconfigdirs target-libgloss"
1180     ;;
1181   i[[3456789]]86-*-beos*)
1182     noconfigdirs="$noconfigdirs gdb"
1183     ;;
1184   i[[3456789]]86-*-rdos*)
1185     noconfigdirs="$noconfigdirs gdb"
1186     ;;
1187   mmix-*-*)
1188     noconfigdirs="$noconfigdirs gdb"
1189     ;;
1190   mt-*-*)
1191     noconfigdirs="$noconfigdirs sim"
1192     ;;
1193   nfp-*-*)
1194     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1195     noconfigdirs="$noconfigdirs $target_libraries"
1196     ;;
1197   pdp11-*-*)
1198     noconfigdirs="$noconfigdirs gdb gprof"
1199     ;;
1200   powerpc-*-aix*)
1201     # copied from rs6000-*-* entry
1202     noconfigdirs="$noconfigdirs gprof"
1203     ;;
1204   powerpc*-*-winnt* | powerpc*-*-pe*)
1205     target_configdirs="$target_configdirs target-winsup"
1206     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1207     # always build newlib.
1208     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1209     ;;
1210     # This is temporary until we can link against shared libraries
1211   powerpcle-*-solaris*)
1212     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1213     ;;
1214   powerpc-*-beos*)
1215     noconfigdirs="$noconfigdirs gdb"
1216     ;;
1217   rs6000-*-lynxos*)
1218     noconfigdirs="$noconfigdirs gprof"
1219     ;;
1220   rs6000-*-aix*)
1221     noconfigdirs="$noconfigdirs gprof"
1222     ;;
1223   rs6000-*-*)
1224     noconfigdirs="$noconfigdirs gprof"
1225     ;;
1226   m68k-apollo-*)
1227     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1228     ;;
1229   microblaze*)
1230     noconfigdirs="$noconfigdirs gprof"
1231     ;;
1232   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1233     if test x$with_newlib = xyes; then
1234       noconfigdirs="$noconfigdirs gprof"
1235     fi
1236     ;;
1237   mips*-*-irix5*)
1238     noconfigdirs="$noconfigdirs gprof target-libgloss"
1239     ;;
1240   mips*-*-irix6*)
1241     noconfigdirs="$noconfigdirs gprof target-libgloss"
1242     ;;
1243   mips*-*-bsd*)
1244     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1245     ;;
1246   mips*-*-linux*)
1247     ;;
1248   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1249   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1250     noconfigdirs="$noconfigdirs ld gas gprof"
1251     ;;
1252   mips*-*-*)
1253     noconfigdirs="$noconfigdirs gprof"
1254     ;;
1255   nvptx*-*-*)
1256     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1257     ;;
1258   sh-*-*)
1259     case "${target}" in
1260       sh*-*-elf)
1261          ;;
1262       *)
1263          noconfigdirs="$noconfigdirs target-libgloss" ;;
1264     esac
1265     ;;
1266   sparc-*-sunos4*)
1267     if test x${is_cross_compiler} = xno ; then
1268            use_gnu_ld=no
1269     fi
1270     ;;
1271   tic6x-*-*)
1272     noconfigdirs="$noconfigdirs sim"
1273     ;;
1274   tilepro*-*-* | tilegx*-*-*)
1275     noconfigdirs="$noconfigdirs sim"
1276     ;;
1277   v810-*-*)
1278     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1279     ;;
1280   vax-*-*)
1281     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1282     ;;
1283   wasm32-*-*)
1284     noconfigdirs="$noconfigdirs ld"
1285     ;;
1286 esac
1287
1288 # If we aren't building newlib, then don't build libgloss, since libgloss
1289 # depends upon some newlib header files.
1290 case "${noconfigdirs}" in
1291   *target-libgloss*) ;;
1292   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1293 esac
1294
1295 # Work in distributions that contain no compiler tools, like Autoconf.
1296 host_makefile_frag=/dev/null
1297 if test -d ${srcdir}/config ; then
1298 case "${host}" in
1299   i[[3456789]]86-*-msdosdjgpp*)
1300     host_makefile_frag="config/mh-djgpp"
1301     ;;
1302   *-cygwin*)
1303     ACX_CHECK_CYGWIN_CAT_WORKS
1304     host_makefile_frag="config/mh-cygwin"
1305     ;;
1306   *-mingw*)
1307     host_makefile_frag="config/mh-mingw"
1308     ;;
1309   alpha*-linux*)
1310     host_makefile_frag="config/mh-alpha-linux"
1311     ;;
1312   hppa*-hp-hpux10*)
1313     host_makefile_frag="config/mh-pa-hpux10"
1314     ;;
1315   hppa*-hp-hpux*)
1316     host_makefile_frag="config/mh-pa"
1317     ;;
1318   hppa*-*)
1319     host_makefile_frag="config/mh-pa"
1320     ;;
1321   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1322     host_makefile_frag="config/mh-darwin"
1323     ;;
1324   powerpc-*-aix*)
1325     host_makefile_frag="config/mh-ppc-aix"
1326     ;;
1327   rs6000-*-aix*)
1328     host_makefile_frag="config/mh-ppc-aix"
1329     ;;
1330 esac
1331 fi
1332
1333 if test "${build}" != "${host}" ; then
1334   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1335   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1336   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1337   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1338   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1339   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1340   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1341   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1342   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1343   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1344   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1345   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1346   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1347   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1348   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1349 else
1350   AR_FOR_BUILD="\$(AR)"
1351   AS_FOR_BUILD="\$(AS)"
1352   CC_FOR_BUILD="\$(CC)"
1353   CXX_FOR_BUILD="\$(CXX)"
1354   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1355   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1356   GOC_FOR_BUILD="\$(GOC)"
1357   GDC_FOR_BUILD="\$(GDC)"
1358   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1359   LD_FOR_BUILD="\$(LD)"
1360   NM_FOR_BUILD="\$(NM)"
1361   RANLIB_FOR_BUILD="\$(RANLIB)"
1362   WINDRES_FOR_BUILD="\$(WINDRES)"
1363   WINDMC_FOR_BUILD="\$(WINDMC)"
1364 fi
1365
1366 AC_PROG_CC_C99
1367 AC_PROG_CXX
1368
1369 # We must set the default linker to the linker used by gcc for the correct
1370 # operation of libtool.  If LD is not defined and we are using gcc, try to
1371 # set the LD default to the ld used by gcc.
1372 if test -z "$LD"; then
1373   if test "$GCC" = yes; then
1374     case $build in
1375     *-*-mingw*)
1376       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1377     *)
1378       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1379     esac
1380     case $gcc_prog_ld in
1381     # Accept absolute paths.
1382     [[\\/]* | [A-Za-z]:[\\/]*)]
1383       LD="$gcc_prog_ld" ;;
1384     esac
1385   fi
1386 fi
1387
1388 # Check whether -static-libstdc++ -static-libgcc is supported.
1389 have_static_libs=no
1390 if test "$GCC" = yes; then
1391   saved_LDFLAGS="$LDFLAGS"
1392
1393   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1394   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1395   AC_LANG_PUSH(C++)
1396   AC_LINK_IFELSE([AC_LANG_SOURCE([
1397 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1398 #error -static-libstdc++ not implemented
1399 #endif
1400 int main() {}])],
1401     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1402     [AC_MSG_RESULT([no])])
1403   AC_LANG_POP(C++)
1404
1405   LDFLAGS="$saved_LDFLAGS"
1406 fi
1407
1408 ACX_PROG_GNAT
1409 ACX_PROG_GDC
1410 ACX_PROG_CMP_IGNORE_INITIAL
1411
1412 AC_ARG_ENABLE([bootstrap],
1413 [AS_HELP_STRING([--enable-bootstrap],
1414                 [enable bootstrapping @<:@yes if native build@:>@])],,
1415 enable_bootstrap=default)
1416
1417 # Issue errors and warnings for invalid/strange bootstrap combinations.
1418 if test -r $srcdir/gcc/configure; then
1419   have_compiler=yes
1420 else
1421   have_compiler=no
1422 fi
1423
1424 case "$have_compiler:$host:$target:$enable_bootstrap" in
1425   *:*:*:no) ;;
1426
1427   # Default behavior.  Enable bootstrap if we have a compiler
1428   # and we are in a native configuration.
1429   yes:$build:$build:default)
1430     enable_bootstrap=yes ;;
1431
1432   *:*:*:default)
1433     enable_bootstrap=no ;;
1434
1435   # We have a compiler and we are in a native configuration, bootstrap is ok
1436   yes:$build:$build:yes)
1437     ;;
1438
1439   # Other configurations, but we have a compiler.  Assume the user knows
1440   # what he's doing.
1441   yes:*:*:yes)
1442     AC_MSG_WARN([trying to bootstrap a cross compiler])
1443     ;;
1444
1445   # No compiler: if they passed --enable-bootstrap explicitly, fail
1446   no:*:*:yes)
1447     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1448
1449   # Fail if wrong command line
1450   *)
1451     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1452     ;;
1453 esac
1454
1455 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1456 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1457 # require C++11 (or higher).
1458 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1459   CXX="$CXX -std=c++11"
1460 elif test "$have_compiler" = yes; then
1461   AX_CXX_COMPILE_STDCXX(11)
1462
1463   if test "${build}" != "${host}"; then
1464     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1465   fi
1466 fi
1467
1468 # Used for setting $lt_cv_objdir
1469 _LT_CHECK_OBJDIR
1470
1471 # Check for GMP, MPFR and MPC
1472 gmplibs="-lmpc -lmpfr -lgmp"
1473 gmpinc=
1474 have_gmp=no
1475
1476 # Specify a location for mpc
1477 # check for this first so it ends up on the link line before mpfr.
1478 AC_ARG_WITH(mpc,
1479 [AS_HELP_STRING([--with-mpc=PATH],
1480                 [specify prefix directory for installed MPC package.
1481                  Equivalent to --with-mpc-include=PATH/include
1482                  plus --with-mpc-lib=PATH/lib])])
1483 AC_ARG_WITH(mpc-include,
1484 [AS_HELP_STRING([--with-mpc-include=PATH],
1485                 [specify directory for installed MPC include files])])
1486 AC_ARG_WITH(mpc-lib,
1487 [AS_HELP_STRING([--with-mpc-lib=PATH],
1488                 [specify directory for the installed MPC library])])
1489
1490 if test "x$with_mpc" != x; then
1491   gmplibs="-L$with_mpc/lib $gmplibs"
1492   gmpinc="-I$with_mpc/include $gmpinc"
1493 fi
1494 if test "x$with_mpc_include" != x; then
1495   gmpinc="-I$with_mpc_include $gmpinc"
1496 fi
1497 if test "x$with_mpc_lib" != x; then
1498   gmplibs="-L$with_mpc_lib $gmplibs"
1499 fi
1500 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1501   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1502   gmpinc='-I$$s/mpc/src '"$gmpinc"
1503   # Do not test the mpc version.  Assume that it is sufficient, since
1504   # it is in the source tree, and the library has not been built yet
1505   # but it would be included on the link line in the version check below
1506   # hence making the test fail.
1507   have_gmp=yes
1508 fi
1509
1510 # Specify a location for mpfr
1511 # check for this first so it ends up on the link line before gmp.
1512 AC_ARG_WITH(mpfr-dir,
1513 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1514 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1515 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1516
1517 AC_ARG_WITH(mpfr,
1518 [AS_HELP_STRING([--with-mpfr=PATH],
1519                 [specify prefix directory for installed MPFR package.
1520                  Equivalent to --with-mpfr-include=PATH/include
1521                  plus --with-mpfr-lib=PATH/lib])])
1522 AC_ARG_WITH(mpfr-include,
1523 [AS_HELP_STRING([--with-mpfr-include=PATH],
1524                 [specify directory for installed MPFR include files])])
1525 AC_ARG_WITH(mpfr-lib,
1526 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1527                 [specify directory for the installed MPFR library])])
1528
1529 if test "x$with_mpfr" != x; then
1530   gmplibs="-L$with_mpfr/lib $gmplibs"
1531   gmpinc="-I$with_mpfr/include $gmpinc"
1532 fi
1533 if test "x$with_mpfr_include" != x; then
1534   gmpinc="-I$with_mpfr_include $gmpinc"
1535 fi
1536 if test "x$with_mpfr_lib" != x; then
1537   gmplibs="-L$with_mpfr_lib $gmplibs"
1538 fi
1539 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1540   # MPFR v3.1.0 moved the sources into a src sub-directory.
1541   if ! test -d ${srcdir}/mpfr/src; then
1542     AC_MSG_ERROR([dnl
1543 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1544   fi
1545   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1546   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1547   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1548   # Do not test the mpfr version.  Assume that it is sufficient, since
1549   # it is in the source tree, and the library has not been built yet
1550   # but it would be included on the link line in the version check below
1551   # hence making the test fail.
1552   have_gmp=yes
1553 fi
1554
1555 # Specify a location for gmp
1556 AC_ARG_WITH(gmp-dir,
1557 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1558 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1559 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1560
1561 AC_ARG_WITH(gmp,
1562 [AS_HELP_STRING([--with-gmp=PATH],
1563                 [specify prefix directory for the installed GMP package.
1564                  Equivalent to --with-gmp-include=PATH/include
1565                  plus --with-gmp-lib=PATH/lib])])
1566 AC_ARG_WITH(gmp-include,
1567 [AS_HELP_STRING([--with-gmp-include=PATH],
1568                 [specify directory for installed GMP include files])])
1569 AC_ARG_WITH(gmp-lib,
1570 [AS_HELP_STRING([--with-gmp-lib=PATH],
1571                 [specify directory for the installed GMP library])])
1572
1573
1574 if test "x$with_gmp" != x; then
1575   gmplibs="-L$with_gmp/lib $gmplibs"
1576   gmpinc="-I$with_gmp/include $gmpinc"
1577 fi
1578 if test "x$with_gmp_include" != x; then
1579   gmpinc="-I$with_gmp_include $gmpinc"
1580 fi
1581 if test "x$with_gmp_lib" != x; then
1582   gmplibs="-L$with_gmp_lib $gmplibs"
1583 fi
1584 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1585   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1586   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1587   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1588   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1589   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1590   # Do not test the gmp version.  Assume that it is sufficient, since
1591   # it is in the source tree, and the library has not been built yet
1592   # but it would be included on the link line in the version check below
1593   # hence making the test fail.
1594   have_gmp=yes
1595 fi
1596
1597 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1598   have_gmp=yes
1599   saved_CFLAGS="$CFLAGS"
1600   CFLAGS="$CFLAGS $gmpinc"
1601   # Check for the recommended and required versions of GMP.
1602   AC_MSG_CHECKING([for the correct version of gmp.h])
1603   AC_TRY_COMPILE([#include "gmp.h"],[
1604   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1605   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1606   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1607   choke me
1608   #endif
1609   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1610   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1611   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1612   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1613   choke me
1614   #endif
1615   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1616    [AC_MSG_RESULT([no]); have_gmp=no])
1617
1618   # If we have GMP, check the MPFR version.
1619   if test x"$have_gmp" = xyes; then
1620     # Check for the recommended and required versions of MPFR.
1621     AC_MSG_CHECKING([for the correct version of mpfr.h])
1622     AC_TRY_COMPILE([#include <gmp.h>
1623     #include <mpfr.h>],[
1624     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1625     choke me
1626     #endif
1627     ], [AC_TRY_COMPILE([#include <gmp.h>
1628     #include <mpfr.h>],[
1629     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1630     choke me
1631     #endif
1632     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1633      [AC_MSG_RESULT([no]); have_gmp=no])
1634   fi
1635
1636   # Check for the MPC header version.
1637   if test x"$have_gmp" = xyes ; then
1638     # Check for the recommended and required versions of MPC.
1639     AC_MSG_CHECKING([for the correct version of mpc.h])
1640     AC_TRY_COMPILE([#include <mpc.h>],[
1641     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1642     choke me
1643     #endif
1644     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1645     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1646     choke me
1647     #endif
1648     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1649      [AC_MSG_RESULT([no]); have_gmp=no])
1650   fi
1651
1652   # Now check the MPFR library.
1653   if test x"$have_gmp" = xyes; then
1654     saved_LIBS="$LIBS"
1655     LIBS="$LIBS $gmplibs"
1656     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1657     AC_TRY_LINK([#include <mpc.h>],[
1658     mpfr_t n;
1659     mpfr_t x;
1660     mpc_t c;
1661     int t;
1662     mpfr_init (n);
1663     mpfr_init (x);
1664     mpfr_atan2 (n, n, x, MPFR_RNDN);
1665     mpfr_erfc (n, x, MPFR_RNDN);
1666     mpfr_subnormalize (x, t, MPFR_RNDN);
1667     mpfr_clear(n);
1668     mpfr_clear(x);
1669     mpc_init2 (c, 53);
1670     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1671     mpc_cosh (c, c, MPC_RNDNN);
1672     mpc_pow (c, c, c, MPC_RNDNN);
1673     mpc_acosh (c, c, MPC_RNDNN);
1674     mpc_clear (c);
1675     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1676     LIBS="$saved_LIBS"
1677   fi
1678
1679   CFLAGS="$saved_CFLAGS"
1680
1681 # The library versions listed in the error message below should match
1682 # the HARD-minimums enforced above.
1683   if test x$have_gmp != xyes; then
1684     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1685 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1686 their locations.  Source code for these libraries can be found at
1687 their respective hosting sites as well as at
1688 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1689 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1690 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1691 make sure that you have installed both the libraries and the header
1692 files.  They may be located in separate packages.])
1693   fi
1694 fi
1695
1696 # Flags needed for both GMP, MPFR and/or MPC.
1697 AC_SUBST(gmplibs)
1698 AC_SUBST(gmpinc)
1699 AC_SUBST(extra_mpfr_configure_flags)
1700 AC_SUBST(extra_mpc_gmp_configure_flags)
1701 AC_SUBST(extra_mpc_mpfr_configure_flags)
1702 AC_SUBST(extra_isl_gmp_configure_flags)
1703
1704 # Libraries to use for stage1 or when not bootstrapping.
1705 AC_ARG_WITH(stage1-libs,
1706 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1707 [if test "$withval" = "no" -o "$withval" = "yes"; then
1708    stage1_libs=
1709  else
1710    stage1_libs=$withval
1711  fi],
1712 [stage1_libs=])
1713 AC_SUBST(stage1_libs)
1714
1715 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1716 # default is yes if gcc is being built; no otherwise.  The reason for
1717 # this default is that gdb is sometimes linked against GNU Source
1718 # Highlight, which is a shared library that uses C++ exceptions.  In
1719 # this case, -static-libstdc++ will cause crashes.
1720 AC_ARG_WITH(static-standard-libraries,
1721 [AS_HELP_STRING([--with-static-standard-libraries],
1722                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1723 [], [with_static_standard_libraries=auto])
1724 if test "$with_static_standard_libraries" = auto; then
1725   with_static_standard_libraries=$have_compiler
1726 fi
1727
1728 # Linker flags to use for stage1 or when not bootstrapping.
1729 AC_ARG_WITH(stage1-ldflags,
1730 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1731 [if test "$withval" = "no" -o "$withval" = "yes"; then
1732    stage1_ldflags=
1733  else
1734    stage1_ldflags=$withval
1735  fi],
1736 [stage1_ldflags=
1737  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1738  # if supported.  But if the user explicitly specified the libraries to use,
1739  # trust that they are doing what they want.
1740  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1741      -a "$have_static_libs" = yes; then
1742    stage1_ldflags="-static-libstdc++ -static-libgcc"
1743  fi])
1744 AC_SUBST(stage1_ldflags)
1745
1746 # Libraries to use for stage2 and later builds.
1747 AC_ARG_WITH(boot-libs,
1748 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1749 [if test "$withval" = "no" -o "$withval" = "yes"; then
1750    poststage1_libs=
1751  else
1752    poststage1_libs=$withval
1753  fi],
1754 [poststage1_libs=])
1755 AC_SUBST(poststage1_libs)
1756
1757 # Linker flags to use for stage2 and later builds.
1758 AC_ARG_WITH(boot-ldflags,
1759 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1760                 [linker flags for stage2 and later])],
1761 [if test "$withval" = "no" -o "$withval" = "yes"; then
1762    poststage1_ldflags=
1763  else
1764    poststage1_ldflags=$withval
1765  fi],
1766 [poststage1_ldflags=
1767  # In stages 2 and 3, default to linking libstdc++ and libgcc
1768  # statically.  But if the user explicitly specified the libraries to
1769  # use, trust that they are doing what they want.
1770  if test "$poststage1_libs" = ""; then
1771    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1772  fi])
1773 AC_SUBST(poststage1_ldflags)
1774
1775 # GCC GRAPHITE dependency isl.
1776 # Basic setup is inlined here, actual checks are in config/isl.m4
1777
1778 AC_ARG_WITH(isl,
1779   [AS_HELP_STRING(
1780    [--with-isl=PATH],
1781    [Specify prefix directory for the installed isl package.
1782     Equivalent to --with-isl-include=PATH/include
1783     plus --with-isl-lib=PATH/lib])])
1784
1785 # Treat --without-isl as a request to disable
1786 # GRAPHITE support and skip all following checks.
1787 if test "x$with_isl" != "xno"; then
1788   # Check for isl
1789   dnl Provide configure switches and initialize islinc & isllibs
1790   dnl with user input.
1791   ISL_INIT_FLAGS
1792   dnl The versions of isl that work for Graphite
1793   ISL_CHECK_VERSION()
1794   dnl Only execute fail-action, if isl has been requested.
1795   ISL_IF_FAILED([
1796     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1797 fi
1798
1799 # If the isl check failed, disable builds of in-tree variant of isl
1800 if test "x$with_isl" = xno ||
1801    test "x$gcc_cv_isl" = xno; then
1802   noconfigdirs="$noconfigdirs isl"
1803   islinc=
1804 fi
1805
1806 AC_SUBST(isllibs)
1807 AC_SUBST(islinc)
1808
1809 # Check for LTO support.
1810 AC_ARG_ENABLE(lto,
1811 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1812 enable_lto=$enableval,
1813 enable_lto=yes; default_enable_lto=yes)
1814
1815 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1816   build_lto_plugin=yes
1817 ],[if test x"$default_enable_lto" = x"yes" ; then
1818     case $target in
1819       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1820       # On other non-ELF platforms, LTO has yet to be validated.
1821       *) enable_lto=no ;;
1822     esac
1823   else
1824   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1825   # It would also be nice to check the binutils support, but we don't
1826   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1827   # warn during gcc/ subconfigure; unless you're bootstrapping with
1828   # -flto it won't be needed until after installation anyway.
1829     case $target in
1830       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1831       *) if test x"$enable_lto" = x"yes"; then
1832         AC_MSG_ERROR([LTO support is not enabled for this target.])
1833         fi
1834       ;;
1835     esac
1836   fi
1837   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1838   # Build it unless LTO was explicitly disabled.
1839   case $target in
1840     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1841     *) ;;
1842   esac
1843 ])
1844
1845 AC_ARG_ENABLE(linker-plugin-configure-flags,
1846   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1847     [additional flags for configuring linker plugins @<:@none@:>@])],
1848   extra_linker_plugin_configure_flags=$enableval,
1849   extra_linker_plugin_configure_flags=)
1850 AC_SUBST(extra_linker_plugin_configure_flags)
1851 AC_ARG_ENABLE(linker-plugin-flags,
1852   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1853     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1854   extra_linker_plugin_flags=$enableval,
1855   extra_linker_plugin_flags=)
1856 AC_SUBST(extra_linker_plugin_flags)
1857
1858 # Enable --enable-host-shared.
1859 # Checked early to determine whether jit is an 'all' language
1860 AC_ARG_ENABLE(host-shared,
1861 [AS_HELP_STRING([--enable-host-shared],
1862                 [build host code as shared libraries])],
1863 [host_shared=$enableval
1864  case $target in
1865    x86_64-*-darwin* | aarch64-*-darwin*)
1866      if test x$host_shared != xyes ; then
1867        # PIC is the default, and actually cannot be switched off.
1868        echo configure.ac: warning: PIC code is required for the configured target, host-shared setting ignored. 1>&2
1869        host_shared=yes
1870      fi ;;
1871   *) ;;
1872  esac],
1873 [case $target in
1874   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
1875   *) host_shared=no ;;
1876  esac])
1877 AC_SUBST(host_shared)
1878
1879 # By default, C and C++ are the only stage 1 languages.
1880 stage1_languages=,c,
1881
1882 # Target libraries that we bootstrap.
1883 bootstrap_target_libs=,target-libgcc,
1884
1885 # Figure out what language subdirectories are present.
1886 # Look if the user specified --enable-languages="..."; if not, use
1887 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1888 # go away some day.
1889 # NB:  embedded tabs in this IF block -- do not untabify
1890 if test -d ${srcdir}/gcc; then
1891   if test x"${enable_languages+set}" != xset; then
1892     if test x"${LANGUAGES+set}" = xset; then
1893       enable_languages="${LANGUAGES}"
1894         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1895     else
1896       enable_languages=default
1897     fi
1898   else
1899     if test x"${enable_languages}" = x ||
1900        test x"${enable_languages}" = xyes;
1901        then
1902       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1903       exit 1
1904     fi
1905   fi
1906   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1907
1908   # 'f95' is the old name for the 'fortran' language. We issue a warning
1909   # and make the substitution.
1910   case ,${enable_languages}, in
1911     *,f95,*)
1912       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1913       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1914       ;;
1915   esac
1916
1917   # If bootstrapping, C++ must be enabled.
1918   case ",$enable_languages,:$enable_bootstrap" in
1919     *,c++,*:*) ;;
1920     *:yes)
1921       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1922         enable_languages="${enable_languages},c++"
1923       else
1924         AC_MSG_ERROR([bootstrapping requires c++ sources])
1925       fi
1926       ;;
1927   esac
1928
1929   # First scan to see if an enabled language requires some other language.
1930   # We assume that a given config-lang.in will list all the language
1931   # front ends it requires, even if some are required indirectly.
1932   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1933     case ${lang_frag} in
1934       ..) ;;
1935       # The odd quoting in the next line works around
1936       # an apparent bug in bash 1.12 on linux.
1937       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1938       *)
1939         # From the config-lang.in, get $language, $lang_requires, and
1940         # $lang_requires_boot_languages.
1941         language=
1942         lang_requires=
1943         lang_requires_boot_languages=
1944         # set srcdir during sourcing lang_frag to the gcc dir.
1945         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1946         # polutes this shell
1947         saved_srcdir=${srcdir}
1948         srcdir=${srcdir}/gcc . ${lang_frag}
1949         srcdir=${saved_srcdir}
1950         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1951           case ,${enable_languages}, in
1952             *,$other,*) ;;
1953             *,default,*) ;;
1954             *,all,*) ;;
1955             *,$language,*)
1956               echo " \`$other' language required by \`$language'; enabling" 1>&2
1957               enable_languages="${enable_languages},${other}"
1958               ;;
1959           esac
1960         done
1961         for other in ${lang_requires_boot_languages} ; do
1962           if test "$other" != "c"; then
1963             case ,${enable_stage1_languages}, in
1964               *,$other,*) ;;
1965               *,default,*) ;;
1966               *,all,*) ;;
1967               *)
1968                 case ,${enable_languages}, in
1969                   *,$language,*)
1970                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1971                     enable_stage1_languages="$enable_stage1_languages,${other}"
1972                     ;;
1973                 esac
1974                 ;;
1975             esac
1976           fi
1977         done
1978         ;;
1979     esac
1980   done
1981
1982   new_enable_languages=,c,
1983
1984   # If LTO is enabled, add the LTO front end.
1985   if test "$enable_lto" = "yes" ; then
1986     case ,${enable_languages}, in
1987       *,lto,*) ;;
1988       *) enable_languages="${enable_languages},lto" ;;
1989     esac
1990     if test "${build_lto_plugin}" = "yes" ; then
1991       configdirs="$configdirs lto-plugin"
1992     fi
1993   fi
1994
1995   # If we're building an offloading compiler, add the LTO front end.
1996   if test x"$enable_as_accelerator_for" != x ; then
1997     case ,${enable_languages}, in
1998       *,lto,*) ;;
1999       *) enable_languages="${enable_languages},lto" ;;
2000     esac
2001   fi
2002
2003   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2004   potential_languages=,c,
2005
2006   enabled_target_libs=
2007   disabled_target_libs=
2008
2009   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2010     case ${lang_frag} in
2011       ..) ;;
2012       # The odd quoting in the next line works around
2013       # an apparent bug in bash 1.12 on linux.
2014       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2015       *)
2016         # From the config-lang.in, get $language, $target_libs,
2017         # $lang_dirs, $boot_language, and $build_by_default
2018         language=
2019         target_libs=
2020         lang_dirs=
2021         subdir_requires=
2022         boot_language=no
2023         build_by_default=yes
2024         # set srcdir during sourcing.  See above about save & restore
2025         saved_srcdir=${srcdir}
2026         srcdir=${srcdir}/gcc . ${lang_frag}
2027         srcdir=${saved_srcdir}
2028         if test x${language} = x; then
2029           echo "${lang_frag} doesn't set \$language." 1>&2
2030           exit 1
2031         fi
2032
2033         if test "$language" = "c++"; then
2034           boot_language=yes
2035         fi
2036
2037         add_this_lang=no
2038         # C is always enabled, so no need to add it again
2039         if test "$language" != "c"; then
2040           case ,${enable_languages}, in
2041             *,${language},*)
2042               # Language was explicitly selected; include it
2043               add_this_lang=yes
2044               ;;
2045             *,all,*)
2046               # All languages are enabled
2047               add_this_lang=all
2048               ;;
2049             *,default,*)
2050               # 'default' was selected, select it if it is a default language
2051               add_this_lang=${build_by_default}
2052               ;;
2053           esac
2054         fi
2055
2056         # Disable languages that need other directories if these aren't available.
2057         for i in $subdir_requires; do
2058           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2059           case ${add_this_lang} in
2060             yes)
2061               # Specifically requested language; tell them.
2062               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2063               ;;
2064             all)
2065               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2066               add_this_lang=unsupported
2067               ;;
2068             *)
2069               # Silently disable.
2070               add_this_lang=unsupported
2071               ;;
2072           esac
2073         done
2074
2075         # Disable Ada if no preexisting GNAT is available.
2076         case ${add_this_lang}:${language}:${have_gnat} in
2077           yes:ada:no)
2078             # Specifically requested language; tell them.
2079             AC_MSG_ERROR([GNAT is required to build $language])
2080             ;;
2081           all:ada:no)
2082             AC_MSG_WARN([GNAT is required to build $language])
2083             add_this_lang=unsupported
2084             ;;
2085           *:ada:no)
2086             # Silently disable.
2087             add_this_lang=unsupported
2088             ;;
2089         esac
2090
2091         # Disable D if no preexisting GDC is available.
2092         case ${add_this_lang}:${language}:${have_gdc} in
2093           yes:d:no)
2094             # Specifically requested language; tell them.
2095             AC_MSG_ERROR([GDC is required to build $language])
2096            ;;
2097           all:d:no)
2098             AC_MSG_WARN([GDC is required to build $language])
2099             add_this_lang=unsupported
2100             ;;
2101           *:d:no)
2102             # Silently disable.
2103             add_this_lang=unsupported
2104             ;;
2105         esac
2106
2107         # Disable jit if -enable-host-shared not specified
2108         # but not if building for Mingw. All code in Windows
2109         # is position independent code (PIC).
2110         case $target in
2111           *mingw*) ;;
2112           *)
2113           case ${add_this_lang}:${language}:${host_shared} in
2114             yes:jit:no)
2115                    # PR jit/64780: explicitly specify --enable-host-shared
2116             AC_MSG_ERROR([
2117 Enabling language "jit" requires --enable-host-shared.
2118
2119 --enable-host-shared typically slows the rest of the compiler down by
2120 a few %, so you must explicitly enable it.
2121
2122 If you want to build both the jit and the regular compiler, it is often
2123 best to do this via two separate configure/builds, in separate
2124 directories, to avoid imposing the performance cost of
2125 --enable-host-shared on the regular compiler.])
2126                     ;;
2127             all:jit:no)
2128               AC_MSG_WARN([--enable-host-shared required to build $language])
2129               add_this_lang=unsupported
2130               ;;
2131             *:jit:no)
2132               # Silently disable.
2133               add_this_lang=unsupported
2134               ;;
2135                 esac
2136           ;;
2137         esac
2138
2139         # Disable a language that is unsupported by the target.
2140         case "${add_this_lang}: $unsupported_languages " in
2141           no:*) ;;
2142           unsupported:*) ;;
2143           *:*" $language "*)
2144             AC_MSG_WARN([${language} not supported for this target])
2145             add_this_lang=unsupported
2146             ;;
2147         esac
2148
2149         case $add_this_lang in
2150           unsupported)
2151             # Remove language-dependent dirs.
2152             disabled_target_libs="$disabled_target_libs $target_libs"
2153             noconfigdirs="$noconfigdirs $lang_dirs"
2154             ;;
2155           no)
2156             # Remove language-dependent dirs; still show language as supported.
2157             disabled_target_libs="$disabled_target_libs $target_libs"
2158             noconfigdirs="$noconfigdirs $lang_dirs"
2159             potential_languages="${potential_languages}${language},"
2160             ;;
2161           all|yes)
2162             new_enable_languages="${new_enable_languages}${language},"
2163             potential_languages="${potential_languages}${language},"
2164             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2165             enabled_target_libs="$enabled_target_libs $target_libs"
2166             case "${boot_language}:,$enable_stage1_languages," in
2167               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2168                 # Add to (comma-separated) list of stage 1 languages.
2169                 case ",$stage1_languages," in
2170                   *,$language,* | ,yes, | ,all,) ;;
2171                   *) stage1_languages="${stage1_languages}${language}," ;;
2172                 esac
2173                 # We need to bootstrap any supporting libraries.
2174                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2175                 ;;
2176             esac
2177             ;;
2178         esac
2179         ;;
2180     esac
2181   done
2182
2183   # Add target libraries which are only needed for disabled languages
2184   # to noconfigdirs.
2185   if test -n "$disabled_target_libs"; then
2186     for dir in $disabled_target_libs; do
2187       case " $enabled_target_libs " in
2188       *" ${dir} "*) ;;
2189       *) noconfigdirs="$noconfigdirs $dir" ;;
2190       esac
2191     done
2192   fi
2193
2194   AC_ARG_ENABLE(stage1-languages,
2195   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2196                   [choose additional languages to build during
2197                   stage1.  Mostly useful for compiler development])],
2198   [case ,${enable_stage1_languages}, in
2199     ,no,|,,)
2200       # Set it to something that will have no effect in the loop below
2201       enable_stage1_languages=c ;;
2202     ,yes,)
2203       enable_stage1_languages=`echo $new_enable_languages | \
2204         sed -e "s/^,//" -e "s/,$//" ` ;;
2205     *,all,*)
2206       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2207         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2208   esac
2209
2210   # Add "good" languages from enable_stage1_languages to stage1_languages,
2211   # while "bad" languages go in missing_languages.  Leave no duplicates.
2212   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2213     case $potential_languages in
2214       *,$i,*)
2215         case $stage1_languages in
2216           *,$i,*) ;;
2217           *) stage1_languages="$stage1_languages$i," ;;
2218         esac ;;
2219       *)
2220         case $missing_languages in
2221           *,$i,*) ;;
2222           *) missing_languages="$missing_languages$i," ;;
2223         esac ;;
2224      esac
2225   done])
2226
2227   # Remove leading/trailing commas that were added for simplicity
2228   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2229   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2230   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2231   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2232
2233   if test "x$missing_languages" != x; then
2234     AC_MSG_ERROR([
2235 The following requested languages could not be built: ${missing_languages}
2236 Supported languages are: ${potential_languages}])
2237   fi
2238   if test "x$new_enable_languages" != "x$enable_languages"; then
2239     echo The following languages will be built: ${new_enable_languages}
2240     enable_languages="$new_enable_languages"
2241   fi
2242
2243   AC_SUBST(stage1_languages)
2244   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2245 fi
2246
2247 # Handle --disable-<component> generically.
2248 for dir in $configdirs $build_configdirs $target_configdirs ; do
2249   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2250   varname=`echo $dirname | sed -e s/+/_/g`
2251   if eval test x\${enable_${varname}} "=" xno ; then
2252     noconfigdirs="$noconfigdirs $dir"
2253   fi
2254 done
2255
2256 # Check for Boehm's garbage collector
2257 AC_ARG_ENABLE(objc-gc,
2258 [AS_HELP_STRING([--enable-objc-gc],
2259                 [enable use of Boehm's garbage collector with the
2260                  GNU Objective-C runtime])])
2261 AC_ARG_WITH([target-bdw-gc],
2262 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2263                 [specify prefix directory for installed bdw-gc package.
2264                  Equivalent to --with-target-bdw-gc-include=PATH/include
2265                  plus --with-target-bdw-gc-lib=PATH/lib])])
2266 AC_ARG_WITH([target-bdw-gc-include],
2267 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2268                 [specify directories for installed bdw-gc include files])])
2269 AC_ARG_WITH([target-bdw-gc-lib],
2270 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2271                 [specify directories for installed bdw-gc library])])
2272
2273 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2274   AC_MSG_CHECKING([for bdw garbage collector])
2275   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2276     dnl no bdw-gw options, assume default locations
2277     AC_MSG_RESULT([using bdw-gc in default locations])
2278   else
2279     dnl bdw-gw options, first error checking, complete checking in libobjc
2280     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2281       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2282     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2283       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2284     else
2285       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2286     fi
2287   fi
2288 esac
2289
2290 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2291 case ,${enable_languages}, in
2292   *,c++,*)
2293     # Disable libitm, libsanitizer if we're not building libstdc++
2294     case "${noconfigdirs}" in
2295       *target-libstdc++-v3*)
2296         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2297         ;;
2298       *) ;;
2299     esac
2300     ;;
2301   *)
2302     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2303     ;;
2304 esac
2305
2306 # If gcc/ is not in the source tree then we'll not be building a
2307 # target compiler, assume in that case we don't want to build any
2308 # target libraries or tools.
2309 #
2310 # This was added primarily for the benefit for binutils-gdb who reuse
2311 # this configure script, but don't always have target tools available.
2312 if test ! -d ${srcdir}/gcc; then
2313    skipdirs="${skipdirs} ${target_configdirs}"
2314 fi
2315
2316 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2317 # $build_configdirs and $target_configdirs.
2318 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2319
2320 notsupp=""
2321 for dir in . $skipdirs $noconfigdirs ; do
2322   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2323   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2324     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2325     if test -r $srcdir/$dirname/configure ; then
2326       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2327         true
2328       else
2329         notsupp="$notsupp $dir"
2330       fi
2331     fi
2332   fi
2333   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2334     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2335     if test -r $srcdir/$dirname/configure ; then
2336       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2337         true
2338       else
2339         notsupp="$notsupp $dir"
2340       fi
2341     fi
2342   fi
2343   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2344     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2345     if test -r $srcdir/$dirname/configure ; then
2346       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2347         true
2348       else
2349         notsupp="$notsupp $dir"
2350       fi
2351     fi
2352   fi
2353 done
2354
2355 # Quietly strip out all directories which aren't configurable in this tree.
2356 # This relies on all configurable subdirectories being autoconfiscated, which
2357 # is now the case.
2358 build_configdirs_all="$build_configdirs"
2359 build_configdirs=
2360 for i in ${build_configdirs_all} ; do
2361   j=`echo $i | sed -e s/build-//g`
2362   if test -f ${srcdir}/$j/configure ; then
2363     build_configdirs="${build_configdirs} $i"
2364   fi
2365 done
2366
2367 configdirs_all="$configdirs"
2368 configdirs=
2369 for i in ${configdirs_all} ; do
2370   if test -f ${srcdir}/$i/configure ; then
2371     configdirs="${configdirs} $i"
2372   fi
2373 done
2374
2375 target_configdirs_all="$target_configdirs"
2376 target_configdirs=
2377 for i in ${target_configdirs_all} ; do
2378   j=`echo $i | sed -e s/target-//g`
2379   if test -f ${srcdir}/$j/configure ; then
2380     target_configdirs="${target_configdirs} $i"
2381   fi
2382 done
2383
2384 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2385 # so we have to add it after the preceding checks.
2386 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2387 then
2388   case " $configdirs " in
2389     *" libiberty "*)
2390       # If we can build libiberty, we can also build libiberty-linker-plugin.
2391       configdirs="$configdirs libiberty-linker-plugin"
2392       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2393         --with-libiberty=../libiberty-linker-plugin";;
2394     *)
2395       AC_MSG_ERROR([libiberty missing]);;
2396   esac
2397 fi
2398
2399 # Sometimes we have special requirements for the host libiberty.
2400 extra_host_libiberty_configure_flags=
2401 extra_host_zlib_configure_flags=
2402 case " $configdirs " in
2403   *" lto-plugin "* | *" libcc1 "*)
2404     # When these are to be built as shared libraries, the same applies to
2405     # libiberty.
2406     extra_host_libiberty_configure_flags=--enable-shared
2407     ;;
2408   *" bfd "*)
2409     # When bfd is to be built as a shared library, the same applies to
2410     # zlib.
2411     if test "$enable_shared" = "yes"; then
2412       extra_host_zlib_configure_flags=--enable-host-shared
2413     fi
2414     ;;
2415 esac
2416 AC_SUBST(extra_host_libiberty_configure_flags)
2417 AC_SUBST(extra_host_zlib_configure_flags)
2418
2419 # Produce a warning message for the subdirs we can't configure.
2420 # This isn't especially interesting in the Cygnus tree, but in the individual
2421 # FSF releases, it's important to let people know when their machine isn't
2422 # supported by the one or two programs in a package.
2423
2424 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2425   # If $appdirs is non-empty, at least one of those directories must still
2426   # be configured, or we error out.  (E.g., if the gas release supports a
2427   # specified target in some subdirs but not the gas subdir, we shouldn't
2428   # pretend that all is well.)
2429   if test -n "$appdirs" ; then
2430     for dir in $appdirs ; do
2431       if test -r $dir/Makefile.in ; then
2432         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2433           appdirs=""
2434           break
2435         fi
2436         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2437           appdirs=""
2438           break
2439         fi
2440       fi
2441     done
2442     if test -n "$appdirs" ; then
2443       echo "*** This configuration is not supported by this package." 1>&2
2444       exit 1
2445     fi
2446   fi
2447   # Okay, some application will build, or we don't care to check.  Still
2448   # notify of subdirs not getting built.
2449   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2450   echo "    ${notsupp}" 1>&2
2451   echo "    (Any other directories should still work fine.)" 1>&2
2452 fi
2453
2454 case "$host" in
2455   *msdosdjgpp*)
2456     enable_gdbtk=no ;;
2457 esac
2458
2459 # To find our prefix, in gcc_cv_tool_prefix.
2460 ACX_TOOL_DIRS
2461
2462 copy_dirs=
2463
2464 AC_ARG_WITH([build-sysroot],
2465   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2466                   [use sysroot as the system root during the build])],
2467   [if test x"$withval" != x ; then
2468      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2469    fi],
2470   [SYSROOT_CFLAGS_FOR_TARGET=])
2471 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2472
2473 AC_ARG_WITH([debug-prefix-map],
2474   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2475                   [map A to B, C to D ... in debug information])],
2476   [if test x"$withval" != x; then
2477      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2478      for debug_map in $withval; do
2479        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2480      done
2481    fi],
2482   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2483 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2484
2485 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2486 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2487 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2488 # We want to ensure that TARGET libraries (which we know are built with
2489 # gcc) are built with "-O2 -g", so include those options when setting
2490 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2491 if test "x$CFLAGS_FOR_TARGET" = x; then
2492   if test "x${is_cross_compiler}" = xyes; then
2493     CFLAGS_FOR_TARGET="-g -O2"
2494   else
2495     CFLAGS_FOR_TARGET=$CFLAGS
2496     case " $CFLAGS " in
2497       *" -O2 "*) ;;
2498       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2499     esac
2500     case " $CFLAGS " in
2501       *" -g "* | *" -g3 "*) ;;
2502       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2503     esac
2504   fi
2505 fi
2506 AC_SUBST(CFLAGS_FOR_TARGET)
2507
2508 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2509   if test "x${is_cross_compiler}" = xyes; then
2510     CXXFLAGS_FOR_TARGET="-g -O2"
2511   else
2512     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2513     case " $CXXFLAGS " in
2514       *" -O2 "*) ;;
2515       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2516     esac
2517     case " $CXXFLAGS " in
2518       *" -g "* | *" -g3 "*) ;;
2519       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2520     esac
2521   fi
2522 fi
2523 AC_SUBST(CXXFLAGS_FOR_TARGET)
2524
2525 AC_SUBST(LDFLAGS_FOR_TARGET)
2526
2527 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2528 # the named directory are copied to $(tooldir)/sys-include.
2529 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2530   if test x${is_cross_compiler} = xno ; then
2531     echo 1>&2 '***' --with-headers is only supported when cross compiling
2532     exit 1
2533   fi
2534   if test x"${with_headers}" != xyes ; then
2535     x=${gcc_cv_tool_prefix}
2536     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2537   fi
2538 fi
2539
2540 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2541 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2542 # are permitted.
2543 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2544   if test x${is_cross_compiler} = xno ; then
2545     echo 1>&2 '***' --with-libs is only supported when cross compiling
2546     exit 1
2547   fi
2548   if test x"${with_libs}" != xyes ; then
2549     # Copy the libraries in reverse order, so that files in the first named
2550     # library override files in subsequent libraries.
2551     x=${gcc_cv_tool_prefix}
2552     for l in ${with_libs}; do
2553       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2554     done
2555   fi
2556 fi
2557
2558 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2559 #
2560 # This is done by determining whether or not the appropriate directory
2561 # is available, and by checking whether or not specific configurations
2562 # have requested that this magic not happen.
2563 #
2564 # The command line options always override the explicit settings in
2565 # configure.ac, and the settings in configure.ac override this magic.
2566 #
2567 # If the default for a toolchain is to use GNU as and ld, and you don't
2568 # want to do that, then you should use the --without-gnu-as and
2569 # --without-gnu-ld options for the configure script.  Similarly, if
2570 # the default is to use the included zlib and you don't want to do that,
2571 # you should use the --with-system-zlib option for the configure script.
2572
2573 if test x${use_gnu_as} = x &&
2574    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2575   with_gnu_as=yes
2576   extra_host_args="$extra_host_args --with-gnu-as"
2577 fi
2578
2579 if test x${use_gnu_ld} = x &&
2580    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2581   with_gnu_ld=yes
2582   extra_host_args="$extra_host_args --with-gnu-ld"
2583 fi
2584
2585 if test x${use_included_zlib} = x &&
2586    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2587   :
2588 else
2589   with_system_zlib=yes
2590   extra_host_args="$extra_host_args --with-system-zlib"
2591 fi
2592
2593 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2594 # can detect this case.
2595
2596 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2597   with_newlib=yes
2598   extra_host_args="$extra_host_args --with-newlib"
2599 fi
2600
2601 # Handle ${copy_dirs}
2602 set fnord ${copy_dirs}
2603 shift
2604 while test $# != 0 ; do
2605   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2606     :
2607   else
2608     echo Copying $1 to $2
2609
2610     # Use the install script to create the directory and all required
2611     # parent directories.
2612     if test -d $2 ; then
2613       :
2614     else
2615       echo >config.temp
2616       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2617     fi
2618
2619     # Copy the directory, assuming we have tar.
2620     # FIXME: Should we use B in the second tar?  Not all systems support it.
2621     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2622
2623     # It is the responsibility of the user to correctly adjust all
2624     # symlinks.  If somebody can figure out how to handle them correctly
2625     # here, feel free to add the code.
2626
2627     echo $1 > $2/COPIED
2628   fi
2629   shift; shift
2630 done
2631
2632 # Determine a target-dependent exec_prefix that the installed
2633 # gcc will search in.  Keep this list sorted by triplet, with
2634 # the *-*-osname triplets last.
2635 md_exec_prefix=
2636 case "${target}" in
2637   i[[34567]]86-pc-msdosdjgpp*)
2638     md_exec_prefix=/dev/env/DJDIR/bin
2639     ;;
2640   *-*-hpux* | \
2641   *-*-nto-qnx* | \
2642   *-*-solaris2*)
2643     md_exec_prefix=/usr/ccs/bin
2644     ;;
2645 esac
2646
2647 extra_arflags_for_target=
2648 extra_nmflags_for_target=
2649 extra_ranlibflags_for_target=
2650 target_makefile_frag=/dev/null
2651 case "${target}" in
2652   spu-*-*)
2653     target_makefile_frag="config/mt-spu"
2654     ;;
2655   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2656     target_makefile_frag="config/mt-sde"
2657     ;;
2658   mipsisa*-*-elfoabi*)
2659     target_makefile_frag="config/mt-mips-elfoabi"
2660     ;;
2661   mips*-*-*linux* | mips*-*-gnu*)
2662     target_makefile_frag="config/mt-mips-gnu"
2663     ;;
2664   nios2-*-elf*)
2665     target_makefile_frag="config/mt-nios2-elf"
2666     ;;
2667   *-*-linux-android*)
2668     target_makefile_frag="config/mt-android"
2669     ;;
2670   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2671     target_makefile_frag="config/mt-gnu"
2672     ;;
2673   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2674     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2675     # commands to handle both 32-bit and 64-bit objects.  These flags are
2676     # harmless if we're using GNU nm or ar.
2677     extra_arflags_for_target=" -X32_64"
2678     extra_nmflags_for_target=" -B -X32_64"
2679     ;;
2680 esac
2681
2682 alphaieee_frag=/dev/null
2683 case $target in
2684   alpha*-*-*)
2685     # This just makes sure to use the -mieee option to build target libs.
2686     # This should probably be set individually by each library.
2687     alphaieee_frag="config/mt-alphaieee"
2688     ;;
2689 esac
2690
2691 # If --enable-target-optspace always use -Os instead of -O2 to build
2692 # the target libraries, similarly if it is not specified, use -Os
2693 # on selected platforms.
2694 ospace_frag=/dev/null
2695 case "${enable_target_optspace}:${target}" in
2696   yes:*)
2697     ospace_frag="config/mt-ospace"
2698     ;;
2699   :d30v-*)
2700     ospace_frag="config/mt-d30v"
2701     ;;
2702   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2703     ospace_frag="config/mt-ospace"
2704     ;;
2705   no:* | :*)
2706     ;;
2707   *)
2708     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2709     ;;
2710 esac
2711
2712 # Some systems (e.g., one of the i386-aix systems the gas testers are
2713 # using) don't handle "\$" correctly, so don't use it here.
2714 tooldir='${exec_prefix}'/${target_noncanonical}
2715 build_tooldir=${tooldir}
2716
2717 # Create a .gdbinit file which runs the one in srcdir
2718 # and tells GDB to look there for source files.
2719
2720 if test -r ${srcdir}/.gdbinit ; then
2721   case ${srcdir} in
2722     .) ;;
2723     *) cat > ./.gdbinit <<EOF
2724 # ${NO_EDIT}
2725 dir ${srcdir}
2726 dir .
2727 source ${srcdir}/.gdbinit
2728 EOF
2729     ;;
2730   esac
2731 fi
2732
2733 # Make sure that the compiler is able to generate an executable.  If it
2734 # can't, we are probably in trouble.  We don't care whether we can run the
2735 # executable--we might be using a cross compiler--we only care whether it
2736 # can be created.  At this point the main configure script has set CC.
2737 we_are_ok=no
2738 echo "int main () { return 0; }" > conftest.c
2739 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2740 if test $? = 0 ; then
2741   if test -s conftest || test -s conftest.exe ; then
2742     we_are_ok=yes
2743   fi
2744 fi
2745 case $we_are_ok in
2746   no)
2747     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2748     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2749     rm -f conftest*
2750     exit 1
2751     ;;
2752 esac
2753 rm -f conftest*
2754
2755 # Decide which environment variable is used to find dynamic libraries.
2756 case "${host}" in
2757   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2758   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2759   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2760   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2761 esac
2762
2763 # On systems where the dynamic library environment variable is PATH,
2764 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2765 # built executables to PATH.
2766 if test "$RPATH_ENVVAR" = PATH; then
2767   GCC_SHLIB_SUBDIR=/shlib
2768 else
2769   GCC_SHLIB_SUBDIR=
2770 fi
2771
2772 # Adjust the toplevel makefile according to whether bootstrap was selected.
2773 case $enable_bootstrap in
2774   yes)
2775     bootstrap_suffix=bootstrap
2776     BUILD_CONFIG=bootstrap-debug
2777     ;;
2778   no)
2779     bootstrap_suffix=no-bootstrap
2780     BUILD_CONFIG=
2781     ;;
2782 esac
2783
2784 AC_MSG_CHECKING(for default BUILD_CONFIG)
2785
2786 AC_ARG_WITH([build-config],
2787   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2788                   [use config/NAME.mk build configuration])],
2789   [case $with_build_config in
2790    yes) with_build_config= ;;
2791    no) with_build_config= BUILD_CONFIG= ;;
2792    esac])
2793
2794 if test "x${with_build_config}" != x; then
2795   BUILD_CONFIG=$with_build_config
2796 else
2797   case $BUILD_CONFIG in
2798   bootstrap-debug)
2799     if echo "int f (void) { return 0; }" > conftest.c &&
2800        ${CC} -c conftest.c &&
2801        mv conftest.o conftest.o.g0 &&
2802        ${CC} -c -g conftest.c &&
2803        mv conftest.o conftest.o.g &&
2804        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2805       :
2806     else
2807       BUILD_CONFIG=
2808     fi
2809     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2810     ;;
2811   esac
2812 fi
2813 AC_MSG_RESULT($BUILD_CONFIG)
2814 AC_SUBST(BUILD_CONFIG)
2815
2816 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2817 AC_MSG_CHECKING([for --enable-vtable-verify])
2818 AC_ARG_ENABLE(vtable-verify,
2819 [AS_HELP_STRING([--enable-vtable-verify],
2820                 [Enable vtable verification feature])],
2821 [case "$enableval" in
2822  yes) enable_vtable_verify=yes ;;
2823  no)  enable_vtable_verify=no ;;
2824  *)   enable_vtable_verify=no;;
2825  esac],
2826 [enable_vtable_verify=no])
2827 AC_MSG_RESULT($enable_vtable_verify)
2828
2829 # Record target_configdirs and the configure arguments for target and
2830 # build configuration in Makefile.
2831 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2832 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2833 bootstrap_fixincludes=no
2834
2835 # If we are building libgomp, bootstrap it.
2836 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2837   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2838 fi
2839
2840 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2841 # or bootstrap-ubsan, bootstrap it.
2842 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2843   case "$BUILD_CONFIG" in
2844     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
2845       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2846       bootstrap_fixincludes=yes
2847       ;;
2848   esac
2849 fi
2850
2851 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2852 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2853    test "$enable_vtable_verify" != no; then
2854   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2855 fi
2856
2857 # If we are building libatomic and the list of enabled languages includes the
2858 # D frontend, bootstrap it.
2859 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
2860   case ,${enable_languages}, in
2861     *,d,*)
2862       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
2863       ;;
2864   esac
2865 fi
2866
2867 # Determine whether gdb needs tk/tcl or not.
2868 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2869 # and in that case we want gdb to be built without tk.  Ugh!
2870 # In fact I believe gdb is the *only* package directly dependent on tk,
2871 # so we should be able to put the 'maybe's in unconditionally and
2872 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2873 # 100% sure that that's safe though.
2874
2875 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2876 case "$enable_gdbtk" in
2877   no)
2878     GDB_TK="" ;;
2879   yes)
2880     GDB_TK="${gdb_tk}" ;;
2881   *)
2882     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2883     # distro.  Eventually someone will fix this and move Insight, nee
2884     # gdbtk to a separate directory.
2885     if test -d ${srcdir}/gdb/gdbtk ; then
2886       GDB_TK="${gdb_tk}"
2887     else
2888       GDB_TK=""
2889     fi
2890     ;;
2891 esac
2892 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2893 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2894
2895 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2896 # else does, only include them if one of these is built.  The Makefile
2897 # provides the ordering, so it's enough here to add to the list.
2898 case " ${configdirs} " in
2899   *\ gdb\ *)
2900     configdirs="${configdirs} gnulib gdbsupport"
2901     ;;
2902   *\ gdbserver\ *)
2903     configdirs="${configdirs} gnulib gdbsupport"
2904     ;;
2905   *\ sim\ *)
2906     configdirs="${configdirs} gnulib"
2907     ;;
2908 esac
2909
2910 # Strip out unwanted targets.
2911
2912 # While at that, we remove Makefiles if we were started for recursive
2913 # configuration, so that the top-level Makefile reconfigures them,
2914 # like we used to do when configure itself was recursive.
2915
2916 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2917 # but now we're fixing up the Makefile ourselves with the additional
2918 # commands passed to AC_CONFIG_FILES.  Use separate variables
2919 # extrasub-{build,host,target} not because there is any reason to split
2920 # the substitutions up that way, but only to remain below the limit of
2921 # 99 commands in a script, for HP-UX sed.
2922
2923 # Do not nest @if/@endif or @unless/@endunless pairs, because
2924 # configure will not warn you at all.
2925
2926 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2927   yes:yes:*\ gold\ *:*,c++,*) ;;
2928   yes:yes:*\ gold\ *:*)
2929     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2930     ;;
2931 esac
2932
2933 extrasub_build=
2934 for module in ${build_configdirs} ; do
2935   if test -z "${no_recursion}" \
2936      && test -f ${build_subdir}/${module}/Makefile; then
2937     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2938     rm -f ${build_subdir}/${module}/Makefile
2939   fi
2940   extrasub_build="$extrasub_build
2941 /^@if build-$module\$/d
2942 /^@endif build-$module\$/d
2943 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2944 /^@if build-$module-$bootstrap_suffix\$/d
2945 /^@endif build-$module-$bootstrap_suffix\$/d
2946 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2947 done
2948 extrasub_host=
2949 for module in ${configdirs} ; do
2950   if test -z "${no_recursion}"; then
2951     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2952       if test -f ${file}; then
2953         echo 1>&2 "*** removing ${file} to force reconfigure"
2954         rm -f ${file}
2955       fi
2956     done
2957   fi
2958   case ${module},${bootstrap_fixincludes} in
2959     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2960     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2961   esac
2962   extrasub_host="$extrasub_host
2963 /^@if $module\$/d
2964 /^@endif $module\$/d
2965 /^@unless $module\$/,/^@endunless $module\$/d
2966 /^@if $module-$host_bootstrap_suffix\$/d
2967 /^@endif $module-$host_bootstrap_suffix\$/d
2968 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2969 done
2970 extrasub_target=
2971 for module in ${target_configdirs} ; do
2972   if test -z "${no_recursion}" \
2973      && test -f ${target_subdir}/${module}/Makefile; then
2974     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2975     rm -f ${target_subdir}/${module}/Makefile
2976   fi
2977
2978   # We only bootstrap target libraries listed in bootstrap_target_libs.
2979   case $bootstrap_target_libs in
2980     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2981     *) target_bootstrap_suffix=no-bootstrap ;;
2982   esac
2983
2984   extrasub_target="$extrasub_target
2985 /^@if target-$module\$/d
2986 /^@endif target-$module\$/d
2987 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2988 /^@if target-$module-$target_bootstrap_suffix\$/d
2989 /^@endif target-$module-$target_bootstrap_suffix\$/d
2990 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2991 done
2992
2993 # Do the final fixup along with target modules.
2994 extrasub_target="$extrasub_target
2995 /^@if /,/^@endif /d
2996 /^@unless /d
2997 /^@endunless /d"
2998
2999 # Create the serialization dependencies.  This uses a temporary file.
3000
3001 AC_ARG_ENABLE([serial-configure],
3002 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3003                 [force sequential configuration of
3004                  sub-packages for the host, target or build
3005                  machine, or all sub-packages])])
3006
3007 case ${enable_serial_configure} in
3008   yes)
3009     enable_serial_build_configure=yes
3010     enable_serial_host_configure=yes
3011     enable_serial_target_configure=yes
3012     ;;
3013 esac
3014
3015 # These force 'configure's to be done one at a time, to avoid problems
3016 # with contention over a shared config.cache.
3017 rm -f serdep.tmp
3018 echo '# serdep.tmp' > serdep.tmp
3019 olditem=
3020 test "x${enable_serial_build_configure}" = xyes &&
3021 for item in ${build_configdirs} ; do
3022   case ${olditem} in
3023     "") ;;
3024     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3025   esac
3026   olditem=${item}
3027 done
3028 olditem=
3029 test "x${enable_serial_host_configure}" = xyes &&
3030 for item in ${configdirs} ; do
3031   case ${olditem} in
3032     "") ;;
3033     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3034   esac
3035   olditem=${item}
3036 done
3037 olditem=
3038 test "x${enable_serial_target_configure}" = xyes &&
3039 for item in ${target_configdirs} ; do
3040   case ${olditem} in
3041     "") ;;
3042     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3043   esac
3044   olditem=${item}
3045 done
3046 serialization_dependencies=serdep.tmp
3047 AC_SUBST_FILE(serialization_dependencies)
3048
3049 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3050 # target, nonopt, and variable assignments.  These are the ones we
3051 # might not want to pass down to subconfigures.  The exception being
3052 # --cache-file=/dev/null, which is used to turn off the use of cache
3053 # files altogether, and which should be passed on to subconfigures.
3054 # Also strip program-prefix, program-suffix, and program-transform-name,
3055 # so that we can pass down a consistent program-transform-name.
3056 baseargs=
3057 tbaseargs=
3058 keep_next=no
3059 skip_next=no
3060 eval "set -- $ac_configure_args"
3061 for ac_arg
3062 do
3063   if test X"$skip_next" = X"yes"; then
3064     skip_next=no
3065     continue
3066   fi
3067   if test X"$keep_next" = X"yes"; then
3068     case $ac_arg in
3069       *\'*)
3070         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3071     esac
3072     baseargs="$baseargs '$ac_arg'"
3073     tbaseargs="$tbaseargs '$ac_arg'"
3074     keep_next=no
3075     continue
3076   fi
3077
3078   # Handle separated arguments.  Based on the logic generated by
3079   # autoconf 2.59.
3080   case $ac_arg in
3081     *=* | --config-cache | -C | -disable-* | --disable-* \
3082       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3083       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3084       | -with-* | --with-* | -without-* | --without-* | --x)
3085       separate_arg=no
3086       ;;
3087     -*)
3088       separate_arg=yes
3089       ;;
3090     *)
3091       separate_arg=no
3092       ;;
3093   esac
3094
3095   skip_targ=no
3096   case $ac_arg in
3097 changequote(,)
3098   --with-* | --without-*)
3099     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3100
3101     case $libopt in
3102     *[-_]include)
3103       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3104       ;;
3105     *[-_]lib)
3106       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3107       ;;
3108     *)
3109       lib=$libopt
3110       ;;
3111     esac
3112 changequote([,])
3113
3114     case $lib in
3115     mpc | mpfr | gmp | isl)
3116       # If we're processing --with-$lib, --with-$lib-include or
3117       # --with-$lib-lib, for one of the libs above, and target is
3118       # different from host, don't pass the current argument to any
3119       # target library's configure.
3120       if test x$is_cross_compiler = xyes; then
3121         skip_targ=yes
3122       fi
3123       ;;
3124     esac
3125     ;;
3126   esac
3127
3128   case "$ac_arg" in
3129     --cache-file=/dev/null | \
3130     -cache-file=/dev/null )
3131       # Handled here to avoid the test to skip args below.
3132       baseargs="$baseargs '$ac_arg'"
3133       tbaseargs="$tbaseargs '$ac_arg'"
3134       # Assert: $separate_arg should always be no.
3135       keep_next=$separate_arg
3136       ;;
3137     --no*)
3138       continue
3139       ;;
3140     --c* | \
3141     --sr* | \
3142     --ho* | \
3143     --bu* | \
3144     --t* | \
3145     --program-* | \
3146     -cache_file* | \
3147     -srcdir* | \
3148     -host* | \
3149     -build* | \
3150     -target* | \
3151     -program-prefix* | \
3152     -program-suffix* | \
3153     -program-transform-name* )
3154       skip_next=$separate_arg
3155       continue
3156       ;;
3157     -*)
3158       # An option.  Add it.
3159       case $ac_arg in
3160         *\'*)
3161           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3162       esac
3163       baseargs="$baseargs '$ac_arg'"
3164       if test X"$skip_targ" = Xno; then
3165         tbaseargs="$tbaseargs '$ac_arg'"
3166       fi
3167       keep_next=$separate_arg
3168       ;;
3169     *)
3170       # Either a variable assignment, or a nonopt (triplet).  Don't
3171       # pass it down; let the Makefile handle this.
3172       continue
3173       ;;
3174   esac
3175 done
3176 # Remove the initial space we just introduced and, as these will be
3177 # expanded by make, quote '$'.
3178 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3179
3180 # Add in --program-transform-name, after --program-prefix and
3181 # --program-suffix have been applied to it.  Autoconf has already
3182 # doubled dollar signs and backslashes in program_transform_name; we want
3183 # the backslashes un-doubled, and then the entire thing wrapped in single
3184 # quotes, because this will be expanded first by make and then by the shell.
3185 # Also, because we want to override the logic in subdir configure scripts to
3186 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3187 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3188 ${program_transform_name}
3189 EOF_SED
3190 gcc_transform_name=`cat conftestsed.out`
3191 rm -f conftestsed.out
3192 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3193 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3194 if test "$silent" = yes; then
3195   baseargs="$baseargs --silent"
3196   tbaseargs="$tbaseargs --silent"
3197 fi
3198 baseargs="$baseargs --disable-option-checking"
3199 tbaseargs="$tbaseargs --disable-option-checking"
3200
3201 # Record and document user additions to sub configure arguments.
3202 AC_ARG_VAR([build_configargs],
3203            [additional configure arguments for build directories])
3204 AC_ARG_VAR([host_configargs],
3205            [additional configure arguments for host directories])
3206 AC_ARG_VAR([target_configargs],
3207            [additional configure arguments for target directories])
3208
3209 # For the build-side libraries, we just need to pretend we're native,
3210 # and not use the same cache file.  Multilibs are neither needed nor
3211 # desired.  We can't even use the same cache file for all build-side
3212 # libraries, as they're compiled differently; some with C, some with
3213 # C++ or with different feature-enabling options.
3214 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3215
3216 # For host modules, accept cache file option, or specification as blank.
3217 case "${cache_file}" in
3218 "") # empty
3219   cache_file_option="" ;;
3220 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3221   cache_file_option="--cache-file=${cache_file}" ;;
3222 *) # relative path
3223   cache_file_option="--cache-file=../${cache_file}" ;;
3224 esac
3225
3226 # Host dirs don't like to share a cache file either, horribly enough.
3227 # This seems to be due to autoconf 2.5x stupidity.
3228 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3229
3230 target_configargs="$target_configargs ${tbaseargs}"
3231
3232 # Passing a --with-cross-host argument lets the target libraries know
3233 # whether they are being built with a cross-compiler or being built
3234 # native.  However, it would be better to use other mechanisms to make the
3235 # sorts of decisions they want to make on this basis.  Please consider
3236 # this option to be deprecated.  FIXME.
3237 if test x${is_cross_compiler} = xyes ; then
3238   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3239 fi
3240
3241 # Special user-friendly check for native x86_64-linux build, if
3242 # multilib is not explicitly enabled.
3243 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3244   x86_64-*linux*:yes:$build:$build:)
3245     # Make sure we have a development environment that handles 32-bit
3246     dev64=no
3247     echo "int main () { return 0; }" > conftest.c
3248     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3249     if test $? = 0 ; then
3250       if test -s conftest || test -s conftest.exe ; then
3251         dev64=yes
3252       fi
3253     fi
3254     rm -f conftest*
3255     if test x${dev64} != xyes ; then
3256       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3257     fi
3258     ;;
3259 esac
3260
3261 # Default to --enable-multilib.
3262 if test x${enable_multilib} = x ; then
3263   target_configargs="--enable-multilib ${target_configargs}"
3264 fi
3265
3266 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3267 # changed from the earlier setting of with_newlib.
3268 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3269   target_configargs="--with-newlib ${target_configargs}"
3270 fi
3271
3272 # Different target subdirs use different values of certain variables
3273 # (notably CXX).  Worse, multilibs use *lots* of different values.
3274 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3275 # it doesn't automatically accept command-line overrides of them.
3276 # This means it's not safe for target subdirs to share a cache file,
3277 # which is disgusting, but there you have it.  Hopefully this can be
3278 # fixed in future.  It's still worthwhile to use a cache file for each
3279 # directory.  I think.
3280
3281 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3282 # We need to pass --target, as newer autoconf's requires consistency
3283 # for target_alias and gcc doesn't manage it consistently.
3284 target_configargs="--cache-file=./config.cache ${target_configargs}"
3285
3286 FLAGS_FOR_TARGET=
3287 case " $target_configdirs " in
3288  *" newlib "*)
3289   case " $target_configargs " in
3290   *" --with-newlib "*)
3291    case "$target" in
3292     *-cygwin*)
3293       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3294       ;;
3295    esac
3296
3297    # If we're not building GCC, don't discard standard headers.
3298    if test -d ${srcdir}/gcc; then
3299      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3300
3301      if test "${build}" != "${host}"; then
3302        # On Canadian crosses, CC_FOR_TARGET will have already been set
3303        # by `configure', so we won't have an opportunity to add -Bgcc/
3304        # to it.  This is right: we don't want to search that directory
3305        # for binaries, but we want the header files in there, so add
3306        # them explicitly.
3307        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3308
3309        # Someone might think of using the pre-installed headers on
3310        # Canadian crosses, in case the installed compiler is not fully
3311        # compatible with the compiler being built.  In this case, it
3312        # would be better to flag an error than risking having
3313        # incompatible object files being constructed.  We can't
3314        # guarantee that an error will be flagged, but let's hope the
3315        # compiler will do it, when presented with incompatible header
3316        # files.
3317      fi
3318    fi
3319
3320    case "${target}-${is_cross_compiler}" in
3321    i[[3456789]]86-*-linux*-no)
3322       # Here host == target, so we don't need to build gcc,
3323       # so we don't want to discard standard headers.
3324       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3325       ;;
3326    *)
3327       # If we're building newlib, use its generic headers last, but search
3328       # for any libc-related directories first (so make it the last -B
3329       # switch).
3330       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3331
3332       # If we're building libgloss, find the startup file, simulator library
3333       # and linker script.
3334       case " $target_configdirs " in
3335         *" libgloss "*)
3336         # Look for startup file, simulator library and maybe linker script.
3337         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3338         # Look for libnosys.a in case the target needs it.
3339         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3340         # Most targets have the linker script in the source directory.
3341         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3342         ;;
3343       esac
3344       ;;
3345    esac
3346    ;;
3347   esac
3348   ;;
3349 esac
3350
3351 case "$target" in
3352   x86_64-*mingw* | *-w64-mingw*)
3353   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3354   # however, use a symlink named 'mingw' in ${prefix} .
3355     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3356     ;;
3357   *-mingw*)
3358   # MinGW can't be handled as Cygwin above since it does not use newlib.
3359     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3360     ;;
3361 esac
3362
3363 # Allow the user to override the flags for
3364 # our build compiler if desired.
3365 if test x"${build}" = x"${host}" ; then
3366   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3367   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3368   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3369   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3370 fi
3371
3372 # On Canadian crosses, we'll be searching the right directories for
3373 # the previously-installed cross compiler, so don't bother to add
3374 # flags for directories within the install tree of the compiler
3375 # being built; programs in there won't even run.
3376 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3377   # Search for pre-installed headers if nothing else fits.
3378   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3379 fi
3380
3381 if test "x${use_gnu_ld}" = x &&
3382    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3383   # Arrange for us to find uninstalled linker scripts.
3384   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3385 fi
3386
3387 # Search for other target-specific linker scripts and such.
3388 case "${target}" in
3389   mep*)
3390     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3391     ;;
3392 esac
3393
3394 # Makefile fragments.
3395 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3396 do
3397   eval fragval=\$$frag
3398   if test $fragval != /dev/null; then
3399     eval $frag=${srcdir}/$fragval
3400   fi
3401 done
3402 AC_SUBST_FILE(host_makefile_frag)
3403 AC_SUBST_FILE(target_makefile_frag)
3404 AC_SUBST_FILE(alphaieee_frag)
3405 AC_SUBST_FILE(ospace_frag)
3406
3407 # Miscellanea: directories, flags, etc.
3408 AC_SUBST(RPATH_ENVVAR)
3409 AC_SUBST(GCC_SHLIB_SUBDIR)
3410 AC_SUBST(tooldir)
3411 AC_SUBST(build_tooldir)
3412 AC_SUBST(CONFIGURE_GDB_TK)
3413 AC_SUBST(GDB_TK)
3414 AC_SUBST(INSTALL_GDB_TK)
3415
3416 # Build module lists & subconfigure args.
3417 AC_SUBST(build_configargs)
3418 AC_SUBST(build_configdirs)
3419
3420 # Host module lists & subconfigure args.
3421 AC_SUBST(host_configargs)
3422 AC_SUBST(configdirs)
3423 AC_SUBST(target_configdirs)
3424
3425 # Target module lists & subconfigure args.
3426 AC_SUBST(target_configargs)
3427
3428
3429 # Build tools.
3430 AC_SUBST(AR_FOR_BUILD)
3431 AC_SUBST(AS_FOR_BUILD)
3432 AC_SUBST(CC_FOR_BUILD)
3433 AC_SUBST(CFLAGS_FOR_BUILD)
3434 AC_SUBST(CPP_FOR_BUILD)
3435 AC_SUBST(CPPFLAGS_FOR_BUILD)
3436 AC_SUBST(CXXFLAGS_FOR_BUILD)
3437 AC_SUBST(CXX_FOR_BUILD)
3438 AC_SUBST(DLLTOOL_FOR_BUILD)
3439 AC_SUBST(DSYMUTIL_FOR_BUILD)
3440 AC_SUBST(GFORTRAN_FOR_BUILD)
3441 AC_SUBST(GOC_FOR_BUILD)
3442 AC_SUBST(GDC_FOR_BUILD)
3443 AC_SUBST(LDFLAGS_FOR_BUILD)
3444 AC_SUBST(LD_FOR_BUILD)
3445 AC_SUBST(NM_FOR_BUILD)
3446 AC_SUBST(RANLIB_FOR_BUILD)
3447 AC_SUBST(WINDMC_FOR_BUILD)
3448 AC_SUBST(WINDRES_FOR_BUILD)
3449
3450 # Generate default definitions for YACC, M4, LEX and other programs that run
3451 # on the build machine.  These are used if the Makefile can't locate these
3452 # programs in objdir.
3453 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3454
3455 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3456 case " $build_configdirs " in
3457   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3458 esac
3459
3460 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3461 case " $build_configdirs " in
3462   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3463 esac
3464
3465 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3466 case " $build_configdirs " in
3467   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3468 esac
3469
3470 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3471 case " $build_configdirs " in
3472   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3473   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3474 esac
3475
3476 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3477 case " $build_configdirs " in
3478   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3479 esac
3480
3481 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3482 case " $build_configdirs " in
3483   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3484   *)
3485 changequote(,)
3486     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3487     # higher, else we use the "missing" dummy.
3488     if ${MAKEINFO} --version \
3489        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3490       :
3491     else
3492       MAKEINFO="$MISSING makeinfo"
3493     fi
3494     ;;
3495 changequote([,])
3496 esac
3497
3498 # FIXME: expect and dejagnu may become build tools?
3499
3500 AC_CHECK_PROGS(EXPECT, expect, expect)
3501 case " $configdirs " in
3502   *" expect "*)
3503     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3504     ;;
3505 esac
3506
3507 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3508 case " $configdirs " in
3509   *" dejagnu "*)
3510     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3511     ;;
3512 esac
3513
3514
3515 # Host tools.
3516 NCN_STRICT_CHECK_TOOLS(AR, ar)
3517 NCN_STRICT_CHECK_TOOLS(AS, as)
3518 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3519 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3520 NCN_STRICT_CHECK_TOOLS(LD, ld)
3521 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3522 NCN_STRICT_CHECK_TOOLS(NM, nm)
3523 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3524 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3525 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3526 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3527 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3528 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3529 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3530 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3531 AC_SUBST(CC)
3532 AC_SUBST(CXX)
3533 AC_SUBST(CFLAGS)
3534 AC_SUBST(CXXFLAGS)
3535 AC_SUBST(GDC)
3536 AC_SUBST(GDCFLAGS)
3537
3538 # Target tools.
3539 AC_ARG_WITH([build-time-tools],
3540   [AS_HELP_STRING([--with-build-time-tools=PATH],
3541                   [use given path to find target tools during the build])],
3542   [case x"$withval" in
3543      x/*) ;;
3544      *)
3545        with_build_time_tools=
3546        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3547        ;;
3548    esac],
3549   [with_build_time_tools=])
3550
3551 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3552 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3553 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3554 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3555 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3556 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3557
3558 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3559 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3560 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3561 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3562 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3563 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3564 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3565 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3566 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3567 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3568 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3569 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3570 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3571 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3572 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3573
3574 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3575
3576 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3577 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3578 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3579 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3580 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3581                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3582                 c++)
3583 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3584                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3585                 c++)
3586 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3587 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3588 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3589 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3590                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3591 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3592                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3593 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3594                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3595 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3596 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3597 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3598 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3599 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3600 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3601 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3602 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3603 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3604 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3605 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3606
3607 AC_SUBST(FLAGS_FOR_TARGET)
3608 AC_SUBST(RAW_CXX_FOR_TARGET)
3609
3610 # Certain tools may need extra flags.
3611 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3612 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3613 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3614
3615 # When building target libraries, except in a Canadian cross, we use
3616 # the same toolchain as the compiler we just built.
3617 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3618 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3619 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3620 if test $host = $build; then
3621   case " $configdirs " in
3622     *" gcc "*)
3623       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3624       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3625       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3626       ;;
3627   esac
3628 fi
3629
3630 AC_SUBST(COMPILER_AS_FOR_TARGET)
3631 AC_SUBST(COMPILER_LD_FOR_TARGET)
3632 AC_SUBST(COMPILER_NM_FOR_TARGET)
3633
3634 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3635 AC_ARG_ENABLE(maintainer-mode,
3636 [AS_HELP_STRING([--enable-maintainer-mode],
3637                 [enable make rules and dependencies not useful
3638                  (and sometimes confusing) to the casual installer])],
3639       USE_MAINTAINER_MODE=$enableval,
3640       USE_MAINTAINER_MODE=no)
3641 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3642 AC_SUBST(MAINTAINER_MODE_TRUE)
3643 AC_SUBST(MAINTAINER_MODE_FALSE)
3644 if test "$USE_MAINTAINER_MODE" = yes; then
3645   MAINTAINER_MODE_TRUE=
3646   MAINTAINER_MODE_FALSE='#'
3647 else
3648   MAINTAINER_MODE_TRUE='#'
3649   MAINTAINER_MODE_FALSE=
3650 fi
3651 MAINT=$MAINTAINER_MODE_TRUE
3652 AC_SUBST(MAINT)dnl
3653
3654 # ---------------------
3655 # GCC bootstrap support
3656 # ---------------------
3657
3658 # Stage specific cflags for build.
3659 stage1_cflags="-g"
3660 case $build in
3661   vax-*-*)
3662     case ${GCC} in
3663       yes) stage1_cflags="-g -Wa,-J" ;;
3664       *) stage1_cflags="-g -J" ;;
3665     esac ;;
3666 esac
3667
3668 AC_SUBST(stage1_cflags)
3669
3670 # Enable --enable-checking in stage1 of the compiler.
3671 AC_ARG_ENABLE(stage1-checking,
3672 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3673                 [choose additional checking for stage1 of the compiler])],
3674 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3675 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3676   # For --disable-checking or implicit --enable-checking=release, avoid
3677   # setting --enable-checking=gc in the default stage1 checking for LTO
3678   # bootstraps.  See PR62077.
3679   case $BUILD_CONFIG in
3680     *lto*)
3681       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3682     *)
3683       stage1_checking=--enable-checking=yes,types;;
3684   esac
3685   if test "x$enable_checking" = x && \
3686      test -d ${srcdir}/gcc && \
3687      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3688     stage1_checking=--enable-checking=yes,types,extra
3689   fi
3690 else
3691   stage1_checking=--enable-checking=$enable_checking,types
3692 fi])
3693 AC_SUBST(stage1_checking)
3694
3695 # Enable -Werror in bootstrap stage2 and later.
3696 AC_ARG_ENABLE(werror,
3697 [AS_HELP_STRING([--enable-werror],
3698                 [enable -Werror in bootstrap stage2 and later])],
3699 [
3700 case ${enable_werror} in
3701   yes) stage2_werror_flag="--enable-werror-always" ;;
3702   *) stage2_werror_flag="" ;;
3703 esac
3704 ],
3705 [
3706 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3707   case $BUILD_CONFIG in
3708   bootstrap-debug)
3709       stage2_werror_flag="--enable-werror-always" ;;
3710   "")
3711       stage2_werror_flag="--enable-werror-always" ;;
3712   esac
3713 fi
3714 ])
3715
3716 AC_SUBST(stage2_werror_flag)
3717
3718 # Specify what files to not compare during bootstrap.
3719
3720 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3721 case "$target" in
3722   hppa*64*-*-hpux*) ;;
3723   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3724   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3725 esac
3726 AC_SUBST(compare_exclusions)
3727
3728 AC_CONFIG_FILES([Makefile],
3729   [sed "$extrasub_build" Makefile |
3730    sed "$extrasub_host" |
3731    sed "$extrasub_target" > mf$$
3732    mv -f mf$$ Makefile],
3733   [extrasub_build="$extrasub_build"
3734    extrasub_host="$extrasub_host"
3735    extrasub_target="$extrasub_target"])
3736 AC_OUTPUT