libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.64)
   5 AC_INIT([GNU OpenMP Runtime Library], 1.0,,[libgomp])
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # -------
   9 # Options
  10 # -------
  11
  12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  13 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  14    [Specify that runtime libraries should be installed in a compiler-specific directory],
  15    permit yes|no)
  16 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  17
  18 # We would like our source tree to be readonly. However when releases or
  19 # pre-releases are generated, the flex/bison generated files as well as the
  20 # various formats of manuals need to be included along with the rest of the
  21 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  22 # just that.
  23 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  24 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  25    [put copies of generated files in source dir intended for creating source
  26     tarballs for users without texinfo bison or flex.],
  27    permit yes|no)
  28 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  29 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  30
  31
  32 # -------
  33 # -------
  34
  35 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  36 #
  37 # You will slowly go insane if you do not grok the following fact:  when
  38 # building this library, the top-level /target/ becomes the library's /host/.
  39 #
  40 # configure then causes --target to default to --host, exactly like any
  41 # other package using autoconf.  Therefore, 'target' and 'host' will
  42 # always be the same.  This makes sense both for native and cross compilers
  43 # just think about it for a little while.  :-)
  44 #
  45 # Also, if this library is being configured as part of a cross compiler, the
  46 # top-level configure script will pass the "real" host as $with_cross_host.
  47 #
  48 # Do not delete or change the following two lines.  For why, see
  49 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  50 AC_CANONICAL_SYSTEM
  51 target_alias=${target_alias-$host_alias}
  52
  53 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  54 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  55 #  1.9.0:  minimum required version
  56 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  57 #              of other PACKAGE_* variables will, however, and there's nothing
  58 #              we can do about that; they come from AC_INIT).
  59 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  60 #            file in the top srcdir, etc, etc), so stop complaining.
  61 #  no-dist:  we don't want 'dist' and related rules.
  62 #  -Wall:  turns on all automake warnings...
  63 #  -Wno-portability:  ...except this one, since GNU make is required.
  64 #  -Wno-override: ... and this one, since we do want this in testsuite.
  65 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  66 AM_ENABLE_MULTILIB(, ..)
  67
  68 # Calculate toolexeclibdir
  69 # Also toolexecdir, though it's only used in toolexeclibdir
  70 case ${enable_version_specific_runtime_libs} in
  71   yes)
  72     # Need the gcc compiler version to know where to install libraries
  73     # and header files if --enable-version-specific-runtime-libs option
  74     # is selected.
  75     toolexecdir='$(libdir)/gcc/$(target_alias)'
  76     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  77     ;;
  78   no)
  79     if test -n "$with_cross_host" &&
  80        test x"$with_cross_host" != x"no"; then
  81       # Install a library built with a cross compiler in tooldir, not libdir.
  82       toolexecdir='$(exec_prefix)/$(target_alias)'
  83       toolexeclibdir='$(toolexecdir)/lib'
  84     else
  85       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  86       toolexeclibdir='$(libdir)'
  87     fi
  88     multi_os_directory=`$CC -print-multi-os-directory`
  89     case $multi_os_directory in
  90       .) ;; # Avoid trailing /.
  91       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  92     esac
  93     ;;
  94 esac
  95 AC_SUBST(toolexecdir)
  96 AC_SUBST(toolexeclibdir)
  97
  98 # Check the compiler.
  99 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 100 # We must force CC to /not/ be precious variables; otherwise
 101 # the wrong, non-multilib-adjusted value will be used in multilibs.
 102 # As a side effect, we have to subst CFLAGS ourselves.
 103
 104 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 105 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 106 AC_PROG_CC
 107 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 108
 109 AC_SUBST(CFLAGS)
 110
 111 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 112 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 113 # in both places for now and restore CFLAGS at the end of config.
 114 save_CFLAGS="$CFLAGS"
 115
 116 # Add -Wall -Werror if we are using GCC.
 117 if test "x$GCC" = "xyes"; then
 118   XCFLAGS="$XCFLAGS -Wall -Werror"
 119 fi
 120
 121 # Find other programs we need.
 122 AC_CHECK_TOOL(AR, ar)
 123 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 124 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 125 AC_PROG_MAKE_SET
 126 AC_PROG_INSTALL
 127
 128 # See if makeinfo has been installed and is modern enough
 129 # that we can use it.
 130 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 131                    [GNU texinfo.* \([0-9][0-9.]*\)],
 132                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 133 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 134
 135
 136 # Configure libtool
 137 AM_PROG_LIBTOOL
 138 AC_SUBST(enable_shared)
 139 AC_SUBST(enable_static)
 140
 141 AM_MAINTAINER_MODE
 142
 143 # Create a spec file, so that compile/link tests don't fail
 144 test -f libgfortran.spec || touch libgfortran.spec
 145 FCFLAGS="$FCFLAGS -L."
 146
 147 # We need gfortran to compile parts of the library
 148 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 149 #AC_PROG_FC(gfortran)
 150 case `echo $GFORTRAN` in
 151   -* | no* )
 152     FC=no ;;
 153   *)
 154     set dummy $GFORTRAN; ac_word=$2
 155     if test -x "$ac_word"; then
 156       FC="$GFORTRAN"
 157     else
 158       FC=no
 159     fi ;;
 160 esac
 161 AC_PROG_FC(gfortran)
 162 FCFLAGS="$FCFLAGS -Wall -L../libgfortran"
 163
 164 # For libtool versioning info, format is CURRENT:REVISION:AGE
 165 libtool_VERSION=1:0:0
 166 AC_SUBST(libtool_VERSION)
 167
 168 # Check header files.
 169 AC_STDC_HEADERS
 170 AC_HEADER_TIME
 171 ACX_HEADER_STRING
 172 AC_CHECK_HEADERS(unistd.h semaphore.h sys/loadavg.h sys/time.h sys/time.h)
 173
 174 GCC_HEADER_STDINT(gstdint.h)
 175
 176 # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 177 # In case the pthread.h system header is not found, this test will fail.
 178 XPCFLAGS=""
 179 CFLAGS="$CFLAGS -pthread"
 180 AC_LINK_IFELSE(
 181  [AC_LANG_PROGRAM(
 182   [#include <pthread.h>
 183    void *g(void *d) { return NULL; }],
 184   [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 185  [XPCFLAGS=" -Wc,-pthread"],
 186  [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 187   AC_LINK_IFELSE(
 188    [AC_LANG_PROGRAM(
 189     [#include <pthread.h>
 190      void *g(void *d) { return NULL; }],
 191     [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 192    [],
 193    [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 194
 195 # Check for functions needed.
 196 AC_CHECK_FUNCS(getloadavg clock_gettime strtoull)
 197
 198 # Check for broken semaphore implementation on darwin.
 199 # sem_init returns: sem_init error: Function not implemented.
 200 case "$host" in
 201   *-darwin*)
 202     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 203         Define if the POSIX Semaphores do not work on your system.)
 204     ;;
 205 esac
 206
 207 GCC_LINUX_FUTEX(:)
 208
 209 # Check for pthread_{,attr_}[sg]etaffinity_np.
 210 AC_LINK_IFELSE(
 211  [AC_LANG_PROGRAM(
 212   [#define _GNU_SOURCE
 213    #include <pthread.h>],
 214   [cpu_set_t cpuset;
 215    pthread_attr_t attr;
 216    pthread_getaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 217    if (CPU_ISSET (0, &cpuset))
 218      CPU_SET (1, &cpuset);
 219    else
 220      CPU_ZERO (&cpuset);
 221    pthread_setaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 222    pthread_attr_init (&attr);
 223    pthread_attr_getaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);
 224    pthread_attr_setaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);])],
 225   AC_DEFINE(HAVE_PTHREAD_AFFINITY_NP, 1,
 226 [       Define if pthread_{,attr_}{g,s}etaffinity_np is supported.]))
 227
 228 # At least for glibc, clock_gettime is in librt.  But don't pull that
 229 # in if it still doesn't give us the function we want.
 230 if test $ac_cv_func_clock_gettime = no; then
 231   AC_CHECK_LIB(rt, clock_gettime,
 232     [LIBS="-lrt $LIBS"
 233      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 234                [Define to 1 if you have the `clock_gettime' function.])])
 235 fi
 236
 237 # See if we support thread-local storage.
 238 GCC_CHECK_TLS
 239
 240 # See what sort of export controls are availible.
 241 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 242 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 243 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 244 LIBGOMP_ENABLE_SYMVERS
 245
 246 if test $enable_symvers = gnu; then
 247   AC_DEFINE(LIBGOMP_GNU_SYMBOL_VERSIONING, 1,
 248             [Define to 1 if GNU symbol versioning is used for libgomp.])
 249 fi
 250
 251 # Get target configury.
 252 . ${srcdir}/configure.tgt
 253 CFLAGS="$save_CFLAGS $XCFLAGS"
 254
 255 # Check for __sync_val_compare_and_swap, but only after the target has
 256 # had a chance to set XCFLAGS.
 257 LIBGOMP_CHECK_SYNC_BUILTINS
 258
 259 XCFLAGS="$XCFLAGS$XPCFLAGS"
 260
 261 AC_SUBST(config_path)
 262 AC_SUBST(XCFLAGS)
 263 AC_SUBST(XLDFLAGS)
 264
 265 # Cleanup and exit.
 266 CFLAGS="$save_CFLAGS"
 267 AC_CACHE_SAVE
 268
 269 if test ${multilib} = yes; then
 270   multilib_arg="--enable-multilib"
 271 else
 272   multilib_arg=
 273 fi
 274
 275 # Set up the set of libraries that we need to link against for libgomp.
 276 # Note that the GOMP_SELF_SPEC in gcc.c will force -pthread for -fopenmp,
 277 # which will force linkage against -lpthread (or equivalent for the system).
 278 # That's not 100% ideal, but about the best we can do easily.
 279 if test $enable_shared = yes; then
 280   link_gomp="-lgomp %{static: $LIBS}"
 281 else
 282   link_gomp="-lgomp $LIBS"
 283 fi
 284 AC_SUBST(link_gomp)
 285
 286 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 287
 288 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 289 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 290 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 291 # need to copy this macro to our acinclude.m4.
 292 save_CFLAGS="$CFLAGS"
 293 for i in $config_path; do
 294   if test -f $srcdir/config/$i/omp-lock.h; then
 295     CFLAGS="$CFLAGS -include confdefs.h -include $srcdir/config/$i/omp-lock.h"
 296     break
 297   fi
 298 done
 299
 300 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 301   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 302 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 303 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 304 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 305 _AC_COMPUTE_INT([sizeof (omp_lock_25_t)], [OMP_LOCK_25_SIZE],,
 306   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_25_t)])])
 307 _AC_COMPUTE_INT([__alignof (omp_lock_25_t)], [OMP_LOCK_25_ALIGN])
 308 _AC_COMPUTE_INT([sizeof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_SIZE])
 309 _AC_COMPUTE_INT([__alignof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_ALIGN])
 310
 311 # If the lock fits in an integer, then arrange for Fortran to use that
 312 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 313 # Except that we don't have a way at present to multi-lib the installed
 314 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 315 # actual target.
 316 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 317 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 318 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 319   OMP_LOCK_KIND=8
 320 fi
 321 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 322   OMP_NEST_LOCK_KIND=8
 323 fi
 324 OMP_LOCK_25_KIND=$OMP_LOCK_25_SIZE
 325 OMP_NEST_LOCK_25_KIND=$OMP_NEST_LOCK_25_SIZE
 326 if test $OMP_LOCK_25_SIZE -gt 8 || test $OMP_LOCK_25_ALIGN -gt $OMP_LOCK_25_SIZE; then
 327   OMP_LOCK_25_KIND=8
 328 fi
 329 if test $OMP_NEST_LOCK_25_SIZE -gt 8 || test $OMP_NEST_LOCK_25_ALIGN -gt $OMP_NEST_LOCK_25_SIZE; then
 330   OMP_NEST_LOCK_25_KIND=8
 331 fi
 332
 333 AC_SUBST(OMP_LOCK_SIZE)
 334 AC_SUBST(OMP_LOCK_ALIGN)
 335 AC_SUBST(OMP_NEST_LOCK_SIZE)
 336 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 337 AC_SUBST(OMP_LOCK_KIND)
 338 AC_SUBST(OMP_NEST_LOCK_KIND)
 339 AC_SUBST(OMP_LOCK_25_SIZE)
 340 AC_SUBST(OMP_LOCK_25_ALIGN)
 341 AC_SUBST(OMP_NEST_LOCK_25_SIZE)
 342 AC_SUBST(OMP_NEST_LOCK_25_ALIGN)
 343 AC_SUBST(OMP_LOCK_25_KIND)
 344 AC_SUBST(OMP_NEST_LOCK_25_KIND)
 345 CFLAGS="$save_CFLAGS"
 346
 347 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 348 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 349 AC_OUTPUT