libstdc++-v3/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.57)
   5 AC_INIT(package-unused, version-unused,, libstdc++)
   6 AC_CONFIG_SRCDIR(src/ios.cc)
   7 AC_CONFIG_HEADER(config.h)
   8
   9 # This works around the fact that libtool configuration may change LD
  10 # for this particular configuration, but some shells, instead of
  11 # keeping the changes in LD private, export them just because LD is
  12 # exported.  Only used at the end of this file.
  13 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  14
  15 # For libtool versioning info, format is CURRENT:REVISION:AGE
  16 libtool_VERSION=6:0:0
  17 AC_SUBST(libtool_VERSION)
  18
  19 # Find the rest of the source tree framework.
  20 GLIBCXX_TOPREL_CONFIGURE
  21
  22 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  23 #
  24 # You will slowly go insane if you do not grok the following fact:  when
  25 # building v3 as part of the compiler, the top-level /target/ becomes the
  26 # library's /host/.  configure then causes --target to default to --host,
  27 # exactly like any other package using autoconf.  Therefore, 'target' and
  28 # 'host' will always be the same.  This makes sense both for native and
  29 # cross compilers, just think about it for a little while.  :-)
  30 #
  31 # Also, if v3 is being configured as part of a cross compiler, the top-level
  32 # configure script will pass the "real" host as $with_cross_host.
  33 #
  34 # Do not delete or change the following two lines.  For why, see
  35 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  36 AC_CANONICAL_SYSTEM
  37 target_alias=${target_alias-$host_alias}
  38
  39 # Handy for debugging:
  40 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  41
  42 if test "$build" != "$host"; then
  43   # We are being configured with some form of cross compiler.
  44   GLIBCXX_IS_NATIVE=false
  45   # GCC_NO_EXECUTABLES
  46 else
  47   GLIBCXX_IS_NATIVE=true
  48 fi
  49
  50 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  51 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  52 #  1.x:  minimum required version
  53 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  54 #              of other PACKAGE_* variables will, however, and there's nothing
  55 #              we can do about that; they come from AC_INIT).
  56 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  57 #            file in the top srcdir, etc, etc), so stop complaining.
  58 #  no-dependencies:  turns off auto dependency generation (just for now)
  59 #  -Wall:  turns on all automake warnings
  60 AM_INIT_AUTOMAKE([1.7.6 no-define foreign no-dependencies -Wall])
  61
  62 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  63 # up critical shell variables.
  64 GLIBCXX_CONFIGURE
  65
  66 #AC_MSG_NOTICE([====== Starting libtool configuration])
  67 AC_LIBTOOL_DLOPEN
  68 AM_PROG_LIBTOOL
  69 AC_SUBST(enable_shared)
  70 AC_SUBST(enable_static)
  71 #AC_MSG_NOTICE([====== Finished libtool configuration]) ; sleep 10
  72
  73 # Check for support bits and g++ features that don't require linking.
  74 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  75 GLIBCXX_ENABLE_LIBUNWIND_EXCEPTIONS
  76 GLIBCXX_ENABLE_PCH([yes])
  77
  78 # Enable all the variable C++ runtime options.
  79 # NB: C_MBCHAR must come early.
  80 GLIBCXX_ENABLE_CSTDIO
  81 GLIBCXX_ENABLE_CLOCALE
  82 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
  83 GLIBCXX_ENABLE_C_MBCHAR([yes])
  84 GLIBCXX_ENABLE_C99([yes])
  85 GLIBCXX_ENABLE_LONG_LONG([yes])
  86 GLIBCXX_ENABLE_THREADS
  87 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
  88 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
  89 GLIBCXX_ENABLE_DEBUG([no])
  90 GLIBCXX_ENABLE_CXX_FLAGS
  91
  92 # No surprises, no surprises...
  93 if test $atomicity_include_dir = cpu/generic ; then
  94   AC_MSG_WARN([No native atomic operations are provided for this platform.])
  95   if test $target_thread_file = single; then
  96     AC_MSG_WARN([They cannot be faked when thread support is disabled.])
  97     AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
  98   else
  99     AC_MSG_WARN([They will be faked using a mutex.])
 100     AC_MSG_WARN([Performance of certain classes will degrade as a result.])
 101   fi
 102 fi
 103
 104
 105 if $GLIBCXX_IS_NATIVE; then
 106
 107   # We can do more elaborate tests that assume a working linker.
 108   CANADIAN=no
 109
 110   # Check for available headers.
 111   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 112   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h \
 113   sys/types.h])
 114
 115   GLIBCXX_CHECK_COMPILER_FEATURES
 116   GLIBCXX_CHECK_LINKER_FEATURES
 117   GLIBCXX_CHECK_MATH_SUPPORT
 118   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 119   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 120   GLIBCXX_CHECK_WCHAR_T_SUPPORT
 121   GLIBCXX_CHECK_STDLIB_SUPPORT
 122
 123   # For showmanyc_helper().
 124   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 125   GLIBCXX_CHECK_POLL
 126   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 127
 128   # For xsputn_2().
 129   AC_CHECK_HEADERS(sys/uio.h)
 130   GLIBCXX_CHECK_WRITEV
 131
 132   AC_LC_MESSAGES
 133
 134   AC_TRY_COMPILE(
 135     [#include <setjmp.h>],
 136     [sigjmp_buf env;
 137      while (! sigsetjmp (env, 1))
 138        siglongjmp (env, 1);
 139     ],
 140     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
 141
 142   AC_FUNC_MMAP
 143
 144 else
 145
 146   # This lets us hard-code the functionality we know we'll have in the cross
 147   # target environment.  "Let" is a sugar-coated word placed on an especially
 148   # dull and tedious hack, actually.
 149   #
 150   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 151   # that involve linking, can't be used:
 152   #    "cannot open sim-crt0.o"
 153   #    "cannot open crt0.o"
 154   # etc.  All this is because there currently exists no unified, consistent
 155   # way for top level CC information to be passed down to target directories:
 156   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 157   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 158   # crosses can be removed.
 159
 160   # If Canadian cross, then don't pick up tools from the build directory.
 161   # Used only in GLIBCXX_EXPORT_INCLUDES.
 162   if test -n "$with_cross_host" &&
 163      test x"$build" != x"$with_cross_host" &&
 164      test x"$build" != x"$target";
 165   then
 166     CANADIAN=yes
 167   else
 168     CANADIAN=no
 169   fi
 170
 171   # Construct crosses by hand, eliminating bits that need ld...
 172   # GLIBCXX_CHECK_COMPILER_FEATURES
 173   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 174   # GLIBCXX_CHECK_MATH_SUPPORT
 175
 176   # First, test for "known" system libraries.  We may be using newlib even
 177   # on a hosted environment.
 178   if test "x${with_newlib}" = "xyes"; then
 179     os_include_dir="os/newlib"
 180     AC_DEFINE(HAVE_HYPOT)
 181
 182     # GLIBCXX_CHECK_STDLIB_SUPPORT
 183     AC_DEFINE(HAVE_STRTOF)
 184     AC_DEFINE(HAVE_STRTOLD)
 185     # AC_FUNC_MMAP
 186     AC_DEFINE(HAVE_MMAP)
 187
 188     AC_DEFINE(HAVE_ACOSF)
 189     AC_DEFINE(HAVE_ASINF)
 190     AC_DEFINE(HAVE_ATAN2F)
 191     AC_DEFINE(HAVE_ATANF)
 192     AC_DEFINE(HAVE_CEILF)
 193     AC_DEFINE(HAVE_COPYSIGN)
 194     AC_DEFINE(HAVE_COPYSIGNF)
 195     AC_DEFINE(HAVE_COSF)
 196     AC_DEFINE(HAVE_COSHF)
 197     AC_DEFINE(HAVE_EXPF)
 198     AC_DEFINE(HAVE_FABSF)
 199     AC_DEFINE(HAVE_FLOORF)
 200     AC_DEFINE(HAVE_FMODF)
 201     AC_DEFINE(HAVE_FREXPF)
 202     AC_DEFINE(HAVE_LDEXPF)
 203     AC_DEFINE(HAVE_LOG10F)
 204     AC_DEFINE(HAVE_LOGF)
 205     AC_DEFINE(HAVE_MODFF)
 206     AC_DEFINE(HAVE_POWF)
 207     AC_DEFINE(HAVE_SINF)
 208     AC_DEFINE(HAVE_SINHF)
 209     AC_DEFINE(HAVE_SQRTF)
 210     AC_DEFINE(HAVE_TANF)
 211     AC_DEFINE(HAVE_TANHF)
 212   else
 213     m4_include([crossconfig.m4])
 214   fi
 215
 216   # At some point, we should differentiate between architectures
 217   # like x86, which have long double versions, and alpha/powerpc/etc.,
 218   # which don't. For the time being, punt.
 219   if test x"long_double_math_on_this_cpu" = x"yes"; then
 220     AC_DEFINE(HAVE_ACOSL)
 221     AC_DEFINE(HAVE_ASINL)
 222     AC_DEFINE(HAVE_ATAN2L)
 223     AC_DEFINE(HAVE_ATANL)
 224     AC_DEFINE(HAVE_CEILL)
 225     AC_DEFINE(HAVE_COPYSIGNL)
 226     AC_DEFINE(HAVE_COSL)
 227     AC_DEFINE(HAVE_COSHL)
 228     AC_DEFINE(HAVE_EXPL)
 229     AC_DEFINE(HAVE_FABSL)
 230     AC_DEFINE(HAVE_FLOORL)
 231     AC_DEFINE(HAVE_FMODL)
 232     AC_DEFINE(HAVE_FREXPL)
 233     AC_DEFINE(HAVE_LDEXPL)
 234     AC_DEFINE(HAVE_LOG10L)
 235     AC_DEFINE(HAVE_LOGL)
 236     AC_DEFINE(HAVE_MODFL)
 237     AC_DEFINE(HAVE_POWL)
 238     AC_DEFINE(HAVE_SINCOSL)
 239     AC_DEFINE(HAVE_SINL)
 240     AC_DEFINE(HAVE_SINHL)
 241     AC_DEFINE(HAVE_SQRTL)
 242     AC_DEFINE(HAVE_TANL)
 243     AC_DEFINE(HAVE_TANHL)
 244   fi
 245
 246 fi
 247
 248 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 249 GLIBCXX_ENABLE_SYMVERS([yes])
 250
 251 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 252 GLIBCXX_CONFIGURE_TESTSUITE
 253
 254 # Propagate the target-specific source directories through the build chain.
 255 # (Nothing currently uses cpu_include_dir directly; only atomicity_include_dir
 256 # uses it, and it only gets used in this file.)
 257 ATOMICITY_INC_SRCDIR=config/${atomicity_include_dir}
 258 OS_INC_SRCDIR=config/${os_include_dir}
 259 FPOS_INC_SRCDIR=config/${fpos_include_dir}
 260 AC_SUBST(ATOMICITY_INC_SRCDIR)
 261 AC_SUBST(FPOS_INC_SRCDIR)
 262 AC_SUBST(OS_INC_SRCDIR)
 263
 264 # Determine cross-compile flags and AM_CONDITIONALs.
 265 #AC_SUBST(GLIBCXX_IS_NATIVE)
 266 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 267 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 268 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 269
 270 AC_CACHE_SAVE
 271
 272 if test ${multilib} = yes; then
 273   multilib_arg="--enable-multilib"
 274 else
 275   multilib_arg=
 276 fi
 277
 278 # Export all the install information.
 279 GLIBCXX_EXPORT_INSTALL_INFO
 280
 281 # Export all the include and flag information to Makefiles.
 282 GLIBCXX_EXPORT_INCLUDES
 283 GLIBCXX_EXPORT_FLAGS
 284
 285 if ${CONFIG_SHELL-/bin/sh} ./libtool --tag CXX --features |
 286    grep "enable shared" > /dev/null;
 287 then
 288   LIBSUPCXX_PICFLAGS=-prefer-pic
 289 else
 290   LIBSUPCXX_PICFLAGS=
 291 fi
 292 AC_SUBST(LIBSUPCXX_PICFLAGS)
 293
 294 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 295 dnl which can all be called multiple times as needed, plus one (different)
 296 dnl AC_OUPUT macro.  This one lists the files to be created:
 297 AC_CONFIG_FILES([ \
 298   Makefile \
 299   include/Makefile \
 300   libmath/Makefile \
 301   libsupc++/Makefile \
 302   po/Makefile \
 303   src/Makefile \
 304   testsuite/Makefile \
 305   ])
 306 AC_CONFIG_FILES([scripts/check_survey],[chmod +x scripts/check_survey])
 307 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 308
 309 dnl These commands are run at the end of config.status:
 310 AC_CONFIG_COMMANDS([default],
 311 [if test -n "$CONFIG_FILES"; then
 312    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 313    # that multilib installs will end up installed in the correct place.
 314    # The testsuite needs it for multilib-aware ABI baseline files.
 315    # To work around this not being passed down from config-ml.in ->
 316    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 317    # append it here.  Only modify Makefiles that have just been created.
 318    #
 319    # Also, get rid of this simulated-VPATH thing that automake does.
 320    cat > vpsed << \_EOF
 321 s!`test -f '$<' || echo '$(srcdir)/'`!!
 322 _EOF
 323    for i in libmath libsupc++ src testsuite; do
 324     case $CONFIG_FILES in
 325      *${i}/Makefile*)
 326        #echo "Adding MULTISUBDIR to $i/Makefile"
 327        sed -f vpsed $i/Makefile > tmp
 328        grep '^MULTISUBDIR =' Makefile >> tmp
 329        mv tmp $i/Makefile
 330        ;;
 331     esac
 332    done
 333    rm vpsed
 334  fi
 335  (cd include && ${MAKE-make})
 336 ],
 337 [
 338 # No init-vars needed so far which aren't already passed by autoconf.
 339 ])
 340
 341 dnl And this actually makes things happen:
 342 AC_OUTPUT