libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([xmalloc.c])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  66 # rely on it - libiberty is built before texinfo.
  67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  68 if test "x$MAKEINFO" = "x"; then
  69     MAKEINFO="@echo makeinfo missing; true"
  70     BUILD_INFO=
  71 else
  72     BUILD_INFO=info
  73     case "$MAKEINFO" in
  74       */missing\ makeinfo*)
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is missing. Info documentation will not be built.])
  78         ;;
  79       *)
  80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  81           x*\ [[1-3]].* )
  82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  83             BUILD_INFO=
  84             AC_MSG_WARN([
  85 *** Makeinfo is too old. Info documentation will not be built.])
  86           ;;
  87         esac
  88         ;;
  89     esac
  90 fi
  91 AC_SUBST(MAKEINFO)
  92 AC_SUBST(BUILD_INFO)
  93
  94 AC_CHECK_PROG(PERL, perl, perl, )
  95 if test x"$PERL" = x""; then
  96   HAVE_PERL='#'
  97 else
  98   HAVE_PERL=''
  99 fi
 100 AC_SUBST(HAVE_PERL)
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl When we start using automake:
 105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 106
 107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 108 dnl to call AC_CHECK_PROG.
 109 AC_CHECK_TOOL(AR, ar)
 110 AC_CHECK_TOOL(RANLIB, ranlib, :)
 111
 112 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 113 # Add --enable-multilib to configure.
 114 # Default to --enable-multilib
 115 AC_ARG_ENABLE(multilib,
 116 [  --enable-multilib       build many library versions (default)],
 117 [case "$enableval" in
 118   yes) multilib=yes ;;
 119   no)  multilib=no ;;
 120   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 121  esac],
 122               [multilib=yes])
 123
 124 # Even if the default multilib is not a cross compilation,
 125 # it may be that some of the other multilibs are.
 126 if test $cross_compiling = no && test $multilib = yes \
 127    && test "x${with_multisubdir}" != x ; then
 128    cross_compiling=maybe
 129 fi
 130
 131 GCC_NO_EXECUTABLES
 132 AC_PROG_CC
 133 AC_SYS_LARGEFILE
 134 AC_PROG_CPP_WERROR
 135
 136 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 137                           -Wstrict-prototypes], [ac_libiberty_warn_cflags])
 138 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 139
 140 AC_PROG_CC_C_O
 141 # autoconf is lame and doesn't give us any substitution variable for this.
 142 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 143   NO_MINUS_C_MINUS_O=yes
 144 else
 145   OUTPUT_OPTION='-o $@'
 146 fi
 147 AC_SUBST(NO_MINUS_C_MINUS_O)
 148 AC_SUBST(OUTPUT_OPTION)
 149
 150 AC_C_CONST
 151 AC_C_INLINE
 152 AC_C_BIGENDIAN
 153
 154 dnl When we start using libtool:
 155 dnl Default to a non shared library.  This may be overridden by the
 156 dnl configure option --enable-shared.
 157 dnl AM_DISABLE_SHARED
 158
 159 dnl When we start using libtool:
 160 dnl AM_PROG_LIBTOOL
 161
 162 dnl When we start using automake:
 163 dnl AM_CONFIG_HEADER(config.h:config.in)
 164 AC_CONFIG_HEADER(config.h:config.in)
 165
 166 dnl When we start using automake:
 167 dnl AM_MAINTAINER_MODE
 168 dnl AC_EXEEXT
 169
 170 dnl When we start using automake:
 171 dnl AM_PROG_INSTALL
 172 AC_PROG_INSTALL
 173
 174 # Don't build the shared library for build.
 175 if [[ -n "${with_build_subdir}" ]]; then
 176   enable_shared=no
 177 fi
 178
 179 frag=
 180 case "${host}" in
 181   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 182                         frag=mh-aix ;;
 183   *-*-cxux7*)           frag=mh-cxux7 ;;
 184   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 185   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 186   i370-*-opened*)       frag=mh-openedition ;;
 187   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 188 esac
 189
 190 if [[ -n "${frag}" ]]; then
 191   frag=${libiberty_topdir}/libiberty/config/$frag
 192 fi
 193
 194 # If they didn't specify --enable-shared, don't generate shared libs.
 195 case "${enable_shared}" in
 196   yes) shared=yes ;;
 197   no) shared=no ;;
 198   "") shared=no ;;
 199   *) shared=yes ;;
 200 esac
 201 if [[ "${shared}" = "yes" ]]; then
 202   case "${host}" in
 203     *-*-cygwin*)        ;;
 204     alpha*-*-linux*)    PICFLAG=-fPIC ;;
 205     arm*-*-*)           PICFLAG=-fPIC ;;
 206     hppa*-*-*)          PICFLAG=-fPIC ;;
 207     i370-*-*)           PICFLAG=-fPIC ;;
 208     ia64-*-*)           PICFLAG=-fpic ;;
 209     i[[34567]]86-*-* | x86_64-*-*)
 210                         PICFLAG=-fpic ;;
 211     m68k-*-*)           PICFLAG=-fpic ;;
 212     mips*-*-linux*)     PICFLAG=-fPIC ;;
 213     powerpc*-*-aix*)    ;;
 214     powerpc*-*-*)       PICFLAG=-fPIC ;;
 215     sparc*-*-*)         case "${CFLAGS}" in
 216                           *-fpic* ) PICFLAG=-fpic ;;
 217                           * ) PICFLAG=-fPIC ;;
 218                         esac ;;
 219     s390*-*-*)          PICFLAG=-fpic ;;
 220   esac
 221 fi
 222 AC_SUBST(PICFLAG)
 223
 224 echo "# Warning: this fragment is automatically generated" > temp-frag
 225
 226 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 227   echo "Appending ${frag} to xhost-mkfrag"
 228   echo "# Following fragment copied from ${frag}" >> temp-frag
 229   cat ${frag} >> temp-frag
 230 fi
 231
 232 # record if we want to build shared libs.
 233 if [[ "${shared}" = "yes" ]]; then
 234   echo enable_shared = yes >> temp-frag
 235 else
 236   echo enable_shared = no >> temp-frag
 237 fi
 238
 239 frag=xhost-mkfrag
 240 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 241
 242 host_makefile_frag=${frag}
 243 AC_SUBST_FILE(host_makefile_frag)
 244
 245 # It's OK to check for header files.  Although the compiler may not be
 246 # able to link anything, it had better be able to at least compile
 247 # something.
 248 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h)
 249 AC_HEADER_SYS_WAIT
 250 AC_HEADER_TIME
 251
 252 libiberty_AC_DECLARE_ERRNO
 253
 254 # Determine the size of an int for struct fibnode.
 255 AC_CHECK_SIZEOF([int])
 256
 257 # Look for a 64-bit type.
 258 AC_MSG_CHECKING([for a 64-bit type])
 259 AC_CACHE_VAL(liberty_cv_uint64,
 260 [AC_TRY_COMPILE(
 261 [#ifdef HAVE_STDINT_H
 262 #include <stdint.h>
 263 #endif],
 264 [extern uint64_t foo;],
 265 liberty_cv_uint64=uint64_t,
 266 [AC_TRY_COMPILE(
 267 [#ifdef HAVE_LIMITS_H
 268 #include <limits.h>
 269 #endif
 270 #ifndef CHAR_BIT
 271 #define CHAR_BIT 8
 272 #endif],
 273 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 274 liberty_cv_uint64="unsigned long",
 275 [AC_TRY_COMPILE(
 276 [#ifdef HAVE_LIMITS_H
 277 #include <limits.h>
 278 #endif
 279 #ifndef CHAR_BIT
 280 #define CHAR_BIT 8
 281 #endif],
 282 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 283 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 284 AC_MSG_RESULT($liberty_cv_uint64)
 285 if test "$liberty_cv_uint64" != none; then
 286   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 287                      [Define to an unsigned 64-bit type available in the compiler.])
 288 fi
 289
 290 AC_TYPE_INTPTR_T
 291 AC_TYPE_UINTPTR_T
 292
 293 # Given the above check, we always have uintptr_t or a fallback
 294 # definition.  So define HAVE_UINTPTR_T in case any imported code
 295 # relies on it.
 296 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 297
 298 AC_TYPE_PID_T
 299
 300 # This is the list of functions which libiberty will provide if they
 301 # are not available on the host.
 302
 303 funcs="asprintf"
 304 funcs="$funcs atexit"
 305 funcs="$funcs basename"
 306 funcs="$funcs bcmp"
 307 funcs="$funcs bcopy"
 308 funcs="$funcs bsearch"
 309 funcs="$funcs bzero"
 310 funcs="$funcs calloc"
 311 funcs="$funcs clock"
 312 funcs="$funcs ffs"
 313 funcs="$funcs getcwd"
 314 funcs="$funcs getpagesize"
 315 funcs="$funcs gettimeofday"
 316 funcs="$funcs index"
 317 funcs="$funcs insque"
 318 funcs="$funcs memchr"
 319 funcs="$funcs memcmp"
 320 funcs="$funcs memcpy"
 321 funcs="$funcs memmem"
 322 funcs="$funcs memmove"
 323 funcs="$funcs mempcpy"
 324 funcs="$funcs memset"
 325 funcs="$funcs mkstemps"
 326 funcs="$funcs putenv"
 327 funcs="$funcs random"
 328 funcs="$funcs rename"
 329 funcs="$funcs rindex"
 330 funcs="$funcs setenv"
 331 funcs="$funcs snprintf"
 332 funcs="$funcs sigsetmask"
 333 funcs="$funcs stpcpy"
 334 funcs="$funcs stpncpy"
 335 funcs="$funcs strcasecmp"
 336 funcs="$funcs strchr"
 337 funcs="$funcs strdup"
 338 funcs="$funcs strncasecmp"
 339 funcs="$funcs strndup"
 340 funcs="$funcs strrchr"
 341 funcs="$funcs strstr"
 342 funcs="$funcs strtod"
 343 funcs="$funcs strtol"
 344 funcs="$funcs strtoul"
 345 funcs="$funcs strverscmp"
 346 funcs="$funcs tmpnam"
 347 funcs="$funcs vasprintf"
 348 funcs="$funcs vfprintf"
 349 funcs="$funcs vprintf"
 350 funcs="$funcs vsnprintf"
 351 funcs="$funcs vsprintf"
 352 funcs="$funcs waitpid"
 353
 354 # Also in the old function.def file: alloca, vfork, getopt.
 355
 356 vars="sys_errlist sys_nerr sys_siglist"
 357
 358 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
 359 checkfuncs="$checkfuncs realpath canonicalize_file_name pstat_getstatic pstat_getdynamic sysmp"
 360 checkfuncs="$checkfuncs getsysinfo table sysctl wait3 wait4 __fsetlocking"
 361
 362 # These are neither executed nor required, but they help keep
 363 # autoheader happy without adding a bunch of text to acconfig.h.
 364 if test "x" = "y"; then
 365   AC_CHECK_FUNCS(asprintf atexit \
 366     basename bcmp bcopy bsearch bzero \
 367     calloc canonicalize_file_name clock \
 368     ffs __fsetlocking \
 369     getcwd getpagesize getrusage getsysinfo gettimeofday \
 370     index insque \
 371     memchr memcmp memcpy memmem memmove memset mkstemps \
 372     on_exit \
 373     psignal pstat_getdynamic pstat_getstatic putenv \
 374     random realpath rename rindex \
 375     sbrk setenv sigsetmask snprintf stpcpy stpncpy strcasecmp strchr strdup \
 376      strerror strncasecmp strndup strrchr strsignal strstr strtod strtol \
 377      strtoul strverscmp sysconf sysctl sysmp \
 378     table times tmpnam \
 379     vasprintf vfprintf vprintf vsprintf \
 380     wait3 wait4 waitpid)
 381   AC_CHECK_DECLS([basename, ffs, asprintf, vasprintf, snprintf, vsnprintf])
 382   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 383   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 384   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 385 fi
 386
 387 # For each of these functions, if the host does not provide the
 388 # function we want to put FN.o in LIBOBJS, and if the host does
 389 # provide the function, we want to define HAVE_FN in config.h.
 390
 391 setobjs=
 392 CHECK=
 393 target_header_dir=
 394 if test -n "${with_target_subdir}"; then
 395
 396   # We are being configured as a target library.  AC_REPLACE_FUNCS
 397   # may not work correctly, because the compiler may not be able to
 398   # link executables.  Note that we may still be being configured
 399   # native.
 400
 401   # If we are being configured for newlib, we know which functions
 402   # newlib provide and which ones we will be expected to provide.
 403
 404   if test "x${with_newlib}" = "xyes"; then
 405     AC_LIBOBJ([asprintf])
 406     AC_LIBOBJ([basename])
 407     AC_LIBOBJ([insque])
 408     AC_LIBOBJ([random])
 409     AC_LIBOBJ([strdup])
 410     AC_LIBOBJ([vasprintf])
 411
 412     for f in $funcs; do
 413       case "$f" in
 414         asprintf | basename | insque | random | strdup | vasprintf)
 415           ;;
 416         *)
 417           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 418           AC_DEFINE_UNQUOTED($n)
 419           ;;
 420       esac
 421     done
 422
 423     # newlib doesnt provide any of the variables in $vars, so we
 424     # dont have to check them here.
 425
 426     # Of the functions in $checkfuncs, newlib only has strerror.
 427     AC_DEFINE(HAVE_STRERROR)
 428
 429     setobjs=yes
 430
 431   fi
 432
 433   # If we are being configured for Mingw, we know which functions
 434   # Mingw provides and which ones we will be expected to provide.
 435
 436   case "${host}" in
 437   *-*-mingw*)
 438     AC_LIBOBJ([asprintf])
 439     AC_LIBOBJ([basename])
 440     AC_LIBOBJ([bcmp])
 441     AC_LIBOBJ([bcopy])
 442     AC_LIBOBJ([bzero])
 443     AC_LIBOBJ([clock])
 444     AC_LIBOBJ([ffs])
 445     AC_LIBOBJ([getpagesize])
 446     AC_LIBOBJ([index])
 447     AC_LIBOBJ([insque])
 448     AC_LIBOBJ([mempcpy])
 449     AC_LIBOBJ([mkstemps])
 450     AC_LIBOBJ([random])
 451     AC_LIBOBJ([rindex])
 452     AC_LIBOBJ([sigsetmask])
 453     AC_LIBOBJ([stpcpy])
 454     AC_LIBOBJ([stpncpy])
 455     AC_LIBOBJ([strndup])
 456     AC_LIBOBJ([strverscmp])
 457     AC_LIBOBJ([vasprintf])
 458     AC_LIBOBJ([waitpid])
 459
 460     for f in $funcs; do
 461       case "$f" in
 462         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strverscmp | vasprintf | waitpid)
 463           ;;
 464         *)
 465           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 466           AC_DEFINE_UNQUOTED($n)
 467           ;;
 468       esac
 469     done
 470
 471     # Mingw doesnt provide any of the variables in $vars, so we
 472     # dont have to check them here.
 473
 474     # Of the functions in $checkfuncs, Mingw only has strerror.
 475     AC_DEFINE(HAVE_STRERROR)
 476
 477     setobjs=yes
 478     ;;
 479
 480   *-*-msdosdjgpp)
 481     AC_LIBOBJ([vasprintf])
 482     AC_LIBOBJ([vsnprintf])
 483     AC_LIBOBJ([snprintf])
 484     AC_LIBOBJ([asprintf])
 485
 486     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 487              getcwd getpagesize getrusage gettimeofday \
 488              index insque memchr memcmp memcpy memmove memset psignal \
 489              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 490              strchr strdup strerror strncasecmp strrchr strstr strtod \
 491              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 492              vsprintf waitpid
 493     do
 494       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 495       AC_DEFINE_UNQUOTED($n)
 496     done
 497
 498
 499     setobjs=yes
 500     ;;
 501
 502   esac
 503
 504   # We may wish to install the target headers somewhere.
 505   AC_ARG_ENABLE(install-libiberty,
 506   [  --enable-install-libiberty       Install headers for end users],
 507   enable_install_libiberty=$enableval,
 508   enable_install_libiberty=no)dnl
 509
 510   # Option parsed, now set things appropriately.
 511   case x"$enable_install_libiberty" in
 512     xyes|x)
 513       target_header_dir=libiberty
 514       ;;
 515     xno)
 516       target_header_dir=
 517       ;;
 518     *)
 519       # This could be sanity-checked in various ways...
 520       target_header_dir="${enable_install_libiberty}"
 521       ;;
 522   esac
 523
 524
 525 else
 526
 527    # Not a target library, so we set things up to run the test suite.
 528    CHECK=really-check
 529
 530 fi
 531
 532 AC_SUBST(CHECK)
 533 AC_SUBST(target_header_dir)
 534
 535 case "${host}" in
 536   *-*-cygwin* | *-*-mingw*)
 537     AC_DEFINE(HAVE_SYS_ERRLIST)
 538     AC_DEFINE(HAVE_SYS_NERR)
 539     ;;
 540 esac
 541
 542 if test -z "${setobjs}"; then
 543   case "${host}" in
 544
 545   *-*-vxworks*)
 546     # Handle VxWorks configuration specially, since on VxWorks the
 547     # libraries are actually on the target board, not in the file
 548     # system.
 549     AC_LIBOBJ([basename])
 550     AC_LIBOBJ([getpagesize])
 551     AC_LIBOBJ([insque])
 552     AC_LIBOBJ([random])
 553     AC_LIBOBJ([strcasecmp])
 554     AC_LIBOBJ([strncasecmp])
 555     AC_LIBOBJ([strdup])
 556     AC_LIBOBJ([vfork])
 557     AC_LIBOBJ([waitpid])
 558     AC_LIBOBJ([vasprintf])
 559     for f in $funcs; do
 560       case "$f" in
 561         basename | getpagesize | insque | random | strcasecmp)
 562           ;;
 563         strncasecmp | strdup | vfork | waitpid | vasprintf)
 564           ;;
 565         *)
 566           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 567           AC_DEFINE_UNQUOTED($n)
 568           ;;
 569       esac
 570     done
 571
 572     # VxWorks doesn't provide any of the variables in $vars, so we
 573     # don't have to check them here.
 574
 575     # Of the functions in $checkfuncs, VxWorks only has strerror.
 576     AC_DEFINE(HAVE_STRERROR)
 577
 578     setobjs=yes
 579     ;;
 580
 581   esac
 582 fi
 583
 584 if test -z "${setobjs}"; then
 585
 586   case "${host}" in
 587
 588   *-*-mingw32*)
 589     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 590     # macros, so the test below won't find them.
 591     libiberty_cv_var_sys_nerr=yes
 592     libiberty_cv_var_sys_errlist=yes
 593     ;;
 594
 595   *-*-msdosdjgpp*)
 596     # vfork and fork are stubs.
 597     ac_cv_func_vfork_works=no
 598     ;;
 599
 600   *-*-uwin*)
 601     # Under some versions of uwin, vfork is notoriously buggy and the test
 602     # can hang configure; on other versions, vfork exists just as a stub.
 603     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 604     ac_cv_func_vfork_works=no
 605     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 606     # macros (actually, these are imported from a DLL, but the end effect
 607     # is the same), so the test below won't find them.
 608     libiberty_cv_var_sys_nerr=yes
 609     libiberty_cv_var_sys_errlist=yes
 610     ;;
 611
 612   *-*-*vms*)
 613     # Under VMS, vfork works very different than on Unix. The standard test
 614     # won't work, and it isn't easily adaptable. It makes more sense to
 615     # just force it.
 616     ac_cv_func_vfork_works=yes
 617     ;;
 618
 619   esac
 620
 621   # We haven't set the list of objects yet.  Use the standard autoconf
 622   # tests.  This will only work if the compiler works.
 623   AC_ISC_POSIX
 624   AC_REPLACE_FUNCS($funcs)
 625   libiberty_AC_FUNC_C_ALLOCA
 626   AC_FUNC_FORK
 627   if test $ac_cv_func_vfork_works = no; then
 628     AC_LIBOBJ([vfork])
 629   fi
 630   # We only need _doprnt if we might use it to implement v*printf.
 631   if test $ac_cv_func_vprintf != yes \
 632      || test $ac_cv_func_vfprintf != yes \
 633      || test $ac_cv_func_vsprintf != yes; then
 634     AC_REPLACE_FUNCS(_doprnt)
 635   else
 636     AC_CHECK_FUNCS(_doprnt)
 637   fi
 638
 639   for v in $vars; do
 640     AC_MSG_CHECKING([for $v])
 641     AC_CACHE_VAL(libiberty_cv_var_$v,
 642       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 643                       [eval "libiberty_cv_var_$v=yes"],
 644                       [eval "libiberty_cv_var_$v=no"])])
 645     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 646       AC_MSG_RESULT(yes)
 647       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 648       AC_DEFINE_UNQUOTED($n)
 649     else
 650       AC_MSG_RESULT(no)
 651     fi
 652   done
 653
 654   # special check for _system_configuration because AIX <4.3.2 do not
 655   # contain the `physmem' member.
 656   AC_MSG_CHECKING([for external symbol _system_configuration])
 657   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 658                         [[double x = _system_configuration.physmem;]])],
 659     [AC_MSG_RESULT([yes])
 660     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 661               [Define if you have the _system_configuration variable.])],
 662     [AC_MSG_RESULT([no])])
 663
 664   AC_CHECK_FUNCS($checkfuncs)
 665   AC_CHECK_DECLS([basename, ffs, asprintf, vasprintf, snprintf, vsnprintf])
 666   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 667   AC_CHECK_DECLS([strverscmp])
 668   libiberty_NEED_DECLARATION(canonicalize_file_name)
 669 fi
 670
 671 # Figure out which version of pexecute to use.
 672 case "${host}" in
 673      *-*-mingw* | *-*-winnt*)   pexecute=./pex-win32.o  ;;
 674      *-*-msdosdjgpp*)           pexecute=./pex-djgpp.o  ;;
 675      *-*-msdos*)                pexecute=./pex-msdos.o  ;;
 676      *)                         pexecute=./pex-unix.o   ;;
 677 esac
 678 AC_SUBST(pexecute)
 679
 680 libiberty_AC_FUNC_STRNCMP
 681
 682 # Install a library built with a cross compiler in $(tooldir) rather
 683 # than $(libdir).
 684 if test -z "${with_cross_host}"; then
 685   INSTALL_DEST=libdir
 686 else
 687   INSTALL_DEST=tooldir
 688 fi
 689 AC_SUBST(INSTALL_DEST)
 690
 691 m4_pattern_allow(LIBOBJS)
 692 L=""
 693 for l in x $LIBOBJS; do
 694   case $l in
 695     x) ;;
 696     *) L="$L ./$l" ;;
 697   esac
 698 done
 699 LIBOBJS="$L"
 700
 701 dnl Required by html and install-html
 702 AC_SUBST(datarootdir)
 703 AC_SUBST(docdir)
 704 AC_SUBST(htmldir)
 705
 706 # We need multilib support, but only if configuring for the target.
 707 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 708 AC_CONFIG_COMMANDS([default],
 709   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 710 if test -n "$CONFIG_FILES"; then
 711   if test -n "${with_target_subdir}"; then
 712     # FIXME: We shouldn't need to set ac_file
 713     ac_file=Makefile
 714     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 715     . ${libiberty_topdir}/config-ml.in
 716   fi
 717 fi]],
 718 [[srcdir=${srcdir}
 719 host=${host}
 720 target=${target}
 721 with_target_subdir=${with_target_subdir}
 722 with_multisubdir=${with_multisubdir}
 723 ac_configure_args="--enable-multilib ${ac_configure_args}"
 724 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 725 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 726 libiberty_topdir=${libiberty_topdir}
 727 ]])
 728 AC_OUTPUT