libcpp/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT(cpplib, [ ], gcc-bugs@gcc.gnu.org, cpplib)
   5 AC_CONFIG_SRCDIR(ucnid.h)
   6 AC_CONFIG_MACRO_DIR(../config)
   7 AC_CANONICAL_SYSTEM
   8
   9 # Checks for programs.
  10 AC_PROG_MAKE_SET
  11 AC_PROG_INSTALL
  12 AC_PROG_CC
  13 AC_PROG_CXX
  14 AC_PROG_RANLIB
  15 AC_CHECK_TOOL(AR, ar)
  16
  17 AC_USE_SYSTEM_EXTENSIONS
  18 AC_SYS_LARGEFILE
  19
  20 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
  21 AC_CHECK_PROGS([ACLOCAL], [aclocal], [$MISSING aclocal])
  22 AC_CHECK_PROGS([AUTOCONF], [autoconf], [$MISSING autoconf])
  23 AC_CHECK_PROGS([AUTOHEADER], [autoheader], [$MISSING autoheader])
  24
  25 if test -z "$ETAGS"; then
  26   ETAGS=etags
  27 fi
  28 AC_SUBST([ETAGS])
  29
  30 # Figure out what compiler warnings we can enable.
  31 # See config/warnings.m4 for details.
  32
  33 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wno-narrowing -Wwrite-strings \
  34                           -Wmissing-format-attribute], [warn])
  35 ACX_PROG_CC_WARNING_OPTS([-Wstrict-prototypes -Wmissing-prototypes \
  36                           -Wold-style-definition -Wc++-compat], [c_warn])
  37 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long])
  38
  39 # Disable exceptions and RTTI if building with g++
  40 ACX_PROG_CC_WARNING_OPTS(
  41        m4_quote(m4_do([-fno-exceptions -fno-rtti])), [noexception_flags])
  42
  43 # Only enable with --enable-werror-always until existing warnings are
  44 # corrected.
  45 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual])
  46
  47 # Dependency checking.
  48 ZW_CREATE_DEPDIR
  49 AC_LANG_PUSH([C++])
  50 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])], [],
  51                   [AC_MSG_ERROR([C++ compiler missing or inoperational])])
  52 AC_LANG_POP([C++])
  53 ZW_PROG_COMPILER_DEPENDENCIES([CXX])
  54
  55 # Checks for header files.
  56 AC_HEADER_TIME
  57 ACX_HEADER_STRING
  58
  59 AC_CHECK_HEADERS(locale.h fcntl.h limits.h stddef.h \
  60         stdlib.h strings.h string.h sys/file.h unistd.h)
  61
  62 # Checks for typedefs, structures, and compiler characteristics.
  63 AC_C_BIGENDIAN
  64 AC_C_CONST
  65 AC_C_INLINE
  66 AC_FUNC_OBSTACK
  67 AC_TYPE_OFF_T
  68 AC_TYPE_SIZE_T
  69 AC_TYPE_SSIZE_T
  70 AC_TYPE_UINTPTR_T
  71 AC_CHECK_TYPE(ptrdiff_t, int)
  72 AC_TYPE_UINT64_T
  73 if test x"$ac_cv_c_uint64_t" = x"no"; then
  74   AC_MSG_ERROR([uint64_t not found])
  75 fi
  76 AC_STRUCT_TM
  77 AC_CHECK_SIZEOF(int)
  78 AC_CHECK_SIZEOF(long)
  79 define(libcpp_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
  80   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
  81   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
  82   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
  83   putchar_unlocked putc_unlocked)
  84 AC_CHECK_FUNCS(libcpp_UNLOCKED_FUNCS)
  85 AC_CHECK_DECLS([abort, asprintf, basename(char *), errno, getopt, vasprintf])
  86 AC_CHECK_DECLS(m4_split(m4_normalize(libcpp_UNLOCKED_FUNCS)))
  87
  88 # Checks for library functions.
  89 AC_FUNC_ALLOCA
  90 AC_HEADER_STDC
  91 AM_LANGINFO_CODESET
  92 ZW_GNU_GETTEXT_SISTER_DIR
  93
  94 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
  95 [AC_TRY_COMPILE([
  96 #include <sys/types.h>
  97 ],
  98 [if ((uchar *)0) return 0;
  99  if (sizeof(uchar)) return 0;],
 100 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
 101 if test $ac_cv_type_uchar = yes; then
 102   AC_DEFINE(HAVE_UCHAR, 1,
 103   [Define if <sys/types.h> defines \`uchar'.])
 104 fi
 105
 106 AC_CHECK_SIZEOF(ino_t)
 107 AC_CHECK_SIZEOF(dev_t)
 108
 109 # g++ on Solaris 10+ defines _XOPEN_SOURCE=600, which exposes a different
 110 # iconv() prototype.
 111 AC_LANG_PUSH([C++])
 112 AM_ICONV
 113 AC_LANG_POP([C++])
 114
 115 # More defines and substitutions.
 116 PACKAGE="$PACKAGE_TARNAME"
 117 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Define to the name of this package.])
 118 AC_SUBST(PACKAGE)
 119
 120 if test "x$enable_nls" != xno; then
 121   USED_CATALOGS='$(CATALOGS)'
 122 else
 123   USED_CATALOGS=
 124 fi
 125 AC_SUBST(USED_CATALOGS)
 126
 127 AC_ARG_ENABLE(maintainer-mode,
 128 [  --enable-maintainer-mode enable rules only needed by maintainers],,
 129 enable_maintainer_mode=no)
 130
 131 if test "x$enable_maintainer_mode" = xno; then
 132   MAINT='#'
 133 else
 134   MAINT=
 135 fi
 136 AC_SUBST(MAINT)
 137
 138 # Enable expensive internal checks
 139 is_release=
 140 if test -f $srcdir/../gcc/DEV-PHASE \
 141    && test x"`cat $srcdir/../gcc/DEV-PHASE`" != xexperimental; then
 142   is_release=yes
 143 fi
 144
 145 AC_ARG_ENABLE(checking,
 146 [AS_HELP_STRING([[--enable-checking[=LIST]]],
 147                 [enable expensive run-time checks.  With LIST,
 148                  enable only specific categories of checks.
 149                  Categories are: yes,no,all,none,release.
 150                  Flags are: misc,valgrind or other strings])],
 151 [ac_checking_flags="${enableval}"],[
 152 # Determine the default checks.
 153 if test x$is_release = x ; then
 154   ac_checking_flags=yes
 155 else
 156   ac_checking_flags=release
 157 fi])
 158 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 159 for check in release $ac_checking_flags
 160 do
 161         case $check in
 162         # these set all the flags to specific states
 163         yes|all) ac_checking=1 ; ac_assert_checking=1 ; ac_valgrind_checking= ;;
 164         no|none) ac_checking= ; ac_assert_checking= ; ac_valgrind_checking= ;;
 165         release) ac_checking= ; ac_assert_checking=1 ; ac_valgrind_checking= ;;
 166         # these enable particular checks
 167         assert) ac_assert_checking=1 ;;
 168         misc) ac_checking=1 ;;
 169         valgrind) ac_valgrind_checking=1 ;;
 170         # accept
 171         *) ;;
 172         esac
 173 done
 174 IFS="$ac_save_IFS"
 175
 176 if test x$ac_checking != x ; then
 177   AC_DEFINE(CHECKING_P, 1,
 178 [Define to 1 if you want more run-time sanity checks.])
 179 else
 180   AC_DEFINE(CHECKING_P, 0)
 181 fi
 182
 183 if test x$ac_assert_checking != x ; then
 184   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 185 [Define if you want assertions enabled.  This is a cheap check.])
 186 fi
 187
 188 if test x$ac_valgrind_checking != x ; then
 189   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 190 [Define if you want to workaround valgrind (a memory checker) warnings about
 191  possible memory leaks because of libcpp use of interior pointers.])
 192 fi
 193
 194 AC_ARG_ENABLE(canonical-system-headers,
 195 [  --enable-canonical-system-headers
 196                           enable or disable system headers canonicalization],
 197 [],
 198 enable_canonical_system_headers=yes)
 199 if test $enable_canonical_system_headers != no; then
 200   AC_DEFINE(ENABLE_CANONICAL_SYSTEM_HEADERS,
 201             1, [Define to enable system headers canonicalization.])
 202 fi
 203
 204 case $target in
 205   i?86-* | x86_64-*)
 206     AC_TRY_COMPILE([], [asm ("pcmpestri %0, %%xmm0, %%xmm1" : : "i"(0))],
 207       [AC_DEFINE([HAVE_SSE4], [1],
 208                  [Define to 1 if you can assemble SSE4 insns.])])
 209 esac
 210
 211 # Enable --enable-host-shared.
 212 AC_ARG_ENABLE(host-shared,
 213 [AS_HELP_STRING([--enable-host-shared],
 214                 [build host code as shared libraries])])
 215 AC_SUBST(enable_host_shared)
 216
 217 # Enable --enable-host-pie.
 218 AC_ARG_ENABLE(host-pie,
 219 [AS_HELP_STRING([--enable-host-pie],
 220                 [build host code as PIE])])
 221 AC_SUBST(enable_host_pie)
 222
 223 if test x$enable_host_shared = xyes; then
 224   PICFLAG=-fPIC
 225 elif test x$enable_host_pie = xyes; then
 226   PICFLAG=-fPIE
 227 else
 228   PICFLAG=
 229 fi
 230
 231 AC_SUBST(PICFLAG)
 232
 233 # Enable Intel CET on Intel CET enabled host if jit is enabled.
 234 GCC_CET_HOST_FLAGS(CET_HOST_FLAGS)
 235 case x$enable_languages in
 236 *jit*)
 237   ;;
 238 *)
 239   CET_HOST_FLAGS=
 240   ;;
 241 esac
 242 AC_SUBST(CET_HOST_FLAGS)
 243
 244 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 245 dnl # an if statement.  This was the source of very frustrating bugs
 246 dnl # in converting to autoconf 2.5x!
 247 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 248
 249 # It is certainly possible that there's valgrind but no valgrind.h.
 250 # GCC relies on making annotations so we must have both.
 251 AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 252 AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 253   [[#include <valgrind/memcheck.h>
 254 #ifndef VALGRIND_DISCARD
 255 #error VALGRIND_DISCARD not defined
 256 #endif]])],
 257   [gcc_cv_header_valgrind_memcheck_h=yes],
 258   [gcc_cv_header_valgrind_memcheck_h=no])
 259 AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 260 AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 261 AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 262   [[#include <memcheck.h>
 263 #ifndef VALGRIND_DISCARD
 264 #error VALGRIND_DISCARD not defined
 265 #endif]])],
 266   [gcc_cv_header_memcheck_h=yes],
 267   [gcc_cv_header_memcheck_h=no])
 268 AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 269 if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 270   AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 271         [Define if valgrind's valgrind/memcheck.h header is installed.])
 272 fi
 273 if test $gcc_cv_header_memcheck_h = yes; then
 274   AC_DEFINE(HAVE_MEMCHECK_H, 1,
 275         [Define if valgrind's memcheck.h header is installed.])
 276 fi
 277
 278 AC_ARG_ENABLE(valgrind-annotations,
 279 [AS_HELP_STRING([--enable-valgrind-annotations],
 280                 [enable valgrind runtime interaction])], [],
 281 [enable_valgrind_annotations=no])
 282 if test x$enable_valgrind_annotations != xno \
 283     || test x$ac_valgrind_checking != x; then
 284   if (test $have_valgrind_h = no \
 285       && test $gcc_cv_header_memcheck_h = no \
 286       && test $gcc_cv_header_valgrind_memcheck_h = no); then
 287     AC_MSG_ERROR([*** valgrind annotations requested, but])
 288     AC_MSG_ERROR([*** Can't find valgrind/memcheck.h, memcheck.h or valgrind.h])
 289   fi
 290   AC_DEFINE(ENABLE_VALGRIND_ANNOTATIONS, 1,
 291 [Define to get calls to the valgrind runtime enabled.])
 292 fi
 293
 294 # Output.
 295
 296 AC_CONFIG_HEADERS(config.h:config.in, [echo timestamp > stamp-h1])
 297 AC_CONFIG_FILES(Makefile)
 298 AC_OUTPUT