configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools c++tools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libhsail-rt \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo \
 167                 target-libphobos \
 168                 target-zlib"
 169
 170 # these tools are built using the target libraries, and are intended to
 171 # run only in the target environment
 172 #
 173 # note: any program that *uses* libraries that are in the "target_libraries"
 174 # list belongs in this list.
 175 #
 176 target_tools="target-rda"
 177
 178 ################################################################################
 179
 180 ## All tools belong in one of the four categories, and are assigned above
 181 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 182 ## is important because configure will choke if they ever get through.
 183 ## ${configdirs} is directories we build using the host tools.
 184 ## ${target_configdirs} is directories we build using the target tools.
 185 configdirs=`echo ${host_libs} ${host_tools}`
 186 target_configdirs=`echo ${target_libraries} ${target_tools}`
 187 build_configdirs=`echo ${build_libs} ${build_tools}`
 188
 189 m4_divert_text([PARSE_ARGS],
 190 [case $srcdir in
 191   *" "*)
 192 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 193     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 194 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 195     ;;
 196 esac
 197 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 198 ])
 199
 200 ################################################################################
 201
 202 srcname="gnu development package"
 203
 204 # This gets set non-empty for some net releases of packages.
 205 appdirs=""
 206
 207 # Define is_cross_compiler to save on calls to 'test'.
 208 is_cross_compiler=
 209 if test x"${host}" = x"${target}" ; then
 210   is_cross_compiler=no
 211 else
 212   is_cross_compiler=yes
 213 fi
 214
 215 # Find the build and target subdir names.
 216 GCC_TOPLEV_SUBDIRS
 217 # Be sure to cover against remnants of an in-tree build.
 218 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 219   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 220 Use a pristine source tree when building in a separate tree])
 221 fi
 222
 223 # Skipdirs are removed silently.
 224 skipdirs=
 225 # Noconfigdirs are removed loudly.
 226 noconfigdirs=""
 227
 228 use_gnu_ld=
 229 # Make sure we don't let GNU ld be added if we didn't want it.
 230 if test x$with_gnu_ld = xno ; then
 231   use_gnu_ld=no
 232   noconfigdirs="$noconfigdirs ld gold"
 233 fi
 234
 235 use_gnu_as=
 236 # Make sure we don't let GNU as be added if we didn't want it.
 237 if test x$with_gnu_as = xno ; then
 238   use_gnu_as=no
 239   noconfigdirs="$noconfigdirs gas"
 240 fi
 241
 242 use_included_zlib=
 243 AC_ARG_WITH(system-zlib,
 244 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 245 # Make sure we don't let ZLIB be added if we didn't want it.
 246 if test x$with_system_zlib = xyes ; then
 247   use_included_zlib=no
 248   noconfigdirs="$noconfigdirs zlib"
 249 fi
 250
 251 # some tools are so dependent upon X11 that if we're not building with X,
 252 # it's not even worth trying to configure, much less build, that tool.
 253
 254 case ${with_x} in
 255   yes | "") ;; # the default value for this tree is that X11 is available
 256   no)
 257     skipdirs="${skipdirs} tk itcl libgui"
 258     # We won't be able to build gdbtk without X.
 259     enable_gdbtk=no
 260     ;;
 261   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 262 esac
 263
 264 # Some are only suitable for cross toolchains.
 265 # Remove these if host=target.
 266 cross_only="target-libgloss target-newlib target-opcodes"
 267
 268 case $is_cross_compiler in
 269   no) skipdirs="${skipdirs} ${cross_only}" ;;
 270 esac
 271
 272 # If both --with-headers and --with-libs are specified, default to
 273 # --without-newlib.
 274 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 275    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 276   if test x"${with_newlib}" = x ; then
 277     with_newlib=no
 278   fi
 279 fi
 280
 281 # Recognize --with-newlib/--without-newlib.
 282 case ${with_newlib} in
 283   no) skipdirs="${skipdirs} target-newlib" ;;
 284   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 285 esac
 286
 287 AC_ARG_ENABLE(as-accelerator-for,
 288 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 289                 [build as offload target compiler.
 290                 Specify offload host triple by ARG])])
 291
 292 AC_ARG_ENABLE(offload-targets,
 293 [AS_HELP_STRING([--enable-offload-targets=LIST],
 294                 [enable offloading to devices from comma-separated LIST of
 295                 TARGET[=DIR]. Use optional path to find offload target compiler
 296                 during the build])],
 297 [
 298   if test x"$enable_offload_targets" = x; then
 299     AC_MSG_ERROR([no offload targets specified])
 300   fi
 301 ], [enable_offload_targets=])
 302
 303 AC_ARG_ENABLE(offload-defaulted,
 304 [AS_HELP_STRING([--enable-offload-defaulted]
 305                 [If enabled, configured but not installed offload compilers and
 306                 libgomp plugins are silently ignored.  Useful for distribution
 307                 compilers where those are in separate optional packages.])],
 308 [enable_offload_defaulted=$enableval],
 309 [enable_offload_defaulted=])
 310
 311 # Handle --enable-gold, --enable-ld.
 312 # --disable-gold [--enable-ld]
 313 #     Build only ld.  Default option.
 314 # --enable-gold [--enable-ld]
 315 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 316 #     as "ld.bfd" and "ld".
 317 # --enable-gold=default [--enable-ld]
 318 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 319 #     install ld as "ld.bfd".
 320 # --enable-gold[=default] --disable-ld
 321 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 322 # --enable-gold --enable-ld=default
 323 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 324 #     and ld.bfd).
 325 #     In other words, ld is default
 326 # --enable-gold=default --enable-ld=default
 327 #     Error.
 328
 329 default_ld=
 330 AC_ARG_ENABLE(gold,
 331 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 332                 [build gold @<:@ARG={default,yes,no}@:>@])],
 333 ENABLE_GOLD=$enableval,
 334 ENABLE_GOLD=no)
 335 case "${ENABLE_GOLD}" in
 336   yes|default)
 337     # Check for ELF target.
 338     is_elf=no
 339     case "${target}" in
 340       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 341       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 342       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 343       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 344         case "${target}" in
 345           *-*-linux*aout* | *-*-linux*oldld*)
 346             ;;
 347           *)
 348             is_elf=yes
 349             ;;
 350         esac
 351     esac
 352
 353     if test "$is_elf" = "yes"; then
 354       # Check for target supported by gold.
 355       case "${target}" in
 356         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 357         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 358           configdirs="$configdirs gold"
 359           if test x${ENABLE_GOLD} = xdefault; then
 360             default_ld=gold
 361           fi
 362           ENABLE_GOLD=yes
 363           ;;
 364       esac
 365     fi
 366     ;;
 367   no)
 368     ;;
 369   *)
 370     AC_MSG_ERROR([invalid --enable-gold argument])
 371     ;;
 372 esac
 373
 374 AC_ARG_ENABLE(ld,
 375 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 376                 [build ld @<:@ARG={default,yes,no}@:>@])],
 377 ENABLE_LD=$enableval,
 378 ENABLE_LD=yes)
 379
 380 case "${ENABLE_LD}" in
 381   default)
 382     if test x${default_ld} != x; then
 383       AC_MSG_ERROR([either gold or ld can be the default ld])
 384     fi
 385     ;;
 386   yes)
 387     ;;
 388   no)
 389     if test x${ENABLE_GOLD} != xyes; then
 390       AC_MSG_WARN([neither ld nor gold are enabled])
 391     fi
 392     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 393     ;;
 394   *)
 395     AC_MSG_ERROR([invalid --enable-ld argument])
 396     ;;
 397 esac
 398
 399 # PR gas/19109
 400 # Decide the default method for compressing debug sections.
 401 # Provide a configure time option to override our default.
 402 AC_ARG_ENABLE(compressed_debug_sections,
 403 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 404                 [Enable compressed debug sections for gas, gold or ld by
 405                  default])],
 406 [
 407   if test x"$enable_compressed_debug_sections" = xyes; then
 408     AC_MSG_ERROR([no program with compressed debug sections specified])
 409   fi
 410 ], [enable_compressed_debug_sections=])
 411
 412 # Configure extra directories which are host specific
 413
 414 case "${host}" in
 415   *-cygwin*)
 416     configdirs="$configdirs libtermcap" ;;
 417 esac
 418
 419 # A target can indicate whether a language isn't supported for some reason.
 420 # Only spaces may be used in this macro; not newlines or tabs.
 421 unsupported_languages=
 422
 423 # Remove more programs from consideration, based on the host or
 424 # target this usually means that a port of the program doesn't
 425 # exist yet.
 426
 427 case "${host}" in
 428   i[[3456789]]86-*-msdosdjgpp*)
 429     noconfigdirs="$noconfigdirs tcl tk itcl"
 430     ;;
 431 esac
 432
 433
 434 AC_ARG_ENABLE(libquadmath,
 435 AS_HELP_STRING([--disable-libquadmath],
 436   [do not build libquadmath directory]),
 437 ENABLE_LIBQUADMATH=$enableval,
 438 ENABLE_LIBQUADMATH=yes)
 439 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 440   noconfigdirs="$noconfigdirs target-libquadmath"
 441 fi
 442
 443
 444 AC_ARG_ENABLE(libquadmath-support,
 445 AS_HELP_STRING([--disable-libquadmath-support],
 446   [disable libquadmath support for Fortran]),
 447 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 448 ENABLE_LIBQUADMATH_SUPPORT=yes)
 449 enable_libquadmath_support=
 450 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 451   enable_libquadmath_support=no
 452 fi
 453
 454
 455 AC_ARG_ENABLE(libada,
 456 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 457 ENABLE_LIBADA=$enableval,
 458 ENABLE_LIBADA=yes)
 459 if test "${ENABLE_LIBADA}" != "yes" ; then
 460   noconfigdirs="$noconfigdirs gnattools"
 461 fi
 462
 463 AC_ARG_ENABLE(libssp,
 464 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 465 ENABLE_LIBSSP=$enableval,
 466 ENABLE_LIBSSP=yes)
 467
 468 AC_ARG_ENABLE(libstdcxx,
 469 AS_HELP_STRING([--disable-libstdcxx],
 470   [do not build libstdc++-v3 directory]),
 471 ENABLE_LIBSTDCXX=$enableval,
 472 ENABLE_LIBSTDCXX=default)
 473 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 474   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 475 fi]
 476
 477 # If this is accelerator compiler and its target is intelmic we enable
 478 # target liboffloadmic by default.  If this is compiler with offloading
 479 # for intelmic we enable host liboffloadmic by default.  Otherwise
 480 # liboffloadmic is disabled by default.
 481 AC_ARG_ENABLE([liboffloadmic],
 482 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 483                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 484 [case "$enableval" in
 485   no | host | target)
 486     enable_liboffloadmic=$enableval ;;
 487   *)
 488     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 489 esac],
 490 [if test x"$enable_as_accelerator_for" != x; then
 491   case "${target}" in
 492     *-intelmic-* | *-intelmicemul-*)
 493       enable_liboffloadmic=target
 494       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 495       ;;
 496     *)
 497       enable_liboffloadmic=no
 498       ;;
 499   esac
 500 else
 501   case "${enable_offload_targets}" in
 502     *-intelmic-* | *-intelmicemul-*)
 503       enable_liboffloadmic=host
 504       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 505       ;;
 506     *)
 507       enable_liboffloadmic=no
 508       ;;
 509     esac
 510 fi])
 511 AC_SUBST(extra_liboffloadmic_configure_flags)
 512
 513 # Enable libgomp by default on hosted POSIX systems, and a few others.
 514 if test x$enable_libgomp = x ; then
 515     case "${target}" in
 516     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 517         ;;
 518     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 519         ;;
 520     *-*-solaris2* | *-*-hpux11*)
 521         ;;
 522     *-*-darwin* | *-*-aix*)
 523         ;;
 524     nvptx*-*-* | amdgcn*-*-*)
 525         ;;
 526     *)
 527         noconfigdirs="$noconfigdirs target-libgomp"
 528         ;;
 529     esac
 530 fi
 531
 532 # Disable libatomic on unsupported systems.
 533 if test -d ${srcdir}/libatomic; then
 534     if test x$enable_libatomic = x; then
 535         AC_MSG_CHECKING([for libatomic support])
 536         if (srcdir=${srcdir}/libatomic; \
 537                 . ${srcdir}/configure.tgt; \
 538                 test -n "$UNSUPPORTED")
 539         then
 540             AC_MSG_RESULT([no])
 541             noconfigdirs="$noconfigdirs target-libatomic"
 542         else
 543             AC_MSG_RESULT([yes])
 544         fi
 545     fi
 546 fi
 547
 548 # Disable liboffloadmic on unsupported systems.
 549 if test -d ${srcdir}/liboffloadmic; then
 550     if test x$enable_liboffloadmic != xno; then
 551         AC_MSG_CHECKING([for liboffloadmic support])
 552         if (srcdir=${srcdir}/liboffloadmic; \
 553                 . ${srcdir}/configure.tgt; \
 554                 test -n "$UNSUPPORTED")
 555         then
 556             AC_MSG_RESULT([no])
 557             noconfigdirs="$noconfigdirs target-liboffloadmic"
 558         else
 559             AC_MSG_RESULT([yes])
 560         fi
 561     fi
 562 fi
 563
 564 # Disable libitm on unsupported systems.
 565 if test -d ${srcdir}/libitm; then
 566     if test x$enable_libitm = x; then
 567         AC_MSG_CHECKING([for libitm support])
 568         if (srcdir=${srcdir}/libitm; \
 569                 . ${srcdir}/configure.tgt; \
 570                 test -n "$UNSUPPORTED")
 571         then
 572             AC_MSG_RESULT([no])
 573             noconfigdirs="$noconfigdirs target-libitm"
 574         else
 575             AC_MSG_RESULT([yes])
 576         fi
 577     fi
 578 fi
 579
 580 # Disable libsanitizer on unsupported systems.
 581 if test -d ${srcdir}/libsanitizer; then
 582     if test x$enable_libsanitizer = x; then
 583         AC_MSG_CHECKING([for libsanitizer support])
 584         if (srcdir=${srcdir}/libsanitizer; \
 585                 . ${srcdir}/configure.tgt; \
 586                 test -n "$UNSUPPORTED")
 587         then
 588             AC_MSG_RESULT([no])
 589             noconfigdirs="$noconfigdirs target-libsanitizer"
 590         else
 591             AC_MSG_RESULT([yes])
 592         fi
 593     fi
 594 fi
 595
 596 # Disable libvtv on unsupported systems.
 597 if test -d ${srcdir}/libvtv; then
 598     if test x$enable_libvtv = x; then
 599         AC_MSG_CHECKING([for libvtv support])
 600         if (srcdir=${srcdir}/libvtv; \
 601                 . ${srcdir}/configure.tgt; \
 602                 test "$VTV_SUPPORTED" != "yes")
 603         then
 604             AC_MSG_RESULT([no])
 605             noconfigdirs="$noconfigdirs target-libvtv"
 606         else
 607             AC_MSG_RESULT([yes])
 608         fi
 609     fi
 610 fi
 611
 612
 613 # Disable libhsail-rt on unsupported systems.
 614 if test -d ${srcdir}/libhsail-rt; then
 615     if test x$enable_libhsail_rt = x; then
 616         AC_MSG_CHECKING([for libhsail-rt support])
 617         if (srcdir=${srcdir}/libhsail-rt; \
 618                 . ${srcdir}/configure.tgt; \
 619                 test -n "$UNSUPPORTED")
 620         then
 621             AC_MSG_RESULT([no])
 622             unsupported_languages="$unsupported_languages brig"
 623             # This implicitly disables also target-libhsail-rt as it won't
 624             # get added to the build without BRIG FE.
 625         else
 626             AC_MSG_RESULT([yes])
 627         fi
 628     fi
 629 fi
 630
 631
 632 # Disable libquadmath for some systems.
 633 case "${target}" in
 634   avr-*-*)
 635     noconfigdirs="$noconfigdirs target-libquadmath"
 636     ;;
 637   # libquadmath is unused on AIX and libquadmath build process use of
 638   # LD_LIBRARY_PATH can break AIX bootstrap.
 639   powerpc-*-aix* | rs6000-*-aix*)
 640     noconfigdirs="$noconfigdirs target-libquadmath"
 641     ;;
 642 esac
 643
 644 # Disable libssp for some systems.
 645 case "${target}" in
 646   avr-*-*)
 647     # No hosted I/O support.
 648     noconfigdirs="$noconfigdirs target-libssp"
 649     ;;
 650   bpf-*-*)
 651     noconfigdirs="$noconfigdirs target-libssp"
 652     ;;
 653   powerpc-*-aix* | rs6000-*-aix*)
 654     noconfigdirs="$noconfigdirs target-libssp"
 655     ;;
 656   pru-*-*)
 657     # No hosted I/O support.
 658     noconfigdirs="$noconfigdirs target-libssp"
 659     ;;
 660   rl78-*-*)
 661     # libssp uses a misaligned load to trigger a fault, but the RL78
 662     # doesn't fault for those - instead, it gives a build-time error
 663     # for explicit misaligned loads.
 664     noconfigdirs="$noconfigdirs target-libssp"
 665     ;;
 666   visium-*-*)
 667     # No hosted I/O support.
 668     noconfigdirs="$noconfigdirs target-libssp"
 669     ;;
 670 esac
 671
 672 # Disable libstdc++-v3 for some systems.
 673 # Allow user to override this if they pass --enable-libstdc++-v3
 674 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 675   case "${target}" in
 676     *-*-vxworks*)
 677       # VxWorks uses the Dinkumware C++ library.
 678       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 679       ;;
 680     amdgcn*-*-*)
 681       # Not ported/fails to build when using newlib.
 682       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 683       ;;
 684     arm*-wince-pe*)
 685       # the C++ libraries don't build on top of CE's C libraries
 686       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 687       ;;
 688     avr-*-*)
 689       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 690       ;;
 691     bpf-*-*)
 692       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 693       ;;
 694     ft32-*-*)
 695       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 696       ;;
 697   esac
 698 fi
 699
 700 # Disable C++ on systems where it is known to not work.
 701 # For testing, you can override this with --enable-languages=c++.
 702 case ,${enable_languages}, in
 703   *,c++,*)
 704     ;;
 705   *)
 706       case "${target}" in
 707         bpf-*-*)
 708           unsupported_languages="$unsupported_languages c++"
 709           ;;
 710       esac
 711       ;;
 712 esac
 713
 714 # Disable Objc on systems where it is known to not work.
 715 # For testing, you can override this with --enable-languages=objc.
 716 case ,${enable_languages}, in
 717   *,objc,*)
 718     ;;
 719   *)
 720       case "${target}" in
 721         bpf-*-*)
 722           unsupported_languages="$unsupported_languages objc"
 723           ;;
 724       esac
 725       ;;
 726 esac
 727
 728 # Disable D on systems where it is known to not work.
 729 # For testing, you can override this with --enable-languages=d.
 730 case ,${enable_languages}, in
 731   *,d,*)
 732     ;;
 733   *)
 734     case "${target}" in
 735       bpf-*-*)
 736         unsupported_languages="$unsupported_languages d"
 737         ;;
 738     esac
 739     ;;
 740 esac
 741
 742 # Disable libphobos on unsupported systems.
 743 # For testing, you can override this with --enable-libphobos.
 744 if test -d ${srcdir}/libphobos; then
 745     if test x$enable_libphobos = x; then
 746         AC_MSG_CHECKING([for libphobos support])
 747         if (srcdir=${srcdir}/libphobos; \
 748                 . ${srcdir}/configure.tgt; \
 749                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 750         then
 751             AC_MSG_RESULT([no])
 752             noconfigdirs="$noconfigdirs target-libphobos"
 753         else
 754             AC_MSG_RESULT([yes])
 755         fi
 756     fi
 757 fi
 758
 759 # Disable Fortran for some systems.
 760 case "${target}" in
 761   mmix-*-*)
 762     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 763     unsupported_languages="$unsupported_languages fortran"
 764     ;;
 765   bpf-*-*)
 766     unsupported_languages="$unsupported_languages fortran"
 767     ;;
 768 esac
 769
 770 # Disable libffi for some systems.
 771 case "${target}" in
 772   powerpc-*-darwin*)
 773     ;;
 774   i[[3456789]]86-*-darwin*)
 775     ;;
 776   x86_64-*-darwin[[912]]*)
 777     ;;
 778   *-*-darwin*)
 779     noconfigdirs="$noconfigdirs target-libffi"
 780     ;;
 781   *-*-netware*)
 782     noconfigdirs="$noconfigdirs target-libffi"
 783     ;;
 784   *-*-phoenix*)
 785     noconfigdirs="$noconfigdirs target-libffi"
 786     ;;
 787   *-*-rtems*)
 788     noconfigdirs="$noconfigdirs target-libffi"
 789     ;;
 790   *-*-tpf*)
 791     noconfigdirs="$noconfigdirs target-libffi"
 792     ;;
 793   *-*-uclinux*)
 794     noconfigdirs="$noconfigdirs target-libffi"
 795     ;;
 796   *-*-vxworks*)
 797     noconfigdirs="$noconfigdirs target-libffi"
 798     ;;
 799   aarch64*-*-freebsd*)
 800     noconfigdirs="$noconfigdirs target-libffi"
 801     ;;
 802   alpha*-*-*vms*)
 803     noconfigdirs="$noconfigdirs target-libffi"
 804     ;;
 805   arm*-*-freebsd*)
 806     noconfigdirs="$noconfigdirs target-libffi"
 807     ;;
 808   arm-wince-pe)
 809     noconfigdirs="$noconfigdirs target-libffi"
 810     ;;
 811   arm*-*-symbianelf*)
 812     noconfigdirs="$noconfigdirs target-libffi"
 813     ;;
 814   bpf-*-*)
 815     noconfigdirs="$noconfigdirs target-libffi"
 816     ;;
 817   cris-*-* | crisv32-*-*)
 818     case "${target}" in
 819       *-*-linux*)
 820         ;;
 821       *) # See PR46792 regarding target-libffi.
 822         noconfigdirs="$noconfigdirs target-libffi";;
 823     esac
 824     ;;
 825   hppa*64*-*-hpux*)
 826     noconfigdirs="$noconfigdirs target-libffi"
 827     ;;
 828   hppa*-hp-hpux11*)
 829     ;;
 830   hppa*-*-hpux*)
 831     noconfigdirs="$noconfigdirs target-libffi"
 832     ;;
 833   ia64*-*-*vms*)
 834     noconfigdirs="$noconfigdirs target-libffi"
 835     ;;
 836   i[[3456789]]86-w64-mingw*)
 837     noconfigdirs="$noconfigdirs target-libffi"
 838     ;;
 839   i[[3456789]]86-*-mingw*)
 840     noconfigdirs="$noconfigdirs target-libffi"
 841     ;;
 842   x86_64-*-mingw*)
 843     noconfigdirs="$noconfigdirs target-libffi"
 844     ;;
 845   mmix-*-*)
 846     noconfigdirs="$noconfigdirs target-libffi"
 847     ;;
 848   powerpc-*-aix*)
 849     ;;
 850   rs6000-*-aix*)
 851     ;;
 852   ft32-*-*)
 853     noconfigdirs="$noconfigdirs target-libffi"
 854     ;;
 855   *-*-lynxos*)
 856     noconfigdirs="$noconfigdirs target-libffi"
 857     ;;
 858 esac
 859
 860 # Disable the go frontend on systems where it is known to not work. Please keep
 861 # this in sync with contrib/config-list.mk.
 862 case "${target}" in
 863 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 864     unsupported_languages="$unsupported_languages go"
 865     ;;
 866 esac
 867
 868 # Only allow gdbserver on some systems.
 869 if test -d ${srcdir}/gdbserver; then
 870     if test x$enable_gdbserver = x; then
 871         AC_MSG_CHECKING([for gdbserver support])
 872         if (srcdir=${srcdir}/gdbserver; \
 873                 . ${srcdir}/configure.srv; \
 874                 test -n "$UNSUPPORTED")
 875         then
 876             AC_MSG_RESULT([no])
 877             noconfigdirs="$noconfigdirs gdbserver"
 878         else
 879             AC_MSG_RESULT([yes])
 880         fi
 881     fi
 882 fi
 883
 884 # Disable libgo for some systems where it is known to not work.
 885 # For testing, you can easily override this with --enable-libgo.
 886 if test x$enable_libgo = x; then
 887     case "${target}" in
 888     *-*-darwin*)
 889         # PR 46986
 890         noconfigdirs="$noconfigdirs target-libgo"
 891         ;;
 892     *-*-cygwin* | *-*-mingw*)
 893         noconfigdirs="$noconfigdirs target-libgo"
 894         ;;
 895     bpf-*-*)
 896         noconfigdirs="$noconfigdirs target-libgo"
 897         ;;
 898     esac
 899 fi
 900
 901 # Default libgloss CPU subdirectory.
 902 libgloss_dir="$target_cpu"
 903
 904 case "${target}" in
 905   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 906     libgloss_dir=wince
 907     ;;
 908   aarch64*-*-* )
 909     libgloss_dir=aarch64
 910     ;;
 911   arm*-*-*)
 912     libgloss_dir=arm
 913     ;;
 914   cris-*-* | crisv32-*-*)
 915     libgloss_dir=cris
 916     ;;
 917   hppa*-*-*)
 918     libgloss_dir=pa
 919     ;;
 920   i[[3456789]]86-*-*)
 921     libgloss_dir=i386
 922     ;;
 923   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 924     libgloss_dir=m68hc11
 925     ;;
 926   m68*-*-* | fido-*-*)
 927     libgloss_dir=m68k
 928     ;;
 929   mips*-*-*)
 930     libgloss_dir=mips
 931     ;;
 932   powerpc*-*-*)
 933     libgloss_dir=rs6000
 934     ;;
 935   pru-*-*)
 936     libgloss_dir=pru
 937     ;;
 938   sparc*-*-*)
 939     libgloss_dir=sparc
 940     ;;
 941 esac
 942
 943 # Disable newlib and libgloss for various target OSes.
 944 case "${target}" in
 945   alpha*-dec-osf*)
 946     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 947     ;;
 948   i[[3456789]]86-*-linux*)
 949     # This section makes it possible to build newlib natively on linux.
 950     # If we are using a cross compiler then don't configure newlib.
 951     if test x${is_cross_compiler} != xno ; then
 952       noconfigdirs="$noconfigdirs target-newlib"
 953     fi
 954     noconfigdirs="$noconfigdirs target-libgloss"
 955     # If we are not using a cross compiler, do configure newlib.
 956     # Note however, that newlib will only be configured in this situation
 957     # if the --with-newlib option has been given, because otherwise
 958     # 'target-newlib' will appear in skipdirs.
 959     ;;
 960   i[[3456789]]86-*-rdos*)
 961     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 962     ;;
 963   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 964     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 965     ;;
 966   sparc-*-sunos4*)
 967     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 968     ;;
 969   bpf-*-*)
 970     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 971     ;;
 972   *-*-aix*)
 973     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 974     ;;
 975   *-*-beos*)
 976     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 977     ;;
 978   *-*-chorusos)
 979     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 980     ;;
 981   *-*-dragonfly*)
 982     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 983     ;;
 984   *-*-freebsd*)
 985     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 986     ;;
 987   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 988     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 989     ;;
 990   *-*-lynxos*)
 991     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 992     ;;
 993   *-*-mingw*)
 994     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 995     ;;
 996   *-*-netbsd*)
 997     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 998     ;;
 999   *-*-netware*)
1000     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1001     ;;
1002   *-*-tpf*)
1003     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1004     ;;
1005   *-*-uclinux*)
1006     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1007     ;;
1008   *-*-vxworks*)
1009     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1010     ;;
1011 esac
1012
1013 case "${target}" in
1014   *-*-chorusos)
1015     ;;
1016   aarch64-*-darwin*)
1017     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1018     noconfigdirs="$noconfigdirs sim target-rda"
1019     ;;
1020   amdgcn*-*-*)
1021     ;;
1022   arm-*-darwin*)
1023     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1024     noconfigdirs="$noconfigdirs sim target-rda"
1025     ;;
1026   powerpc-*-darwin*)
1027     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1028     noconfigdirs="$noconfigdirs sim target-rda"
1029     ;;
1030   i[[3456789]]86-*-darwin*)
1031     noconfigdirs="$noconfigdirs ld gprof"
1032     noconfigdirs="$noconfigdirs sim target-rda"
1033     ;;
1034   x86_64-*-darwin[[912]]*)
1035     noconfigdirs="$noconfigdirs ld gas gprof"
1036     noconfigdirs="$noconfigdirs sim target-rda"
1037     ;;
1038   *-*-darwin*)
1039     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1040     noconfigdirs="$noconfigdirs sim target-rda"
1041     ;;
1042   *-*-dragonfly*)
1043     ;;
1044   *-*-freebsd*)
1045     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
1046         && ! test -d ${srcdir}/gmp \
1047         && test -f /usr/local/include/gmp.h; then
1048       with_gmp=/usr/local
1049     fi
1050     ;;
1051   *-*-kaos*)
1052     # Remove unsupported stuff on all kaOS configurations.
1053     noconfigdirs="$noconfigdirs target-libgloss"
1054     ;;
1055   *-*-netbsd*)
1056     ;;
1057   *-*-netware*)
1058     ;;
1059   *-*-phoenix*)
1060     noconfigdirs="$noconfigdirs target-libgloss"
1061     ;;
1062   *-*-rtems*)
1063     noconfigdirs="$noconfigdirs target-libgloss"
1064     ;;
1065     # The tpf target doesn't support gdb yet.
1066   *-*-tpf*)
1067     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1068     ;;
1069   *-*-uclinux*)
1070     noconfigdirs="$noconfigdirs target-rda"
1071     ;;
1072   *-*-vxworks*)
1073     ;;
1074   alpha*-dec-osf*)
1075     # ld works, but does not support shared libraries.
1076     # gas doesn't generate exception information.
1077     noconfigdirs="$noconfigdirs gas ld"
1078     ;;
1079   alpha*-*-*vms*)
1080     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1081     ;;
1082   alpha*-*-*)
1083     # newlib is not 64 bit ready
1084     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1085     ;;
1086   bpf-*-*)
1087     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1088     ;;
1089   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1090     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1091     ;;
1092   arc*-*-*)
1093     noconfigdirs="$noconfigdirs sim"
1094     ;;
1095   arm-*-pe*)
1096     noconfigdirs="$noconfigdirs target-libgloss"
1097     ;;
1098   arm-*-riscix*)
1099     noconfigdirs="$noconfigdirs ld target-libgloss"
1100     ;;
1101   avr-*-*)
1102     if test x${with_avrlibc} != xno; then
1103       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1104     fi
1105     ;;
1106   c4x-*-* | tic4x-*-*)
1107     noconfigdirs="$noconfigdirs target-libgloss"
1108     ;;
1109   tic54x-*-*)
1110     noconfigdirs="$noconfigdirs target-libgloss gdb"
1111     ;;
1112   d10v-*-*)
1113     noconfigdirs="$noconfigdirs target-libgloss"
1114     ;;
1115   d30v-*-*)
1116     noconfigdirs="$noconfigdirs gdb"
1117     ;;
1118   fr30-*-elf*)
1119     noconfigdirs="$noconfigdirs gdb"
1120     ;;
1121   ft32-*-*)
1122     noconfigdirs="$noconfigdirs target-rda gprof"
1123     ;;
1124   moxie-*-*)
1125     noconfigdirs="$noconfigdirs"
1126     ;;
1127   h8300*-*-*)
1128     noconfigdirs="$noconfigdirs target-libgloss"
1129     ;;
1130   h8500-*-*)
1131     noconfigdirs="$noconfigdirs target-libgloss"
1132     ;;
1133   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1134     ;;
1135   hppa*64*-*-hpux*)
1136     noconfigdirs="$noconfigdirs gdb"
1137     ;;
1138   hppa*-*-hpux11*)
1139     noconfigdirs="$noconfigdirs gdb ld"
1140     ;;
1141   hppa*64*-*-linux*)
1142     ;;
1143   hppa*-*-linux*)
1144     ;;
1145   hppa*-*-*elf* | \
1146   hppa*-*-lites* | \
1147   hppa*-*-openbsd* | \
1148   hppa*64*-*-*)
1149     ;;
1150   hppa*-*-pro*)
1151     ;;
1152   hppa*-*-*)
1153     noconfigdirs="$noconfigdirs ld"
1154     ;;
1155   i960-*-*)
1156     noconfigdirs="$noconfigdirs gdb"
1157     ;;
1158   ia64*-*-elf*)
1159     # No gdb support yet.
1160     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1161     ;;
1162   ia64*-**-hpux*)
1163     # No ld support yet.
1164     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1165     ;;
1166   ia64*-*-*vms*)
1167     # No ld support yet.
1168     noconfigdirs="$noconfigdirs libgui itcl ld"
1169     ;;
1170   i[[3456789]]86-w64-mingw*)
1171     ;;
1172   i[[3456789]]86-*-mingw*)
1173     target_configdirs="$target_configdirs target-winsup"
1174     ;;
1175   *-*-cygwin*)
1176     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1177     noconfigdirs="$noconfigdirs target-libgloss"
1178     # always build newlib if winsup directory is present.
1179     if test -d "$srcdir/winsup/cygwin"; then
1180       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1181     elif test -d "$srcdir/newlib"; then
1182       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1183     fi
1184     ;;
1185   i[[3456789]]86-*-pe)
1186     noconfigdirs="$noconfigdirs target-libgloss"
1187     ;;
1188   i[[3456789]]86-*-sco3.2v5*)
1189     # The linker does not yet know about weak symbols in COFF,
1190     # and is not configured to handle mixed ELF and COFF.
1191     noconfigdirs="$noconfigdirs ld target-libgloss"
1192     ;;
1193   i[[3456789]]86-*-sco*)
1194     noconfigdirs="$noconfigdirs gprof target-libgloss"
1195     ;;
1196   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1197     noconfigdirs="$noconfigdirs target-libgloss"
1198     ;;
1199   i[[3456789]]86-*-sysv4*)
1200     noconfigdirs="$noconfigdirs target-libgloss"
1201     ;;
1202   i[[3456789]]86-*-beos*)
1203     noconfigdirs="$noconfigdirs gdb"
1204     ;;
1205   i[[3456789]]86-*-rdos*)
1206     noconfigdirs="$noconfigdirs gdb"
1207     ;;
1208   mmix-*-*)
1209     noconfigdirs="$noconfigdirs gdb"
1210     ;;
1211   mt-*-*)
1212     noconfigdirs="$noconfigdirs sim"
1213     ;;
1214   nfp-*-*)
1215     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1216     noconfigdirs="$noconfigdirs $target_libraries"
1217     ;;
1218   pdp11-*-*)
1219     noconfigdirs="$noconfigdirs gdb gprof"
1220     ;;
1221   powerpc-*-aix*)
1222     # copied from rs6000-*-* entry
1223     noconfigdirs="$noconfigdirs gprof"
1224     ;;
1225   powerpc*-*-winnt* | powerpc*-*-pe*)
1226     target_configdirs="$target_configdirs target-winsup"
1227     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1228     # always build newlib.
1229     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1230     ;;
1231     # This is temporary until we can link against shared libraries
1232   powerpcle-*-solaris*)
1233     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1234     ;;
1235   powerpc-*-beos*)
1236     noconfigdirs="$noconfigdirs gdb"
1237     ;;
1238   rs6000-*-lynxos*)
1239     noconfigdirs="$noconfigdirs gprof"
1240     ;;
1241   rs6000-*-aix*)
1242     noconfigdirs="$noconfigdirs gprof"
1243     ;;
1244   rs6000-*-*)
1245     noconfigdirs="$noconfigdirs gprof"
1246     ;;
1247   m68k-apollo-*)
1248     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1249     ;;
1250   microblaze*)
1251     noconfigdirs="$noconfigdirs gprof"
1252     ;;
1253   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1254     if test x$with_newlib = xyes; then
1255       noconfigdirs="$noconfigdirs gprof"
1256     fi
1257     ;;
1258   mips*-*-irix5*)
1259     noconfigdirs="$noconfigdirs gprof target-libgloss"
1260     ;;
1261   mips*-*-irix6*)
1262     noconfigdirs="$noconfigdirs gprof target-libgloss"
1263     ;;
1264   mips*-*-bsd*)
1265     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1266     ;;
1267   mips*-*-linux*)
1268     ;;
1269   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1270   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1271     noconfigdirs="$noconfigdirs ld gas gprof"
1272     ;;
1273   mips*-*-*)
1274     noconfigdirs="$noconfigdirs gprof"
1275     ;;
1276   nvptx*-*-*)
1277     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1278     ;;
1279   sh-*-*)
1280     case "${target}" in
1281       sh*-*-elf)
1282          ;;
1283       *)
1284          noconfigdirs="$noconfigdirs target-libgloss" ;;
1285     esac
1286     ;;
1287   sparc-*-sunos4*)
1288     if test x${is_cross_compiler} = xno ; then
1289            use_gnu_ld=no
1290     fi
1291     ;;
1292   tic6x-*-*)
1293     noconfigdirs="$noconfigdirs sim"
1294     ;;
1295   tilepro*-*-* | tilegx*-*-*)
1296     noconfigdirs="$noconfigdirs sim"
1297     ;;
1298   v810-*-*)
1299     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1300     ;;
1301   vax-*-*)
1302     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1303     ;;
1304   wasm32-*-*)
1305     noconfigdirs="$noconfigdirs ld"
1306     ;;
1307 esac
1308
1309 # If we aren't building newlib, then don't build libgloss, since libgloss
1310 # depends upon some newlib header files.
1311 case "${noconfigdirs}" in
1312   *target-libgloss*) ;;
1313   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1314 esac
1315
1316 # Work in distributions that contain no compiler tools, like Autoconf.
1317 host_makefile_frag=/dev/null
1318 if test -d ${srcdir}/config ; then
1319 case "${host}" in
1320   i[[3456789]]86-*-msdosdjgpp*)
1321     host_makefile_frag="config/mh-djgpp"
1322     ;;
1323   *-cygwin*)
1324     ACX_CHECK_CYGWIN_CAT_WORKS
1325     host_makefile_frag="config/mh-cygwin"
1326     ;;
1327   *-mingw*)
1328     host_makefile_frag="config/mh-mingw"
1329     ;;
1330   alpha*-linux*)
1331     host_makefile_frag="config/mh-alpha-linux"
1332     ;;
1333   hppa*-hp-hpux10*)
1334     host_makefile_frag="config/mh-pa-hpux10"
1335     ;;
1336   hppa*-hp-hpux*)
1337     host_makefile_frag="config/mh-pa"
1338     ;;
1339   hppa*-*)
1340     host_makefile_frag="config/mh-pa"
1341     ;;
1342   *-*-darwin*)
1343     host_makefile_frag="config/mh-darwin"
1344     ;;
1345   powerpc-*-aix*)
1346     host_makefile_frag="config/mh-ppc-aix"
1347     ;;
1348   rs6000-*-aix*)
1349     host_makefile_frag="config/mh-ppc-aix"
1350     ;;
1351 esac
1352 fi
1353
1354 if test "${build}" != "${host}" ; then
1355   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1356   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1357   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1358   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1359   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1360   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1361   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1362   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1363   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1364   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1365   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1366   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1367   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1368 else
1369   AR_FOR_BUILD="\$(AR)"
1370   AS_FOR_BUILD="\$(AS)"
1371   CC_FOR_BUILD="\$(CC)"
1372   CXX_FOR_BUILD="\$(CXX)"
1373   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1374   GOC_FOR_BUILD="\$(GOC)"
1375   GDC_FOR_BUILD="\$(GDC)"
1376   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1377   LD_FOR_BUILD="\$(LD)"
1378   NM_FOR_BUILD="\$(NM)"
1379   RANLIB_FOR_BUILD="\$(RANLIB)"
1380   WINDRES_FOR_BUILD="\$(WINDRES)"
1381   WINDMC_FOR_BUILD="\$(WINDMC)"
1382 fi
1383
1384 AC_PROG_CC
1385 AC_PROG_CXX
1386
1387 # We must set the default linker to the linker used by gcc for the correct
1388 # operation of libtool.  If LD is not defined and we are using gcc, try to
1389 # set the LD default to the ld used by gcc.
1390 if test -z "$LD"; then
1391   if test "$GCC" = yes; then
1392     case $build in
1393     *-*-mingw*)
1394       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1395     *)
1396       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1397     esac
1398     case $gcc_prog_ld in
1399     # Accept absolute paths.
1400     [[\\/]* | [A-Za-z]:[\\/]*)]
1401       LD="$gcc_prog_ld" ;;
1402     esac
1403   fi
1404 fi
1405
1406 # Check whether -static-libstdc++ -static-libgcc is supported.
1407 have_static_libs=no
1408 if test "$GCC" = yes; then
1409   saved_LDFLAGS="$LDFLAGS"
1410
1411   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1412   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1413   AC_LANG_PUSH(C++)
1414   AC_LINK_IFELSE([AC_LANG_SOURCE([
1415 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1416 #error -static-libstdc++ not implemented
1417 #endif
1418 int main() {}])],
1419     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1420     [AC_MSG_RESULT([no])])
1421   AC_LANG_POP(C++)
1422
1423   LDFLAGS="$saved_LDFLAGS"
1424 fi
1425
1426 ACX_PROG_GNAT
1427 ACX_PROG_CMP_IGNORE_INITIAL
1428
1429 AC_ARG_ENABLE([bootstrap],
1430 [AS_HELP_STRING([--enable-bootstrap],
1431                 [enable bootstrapping @<:@yes if native build@:>@])],,
1432 enable_bootstrap=default)
1433
1434 # Issue errors and warnings for invalid/strange bootstrap combinations.
1435 if test -r $srcdir/gcc/configure; then
1436   have_compiler=yes
1437 else
1438   have_compiler=no
1439 fi
1440
1441 case "$have_compiler:$host:$target:$enable_bootstrap" in
1442   *:*:*:no) ;;
1443
1444   # Default behavior.  Enable bootstrap if we have a compiler
1445   # and we are in a native configuration.
1446   yes:$build:$build:default)
1447     enable_bootstrap=yes ;;
1448
1449   *:*:*:default)
1450     enable_bootstrap=no ;;
1451
1452   # We have a compiler and we are in a native configuration, bootstrap is ok
1453   yes:$build:$build:yes)
1454     ;;
1455
1456   # Other configurations, but we have a compiler.  Assume the user knows
1457   # what he's doing.
1458   yes:*:*:yes)
1459     AC_MSG_WARN([trying to bootstrap a cross compiler])
1460     ;;
1461
1462   # No compiler: if they passed --enable-bootstrap explicitly, fail
1463   no:*:*:yes)
1464     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1465
1466   # Fail if wrong command line
1467   *)
1468     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1469     ;;
1470 esac
1471
1472 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1473 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1474 # require C++11 (or higher).
1475 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1476   CXX="$CXX -std=c++11"
1477 elif test "$have_compiler" = yes; then
1478   AX_CXX_COMPILE_STDCXX(11)
1479
1480   if test "${build}" != "${host}"; then
1481     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1482   fi
1483 fi
1484
1485 # Used for setting $lt_cv_objdir
1486 _LT_CHECK_OBJDIR
1487
1488 # Check for GMP, MPFR and MPC
1489 gmplibs="-lmpc -lmpfr -lgmp"
1490 gmpinc=
1491 have_gmp=no
1492
1493 # Specify a location for mpc
1494 # check for this first so it ends up on the link line before mpfr.
1495 AC_ARG_WITH(mpc,
1496 [AS_HELP_STRING([--with-mpc=PATH],
1497                 [specify prefix directory for installed MPC package.
1498                  Equivalent to --with-mpc-include=PATH/include
1499                  plus --with-mpc-lib=PATH/lib])])
1500 AC_ARG_WITH(mpc-include,
1501 [AS_HELP_STRING([--with-mpc-include=PATH],
1502                 [specify directory for installed MPC include files])])
1503 AC_ARG_WITH(mpc-lib,
1504 [AS_HELP_STRING([--with-mpc-lib=PATH],
1505                 [specify directory for the installed MPC library])])
1506
1507 if test "x$with_mpc" != x; then
1508   gmplibs="-L$with_mpc/lib $gmplibs"
1509   gmpinc="-I$with_mpc/include $gmpinc"
1510 fi
1511 if test "x$with_mpc_include" != x; then
1512   gmpinc="-I$with_mpc_include $gmpinc"
1513 fi
1514 if test "x$with_mpc_lib" != x; then
1515   gmplibs="-L$with_mpc_lib $gmplibs"
1516 fi
1517 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1518   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1519   gmpinc='-I$$s/mpc/src '"$gmpinc"
1520   # Do not test the mpc version.  Assume that it is sufficient, since
1521   # it is in the source tree, and the library has not been built yet
1522   # but it would be included on the link line in the version check below
1523   # hence making the test fail.
1524   have_gmp=yes
1525 fi
1526
1527 # Specify a location for mpfr
1528 # check for this first so it ends up on the link line before gmp.
1529 AC_ARG_WITH(mpfr-dir,
1530 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1531 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1532 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1533
1534 AC_ARG_WITH(mpfr,
1535 [AS_HELP_STRING([--with-mpfr=PATH],
1536                 [specify prefix directory for installed MPFR package.
1537                  Equivalent to --with-mpfr-include=PATH/include
1538                  plus --with-mpfr-lib=PATH/lib])])
1539 AC_ARG_WITH(mpfr-include,
1540 [AS_HELP_STRING([--with-mpfr-include=PATH],
1541                 [specify directory for installed MPFR include files])])
1542 AC_ARG_WITH(mpfr-lib,
1543 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1544                 [specify directory for the installed MPFR library])])
1545
1546 if test "x$with_mpfr" != x; then
1547   gmplibs="-L$with_mpfr/lib $gmplibs"
1548   gmpinc="-I$with_mpfr/include $gmpinc"
1549 fi
1550 if test "x$with_mpfr_include" != x; then
1551   gmpinc="-I$with_mpfr_include $gmpinc"
1552 fi
1553 if test "x$with_mpfr_lib" != x; then
1554   gmplibs="-L$with_mpfr_lib $gmplibs"
1555 fi
1556 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1557   # MPFR v3.1.0 moved the sources into a src sub-directory.
1558   if ! test -d ${srcdir}/mpfr/src; then
1559     AC_MSG_ERROR([dnl
1560 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1561   fi
1562   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1563   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1564   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1565   # Do not test the mpfr version.  Assume that it is sufficient, since
1566   # it is in the source tree, and the library has not been built yet
1567   # but it would be included on the link line in the version check below
1568   # hence making the test fail.
1569   have_gmp=yes
1570 fi
1571
1572 # Specify a location for gmp
1573 AC_ARG_WITH(gmp-dir,
1574 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1575 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1576 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1577
1578 AC_ARG_WITH(gmp,
1579 [AS_HELP_STRING([--with-gmp=PATH],
1580                 [specify prefix directory for the installed GMP package.
1581                  Equivalent to --with-gmp-include=PATH/include
1582                  plus --with-gmp-lib=PATH/lib])])
1583 AC_ARG_WITH(gmp-include,
1584 [AS_HELP_STRING([--with-gmp-include=PATH],
1585                 [specify directory for installed GMP include files])])
1586 AC_ARG_WITH(gmp-lib,
1587 [AS_HELP_STRING([--with-gmp-lib=PATH],
1588                 [specify directory for the installed GMP library])])
1589
1590
1591 if test "x$with_gmp" != x; then
1592   gmplibs="-L$with_gmp/lib $gmplibs"
1593   gmpinc="-I$with_gmp/include $gmpinc"
1594 fi
1595 if test "x$with_gmp_include" != x; then
1596   gmpinc="-I$with_gmp_include $gmpinc"
1597 fi
1598 if test "x$with_gmp_lib" != x; then
1599   gmplibs="-L$with_gmp_lib $gmplibs"
1600 fi
1601 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1602   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1603   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1604   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1605   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1606   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1607   # Do not test the gmp version.  Assume that it is sufficient, since
1608   # it is in the source tree, and the library has not been built yet
1609   # but it would be included on the link line in the version check below
1610   # hence making the test fail.
1611   have_gmp=yes
1612 fi
1613
1614 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1615   have_gmp=yes
1616   saved_CFLAGS="$CFLAGS"
1617   CFLAGS="$CFLAGS $gmpinc"
1618   # Check for the recommended and required versions of GMP.
1619   AC_MSG_CHECKING([for the correct version of gmp.h])
1620   AC_TRY_COMPILE([#include "gmp.h"],[
1621   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1622   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1623   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1624   choke me
1625   #endif
1626   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1627   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1628   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1629   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1630   choke me
1631   #endif
1632   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1633    [AC_MSG_RESULT([no]); have_gmp=no])
1634
1635   # If we have GMP, check the MPFR version.
1636   if test x"$have_gmp" = xyes; then
1637     # Check for the recommended and required versions of MPFR.
1638     AC_MSG_CHECKING([for the correct version of mpfr.h])
1639     AC_TRY_COMPILE([#include <gmp.h>
1640     #include <mpfr.h>],[
1641     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1642     choke me
1643     #endif
1644     ], [AC_TRY_COMPILE([#include <gmp.h>
1645     #include <mpfr.h>],[
1646     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1647     choke me
1648     #endif
1649     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1650      [AC_MSG_RESULT([no]); have_gmp=no])
1651   fi
1652
1653   # Check for the MPC header version.
1654   if test x"$have_gmp" = xyes ; then
1655     # Check for the recommended and required versions of MPC.
1656     AC_MSG_CHECKING([for the correct version of mpc.h])
1657     AC_TRY_COMPILE([#include <mpc.h>],[
1658     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1659     choke me
1660     #endif
1661     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1662     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1663     choke me
1664     #endif
1665     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1666      [AC_MSG_RESULT([no]); have_gmp=no])
1667   fi
1668
1669   # Now check the MPFR library.
1670   if test x"$have_gmp" = xyes; then
1671     saved_LIBS="$LIBS"
1672     LIBS="$LIBS $gmplibs"
1673     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1674     AC_TRY_LINK([#include <mpc.h>],[
1675     mpfr_t n;
1676     mpfr_t x;
1677     mpc_t c;
1678     int t;
1679     mpfr_init (n);
1680     mpfr_init (x);
1681     mpfr_atan2 (n, n, x, MPFR_RNDN);
1682     mpfr_erfc (n, x, MPFR_RNDN);
1683     mpfr_subnormalize (x, t, MPFR_RNDN);
1684     mpfr_clear(n);
1685     mpfr_clear(x);
1686     mpc_init2 (c, 53);
1687     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1688     mpc_cosh (c, c, MPC_RNDNN);
1689     mpc_pow (c, c, c, MPC_RNDNN);
1690     mpc_acosh (c, c, MPC_RNDNN);
1691     mpc_clear (c);
1692     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1693     LIBS="$saved_LIBS"
1694   fi
1695
1696   CFLAGS="$saved_CFLAGS"
1697
1698 # The library versions listed in the error message below should match
1699 # the HARD-minimums enforced above.
1700   if test x$have_gmp != xyes; then
1701     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1702 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1703 their locations.  Source code for these libraries can be found at
1704 their respective hosting sites as well as at
1705 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1706 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1707 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1708 make sure that you have installed both the libraries and the header
1709 files.  They may be located in separate packages.])
1710   fi
1711 fi
1712
1713 # Flags needed for both GMP, MPFR and/or MPC.
1714 AC_SUBST(gmplibs)
1715 AC_SUBST(gmpinc)
1716 AC_SUBST(extra_mpfr_configure_flags)
1717 AC_SUBST(extra_mpc_gmp_configure_flags)
1718 AC_SUBST(extra_mpc_mpfr_configure_flags)
1719 AC_SUBST(extra_isl_gmp_configure_flags)
1720
1721 # Libraries to use for stage1 or when not bootstrapping.
1722 AC_ARG_WITH(stage1-libs,
1723 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1724 [if test "$withval" = "no" -o "$withval" = "yes"; then
1725    stage1_libs=
1726  else
1727    stage1_libs=$withval
1728  fi],
1729 [stage1_libs=])
1730 AC_SUBST(stage1_libs)
1731
1732 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1733 # default is yes if gcc is being built; no otherwise.  The reason for
1734 # this default is that gdb is sometimes linked against GNU Source
1735 # Highlight, which is a shared library that uses C++ exceptions.  In
1736 # this case, -static-libstdc++ will cause crashes.
1737 AC_ARG_WITH(static-standard-libraries,
1738 [AS_HELP_STRING([--with-static-standard-libraries],
1739                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1740 [], [with_static_standard_libraries=auto])
1741 if test "$with_static_standard_libraries" = auto; then
1742   with_static_standard_libraries=$have_compiler
1743 fi
1744
1745 # Linker flags to use for stage1 or when not bootstrapping.
1746 AC_ARG_WITH(stage1-ldflags,
1747 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1748 [if test "$withval" = "no" -o "$withval" = "yes"; then
1749    stage1_ldflags=
1750  else
1751    stage1_ldflags=$withval
1752  fi],
1753 [stage1_ldflags=
1754  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1755  # if supported.  But if the user explicitly specified the libraries to use,
1756  # trust that they are doing what they want.
1757  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1758      -a "$have_static_libs" = yes; then
1759    stage1_ldflags="-static-libstdc++ -static-libgcc"
1760  fi])
1761 AC_SUBST(stage1_ldflags)
1762
1763 # Libraries to use for stage2 and later builds.
1764 AC_ARG_WITH(boot-libs,
1765 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1766 [if test "$withval" = "no" -o "$withval" = "yes"; then
1767    poststage1_libs=
1768  else
1769    poststage1_libs=$withval
1770  fi],
1771 [poststage1_libs=])
1772 AC_SUBST(poststage1_libs)
1773
1774 # Linker flags to use for stage2 and later builds.
1775 AC_ARG_WITH(boot-ldflags,
1776 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1777                 [linker flags for stage2 and later])],
1778 [if test "$withval" = "no" -o "$withval" = "yes"; then
1779    poststage1_ldflags=
1780  else
1781    poststage1_ldflags=$withval
1782  fi],
1783 [poststage1_ldflags=
1784  # In stages 2 and 3, default to linking libstdc++ and libgcc
1785  # statically.  But if the user explicitly specified the libraries to
1786  # use, trust that they are doing what they want.
1787  if test "$poststage1_libs" = ""; then
1788    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1789  fi])
1790 AC_SUBST(poststage1_ldflags)
1791
1792 # GCC GRAPHITE dependency isl.
1793 # Basic setup is inlined here, actual checks are in config/isl.m4
1794
1795 AC_ARG_WITH(isl,
1796   [AS_HELP_STRING(
1797    [--with-isl=PATH],
1798    [Specify prefix directory for the installed isl package.
1799     Equivalent to --with-isl-include=PATH/include
1800     plus --with-isl-lib=PATH/lib])])
1801
1802 # Treat --without-isl as a request to disable
1803 # GRAPHITE support and skip all following checks.
1804 if test "x$with_isl" != "xno"; then
1805   # Check for isl
1806   dnl Provide configure switches and initialize islinc & isllibs
1807   dnl with user input.
1808   ISL_INIT_FLAGS
1809   dnl The versions of isl that work for Graphite
1810   ISL_CHECK_VERSION()
1811   dnl Only execute fail-action, if isl has been requested.
1812   ISL_IF_FAILED([
1813     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1814 fi
1815
1816 # If the isl check failed, disable builds of in-tree variant of isl
1817 if test "x$with_isl" = xno ||
1818    test "x$gcc_cv_isl" = xno; then
1819   noconfigdirs="$noconfigdirs isl"
1820   islinc=
1821 fi
1822
1823 AC_SUBST(isllibs)
1824 AC_SUBST(islinc)
1825
1826 # Check for LTO support.
1827 AC_ARG_ENABLE(lto,
1828 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1829 enable_lto=$enableval,
1830 enable_lto=yes; default_enable_lto=yes)
1831
1832 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1833   build_lto_plugin=yes
1834 ],[if test x"$default_enable_lto" = x"yes" ; then
1835     case $target in
1836       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1837       # On other non-ELF platforms, LTO has yet to be validated.
1838       *) enable_lto=no ;;
1839     esac
1840   else
1841   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1842   # It would also be nice to check the binutils support, but we don't
1843   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1844   # warn during gcc/ subconfigure; unless you're bootstrapping with
1845   # -flto it won't be needed until after installation anyway.
1846     case $target in
1847       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1848       *) if test x"$enable_lto" = x"yes"; then
1849         AC_MSG_ERROR([LTO support is not enabled for this target.])
1850         fi
1851       ;;
1852     esac
1853   fi
1854   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1855   # Build it unless LTO was explicitly disabled.
1856   case $target in
1857     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1858     *) ;;
1859   esac
1860 ])
1861
1862 AC_ARG_ENABLE(linker-plugin-configure-flags,
1863   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1864     [additional flags for configuring linker plugins @<:@none@:>@])],
1865   extra_linker_plugin_configure_flags=$enableval,
1866   extra_linker_plugin_configure_flags=)
1867 AC_SUBST(extra_linker_plugin_configure_flags)
1868 AC_ARG_ENABLE(linker-plugin-flags,
1869   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1870     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1871   extra_linker_plugin_flags=$enableval,
1872   extra_linker_plugin_flags=)
1873 AC_SUBST(extra_linker_plugin_flags)
1874
1875 # Enable --enable-host-shared.
1876 # Checked early to determine whether jit is an 'all' language
1877 AC_ARG_ENABLE(host-shared,
1878 [AS_HELP_STRING([--enable-host-shared],
1879                 [build host code as shared libraries])],
1880 [host_shared=$enableval], [host_shared=no])
1881 AC_SUBST(host_shared)
1882
1883 # By default, C and C++ are the only stage 1 languages.
1884 stage1_languages=,c,
1885
1886 # Target libraries that we bootstrap.
1887 bootstrap_target_libs=,target-libgcc,
1888
1889 # Figure out what language subdirectories are present.
1890 # Look if the user specified --enable-languages="..."; if not, use
1891 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1892 # go away some day.
1893 # NB:  embedded tabs in this IF block -- do not untabify
1894 if test -d ${srcdir}/gcc; then
1895   if test x"${enable_languages+set}" != xset; then
1896     if test x"${LANGUAGES+set}" = xset; then
1897       enable_languages="${LANGUAGES}"
1898         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1899     else
1900       enable_languages=default
1901     fi
1902   else
1903     if test x"${enable_languages}" = x ||
1904        test x"${enable_languages}" = xyes;
1905        then
1906       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1907       exit 1
1908     fi
1909   fi
1910   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1911
1912   # 'f95' is the old name for the 'fortran' language. We issue a warning
1913   # and make the substitution.
1914   case ,${enable_languages}, in
1915     *,f95,*)
1916       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1917       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1918       ;;
1919   esac
1920
1921   # If bootstrapping, C++ must be enabled.
1922   case ",$enable_languages,:$enable_bootstrap" in
1923     *,c++,*:*) ;;
1924     *:yes)
1925       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1926         enable_languages="${enable_languages},c++"
1927       else
1928         AC_MSG_ERROR([bootstrapping requires c++ sources])
1929       fi
1930       ;;
1931   esac
1932
1933   # First scan to see if an enabled language requires some other language.
1934   # We assume that a given config-lang.in will list all the language
1935   # front ends it requires, even if some are required indirectly.
1936   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1937     case ${lang_frag} in
1938       ..) ;;
1939       # The odd quoting in the next line works around
1940       # an apparent bug in bash 1.12 on linux.
1941       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1942       *)
1943         # From the config-lang.in, get $language, $lang_requires, and
1944         # $lang_requires_boot_languages.
1945         language=
1946         lang_requires=
1947         lang_requires_boot_languages=
1948         # set srcdir during sourcing lang_frag to the gcc dir.
1949         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1950         # polutes this shell
1951         saved_srcdir=${srcdir}
1952         srcdir=${srcdir}/gcc . ${lang_frag}
1953         srcdir=${saved_srcdir}
1954         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1955           case ,${enable_languages}, in
1956             *,$other,*) ;;
1957             *,default,*) ;;
1958             *,all,*) ;;
1959             *,$language,*)
1960               echo " \`$other' language required by \`$language'; enabling" 1>&2
1961               enable_languages="${enable_languages},${other}"
1962               ;;
1963           esac
1964         done
1965         for other in ${lang_requires_boot_languages} ; do
1966           if test "$other" != "c"; then
1967             case ,${enable_stage1_languages}, in
1968               *,$other,*) ;;
1969               *,default,*) ;;
1970               *,all,*) ;;
1971               *)
1972                 case ,${enable_languages}, in
1973                   *,$language,*)
1974                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1975                     enable_stage1_languages="$enable_stage1_languages,${other}"
1976                     ;;
1977                 esac
1978                 ;;
1979             esac
1980           fi
1981         done
1982         ;;
1983     esac
1984   done
1985
1986   new_enable_languages=,c,
1987
1988   # If LTO is enabled, add the LTO front end.
1989   if test "$enable_lto" = "yes" ; then
1990     case ,${enable_languages}, in
1991       *,lto,*) ;;
1992       *) enable_languages="${enable_languages},lto" ;;
1993     esac
1994     if test "${build_lto_plugin}" = "yes" ; then
1995       configdirs="$configdirs lto-plugin"
1996     fi
1997   fi
1998
1999   # If we're building an offloading compiler, add the LTO front end.
2000   if test x"$enable_as_accelerator_for" != x ; then
2001     case ,${enable_languages}, in
2002       *,lto,*) ;;
2003       *) enable_languages="${enable_languages},lto" ;;
2004     esac
2005   fi
2006
2007   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2008   potential_languages=,c,
2009
2010   enabled_target_libs=
2011   disabled_target_libs=
2012
2013   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2014     case ${lang_frag} in
2015       ..) ;;
2016       # The odd quoting in the next line works around
2017       # an apparent bug in bash 1.12 on linux.
2018       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2019       *)
2020         # From the config-lang.in, get $language, $target_libs,
2021         # $lang_dirs, $boot_language, and $build_by_default
2022         language=
2023         target_libs=
2024         lang_dirs=
2025         subdir_requires=
2026         boot_language=no
2027         build_by_default=yes
2028         # set srcdir during sourcing.  See above about save & restore
2029         saved_srcdir=${srcdir}
2030         srcdir=${srcdir}/gcc . ${lang_frag}
2031         srcdir=${saved_srcdir}
2032         if test x${language} = x; then
2033           echo "${lang_frag} doesn't set \$language." 1>&2
2034           exit 1
2035         fi
2036
2037         if test "$language" = "c++"; then
2038           boot_language=yes
2039         fi
2040
2041         add_this_lang=no
2042         # C is always enabled, so no need to add it again
2043         if test "$language" != "c"; then
2044           case ,${enable_languages}, in
2045             *,${language},*)
2046               # Language was explicitly selected; include it
2047               add_this_lang=yes
2048               ;;
2049             *,all,*)
2050               # All languages are enabled
2051               add_this_lang=all
2052               ;;
2053             *,default,*)
2054               # 'default' was selected, select it if it is a default language
2055               add_this_lang=${build_by_default}
2056               ;;
2057           esac
2058         fi
2059
2060         # Disable languages that need other directories if these aren't available.
2061         for i in $subdir_requires; do
2062           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2063           case ${add_this_lang} in
2064             yes)
2065               # Specifically requested language; tell them.
2066               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2067               ;;
2068             all)
2069               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2070               add_this_lang=unsupported
2071               ;;
2072             *)
2073               # Silently disable.
2074               add_this_lang=unsupported
2075               ;;
2076           esac
2077         done
2078
2079         # Disable Ada if no preexisting GNAT is available.
2080         case ${add_this_lang}:${language}:${have_gnat} in
2081           yes:ada:no)
2082             # Specifically requested language; tell them.
2083             AC_MSG_ERROR([GNAT is required to build $language])
2084             ;;
2085           all:ada:no)
2086             AC_MSG_WARN([GNAT is required to build $language])
2087             add_this_lang=unsupported
2088             ;;
2089           *:ada:no)
2090             # Silently disable.
2091             add_this_lang=unsupported
2092             ;;
2093         esac
2094
2095         # Disable jit if -enable-host-shared not specified
2096         # but not if building for Mingw. All code in Windows
2097         # is position independent code (PIC).
2098         case $target in
2099           *mingw*) ;;
2100           *)
2101           case ${add_this_lang}:${language}:${host_shared} in
2102             yes:jit:no)
2103                    # PR jit/64780: explicitly specify --enable-host-shared
2104             AC_MSG_ERROR([
2105 Enabling language "jit" requires --enable-host-shared.
2106
2107 --enable-host-shared typically slows the rest of the compiler down by
2108 a few %, so you must explicitly enable it.
2109
2110 If you want to build both the jit and the regular compiler, it is often
2111 best to do this via two separate configure/builds, in separate
2112 directories, to avoid imposing the performance cost of
2113 --enable-host-shared on the regular compiler.])
2114                     ;;
2115             all:jit:no)
2116               AC_MSG_WARN([--enable-host-shared required to build $language])
2117               add_this_lang=unsupported
2118               ;;
2119             *:jit:no)
2120               # Silently disable.
2121               add_this_lang=unsupported
2122               ;;
2123                 esac
2124           ;;
2125         esac
2126
2127         # Disable a language that is unsupported by the target.
2128         case "${add_this_lang}: $unsupported_languages " in
2129           no:*) ;;
2130           unsupported:*) ;;
2131           *:*" $language "*)
2132             AC_MSG_WARN([${language} not supported for this target])
2133             add_this_lang=unsupported
2134             ;;
2135         esac
2136
2137         case $add_this_lang in
2138           unsupported)
2139             # Remove language-dependent dirs.
2140             disabled_target_libs="$disabled_target_libs $target_libs"
2141             noconfigdirs="$noconfigdirs $lang_dirs"
2142             ;;
2143           no)
2144             # Remove language-dependent dirs; still show language as supported.
2145             disabled_target_libs="$disabled_target_libs $target_libs"
2146             noconfigdirs="$noconfigdirs $lang_dirs"
2147             potential_languages="${potential_languages}${language},"
2148             ;;
2149           all|yes)
2150             new_enable_languages="${new_enable_languages}${language},"
2151             potential_languages="${potential_languages}${language},"
2152             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2153             enabled_target_libs="$enabled_target_libs $target_libs"
2154             case "${boot_language}:,$enable_stage1_languages," in
2155               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2156                 # Add to (comma-separated) list of stage 1 languages.
2157                 case ",$stage1_languages," in
2158                   *,$language,* | ,yes, | ,all,) ;;
2159                   *) stage1_languages="${stage1_languages}${language}," ;;
2160                 esac
2161                 # We need to bootstrap any supporting libraries.
2162                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2163                 ;;
2164             esac
2165             ;;
2166         esac
2167         ;;
2168     esac
2169   done
2170
2171   # Add target libraries which are only needed for disabled languages
2172   # to noconfigdirs.
2173   if test -n "$disabled_target_libs"; then
2174     for dir in $disabled_target_libs; do
2175       case " $enabled_target_libs " in
2176       *" ${dir} "*) ;;
2177       *) noconfigdirs="$noconfigdirs $dir" ;;
2178       esac
2179     done
2180   fi
2181
2182   AC_ARG_ENABLE(stage1-languages,
2183   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2184                   [choose additional languages to build during
2185                   stage1.  Mostly useful for compiler development])],
2186   [case ,${enable_stage1_languages}, in
2187     ,no,|,,)
2188       # Set it to something that will have no effect in the loop below
2189       enable_stage1_languages=c ;;
2190     ,yes,)
2191       enable_stage1_languages=`echo $new_enable_languages | \
2192         sed -e "s/^,//" -e "s/,$//" ` ;;
2193     *,all,*)
2194       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2195         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2196   esac
2197
2198   # Add "good" languages from enable_stage1_languages to stage1_languages,
2199   # while "bad" languages go in missing_languages.  Leave no duplicates.
2200   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2201     case $potential_languages in
2202       *,$i,*)
2203         case $stage1_languages in
2204           *,$i,*) ;;
2205           *) stage1_languages="$stage1_languages$i," ;;
2206         esac ;;
2207       *)
2208         case $missing_languages in
2209           *,$i,*) ;;
2210           *) missing_languages="$missing_languages$i," ;;
2211         esac ;;
2212      esac
2213   done])
2214
2215   # Remove leading/trailing commas that were added for simplicity
2216   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2217   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2218   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2219   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2220
2221   if test "x$missing_languages" != x; then
2222     AC_MSG_ERROR([
2223 The following requested languages could not be built: ${missing_languages}
2224 Supported languages are: ${potential_languages}])
2225   fi
2226   if test "x$new_enable_languages" != "x$enable_languages"; then
2227     echo The following languages will be built: ${new_enable_languages}
2228     enable_languages="$new_enable_languages"
2229   fi
2230
2231   AC_SUBST(stage1_languages)
2232   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2233 fi
2234
2235 # Handle --disable-<component> generically.
2236 for dir in $configdirs $build_configdirs $target_configdirs ; do
2237   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2238   varname=`echo $dirname | sed -e s/+/_/g`
2239   if eval test x\${enable_${varname}} "=" xno ; then
2240     noconfigdirs="$noconfigdirs $dir"
2241   fi
2242 done
2243
2244 # Check for Boehm's garbage collector
2245 AC_ARG_ENABLE(objc-gc,
2246 [AS_HELP_STRING([--enable-objc-gc],
2247                 [enable use of Boehm's garbage collector with the
2248                  GNU Objective-C runtime])])
2249 AC_ARG_WITH([target-bdw-gc],
2250 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2251                 [specify prefix directory for installed bdw-gc package.
2252                  Equivalent to --with-target-bdw-gc-include=PATH/include
2253                  plus --with-target-bdw-gc-lib=PATH/lib])])
2254 AC_ARG_WITH([target-bdw-gc-include],
2255 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2256                 [specify directories for installed bdw-gc include files])])
2257 AC_ARG_WITH([target-bdw-gc-lib],
2258 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2259                 [specify directories for installed bdw-gc library])])
2260
2261 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2262   AC_MSG_CHECKING([for bdw garbage collector])
2263   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2264     dnl no bdw-gw options, assume default locations
2265     AC_MSG_RESULT([using bdw-gc in default locations])
2266   else
2267     dnl bdw-gw options, first error checking, complete checking in libobjc
2268     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2269       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2270     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2271       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2272     else
2273       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2274     fi
2275   fi
2276 esac
2277
2278 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2279 case ,${enable_languages}, in
2280   *,c++,*)
2281     # Disable libitm, libsanitizer if we're not building libstdc++
2282     case "${noconfigdirs}" in
2283       *target-libstdc++-v3*)
2284         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2285         ;;
2286       *) ;;
2287     esac
2288     ;;
2289   *)
2290     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2291     ;;
2292 esac
2293
2294 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2295 # $build_configdirs and $target_configdirs.
2296 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2297
2298 notsupp=""
2299 for dir in . $skipdirs $noconfigdirs ; do
2300   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2301   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2302     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2303     if test -r $srcdir/$dirname/configure ; then
2304       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2305         true
2306       else
2307         notsupp="$notsupp $dir"
2308       fi
2309     fi
2310   fi
2311   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2312     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2313     if test -r $srcdir/$dirname/configure ; then
2314       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2315         true
2316       else
2317         notsupp="$notsupp $dir"
2318       fi
2319     fi
2320   fi
2321   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2322     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2323     if test -r $srcdir/$dirname/configure ; then
2324       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2325         true
2326       else
2327         notsupp="$notsupp $dir"
2328       fi
2329     fi
2330   fi
2331 done
2332
2333 # Quietly strip out all directories which aren't configurable in this tree.
2334 # This relies on all configurable subdirectories being autoconfiscated, which
2335 # is now the case.
2336 build_configdirs_all="$build_configdirs"
2337 build_configdirs=
2338 for i in ${build_configdirs_all} ; do
2339   j=`echo $i | sed -e s/build-//g`
2340   if test -f ${srcdir}/$j/configure ; then
2341     build_configdirs="${build_configdirs} $i"
2342   fi
2343 done
2344
2345 configdirs_all="$configdirs"
2346 configdirs=
2347 for i in ${configdirs_all} ; do
2348   if test -f ${srcdir}/$i/configure ; then
2349     configdirs="${configdirs} $i"
2350   fi
2351 done
2352
2353 target_configdirs_all="$target_configdirs"
2354 target_configdirs=
2355 for i in ${target_configdirs_all} ; do
2356   j=`echo $i | sed -e s/target-//g`
2357   if test -f ${srcdir}/$j/configure ; then
2358     target_configdirs="${target_configdirs} $i"
2359   fi
2360 done
2361
2362 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2363 # so we have to add it after the preceding checks.
2364 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2365 then
2366   case " $configdirs " in
2367     *" libiberty "*)
2368       # If we can build libiberty, we can also build libiberty-linker-plugin.
2369       configdirs="$configdirs libiberty-linker-plugin"
2370       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2371         --with-libiberty=../libiberty-linker-plugin";;
2372     *)
2373       AC_MSG_ERROR([libiberty missing]);;
2374   esac
2375 fi
2376
2377 # Sometimes we have special requirements for the host libiberty.
2378 extra_host_libiberty_configure_flags=
2379 extra_host_zlib_configure_flags=
2380 case " $configdirs " in
2381   *" lto-plugin "* | *" libcc1 "*)
2382     # When these are to be built as shared libraries, the same applies to
2383     # libiberty.
2384     extra_host_libiberty_configure_flags=--enable-shared
2385     ;;
2386   *" bfd "*)
2387     # When bfd is to be built as a shared library, the same applies to
2388     # zlib.
2389     if test "$enable_shared" = "yes"; then
2390       extra_host_zlib_configure_flags=--enable-host-shared
2391     fi
2392     ;;
2393 esac
2394 AC_SUBST(extra_host_libiberty_configure_flags)
2395 AC_SUBST(extra_host_zlib_configure_flags)
2396
2397 # Produce a warning message for the subdirs we can't configure.
2398 # This isn't especially interesting in the Cygnus tree, but in the individual
2399 # FSF releases, it's important to let people know when their machine isn't
2400 # supported by the one or two programs in a package.
2401
2402 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2403   # If $appdirs is non-empty, at least one of those directories must still
2404   # be configured, or we error out.  (E.g., if the gas release supports a
2405   # specified target in some subdirs but not the gas subdir, we shouldn't
2406   # pretend that all is well.)
2407   if test -n "$appdirs" ; then
2408     for dir in $appdirs ; do
2409       if test -r $dir/Makefile.in ; then
2410         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2411           appdirs=""
2412           break
2413         fi
2414         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2415           appdirs=""
2416           break
2417         fi
2418       fi
2419     done
2420     if test -n "$appdirs" ; then
2421       echo "*** This configuration is not supported by this package." 1>&2
2422       exit 1
2423     fi
2424   fi
2425   # Okay, some application will build, or we don't care to check.  Still
2426   # notify of subdirs not getting built.
2427   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2428   echo "    ${notsupp}" 1>&2
2429   echo "    (Any other directories should still work fine.)" 1>&2
2430 fi
2431
2432 case "$host" in
2433   *msdosdjgpp*)
2434     enable_gdbtk=no ;;
2435 esac
2436
2437 # To find our prefix, in gcc_cv_tool_prefix.
2438 ACX_TOOL_DIRS
2439
2440 copy_dirs=
2441
2442 AC_ARG_WITH([build-sysroot],
2443   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2444                   [use sysroot as the system root during the build])],
2445   [if test x"$withval" != x ; then
2446      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2447    fi],
2448   [SYSROOT_CFLAGS_FOR_TARGET=])
2449 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2450
2451 AC_ARG_WITH([debug-prefix-map],
2452   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2453                   [map A to B, C to D ... in debug information])],
2454   [if test x"$withval" != x; then
2455      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2456      for debug_map in $withval; do
2457        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2458      done
2459    fi],
2460   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2461 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2462
2463 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2464 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2465 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2466 # We want to ensure that TARGET libraries (which we know are built with
2467 # gcc) are built with "-O2 -g", so include those options when setting
2468 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2469 if test "x$CFLAGS_FOR_TARGET" = x; then
2470   if test "x${is_cross_compiler}" = xyes; then
2471     CFLAGS_FOR_TARGET="-g -O2"
2472   else
2473     CFLAGS_FOR_TARGET=$CFLAGS
2474     case " $CFLAGS " in
2475       *" -O2 "*) ;;
2476       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2477     esac
2478     case " $CFLAGS " in
2479       *" -g "* | *" -g3 "*) ;;
2480       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2481     esac
2482   fi
2483 fi
2484 AC_SUBST(CFLAGS_FOR_TARGET)
2485
2486 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2487   if test "x${is_cross_compiler}" = xyes; then
2488     CXXFLAGS_FOR_TARGET="-g -O2"
2489   else
2490     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2491     case " $CXXFLAGS " in
2492       *" -O2 "*) ;;
2493       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2494     esac
2495     case " $CXXFLAGS " in
2496       *" -g "* | *" -g3 "*) ;;
2497       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2498     esac
2499   fi
2500 fi
2501 AC_SUBST(CXXFLAGS_FOR_TARGET)
2502
2503 AC_SUBST(LDFLAGS_FOR_TARGET)
2504
2505 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2506 # the named directory are copied to $(tooldir)/sys-include.
2507 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2508   if test x${is_cross_compiler} = xno ; then
2509     echo 1>&2 '***' --with-headers is only supported when cross compiling
2510     exit 1
2511   fi
2512   if test x"${with_headers}" != xyes ; then
2513     x=${gcc_cv_tool_prefix}
2514     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2515   fi
2516 fi
2517
2518 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2519 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2520 # are permitted.
2521 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2522   if test x${is_cross_compiler} = xno ; then
2523     echo 1>&2 '***' --with-libs is only supported when cross compiling
2524     exit 1
2525   fi
2526   if test x"${with_libs}" != xyes ; then
2527     # Copy the libraries in reverse order, so that files in the first named
2528     # library override files in subsequent libraries.
2529     x=${gcc_cv_tool_prefix}
2530     for l in ${with_libs}; do
2531       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2532     done
2533   fi
2534 fi
2535
2536 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2537 #
2538 # This is done by determining whether or not the appropriate directory
2539 # is available, and by checking whether or not specific configurations
2540 # have requested that this magic not happen.
2541 #
2542 # The command line options always override the explicit settings in
2543 # configure.ac, and the settings in configure.ac override this magic.
2544 #
2545 # If the default for a toolchain is to use GNU as and ld, and you don't
2546 # want to do that, then you should use the --without-gnu-as and
2547 # --without-gnu-ld options for the configure script.  Similarly, if
2548 # the default is to use the included zlib and you don't want to do that,
2549 # you should use the --with-system-zlib option for the configure script.
2550
2551 if test x${use_gnu_as} = x &&
2552    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2553   with_gnu_as=yes
2554   extra_host_args="$extra_host_args --with-gnu-as"
2555 fi
2556
2557 if test x${use_gnu_ld} = x &&
2558    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2559   with_gnu_ld=yes
2560   extra_host_args="$extra_host_args --with-gnu-ld"
2561 fi
2562
2563 if test x${use_included_zlib} = x &&
2564    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2565   :
2566 else
2567   with_system_zlib=yes
2568   extra_host_args="$extra_host_args --with-system-zlib"
2569 fi
2570
2571 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2572 # can detect this case.
2573
2574 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2575   with_newlib=yes
2576   extra_host_args="$extra_host_args --with-newlib"
2577 fi
2578
2579 # Handle ${copy_dirs}
2580 set fnord ${copy_dirs}
2581 shift
2582 while test $# != 0 ; do
2583   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2584     :
2585   else
2586     echo Copying $1 to $2
2587
2588     # Use the install script to create the directory and all required
2589     # parent directories.
2590     if test -d $2 ; then
2591       :
2592     else
2593       echo >config.temp
2594       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2595     fi
2596
2597     # Copy the directory, assuming we have tar.
2598     # FIXME: Should we use B in the second tar?  Not all systems support it.
2599     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2600
2601     # It is the responsibility of the user to correctly adjust all
2602     # symlinks.  If somebody can figure out how to handle them correctly
2603     # here, feel free to add the code.
2604
2605     echo $1 > $2/COPIED
2606   fi
2607   shift; shift
2608 done
2609
2610 # Determine a target-dependent exec_prefix that the installed
2611 # gcc will search in.  Keep this list sorted by triplet, with
2612 # the *-*-osname triplets last.
2613 md_exec_prefix=
2614 case "${target}" in
2615   i[[34567]]86-pc-msdosdjgpp*)
2616     md_exec_prefix=/dev/env/DJDIR/bin
2617     ;;
2618   *-*-hpux* | \
2619   *-*-nto-qnx* | \
2620   *-*-solaris2*)
2621     md_exec_prefix=/usr/ccs/bin
2622     ;;
2623 esac
2624
2625 extra_arflags_for_target=
2626 extra_nmflags_for_target=
2627 extra_ranlibflags_for_target=
2628 target_makefile_frag=/dev/null
2629 case "${target}" in
2630   spu-*-*)
2631     target_makefile_frag="config/mt-spu"
2632     ;;
2633   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2634     target_makefile_frag="config/mt-sde"
2635     ;;
2636   mipsisa*-*-elfoabi*)
2637     target_makefile_frag="config/mt-mips-elfoabi"
2638     ;;
2639   mips*-*-*linux* | mips*-*-gnu*)
2640     target_makefile_frag="config/mt-mips-gnu"
2641     ;;
2642   nios2-*-elf*)
2643     target_makefile_frag="config/mt-nios2-elf"
2644     ;;
2645   *-*-linux-android*)
2646     target_makefile_frag="config/mt-android"
2647     ;;
2648   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2649     target_makefile_frag="config/mt-gnu"
2650     ;;
2651   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2652     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2653     # commands to handle both 32-bit and 64-bit objects.  These flags are
2654     # harmless if we're using GNU nm or ar.
2655     extra_arflags_for_target=" -X32_64"
2656     extra_nmflags_for_target=" -B -X32_64"
2657     ;;
2658 esac
2659
2660 alphaieee_frag=/dev/null
2661 case $target in
2662   alpha*-*-*)
2663     # This just makes sure to use the -mieee option to build target libs.
2664     # This should probably be set individually by each library.
2665     alphaieee_frag="config/mt-alphaieee"
2666     ;;
2667 esac
2668
2669 # If --enable-target-optspace always use -Os instead of -O2 to build
2670 # the target libraries, similarly if it is not specified, use -Os
2671 # on selected platforms.
2672 ospace_frag=/dev/null
2673 case "${enable_target_optspace}:${target}" in
2674   yes:*)
2675     ospace_frag="config/mt-ospace"
2676     ;;
2677   :d30v-*)
2678     ospace_frag="config/mt-d30v"
2679     ;;
2680   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2681     ospace_frag="config/mt-ospace"
2682     ;;
2683   no:* | :*)
2684     ;;
2685   *)
2686     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2687     ;;
2688 esac
2689
2690 # Some systems (e.g., one of the i386-aix systems the gas testers are
2691 # using) don't handle "\$" correctly, so don't use it here.
2692 tooldir='${exec_prefix}'/${target_noncanonical}
2693 build_tooldir=${tooldir}
2694
2695 # Create a .gdbinit file which runs the one in srcdir
2696 # and tells GDB to look there for source files.
2697
2698 if test -r ${srcdir}/.gdbinit ; then
2699   case ${srcdir} in
2700     .) ;;
2701     *) cat > ./.gdbinit <<EOF
2702 # ${NO_EDIT}
2703 dir ${srcdir}
2704 dir .
2705 source ${srcdir}/.gdbinit
2706 EOF
2707     ;;
2708   esac
2709 fi
2710
2711 # Make sure that the compiler is able to generate an executable.  If it
2712 # can't, we are probably in trouble.  We don't care whether we can run the
2713 # executable--we might be using a cross compiler--we only care whether it
2714 # can be created.  At this point the main configure script has set CC.
2715 we_are_ok=no
2716 echo "int main () { return 0; }" > conftest.c
2717 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2718 if test $? = 0 ; then
2719   if test -s conftest || test -s conftest.exe ; then
2720     we_are_ok=yes
2721   fi
2722 fi
2723 case $we_are_ok in
2724   no)
2725     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2726     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2727     rm -f conftest*
2728     exit 1
2729     ;;
2730 esac
2731 rm -f conftest*
2732
2733 # Decide which environment variable is used to find dynamic libraries.
2734 case "${host}" in
2735   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2736   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2737   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2738   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2739 esac
2740
2741 # On systems where the dynamic library environment variable is PATH,
2742 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2743 # built executables to PATH.
2744 if test "$RPATH_ENVVAR" = PATH; then
2745   GCC_SHLIB_SUBDIR=/shlib
2746 else
2747   GCC_SHLIB_SUBDIR=
2748 fi
2749
2750 # Adjust the toplevel makefile according to whether bootstrap was selected.
2751 case $enable_bootstrap in
2752   yes)
2753     bootstrap_suffix=bootstrap
2754     BUILD_CONFIG=bootstrap-debug
2755     ;;
2756   no)
2757     bootstrap_suffix=no-bootstrap
2758     BUILD_CONFIG=
2759     ;;
2760 esac
2761
2762 AC_MSG_CHECKING(for default BUILD_CONFIG)
2763
2764 AC_ARG_WITH([build-config],
2765   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2766                   [use config/NAME.mk build configuration])],
2767   [case $with_build_config in
2768    yes) with_build_config= ;;
2769    no) with_build_config= BUILD_CONFIG= ;;
2770    esac])
2771
2772 if test "x${with_build_config}" != x; then
2773   BUILD_CONFIG=$with_build_config
2774 else
2775   case $BUILD_CONFIG in
2776   bootstrap-debug)
2777     if echo "int f (void) { return 0; }" > conftest.c &&
2778        ${CC} -c conftest.c &&
2779        mv conftest.o conftest.o.g0 &&
2780        ${CC} -c -g conftest.c &&
2781        mv conftest.o conftest.o.g &&
2782        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2783       :
2784     else
2785       BUILD_CONFIG=
2786     fi
2787     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2788     ;;
2789   esac
2790 fi
2791 AC_MSG_RESULT($BUILD_CONFIG)
2792 AC_SUBST(BUILD_CONFIG)
2793
2794 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2795 AC_MSG_CHECKING([for --enable-vtable-verify])
2796 AC_ARG_ENABLE(vtable-verify,
2797 [AS_HELP_STRING([--enable-vtable-verify],
2798                 [Enable vtable verification feature])],
2799 [case "$enableval" in
2800  yes) enable_vtable_verify=yes ;;
2801  no)  enable_vtable_verify=no ;;
2802  *)   enable_vtable_verify=no;;
2803  esac],
2804 [enable_vtable_verify=no])
2805 AC_MSG_RESULT($enable_vtable_verify)
2806
2807 # Record target_configdirs and the configure arguments for target and
2808 # build configuration in Makefile.
2809 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2810 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2811 bootstrap_fixincludes=no
2812
2813 # If we are building libgomp, bootstrap it.
2814 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2815   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2816 fi
2817
2818 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2819 # or bootstrap-ubsan, bootstrap it.
2820 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2821   case "$BUILD_CONFIG" in
2822     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
2823       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2824       bootstrap_fixincludes=yes
2825       ;;
2826   esac
2827 fi
2828
2829 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2830 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2831    test "$enable_vtable_verify" != no; then
2832   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2833 fi
2834
2835 # Determine whether gdb needs tk/tcl or not.
2836 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2837 # and in that case we want gdb to be built without tk.  Ugh!
2838 # In fact I believe gdb is the *only* package directly dependent on tk,
2839 # so we should be able to put the 'maybe's in unconditionally and
2840 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2841 # 100% sure that that's safe though.
2842
2843 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2844 case "$enable_gdbtk" in
2845   no)
2846     GDB_TK="" ;;
2847   yes)
2848     GDB_TK="${gdb_tk}" ;;
2849   *)
2850     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2851     # distro.  Eventually someone will fix this and move Insight, nee
2852     # gdbtk to a separate directory.
2853     if test -d ${srcdir}/gdb/gdbtk ; then
2854       GDB_TK="${gdb_tk}"
2855     else
2856       GDB_TK=""
2857     fi
2858     ;;
2859 esac
2860 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2861 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2862
2863 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2864 # else does, only include them if one of these is built.  The Makefile
2865 # provides the ordering, so it's enough here to add to the list.
2866 case " ${configdirs} " in
2867   *\ gdb\ *)
2868     configdirs="${configdirs} gnulib gdbsupport"
2869     ;;
2870   *\ gdbserver\ *)
2871     configdirs="${configdirs} gnulib gdbsupport"
2872     ;;
2873 esac
2874
2875 # Strip out unwanted targets.
2876
2877 # While at that, we remove Makefiles if we were started for recursive
2878 # configuration, so that the top-level Makefile reconfigures them,
2879 # like we used to do when configure itself was recursive.
2880
2881 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2882 # but now we're fixing up the Makefile ourselves with the additional
2883 # commands passed to AC_CONFIG_FILES.  Use separate variables
2884 # extrasub-{build,host,target} not because there is any reason to split
2885 # the substitutions up that way, but only to remain below the limit of
2886 # 99 commands in a script, for HP-UX sed.
2887
2888 # Do not nest @if/@endif or @unless/@endunless pairs, because
2889 # configure will not warn you at all.
2890
2891 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2892   yes:yes:*\ gold\ *:*,c++,*) ;;
2893   yes:yes:*\ gold\ *:*)
2894     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2895     ;;
2896 esac
2897
2898 extrasub_build=
2899 for module in ${build_configdirs} ; do
2900   if test -z "${no_recursion}" \
2901      && test -f ${build_subdir}/${module}/Makefile; then
2902     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2903     rm -f ${build_subdir}/${module}/Makefile
2904   fi
2905   extrasub_build="$extrasub_build
2906 /^@if build-$module\$/d
2907 /^@endif build-$module\$/d
2908 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2909 /^@if build-$module-$bootstrap_suffix\$/d
2910 /^@endif build-$module-$bootstrap_suffix\$/d
2911 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2912 done
2913 extrasub_host=
2914 for module in ${configdirs} ; do
2915   if test -z "${no_recursion}"; then
2916     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2917       if test -f ${file}; then
2918         echo 1>&2 "*** removing ${file} to force reconfigure"
2919         rm -f ${file}
2920       fi
2921     done
2922   fi
2923   case ${module},${bootstrap_fixincludes} in
2924     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2925     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2926   esac
2927   extrasub_host="$extrasub_host
2928 /^@if $module\$/d
2929 /^@endif $module\$/d
2930 /^@unless $module\$/,/^@endunless $module\$/d
2931 /^@if $module-$host_bootstrap_suffix\$/d
2932 /^@endif $module-$host_bootstrap_suffix\$/d
2933 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2934 done
2935 extrasub_target=
2936 for module in ${target_configdirs} ; do
2937   if test -z "${no_recursion}" \
2938      && test -f ${target_subdir}/${module}/Makefile; then
2939     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2940     rm -f ${target_subdir}/${module}/Makefile
2941   fi
2942
2943   # We only bootstrap target libraries listed in bootstrap_target_libs.
2944   case $bootstrap_target_libs in
2945     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2946     *) target_bootstrap_suffix=no-bootstrap ;;
2947   esac
2948
2949   extrasub_target="$extrasub_target
2950 /^@if target-$module\$/d
2951 /^@endif target-$module\$/d
2952 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2953 /^@if target-$module-$target_bootstrap_suffix\$/d
2954 /^@endif target-$module-$target_bootstrap_suffix\$/d
2955 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2956 done
2957
2958 # Do the final fixup along with target modules.
2959 extrasub_target="$extrasub_target
2960 /^@if /,/^@endif /d
2961 /^@unless /d
2962 /^@endunless /d"
2963
2964 # Create the serialization dependencies.  This uses a temporary file.
2965
2966 AC_ARG_ENABLE([serial-configure],
2967 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2968                 [force sequential configuration of
2969                  sub-packages for the host, target or build
2970                  machine, or all sub-packages])])
2971
2972 case ${enable_serial_configure} in
2973   yes)
2974     enable_serial_build_configure=yes
2975     enable_serial_host_configure=yes
2976     enable_serial_target_configure=yes
2977     ;;
2978 esac
2979
2980 # These force 'configure's to be done one at a time, to avoid problems
2981 # with contention over a shared config.cache.
2982 rm -f serdep.tmp
2983 echo '# serdep.tmp' > serdep.tmp
2984 olditem=
2985 test "x${enable_serial_build_configure}" = xyes &&
2986 for item in ${build_configdirs} ; do
2987   case ${olditem} in
2988     "") ;;
2989     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2990   esac
2991   olditem=${item}
2992 done
2993 olditem=
2994 test "x${enable_serial_host_configure}" = xyes &&
2995 for item in ${configdirs} ; do
2996   case ${olditem} in
2997     "") ;;
2998     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2999   esac
3000   olditem=${item}
3001 done
3002 olditem=
3003 test "x${enable_serial_target_configure}" = xyes &&
3004 for item in ${target_configdirs} ; do
3005   case ${olditem} in
3006     "") ;;
3007     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3008   esac
3009   olditem=${item}
3010 done
3011 serialization_dependencies=serdep.tmp
3012 AC_SUBST_FILE(serialization_dependencies)
3013
3014 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3015 # target, nonopt, and variable assignments.  These are the ones we
3016 # might not want to pass down to subconfigures.  The exception being
3017 # --cache-file=/dev/null, which is used to turn off the use of cache
3018 # files altogether, and which should be passed on to subconfigures.
3019 # Also strip program-prefix, program-suffix, and program-transform-name,
3020 # so that we can pass down a consistent program-transform-name.
3021 baseargs=
3022 tbaseargs=
3023 keep_next=no
3024 skip_next=no
3025 eval "set -- $ac_configure_args"
3026 for ac_arg
3027 do
3028   if test X"$skip_next" = X"yes"; then
3029     skip_next=no
3030     continue
3031   fi
3032   if test X"$keep_next" = X"yes"; then
3033     case $ac_arg in
3034       *\'*)
3035         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3036     esac
3037     baseargs="$baseargs '$ac_arg'"
3038     tbaseargs="$tbaseargs '$ac_arg'"
3039     keep_next=no
3040     continue
3041   fi
3042
3043   # Handle separated arguments.  Based on the logic generated by
3044   # autoconf 2.59.
3045   case $ac_arg in
3046     *=* | --config-cache | -C | -disable-* | --disable-* \
3047       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3048       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3049       | -with-* | --with-* | -without-* | --without-* | --x)
3050       separate_arg=no
3051       ;;
3052     -*)
3053       separate_arg=yes
3054       ;;
3055     *)
3056       separate_arg=no
3057       ;;
3058   esac
3059
3060   skip_targ=no
3061   case $ac_arg in
3062 changequote(,)
3063   --with-* | --without-*)
3064     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3065
3066     case $libopt in
3067     *[-_]include)
3068       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3069       ;;
3070     *[-_]lib)
3071       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3072       ;;
3073     *)
3074       lib=$libopt
3075       ;;
3076     esac
3077 changequote([,])
3078
3079     case $lib in
3080     mpc | mpfr | gmp | isl)
3081       # If we're processing --with-$lib, --with-$lib-include or
3082       # --with-$lib-lib, for one of the libs above, and target is
3083       # different from host, don't pass the current argument to any
3084       # target library's configure.
3085       if test x$is_cross_compiler = xyes; then
3086         skip_targ=yes
3087       fi
3088       ;;
3089     esac
3090     ;;
3091   esac
3092
3093   case "$ac_arg" in
3094     --cache-file=/dev/null | \
3095     -cache-file=/dev/null )
3096       # Handled here to avoid the test to skip args below.
3097       baseargs="$baseargs '$ac_arg'"
3098       tbaseargs="$tbaseargs '$ac_arg'"
3099       # Assert: $separate_arg should always be no.
3100       keep_next=$separate_arg
3101       ;;
3102     --no*)
3103       continue
3104       ;;
3105     --c* | \
3106     --sr* | \
3107     --ho* | \
3108     --bu* | \
3109     --t* | \
3110     --program-* | \
3111     -cache_file* | \
3112     -srcdir* | \
3113     -host* | \
3114     -build* | \
3115     -target* | \
3116     -program-prefix* | \
3117     -program-suffix* | \
3118     -program-transform-name* )
3119       skip_next=$separate_arg
3120       continue
3121       ;;
3122     -*)
3123       # An option.  Add it.
3124       case $ac_arg in
3125         *\'*)
3126           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3127       esac
3128       baseargs="$baseargs '$ac_arg'"
3129       if test X"$skip_targ" = Xno; then
3130         tbaseargs="$tbaseargs '$ac_arg'"
3131       fi
3132       keep_next=$separate_arg
3133       ;;
3134     *)
3135       # Either a variable assignment, or a nonopt (triplet).  Don't
3136       # pass it down; let the Makefile handle this.
3137       continue
3138       ;;
3139   esac
3140 done
3141 # Remove the initial space we just introduced and, as these will be
3142 # expanded by make, quote '$'.
3143 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3144
3145 # Add in --program-transform-name, after --program-prefix and
3146 # --program-suffix have been applied to it.  Autoconf has already
3147 # doubled dollar signs and backslashes in program_transform_name; we want
3148 # the backslashes un-doubled, and then the entire thing wrapped in single
3149 # quotes, because this will be expanded first by make and then by the shell.
3150 # Also, because we want to override the logic in subdir configure scripts to
3151 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3152 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3153 ${program_transform_name}
3154 EOF_SED
3155 gcc_transform_name=`cat conftestsed.out`
3156 rm -f conftestsed.out
3157 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3158 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3159 if test "$silent" = yes; then
3160   baseargs="$baseargs --silent"
3161   tbaseargs="$tbaseargs --silent"
3162 fi
3163 baseargs="$baseargs --disable-option-checking"
3164 tbaseargs="$tbaseargs --disable-option-checking"
3165
3166 # Record and document user additions to sub configure arguments.
3167 AC_ARG_VAR([build_configargs],
3168            [additional configure arguments for build directories])
3169 AC_ARG_VAR([host_configargs],
3170            [additional configure arguments for host directories])
3171 AC_ARG_VAR([target_configargs],
3172            [additional configure arguments for target directories])
3173
3174 # For the build-side libraries, we just need to pretend we're native,
3175 # and not use the same cache file.  Multilibs are neither needed nor
3176 # desired.  We can't even use the same cache file for all build-side
3177 # libraries, as they're compiled differently; some with C, some with
3178 # C++ or with different feature-enabling options.
3179 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3180
3181 # For host modules, accept cache file option, or specification as blank.
3182 case "${cache_file}" in
3183 "") # empty
3184   cache_file_option="" ;;
3185 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3186   cache_file_option="--cache-file=${cache_file}" ;;
3187 *) # relative path
3188   cache_file_option="--cache-file=../${cache_file}" ;;
3189 esac
3190
3191 # Host dirs don't like to share a cache file either, horribly enough.
3192 # This seems to be due to autoconf 2.5x stupidity.
3193 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3194
3195 target_configargs="$target_configargs ${tbaseargs}"
3196
3197 # Passing a --with-cross-host argument lets the target libraries know
3198 # whether they are being built with a cross-compiler or being built
3199 # native.  However, it would be better to use other mechanisms to make the
3200 # sorts of decisions they want to make on this basis.  Please consider
3201 # this option to be deprecated.  FIXME.
3202 if test x${is_cross_compiler} = xyes ; then
3203   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3204 fi
3205
3206 # Special user-friendly check for native x86_64-linux build, if
3207 # multilib is not explicitly enabled.
3208 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3209   x86_64-*linux*:yes:$build:$build:)
3210     # Make sure we have a development environment that handles 32-bit
3211     dev64=no
3212     echo "int main () { return 0; }" > conftest.c
3213     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3214     if test $? = 0 ; then
3215       if test -s conftest || test -s conftest.exe ; then
3216         dev64=yes
3217       fi
3218     fi
3219     rm -f conftest*
3220     if test x${dev64} != xyes ; then
3221       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3222     fi
3223     ;;
3224 esac
3225
3226 # Default to --enable-multilib.
3227 if test x${enable_multilib} = x ; then
3228   target_configargs="--enable-multilib ${target_configargs}"
3229 fi
3230
3231 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3232 # changed from the earlier setting of with_newlib.
3233 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3234   target_configargs="--with-newlib ${target_configargs}"
3235 fi
3236
3237 # Different target subdirs use different values of certain variables
3238 # (notably CXX).  Worse, multilibs use *lots* of different values.
3239 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3240 # it doesn't automatically accept command-line overrides of them.
3241 # This means it's not safe for target subdirs to share a cache file,
3242 # which is disgusting, but there you have it.  Hopefully this can be
3243 # fixed in future.  It's still worthwhile to use a cache file for each
3244 # directory.  I think.
3245
3246 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3247 # We need to pass --target, as newer autoconf's requires consistency
3248 # for target_alias and gcc doesn't manage it consistently.
3249 target_configargs="--cache-file=./config.cache ${target_configargs}"
3250
3251 FLAGS_FOR_TARGET=
3252 case " $target_configdirs " in
3253  *" newlib "*)
3254   case " $target_configargs " in
3255   *" --with-newlib "*)
3256    case "$target" in
3257     *-cygwin*)
3258       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3259       ;;
3260    esac
3261
3262    # If we're not building GCC, don't discard standard headers.
3263    if test -d ${srcdir}/gcc; then
3264      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3265
3266      if test "${build}" != "${host}"; then
3267        # On Canadian crosses, CC_FOR_TARGET will have already been set
3268        # by `configure', so we won't have an opportunity to add -Bgcc/
3269        # to it.  This is right: we don't want to search that directory
3270        # for binaries, but we want the header files in there, so add
3271        # them explicitly.
3272        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3273
3274        # Someone might think of using the pre-installed headers on
3275        # Canadian crosses, in case the installed compiler is not fully
3276        # compatible with the compiler being built.  In this case, it
3277        # would be better to flag an error than risking having
3278        # incompatible object files being constructed.  We can't
3279        # guarantee that an error will be flagged, but let's hope the
3280        # compiler will do it, when presented with incompatible header
3281        # files.
3282      fi
3283    fi
3284
3285    case "${target}-${is_cross_compiler}" in
3286    i[[3456789]]86-*-linux*-no)
3287       # Here host == target, so we don't need to build gcc,
3288       # so we don't want to discard standard headers.
3289       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3290       ;;
3291    *)
3292       # If we're building newlib, use its generic headers last, but search
3293       # for any libc-related directories first (so make it the last -B
3294       # switch).
3295       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3296
3297       # If we're building libgloss, find the startup file, simulator library
3298       # and linker script.
3299       case " $target_configdirs " in
3300         *" libgloss "*)
3301         # Look for startup file, simulator library and maybe linker script.
3302         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3303         # Look for libnosys.a in case the target needs it.
3304         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3305         # Most targets have the linker script in the source directory.
3306         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3307         ;;
3308       esac
3309       ;;
3310    esac
3311    ;;
3312   esac
3313   ;;
3314 esac
3315
3316 case "$target" in
3317   x86_64-*mingw* | *-w64-mingw*)
3318   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3319   # however, use a symlink named 'mingw' in ${prefix} .
3320     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3321     ;;
3322   *-mingw*)
3323   # MinGW can't be handled as Cygwin above since it does not use newlib.
3324     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3325     ;;
3326 esac
3327
3328 # Allow the user to override the flags for
3329 # our build compiler if desired.
3330 if test x"${build}" = x"${host}" ; then
3331   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3332   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3333   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3334 fi
3335
3336 # On Canadian crosses, we'll be searching the right directories for
3337 # the previously-installed cross compiler, so don't bother to add
3338 # flags for directories within the install tree of the compiler
3339 # being built; programs in there won't even run.
3340 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3341   # Search for pre-installed headers if nothing else fits.
3342   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3343 fi
3344
3345 if test "x${use_gnu_ld}" = x &&
3346    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3347   # Arrange for us to find uninstalled linker scripts.
3348   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3349 fi
3350
3351 # Search for other target-specific linker scripts and such.
3352 case "${target}" in
3353   mep*)
3354     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3355     ;;
3356 esac
3357
3358 # Makefile fragments.
3359 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3360 do
3361   eval fragval=\$$frag
3362   if test $fragval != /dev/null; then
3363     eval $frag=${srcdir}/$fragval
3364   fi
3365 done
3366 AC_SUBST_FILE(host_makefile_frag)
3367 AC_SUBST_FILE(target_makefile_frag)
3368 AC_SUBST_FILE(alphaieee_frag)
3369 AC_SUBST_FILE(ospace_frag)
3370
3371 # Miscellanea: directories, flags, etc.
3372 AC_SUBST(RPATH_ENVVAR)
3373 AC_SUBST(GCC_SHLIB_SUBDIR)
3374 AC_SUBST(tooldir)
3375 AC_SUBST(build_tooldir)
3376 AC_SUBST(CONFIGURE_GDB_TK)
3377 AC_SUBST(GDB_TK)
3378 AC_SUBST(INSTALL_GDB_TK)
3379
3380 # Build module lists & subconfigure args.
3381 AC_SUBST(build_configargs)
3382 AC_SUBST(build_configdirs)
3383
3384 # Host module lists & subconfigure args.
3385 AC_SUBST(host_configargs)
3386 AC_SUBST(configdirs)
3387 AC_SUBST(target_configdirs)
3388
3389 # Target module lists & subconfigure args.
3390 AC_SUBST(target_configargs)
3391
3392
3393 # Build tools.
3394 AC_SUBST(AR_FOR_BUILD)
3395 AC_SUBST(AS_FOR_BUILD)
3396 AC_SUBST(CC_FOR_BUILD)
3397 AC_SUBST(CFLAGS_FOR_BUILD)
3398 AC_SUBST(CXXFLAGS_FOR_BUILD)
3399 AC_SUBST(CXX_FOR_BUILD)
3400 AC_SUBST(DLLTOOL_FOR_BUILD)
3401 AC_SUBST(GFORTRAN_FOR_BUILD)
3402 AC_SUBST(GOC_FOR_BUILD)
3403 AC_SUBST(GDC_FOR_BUILD)
3404 AC_SUBST(LDFLAGS_FOR_BUILD)
3405 AC_SUBST(LD_FOR_BUILD)
3406 AC_SUBST(NM_FOR_BUILD)
3407 AC_SUBST(RANLIB_FOR_BUILD)
3408 AC_SUBST(WINDMC_FOR_BUILD)
3409 AC_SUBST(WINDRES_FOR_BUILD)
3410
3411 # Generate default definitions for YACC, M4, LEX and other programs that run
3412 # on the build machine.  These are used if the Makefile can't locate these
3413 # programs in objdir.
3414 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3415
3416 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3417 case " $build_configdirs " in
3418   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3419 esac
3420
3421 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3422 case " $build_configdirs " in
3423   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3424 esac
3425
3426 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3427 case " $build_configdirs " in
3428   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3429 esac
3430
3431 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3432 case " $build_configdirs " in
3433   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3434   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3435 esac
3436
3437 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3438 case " $build_configdirs " in
3439   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3440 esac
3441
3442 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3443 case " $build_configdirs " in
3444   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3445   *)
3446 changequote(,)
3447     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3448     # higher, else we use the "missing" dummy.
3449     if ${MAKEINFO} --version \
3450        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3451       :
3452     else
3453       MAKEINFO="$MISSING makeinfo"
3454     fi
3455     ;;
3456 changequote([,])
3457 esac
3458
3459 # FIXME: expect and dejagnu may become build tools?
3460
3461 AC_CHECK_PROGS(EXPECT, expect, expect)
3462 case " $configdirs " in
3463   *" expect "*)
3464     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3465     ;;
3466 esac
3467
3468 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3469 case " $configdirs " in
3470   *" dejagnu "*)
3471     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3472     ;;
3473 esac
3474
3475
3476 # Host tools.
3477 NCN_STRICT_CHECK_TOOLS(AR, ar)
3478 NCN_STRICT_CHECK_TOOLS(AS, as)
3479 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3480 NCN_STRICT_CHECK_TOOLS(LD, ld)
3481 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3482 NCN_STRICT_CHECK_TOOLS(NM, nm)
3483 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3484 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3485 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3486 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3487 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3488 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3489 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3490 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3491 AC_SUBST(CC)
3492 AC_SUBST(CXX)
3493 AC_SUBST(CFLAGS)
3494 AC_SUBST(CXXFLAGS)
3495
3496 # Target tools.
3497 AC_ARG_WITH([build-time-tools],
3498   [AS_HELP_STRING([--with-build-time-tools=PATH],
3499                   [use given path to find target tools during the build])],
3500   [case x"$withval" in
3501      x/*) ;;
3502      *)
3503        with_build_time_tools=
3504        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3505        ;;
3506    esac],
3507   [with_build_time_tools=])
3508
3509 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3510 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3511 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3512 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3513 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3514 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3515
3516 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3517 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3518 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3519 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3520 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3521 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3522 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3523 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3524 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3525 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3526 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3527 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3528 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3529 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3530
3531 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3532
3533 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3534 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3535 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3536 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3537 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3538                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3539                 c++)
3540 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3541                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3542                 c++)
3543 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3544 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3545 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3546                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3547 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3548                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3549 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3550                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3551 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3552 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3553 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3554 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3555 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3556 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3557 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3558 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3559 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3560 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3561 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3562
3563 AC_SUBST(FLAGS_FOR_TARGET)
3564 AC_SUBST(RAW_CXX_FOR_TARGET)
3565
3566 # Certain tools may need extra flags.
3567 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3568 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3569 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3570
3571 # When building target libraries, except in a Canadian cross, we use
3572 # the same toolchain as the compiler we just built.
3573 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3574 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3575 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3576 if test $host = $build; then
3577   case " $configdirs " in
3578     *" gcc "*)
3579       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3580       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3581       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3582       ;;
3583   esac
3584 fi
3585
3586 AC_SUBST(COMPILER_AS_FOR_TARGET)
3587 AC_SUBST(COMPILER_LD_FOR_TARGET)
3588 AC_SUBST(COMPILER_NM_FOR_TARGET)
3589
3590 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3591 AC_ARG_ENABLE(maintainer-mode,
3592 [AS_HELP_STRING([--enable-maintainer-mode],
3593                 [enable make rules and dependencies not useful
3594                  (and sometimes confusing) to the casual installer])],
3595       USE_MAINTAINER_MODE=$enableval,
3596       USE_MAINTAINER_MODE=no)
3597 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3598 AC_SUBST(MAINTAINER_MODE_TRUE)
3599 AC_SUBST(MAINTAINER_MODE_FALSE)
3600 if test "$USE_MAINTAINER_MODE" = yes; then
3601   MAINTAINER_MODE_TRUE=
3602   MAINTAINER_MODE_FALSE='#'
3603 else
3604   MAINTAINER_MODE_TRUE='#'
3605   MAINTAINER_MODE_FALSE=
3606 fi
3607 MAINT=$MAINTAINER_MODE_TRUE
3608 AC_SUBST(MAINT)dnl
3609
3610 # ---------------------
3611 # GCC bootstrap support
3612 # ---------------------
3613
3614 # Stage specific cflags for build.
3615 stage1_cflags="-g"
3616 case $build in
3617   vax-*-*)
3618     case ${GCC} in
3619       yes) stage1_cflags="-g -Wa,-J" ;;
3620       *) stage1_cflags="-g -J" ;;
3621     esac ;;
3622 esac
3623
3624 AC_SUBST(stage1_cflags)
3625
3626 # Enable --enable-checking in stage1 of the compiler.
3627 AC_ARG_ENABLE(stage1-checking,
3628 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3629                 [choose additional checking for stage1 of the compiler])],
3630 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3631 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3632   # For --disable-checking or implicit --enable-checking=release, avoid
3633   # setting --enable-checking=gc in the default stage1 checking for LTO
3634   # bootstraps.  See PR62077.
3635   case $BUILD_CONFIG in
3636     *lto*)
3637       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3638     *)
3639       stage1_checking=--enable-checking=yes,types;;
3640   esac
3641   if test "x$enable_checking" = x && \
3642      test -d ${srcdir}/gcc && \
3643      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3644     stage1_checking=--enable-checking=yes,types,extra
3645   fi
3646 else
3647   stage1_checking=--enable-checking=$enable_checking,types
3648 fi])
3649 AC_SUBST(stage1_checking)
3650
3651 # Enable -Werror in bootstrap stage2 and later.
3652 AC_ARG_ENABLE(werror,
3653 [AS_HELP_STRING([--enable-werror],
3654                 [enable -Werror in bootstrap stage2 and later])],
3655 [
3656 case ${enable_werror} in
3657   yes) stage2_werror_flag="--enable-werror-always" ;;
3658   *) stage2_werror_flag="" ;;
3659 esac
3660 ],
3661 [
3662 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3663   case $BUILD_CONFIG in
3664   bootstrap-debug)
3665       stage2_werror_flag="--enable-werror-always" ;;
3666   "")
3667       stage2_werror_flag="--enable-werror-always" ;;
3668   esac
3669 fi
3670 ])
3671
3672 AC_SUBST(stage2_werror_flag)
3673
3674 # Specify what files to not compare during bootstrap.
3675
3676 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3677 case "$target" in
3678   hppa*64*-*-hpux*) ;;
3679   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3680   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3681 esac
3682 AC_SUBST(compare_exclusions)
3683
3684 AC_CONFIG_FILES([Makefile],
3685   [sed "$extrasub_build" Makefile |
3686    sed "$extrasub_host" |
3687    sed "$extrasub_target" > mf$$
3688    mv -f mf$$ Makefile],
3689   [extrasub_build="$extrasub_build"
3690    extrasub_host="$extrasub_host"
3691    extrasub_target="$extrasub_target"])
3692 AC_OUTPUT