libobjc/configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1994-2017 Free Software Foundation, Inc.
   3 #   Originally contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GCC.
   6 #
   7 #GCC is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 3, or (at your option)
  10 #any later version.
  11 #
  12 #GCC is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GCC; see the file COPYING3.  If not see
  19 #<http://www.gnu.org/licenses/>.
  20
  21 AC_PREREQ(2.64)
  22 AC_INIT(package-unused, version-unused,, libobjc)
  23 AC_CONFIG_SRCDIR([objc/objc.h])
  24 GCC_TOPLEV_SUBDIRS
  25
  26 # We need the following definitions because AC_PROG_LIBTOOL relies on them
  27 PACKAGE=libobjc
  28 # Version is pulled out to make it a bit easier to change using sed.
  29 VERSION=4:0:0
  30 AC_SUBST(VERSION)
  31
  32 # This works around the fact that libtool configuration may change LD
  33 # for this particular configuration, but some shells, instead of
  34 # keeping the changes in LD private, export them just because LD is
  35 # exported.
  36 ORIGINAL_LD_FOR_MULTILIBS=$LD
  37
  38 # -------
  39 # Options
  40 # -------
  41
  42 # We use these options to decide which functions to include.
  43 AC_ARG_WITH(target-subdir,
  44 [  --with-target-subdir=SUBDIR
  45                            configuring in a subdirectory])
  46 AC_ARG_WITH(cross-host,
  47 [  --with-cross-host=HOST  configuring with a cross compiler])
  48
  49 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  50 AC_ARG_ENABLE(version-specific-runtime-libs,
  51 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  52 [case "$enableval" in
  53  yes) version_specific_libs=yes ;;
  54  no)  version_specific_libs=no ;;
  55  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  56  esac],
  57 [version_specific_libs=no])
  58 AC_MSG_RESULT($version_specific_libs)
  59
  60 # -----------
  61 # Directories
  62 # -----------
  63
  64 # Find the rest of the source tree framework.
  65 AM_ENABLE_MULTILIB(, ..)
  66
  67 AC_CANONICAL_SYSTEM
  68 ACX_NONCANONICAL_TARGET
  69
  70 # Export source directory.
  71 # These need to be absolute paths, yet at the same time need to
  72 # canonicalize only relative paths, because then amd will not unmount
  73 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  74 case $srcdir in
  75   [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
  76   *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  77 esac
  78 AC_SUBST(glibcpp_srcdir)
  79
  80 # Calculate toolexeclibdir
  81 # Also toolexecdir, though it's only used in toolexeclibdir
  82 case ${version_specific_libs} in
  83   yes)
  84     # Need the gcc compiler version to know where to install libraries
  85     # and header files if --enable-version-specific-runtime-libs option
  86     # is selected.
  87     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
  88     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  89     ;;
  90   no)
  91     if test -n "$with_cross_host" &&
  92        test x"$with_cross_host" != x"no"; then
  93       # Install a library built with a cross compiler in tooldir, not libdir.
  94       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
  95       toolexeclibdir='$(toolexecdir)/lib'
  96     else
  97       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
  98       toolexeclibdir='$(libdir)'
  99     fi
 100     multi_os_directory=`$CC -print-multi-os-directory`
 101     case $multi_os_directory in
 102       .) ;; # Avoid trailing /.
 103       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 104     esac
 105     ;;
 106 esac
 107 AC_SUBST(toolexecdir)
 108 AC_SUBST(toolexeclibdir)
 109
 110 # Figure out if we want to name the include directory and the
 111 #  library name changes differently.
 112 includedirname=include
 113 libsuffix=
 114 case "${host}" in
 115   *-darwin*)
 116     # Darwin is the only target so far that needs a different include directory.
 117     includedirname=include-gnu-runtime
 118     libsuffix=-gnu
 119     ;;
 120 esac
 121 AC_SUBST(includedirname)
 122 AC_SUBST(libsuffix)
 123
 124 AC_CONFIG_HEADERS(config.h)
 125
 126 # --------
 127 # Programs
 128 # --------
 129
 130 GCC_NO_EXECUTABLES
 131
 132 # We must force CC to /not/ be a precious variable; otherwise
 133 # the wrong, non-multilib-adjusted value will be used in multilibs.
 134 # As a side effect, we have to subst CFLAGS ourselves.
 135 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 136 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 137 AC_PROG_CC
 138 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 139
 140 # extra LD Flags which are required for targets
 141 ACX_LT_HOST_FLAGS
 142 case "${host}" in
 143   *-darwin*)
 144     # Darwin needs -single_module when linking libobjc
 145     extra_ldflags_libobjc='$(lt_host_flags) -Wl,-single_module'
 146     ;;
 147   *-cygwin*|*-mingw*)
 148     # Tell libtool to build DLLs on Windows
 149     extra_ldflags_libobjc='$(lt_host_flags)'
 150     ;;
 151 esac
 152 AC_SUBST(extra_ldflags_libobjc)
 153
 154 # Add CET specific flags if CET is enabled
 155 GCC_CET_FLAGS(CET_FLAGS)
 156 XCFLAGS="$XCFLAGS $CET_FLAGS"
 157
 158 AC_SUBST(CFLAGS)
 159 AC_SUBST(XCFLAGS)
 160
 161 AC_CHECK_TOOL(AS, as)
 162 AC_CHECK_TOOL(AR, ar)
 163 AC_CHECK_TOOL(RANLIB, ranlib, :)
 164 AC_PROG_INSTALL
 165
 166 AM_MAINTAINER_MODE
 167
 168 # Enable Win32 DLL on MS Windows - FIXME
 169 AC_LIBTOOL_WIN32_DLL
 170
 171 AC_PROG_LIBTOOL
 172
 173 AM_PROG_CC_C_O
 174
 175 AC_PROG_MAKE_SET
 176
 177 # -------
 178 # Headers
 179 # -------
 180
 181 # Sanity check for the cross-compilation case:
 182 AC_CHECK_HEADER(stdio.h,:,
 183   [AC_MSG_ERROR([Can't find stdio.h.
 184 You must have a usable C system for the target already installed, at least
 185 including headers and, preferably, the library, before you can configure
 186 the Objective C runtime system.  If necessary, install gcc now with
 187 \`LANGUAGES=c', then the target library, then build with \`LANGUAGES=objc'.])])
 188
 189 AC_HEADER_STDC
 190
 191 AC_CHECK_HEADERS(sched.h)
 192
 193 # -----------
 194 # Miscellanea
 195 # -----------
 196
 197 # Check if we have thread-local storage
 198 GCC_CHECK_TLS
 199
 200 gt_BITFIELD_TYPE_MATTERS
 201
 202 # -----------
 203 # boehm-gc
 204 # -----------
 205
 206 AC_ARG_ENABLE(objc-gc,
 207 [AS_HELP_STRING([--enable-objc-gc],
 208                 [enable use of Boehm's garbage collector with the
 209                  GNU Objective-C runtime])],,enable_objc_gc=no)
 210 AC_ARG_WITH([target-bdw-gc],
 211 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
 212                 [specify prefix directory for installed bdw-gc package.
 213                  Equivalent to --with-target-bdw-gc-include=PATH/include
 214                  plus --with-target-bdw-gc-lib=PATH/lib])])
 215 AC_ARG_WITH([target-bdw-gc-include],
 216 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
 217                 [specify directories for installed bdw-gc include files])])
 218 AC_ARG_WITH([target-bdw-gc-lib],
 219 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
 220                 [specify directories for installed bdw-gc library])])
 221
 222 case "$enable_objc_gc" in
 223 no)
 224   use_bdw_gc=no
 225   ;;
 226 *)
 227   AC_MSG_CHECKING([for bdw garbage collector])
 228   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
 229     dnl no bdw-gw options, assuming bdw-gc in default locations
 230     BDW_GC_CFLAGS=
 231     BDW_GC_LIBS="-lgc"
 232   else
 233     dnl bdw-gw options passed by configure flags
 234     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
 235       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
 236     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
 237       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
 238     else
 239       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
 240     fi
 241     mldir=`${CC-gcc} --print-multi-directory 2>/dev/null`
 242     bdw_val=
 243     if test "x$with_target_bdw_gc" != x; then
 244       for i in `echo $with_target_bdw_gc | tr ',' ' '`; do
 245         case "$i" in
 246           *=*) sd=${i%%=*}; d=${i#*=} ;;
 247           *) sd=.; d=$i ;;
 248         esac
 249         if test "$mldir" = "$sd"; then
 250           bdw_val=$d
 251         fi
 252       done
 253       if test "x$bdw_val" = x; then
 254         AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc])
 255       fi
 256       bdw_inc_dir="$bdw_val/include"
 257       bdw_lib_dir="$bdw_val/lib"
 258     fi
 259     bdw_val=
 260     if test "x$with_target_bdw_gc_include" != x; then
 261       for i in `echo $with_target_bdw_gc_include | tr ',' ' '`; do
 262         case "$i" in
 263           *=*) sd=${i%%=*}; d=${i#*=} ;;
 264           *) sd=.; d=$i; fallback=$i ;;
 265         esac
 266         if test "$mldir" = "$sd"; then
 267           bdw_val=$d
 268         fi
 269       done
 270       if test "x$bdw_val" = x && test "x$bdw_inc_dir" = x && test "x$fallback" != x; then
 271         bdw_inc_dir="$fallback"
 272       elif test "x$bdw_val" = x; then
 273         AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-include])
 274       else
 275         bdw_inc_dir="$bdw_val"
 276       fi
 277     fi
 278     bdw_val=
 279     if test "x$with_target_bdw_gc_lib" != x; then
 280       for i in `echo $with_target_bdw_gc_lib | tr ',' ' '`; do
 281         case "$i" in
 282           *=*) sd=${i%%=*}; d=${i#*=} ;;
 283           *) sd=.; d=$i ;;
 284         esac
 285         if test "$mldir" = "$sd"; then
 286           bdw_val=$d
 287         fi
 288       done
 289       if test "x$bdw_val" = x; then
 290         AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-lib])
 291       fi
 292       bdw_lib_dir="$bdw_val"
 293     fi
 294     if test "x$bdw_inc_dir" = x; then
 295       AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-include])
 296     fi
 297     if test "x$bdw_lib_dir" = x; then
 298       AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-lib])
 299     fi
 300     BDW_GC_CFLAGS="-I$bdw_inc_dir"
 301     if test -f $bdw_lib_dir/libgc.la; then
 302       BDW_GC_LIBS="$bdw_lib_dir/libgc.la"
 303     else
 304       BDW_GC_LIBS="-L$bdw_lib_dir -lgc"
 305     fi
 306     AC_MSG_RESULT([found])
 307   fi
 308
 309   case "$BDW_GC_LIBS" in
 310   *libgc.la)
 311     use_bdw_gc=yes
 312     ;;
 313   *)
 314     AC_MSG_CHECKING([for system boehm-gc])
 315     save_CFLAGS=$CFLAGS
 316     save_LIBS=$LIBS
 317     CFLAGS="$CFLAGS $BDW_GC_CFLAGS"
 318     LIBS="$LIBS $BDW_GC_LIBS"
 319     dnl the link test is not good enough for ARM32 multilib detection,
 320     dnl first check to link, then to run
 321     AC_LINK_IFELSE(
 322       [AC_LANG_PROGRAM([#include <gc/gc.h>],[GC_init()])],
 323       [
 324         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 325           #include <gc/gc.h>
 326           int main() {
 327             GC_init();
 328             return 0;
 329           }
 330           ]])],
 331           [system_bdw_gc_found=yes],
 332           [system_bdw_gc_found=no],
 333           dnl assume no system boehm-gc for cross builds ...
 334           [system_bdw_gc_found=no]
 335         )
 336       ],
 337       [system_bdw_gc_found=no])
 338     CFLAGS=$save_CFLAGS
 339     LIBS=$save_LIBS
 340     if test x$enable_objc_gc = xauto && test x$system_bdw_gc_found = xno; then
 341       AC_MSG_WARN([system bdw-gc not found, not building libobjc_gc])
 342       use_bdw_gc=no
 343     elif test x$enable_objc_gc = xyes && test x$system_bdw_gc_found = xno; then
 344       AC_MSG_ERROR([system bdw-gc required but not found])
 345     else
 346       use_bdw_gc=yes
 347       AC_MSG_RESULT([found])
 348     fi
 349   esac
 350 esac
 351
 352 if test "$use_bdw_gc" = no; then
 353   OBJC_GCFLAGS=''
 354   OBJC_BOEHM_GC=''
 355   OBJC_BOEHM_GC_INCLUDES=''
 356   OBJC_BOEHM_GC_LIBS=''
 357 else
 358   OBJC_GCFLAGS='-DOBJC_WITH_GC=1'
 359   OBJC_BOEHM_GC='libobjc_gc$(libsuffix).la'
 360   OBJC_BOEHM_GC_INCLUDES=$BDW_GC_CFLAGS
 361   OBJC_BOEHM_GC_LIBS=$BDW_GC_LIBS
 362 fi
 363 AC_SUBST(OBJC_GCFLAGS)
 364 AC_SUBST(OBJC_BOEHM_GC)
 365 AC_SUBST(OBJC_BOEHM_GC_INCLUDES)
 366 AC_SUBST(OBJC_BOEHM_GC_LIBS)
 367
 368 # Determine what GCC version number to use in filesystem paths.
 369 GCC_BASE_VER
 370
 371 # ------
 372 # Output
 373 # ------
 374
 375 if test ${multilib} = yes; then
 376   multilib_arg="--enable-multilib"
 377 else
 378   multilib_arg=
 379 fi
 380
 381 AC_CONFIG_FILES([Makefile])
 382 AC_OUTPUT