configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools c++tools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libatomic \
 155                 target-libitm \
 156                 target-libstdc++-v3 \
 157                 target-libsanitizer \
 158                 target-libvtv \
 159                 target-libssp \
 160                 target-libquadmath \
 161                 target-libgfortran \
 162                 target-libffi \
 163                 target-libobjc \
 164                 target-libada \
 165                 target-libgo \
 166                 target-libphobos \
 167                 target-zlib"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # some tools are so dependent upon X11 that if we're not building with X,
 251 # it's not even worth trying to configure, much less build, that tool.
 252
 253 case ${with_x} in
 254   yes | "") ;; # the default value for this tree is that X11 is available
 255   no)
 256     skipdirs="${skipdirs} tk itcl libgui"
 257     # We won't be able to build gdbtk without X.
 258     enable_gdbtk=no
 259     ;;
 260   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 261 esac
 262
 263 # Some are only suitable for cross toolchains.
 264 # Remove these if host=target.
 265 cross_only="target-libgloss target-newlib target-opcodes"
 266
 267 case $is_cross_compiler in
 268   no) skipdirs="${skipdirs} ${cross_only}" ;;
 269 esac
 270
 271 # If both --with-headers and --with-libs are specified, default to
 272 # --without-newlib.
 273 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 274    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 275   if test x"${with_newlib}" = x ; then
 276     with_newlib=no
 277   fi
 278 fi
 279
 280 # Recognize --with-newlib/--without-newlib.
 281 case ${with_newlib} in
 282   no) skipdirs="${skipdirs} target-newlib" ;;
 283   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 284 esac
 285
 286 AC_ARG_ENABLE(as-accelerator-for,
 287 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 288                 [build as offload target compiler.
 289                 Specify offload host triple by ARG])])
 290
 291 AC_ARG_ENABLE(offload-targets,
 292 [AS_HELP_STRING([--enable-offload-targets=LIST],
 293                 [enable offloading to devices from comma-separated LIST of
 294                 TARGET[=DIR]. Use optional path to find offload target compiler
 295                 during the build])],
 296 [
 297   if test x"$enable_offload_targets" = x; then
 298     AC_MSG_ERROR([no offload targets specified])
 299   fi
 300 ], [enable_offload_targets=])
 301
 302 AC_ARG_ENABLE(offload-defaulted,
 303 [AS_HELP_STRING([--enable-offload-defaulted]
 304                 [If enabled, configured but not installed offload compilers and
 305                 libgomp plugins are silently ignored.  Useful for distribution
 306                 compilers where those are in separate optional packages.])],
 307 [enable_offload_defaulted=$enableval],
 308 [enable_offload_defaulted=])
 309
 310 # Handle --enable-gold, --enable-ld.
 311 # --disable-gold [--enable-ld]
 312 #     Build only ld.  Default option.
 313 # --enable-gold [--enable-ld]
 314 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 315 #     as "ld.bfd" and "ld".
 316 # --enable-gold=default [--enable-ld]
 317 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 318 #     install ld as "ld.bfd".
 319 # --enable-gold[=default] --disable-ld
 320 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 321 # --enable-gold --enable-ld=default
 322 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 323 #     and ld.bfd).
 324 #     In other words, ld is default
 325 # --enable-gold=default --enable-ld=default
 326 #     Error.
 327
 328 default_ld=
 329 AC_ARG_ENABLE(gold,
 330 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 331                 [build gold @<:@ARG={default,yes,no}@:>@])],
 332 ENABLE_GOLD=$enableval,
 333 ENABLE_GOLD=no)
 334 case "${ENABLE_GOLD}" in
 335   yes|default)
 336     # Check for ELF target.
 337     is_elf=no
 338     case "${target}" in
 339       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 340       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 341       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 342       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 343         case "${target}" in
 344           *-*-linux*aout* | *-*-linux*oldld*)
 345             ;;
 346           *)
 347             is_elf=yes
 348             ;;
 349         esac
 350     esac
 351
 352     if test "$is_elf" = "yes"; then
 353       # Check for target supported by gold.
 354       case "${target}" in
 355         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 356         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 357           configdirs="$configdirs gold"
 358           if test x${ENABLE_GOLD} = xdefault; then
 359             default_ld=gold
 360           fi
 361           ENABLE_GOLD=yes
 362           ;;
 363       esac
 364     fi
 365     ;;
 366   no)
 367     ;;
 368   *)
 369     AC_MSG_ERROR([invalid --enable-gold argument])
 370     ;;
 371 esac
 372
 373 AC_ARG_ENABLE(ld,
 374 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 375                 [build ld @<:@ARG={default,yes,no}@:>@])],
 376 ENABLE_LD=$enableval,
 377 ENABLE_LD=yes)
 378
 379 case "${ENABLE_LD}" in
 380   default)
 381     if test x${default_ld} != x; then
 382       AC_MSG_ERROR([either gold or ld can be the default ld])
 383     fi
 384     ;;
 385   yes)
 386     ;;
 387   no)
 388     if test x${ENABLE_GOLD} != xyes; then
 389       AC_MSG_WARN([neither ld nor gold are enabled])
 390     fi
 391     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 392     ;;
 393   *)
 394     AC_MSG_ERROR([invalid --enable-ld argument])
 395     ;;
 396 esac
 397
 398 # PR gas/19109
 399 # Decide the default method for compressing debug sections.
 400 # Provide a configure time option to override our default.
 401 AC_ARG_ENABLE(compressed_debug_sections,
 402 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 403                 [Enable compressed debug sections for gas, gold or ld by
 404                  default])],
 405 [
 406   if test x"$enable_compressed_debug_sections" = xyes; then
 407     AC_MSG_ERROR([no program with compressed debug sections specified])
 408   fi
 409 ], [enable_compressed_debug_sections=])
 410
 411 # Configure extra directories which are host specific
 412
 413 case "${host}" in
 414   *-cygwin*)
 415     configdirs="$configdirs libtermcap" ;;
 416 esac
 417
 418 # A target can indicate whether a language isn't supported for some reason.
 419 # Only spaces may be used in this macro; not newlines or tabs.
 420 unsupported_languages=
 421
 422 # Remove more programs from consideration, based on the host or
 423 # target this usually means that a port of the program doesn't
 424 # exist yet.
 425
 426 case "${host}" in
 427   i[[3456789]]86-*-msdosdjgpp*)
 428     noconfigdirs="$noconfigdirs tcl tk itcl"
 429     ;;
 430 esac
 431
 432
 433 AC_ARG_ENABLE(libquadmath,
 434 AS_HELP_STRING([--disable-libquadmath],
 435   [do not build libquadmath directory]),
 436 ENABLE_LIBQUADMATH=$enableval,
 437 ENABLE_LIBQUADMATH=yes)
 438 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 439   noconfigdirs="$noconfigdirs target-libquadmath"
 440 fi
 441
 442
 443 AC_ARG_ENABLE(libquadmath-support,
 444 AS_HELP_STRING([--disable-libquadmath-support],
 445   [disable libquadmath support for Fortran]),
 446 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 447 ENABLE_LIBQUADMATH_SUPPORT=yes)
 448 enable_libquadmath_support=
 449 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 450   enable_libquadmath_support=no
 451 fi
 452
 453
 454 AC_ARG_ENABLE(libada,
 455 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 456 ENABLE_LIBADA=$enableval,
 457 ENABLE_LIBADA=yes)
 458 if test "${ENABLE_LIBADA}" != "yes" ; then
 459   noconfigdirs="$noconfigdirs gnattools"
 460 fi
 461
 462 AC_ARG_ENABLE(libssp,
 463 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 464 ENABLE_LIBSSP=$enableval,
 465 ENABLE_LIBSSP=yes)
 466
 467 AC_ARG_ENABLE(libstdcxx,
 468 AS_HELP_STRING([--disable-libstdcxx],
 469   [do not build libstdc++-v3 directory]),
 470 ENABLE_LIBSTDCXX=$enableval,
 471 ENABLE_LIBSTDCXX=default)
 472 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 473   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 474 fi]
 475
 476 # If this is accelerator compiler and its target is intelmic we enable
 477 # target liboffloadmic by default.  If this is compiler with offloading
 478 # for intelmic we enable host liboffloadmic by default.  Otherwise
 479 # liboffloadmic is disabled by default.
 480 AC_ARG_ENABLE([liboffloadmic],
 481 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 482                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 483 [case "$enableval" in
 484   no | host | target)
 485     enable_liboffloadmic=$enableval ;;
 486   *)
 487     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 488 esac],
 489 [if test x"$enable_as_accelerator_for" != x; then
 490   case "${target}" in
 491     *-intelmic-* | *-intelmicemul-*)
 492       enable_liboffloadmic=target
 493       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 494       ;;
 495     *)
 496       enable_liboffloadmic=no
 497       ;;
 498   esac
 499 else
 500   case "${enable_offload_targets}" in
 501     *-intelmic-* | *-intelmicemul-*)
 502       enable_liboffloadmic=host
 503       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 504       ;;
 505     *)
 506       enable_liboffloadmic=no
 507       ;;
 508     esac
 509 fi])
 510 AC_SUBST(extra_liboffloadmic_configure_flags)
 511
 512 # Enable libgomp by default on hosted POSIX systems, and a few others.
 513 if test x$enable_libgomp = x ; then
 514     case "${target}" in
 515     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 516         ;;
 517     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 518         ;;
 519     *-*-solaris2* | *-*-hpux11*)
 520         ;;
 521     *-*-darwin* | *-*-aix*)
 522         ;;
 523     nvptx*-*-* | amdgcn*-*-*)
 524         ;;
 525     *)
 526         noconfigdirs="$noconfigdirs target-libgomp"
 527         ;;
 528     esac
 529 fi
 530
 531 # Disable libatomic on unsupported systems.
 532 if test -d ${srcdir}/libatomic; then
 533     if test x$enable_libatomic = x; then
 534         AC_MSG_CHECKING([for libatomic support])
 535         if (srcdir=${srcdir}/libatomic; \
 536                 . ${srcdir}/configure.tgt; \
 537                 test -n "$UNSUPPORTED")
 538         then
 539             AC_MSG_RESULT([no])
 540             noconfigdirs="$noconfigdirs target-libatomic"
 541         else
 542             AC_MSG_RESULT([yes])
 543         fi
 544     fi
 545 fi
 546
 547 # Disable liboffloadmic on unsupported systems.
 548 if test -d ${srcdir}/liboffloadmic; then
 549     if test x$enable_liboffloadmic != xno; then
 550         AC_MSG_CHECKING([for liboffloadmic support])
 551         if (srcdir=${srcdir}/liboffloadmic; \
 552                 . ${srcdir}/configure.tgt; \
 553                 test -n "$UNSUPPORTED")
 554         then
 555             AC_MSG_RESULT([no])
 556             noconfigdirs="$noconfigdirs target-liboffloadmic"
 557         else
 558             AC_MSG_RESULT([yes])
 559         fi
 560     fi
 561 fi
 562
 563 # Disable libitm on unsupported systems.
 564 if test -d ${srcdir}/libitm; then
 565     if test x$enable_libitm = x; then
 566         AC_MSG_CHECKING([for libitm support])
 567         if (srcdir=${srcdir}/libitm; \
 568                 . ${srcdir}/configure.tgt; \
 569                 test -n "$UNSUPPORTED")
 570         then
 571             AC_MSG_RESULT([no])
 572             noconfigdirs="$noconfigdirs target-libitm"
 573         else
 574             AC_MSG_RESULT([yes])
 575         fi
 576     fi
 577 fi
 578
 579 # Disable libsanitizer on unsupported systems.
 580 if test -d ${srcdir}/libsanitizer; then
 581     if test x$enable_libsanitizer = x; then
 582         AC_MSG_CHECKING([for libsanitizer support])
 583         if (srcdir=${srcdir}/libsanitizer; \
 584                 . ${srcdir}/configure.tgt; \
 585                 test -n "$UNSUPPORTED")
 586         then
 587             AC_MSG_RESULT([no])
 588             noconfigdirs="$noconfigdirs target-libsanitizer"
 589         else
 590             AC_MSG_RESULT([yes])
 591         fi
 592     fi
 593 fi
 594
 595 # Disable libvtv on unsupported systems.
 596 if test -d ${srcdir}/libvtv; then
 597     if test x$enable_libvtv = x; then
 598         AC_MSG_CHECKING([for libvtv support])
 599         if (srcdir=${srcdir}/libvtv; \
 600                 . ${srcdir}/configure.tgt; \
 601                 test "$VTV_SUPPORTED" != "yes")
 602         then
 603             AC_MSG_RESULT([no])
 604             noconfigdirs="$noconfigdirs target-libvtv"
 605         else
 606             AC_MSG_RESULT([yes])
 607         fi
 608     fi
 609 fi
 610
 611 # Disable libquadmath for some systems.
 612 case "${target}" in
 613   avr-*-*)
 614     noconfigdirs="$noconfigdirs target-libquadmath"
 615     ;;
 616   # libquadmath is unused on AIX and libquadmath build process use of
 617   # LD_LIBRARY_PATH can break AIX bootstrap.
 618   powerpc-*-aix* | rs6000-*-aix*)
 619     noconfigdirs="$noconfigdirs target-libquadmath"
 620     ;;
 621 esac
 622
 623 # Disable libssp for some systems.
 624 case "${target}" in
 625   avr-*-*)
 626     # No hosted I/O support.
 627     noconfigdirs="$noconfigdirs target-libssp"
 628     ;;
 629   bpf-*-*)
 630     noconfigdirs="$noconfigdirs target-libssp"
 631     ;;
 632   powerpc-*-aix* | rs6000-*-aix*)
 633     noconfigdirs="$noconfigdirs target-libssp"
 634     ;;
 635   pru-*-*)
 636     # No hosted I/O support.
 637     noconfigdirs="$noconfigdirs target-libssp"
 638     ;;
 639   rl78-*-*)
 640     # libssp uses a misaligned load to trigger a fault, but the RL78
 641     # doesn't fault for those - instead, it gives a build-time error
 642     # for explicit misaligned loads.
 643     noconfigdirs="$noconfigdirs target-libssp"
 644     ;;
 645   visium-*-*)
 646     # No hosted I/O support.
 647     noconfigdirs="$noconfigdirs target-libssp"
 648     ;;
 649 esac
 650
 651 # Disable libstdc++-v3 for some systems.
 652 # Allow user to override this if they pass --enable-libstdc++-v3
 653 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 654   case "${target}" in
 655     *-*-vxworks*)
 656       # VxWorks uses the Dinkumware C++ library.
 657       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 658       ;;
 659     amdgcn*-*-*)
 660       # Not ported/fails to build when using newlib.
 661       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 662       ;;
 663     arm*-wince-pe*)
 664       # the C++ libraries don't build on top of CE's C libraries
 665       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 666       ;;
 667     avr-*-*)
 668       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 669       ;;
 670     bpf-*-*)
 671       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 672       ;;
 673     ft32-*-*)
 674       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 675       ;;
 676   esac
 677 fi
 678
 679 # Disable C++ on systems where it is known to not work.
 680 # For testing, you can override this with --enable-languages=c++.
 681 case ,${enable_languages}, in
 682   *,c++,*)
 683     ;;
 684   *)
 685       case "${target}" in
 686         bpf-*-*)
 687           unsupported_languages="$unsupported_languages c++"
 688           ;;
 689       esac
 690       ;;
 691 esac
 692
 693 # Disable Objc on systems where it is known to not work.
 694 # For testing, you can override this with --enable-languages=objc.
 695 case ,${enable_languages}, in
 696   *,objc,*)
 697     ;;
 698   *)
 699       case "${target}" in
 700         bpf-*-*)
 701           unsupported_languages="$unsupported_languages objc"
 702           ;;
 703       esac
 704       ;;
 705 esac
 706
 707 # Disable D on systems where it is known to not work.
 708 # For testing, you can override this with --enable-languages=d.
 709 case ,${enable_languages}, in
 710   *,d,*)
 711     ;;
 712   *)
 713     case "${target}" in
 714       bpf-*-*)
 715         unsupported_languages="$unsupported_languages d"
 716         ;;
 717     esac
 718     ;;
 719 esac
 720
 721 # Disable libphobos on unsupported systems.
 722 # For testing, you can override this with --enable-libphobos.
 723 if test -d ${srcdir}/libphobos; then
 724     if test x$enable_libphobos = x; then
 725         AC_MSG_CHECKING([for libphobos support])
 726         if (srcdir=${srcdir}/libphobos; \
 727                 . ${srcdir}/configure.tgt; \
 728                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 729         then
 730             AC_MSG_RESULT([no])
 731             noconfigdirs="$noconfigdirs target-libphobos"
 732         else
 733             AC_MSG_RESULT([yes])
 734         fi
 735     fi
 736 fi
 737
 738 # Disable Fortran for some systems.
 739 case "${target}" in
 740   mmix-*-*)
 741     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 742     unsupported_languages="$unsupported_languages fortran"
 743     ;;
 744   bpf-*-*)
 745     unsupported_languages="$unsupported_languages fortran"
 746     ;;
 747 esac
 748
 749 # Disable libffi for some systems.
 750 case "${target}" in
 751   powerpc-*-darwin*)
 752     ;;
 753   i[[3456789]]86-*-darwin*)
 754     ;;
 755   x86_64-*-darwin[[912]]*)
 756     ;;
 757   *-*-darwin*)
 758     noconfigdirs="$noconfigdirs target-libffi"
 759     ;;
 760   *-*-netware*)
 761     noconfigdirs="$noconfigdirs target-libffi"
 762     ;;
 763   *-*-phoenix*)
 764     noconfigdirs="$noconfigdirs target-libffi"
 765     ;;
 766   *-*-rtems*)
 767     noconfigdirs="$noconfigdirs target-libffi"
 768     ;;
 769   *-*-tpf*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772   *-*-uclinux*)
 773     noconfigdirs="$noconfigdirs target-libffi"
 774     ;;
 775   *-*-vxworks*)
 776     noconfigdirs="$noconfigdirs target-libffi"
 777     ;;
 778   aarch64*-*-freebsd*)
 779     noconfigdirs="$noconfigdirs target-libffi"
 780     ;;
 781   alpha*-*-*vms*)
 782     noconfigdirs="$noconfigdirs target-libffi"
 783     ;;
 784   arm*-*-freebsd*)
 785     noconfigdirs="$noconfigdirs target-libffi"
 786     ;;
 787   arm-wince-pe)
 788     noconfigdirs="$noconfigdirs target-libffi"
 789     ;;
 790   arm*-*-symbianelf*)
 791     noconfigdirs="$noconfigdirs target-libffi"
 792     ;;
 793   bpf-*-*)
 794     noconfigdirs="$noconfigdirs target-libffi"
 795     ;;
 796   cris-*-* | crisv32-*-*)
 797     case "${target}" in
 798       *-*-linux*)
 799         ;;
 800       *) # See PR46792 regarding target-libffi.
 801         noconfigdirs="$noconfigdirs target-libffi";;
 802     esac
 803     ;;
 804   hppa*64*-*-hpux*)
 805     noconfigdirs="$noconfigdirs target-libffi"
 806     ;;
 807   hppa*-hp-hpux11*)
 808     ;;
 809   hppa*-*-hpux*)
 810     noconfigdirs="$noconfigdirs target-libffi"
 811     ;;
 812   ia64*-*-*vms*)
 813     noconfigdirs="$noconfigdirs target-libffi"
 814     ;;
 815   i[[3456789]]86-w64-mingw*)
 816     noconfigdirs="$noconfigdirs target-libffi"
 817     ;;
 818   i[[3456789]]86-*-mingw*)
 819     noconfigdirs="$noconfigdirs target-libffi"
 820     ;;
 821   x86_64-*-mingw*)
 822     noconfigdirs="$noconfigdirs target-libffi"
 823     ;;
 824   mmix-*-*)
 825     noconfigdirs="$noconfigdirs target-libffi"
 826     ;;
 827   powerpc-*-aix*)
 828     ;;
 829   rs6000-*-aix*)
 830     ;;
 831   ft32-*-*)
 832     noconfigdirs="$noconfigdirs target-libffi"
 833     ;;
 834   *-*-lynxos*)
 835     noconfigdirs="$noconfigdirs target-libffi"
 836     ;;
 837 esac
 838
 839 # Disable the go frontend on systems where it is known to not work. Please keep
 840 # this in sync with contrib/config-list.mk.
 841 case "${target}" in
 842 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 843     unsupported_languages="$unsupported_languages go"
 844     ;;
 845 esac
 846
 847 # Only allow gdbserver on some systems.
 848 if test -d ${srcdir}/gdbserver; then
 849     if test x$enable_gdbserver = x; then
 850         AC_MSG_CHECKING([for gdbserver support])
 851         if (srcdir=${srcdir}/gdbserver; \
 852                 . ${srcdir}/configure.srv; \
 853                 test -n "$UNSUPPORTED")
 854         then
 855             AC_MSG_RESULT([no])
 856             noconfigdirs="$noconfigdirs gdbserver"
 857         else
 858             AC_MSG_RESULT([yes])
 859         fi
 860     fi
 861 fi
 862
 863 # Disable libgo for some systems where it is known to not work.
 864 # For testing, you can easily override this with --enable-libgo.
 865 if test x$enable_libgo = x; then
 866     case "${target}" in
 867     *-*-darwin*)
 868         # PR 46986
 869         noconfigdirs="$noconfigdirs target-libgo"
 870         ;;
 871     *-*-cygwin* | *-*-mingw*)
 872         noconfigdirs="$noconfigdirs target-libgo"
 873         ;;
 874     bpf-*-*)
 875         noconfigdirs="$noconfigdirs target-libgo"
 876         ;;
 877     esac
 878 fi
 879
 880 # Default libgloss CPU subdirectory.
 881 libgloss_dir="$target_cpu"
 882
 883 case "${target}" in
 884   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 885     libgloss_dir=wince
 886     ;;
 887   aarch64*-*-* )
 888     libgloss_dir=aarch64
 889     ;;
 890   arm*-*-*)
 891     libgloss_dir=arm
 892     ;;
 893   cris-*-* | crisv32-*-*)
 894     libgloss_dir=cris
 895     ;;
 896   hppa*-*-*)
 897     libgloss_dir=pa
 898     ;;
 899   i[[3456789]]86-*-*)
 900     libgloss_dir=i386
 901     ;;
 902   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 903     libgloss_dir=m68hc11
 904     ;;
 905   m68*-*-* | fido-*-*)
 906     libgloss_dir=m68k
 907     ;;
 908   mips*-*-*)
 909     libgloss_dir=mips
 910     ;;
 911   powerpc*-*-*)
 912     libgloss_dir=rs6000
 913     ;;
 914   pru-*-*)
 915     libgloss_dir=pru
 916     ;;
 917   sparc*-*-*)
 918     libgloss_dir=sparc
 919     ;;
 920 esac
 921
 922 # Disable newlib and libgloss for various target OSes.
 923 case "${target}" in
 924   alpha*-dec-osf*)
 925     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 926     ;;
 927   i[[3456789]]86-*-linux*)
 928     # This section makes it possible to build newlib natively on linux.
 929     # If we are using a cross compiler then don't configure newlib.
 930     if test x${is_cross_compiler} != xno ; then
 931       noconfigdirs="$noconfigdirs target-newlib"
 932     fi
 933     noconfigdirs="$noconfigdirs target-libgloss"
 934     # If we are not using a cross compiler, do configure newlib.
 935     # Note however, that newlib will only be configured in this situation
 936     # if the --with-newlib option has been given, because otherwise
 937     # 'target-newlib' will appear in skipdirs.
 938     ;;
 939   i[[3456789]]86-*-rdos*)
 940     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 941     ;;
 942   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 943     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 944     ;;
 945   sparc-*-sunos4*)
 946     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 947     ;;
 948   bpf-*-*)
 949     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 950     ;;
 951   *-*-aix*)
 952     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 953     ;;
 954   *-*-beos*)
 955     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 956     ;;
 957   *-*-chorusos)
 958     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 959     ;;
 960   *-*-dragonfly*)
 961     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 962     ;;
 963   *-*-freebsd*)
 964     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 965     ;;
 966   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 967     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 968     ;;
 969   *-*-lynxos*)
 970     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 971     ;;
 972   *-*-mingw*)
 973     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 974     ;;
 975   *-*-netbsd*)
 976     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 977     ;;
 978   *-*-netware*)
 979     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 980     ;;
 981   *-*-tpf*)
 982     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 983     ;;
 984   *-*-uclinux*)
 985     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 986     ;;
 987   *-*-vxworks*)
 988     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 989     ;;
 990 esac
 991
 992 case "${target}" in
 993   *-*-chorusos)
 994     ;;
 995   aarch64-*-darwin*)
 996     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 997     noconfigdirs="$noconfigdirs sim target-rda"
 998     ;;
 999   amdgcn*-*-*)
1000     ;;
1001   arm-*-darwin*)
1002     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1003     noconfigdirs="$noconfigdirs sim target-rda"
1004     ;;
1005   powerpc-*-darwin*)
1006     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1007     noconfigdirs="$noconfigdirs sim target-rda"
1008     ;;
1009   i[[3456789]]86-*-darwin*)
1010     noconfigdirs="$noconfigdirs ld gprof"
1011     noconfigdirs="$noconfigdirs sim target-rda"
1012     ;;
1013   x86_64-*-darwin[[912]]*)
1014     noconfigdirs="$noconfigdirs ld gas gprof"
1015     noconfigdirs="$noconfigdirs sim target-rda"
1016     ;;
1017   *-*-darwin*)
1018     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1019     noconfigdirs="$noconfigdirs sim target-rda"
1020     ;;
1021   *-*-dragonfly*)
1022     ;;
1023   *-*-freebsd*)
1024     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
1025         && ! test -d ${srcdir}/gmp \
1026         && test -f /usr/local/include/gmp.h; then
1027       with_gmp=/usr/local
1028     fi
1029     ;;
1030   *-*-kaos*)
1031     # Remove unsupported stuff on all kaOS configurations.
1032     noconfigdirs="$noconfigdirs target-libgloss"
1033     ;;
1034   *-*-netbsd*)
1035     ;;
1036   *-*-netware*)
1037     ;;
1038   *-*-phoenix*)
1039     noconfigdirs="$noconfigdirs target-libgloss"
1040     ;;
1041   *-*-rtems*)
1042     noconfigdirs="$noconfigdirs target-libgloss"
1043     ;;
1044     # The tpf target doesn't support gdb yet.
1045   *-*-tpf*)
1046     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1047     ;;
1048   *-*-uclinux*)
1049     noconfigdirs="$noconfigdirs target-rda"
1050     ;;
1051   *-*-vxworks*)
1052     ;;
1053   alpha*-dec-osf*)
1054     # ld works, but does not support shared libraries.
1055     # gas doesn't generate exception information.
1056     noconfigdirs="$noconfigdirs gas ld"
1057     ;;
1058   alpha*-*-*vms*)
1059     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1060     ;;
1061   alpha*-*-*)
1062     # newlib is not 64 bit ready
1063     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1064     ;;
1065   bpf-*-*)
1066     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1067     ;;
1068   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1069     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1070     ;;
1071   arc*-*-*)
1072     noconfigdirs="$noconfigdirs sim"
1073     ;;
1074   arm-*-pe*)
1075     noconfigdirs="$noconfigdirs target-libgloss"
1076     ;;
1077   arm-*-riscix*)
1078     noconfigdirs="$noconfigdirs ld target-libgloss"
1079     ;;
1080   avr-*-*)
1081     if test x${with_avrlibc} != xno; then
1082       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1083     fi
1084     ;;
1085   c4x-*-* | tic4x-*-*)
1086     noconfigdirs="$noconfigdirs target-libgloss"
1087     ;;
1088   tic54x-*-*)
1089     noconfigdirs="$noconfigdirs target-libgloss gdb"
1090     ;;
1091   d10v-*-*)
1092     noconfigdirs="$noconfigdirs target-libgloss"
1093     ;;
1094   d30v-*-*)
1095     noconfigdirs="$noconfigdirs gdb"
1096     ;;
1097   fr30-*-elf*)
1098     noconfigdirs="$noconfigdirs gdb"
1099     ;;
1100   ft32-*-*)
1101     noconfigdirs="$noconfigdirs target-rda gprof"
1102     ;;
1103   moxie-*-*)
1104     noconfigdirs="$noconfigdirs"
1105     ;;
1106   h8300*-*-*)
1107     noconfigdirs="$noconfigdirs target-libgloss"
1108     ;;
1109   h8500-*-*)
1110     noconfigdirs="$noconfigdirs target-libgloss"
1111     ;;
1112   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1113     ;;
1114   hppa*64*-*-hpux*)
1115     noconfigdirs="$noconfigdirs gdb"
1116     ;;
1117   hppa*-*-hpux11*)
1118     noconfigdirs="$noconfigdirs gdb ld"
1119     ;;
1120   hppa*64*-*-linux*)
1121     ;;
1122   hppa*-*-linux*)
1123     ;;
1124   hppa*-*-*elf* | \
1125   hppa*-*-lites* | \
1126   hppa*-*-openbsd* | \
1127   hppa*64*-*-*)
1128     ;;
1129   hppa*-*-pro*)
1130     ;;
1131   hppa*-*-*)
1132     noconfigdirs="$noconfigdirs ld"
1133     ;;
1134   i960-*-*)
1135     noconfigdirs="$noconfigdirs gdb"
1136     ;;
1137   ia64*-*-elf*)
1138     # No gdb support yet.
1139     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1140     ;;
1141   ia64*-**-hpux*)
1142     # No ld support yet.
1143     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1144     ;;
1145   ia64*-*-*vms*)
1146     # No ld support yet.
1147     noconfigdirs="$noconfigdirs libgui itcl ld"
1148     ;;
1149   i[[3456789]]86-w64-mingw*)
1150     ;;
1151   i[[3456789]]86-*-mingw*)
1152     target_configdirs="$target_configdirs target-winsup"
1153     ;;
1154   *-*-cygwin*)
1155     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1156     noconfigdirs="$noconfigdirs target-libgloss"
1157     # always build newlib if winsup directory is present.
1158     if test -d "$srcdir/winsup/cygwin"; then
1159       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1160     elif test -d "$srcdir/newlib"; then
1161       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1162     fi
1163     ;;
1164   i[[3456789]]86-*-pe)
1165     noconfigdirs="$noconfigdirs target-libgloss"
1166     ;;
1167   i[[3456789]]86-*-sco3.2v5*)
1168     # The linker does not yet know about weak symbols in COFF,
1169     # and is not configured to handle mixed ELF and COFF.
1170     noconfigdirs="$noconfigdirs ld target-libgloss"
1171     ;;
1172   i[[3456789]]86-*-sco*)
1173     noconfigdirs="$noconfigdirs gprof target-libgloss"
1174     ;;
1175   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1176     noconfigdirs="$noconfigdirs target-libgloss"
1177     ;;
1178   i[[3456789]]86-*-sysv4*)
1179     noconfigdirs="$noconfigdirs target-libgloss"
1180     ;;
1181   i[[3456789]]86-*-beos*)
1182     noconfigdirs="$noconfigdirs gdb"
1183     ;;
1184   i[[3456789]]86-*-rdos*)
1185     noconfigdirs="$noconfigdirs gdb"
1186     ;;
1187   mmix-*-*)
1188     noconfigdirs="$noconfigdirs gdb"
1189     ;;
1190   mt-*-*)
1191     noconfigdirs="$noconfigdirs sim"
1192     ;;
1193   nfp-*-*)
1194     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1195     noconfigdirs="$noconfigdirs $target_libraries"
1196     ;;
1197   pdp11-*-*)
1198     noconfigdirs="$noconfigdirs gdb gprof"
1199     ;;
1200   powerpc-*-aix*)
1201     # copied from rs6000-*-* entry
1202     noconfigdirs="$noconfigdirs gprof"
1203     ;;
1204   powerpc*-*-winnt* | powerpc*-*-pe*)
1205     target_configdirs="$target_configdirs target-winsup"
1206     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1207     # always build newlib.
1208     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1209     ;;
1210     # This is temporary until we can link against shared libraries
1211   powerpcle-*-solaris*)
1212     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1213     ;;
1214   powerpc-*-beos*)
1215     noconfigdirs="$noconfigdirs gdb"
1216     ;;
1217   rs6000-*-lynxos*)
1218     noconfigdirs="$noconfigdirs gprof"
1219     ;;
1220   rs6000-*-aix*)
1221     noconfigdirs="$noconfigdirs gprof"
1222     ;;
1223   rs6000-*-*)
1224     noconfigdirs="$noconfigdirs gprof"
1225     ;;
1226   m68k-apollo-*)
1227     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1228     ;;
1229   microblaze*)
1230     noconfigdirs="$noconfigdirs gprof"
1231     ;;
1232   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1233     if test x$with_newlib = xyes; then
1234       noconfigdirs="$noconfigdirs gprof"
1235     fi
1236     ;;
1237   mips*-*-irix5*)
1238     noconfigdirs="$noconfigdirs gprof target-libgloss"
1239     ;;
1240   mips*-*-irix6*)
1241     noconfigdirs="$noconfigdirs gprof target-libgloss"
1242     ;;
1243   mips*-*-bsd*)
1244     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1245     ;;
1246   mips*-*-linux*)
1247     ;;
1248   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1249   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1250     noconfigdirs="$noconfigdirs ld gas gprof"
1251     ;;
1252   mips*-*-*)
1253     noconfigdirs="$noconfigdirs gprof"
1254     ;;
1255   nvptx*-*-*)
1256     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1257     ;;
1258   sh-*-*)
1259     case "${target}" in
1260       sh*-*-elf)
1261          ;;
1262       *)
1263          noconfigdirs="$noconfigdirs target-libgloss" ;;
1264     esac
1265     ;;
1266   sparc-*-sunos4*)
1267     if test x${is_cross_compiler} = xno ; then
1268            use_gnu_ld=no
1269     fi
1270     ;;
1271   tic6x-*-*)
1272     noconfigdirs="$noconfigdirs sim"
1273     ;;
1274   tilepro*-*-* | tilegx*-*-*)
1275     noconfigdirs="$noconfigdirs sim"
1276     ;;
1277   v810-*-*)
1278     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1279     ;;
1280   vax-*-*)
1281     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1282     ;;
1283   wasm32-*-*)
1284     noconfigdirs="$noconfigdirs ld"
1285     ;;
1286 esac
1287
1288 # If we aren't building newlib, then don't build libgloss, since libgloss
1289 # depends upon some newlib header files.
1290 case "${noconfigdirs}" in
1291   *target-libgloss*) ;;
1292   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1293 esac
1294
1295 # Work in distributions that contain no compiler tools, like Autoconf.
1296 host_makefile_frag=/dev/null
1297 if test -d ${srcdir}/config ; then
1298 case "${host}" in
1299   i[[3456789]]86-*-msdosdjgpp*)
1300     host_makefile_frag="config/mh-djgpp"
1301     ;;
1302   *-cygwin*)
1303     ACX_CHECK_CYGWIN_CAT_WORKS
1304     host_makefile_frag="config/mh-cygwin"
1305     ;;
1306   *-mingw*)
1307     host_makefile_frag="config/mh-mingw"
1308     ;;
1309   alpha*-linux*)
1310     host_makefile_frag="config/mh-alpha-linux"
1311     ;;
1312   hppa*-hp-hpux10*)
1313     host_makefile_frag="config/mh-pa-hpux10"
1314     ;;
1315   hppa*-hp-hpux*)
1316     host_makefile_frag="config/mh-pa"
1317     ;;
1318   hppa*-*)
1319     host_makefile_frag="config/mh-pa"
1320     ;;
1321   *-*-darwin*)
1322     host_makefile_frag="config/mh-darwin"
1323     ;;
1324   powerpc-*-aix*)
1325     host_makefile_frag="config/mh-ppc-aix"
1326     ;;
1327   rs6000-*-aix*)
1328     host_makefile_frag="config/mh-ppc-aix"
1329     ;;
1330 esac
1331 fi
1332
1333 if test "${build}" != "${host}" ; then
1334   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1335   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1336   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1337   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1338   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1339   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1340   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1341   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1342   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1343   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1344   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1345   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1346   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1347 else
1348   AR_FOR_BUILD="\$(AR)"
1349   AS_FOR_BUILD="\$(AS)"
1350   CC_FOR_BUILD="\$(CC)"
1351   CXX_FOR_BUILD="\$(CXX)"
1352   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1353   GOC_FOR_BUILD="\$(GOC)"
1354   GDC_FOR_BUILD="\$(GDC)"
1355   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1356   LD_FOR_BUILD="\$(LD)"
1357   NM_FOR_BUILD="\$(NM)"
1358   RANLIB_FOR_BUILD="\$(RANLIB)"
1359   WINDRES_FOR_BUILD="\$(WINDRES)"
1360   WINDMC_FOR_BUILD="\$(WINDMC)"
1361 fi
1362
1363 AC_PROG_CC_C99
1364 AC_PROG_CXX
1365
1366 # We must set the default linker to the linker used by gcc for the correct
1367 # operation of libtool.  If LD is not defined and we are using gcc, try to
1368 # set the LD default to the ld used by gcc.
1369 if test -z "$LD"; then
1370   if test "$GCC" = yes; then
1371     case $build in
1372     *-*-mingw*)
1373       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1374     *)
1375       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1376     esac
1377     case $gcc_prog_ld in
1378     # Accept absolute paths.
1379     [[\\/]* | [A-Za-z]:[\\/]*)]
1380       LD="$gcc_prog_ld" ;;
1381     esac
1382   fi
1383 fi
1384
1385 # Check whether -static-libstdc++ -static-libgcc is supported.
1386 have_static_libs=no
1387 if test "$GCC" = yes; then
1388   saved_LDFLAGS="$LDFLAGS"
1389
1390   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1391   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1392   AC_LANG_PUSH(C++)
1393   AC_LINK_IFELSE([AC_LANG_SOURCE([
1394 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1395 #error -static-libstdc++ not implemented
1396 #endif
1397 int main() {}])],
1398     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1399     [AC_MSG_RESULT([no])])
1400   AC_LANG_POP(C++)
1401
1402   LDFLAGS="$saved_LDFLAGS"
1403 fi
1404
1405 ACX_PROG_GNAT
1406 ACX_PROG_CMP_IGNORE_INITIAL
1407
1408 AC_ARG_ENABLE([bootstrap],
1409 [AS_HELP_STRING([--enable-bootstrap],
1410                 [enable bootstrapping @<:@yes if native build@:>@])],,
1411 enable_bootstrap=default)
1412
1413 # Issue errors and warnings for invalid/strange bootstrap combinations.
1414 if test -r $srcdir/gcc/configure; then
1415   have_compiler=yes
1416 else
1417   have_compiler=no
1418 fi
1419
1420 case "$have_compiler:$host:$target:$enable_bootstrap" in
1421   *:*:*:no) ;;
1422
1423   # Default behavior.  Enable bootstrap if we have a compiler
1424   # and we are in a native configuration.
1425   yes:$build:$build:default)
1426     enable_bootstrap=yes ;;
1427
1428   *:*:*:default)
1429     enable_bootstrap=no ;;
1430
1431   # We have a compiler and we are in a native configuration, bootstrap is ok
1432   yes:$build:$build:yes)
1433     ;;
1434
1435   # Other configurations, but we have a compiler.  Assume the user knows
1436   # what he's doing.
1437   yes:*:*:yes)
1438     AC_MSG_WARN([trying to bootstrap a cross compiler])
1439     ;;
1440
1441   # No compiler: if they passed --enable-bootstrap explicitly, fail
1442   no:*:*:yes)
1443     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1444
1445   # Fail if wrong command line
1446   *)
1447     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1448     ;;
1449 esac
1450
1451 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1452 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1453 # require C++11 (or higher).
1454 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1455   CXX="$CXX -std=c++11"
1456 elif test "$have_compiler" = yes; then
1457   AX_CXX_COMPILE_STDCXX(11)
1458
1459   if test "${build}" != "${host}"; then
1460     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1461   fi
1462 fi
1463
1464 # Used for setting $lt_cv_objdir
1465 _LT_CHECK_OBJDIR
1466
1467 # Check for GMP, MPFR and MPC
1468 gmplibs="-lmpc -lmpfr -lgmp"
1469 gmpinc=
1470 have_gmp=no
1471
1472 # Specify a location for mpc
1473 # check for this first so it ends up on the link line before mpfr.
1474 AC_ARG_WITH(mpc,
1475 [AS_HELP_STRING([--with-mpc=PATH],
1476                 [specify prefix directory for installed MPC package.
1477                  Equivalent to --with-mpc-include=PATH/include
1478                  plus --with-mpc-lib=PATH/lib])])
1479 AC_ARG_WITH(mpc-include,
1480 [AS_HELP_STRING([--with-mpc-include=PATH],
1481                 [specify directory for installed MPC include files])])
1482 AC_ARG_WITH(mpc-lib,
1483 [AS_HELP_STRING([--with-mpc-lib=PATH],
1484                 [specify directory for the installed MPC library])])
1485
1486 if test "x$with_mpc" != x; then
1487   gmplibs="-L$with_mpc/lib $gmplibs"
1488   gmpinc="-I$with_mpc/include $gmpinc"
1489 fi
1490 if test "x$with_mpc_include" != x; then
1491   gmpinc="-I$with_mpc_include $gmpinc"
1492 fi
1493 if test "x$with_mpc_lib" != x; then
1494   gmplibs="-L$with_mpc_lib $gmplibs"
1495 fi
1496 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1497   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1498   gmpinc='-I$$s/mpc/src '"$gmpinc"
1499   # Do not test the mpc version.  Assume that it is sufficient, since
1500   # it is in the source tree, and the library has not been built yet
1501   # but it would be included on the link line in the version check below
1502   # hence making the test fail.
1503   have_gmp=yes
1504 fi
1505
1506 # Specify a location for mpfr
1507 # check for this first so it ends up on the link line before gmp.
1508 AC_ARG_WITH(mpfr-dir,
1509 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1510 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1511 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1512
1513 AC_ARG_WITH(mpfr,
1514 [AS_HELP_STRING([--with-mpfr=PATH],
1515                 [specify prefix directory for installed MPFR package.
1516                  Equivalent to --with-mpfr-include=PATH/include
1517                  plus --with-mpfr-lib=PATH/lib])])
1518 AC_ARG_WITH(mpfr-include,
1519 [AS_HELP_STRING([--with-mpfr-include=PATH],
1520                 [specify directory for installed MPFR include files])])
1521 AC_ARG_WITH(mpfr-lib,
1522 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1523                 [specify directory for the installed MPFR library])])
1524
1525 if test "x$with_mpfr" != x; then
1526   gmplibs="-L$with_mpfr/lib $gmplibs"
1527   gmpinc="-I$with_mpfr/include $gmpinc"
1528 fi
1529 if test "x$with_mpfr_include" != x; then
1530   gmpinc="-I$with_mpfr_include $gmpinc"
1531 fi
1532 if test "x$with_mpfr_lib" != x; then
1533   gmplibs="-L$with_mpfr_lib $gmplibs"
1534 fi
1535 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1536   # MPFR v3.1.0 moved the sources into a src sub-directory.
1537   if ! test -d ${srcdir}/mpfr/src; then
1538     AC_MSG_ERROR([dnl
1539 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1540   fi
1541   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1542   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1543   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1544   # Do not test the mpfr version.  Assume that it is sufficient, since
1545   # it is in the source tree, and the library has not been built yet
1546   # but it would be included on the link line in the version check below
1547   # hence making the test fail.
1548   have_gmp=yes
1549 fi
1550
1551 # Specify a location for gmp
1552 AC_ARG_WITH(gmp-dir,
1553 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1554 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1555 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1556
1557 AC_ARG_WITH(gmp,
1558 [AS_HELP_STRING([--with-gmp=PATH],
1559                 [specify prefix directory for the installed GMP package.
1560                  Equivalent to --with-gmp-include=PATH/include
1561                  plus --with-gmp-lib=PATH/lib])])
1562 AC_ARG_WITH(gmp-include,
1563 [AS_HELP_STRING([--with-gmp-include=PATH],
1564                 [specify directory for installed GMP include files])])
1565 AC_ARG_WITH(gmp-lib,
1566 [AS_HELP_STRING([--with-gmp-lib=PATH],
1567                 [specify directory for the installed GMP library])])
1568
1569
1570 if test "x$with_gmp" != x; then
1571   gmplibs="-L$with_gmp/lib $gmplibs"
1572   gmpinc="-I$with_gmp/include $gmpinc"
1573 fi
1574 if test "x$with_gmp_include" != x; then
1575   gmpinc="-I$with_gmp_include $gmpinc"
1576 fi
1577 if test "x$with_gmp_lib" != x; then
1578   gmplibs="-L$with_gmp_lib $gmplibs"
1579 fi
1580 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1581   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1582   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1583   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1584   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1585   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1586   # Do not test the gmp version.  Assume that it is sufficient, since
1587   # it is in the source tree, and the library has not been built yet
1588   # but it would be included on the link line in the version check below
1589   # hence making the test fail.
1590   have_gmp=yes
1591 fi
1592
1593 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1594   have_gmp=yes
1595   saved_CFLAGS="$CFLAGS"
1596   CFLAGS="$CFLAGS $gmpinc"
1597   # Check for the recommended and required versions of GMP.
1598   AC_MSG_CHECKING([for the correct version of gmp.h])
1599   AC_TRY_COMPILE([#include "gmp.h"],[
1600   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1601   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1602   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1603   choke me
1604   #endif
1605   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1606   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1607   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1608   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1609   choke me
1610   #endif
1611   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1612    [AC_MSG_RESULT([no]); have_gmp=no])
1613
1614   # If we have GMP, check the MPFR version.
1615   if test x"$have_gmp" = xyes; then
1616     # Check for the recommended and required versions of MPFR.
1617     AC_MSG_CHECKING([for the correct version of mpfr.h])
1618     AC_TRY_COMPILE([#include <gmp.h>
1619     #include <mpfr.h>],[
1620     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1621     choke me
1622     #endif
1623     ], [AC_TRY_COMPILE([#include <gmp.h>
1624     #include <mpfr.h>],[
1625     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1626     choke me
1627     #endif
1628     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1629      [AC_MSG_RESULT([no]); have_gmp=no])
1630   fi
1631
1632   # Check for the MPC header version.
1633   if test x"$have_gmp" = xyes ; then
1634     # Check for the recommended and required versions of MPC.
1635     AC_MSG_CHECKING([for the correct version of mpc.h])
1636     AC_TRY_COMPILE([#include <mpc.h>],[
1637     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1638     choke me
1639     #endif
1640     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1641     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1642     choke me
1643     #endif
1644     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1645      [AC_MSG_RESULT([no]); have_gmp=no])
1646   fi
1647
1648   # Now check the MPFR library.
1649   if test x"$have_gmp" = xyes; then
1650     saved_LIBS="$LIBS"
1651     LIBS="$LIBS $gmplibs"
1652     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1653     AC_TRY_LINK([#include <mpc.h>],[
1654     mpfr_t n;
1655     mpfr_t x;
1656     mpc_t c;
1657     int t;
1658     mpfr_init (n);
1659     mpfr_init (x);
1660     mpfr_atan2 (n, n, x, MPFR_RNDN);
1661     mpfr_erfc (n, x, MPFR_RNDN);
1662     mpfr_subnormalize (x, t, MPFR_RNDN);
1663     mpfr_clear(n);
1664     mpfr_clear(x);
1665     mpc_init2 (c, 53);
1666     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1667     mpc_cosh (c, c, MPC_RNDNN);
1668     mpc_pow (c, c, c, MPC_RNDNN);
1669     mpc_acosh (c, c, MPC_RNDNN);
1670     mpc_clear (c);
1671     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1672     LIBS="$saved_LIBS"
1673   fi
1674
1675   CFLAGS="$saved_CFLAGS"
1676
1677 # The library versions listed in the error message below should match
1678 # the HARD-minimums enforced above.
1679   if test x$have_gmp != xyes; then
1680     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1681 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1682 their locations.  Source code for these libraries can be found at
1683 their respective hosting sites as well as at
1684 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1685 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1686 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1687 make sure that you have installed both the libraries and the header
1688 files.  They may be located in separate packages.])
1689   fi
1690 fi
1691
1692 # Flags needed for both GMP, MPFR and/or MPC.
1693 AC_SUBST(gmplibs)
1694 AC_SUBST(gmpinc)
1695 AC_SUBST(extra_mpfr_configure_flags)
1696 AC_SUBST(extra_mpc_gmp_configure_flags)
1697 AC_SUBST(extra_mpc_mpfr_configure_flags)
1698 AC_SUBST(extra_isl_gmp_configure_flags)
1699
1700 # Libraries to use for stage1 or when not bootstrapping.
1701 AC_ARG_WITH(stage1-libs,
1702 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1703 [if test "$withval" = "no" -o "$withval" = "yes"; then
1704    stage1_libs=
1705  else
1706    stage1_libs=$withval
1707  fi],
1708 [stage1_libs=])
1709 AC_SUBST(stage1_libs)
1710
1711 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1712 # default is yes if gcc is being built; no otherwise.  The reason for
1713 # this default is that gdb is sometimes linked against GNU Source
1714 # Highlight, which is a shared library that uses C++ exceptions.  In
1715 # this case, -static-libstdc++ will cause crashes.
1716 AC_ARG_WITH(static-standard-libraries,
1717 [AS_HELP_STRING([--with-static-standard-libraries],
1718                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1719 [], [with_static_standard_libraries=auto])
1720 if test "$with_static_standard_libraries" = auto; then
1721   with_static_standard_libraries=$have_compiler
1722 fi
1723
1724 # Linker flags to use for stage1 or when not bootstrapping.
1725 AC_ARG_WITH(stage1-ldflags,
1726 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1727 [if test "$withval" = "no" -o "$withval" = "yes"; then
1728    stage1_ldflags=
1729  else
1730    stage1_ldflags=$withval
1731  fi],
1732 [stage1_ldflags=
1733  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1734  # if supported.  But if the user explicitly specified the libraries to use,
1735  # trust that they are doing what they want.
1736  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1737      -a "$have_static_libs" = yes; then
1738    stage1_ldflags="-static-libstdc++ -static-libgcc"
1739  fi])
1740 AC_SUBST(stage1_ldflags)
1741
1742 # Libraries to use for stage2 and later builds.
1743 AC_ARG_WITH(boot-libs,
1744 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1745 [if test "$withval" = "no" -o "$withval" = "yes"; then
1746    poststage1_libs=
1747  else
1748    poststage1_libs=$withval
1749  fi],
1750 [poststage1_libs=])
1751 AC_SUBST(poststage1_libs)
1752
1753 # Linker flags to use for stage2 and later builds.
1754 AC_ARG_WITH(boot-ldflags,
1755 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1756                 [linker flags for stage2 and later])],
1757 [if test "$withval" = "no" -o "$withval" = "yes"; then
1758    poststage1_ldflags=
1759  else
1760    poststage1_ldflags=$withval
1761  fi],
1762 [poststage1_ldflags=
1763  # In stages 2 and 3, default to linking libstdc++ and libgcc
1764  # statically.  But if the user explicitly specified the libraries to
1765  # use, trust that they are doing what they want.
1766  if test "$poststage1_libs" = ""; then
1767    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1768  fi])
1769 AC_SUBST(poststage1_ldflags)
1770
1771 # GCC GRAPHITE dependency isl.
1772 # Basic setup is inlined here, actual checks are in config/isl.m4
1773
1774 AC_ARG_WITH(isl,
1775   [AS_HELP_STRING(
1776    [--with-isl=PATH],
1777    [Specify prefix directory for the installed isl package.
1778     Equivalent to --with-isl-include=PATH/include
1779     plus --with-isl-lib=PATH/lib])])
1780
1781 # Treat --without-isl as a request to disable
1782 # GRAPHITE support and skip all following checks.
1783 if test "x$with_isl" != "xno"; then
1784   # Check for isl
1785   dnl Provide configure switches and initialize islinc & isllibs
1786   dnl with user input.
1787   ISL_INIT_FLAGS
1788   dnl The versions of isl that work for Graphite
1789   ISL_CHECK_VERSION()
1790   dnl Only execute fail-action, if isl has been requested.
1791   ISL_IF_FAILED([
1792     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1793 fi
1794
1795 # If the isl check failed, disable builds of in-tree variant of isl
1796 if test "x$with_isl" = xno ||
1797    test "x$gcc_cv_isl" = xno; then
1798   noconfigdirs="$noconfigdirs isl"
1799   islinc=
1800 fi
1801
1802 AC_SUBST(isllibs)
1803 AC_SUBST(islinc)
1804
1805 # Check for LTO support.
1806 AC_ARG_ENABLE(lto,
1807 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1808 enable_lto=$enableval,
1809 enable_lto=yes; default_enable_lto=yes)
1810
1811 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1812   build_lto_plugin=yes
1813 ],[if test x"$default_enable_lto" = x"yes" ; then
1814     case $target in
1815       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1816       # On other non-ELF platforms, LTO has yet to be validated.
1817       *) enable_lto=no ;;
1818     esac
1819   else
1820   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1821   # It would also be nice to check the binutils support, but we don't
1822   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1823   # warn during gcc/ subconfigure; unless you're bootstrapping with
1824   # -flto it won't be needed until after installation anyway.
1825     case $target in
1826       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1827       *) if test x"$enable_lto" = x"yes"; then
1828         AC_MSG_ERROR([LTO support is not enabled for this target.])
1829         fi
1830       ;;
1831     esac
1832   fi
1833   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1834   # Build it unless LTO was explicitly disabled.
1835   case $target in
1836     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1837     *) ;;
1838   esac
1839 ])
1840
1841 AC_ARG_ENABLE(linker-plugin-configure-flags,
1842   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1843     [additional flags for configuring linker plugins @<:@none@:>@])],
1844   extra_linker_plugin_configure_flags=$enableval,
1845   extra_linker_plugin_configure_flags=)
1846 AC_SUBST(extra_linker_plugin_configure_flags)
1847 AC_ARG_ENABLE(linker-plugin-flags,
1848   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1849     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1850   extra_linker_plugin_flags=$enableval,
1851   extra_linker_plugin_flags=)
1852 AC_SUBST(extra_linker_plugin_flags)
1853
1854 # Enable --enable-host-shared.
1855 # Checked early to determine whether jit is an 'all' language
1856 AC_ARG_ENABLE(host-shared,
1857 [AS_HELP_STRING([--enable-host-shared],
1858                 [build host code as shared libraries])],
1859 [host_shared=$enableval], [host_shared=no])
1860 AC_SUBST(host_shared)
1861
1862 # By default, C and C++ are the only stage 1 languages.
1863 stage1_languages=,c,
1864
1865 # Target libraries that we bootstrap.
1866 bootstrap_target_libs=,target-libgcc,
1867
1868 # Figure out what language subdirectories are present.
1869 # Look if the user specified --enable-languages="..."; if not, use
1870 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1871 # go away some day.
1872 # NB:  embedded tabs in this IF block -- do not untabify
1873 if test -d ${srcdir}/gcc; then
1874   if test x"${enable_languages+set}" != xset; then
1875     if test x"${LANGUAGES+set}" = xset; then
1876       enable_languages="${LANGUAGES}"
1877         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1878     else
1879       enable_languages=default
1880     fi
1881   else
1882     if test x"${enable_languages}" = x ||
1883        test x"${enable_languages}" = xyes;
1884        then
1885       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1886       exit 1
1887     fi
1888   fi
1889   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1890
1891   # 'f95' is the old name for the 'fortran' language. We issue a warning
1892   # and make the substitution.
1893   case ,${enable_languages}, in
1894     *,f95,*)
1895       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1896       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1897       ;;
1898   esac
1899
1900   # If bootstrapping, C++ must be enabled.
1901   case ",$enable_languages,:$enable_bootstrap" in
1902     *,c++,*:*) ;;
1903     *:yes)
1904       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1905         enable_languages="${enable_languages},c++"
1906       else
1907         AC_MSG_ERROR([bootstrapping requires c++ sources])
1908       fi
1909       ;;
1910   esac
1911
1912   # First scan to see if an enabled language requires some other language.
1913   # We assume that a given config-lang.in will list all the language
1914   # front ends it requires, even if some are required indirectly.
1915   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1916     case ${lang_frag} in
1917       ..) ;;
1918       # The odd quoting in the next line works around
1919       # an apparent bug in bash 1.12 on linux.
1920       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1921       *)
1922         # From the config-lang.in, get $language, $lang_requires, and
1923         # $lang_requires_boot_languages.
1924         language=
1925         lang_requires=
1926         lang_requires_boot_languages=
1927         # set srcdir during sourcing lang_frag to the gcc dir.
1928         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1929         # polutes this shell
1930         saved_srcdir=${srcdir}
1931         srcdir=${srcdir}/gcc . ${lang_frag}
1932         srcdir=${saved_srcdir}
1933         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1934           case ,${enable_languages}, in
1935             *,$other,*) ;;
1936             *,default,*) ;;
1937             *,all,*) ;;
1938             *,$language,*)
1939               echo " \`$other' language required by \`$language'; enabling" 1>&2
1940               enable_languages="${enable_languages},${other}"
1941               ;;
1942           esac
1943         done
1944         for other in ${lang_requires_boot_languages} ; do
1945           if test "$other" != "c"; then
1946             case ,${enable_stage1_languages}, in
1947               *,$other,*) ;;
1948               *,default,*) ;;
1949               *,all,*) ;;
1950               *)
1951                 case ,${enable_languages}, in
1952                   *,$language,*)
1953                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1954                     enable_stage1_languages="$enable_stage1_languages,${other}"
1955                     ;;
1956                 esac
1957                 ;;
1958             esac
1959           fi
1960         done
1961         ;;
1962     esac
1963   done
1964
1965   new_enable_languages=,c,
1966
1967   # If LTO is enabled, add the LTO front end.
1968   if test "$enable_lto" = "yes" ; then
1969     case ,${enable_languages}, in
1970       *,lto,*) ;;
1971       *) enable_languages="${enable_languages},lto" ;;
1972     esac
1973     if test "${build_lto_plugin}" = "yes" ; then
1974       configdirs="$configdirs lto-plugin"
1975     fi
1976   fi
1977
1978   # If we're building an offloading compiler, add the LTO front end.
1979   if test x"$enable_as_accelerator_for" != x ; then
1980     case ,${enable_languages}, in
1981       *,lto,*) ;;
1982       *) enable_languages="${enable_languages},lto" ;;
1983     esac
1984   fi
1985
1986   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1987   potential_languages=,c,
1988
1989   enabled_target_libs=
1990   disabled_target_libs=
1991
1992   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1993     case ${lang_frag} in
1994       ..) ;;
1995       # The odd quoting in the next line works around
1996       # an apparent bug in bash 1.12 on linux.
1997       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1998       *)
1999         # From the config-lang.in, get $language, $target_libs,
2000         # $lang_dirs, $boot_language, and $build_by_default
2001         language=
2002         target_libs=
2003         lang_dirs=
2004         subdir_requires=
2005         boot_language=no
2006         build_by_default=yes
2007         # set srcdir during sourcing.  See above about save & restore
2008         saved_srcdir=${srcdir}
2009         srcdir=${srcdir}/gcc . ${lang_frag}
2010         srcdir=${saved_srcdir}
2011         if test x${language} = x; then
2012           echo "${lang_frag} doesn't set \$language." 1>&2
2013           exit 1
2014         fi
2015
2016         if test "$language" = "c++"; then
2017           boot_language=yes
2018         fi
2019
2020         add_this_lang=no
2021         # C is always enabled, so no need to add it again
2022         if test "$language" != "c"; then
2023           case ,${enable_languages}, in
2024             *,${language},*)
2025               # Language was explicitly selected; include it
2026               add_this_lang=yes
2027               ;;
2028             *,all,*)
2029               # All languages are enabled
2030               add_this_lang=all
2031               ;;
2032             *,default,*)
2033               # 'default' was selected, select it if it is a default language
2034               add_this_lang=${build_by_default}
2035               ;;
2036           esac
2037         fi
2038
2039         # Disable languages that need other directories if these aren't available.
2040         for i in $subdir_requires; do
2041           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2042           case ${add_this_lang} in
2043             yes)
2044               # Specifically requested language; tell them.
2045               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2046               ;;
2047             all)
2048               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2049               add_this_lang=unsupported
2050               ;;
2051             *)
2052               # Silently disable.
2053               add_this_lang=unsupported
2054               ;;
2055           esac
2056         done
2057
2058         # Disable Ada if no preexisting GNAT is available.
2059         case ${add_this_lang}:${language}:${have_gnat} in
2060           yes:ada:no)
2061             # Specifically requested language; tell them.
2062             AC_MSG_ERROR([GNAT is required to build $language])
2063             ;;
2064           all:ada:no)
2065             AC_MSG_WARN([GNAT is required to build $language])
2066             add_this_lang=unsupported
2067             ;;
2068           *:ada:no)
2069             # Silently disable.
2070             add_this_lang=unsupported
2071             ;;
2072         esac
2073
2074         # Disable jit if -enable-host-shared not specified
2075         # but not if building for Mingw. All code in Windows
2076         # is position independent code (PIC).
2077         case $target in
2078           *mingw*) ;;
2079           *)
2080           case ${add_this_lang}:${language}:${host_shared} in
2081             yes:jit:no)
2082                    # PR jit/64780: explicitly specify --enable-host-shared
2083             AC_MSG_ERROR([
2084 Enabling language "jit" requires --enable-host-shared.
2085
2086 --enable-host-shared typically slows the rest of the compiler down by
2087 a few %, so you must explicitly enable it.
2088
2089 If you want to build both the jit and the regular compiler, it is often
2090 best to do this via two separate configure/builds, in separate
2091 directories, to avoid imposing the performance cost of
2092 --enable-host-shared on the regular compiler.])
2093                     ;;
2094             all:jit:no)
2095               AC_MSG_WARN([--enable-host-shared required to build $language])
2096               add_this_lang=unsupported
2097               ;;
2098             *:jit:no)
2099               # Silently disable.
2100               add_this_lang=unsupported
2101               ;;
2102                 esac
2103           ;;
2104         esac
2105
2106         # Disable a language that is unsupported by the target.
2107         case "${add_this_lang}: $unsupported_languages " in
2108           no:*) ;;
2109           unsupported:*) ;;
2110           *:*" $language "*)
2111             AC_MSG_WARN([${language} not supported for this target])
2112             add_this_lang=unsupported
2113             ;;
2114         esac
2115
2116         case $add_this_lang in
2117           unsupported)
2118             # Remove language-dependent dirs.
2119             disabled_target_libs="$disabled_target_libs $target_libs"
2120             noconfigdirs="$noconfigdirs $lang_dirs"
2121             ;;
2122           no)
2123             # Remove language-dependent dirs; still show language as supported.
2124             disabled_target_libs="$disabled_target_libs $target_libs"
2125             noconfigdirs="$noconfigdirs $lang_dirs"
2126             potential_languages="${potential_languages}${language},"
2127             ;;
2128           all|yes)
2129             new_enable_languages="${new_enable_languages}${language},"
2130             potential_languages="${potential_languages}${language},"
2131             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2132             enabled_target_libs="$enabled_target_libs $target_libs"
2133             case "${boot_language}:,$enable_stage1_languages," in
2134               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2135                 # Add to (comma-separated) list of stage 1 languages.
2136                 case ",$stage1_languages," in
2137                   *,$language,* | ,yes, | ,all,) ;;
2138                   *) stage1_languages="${stage1_languages}${language}," ;;
2139                 esac
2140                 # We need to bootstrap any supporting libraries.
2141                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2142                 ;;
2143             esac
2144             ;;
2145         esac
2146         ;;
2147     esac
2148   done
2149
2150   # Add target libraries which are only needed for disabled languages
2151   # to noconfigdirs.
2152   if test -n "$disabled_target_libs"; then
2153     for dir in $disabled_target_libs; do
2154       case " $enabled_target_libs " in
2155       *" ${dir} "*) ;;
2156       *) noconfigdirs="$noconfigdirs $dir" ;;
2157       esac
2158     done
2159   fi
2160
2161   AC_ARG_ENABLE(stage1-languages,
2162   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2163                   [choose additional languages to build during
2164                   stage1.  Mostly useful for compiler development])],
2165   [case ,${enable_stage1_languages}, in
2166     ,no,|,,)
2167       # Set it to something that will have no effect in the loop below
2168       enable_stage1_languages=c ;;
2169     ,yes,)
2170       enable_stage1_languages=`echo $new_enable_languages | \
2171         sed -e "s/^,//" -e "s/,$//" ` ;;
2172     *,all,*)
2173       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2174         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2175   esac
2176
2177   # Add "good" languages from enable_stage1_languages to stage1_languages,
2178   # while "bad" languages go in missing_languages.  Leave no duplicates.
2179   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2180     case $potential_languages in
2181       *,$i,*)
2182         case $stage1_languages in
2183           *,$i,*) ;;
2184           *) stage1_languages="$stage1_languages$i," ;;
2185         esac ;;
2186       *)
2187         case $missing_languages in
2188           *,$i,*) ;;
2189           *) missing_languages="$missing_languages$i," ;;
2190         esac ;;
2191      esac
2192   done])
2193
2194   # Remove leading/trailing commas that were added for simplicity
2195   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2196   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2197   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2198   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2199
2200   if test "x$missing_languages" != x; then
2201     AC_MSG_ERROR([
2202 The following requested languages could not be built: ${missing_languages}
2203 Supported languages are: ${potential_languages}])
2204   fi
2205   if test "x$new_enable_languages" != "x$enable_languages"; then
2206     echo The following languages will be built: ${new_enable_languages}
2207     enable_languages="$new_enable_languages"
2208   fi
2209
2210   AC_SUBST(stage1_languages)
2211   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2212 fi
2213
2214 # Handle --disable-<component> generically.
2215 for dir in $configdirs $build_configdirs $target_configdirs ; do
2216   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2217   varname=`echo $dirname | sed -e s/+/_/g`
2218   if eval test x\${enable_${varname}} "=" xno ; then
2219     noconfigdirs="$noconfigdirs $dir"
2220   fi
2221 done
2222
2223 # Check for Boehm's garbage collector
2224 AC_ARG_ENABLE(objc-gc,
2225 [AS_HELP_STRING([--enable-objc-gc],
2226                 [enable use of Boehm's garbage collector with the
2227                  GNU Objective-C runtime])])
2228 AC_ARG_WITH([target-bdw-gc],
2229 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2230                 [specify prefix directory for installed bdw-gc package.
2231                  Equivalent to --with-target-bdw-gc-include=PATH/include
2232                  plus --with-target-bdw-gc-lib=PATH/lib])])
2233 AC_ARG_WITH([target-bdw-gc-include],
2234 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2235                 [specify directories for installed bdw-gc include files])])
2236 AC_ARG_WITH([target-bdw-gc-lib],
2237 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2238                 [specify directories for installed bdw-gc library])])
2239
2240 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2241   AC_MSG_CHECKING([for bdw garbage collector])
2242   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2243     dnl no bdw-gw options, assume default locations
2244     AC_MSG_RESULT([using bdw-gc in default locations])
2245   else
2246     dnl bdw-gw options, first error checking, complete checking in libobjc
2247     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2248       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2249     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2250       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2251     else
2252       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2253     fi
2254   fi
2255 esac
2256
2257 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2258 case ,${enable_languages}, in
2259   *,c++,*)
2260     # Disable libitm, libsanitizer if we're not building libstdc++
2261     case "${noconfigdirs}" in
2262       *target-libstdc++-v3*)
2263         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2264         ;;
2265       *) ;;
2266     esac
2267     ;;
2268   *)
2269     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2270     ;;
2271 esac
2272
2273 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2274 # $build_configdirs and $target_configdirs.
2275 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2276
2277 notsupp=""
2278 for dir in . $skipdirs $noconfigdirs ; do
2279   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2280   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2281     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2282     if test -r $srcdir/$dirname/configure ; then
2283       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2284         true
2285       else
2286         notsupp="$notsupp $dir"
2287       fi
2288     fi
2289   fi
2290   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2291     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2292     if test -r $srcdir/$dirname/configure ; then
2293       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2294         true
2295       else
2296         notsupp="$notsupp $dir"
2297       fi
2298     fi
2299   fi
2300   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2301     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2302     if test -r $srcdir/$dirname/configure ; then
2303       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2304         true
2305       else
2306         notsupp="$notsupp $dir"
2307       fi
2308     fi
2309   fi
2310 done
2311
2312 # Quietly strip out all directories which aren't configurable in this tree.
2313 # This relies on all configurable subdirectories being autoconfiscated, which
2314 # is now the case.
2315 build_configdirs_all="$build_configdirs"
2316 build_configdirs=
2317 for i in ${build_configdirs_all} ; do
2318   j=`echo $i | sed -e s/build-//g`
2319   if test -f ${srcdir}/$j/configure ; then
2320     build_configdirs="${build_configdirs} $i"
2321   fi
2322 done
2323
2324 configdirs_all="$configdirs"
2325 configdirs=
2326 for i in ${configdirs_all} ; do
2327   if test -f ${srcdir}/$i/configure ; then
2328     configdirs="${configdirs} $i"
2329   fi
2330 done
2331
2332 target_configdirs_all="$target_configdirs"
2333 target_configdirs=
2334 for i in ${target_configdirs_all} ; do
2335   j=`echo $i | sed -e s/target-//g`
2336   if test -f ${srcdir}/$j/configure ; then
2337     target_configdirs="${target_configdirs} $i"
2338   fi
2339 done
2340
2341 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2342 # so we have to add it after the preceding checks.
2343 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2344 then
2345   case " $configdirs " in
2346     *" libiberty "*)
2347       # If we can build libiberty, we can also build libiberty-linker-plugin.
2348       configdirs="$configdirs libiberty-linker-plugin"
2349       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2350         --with-libiberty=../libiberty-linker-plugin";;
2351     *)
2352       AC_MSG_ERROR([libiberty missing]);;
2353   esac
2354 fi
2355
2356 # Sometimes we have special requirements for the host libiberty.
2357 extra_host_libiberty_configure_flags=
2358 extra_host_zlib_configure_flags=
2359 case " $configdirs " in
2360   *" lto-plugin "* | *" libcc1 "*)
2361     # When these are to be built as shared libraries, the same applies to
2362     # libiberty.
2363     extra_host_libiberty_configure_flags=--enable-shared
2364     ;;
2365   *" bfd "*)
2366     # When bfd is to be built as a shared library, the same applies to
2367     # zlib.
2368     if test "$enable_shared" = "yes"; then
2369       extra_host_zlib_configure_flags=--enable-host-shared
2370     fi
2371     ;;
2372 esac
2373 AC_SUBST(extra_host_libiberty_configure_flags)
2374 AC_SUBST(extra_host_zlib_configure_flags)
2375
2376 # Produce a warning message for the subdirs we can't configure.
2377 # This isn't especially interesting in the Cygnus tree, but in the individual
2378 # FSF releases, it's important to let people know when their machine isn't
2379 # supported by the one or two programs in a package.
2380
2381 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2382   # If $appdirs is non-empty, at least one of those directories must still
2383   # be configured, or we error out.  (E.g., if the gas release supports a
2384   # specified target in some subdirs but not the gas subdir, we shouldn't
2385   # pretend that all is well.)
2386   if test -n "$appdirs" ; then
2387     for dir in $appdirs ; do
2388       if test -r $dir/Makefile.in ; then
2389         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2390           appdirs=""
2391           break
2392         fi
2393         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2394           appdirs=""
2395           break
2396         fi
2397       fi
2398     done
2399     if test -n "$appdirs" ; then
2400       echo "*** This configuration is not supported by this package." 1>&2
2401       exit 1
2402     fi
2403   fi
2404   # Okay, some application will build, or we don't care to check.  Still
2405   # notify of subdirs not getting built.
2406   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2407   echo "    ${notsupp}" 1>&2
2408   echo "    (Any other directories should still work fine.)" 1>&2
2409 fi
2410
2411 case "$host" in
2412   *msdosdjgpp*)
2413     enable_gdbtk=no ;;
2414 esac
2415
2416 # To find our prefix, in gcc_cv_tool_prefix.
2417 ACX_TOOL_DIRS
2418
2419 copy_dirs=
2420
2421 AC_ARG_WITH([build-sysroot],
2422   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2423                   [use sysroot as the system root during the build])],
2424   [if test x"$withval" != x ; then
2425      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2426    fi],
2427   [SYSROOT_CFLAGS_FOR_TARGET=])
2428 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2429
2430 AC_ARG_WITH([debug-prefix-map],
2431   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2432                   [map A to B, C to D ... in debug information])],
2433   [if test x"$withval" != x; then
2434      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2435      for debug_map in $withval; do
2436        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2437      done
2438    fi],
2439   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2440 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2441
2442 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2443 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2444 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2445 # We want to ensure that TARGET libraries (which we know are built with
2446 # gcc) are built with "-O2 -g", so include those options when setting
2447 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2448 if test "x$CFLAGS_FOR_TARGET" = x; then
2449   if test "x${is_cross_compiler}" = xyes; then
2450     CFLAGS_FOR_TARGET="-g -O2"
2451   else
2452     CFLAGS_FOR_TARGET=$CFLAGS
2453     case " $CFLAGS " in
2454       *" -O2 "*) ;;
2455       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2456     esac
2457     case " $CFLAGS " in
2458       *" -g "* | *" -g3 "*) ;;
2459       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2460     esac
2461   fi
2462 fi
2463 AC_SUBST(CFLAGS_FOR_TARGET)
2464
2465 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2466   if test "x${is_cross_compiler}" = xyes; then
2467     CXXFLAGS_FOR_TARGET="-g -O2"
2468   else
2469     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2470     case " $CXXFLAGS " in
2471       *" -O2 "*) ;;
2472       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2473     esac
2474     case " $CXXFLAGS " in
2475       *" -g "* | *" -g3 "*) ;;
2476       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2477     esac
2478   fi
2479 fi
2480 AC_SUBST(CXXFLAGS_FOR_TARGET)
2481
2482 AC_SUBST(LDFLAGS_FOR_TARGET)
2483
2484 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2485 # the named directory are copied to $(tooldir)/sys-include.
2486 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2487   if test x${is_cross_compiler} = xno ; then
2488     echo 1>&2 '***' --with-headers is only supported when cross compiling
2489     exit 1
2490   fi
2491   if test x"${with_headers}" != xyes ; then
2492     x=${gcc_cv_tool_prefix}
2493     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2494   fi
2495 fi
2496
2497 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2498 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2499 # are permitted.
2500 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2501   if test x${is_cross_compiler} = xno ; then
2502     echo 1>&2 '***' --with-libs is only supported when cross compiling
2503     exit 1
2504   fi
2505   if test x"${with_libs}" != xyes ; then
2506     # Copy the libraries in reverse order, so that files in the first named
2507     # library override files in subsequent libraries.
2508     x=${gcc_cv_tool_prefix}
2509     for l in ${with_libs}; do
2510       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2511     done
2512   fi
2513 fi
2514
2515 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2516 #
2517 # This is done by determining whether or not the appropriate directory
2518 # is available, and by checking whether or not specific configurations
2519 # have requested that this magic not happen.
2520 #
2521 # The command line options always override the explicit settings in
2522 # configure.ac, and the settings in configure.ac override this magic.
2523 #
2524 # If the default for a toolchain is to use GNU as and ld, and you don't
2525 # want to do that, then you should use the --without-gnu-as and
2526 # --without-gnu-ld options for the configure script.  Similarly, if
2527 # the default is to use the included zlib and you don't want to do that,
2528 # you should use the --with-system-zlib option for the configure script.
2529
2530 if test x${use_gnu_as} = x &&
2531    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2532   with_gnu_as=yes
2533   extra_host_args="$extra_host_args --with-gnu-as"
2534 fi
2535
2536 if test x${use_gnu_ld} = x &&
2537    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2538   with_gnu_ld=yes
2539   extra_host_args="$extra_host_args --with-gnu-ld"
2540 fi
2541
2542 if test x${use_included_zlib} = x &&
2543    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2544   :
2545 else
2546   with_system_zlib=yes
2547   extra_host_args="$extra_host_args --with-system-zlib"
2548 fi
2549
2550 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2551 # can detect this case.
2552
2553 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2554   with_newlib=yes
2555   extra_host_args="$extra_host_args --with-newlib"
2556 fi
2557
2558 # Handle ${copy_dirs}
2559 set fnord ${copy_dirs}
2560 shift
2561 while test $# != 0 ; do
2562   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2563     :
2564   else
2565     echo Copying $1 to $2
2566
2567     # Use the install script to create the directory and all required
2568     # parent directories.
2569     if test -d $2 ; then
2570       :
2571     else
2572       echo >config.temp
2573       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2574     fi
2575
2576     # Copy the directory, assuming we have tar.
2577     # FIXME: Should we use B in the second tar?  Not all systems support it.
2578     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2579
2580     # It is the responsibility of the user to correctly adjust all
2581     # symlinks.  If somebody can figure out how to handle them correctly
2582     # here, feel free to add the code.
2583
2584     echo $1 > $2/COPIED
2585   fi
2586   shift; shift
2587 done
2588
2589 # Determine a target-dependent exec_prefix that the installed
2590 # gcc will search in.  Keep this list sorted by triplet, with
2591 # the *-*-osname triplets last.
2592 md_exec_prefix=
2593 case "${target}" in
2594   i[[34567]]86-pc-msdosdjgpp*)
2595     md_exec_prefix=/dev/env/DJDIR/bin
2596     ;;
2597   *-*-hpux* | \
2598   *-*-nto-qnx* | \
2599   *-*-solaris2*)
2600     md_exec_prefix=/usr/ccs/bin
2601     ;;
2602 esac
2603
2604 extra_arflags_for_target=
2605 extra_nmflags_for_target=
2606 extra_ranlibflags_for_target=
2607 target_makefile_frag=/dev/null
2608 case "${target}" in
2609   spu-*-*)
2610     target_makefile_frag="config/mt-spu"
2611     ;;
2612   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2613     target_makefile_frag="config/mt-sde"
2614     ;;
2615   mipsisa*-*-elfoabi*)
2616     target_makefile_frag="config/mt-mips-elfoabi"
2617     ;;
2618   mips*-*-*linux* | mips*-*-gnu*)
2619     target_makefile_frag="config/mt-mips-gnu"
2620     ;;
2621   nios2-*-elf*)
2622     target_makefile_frag="config/mt-nios2-elf"
2623     ;;
2624   *-*-linux-android*)
2625     target_makefile_frag="config/mt-android"
2626     ;;
2627   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2628     target_makefile_frag="config/mt-gnu"
2629     ;;
2630   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2631     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2632     # commands to handle both 32-bit and 64-bit objects.  These flags are
2633     # harmless if we're using GNU nm or ar.
2634     extra_arflags_for_target=" -X32_64"
2635     extra_nmflags_for_target=" -B -X32_64"
2636     ;;
2637 esac
2638
2639 alphaieee_frag=/dev/null
2640 case $target in
2641   alpha*-*-*)
2642     # This just makes sure to use the -mieee option to build target libs.
2643     # This should probably be set individually by each library.
2644     alphaieee_frag="config/mt-alphaieee"
2645     ;;
2646 esac
2647
2648 # If --enable-target-optspace always use -Os instead of -O2 to build
2649 # the target libraries, similarly if it is not specified, use -Os
2650 # on selected platforms.
2651 ospace_frag=/dev/null
2652 case "${enable_target_optspace}:${target}" in
2653   yes:*)
2654     ospace_frag="config/mt-ospace"
2655     ;;
2656   :d30v-*)
2657     ospace_frag="config/mt-d30v"
2658     ;;
2659   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2660     ospace_frag="config/mt-ospace"
2661     ;;
2662   no:* | :*)
2663     ;;
2664   *)
2665     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2666     ;;
2667 esac
2668
2669 # Some systems (e.g., one of the i386-aix systems the gas testers are
2670 # using) don't handle "\$" correctly, so don't use it here.
2671 tooldir='${exec_prefix}'/${target_noncanonical}
2672 build_tooldir=${tooldir}
2673
2674 # Create a .gdbinit file which runs the one in srcdir
2675 # and tells GDB to look there for source files.
2676
2677 if test -r ${srcdir}/.gdbinit ; then
2678   case ${srcdir} in
2679     .) ;;
2680     *) cat > ./.gdbinit <<EOF
2681 # ${NO_EDIT}
2682 dir ${srcdir}
2683 dir .
2684 source ${srcdir}/.gdbinit
2685 EOF
2686     ;;
2687   esac
2688 fi
2689
2690 # Make sure that the compiler is able to generate an executable.  If it
2691 # can't, we are probably in trouble.  We don't care whether we can run the
2692 # executable--we might be using a cross compiler--we only care whether it
2693 # can be created.  At this point the main configure script has set CC.
2694 we_are_ok=no
2695 echo "int main () { return 0; }" > conftest.c
2696 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2697 if test $? = 0 ; then
2698   if test -s conftest || test -s conftest.exe ; then
2699     we_are_ok=yes
2700   fi
2701 fi
2702 case $we_are_ok in
2703   no)
2704     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2705     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2706     rm -f conftest*
2707     exit 1
2708     ;;
2709 esac
2710 rm -f conftest*
2711
2712 # Decide which environment variable is used to find dynamic libraries.
2713 case "${host}" in
2714   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2715   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2716   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2717   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2718 esac
2719
2720 # On systems where the dynamic library environment variable is PATH,
2721 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2722 # built executables to PATH.
2723 if test "$RPATH_ENVVAR" = PATH; then
2724   GCC_SHLIB_SUBDIR=/shlib
2725 else
2726   GCC_SHLIB_SUBDIR=
2727 fi
2728
2729 # Adjust the toplevel makefile according to whether bootstrap was selected.
2730 case $enable_bootstrap in
2731   yes)
2732     bootstrap_suffix=bootstrap
2733     BUILD_CONFIG=bootstrap-debug
2734     ;;
2735   no)
2736     bootstrap_suffix=no-bootstrap
2737     BUILD_CONFIG=
2738     ;;
2739 esac
2740
2741 AC_MSG_CHECKING(for default BUILD_CONFIG)
2742
2743 AC_ARG_WITH([build-config],
2744   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2745                   [use config/NAME.mk build configuration])],
2746   [case $with_build_config in
2747    yes) with_build_config= ;;
2748    no) with_build_config= BUILD_CONFIG= ;;
2749    esac])
2750
2751 if test "x${with_build_config}" != x; then
2752   BUILD_CONFIG=$with_build_config
2753 else
2754   case $BUILD_CONFIG in
2755   bootstrap-debug)
2756     if echo "int f (void) { return 0; }" > conftest.c &&
2757        ${CC} -c conftest.c &&
2758        mv conftest.o conftest.o.g0 &&
2759        ${CC} -c -g conftest.c &&
2760        mv conftest.o conftest.o.g &&
2761        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2762       :
2763     else
2764       BUILD_CONFIG=
2765     fi
2766     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2767     ;;
2768   esac
2769 fi
2770 AC_MSG_RESULT($BUILD_CONFIG)
2771 AC_SUBST(BUILD_CONFIG)
2772
2773 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2774 AC_MSG_CHECKING([for --enable-vtable-verify])
2775 AC_ARG_ENABLE(vtable-verify,
2776 [AS_HELP_STRING([--enable-vtable-verify],
2777                 [Enable vtable verification feature])],
2778 [case "$enableval" in
2779  yes) enable_vtable_verify=yes ;;
2780  no)  enable_vtable_verify=no ;;
2781  *)   enable_vtable_verify=no;;
2782  esac],
2783 [enable_vtable_verify=no])
2784 AC_MSG_RESULT($enable_vtable_verify)
2785
2786 # Record target_configdirs and the configure arguments for target and
2787 # build configuration in Makefile.
2788 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2789 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2790 bootstrap_fixincludes=no
2791
2792 # If we are building libgomp, bootstrap it.
2793 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2794   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2795 fi
2796
2797 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2798 # or bootstrap-ubsan, bootstrap it.
2799 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2800   case "$BUILD_CONFIG" in
2801     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
2802       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2803       bootstrap_fixincludes=yes
2804       ;;
2805   esac
2806 fi
2807
2808 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2809 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2810    test "$enable_vtable_verify" != no; then
2811   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2812 fi
2813
2814 # Determine whether gdb needs tk/tcl or not.
2815 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2816 # and in that case we want gdb to be built without tk.  Ugh!
2817 # In fact I believe gdb is the *only* package directly dependent on tk,
2818 # so we should be able to put the 'maybe's in unconditionally and
2819 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2820 # 100% sure that that's safe though.
2821
2822 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2823 case "$enable_gdbtk" in
2824   no)
2825     GDB_TK="" ;;
2826   yes)
2827     GDB_TK="${gdb_tk}" ;;
2828   *)
2829     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2830     # distro.  Eventually someone will fix this and move Insight, nee
2831     # gdbtk to a separate directory.
2832     if test -d ${srcdir}/gdb/gdbtk ; then
2833       GDB_TK="${gdb_tk}"
2834     else
2835       GDB_TK=""
2836     fi
2837     ;;
2838 esac
2839 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2840 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2841
2842 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2843 # else does, only include them if one of these is built.  The Makefile
2844 # provides the ordering, so it's enough here to add to the list.
2845 case " ${configdirs} " in
2846   *\ gdb\ *)
2847     configdirs="${configdirs} gnulib gdbsupport"
2848     ;;
2849   *\ gdbserver\ *)
2850     configdirs="${configdirs} gnulib gdbsupport"
2851     ;;
2852   *\ sim\ *)
2853     configdirs="${configdirs} gnulib"
2854     ;;
2855 esac
2856
2857 # Strip out unwanted targets.
2858
2859 # While at that, we remove Makefiles if we were started for recursive
2860 # configuration, so that the top-level Makefile reconfigures them,
2861 # like we used to do when configure itself was recursive.
2862
2863 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2864 # but now we're fixing up the Makefile ourselves with the additional
2865 # commands passed to AC_CONFIG_FILES.  Use separate variables
2866 # extrasub-{build,host,target} not because there is any reason to split
2867 # the substitutions up that way, but only to remain below the limit of
2868 # 99 commands in a script, for HP-UX sed.
2869
2870 # Do not nest @if/@endif or @unless/@endunless pairs, because
2871 # configure will not warn you at all.
2872
2873 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2874   yes:yes:*\ gold\ *:*,c++,*) ;;
2875   yes:yes:*\ gold\ *:*)
2876     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2877     ;;
2878 esac
2879
2880 extrasub_build=
2881 for module in ${build_configdirs} ; do
2882   if test -z "${no_recursion}" \
2883      && test -f ${build_subdir}/${module}/Makefile; then
2884     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2885     rm -f ${build_subdir}/${module}/Makefile
2886   fi
2887   extrasub_build="$extrasub_build
2888 /^@if build-$module\$/d
2889 /^@endif build-$module\$/d
2890 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2891 /^@if build-$module-$bootstrap_suffix\$/d
2892 /^@endif build-$module-$bootstrap_suffix\$/d
2893 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2894 done
2895 extrasub_host=
2896 for module in ${configdirs} ; do
2897   if test -z "${no_recursion}"; then
2898     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2899       if test -f ${file}; then
2900         echo 1>&2 "*** removing ${file} to force reconfigure"
2901         rm -f ${file}
2902       fi
2903     done
2904   fi
2905   case ${module},${bootstrap_fixincludes} in
2906     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2907     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2908   esac
2909   extrasub_host="$extrasub_host
2910 /^@if $module\$/d
2911 /^@endif $module\$/d
2912 /^@unless $module\$/,/^@endunless $module\$/d
2913 /^@if $module-$host_bootstrap_suffix\$/d
2914 /^@endif $module-$host_bootstrap_suffix\$/d
2915 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2916 done
2917 extrasub_target=
2918 for module in ${target_configdirs} ; do
2919   if test -z "${no_recursion}" \
2920      && test -f ${target_subdir}/${module}/Makefile; then
2921     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2922     rm -f ${target_subdir}/${module}/Makefile
2923   fi
2924
2925   # We only bootstrap target libraries listed in bootstrap_target_libs.
2926   case $bootstrap_target_libs in
2927     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2928     *) target_bootstrap_suffix=no-bootstrap ;;
2929   esac
2930
2931   extrasub_target="$extrasub_target
2932 /^@if target-$module\$/d
2933 /^@endif target-$module\$/d
2934 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2935 /^@if target-$module-$target_bootstrap_suffix\$/d
2936 /^@endif target-$module-$target_bootstrap_suffix\$/d
2937 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2938 done
2939
2940 # Do the final fixup along with target modules.
2941 extrasub_target="$extrasub_target
2942 /^@if /,/^@endif /d
2943 /^@unless /d
2944 /^@endunless /d"
2945
2946 # Create the serialization dependencies.  This uses a temporary file.
2947
2948 AC_ARG_ENABLE([serial-configure],
2949 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2950                 [force sequential configuration of
2951                  sub-packages for the host, target or build
2952                  machine, or all sub-packages])])
2953
2954 case ${enable_serial_configure} in
2955   yes)
2956     enable_serial_build_configure=yes
2957     enable_serial_host_configure=yes
2958     enable_serial_target_configure=yes
2959     ;;
2960 esac
2961
2962 # These force 'configure's to be done one at a time, to avoid problems
2963 # with contention over a shared config.cache.
2964 rm -f serdep.tmp
2965 echo '# serdep.tmp' > serdep.tmp
2966 olditem=
2967 test "x${enable_serial_build_configure}" = xyes &&
2968 for item in ${build_configdirs} ; do
2969   case ${olditem} in
2970     "") ;;
2971     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2972   esac
2973   olditem=${item}
2974 done
2975 olditem=
2976 test "x${enable_serial_host_configure}" = xyes &&
2977 for item in ${configdirs} ; do
2978   case ${olditem} in
2979     "") ;;
2980     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2981   esac
2982   olditem=${item}
2983 done
2984 olditem=
2985 test "x${enable_serial_target_configure}" = xyes &&
2986 for item in ${target_configdirs} ; do
2987   case ${olditem} in
2988     "") ;;
2989     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2990   esac
2991   olditem=${item}
2992 done
2993 serialization_dependencies=serdep.tmp
2994 AC_SUBST_FILE(serialization_dependencies)
2995
2996 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2997 # target, nonopt, and variable assignments.  These are the ones we
2998 # might not want to pass down to subconfigures.  The exception being
2999 # --cache-file=/dev/null, which is used to turn off the use of cache
3000 # files altogether, and which should be passed on to subconfigures.
3001 # Also strip program-prefix, program-suffix, and program-transform-name,
3002 # so that we can pass down a consistent program-transform-name.
3003 baseargs=
3004 tbaseargs=
3005 keep_next=no
3006 skip_next=no
3007 eval "set -- $ac_configure_args"
3008 for ac_arg
3009 do
3010   if test X"$skip_next" = X"yes"; then
3011     skip_next=no
3012     continue
3013   fi
3014   if test X"$keep_next" = X"yes"; then
3015     case $ac_arg in
3016       *\'*)
3017         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3018     esac
3019     baseargs="$baseargs '$ac_arg'"
3020     tbaseargs="$tbaseargs '$ac_arg'"
3021     keep_next=no
3022     continue
3023   fi
3024
3025   # Handle separated arguments.  Based on the logic generated by
3026   # autoconf 2.59.
3027   case $ac_arg in
3028     *=* | --config-cache | -C | -disable-* | --disable-* \
3029       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3030       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3031       | -with-* | --with-* | -without-* | --without-* | --x)
3032       separate_arg=no
3033       ;;
3034     -*)
3035       separate_arg=yes
3036       ;;
3037     *)
3038       separate_arg=no
3039       ;;
3040   esac
3041
3042   skip_targ=no
3043   case $ac_arg in
3044 changequote(,)
3045   --with-* | --without-*)
3046     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3047
3048     case $libopt in
3049     *[-_]include)
3050       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3051       ;;
3052     *[-_]lib)
3053       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3054       ;;
3055     *)
3056       lib=$libopt
3057       ;;
3058     esac
3059 changequote([,])
3060
3061     case $lib in
3062     mpc | mpfr | gmp | isl)
3063       # If we're processing --with-$lib, --with-$lib-include or
3064       # --with-$lib-lib, for one of the libs above, and target is
3065       # different from host, don't pass the current argument to any
3066       # target library's configure.
3067       if test x$is_cross_compiler = xyes; then
3068         skip_targ=yes
3069       fi
3070       ;;
3071     esac
3072     ;;
3073   esac
3074
3075   case "$ac_arg" in
3076     --cache-file=/dev/null | \
3077     -cache-file=/dev/null )
3078       # Handled here to avoid the test to skip args below.
3079       baseargs="$baseargs '$ac_arg'"
3080       tbaseargs="$tbaseargs '$ac_arg'"
3081       # Assert: $separate_arg should always be no.
3082       keep_next=$separate_arg
3083       ;;
3084     --no*)
3085       continue
3086       ;;
3087     --c* | \
3088     --sr* | \
3089     --ho* | \
3090     --bu* | \
3091     --t* | \
3092     --program-* | \
3093     -cache_file* | \
3094     -srcdir* | \
3095     -host* | \
3096     -build* | \
3097     -target* | \
3098     -program-prefix* | \
3099     -program-suffix* | \
3100     -program-transform-name* )
3101       skip_next=$separate_arg
3102       continue
3103       ;;
3104     -*)
3105       # An option.  Add it.
3106       case $ac_arg in
3107         *\'*)
3108           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3109       esac
3110       baseargs="$baseargs '$ac_arg'"
3111       if test X"$skip_targ" = Xno; then
3112         tbaseargs="$tbaseargs '$ac_arg'"
3113       fi
3114       keep_next=$separate_arg
3115       ;;
3116     *)
3117       # Either a variable assignment, or a nonopt (triplet).  Don't
3118       # pass it down; let the Makefile handle this.
3119       continue
3120       ;;
3121   esac
3122 done
3123 # Remove the initial space we just introduced and, as these will be
3124 # expanded by make, quote '$'.
3125 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3126
3127 # Add in --program-transform-name, after --program-prefix and
3128 # --program-suffix have been applied to it.  Autoconf has already
3129 # doubled dollar signs and backslashes in program_transform_name; we want
3130 # the backslashes un-doubled, and then the entire thing wrapped in single
3131 # quotes, because this will be expanded first by make and then by the shell.
3132 # Also, because we want to override the logic in subdir configure scripts to
3133 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3134 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3135 ${program_transform_name}
3136 EOF_SED
3137 gcc_transform_name=`cat conftestsed.out`
3138 rm -f conftestsed.out
3139 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3140 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3141 if test "$silent" = yes; then
3142   baseargs="$baseargs --silent"
3143   tbaseargs="$tbaseargs --silent"
3144 fi
3145 baseargs="$baseargs --disable-option-checking"
3146 tbaseargs="$tbaseargs --disable-option-checking"
3147
3148 # Record and document user additions to sub configure arguments.
3149 AC_ARG_VAR([build_configargs],
3150            [additional configure arguments for build directories])
3151 AC_ARG_VAR([host_configargs],
3152            [additional configure arguments for host directories])
3153 AC_ARG_VAR([target_configargs],
3154            [additional configure arguments for target directories])
3155
3156 # For the build-side libraries, we just need to pretend we're native,
3157 # and not use the same cache file.  Multilibs are neither needed nor
3158 # desired.  We can't even use the same cache file for all build-side
3159 # libraries, as they're compiled differently; some with C, some with
3160 # C++ or with different feature-enabling options.
3161 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3162
3163 # For host modules, accept cache file option, or specification as blank.
3164 case "${cache_file}" in
3165 "") # empty
3166   cache_file_option="" ;;
3167 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3168   cache_file_option="--cache-file=${cache_file}" ;;
3169 *) # relative path
3170   cache_file_option="--cache-file=../${cache_file}" ;;
3171 esac
3172
3173 # Host dirs don't like to share a cache file either, horribly enough.
3174 # This seems to be due to autoconf 2.5x stupidity.
3175 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3176
3177 target_configargs="$target_configargs ${tbaseargs}"
3178
3179 # Passing a --with-cross-host argument lets the target libraries know
3180 # whether they are being built with a cross-compiler or being built
3181 # native.  However, it would be better to use other mechanisms to make the
3182 # sorts of decisions they want to make on this basis.  Please consider
3183 # this option to be deprecated.  FIXME.
3184 if test x${is_cross_compiler} = xyes ; then
3185   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3186 fi
3187
3188 # Special user-friendly check for native x86_64-linux build, if
3189 # multilib is not explicitly enabled.
3190 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3191   x86_64-*linux*:yes:$build:$build:)
3192     # Make sure we have a development environment that handles 32-bit
3193     dev64=no
3194     echo "int main () { return 0; }" > conftest.c
3195     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3196     if test $? = 0 ; then
3197       if test -s conftest || test -s conftest.exe ; then
3198         dev64=yes
3199       fi
3200     fi
3201     rm -f conftest*
3202     if test x${dev64} != xyes ; then
3203       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3204     fi
3205     ;;
3206 esac
3207
3208 # Default to --enable-multilib.
3209 if test x${enable_multilib} = x ; then
3210   target_configargs="--enable-multilib ${target_configargs}"
3211 fi
3212
3213 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3214 # changed from the earlier setting of with_newlib.
3215 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3216   target_configargs="--with-newlib ${target_configargs}"
3217 fi
3218
3219 # Different target subdirs use different values of certain variables
3220 # (notably CXX).  Worse, multilibs use *lots* of different values.
3221 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3222 # it doesn't automatically accept command-line overrides of them.
3223 # This means it's not safe for target subdirs to share a cache file,
3224 # which is disgusting, but there you have it.  Hopefully this can be
3225 # fixed in future.  It's still worthwhile to use a cache file for each
3226 # directory.  I think.
3227
3228 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3229 # We need to pass --target, as newer autoconf's requires consistency
3230 # for target_alias and gcc doesn't manage it consistently.
3231 target_configargs="--cache-file=./config.cache ${target_configargs}"
3232
3233 FLAGS_FOR_TARGET=
3234 case " $target_configdirs " in
3235  *" newlib "*)
3236   case " $target_configargs " in
3237   *" --with-newlib "*)
3238    case "$target" in
3239     *-cygwin*)
3240       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3241       ;;
3242    esac
3243
3244    # If we're not building GCC, don't discard standard headers.
3245    if test -d ${srcdir}/gcc; then
3246      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3247
3248      if test "${build}" != "${host}"; then
3249        # On Canadian crosses, CC_FOR_TARGET will have already been set
3250        # by `configure', so we won't have an opportunity to add -Bgcc/
3251        # to it.  This is right: we don't want to search that directory
3252        # for binaries, but we want the header files in there, so add
3253        # them explicitly.
3254        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3255
3256        # Someone might think of using the pre-installed headers on
3257        # Canadian crosses, in case the installed compiler is not fully
3258        # compatible with the compiler being built.  In this case, it
3259        # would be better to flag an error than risking having
3260        # incompatible object files being constructed.  We can't
3261        # guarantee that an error will be flagged, but let's hope the
3262        # compiler will do it, when presented with incompatible header
3263        # files.
3264      fi
3265    fi
3266
3267    case "${target}-${is_cross_compiler}" in
3268    i[[3456789]]86-*-linux*-no)
3269       # Here host == target, so we don't need to build gcc,
3270       # so we don't want to discard standard headers.
3271       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3272       ;;
3273    *)
3274       # If we're building newlib, use its generic headers last, but search
3275       # for any libc-related directories first (so make it the last -B
3276       # switch).
3277       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3278
3279       # If we're building libgloss, find the startup file, simulator library
3280       # and linker script.
3281       case " $target_configdirs " in
3282         *" libgloss "*)
3283         # Look for startup file, simulator library and maybe linker script.
3284         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3285         # Look for libnosys.a in case the target needs it.
3286         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3287         # Most targets have the linker script in the source directory.
3288         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3289         ;;
3290       esac
3291       ;;
3292    esac
3293    ;;
3294   esac
3295   ;;
3296 esac
3297
3298 case "$target" in
3299   x86_64-*mingw* | *-w64-mingw*)
3300   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3301   # however, use a symlink named 'mingw' in ${prefix} .
3302     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3303     ;;
3304   *-mingw*)
3305   # MinGW can't be handled as Cygwin above since it does not use newlib.
3306     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3307     ;;
3308 esac
3309
3310 # Allow the user to override the flags for
3311 # our build compiler if desired.
3312 if test x"${build}" = x"${host}" ; then
3313   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3314   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3315   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3316 fi
3317
3318 # On Canadian crosses, we'll be searching the right directories for
3319 # the previously-installed cross compiler, so don't bother to add
3320 # flags for directories within the install tree of the compiler
3321 # being built; programs in there won't even run.
3322 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3323   # Search for pre-installed headers if nothing else fits.
3324   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3325 fi
3326
3327 if test "x${use_gnu_ld}" = x &&
3328    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3329   # Arrange for us to find uninstalled linker scripts.
3330   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3331 fi
3332
3333 # Search for other target-specific linker scripts and such.
3334 case "${target}" in
3335   mep*)
3336     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3337     ;;
3338 esac
3339
3340 # Makefile fragments.
3341 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3342 do
3343   eval fragval=\$$frag
3344   if test $fragval != /dev/null; then
3345     eval $frag=${srcdir}/$fragval
3346   fi
3347 done
3348 AC_SUBST_FILE(host_makefile_frag)
3349 AC_SUBST_FILE(target_makefile_frag)
3350 AC_SUBST_FILE(alphaieee_frag)
3351 AC_SUBST_FILE(ospace_frag)
3352
3353 # Miscellanea: directories, flags, etc.
3354 AC_SUBST(RPATH_ENVVAR)
3355 AC_SUBST(GCC_SHLIB_SUBDIR)
3356 AC_SUBST(tooldir)
3357 AC_SUBST(build_tooldir)
3358 AC_SUBST(CONFIGURE_GDB_TK)
3359 AC_SUBST(GDB_TK)
3360 AC_SUBST(INSTALL_GDB_TK)
3361
3362 # Build module lists & subconfigure args.
3363 AC_SUBST(build_configargs)
3364 AC_SUBST(build_configdirs)
3365
3366 # Host module lists & subconfigure args.
3367 AC_SUBST(host_configargs)
3368 AC_SUBST(configdirs)
3369 AC_SUBST(target_configdirs)
3370
3371 # Target module lists & subconfigure args.
3372 AC_SUBST(target_configargs)
3373
3374
3375 # Build tools.
3376 AC_SUBST(AR_FOR_BUILD)
3377 AC_SUBST(AS_FOR_BUILD)
3378 AC_SUBST(CC_FOR_BUILD)
3379 AC_SUBST(CFLAGS_FOR_BUILD)
3380 AC_SUBST(CXXFLAGS_FOR_BUILD)
3381 AC_SUBST(CXX_FOR_BUILD)
3382 AC_SUBST(DLLTOOL_FOR_BUILD)
3383 AC_SUBST(GFORTRAN_FOR_BUILD)
3384 AC_SUBST(GOC_FOR_BUILD)
3385 AC_SUBST(GDC_FOR_BUILD)
3386 AC_SUBST(LDFLAGS_FOR_BUILD)
3387 AC_SUBST(LD_FOR_BUILD)
3388 AC_SUBST(NM_FOR_BUILD)
3389 AC_SUBST(RANLIB_FOR_BUILD)
3390 AC_SUBST(WINDMC_FOR_BUILD)
3391 AC_SUBST(WINDRES_FOR_BUILD)
3392
3393 # Generate default definitions for YACC, M4, LEX and other programs that run
3394 # on the build machine.  These are used if the Makefile can't locate these
3395 # programs in objdir.
3396 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3397
3398 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3399 case " $build_configdirs " in
3400   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3401 esac
3402
3403 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3404 case " $build_configdirs " in
3405   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3406 esac
3407
3408 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3409 case " $build_configdirs " in
3410   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3411 esac
3412
3413 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3414 case " $build_configdirs " in
3415   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3416   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3417 esac
3418
3419 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3420 case " $build_configdirs " in
3421   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3422 esac
3423
3424 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3425 case " $build_configdirs " in
3426   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3427   *)
3428 changequote(,)
3429     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3430     # higher, else we use the "missing" dummy.
3431     if ${MAKEINFO} --version \
3432        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3433       :
3434     else
3435       MAKEINFO="$MISSING makeinfo"
3436     fi
3437     ;;
3438 changequote([,])
3439 esac
3440
3441 # FIXME: expect and dejagnu may become build tools?
3442
3443 AC_CHECK_PROGS(EXPECT, expect, expect)
3444 case " $configdirs " in
3445   *" expect "*)
3446     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3447     ;;
3448 esac
3449
3450 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3451 case " $configdirs " in
3452   *" dejagnu "*)
3453     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3454     ;;
3455 esac
3456
3457
3458 # Host tools.
3459 NCN_STRICT_CHECK_TOOLS(AR, ar)
3460 NCN_STRICT_CHECK_TOOLS(AS, as)
3461 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3462 NCN_STRICT_CHECK_TOOLS(LD, ld)
3463 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3464 NCN_STRICT_CHECK_TOOLS(NM, nm)
3465 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3466 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3467 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3468 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3469 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3470 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3471 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3472 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3473 AC_SUBST(CC)
3474 AC_SUBST(CXX)
3475 AC_SUBST(CFLAGS)
3476 AC_SUBST(CXXFLAGS)
3477
3478 # Target tools.
3479 AC_ARG_WITH([build-time-tools],
3480   [AS_HELP_STRING([--with-build-time-tools=PATH],
3481                   [use given path to find target tools during the build])],
3482   [case x"$withval" in
3483      x/*) ;;
3484      *)
3485        with_build_time_tools=
3486        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3487        ;;
3488    esac],
3489   [with_build_time_tools=])
3490
3491 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3492 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3493 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3494 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3495 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3496 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3497
3498 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3499 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3500 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3501 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3502 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3503 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3504 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3505 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3506 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3507 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3508 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3509 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3510 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3511 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3512
3513 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3514
3515 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3516 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3517 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3518 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3519 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3520                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3521                 c++)
3522 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3523                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3524                 c++)
3525 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3526 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3527 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3528                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3529 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3530                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3531 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3532                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3533 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3534 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3535 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3536 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3537 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3538 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3539 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3540 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3541 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3542 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3543 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3544
3545 AC_SUBST(FLAGS_FOR_TARGET)
3546 AC_SUBST(RAW_CXX_FOR_TARGET)
3547
3548 # Certain tools may need extra flags.
3549 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3550 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3551 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3552
3553 # When building target libraries, except in a Canadian cross, we use
3554 # the same toolchain as the compiler we just built.
3555 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3556 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3557 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3558 if test $host = $build; then
3559   case " $configdirs " in
3560     *" gcc "*)
3561       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3562       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3563       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3564       ;;
3565   esac
3566 fi
3567
3568 AC_SUBST(COMPILER_AS_FOR_TARGET)
3569 AC_SUBST(COMPILER_LD_FOR_TARGET)
3570 AC_SUBST(COMPILER_NM_FOR_TARGET)
3571
3572 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3573 AC_ARG_ENABLE(maintainer-mode,
3574 [AS_HELP_STRING([--enable-maintainer-mode],
3575                 [enable make rules and dependencies not useful
3576                  (and sometimes confusing) to the casual installer])],
3577       USE_MAINTAINER_MODE=$enableval,
3578       USE_MAINTAINER_MODE=no)
3579 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3580 AC_SUBST(MAINTAINER_MODE_TRUE)
3581 AC_SUBST(MAINTAINER_MODE_FALSE)
3582 if test "$USE_MAINTAINER_MODE" = yes; then
3583   MAINTAINER_MODE_TRUE=
3584   MAINTAINER_MODE_FALSE='#'
3585 else
3586   MAINTAINER_MODE_TRUE='#'
3587   MAINTAINER_MODE_FALSE=
3588 fi
3589 MAINT=$MAINTAINER_MODE_TRUE
3590 AC_SUBST(MAINT)dnl
3591
3592 # ---------------------
3593 # GCC bootstrap support
3594 # ---------------------
3595
3596 # Stage specific cflags for build.
3597 stage1_cflags="-g"
3598 case $build in
3599   vax-*-*)
3600     case ${GCC} in
3601       yes) stage1_cflags="-g -Wa,-J" ;;
3602       *) stage1_cflags="-g -J" ;;
3603     esac ;;
3604 esac
3605
3606 AC_SUBST(stage1_cflags)
3607
3608 # Enable --enable-checking in stage1 of the compiler.
3609 AC_ARG_ENABLE(stage1-checking,
3610 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3611                 [choose additional checking for stage1 of the compiler])],
3612 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3613 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3614   # For --disable-checking or implicit --enable-checking=release, avoid
3615   # setting --enable-checking=gc in the default stage1 checking for LTO
3616   # bootstraps.  See PR62077.
3617   case $BUILD_CONFIG in
3618     *lto*)
3619       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3620     *)
3621       stage1_checking=--enable-checking=yes,types;;
3622   esac
3623   if test "x$enable_checking" = x && \
3624      test -d ${srcdir}/gcc && \
3625      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3626     stage1_checking=--enable-checking=yes,types,extra
3627   fi
3628 else
3629   stage1_checking=--enable-checking=$enable_checking,types
3630 fi])
3631 AC_SUBST(stage1_checking)
3632
3633 # Enable -Werror in bootstrap stage2 and later.
3634 AC_ARG_ENABLE(werror,
3635 [AS_HELP_STRING([--enable-werror],
3636                 [enable -Werror in bootstrap stage2 and later])],
3637 [
3638 case ${enable_werror} in
3639   yes) stage2_werror_flag="--enable-werror-always" ;;
3640   *) stage2_werror_flag="" ;;
3641 esac
3642 ],
3643 [
3644 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3645   case $BUILD_CONFIG in
3646   bootstrap-debug)
3647       stage2_werror_flag="--enable-werror-always" ;;
3648   "")
3649       stage2_werror_flag="--enable-werror-always" ;;
3650   esac
3651 fi
3652 ])
3653
3654 AC_SUBST(stage2_werror_flag)
3655
3656 # Specify what files to not compare during bootstrap.
3657
3658 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3659 case "$target" in
3660   hppa*64*-*-hpux*) ;;
3661   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3662   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3663 esac
3664 AC_SUBST(compare_exclusions)
3665
3666 AC_CONFIG_FILES([Makefile],
3667   [sed "$extrasub_build" Makefile |
3668    sed "$extrasub_host" |
3669    sed "$extrasub_target" > mf$$
3670    mv -f mf$$ Makefile],
3671   [extrasub_build="$extrasub_build"
3672    extrasub_host="$extrasub_host"
3673    extrasub_target="$extrasub_target"])
3674 AC_OUTPUT