libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/lib-ld.m4)
   8 sinclude(../config/override.m4)
   9 sinclude(../config/picflag.m4)
  10 sinclude(../config/dfp.m4)
  11 sinclude(../config/unwind_ipinfo.m4)
  12 sinclude(../config/gthr.m4)
  13 sinclude(../config/sjlj.m4)
  14 sinclude(../config/cet.m4)
  15
  16 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  17 AC_CONFIG_SRCDIR([static-object.mk])
  18
  19 # The libgcc should not depend on any header files
  20 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  21   [m4_divert_text([DEFAULTS],
  22     [ac_includes_default='/* none */'])])
  23
  24 AC_ARG_WITH(target-subdir,
  25 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  26 AC_ARG_WITH(cross-host,
  27 [  --with-cross-host=HOST           Configuring with a cross compiler])
  28 AC_ARG_WITH(ld,
  29 [  --with-ld               arrange to use the specified ld (full pathname)])
  30
  31 if test "${srcdir}" = "."; then
  32   if test -n "${with_build_subdir}"; then
  33     libgcc_topdir="${srcdir}/../.."
  34     with_target_subdir=
  35   elif test -z "${with_target_subdir}"; then
  36     libgcc_topdir="${srcdir}/.."
  37   else
  38     if test "${with_target_subdir}" != "."; then
  39       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  40     else
  41       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  42     fi
  43   fi
  44 else
  45   libgcc_topdir="${srcdir}/.."
  46 fi
  47 AC_SUBST(libgcc_topdir)
  48 AC_CONFIG_AUX_DIR($libgcc_topdir)
  49 AC_CONFIG_HEADER(auto-target.h:config.in)
  50
  51 AC_ARG_ENABLE(shared,
  52 [  --disable-shared        don't provide a shared libgcc],
  53 [
  54   case $enable_shared in
  55   yes | no) ;;
  56   *)
  57     enable_shared=no
  58     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  59     for pkg in $enableval; do
  60       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  61         enable_shared=yes
  62       fi
  63     done
  64     IFS="$ac_save_ifs"
  65     ;;
  66   esac
  67 ], [enable_shared=yes])
  68 AC_SUBST(enable_shared)
  69
  70 AC_ARG_ENABLE(gcov,
  71 [  --disable-gcov          don't provide libgcov and related host tools],
  72 [], [enable_gcov=yes])
  73 AC_SUBST(enable_gcov)
  74
  75 AC_ARG_ENABLE(vtable-verify,
  76 [  --enable-vtable-verify    Enable vtable verification feature ],
  77 [case "$enableval" in
  78  yes) enable_vtable_verify=yes ;;
  79  no)  enable_vtable_verify=no ;;
  80  *)   enable_vtable_verify=no;;
  81  esac],
  82 [enable_vtable_verify=no])
  83 AC_SUBST(enable_vtable_verify)
  84
  85 AC_ARG_WITH(aix-soname,
  86 [AS_HELP_STRING([--with-aix-soname=aix|svr4|both],
  87     [shared library versioning (aka "SONAME") variant to provide on AIX])],
  88 [case "${host}:${enable_shared}" in
  89  power*-*-aix[[5-9]]*:yes)
  90    AC_MSG_CHECKING([which variant of shared library versioning to provide for shared libgcc])
  91    case ${withval} in
  92      aix|svr4|both) ;;
  93      *) AC_MSG_ERROR([Unknown argument to --with-aix-soname]);;
  94    esac
  95    AC_MSG_RESULT($withval)
  96    ;;
  97  *) with_aix_soname=aix ;;
  98  esac
  99 ], [with_aix_soname=aix])
 100 AC_SUBST(with_aix_soname)
 101
 102 GCC_PICFLAG
 103 AC_SUBST(PICFLAG)
 104
 105 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 106 AC_ARG_ENABLE(version-specific-runtime-libs,
 107 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
 108 [case "$enableval" in
 109  yes) version_specific_libs=yes ;;
 110  no)  version_specific_libs=no ;;
 111  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 112  esac],
 113 [version_specific_libs=no])
 114 AC_MSG_RESULT($version_specific_libs)
 115
 116 AC_ARG_WITH(slibdir,
 117 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
 118 slibdir="$with_slibdir",
 119 if test "${version_specific_libs}" = yes; then
 120   slibdir='$(libsubdir)'
 121 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
 122   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
 123 else
 124   slibdir='$(libdir)'
 125 fi)
 126 AC_SUBST(slibdir)
 127
 128 # Command-line options.
 129 # Very limited version of AC_MAINTAINER_MODE.
 130 AC_ARG_ENABLE([maintainer-mode],
 131   [AC_HELP_STRING([--enable-maintainer-mode],
 132                  [enable make rules and dependencies not useful (and
 133                   sometimes confusing) to the casual installer])],
 134   [case ${enable_maintainer_mode} in
 135      yes) MAINT='' ;;
 136      no) MAINT='#' ;;
 137      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 138    esac
 139    maintainer_mode=${enableval}],
 140   [MAINT='#'])
 141 AC_SUBST([MAINT])dnl
 142
 143 AC_PROG_INSTALL
 144
 145 AC_PROG_AWK
 146 # We need awk; bail out if it's missing.
 147 case ${AWK} in
 148   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 149 esac
 150
 151 AC_CANONICAL_HOST
 152 ACX_NONCANONICAL_HOST
 153 ACX_NONCANONICAL_TARGET
 154 GCC_TOPLEV_SUBDIRS
 155
 156 # Calculate toolexeclibdir
 157 # Also toolexecdir, though it's only used in toolexeclibdir
 158 case ${version_specific_libs} in
 159   yes)
 160     # Need the gcc compiler version to know where to install libraries
 161     # and header files if --enable-version-specific-runtime-libs option
 162     # is selected.
 163     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 164     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 165     ;;
 166   no)
 167     if test -n "$with_cross_host" &&
 168        test x"$with_cross_host" != x"no"; then
 169       # Install a library built with a cross compiler in tooldir, not libdir.
 170       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 171       toolexeclibdir='$(toolexecdir)/lib'
 172     else
 173       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 174       toolexeclibdir='$(libdir)'
 175     fi
 176     multi_os_directory=`$CC -print-multi-os-directory`
 177     case $multi_os_directory in
 178       .) ;; # Avoid trailing /.
 179       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 180     esac
 181     ;;
 182 esac
 183 AC_SUBST(toolexecdir)
 184 AC_SUBST(toolexeclibdir)
 185
 186 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 187 dnl to call AC_CHECK_PROG.
 188 AC_CHECK_TOOL(AR, ar)
 189 AC_CHECK_TOOL(LIPO, lipo, :)
 190 AC_CHECK_TOOL(NM, nm)
 191 AC_CHECK_TOOL(RANLIB, ranlib, :)
 192 AC_CHECK_TOOL(STRIP, strip, :)
 193 AC_PROG_LN_S
 194
 195 GCC_NO_EXECUTABLES
 196 AC_PROG_CC
 197 AC_PROG_CPP_WERROR
 198
 199 AC_SYS_LARGEFILE
 200
 201 AC_CHECK_SIZEOF([double])
 202 AC_CHECK_SIZEOF([long double])
 203 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 204 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 205 AC_SUBST(double_type_size)
 206 AC_SUBST(long_double_type_size)
 207
 208 AC_CHECK_HEADERS(inttypes.h stdint.h stdlib.h ftw.h \
 209         unistd.h sys/stat.h sys/types.h \
 210         string.h strings.h memory.h)
 211 AC_HEADER_STDC
 212
 213 # Check for decimal float support.
 214 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 215                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 216 #include <fenv.h>
 217 ]], [[
 218 _Decimal32 x;
 219 int fe_except =
 220   FE_INVALID|FE_DIVBYZERO|FE_OVERFLOW|FE_UNDERFLOW|FE_INEXACT;
 221 ]])],
 222                                   [libgcc_cv_dfp=yes],
 223                                   [libgcc_cv_dfp=no])])
 224 decimal_float=$libgcc_cv_dfp
 225 AC_SUBST(decimal_float)
 226
 227 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 228
 229 # Check for fixed-point support.
 230 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 231                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Sat _Fract x;])],
 232                                   [libgcc_cv_fixed_point=yes],
 233                                   [libgcc_cv_fixed_point=no])])
 234 fixed_point=$libgcc_cv_fixed_point
 235 AC_SUBST(fixed_point)
 236
 237 # For platforms with the unwind ABI which includes an unwind library,
 238 # libunwind, we can choose to use the system libunwind.
 239 # config.gcc also contains tests of with_system_libunwind.
 240 GCC_CHECK_UNWIND_GETIPINFO
 241
 242 # Check if the compiler is configured for setjmp/longjmp exceptions.
 243 GCC_CHECK_SJLJ_EXCEPTIONS
 244
 245 GCC_CET_FLAGS(CET_FLAGS)
 246 AC_SUBST(CET_FLAGS)
 247
 248 AC_ARG_ENABLE([explicit-exception-frame-registration],
 249   [AC_HELP_STRING([--enable-explicit-exception-frame-registration],
 250      [register exception tables explicitly at module start, for use
 251       e.g. for compatibility with installations without PT_GNU_EH_FRAME support])],
 252 [
 253 force_explicit_eh_registry=
 254 if test "$enable_explicit_exception_frame_registration" = yes; then
 255   if test $ac_cv_sjlj_exceptions = yes; then
 256     AC_MSG_ERROR([Can't --enable-explicit-exception-frame-registration
 257                   with setjmp/longjmp exceptions])
 258   fi
 259   force_explicit_eh_registry=-DUSE_EH_FRAME_REGISTRY_ALWAYS
 260 fi
 261 ])
 262 AC_SUBST([force_explicit_eh_registry])
 263
 264 AC_LIB_PROG_LD_GNU
 265
 266 AC_MSG_CHECKING([for thread model used by GCC])
 267 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 268 AC_MSG_RESULT([$target_thread_file])
 269
 270 # Check for assembler CFI support.
 271 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 272                [AC_COMPILE_IFELSE(
 273 [AC_LANG_SOURCE([asm("\n\
 274         .text\n\
 275         .cfi_startproc\n\
 276         .cfi_personality 0, symbol\n\
 277         .cfi_endproc");])],
 278   [libgcc_cv_cfi=yes],
 279   [libgcc_cv_cfi=no])])
 280
 281 # Check 32bit or 64bit.  In the case of MIPS, this really determines the
 282 # word size rather than the address size.
 283 cat > conftest.c <<EOF
 284 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__)) \
 285     || defined(__mips64)
 286 host_address=64
 287 #else
 288 host_address=32
 289 #endif
 290 EOF
 291 eval `${CC-cc} -E conftest.c | grep host_address=`
 292 rm -f conftest.c
 293
 294 case ${host} in
 295 mips*-*-*)
 296   AC_CACHE_CHECK([whether the target is hard-float],
 297                  [libgcc_cv_mips_hard_float],
 298                  [AC_COMPILE_IFELSE(
 299     [AC_LANG_SOURCE([#ifndef __mips_hard_float
 300      #error FOO
 301      #endif
 302     ])],
 303     [libgcc_cv_mips_hard_float=yes],
 304     [libgcc_cv_mips_hard_float=no])])
 305 esac
 306
 307 case ${host} in
 308 *-*-solaris2*)
 309   # Check for system-provided CRTs on Solaris 11.4.
 310   AC_CACHE_CHECK([system-provided CRTs on Solaris],
 311                  [libgcc_cv_solaris_crts],
 312     [libgcc_cv_solaris_crts=no
 313      libgcc_sysroot="`${CC} -print-sysroot`"
 314      libgcc_libdir="$libgcc_sysroot/usr/lib"
 315      # At the time they were added, gcrt1.o became a symlink for backwards
 316      # compatibility on x86, while crt1.o was added on sparc, so check for that.
 317      case ${host} in
 318        i?86-*-solaris2* | x86_64-*-solaris2*)
 319          if test -h "$libgcc_libdir/gcrt1.o"; then libgcc_cv_solaris_crts=yes; fi
 320          ;;
 321        sparc*-*-solaris2*)
 322          if test -f "$libgcc_libdir/crt1.o"; then libgcc_cv_solaris_crts=yes; fi
 323          ;;
 324      esac])
 325   if test $libgcc_cv_solaris_crts = yes; then
 326     AC_DEFINE(HAVE_SOLARIS_CRTS, 1,
 327       [Define if the system-provided CRTs are present on Solaris.])
 328   fi
 329   ;;
 330 esac
 331
 332 # Determine the version of glibc, if any, used on the target.
 333 AC_MSG_CHECKING([for target glibc version])
 334 AC_ARG_WITH([glibc-version],
 335   [AS_HELP_STRING([--with-glibc-version=M.N],
 336     [assume GCC used with glibc version M.N or later])], [
 337 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
 338   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
 339   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
 340 else
 341   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
 342 fi], [
 343 AC_COMPUTE_INT([glibc_version_major], [__GLIBC__],
 344                                       [#include <features.h>],
 345                                       [glibc_version_major=0])
 346 AC_COMPUTE_INT([glibc_version_minor], [__GLIBC_MINOR__],
 347                                       [#include <features.h>],
 348                                       [glibc_version_minor=0])])
 349 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
 350
 351 # Determine floating-point type for powerpc*-*-linux*.
 352 # Single-precision-only FPRs are not a supported configuration for
 353 # this target, so are not allowed for in this test.
 354 case ${host} in
 355 powerpc*-*-linux*)
 356   cat > conftest.c <<EOF
 357 #ifdef __powerpc64__
 358 ppc_fp_type=64
 359 #elif defined _SOFT_FLOAT
 360 ppc_fp_type=soft
 361 #elif defined _SOFT_DOUBLE
 362 ppc_fp_type=e500v1
 363 #elif defined __NO_FPRS__
 364 ppc_fp_type=e500v2
 365 #else
 366 ppc_fp_type=hard
 367 #endif
 368 EOF
 369 eval `${CC-cc} -E conftest.c | grep ppc_fp_type=`
 370 rm -f conftest.c
 371 # glibc 2.19 and later provide all the soft-fp functions, with proper
 372 # interactions with <fenv.h> exception and rounding mode handling, so
 373 # make libgcc's versions into compat symbols if a recent enough glibc
 374 # version is being used.
 375 ppc_fp_compat=
 376 case ${ppc_fp_type} in
 377 soft|e500v1|e500v2)
 378   if test $glibc_version_major -gt 2 \
 379     || ( test $glibc_version_major -eq 2 \
 380         && test $glibc_version_minor -ge 19 ); then
 381     ppc_fp_compat="t-softfp-compat"
 382   fi
 383   ;;
 384 esac
 385 ;;
 386 esac
 387
 388 case ${host} in
 389 # At present, we cannot turn -mfloat128 on via #pragma GCC target, so just
 390 # check if we have VSX (ISA 2.06) support to build the software libraries, and
 391 # whether the assembler can handle xsaddqp for hardware support.  Also check if
 392 # a new glibc is being used so that __builtin_cpu_supports can be used.
 393 powerpc*-*-linux*)
 394   saved_CFLAGS="$CFLAGS"
 395   CFLAGS="$CFLAGS -mabi=altivec -mvsx -mfloat128"
 396   AC_CACHE_CHECK([for PowerPC ISA 2.06 to build __float128 libraries],
 397                  [libgcc_cv_powerpc_float128],
 398                  [AC_COMPILE_IFELSE(
 399     [AC_LANG_SOURCE([vector double dadd (vector double a, vector double b) { return a + b; }])],
 400     [libgcc_cv_powerpc_float128=yes],
 401     [libgcc_cv_powerpc_float128=no])])
 402
 403   CFLAGS="$CFLAGS -mpower9-vector -mfloat128-hardware"
 404   AC_CACHE_CHECK([for PowerPC ISA 3.0 to build hardware __float128 libraries],
 405                  [libgcc_cv_powerpc_float128_hw],
 406                  [AC_COMPILE_IFELSE(
 407     [AC_LANG_SOURCE([#include <sys/auxv.h>
 408      #ifndef AT_PLATFORM
 409      #error "AT_PLATFORM is not defined"
 410      #endif
 411      #ifndef __BUILTIN_CPU_SUPPORTS__
 412      #error "__builtin_cpu_supports is not available"
 413      #endif
 414      vector unsigned char add (vector unsigned char a, vector unsigned char b)
 415      {
 416        vector unsigned char ret;
 417        __asm__ ("xsaddqp %0,%1,%2" : "=v" (ret) : "v" (a), "v" (b));
 418        return ret;
 419      }
 420      void *add_resolver (void) { return (void *) add; }
 421      __float128 add_ifunc (__float128, __float128)
 422         __attribute__ ((__ifunc__ ("add_resolver")));])],
 423     [libgcc_cv_powerpc_float128_hw=yes],
 424     [libgcc_cv_powerpc_float128_hw=no])])
 425   CFLAGS="$saved_CFLAGS"
 426 esac
 427
 428 # Collect host-machine-specific information.
 429 . ${srcdir}/config.host
 430
 431 # Used for constructing correct paths for offload compilers.
 432 accel_dir_suffix=
 433 real_host_noncanonical=${host_noncanonical}
 434 if test x"$enable_as_accelerator_for" != x; then
 435   accel_dir_suffix=/accel/${target_noncanonical}
 436   real_host_noncanonical=${enable_as_accelerator_for}
 437 fi
 438 AC_SUBST(accel_dir_suffix)
 439 AC_SUBST(real_host_noncanonical)
 440
 441 if test x"$enable_offload_targets" != x; then
 442   extra_parts="${extra_parts} crtoffloadbegin.o crtoffloadend.o crtoffloadtable.o"
 443 fi
 444
 445 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 446 # This is after config.host so we can augment tmake_file.
 447 # Link with -nostartfiles -nodefaultlibs since neither are present while
 448 # building libgcc.
 449 case ${host} in
 450 i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 451   cat > conftest.s <<EOF
 452         .section        .eh_frame,"a",@unwind
 453         .zero   4
 454         .section        .jcr,"aw",@progbits
 455         .zero   8
 456 EOF
 457   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 458       tmake_file="${tmake_file} i386/t-crtstuff"
 459   fi
 460   ;;
 461 esac
 462
 463 # Check if Solaris linker support v2 linker mapfile syntax.
 464 # Link with -nostartfiles -nodefaultlibs since neither are present while
 465 # building libgcc.
 466 case ${host} in
 467 *-*-solaris2*)
 468   solaris_ld_v2_maps=no
 469   echo 'int main(void) {return 0;}' > conftest.c
 470   echo '$mapfile_version 2' > conftest.map
 471   if AC_TRY_COMMAND([${CC-cc} -nostartfiles -nodefaultlibs -Wl,-M,conftest.map -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
 472       solaris_ld_v2_maps=yes
 473   fi
 474   ;;
 475 esac
 476 AC_SUBST(solaris_ld_v2_maps)
 477
 478 # Check if xtensa target is configured for windowed ABI and thus needs to use
 479 # custom unwind code.
 480 # This is after config.host so we can augment tmake_file.
 481 case ${host} in
 482 xtensa*-*)
 483   cat > conftest.c <<EOF
 484         #ifdef __XTENSA_CALL0_ABI__
 485         #error
 486         #endif
 487 EOF
 488   if AC_TRY_COMMAND(${CC-cc} -E -o conftest.i conftest.c 1>&AS_MESSAGE_LOG_FD); then
 489       tmake_file="${tmake_file} xtensa/t-windowed"
 490   fi
 491   ;;
 492 esac
 493
 494 # Check for visibility support.  This is after config.host so that
 495 # we can check for asm_hidden_op.
 496 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 497     libgcc_cv_hidden_visibility_attribute, [
 498         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 499         libgcc_cv_hidden_visibility_attribute=no
 500         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 501             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 502                 libgcc_cv_hidden_visibility_attribute=yes
 503             fi
 504         fi
 505         rm -f conftest.*
 506     ])
 507
 508 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 509     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 510     AC_DEFINE_UNQUOTED(AS_HIDDEN_DIRECTIVE, $asm_hidden_op, [Define to the .hidden-like directive if it exists.])
 511 else
 512     vis_hide=
 513 fi
 514 AC_SUBST(vis_hide)
 515
 516 # Check for .cfi_sections .debug_frame support.
 517 AC_CACHE_CHECK([for .cfi_sections .debug_frame],
 518     libgcc_cv_cfi_sections_directive, [
 519         echo 'int foo (int, char *);' > conftest.c
 520         echo 'int bar (int x) { char *y = __builtin_alloca (x); return foo (x + 1, y) + 1; }' >> conftest.c
 521         libgcc_cv_cfi_sections_directive=no
 522         if AC_TRY_COMMAND(${CC-cc} -Werror -g -fno-asynchronous-unwind-tables -fno-unwind-tables -fno-exceptions -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 523             if grep "\\.cfi_sections.*\\.debug_frame" conftest.s >/dev/null; then
 524                 libgcc_cv_cfi_sections_directive=yes
 525             fi
 526         fi
 527         rm -f conftest.*
 528     ])
 529 if test $libgcc_cv_cfi_sections_directive = yes; then
 530     AC_DEFINE(HAVE_AS_CFI_SECTIONS, 1, [Define to 1 if the assembler supports .cfi_sections .debug_frame directive.])
 531 fi
 532
 533 # See if we have thread-local storage.  We can only test assembler
 534 # since link-time and run-time tests require the newly built
 535 # gcc, which can't be used to build executable due to that libgcc
 536 # is yet to be built here.
 537 GCC_CHECK_CC_TLS
 538 set_have_cc_tls=
 539 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 540   set_have_cc_tls="-DHAVE_CC_TLS"
 541 fi
 542 AC_SUBST(set_have_cc_tls)
 543
 544 # See if we have emulated thread-local storage.
 545 GCC_CHECK_EMUTLS
 546 set_use_emutls=
 547 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 548   set_use_emutls="-DUSE_EMUTLS"
 549 fi
 550 AC_SUBST(set_use_emutls)
 551
 552 dnl Check if as supports AVX instructions.
 553 AC_DEFUN([LIBGCC_CHECK_AS_AVX], [
 554 case "${target}" in
 555 i[[34567]]86-*-* | x86_64-*-*)
 556   AC_CACHE_CHECK([if the assembler supports AVX], libgcc_cv_as_avx, [
 557     AC_TRY_COMPILE([], [asm("vzeroupper");],
 558                    [libgcc_cv_as_avx=yes], [libgcc_cv_as_avx=no])
 559   ])
 560   if test x$libgcc_cv_as_avx = xyes; then
 561     AC_DEFINE(HAVE_AS_AVX, 1, [Define to 1 if the assembler supports AVX.])
 562   fi
 563   ;;
 564 esac])
 565 LIBGCC_CHECK_AS_AVX
 566
 567 dnl Check if as supports RTM instructions.
 568 AC_CACHE_CHECK(for init priority support, libgcc_cv_init_priority, [
 569 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,
 570   [[void ip (void) __attribute__ ((constructor (1)));]])],
 571   [libgcc_cv_init_priority=yes],[libgcc_cv_init_priority=no])])
 572 if test $libgcc_cv_init_priority = yes; then
 573   AC_DEFINE(HAVE_INIT_PRIORITY, 1,
 574   [Define if the compiler supports init priority.])
 575 fi
 576
 577 # Conditionalize the sfp-machine.h header for this target machine.
 578 if test -z "${sfp_machine_header}"; then
 579         sfp_machine_header=$cpu_type/sfp-machine.h
 580         if test -f ${srcdir}/config/${sfp_machine_header}; then
 581                 :
 582         else
 583                 sfp_machine_header=no-sfp-machine.h
 584         fi
 585 fi
 586 AC_SUBST(sfp_machine_header)
 587
 588 # Conditionalize the makefile for this target machine.
 589 tmake_file_=
 590 for f in ${tmake_file}
 591 do
 592         if test -f ${srcdir}/config/$f
 593         then
 594                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 595         fi
 596 done
 597 tmake_file="${tmake_file_}"
 598 AC_SUBST(tmake_file)
 599
 600 # Likewise export definitions for libgcc_tm.h
 601 tm_file_=
 602 for f in ${tm_file}
 603 do
 604         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 605 done
 606 tm_file="${tm_file_}"
 607 AC_SUBST(tm_file)
 608 AC_SUBST(tm_defines)
 609
 610 # Map from thread model to thread header.
 611 GCC_AC_THREAD_HEADER([$target_thread_file])
 612
 613 # Determine what GCC version number to use in filesystem paths.
 614 GCC_BASE_VER
 615
 616 # Substitute configuration variables
 617 AC_SUBST(cpu_type)
 618 AC_SUBST(extra_parts)
 619 AC_SUBST(asm_hidden_op)
 620 AC_SUBST(enable_execute_stack)
 621 AC_SUBST(unwind_header)
 622 AC_SUBST(md_unwind_header)
 623 AC_SUBST(sfp_machine_header)
 624 AC_SUBST(thread_header)
 625
 626 # We need multilib support.
 627 AC_CONFIG_FILES([Makefile])
 628 AC_CONFIG_COMMANDS([default],
 629   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 630 if test -n "$CONFIG_FILES"; then
 631   # FIXME: We shouldn't need to set ac_file
 632   ac_file=Makefile
 633   . ${libgcc_topdir}/config-ml.in
 634 fi]],
 635 [[srcdir=${srcdir}
 636 host=${host}
 637 with_target_subdir=${with_target_subdir}
 638 with_multisubdir=${with_multisubdir}
 639 ac_configure_args="--enable-multilib ${ac_configure_args}"
 640 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 641 libgcc_topdir=${libgcc_topdir}
 642 CC="${CC}"
 643 ]])
 644 AC_OUTPUT