libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_INIT([GNU Offloading and Multi Processing Runtime Library], 1.0,,[libgomp])
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # -------
   8 # Options
   9 # -------
  10
  11 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  12 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  13    [Specify that runtime libraries should be installed in a compiler-specific directory],
  14    permit yes|no)
  15 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  16
  17 # We would like our source tree to be readonly. However when releases or
  18 # pre-releases are generated, the flex/bison generated files as well as the
  19 # various formats of manuals need to be included along with the rest of the
  20 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  21 # just that.
  22 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  23 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  24    [put copies of generated files in source dir intended for creating source
  25     tarballs for users without texinfo bison or flex.],
  26    permit yes|no)
  27 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  28 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  29
  30
  31 # -------
  32 # -------
  33
  34 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  35 #
  36 # You will slowly go insane if you do not grok the following fact:  when
  37 # building this library, the top-level /target/ becomes the library's /host/.
  38 #
  39 # configure then causes --target to default to --host, exactly like any
  40 # other package using autoconf.  Therefore, 'target' and 'host' will
  41 # always be the same.  This makes sense both for native and cross compilers
  42 # just think about it for a little while.  :-)
  43 #
  44 # Also, if this library is being configured as part of a cross compiler, the
  45 # top-level configure script will pass the "real" host as $with_cross_host.
  46 #
  47 # Do not delete or change the following two lines.  For why, see
  48 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  49 AC_CANONICAL_SYSTEM
  50 target_alias=${target_alias-$host_alias}
  51
  52 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  53 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  54 #  1.9.0:  minimum required version
  55 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  56 #              of other PACKAGE_* variables will, however, and there's nothing
  57 #              we can do about that; they come from AC_INIT).
  58 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  59 #            file in the top srcdir, etc, etc), so stop complaining.
  60 #  no-dist:  we don't want 'dist' and related rules.
  61 #  -Wall:  turns on all automake warnings...
  62 #  -Wno-portability:  ...except this one, since GNU make is required.
  63 #  -Wno-override: ... and this one, since we do want this in testsuite.
  64 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  65 AM_ENABLE_MULTILIB(, ..)
  66
  67 # Calculate toolexeclibdir
  68 # Also toolexecdir, though it's only used in toolexeclibdir
  69 case ${enable_version_specific_runtime_libs} in
  70   yes)
  71     # Need the gcc compiler version to know where to install libraries
  72     # and header files if --enable-version-specific-runtime-libs option
  73     # is selected.
  74     toolexecdir='$(libdir)/gcc/$(target_alias)'
  75     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  76     ;;
  77   no)
  78     if test -n "$with_cross_host" &&
  79        test x"$with_cross_host" != x"no"; then
  80       # Install a library built with a cross compiler in tooldir, not libdir.
  81       toolexecdir='$(exec_prefix)/$(target_alias)'
  82       toolexeclibdir='$(toolexecdir)/lib'
  83     else
  84       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  85       toolexeclibdir='$(libdir)'
  86     fi
  87     multi_os_directory=`$CC -print-multi-os-directory`
  88     case $multi_os_directory in
  89       .) ;; # Avoid trailing /.
  90       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  91     esac
  92     ;;
  93 esac
  94 AC_SUBST(toolexecdir)
  95 AC_SUBST(toolexeclibdir)
  96
  97 # Check the compiler.
  98 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  99 # We must force CC to /not/ be precious variables; otherwise
 100 # the wrong, non-multilib-adjusted value will be used in multilibs.
 101 # As a side effect, we have to subst CFLAGS ourselves.
 102
 103 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 104 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 105 AC_PROG_CC
 106 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 107
 108 AC_SUBST(CFLAGS)
 109
 110 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 111 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 112 # in both places for now and restore CFLAGS at the end of config.
 113 save_CFLAGS="$CFLAGS"
 114
 115 # Add -Wall -Werror if we are using GCC.
 116 if test "x$GCC" = "xyes"; then
 117   XCFLAGS="$XCFLAGS -Wall -Werror"
 118 fi
 119
 120 # Find other programs we need.
 121 AC_CHECK_TOOL(AR, ar)
 122 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 123 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 124 AC_PROG_MAKE_SET
 125 AC_PROG_INSTALL
 126
 127 # See if makeinfo has been installed and is modern enough
 128 # that we can use it.
 129 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 130                    [GNU texinfo.* \([0-9][0-9.]*\)],
 131                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 132 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 133
 134
 135 # Configure libtool
 136 AM_PROG_LIBTOOL
 137 ACX_LT_HOST_FLAGS
 138 AC_SUBST(enable_shared)
 139 AC_SUBST(enable_static)
 140
 141 AM_MAINTAINER_MODE
 142
 143 # Create a spec file, so that compile/link tests don't fail
 144 test -f libgfortran.spec || touch libgfortran.spec
 145 FCFLAGS="$FCFLAGS -L."
 146
 147 # We need gfortran to compile parts of the library
 148 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 149 #AC_PROG_FC(gfortran)
 150 case `echo $GFORTRAN` in
 151   -* | no* )
 152     FC=no ;;
 153   *)
 154     set dummy $GFORTRAN; ac_word=$2
 155     if test -x "$ac_word"; then
 156       FC="$GFORTRAN"
 157     else
 158       FC=no
 159     fi ;;
 160 esac
 161 AC_PROG_FC(gfortran)
 162 FCFLAGS="$FCFLAGS -Wall -L../libgfortran"
 163
 164 # For libtool versioning info, format is CURRENT:REVISION:AGE
 165 libtool_VERSION=1:0:0
 166 AC_SUBST(libtool_VERSION)
 167
 168 # Check header files.
 169 AC_STDC_HEADERS
 170 AC_HEADER_TIME
 171 ACX_HEADER_STRING
 172 AC_CHECK_HEADERS(pthread.h unistd.h semaphore.h sys/loadavg.h sys/sysctl.h sys/time.h)
 173
 174 GCC_HEADER_STDINT(gstdint.h)
 175
 176 XPCFLAGS=""
 177 case "$host" in
 178   *-*-rtems*)
 179     # RTEMS supports Pthreads, but the library is not available at GCC build time.
 180     ;;
 181   nvptx*-*-*)
 182     # NVPTX does not support Pthreads, has its own code replacement.
 183     libgomp_use_pthreads=no
 184     # NVPTX is an accelerator-only target
 185     libgomp_offloaded_only=yes
 186     ;;
 187   *)
 188     # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 189     # In case the pthread.h system header is not found, this test will fail.
 190     CFLAGS="$CFLAGS -pthread"
 191     AC_LINK_IFELSE(
 192      [AC_LANG_PROGRAM(
 193       [#include <pthread.h>
 194        void *g(void *d) { return NULL; }],
 195       [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 196      [XPCFLAGS=" -Wc,-pthread"],
 197      [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 198       AC_LINK_IFELSE(
 199        [AC_LANG_PROGRAM(
 200         [#include <pthread.h>
 201          void *g(void *d) { return NULL; }],
 202         [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 203        [],
 204        [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 205 esac
 206
 207 if test x$libgomp_use_pthreads != xno; then
 208   AC_DEFINE(LIBGOMP_USE_PTHREADS, 1,
 209             [Define to 1 if libgomp should use POSIX threads.])
 210 fi
 211
 212 if test x$libgomp_offloaded_only = xyes; then
 213   AC_DEFINE(LIBGOMP_OFFLOADED_ONLY, 1,
 214             [Define to 1 if building libgomp for an accelerator-only target.])
 215 fi
 216
 217 m4_include([plugin/configfrag.ac])
 218
 219 # Check for functions needed.
 220 AC_CHECK_FUNCS(getloadavg clock_gettime strtoull)
 221
 222 # Check for broken semaphore implementation on darwin.
 223 # sem_init returns: sem_init error: Function not implemented.
 224 case "$host" in
 225   *-darwin*)
 226     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 227         Define if the POSIX Semaphores do not work on your system.)
 228     ;;
 229 esac
 230
 231 # RTEMS specific checks
 232 case "$host" in
 233   *-*-rtems*)
 234     AC_CHECK_TYPES([struct _Mutex_Control],[],[],[#include <sys/lock.h>])
 235     ;;
 236 esac
 237
 238 GCC_LINUX_FUTEX(:)
 239
 240 # Check for pthread_{,attr_}[sg]etaffinity_np.
 241 AC_LINK_IFELSE(
 242  [AC_LANG_PROGRAM(
 243   [#define _GNU_SOURCE
 244    #include <pthread.h>],
 245   [cpu_set_t cpuset;
 246    pthread_attr_t attr;
 247    pthread_getaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 248    if (CPU_ISSET (0, &cpuset))
 249      CPU_SET (1, &cpuset);
 250    else
 251      CPU_ZERO (&cpuset);
 252    pthread_setaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 253    pthread_attr_init (&attr);
 254    pthread_attr_getaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);
 255    pthread_attr_setaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);])],
 256   AC_DEFINE(HAVE_PTHREAD_AFFINITY_NP, 1,
 257 [       Define if pthread_{,attr_}{g,s}etaffinity_np is supported.]))
 258
 259 # At least for glibc, clock_gettime is in librt.  But don't pull that
 260 # in if it still doesn't give us the function we want.
 261 if test $ac_cv_func_clock_gettime = no; then
 262   AC_CHECK_LIB(rt, clock_gettime,
 263     [LIBS="-lrt $LIBS"
 264      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 265                [Define to 1 if you have the `clock_gettime' function.])])
 266 fi
 267
 268 # See if we support thread-local storage.
 269 GCC_CHECK_TLS
 270
 271 # See if we have emulated thread-local storage.
 272 GCC_CHECK_EMUTLS
 273
 274 # See what sort of export controls are available.
 275 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 276 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 277 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 278 LIBGOMP_ENABLE_SYMVERS
 279
 280 if test $enable_symvers = gnu; then
 281   AC_DEFINE(LIBGOMP_GNU_SYMBOL_VERSIONING, 1,
 282             [Define to 1 if GNU symbol versioning is used for libgomp.])
 283 fi
 284
 285 # Get target configury.
 286 . ${srcdir}/configure.tgt
 287 CFLAGS="$save_CFLAGS $XCFLAGS"
 288
 289 # Check for __sync_val_compare_and_swap, but only after the target has
 290 # had a chance to set XCFLAGS.
 291 LIBGOMP_CHECK_SYNC_BUILTINS
 292
 293 XCFLAGS="$XCFLAGS$XPCFLAGS"
 294
 295 # Add CET specific flags if CET is enabled
 296 GCC_CET_FLAGS(CET_FLAGS)
 297 XCFLAGS="$XCFLAGS $CET_FLAGS"
 298 FCFLAGS="$FCFLAGS $CET_FLAGS"
 299
 300 AC_SUBST(config_path)
 301 AC_SUBST(XCFLAGS)
 302 AC_SUBST(XLDFLAGS)
 303
 304 # Cleanup and exit.
 305 CFLAGS="$save_CFLAGS"
 306 AC_CACHE_SAVE
 307
 308 if test ${multilib} = yes; then
 309   multilib_arg="--enable-multilib"
 310 else
 311   multilib_arg=
 312 fi
 313
 314 # Set up the set of libraries that we need to link against for libgomp.
 315 # Note that the GOMP_SELF_SPEC in gcc.c may force -pthread,
 316 # which will force linkage against -lpthread (or equivalent for the system).
 317 # That's not 100% ideal, but about the best we can do easily.
 318 if test $enable_shared = yes; then
 319   link_gomp="-lgomp %{static: $LIBS}"
 320 else
 321   link_gomp="-lgomp $LIBS"
 322 fi
 323 AC_SUBST(link_gomp)
 324
 325 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 326
 327 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 328 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 329 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 330 # need to copy this macro to our acinclude.m4.
 331 save_CFLAGS="$CFLAGS"
 332 for i in $config_path; do
 333   if test -f $srcdir/config/$i/omp-lock.h; then
 334     CFLAGS="$CFLAGS -include confdefs.h -include $srcdir/config/$i/omp-lock.h"
 335     break
 336   fi
 337 done
 338
 339 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 340   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 341 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 342 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 343 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 344 _AC_COMPUTE_INT([sizeof (omp_lock_25_t)], [OMP_LOCK_25_SIZE],,
 345   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_25_t)])])
 346 _AC_COMPUTE_INT([__alignof (omp_lock_25_t)], [OMP_LOCK_25_ALIGN])
 347 _AC_COMPUTE_INT([sizeof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_SIZE])
 348 _AC_COMPUTE_INT([__alignof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_ALIGN])
 349
 350 # If the lock fits in an integer, then arrange for Fortran to use that
 351 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 352 # Except that we don't have a way at present to multi-lib the installed
 353 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 354 # actual target.
 355 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 356 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 357 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 358   OMP_LOCK_KIND=8
 359 fi
 360 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 361   OMP_NEST_LOCK_KIND=8
 362 fi
 363 OMP_LOCK_25_KIND=$OMP_LOCK_25_SIZE
 364 OMP_NEST_LOCK_25_KIND=$OMP_NEST_LOCK_25_SIZE
 365 if test $OMP_LOCK_25_SIZE -gt 8 || test $OMP_LOCK_25_ALIGN -gt $OMP_LOCK_25_SIZE; then
 366   OMP_LOCK_25_KIND=8
 367 fi
 368 if test $OMP_NEST_LOCK_25_SIZE -gt 8 || test $OMP_NEST_LOCK_25_ALIGN -gt $OMP_NEST_LOCK_25_SIZE; then
 369   OMP_NEST_LOCK_25_KIND=8
 370 fi
 371
 372 AC_SUBST(OMP_LOCK_SIZE)
 373 AC_SUBST(OMP_LOCK_ALIGN)
 374 AC_SUBST(OMP_NEST_LOCK_SIZE)
 375 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 376 AC_SUBST(OMP_LOCK_KIND)
 377 AC_SUBST(OMP_NEST_LOCK_KIND)
 378 AC_SUBST(OMP_LOCK_25_SIZE)
 379 AC_SUBST(OMP_LOCK_25_ALIGN)
 380 AC_SUBST(OMP_NEST_LOCK_25_SIZE)
 381 AC_SUBST(OMP_NEST_LOCK_25_ALIGN)
 382 AC_SUBST(OMP_LOCK_25_KIND)
 383 AC_SUBST(OMP_NEST_LOCK_25_KIND)
 384 CFLAGS="$save_CFLAGS"
 385
 386 # Determine what GCC version number to use in filesystem paths.
 387 GCC_BASE_VER
 388
 389 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 390 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 391 AC_CONFIG_FILES([testsuite/libgomp-test-support.pt.exp:testsuite/libgomp-test-support.exp.in])
 392 AC_OUTPUT