configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [https://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([binutils],
 131             AC_HELP_STRING([--with-binutils=PATH],
 132                            [specify location of binutils (as and ld)]),
 133             [path_binutils=$withval],
 134             [path_binutils=''])
 135 AC_ARG_WITH([selinux],
 136             AC_HELP_STRING([--with-selinux],
 137                            [if building with SELinux support]),
 138             [with_selinux=$withval],
 139             [with_selinux=auto])
 140
 141 AC_ARG_WITH([headers],
 142             AC_HELP_STRING([--with-headers=PATH],
 143                            [location of system headers to use
 144                             (for example /usr/src/linux/include)
 145                             @<:@default=compiler default@:>@]),
 146             [sysheaders=$withval],
 147             [sysheaders=''])
 148 AC_SUBST(sysheaders)
 149
 150 AC_SUBST(use_default_link)
 151 AC_ARG_WITH([default-link],
 152             AC_HELP_STRING([--with-default-link],
 153                            [do not use explicit linker scripts]),
 154             [use_default_link=$withval],
 155             [use_default_link=default])
 156
 157 dnl Additional build flags injection.
 158 AC_ARG_WITH([nonshared-cflags],
 159             AC_HELP_STRING([--with-nonshared-cflags=CFLAGS],
 160                            [build nonshared libraries with additional CFLAGS]),
 161             [extra_nonshared_cflags=$withval],
 162             [extra_nonshared_cflags=])
 163 AC_SUBST(extra_nonshared_cflags)
 164
 165 AC_ARG_ENABLE([sanity-checks],
 166               AC_HELP_STRING([--disable-sanity-checks],
 167                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 168               [enable_sanity=$enableval],
 169               [enable_sanity=yes])
 170
 171 AC_ARG_ENABLE([shared],
 172               AC_HELP_STRING([--enable-shared],
 173                              [build shared library @<:@default=yes if GNU ld@:>@]),
 174               [shared=$enableval],
 175               [shared=yes])
 176 AC_ARG_ENABLE([profile],
 177               AC_HELP_STRING([--enable-profile],
 178                              [build profiled library @<:@default=no@:>@]),
 179               [profile=$enableval],
 180               [profile=no])
 181 AC_ARG_ENABLE([static-pie],
 182               AC_HELP_STRING([--enable-static-pie],
 183                              [enable static PIE support and use it in the testsuite @<:@default=no@:>@]),
 184               [static_pie=$enableval],
 185               [static_pie=no])
 186 AC_ARG_ENABLE([timezone-tools],
 187               AC_HELP_STRING([--disable-timezone-tools],
 188                              [do not install timezone tools @<:@default=install@:>@]),
 189               [enable_timezone_tools=$enableval],
 190               [enable_timezone_tools=yes])
 191 AC_SUBST(enable_timezone_tools)
 192
 193 AC_ARG_ENABLE([hardcoded-path-in-tests],
 194               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 195                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 196               [hardcoded_path_in_tests=$enableval],
 197               [hardcoded_path_in_tests=no])
 198 AC_SUBST(hardcoded_path_in_tests)
 199
 200 AC_ARG_ENABLE([stackguard-randomization],
 201               AC_HELP_STRING([--enable-stackguard-randomization],
 202                              [initialize __stack_chk_guard canary with a random number at program start]),
 203               [enable_stackguard_randomize=$enableval],
 204               [enable_stackguard_randomize=no])
 205 if test "$enable_stackguard_randomize" = yes; then
 206   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 207 fi
 208
 209 AC_ARG_ENABLE([hidden-plt],
 210               AC_HELP_STRING([--disable-hidden-plt],
 211                              [do not hide internal function calls to avoid PLT]),
 212               [hidden=$enableval],
 213               [hidden=yes])
 214 if test "x$hidden" = xno; then
 215   AC_DEFINE(NO_HIDDEN)
 216 fi
 217
 218 AC_ARG_ENABLE([bind-now],
 219               AC_HELP_STRING([--enable-bind-now],
 220                              [disable lazy relocations in DSOs]),
 221               [bindnow=$enableval],
 222               [bindnow=no])
 223 AC_SUBST(bindnow)
 224 if test "x$bindnow" = xyes; then
 225   AC_DEFINE(BIND_NOW)
 226 fi
 227
 228 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 229 dnl -fstack-protector-strong.
 230 AC_ARG_ENABLE([stack-protector],
 231               AC_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 232                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 233               [enable_stack_protector=$enableval],
 234               [enable_stack_protector=no])
 235 case "$enable_stack_protector" in
 236 all|yes|no|strong) ;;
 237 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 238 esac
 239
 240 dnl On some platforms we cannot use dynamic loading.  We must provide
 241 dnl static NSS modules.
 242 AC_ARG_ENABLE([static-nss],
 243               AC_HELP_STRING([--enable-static-nss],
 244                              [build static NSS modules @<:@default=no@:>@]),
 245               [static_nss=$enableval],
 246               [static_nss=no])
 247 dnl Enable static NSS also if we build no shared objects.
 248 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 249   static_nss=yes
 250   AC_DEFINE(DO_STATIC_NSS)
 251 fi
 252
 253 AC_ARG_ENABLE([force-install],
 254               AC_HELP_STRING([--disable-force-install],
 255                              [don't force installation of files from this package, even if they are older than the installed files]),
 256               [force_install=$enableval],
 257               [force_install=yes])
 258 AC_SUBST(force_install)
 259
 260 AC_ARG_ENABLE([maintainer-mode],
 261               AC_HELP_STRING([--enable-maintainer-mode],
 262                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 263               [maintainer=$enableval],
 264               [maintainer=no])
 265
 266 dnl On some platforms we allow dropping compatibility with all kernel
 267 dnl versions.
 268 AC_ARG_ENABLE([kernel],
 269               AC_HELP_STRING([--enable-kernel=VERSION],
 270                              [compile for compatibility with kernel not older than VERSION]),
 271               [minimum_kernel=$enableval],
 272               [])
 273 dnl Prevent unreasonable values.
 274 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 275   # Better nothing than this.
 276   minimum_kernel=""
 277 else
 278   if test "$minimum_kernel" = current; then
 279     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 280   fi
 281 fi
 282
 283 dnl For the development we sometimes want gcc to issue even more warnings.
 284 dnl This is not the default since many of the extra warnings are not
 285 dnl appropriate.
 286 AC_ARG_ENABLE([all-warnings],
 287               AC_HELP_STRING([--enable-all-warnings],
 288                              [enable all useful warnings gcc can issue]),
 289               [all_warnings=$enableval],
 290               [])
 291 AC_SUBST(all_warnings)
 292
 293 AC_ARG_ENABLE([werror],
 294               AC_HELP_STRING([--disable-werror],
 295                              [do not build with -Werror]),
 296               [enable_werror=$enableval],
 297               [enable_werror=yes])
 298 AC_SUBST(enable_werror)
 299
 300 AC_ARG_ENABLE([multi-arch],
 301               AC_HELP_STRING([--enable-multi-arch],
 302                              [enable single DSO with optimizations for multiple architectures]),
 303               [multi_arch=$enableval],
 304               [multi_arch=default])
 305
 306 AC_ARG_ENABLE([experimental-malloc],
 307               AC_HELP_STRING([--disable-experimental-malloc],
 308                              [disable experimental malloc features]),
 309               [experimental_malloc=$enableval],
 310               [experimental_malloc=yes])
 311 AC_SUBST(experimental_malloc)
 312
 313 AC_ARG_ENABLE([crypt],
 314               AC_HELP_STRING([--disable-crypt],
 315                              [do not build nor install the passphrase hashing library, libcrypt]),
 316               [build_crypt=$enableval],
 317               [build_crypt=yes])
 318 AC_SUBST(build_crypt)
 319
 320 AC_ARG_ENABLE([nss-crypt],
 321               AC_HELP_STRING([--enable-nss-crypt],
 322                              [enable libcrypt to use nss]),
 323               [nss_crypt=$enableval],
 324               [nss_crypt=no])
 325 if test x$build_libcrypt = xno && test x$nss_crypt = xyes; then
 326   AC_MSG_WARN([--enable-nss-crypt has no effect when libcrypt is disabled])
 327   nss_crypt=no
 328 fi
 329 if test x$nss_crypt = xyes; then
 330   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 331   if test $? -ne 0; then
 332     AC_MSG_ERROR([cannot find include directory with nss-config])
 333   fi
 334   nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
 335   if test $? -ne 0; then
 336     AC_MSG_ERROR([cannot find include directory with nspr-config])
 337   fi
 338   old_CFLAGS="$CFLAGS"
 339   CFLAGS="$CFLAGS $nss_includes $nspr_includes"
 340   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 341 #include <hasht.h>
 342 #include <nsslowhash.h>
 343 void f (void) { NSSLOW_Init (); }])],
 344              libc_cv_nss_crypt=yes,
 345              AC_MSG_ERROR([
 346 cannot find NSS headers with lowlevel hash function interfaces]))
 347   old_LIBS="$LIBS"
 348   old_LDFLAGS="$LDFLAGS"
 349   LIBS="$LIBS -lfreebl3"
 350   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 351 #include <hasht.h>
 352 #include <nsslowhash.h>],
 353                                   [NSSLOW_Init();])],
 354                  libc_cv_nss_crypt=yes,
 355                  AC_MSG_ERROR([
 356 cannot link program using lowlevel NSS hash functions]))
 357   # Check to see if there is a static NSS cryptographic library.
 358   # If there isn't then we can't link anything with libcrypt.a,
 359   # and that might mean disabling some static tests.
 360   LDFLAGS="$LDFLAGS -static"
 361   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 362 #include <hasht.h>
 363 #include <nsslowhash.h>],
 364                                   [NSSLOW_Init();])],
 365                  libc_cv_static_nss_crypt=yes,
 366                  libc_cv_static_nss_crypt=no)
 367   LDFLAGS="$old_LDFLAGS"
 368   CFLAGS="$old_CFLAGS"
 369   LIBS="$old_LIBS"
 370 else
 371   libc_cv_nss_crypt=no
 372   libc_cv_static_nss_crypt=no
 373 fi
 374 AC_SUBST(libc_cv_nss_crypt)
 375 AC_SUBST(libc_cv_static_nss_crypt)
 376
 377
 378 AC_ARG_ENABLE([obsolete-rpc],
 379               AC_HELP_STRING([--enable-obsolete-rpc],
 380                              [build and install the obsolete RPC code for link-time usage]),
 381               [link_obsolete_rpc=$enableval],
 382               [link_obsolete_rpc=no])
 383 AC_SUBST(link_obsolete_rpc)
 384
 385 if test "$link_obsolete_rpc" = yes; then
 386   AC_DEFINE(LINK_OBSOLETE_RPC)
 387 fi
 388
 389 AC_ARG_ENABLE([obsolete-nsl],
 390               AC_HELP_STRING([--enable-obsolete-nsl],
 391                              [build and install the obsolete libnsl library and depending NSS modules]),
 392               [build_obsolete_nsl=$enableval],
 393               [build_obsolete_nsl=no])
 394 AC_SUBST(build_obsolete_nsl)
 395
 396 if test "$build_obsolete_nsl" = yes; then
 397   AC_DEFINE(LINK_OBSOLETE_NSL)
 398 fi
 399
 400 AC_ARG_ENABLE([systemtap],
 401               [AS_HELP_STRING([--enable-systemtap],
 402                [enable systemtap static probe points @<:@default=no@:>@])],
 403               [systemtap=$enableval],
 404               [systemtap=no])
 405 if test "x$systemtap" != xno; then
 406   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 407   old_CFLAGS="$CFLAGS"
 408   CFLAGS="-std=gnu11 $CFLAGS"
 409   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 410 void foo (int i, void *p)
 411 {
 412   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 413        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 414 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 415   CFLAGS="$old_CFLAGS"])
 416   if test $libc_cv_sdt = yes; then
 417     AC_DEFINE([USE_STAP_PROBE])
 418   elif test "x$systemtap" != xauto; then
 419     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 420   fi
 421 fi
 422
 423 AC_ARG_ENABLE([build-nscd],
 424               [AS_HELP_STRING([--disable-build-nscd],
 425                [disable building and installing the nscd daemon])],
 426               [build_nscd=$enableval],
 427               [build_nscd=default])
 428 AC_SUBST(build_nscd)
 429
 430 # Note the use of $use_nscd is near the bottom of the file.
 431 AC_ARG_ENABLE([nscd],
 432               [AS_HELP_STRING([--disable-nscd],
 433                [library functions will not contact the nscd daemon])],
 434               [use_nscd=$enableval],
 435               [use_nscd=yes])
 436
 437 AC_ARG_ENABLE([pt_chown],
 438               [AS_HELP_STRING([--enable-pt_chown],
 439                [Enable building and installing pt_chown])],
 440               [build_pt_chown=$enableval],
 441               [build_pt_chown=no])
 442 AC_SUBST(build_pt_chown)
 443 if test "$build_pt_chown" = yes; then
 444   AC_DEFINE(HAVE_PT_CHOWN)
 445 fi
 446
 447 AC_ARG_ENABLE([tunables],
 448               [AS_HELP_STRING([--enable-tunables],
 449                [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
 450               [have_tunables=$enableval],
 451               [have_tunables=yes])
 452 AC_SUBST(have_tunables)
 453 if test "$have_tunables" = yes; then
 454   AC_DEFINE(HAVE_TUNABLES)
 455 fi
 456
 457 # The abi-tags file uses a fairly simplistic model for name recognition that
 458 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 459 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 460 # This doesn't get used much beyond that, so it's fairly safe.
 461 case "$host_os" in
 462 linux*)
 463   ;;
 464 gnu*)
 465   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 466   ;;
 467 esac
 468
 469 AC_ARG_ENABLE([mathvec],
 470               [AS_HELP_STRING([--enable-mathvec],
 471               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 472               [build_mathvec=$enableval],
 473               [build_mathvec=notset])
 474
 475 AC_ARG_ENABLE([cet],
 476               AC_HELP_STRING([--enable-cet],
 477                              [enable Intel Control-flow Enforcement Technology (CET), x86 only]),
 478               [enable_cet=$enableval],
 479               [enable_cet=no])
 480
 481 # We keep the original values in `$config_*' and never modify them, so we
 482 # can write them unchanged into config.make.  Everything else uses
 483 # $machine, $vendor, and $os, and changes them whenever convenient.
 484 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 485
 486 # Don't allow vendor == "unknown"
 487 test "$config_vendor" = unknown && config_vendor=
 488 config_os="`echo $config_os | sed 's/^unknown-//'`"
 489
 490 # Some configurations imply other options.
 491 elf=yes
 492
 493 # The configure fragment of a port can modify these to supplement
 494 # or override the table in the case statement below.  No fragment should
 495 # ever change the config_* variables, however.
 496 machine=$config_machine
 497 vendor=$config_vendor
 498 os=$config_os
 499 base_os=''
 500
 501 submachine=
 502 AC_ARG_WITH([cpu],
 503             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 504             [dnl
 505   case "$withval" in
 506   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 507   no) ;;
 508   *) submachine="$withval" ;;
 509   esac
 510 ])
 511
 512 # An preconfigure script can set this when it wants to disable the sanity
 513 # check below.
 514 libc_config_ok=no
 515
 516 # A preconfigure script for a system that may or may not use fpu
 517 # sysdeps directories sets this to a preprocessor conditional for
 518 # whether to use such directories.
 519 with_fp_cond=1
 520
 521 dnl Let sysdeps/*/preconfigure act here.
 522 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 523
 524
 525 ###
 526 ### By using the undocumented --enable-hacker-mode option for configure
 527 ### one can skip this test to make the configuration not fail for unsupported
 528 ### platforms.
 529 ###
 530 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 531   case "$machine-$host_os" in
 532   *-linux* | *-gnu*)
 533     ;;
 534   *)
 535     AC_MSG_ERROR([
 536 *** The GNU C library is currently unavailable for this platform.
 537 *** If you are interested in seeing glibc on this platform visit
 538 *** the "How to submit a new port" in the wiki:
 539 ***   https://sourceware.org/glibc/wiki/#Development
 540 *** and join the community!])
 541     ;;
 542   esac
 543 fi
 544
 545 # Set base_machine if not set by a preconfigure fragment.
 546 test -n "$base_machine" || base_machine=$machine
 547 AC_SUBST(base_machine)
 548
 549 # Determine whether to use fpu or nofpu sysdeps directories.
 550 AC_CACHE_CHECK([for use of fpu sysdeps directories],
 551                libc_cv_with_fp, [dnl
 552 cat > conftest.c <<EOF
 553 #if $with_fp_cond
 554 int dummy;
 555 #else
 556 # error "no hardware floating point"
 557 #endif
 558 EOF
 559 libc_cv_with_fp=no
 560 if ${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s \
 561    1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 562   libc_cv_with_fp=yes
 563 fi
 564 rm -f conftest*])
 565 AC_SUBST(libc_cv_with_fp)
 566
 567 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 568 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 569                    [libc_cv_ssp=yes],
 570                    [libc_cv_ssp=no])
 571 ])
 572
 573 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 574 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 575                    [libc_cv_ssp_strong=yes],
 576                    [libc_cv_ssp_strong=no])
 577 ])
 578
 579 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 580 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 581                    [libc_cv_ssp_all=yes],
 582                    [libc_cv_ssp_all=no])
 583 ])
 584
 585 stack_protector=
 586 no_stack_protector=
 587 if test "$libc_cv_ssp" = yes; then
 588   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 589   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 590 fi
 591
 592 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 593   stack_protector="-fstack-protector"
 594   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 595 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 596   stack_protector="-fstack-protector-all"
 597   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 598 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 599   stack_protector="-fstack-protector-strong"
 600   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 601 else
 602   stack_protector="-fno-stack-protector"
 603   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 604 fi
 605 AC_SUBST(libc_cv_ssp)
 606 AC_SUBST(stack_protector)
 607 AC_SUBST(no_stack_protector)
 608
 609 if test -n "$stack_protector"; then
 610   dnl Don't run configure tests with stack-protection on, to avoid problems with
 611   dnl bootstrapping.
 612   no_ssp=-fno-stack-protector
 613 else
 614   no_ssp=
 615
 616   if test "$enable_stack_protector" != no; then
 617     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 618   fi
 619 fi
 620
 621 # For the multi-arch option we need support in the assembler & linker.
 622 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 623                libc_cv_ld_gnu_indirect_function, [dnl
 624 cat > conftest.S <<EOF
 625 .type foo,%gnu_indirect_function
 626 foo:
 627 .globl _start
 628 _start:
 629 .globl __start
 630 __start:
 631 .data
 632 #ifdef _LP64
 633 .quad foo
 634 #else
 635 .long foo
 636 #endif
 637 EOF
 638 libc_cv_ld_gnu_indirect_function=no
 639 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 640             -nostartfiles -nostdlib $no_ssp \
 641             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 642   # Do a link to see if the backend supports IFUNC relocs.
 643   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 644   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 645     libc_cv_ld_gnu_indirect_function=yes
 646   }
 647 fi
 648 rm -f conftest*])
 649
 650 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 651 AC_CACHE_CHECK([for gcc attribute ifunc support],
 652                libc_cv_gcc_indirect_function, [dnl
 653 cat > conftest.c <<EOF
 654 extern int func (int);
 655 int used_func (int a)
 656 {
 657   return a;
 658 }
 659 static void *resolver ()
 660 {
 661   return &used_func;
 662 }
 663 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 664 EOF
 665 libc_cv_gcc_indirect_function=no
 666 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 667    2>&AS_MESSAGE_LOG_FD ; then
 668   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 669     libc_cv_gcc_indirect_function=yes
 670   fi
 671 fi
 672 rm -f conftest*])
 673
 674 # Check if gcc warns about alias for function with incompatible types.
 675 AC_CACHE_CHECK([if compiler warns about alias for function with incompatible types],
 676                libc_cv_gcc_incompatible_alias, [dnl
 677 cat > conftest.c <<EOF
 678 int __redirect_foo (const void *s, int c);
 679
 680 __typeof (__redirect_foo) *foo_impl (void) __asm__ ("foo");
 681 __typeof (__redirect_foo) *foo_impl (void)
 682 {
 683   return 0;
 684 }
 685
 686 extern __typeof (__redirect_foo) foo_alias __attribute__ ((alias ("foo")));
 687 EOF
 688 libc_cv_gcc_incompatible_alias=yes
 689 if ${CC-cc} -Werror -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 690   libc_cv_gcc_incompatible_alias=no
 691 fi
 692 rm -f conftest*])
 693
 694 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 695   if test x"$multi_arch" = xyes; then
 696     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 697   else
 698     multi_arch=no
 699   fi
 700 fi
 701 if test x"$libc_cv_gcc_indirect_function" != xyes; then
 702   # GCC 8+ emits a warning for alias with incompatible types and it might
 703   # fail to build ifunc resolvers aliases to either weak or internal
 704   # symbols.  Disables multiarch build in this case.
 705   if test x"$libc_cv_gcc_incompatible_alias" == xyes; then
 706     AC_MSG_WARN([gcc emits a warning for alias between functions of incompatible types])
 707     if test x"$multi_arch" = xyes; then
 708       AC_MSG_ERROR([--enable-multi-arch support requires a gcc with gnu-indirect-function support])
 709     fi
 710     AC_MSG_WARN([Multi-arch is disabled.])
 711     multi_arch=no
 712   elif test x"$multi_arch" = xyes; then
 713     AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 714 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 715   fi
 716 fi
 717 multi_arch_d=
 718 if test x"$multi_arch" != xno; then
 719   multi_arch_d=/multiarch
 720 fi
 721
 722 # Compute the list of sysdep directories for this configuration.
 723 # This can take a while to compute.
 724 sysdep_dir=$srcdir/sysdeps
 725 AC_MSG_CHECKING(sysdep dirs)
 726 dnl We need to use [ and ] for other purposes for a while now.
 727 changequote(,)dnl
 728 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 729 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 730
 731 test "x$base_os" != x || case "$os" in
 732 gnu*)
 733   base_os=mach/hurd ;;
 734 linux*)
 735   base_os=unix/sysv ;;
 736 esac
 737
 738 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 739 tail=$os
 740 ostry=$os
 741 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 742   ostry="$ostry /$o"
 743   tail=$o
 744 done
 745 o=`echo $tail | sed 's/[0-9]*$//'`
 746 if test $o != $tail; then
 747   ostry="$ostry /$o"
 748 fi
 749 # For linux-gnu, try linux-gnu, then linux.
 750 o=`echo $tail | sed 's/-.*$//'`
 751 if test $o != $tail; then
 752   ostry="$ostry /$o"
 753 fi
 754
 755 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 756 base=
 757 tail=$base_os
 758 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 759   set $b
 760   base="$base /$1"
 761   tail="$2"
 762 done
 763
 764 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 765 mach=
 766 tail=$machine${submachine:+/$submachine}
 767 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 768   set $m
 769   # Prepend the machine's FPU directory unless --without-fp.
 770   if test "$libc_cv_with_fp" = yes; then
 771     maybe_fpu=/fpu
 772   else
 773     maybe_fpu=/nofpu
 774   fi
 775   # For each machine term, try it with and then without /multiarch.
 776   for try_fpu in $maybe_fpu ''; do
 777     for try_multi in $multi_arch_d ''; do
 778       mach="$mach /$1$try_fpu$try_multi"
 779     done
 780   done
 781   tail="$2"
 782 done
 783
 784 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 785 changequote([,])dnl
 786
 787 # Find what sysdep directories exist.
 788 sysnames=
 789 for b in $base ''; do
 790   for m0 in $mach ''; do
 791     for v in /$vendor ''; do
 792       test "$v" = / && continue
 793       for o in /$ostry ''; do
 794         test "$o" = / && continue
 795         for m in $mach ''; do
 796           try_suffix="$m0$b$v$o$m"
 797           if test -n "$try_suffix"; then
 798             try_srcdir="${srcdir}/"
 799             try="sysdeps$try_suffix"
 800             test -n "$enable_debug_configure" &&
 801             echo "$0 [DEBUG]: try $try" >&2
 802             if test -d "$try_srcdir$try"; then
 803               sysnames="$sysnames $try"
 804               { test -n "$o" || test -n "$b"; } && os_used=t
 805               { test -n "$m" || test -n "$m0"; } && machine_used=t
 806               case x${m0:-$m} in
 807               x*/$submachine) submachine_used=t ;;
 808               esac
 809             fi
 810           fi
 811         done
 812       done
 813     done
 814   done
 815 done
 816
 817 # If the assembler supports gnu_indirect_function symbol type and the
 818 # architecture supports multi-arch, we enable multi-arch by default.
 819 case $sysnames in
 820 *"$multi_arch_d"*)
 821   ;;
 822 *)
 823   test x"$multi_arch" = xdefault && multi_arch=no
 824   ;;
 825 esac
 826 if test x"$multi_arch" != xno; then
 827   AC_DEFINE(USE_MULTIARCH)
 828 fi
 829 AC_SUBST(multi_arch)
 830
 831 if test -z "$os_used" && test "$os" != none; then
 832   AC_MSG_ERROR(Operating system $os is not supported.)
 833 fi
 834 if test -z "$machine_used" && test "$machine" != none; then
 835   AC_MSG_ERROR(The $machine is not supported.)
 836 fi
 837 if test -z "$submachine_used" && test -n "$submachine"; then
 838   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 839 fi
 840 AC_SUBST(submachine)
 841
 842 # We have now validated the configuration.
 843
 844 # Expand the list of system names into a full list of directories
 845 # from each element's parent name and Implies file (if present).
 846 set $sysnames
 847 names=
 848 while test $# -gt 0; do
 849   name=$1
 850   shift
 851
 852   case " $names " in *" $name "*)
 853     # Already in the list.
 854     continue
 855   esac
 856
 857   # Report each name as we discover it, so there is no long pause in output.
 858   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 859
 860   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 861
 862   case $name in
 863     /*) xsrcdir= ;;
 864     *)  xsrcdir=$srcdir/ ;;
 865   esac
 866   test -n "$enable_debug_configure" &&
 867   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 868
 869   for implies_file in Implies Implies-before Implies-after; do
 870     implies_type=`echo $implies_file | sed s/-/_/`
 871     eval ${implies_type}=
 872     if test -f $xsrcdir$name/$implies_file; then
 873       # Collect more names from the `Implies' file (removing comments).
 874       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 875       for x in $implied_candidate; do
 876         found=no
 877         if test -d $xsrcdir$name_base/$x; then
 878           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 879           found=yes
 880         fi
 881         try="sysdeps/$x"
 882         try_srcdir=$srcdir/
 883         test -n "$enable_debug_configure" &&
 884          echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
 885         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 886         then
 887           eval "${implies_type}=\"\$${implies_type} \$try\""
 888           found=yes
 889         fi
 890         if test $found = no; then
 891           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 892         fi
 893       done
 894     fi
 895   done
 896
 897   # Add NAME to the list of names.
 898   names="$names $name"
 899
 900   # Find the parent of NAME, using the empty string if it has none.
 901 changequote(,)dnl
 902   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 903 changequote([,])dnl
 904
 905   test -n "$enable_debug_configure" &&
 906     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 907 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 908
 909   # Add the names implied by NAME, and NAME's parent (if it has one), to
 910   # the list of names to be processed (the argument list).  We prepend the
 911   # implied names to the list and append the parent.  We want implied
 912   # directories to come before further directories inferred from the
 913   # configuration components; this ensures that for sysv4, unix/common
 914   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 915   # after sysv4).
 916   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 917   test -n "$sysnames" && set $sysnames
 918 done
 919
 920 # Add the default directories.
 921 default_sysnames="sysdeps/generic"
 922 sysnames="$names $default_sysnames"
 923 AC_SUBST(sysnames)
 924 # The other names were emitted during the scan.
 925 AC_MSG_RESULT($default_sysnames)
 926
 927
 928 ### Locate tools.
 929
 930 AC_PROG_INSTALL
 931 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 932   # The makefiles need to use a different form to find it in $srcdir.
 933   INSTALL='\$(..)./scripts/install-sh -c'
 934 fi
 935 AC_PROG_LN_S
 936
 937 LIBC_PROG_BINUTILS
 938
 939 # Accept binutils 2.25 or newer.
 940 AC_CHECK_PROG_VER(AS, $AS, --version,
 941                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 942                   [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 943                   AS=: critic_missing="$critic_missing as")
 944
 945 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
 946   # Accept gold 1.14 or higher
 947   AC_CHECK_PROG_VER(LD, $LD, --version,
 948                     [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
 949                     [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
 950                     LD=: critic_missing="$critic_missing GNU gold")
 951 else
 952   AC_CHECK_PROG_VER(LD, $LD, --version,
 953                     [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 954                     [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 955                     LD=: critic_missing="$critic_missing GNU ld")
 956 fi
 957
 958 # These programs are version sensitive.
 959 AC_CHECK_TOOL_PREFIX
 960 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 961   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 962   [[4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 963
 964 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 965   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 966   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 967   MSGFMT=: aux_missing="$aux_missing msgfmt")
 968 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 969   [GNU texinfo.* \([0-9][0-9.]*\)],
 970   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
 971   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 972 AC_CHECK_PROG_VER(SED, sed, --version,
 973   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
 974   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 975   SED=: aux_missing="$aux_missing sed")
 976 AC_CHECK_PROG_VER(AWK, gawk, --version,
 977   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
 978   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
 979 AC_CHECK_PROG_VER(BISON, bison, --version,
 980   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
 981   [2.7*|[3-9].*|[1-9][0-9]*], critic_missing="$critic_missing bison")
 982
 983 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
 984 AC_TRY_COMPILE([], [
 985 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 9)
 986 #error insufficient compiler
 987 #endif],
 988                [libc_cv_compiler_ok=yes],
 989                [libc_cv_compiler_ok=no])])
 990 AS_IF([test $libc_cv_compiler_ok != yes],
 991       [critic_missing="$critic_missing compiler"])
 992
 993 AC_CHECK_TOOL(NM, nm, false)
 994
 995 if test "x$maintainer" = "xyes"; then
 996   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 997   case "x$AUTOCONF" in
 998   xno|x|x:) AUTOCONF=no ;;
 999   *)
1000     AC_CACHE_CHECK(dnl
1001   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1002     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1003       libc_cv_autoconf_works=yes
1004     else
1005       libc_cv_autoconf_works=no
1006     fi])
1007     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1008     ;;
1009   esac
1010   if test "x$AUTOCONF" = xno; then
1011     aux_missing="$aux_missing autoconf"
1012   fi
1013 else
1014   AUTOCONF=no
1015 fi
1016
1017 # Check for python3 if available, or else python.
1018 AC_CHECK_PROGS(PYTHON_PROG, python3 python,no)
1019 case "x$PYTHON_PROG" in
1020 xno|x|x:) PYTHON_PROG=no ;;
1021 *) ;;
1022 esac
1023
1024 if test "x$PYTHON_PROG" = xno; then
1025   aux_missing="$aux_missing python"
1026 else
1027   PYTHON="$PYTHON_PROG -B"
1028   AC_SUBST(PYTHON)
1029 fi
1030
1031 test -n "$critic_missing" && AC_MSG_ERROR([
1032 *** These critical programs are missing or too old:$critic_missing
1033 *** Check the INSTALL file for required versions.])
1034
1035 test -n "$aux_missing" && AC_MSG_WARN([
1036 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1037 *** some features or tests will be disabled.
1038 *** Check the INSTALL file for required versions.])
1039
1040 # if using special system headers, find out the compiler's sekrit
1041 # header directory and add that to the list.  NOTE: Only does the right
1042 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1043 if test -n "$sysheaders"; then
1044   SYSINCLUDES=-nostdinc
1045   for d in include include-fixed; do
1046     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1047     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1048   done
1049   SYSINCLUDES="$SYSINCLUDES \
1050 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1051   if test -n "$CXX"; then
1052     CXX_SYSINCLUDES=
1053     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1054     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1055       test "x$cxxheaders" != x &&
1056       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1057     done
1058   fi
1059 fi
1060 AC_SUBST(SYSINCLUDES)
1061 AC_SUBST(CXX_SYSINCLUDES)
1062
1063 # Obtain some C++ header file paths.  This is used to make a local
1064 # copy of those headers in Makerules.
1065 if test -n "$CXX"; then
1066   find_cxx_header () {
1067     echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1068          | sed -n "\,$1:,{s/:\$//;p}"
1069   }
1070   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1071   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1072   CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1073 fi
1074 AC_SUBST(CXX_CSTDLIB_HEADER)
1075 AC_SUBST(CXX_CMATH_HEADER)
1076 AC_SUBST(CXX_BITS_STD_ABS_H)
1077
1078 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1079 # since this would lead to problems installing/building glibc.
1080 # LD_LIBRARY_PATH contains the current directory if one of the following
1081 # is true:
1082 # - one of the terminals (":" and ";") is the first or last sign
1083 # - two terminals occur directly after each other
1084 # - the path contains an element with a dot in it
1085 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1086 changequote(,)dnl
1087 case ${LD_LIBRARY_PATH} in
1088   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1089     ld_library_path_setting="contains current directory"
1090     ;;
1091   *)
1092     ld_library_path_setting="ok"
1093     ;;
1094 esac
1095 changequote([,])dnl
1096 AC_MSG_RESULT($ld_library_path_setting)
1097 if test "$ld_library_path_setting" != "ok"; then
1098 AC_MSG_ERROR([
1099 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1100 *** building glibc. Please change the environment variable
1101 *** and run configure again.])
1102 fi
1103
1104 AC_PATH_PROG(BASH_SHELL, bash, no)
1105
1106 AC_PATH_PROG(PERL, perl, no)
1107 if test "$PERL" != no &&
1108    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1109   PERL=no
1110 fi
1111 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1112              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1113
1114 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1115 cat > conftest.s <<EOF
1116 .text
1117 foo:
1118 .set glibc_conftest_frobozz,foo
1119 .globl glibc_conftest_frobozz
1120 EOF
1121 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1122 # (but it doesn't work), so we must do a linking check to be sure.
1123 cat > conftest1.c <<\EOF
1124 extern int glibc_conftest_frobozz;
1125 void _start() { glibc_conftest_frobozz = 1; }
1126 EOF
1127 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1128             -nostartfiles -nostdlib $no_ssp \
1129             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1130   libc_cv_asm_set_directive=yes
1131 else
1132   libc_cv_asm_set_directive=no
1133 fi
1134 rm -f conftest*])
1135 if test $libc_cv_asm_set_directive = yes; then
1136   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1137 fi
1138
1139 AC_CACHE_CHECK(linker support for protected data symbol,
1140                libc_cv_protected_data,
1141                [cat > conftest.c <<EOF
1142                 int bar __attribute__ ((visibility ("protected"))) = 1;
1143 EOF
1144                 libc_cv_protected_data=no
1145                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1146                   cat > conftest.c <<EOF
1147                   extern int bar;
1148                   int main (void) { return bar; }
1149 EOF
1150                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1151                     libc_cv_protected_data=yes
1152                   fi
1153                 fi
1154                 rm -f conftest.*
1155                ])
1156 AC_SUBST(libc_cv_protected_data)
1157
1158 AC_CACHE_CHECK(linker support for INSERT in linker script,
1159                libc_cv_insert,
1160                [cat > conftest.c <<EOF
1161                 const int __attribute__ ((section(".bar"))) bar = 0x12345678;
1162                 int test (void) { return bar; }
1163 EOF
1164                 cat > conftest.t <<EOF
1165                 SECTIONS
1166                 {
1167                   .bar : { *(.bar) }
1168                 }
1169                 INSERT AFTER .rela.dyn;
1170 EOF
1171                 libc_cv_insert=no
1172                 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1173                   libc_cv_insert=yes
1174                 fi
1175                 rm -f conftest.*
1176                ])
1177 AC_SUBST(libc_cv_insert)
1178
1179 AC_CACHE_CHECK(for broken __attribute__((alias())),
1180                libc_cv_broken_alias_attribute,
1181                [cat > conftest.c <<EOF
1182                extern int foo (int x) __asm ("xyzzy");
1183                int bar (int x) { return x; }
1184                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1185                extern int dfoo;
1186                extern __typeof (dfoo) dfoo __asm ("abccb");
1187                int dfoo = 1;
1188 EOF
1189                libc_cv_broken_alias_attribute=yes
1190                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1191                  if grep 'xyzzy' conftest.s >/dev/null &&
1192                     grep 'abccb' conftest.s >/dev/null; then
1193                    libc_cv_broken_alias_attribute=no
1194                  fi
1195                fi
1196                rm -f conftest.c conftest.s
1197                ])
1198 if test $libc_cv_broken_alias_attribute = yes; then
1199   AC_MSG_ERROR(working alias attribute support required)
1200 fi
1201
1202 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1203                libc_cv_have_sdata_section,
1204                [echo "int i;" > conftest.c
1205                 libc_cv_have_sdata_section=no
1206                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1207                    | grep '\.sdata' >/dev/null; then
1208                   libc_cv_have_sdata_section=yes
1209                 fi
1210                 rm -f conftest.c conftest.so
1211                ])
1212 if test $libc_cv_have_sdata_section = yes; then
1213   AC_DEFINE(HAVE_SDATA_SECTION)
1214 fi
1215
1216 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1217                libc_cv_ctors_header, [dnl
1218   libc_cv_ctors_header=yes
1219   LIBC_TRY_LINK_STATIC([
1220 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1221 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1222 ],
1223               [dnl
1224       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1225         { gsub(/\@<:@ */, "@<:@") }
1226         $2 == ".ctors" || $2 == ".dtors" {
1227           size = strtonum("0x" $6)
1228           align = strtonum("0x" $NF)
1229           seen@<:@$2@:>@ = 1
1230           stub@<:@$2@:>@ = size == align * 2
1231         }
1232         END {
1233           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1234           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1235           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1236         }
1237       '], [libc_cv_ctors_header=no])
1238     ], [dnl
1239       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1240     ])
1241 ])
1242 if test $libc_cv_ctors_header = no; then
1243   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1244 fi
1245
1246 AC_CACHE_CHECK(for libunwind-support in compiler,
1247                libc_cv_cc_with_libunwind, [
1248   cat > conftest.c <<EOF
1249 int main (void) { return 0; }
1250 EOF
1251   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1252      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1253     libc_cv_cc_with_libunwind=yes
1254   else
1255     libc_cv_cc_with_libunwind=no
1256   fi
1257   rm -f conftest*])
1258 AC_SUBST(libc_cv_cc_with_libunwind)
1259 if test $libc_cv_cc_with_libunwind = yes; then
1260   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1261 fi
1262
1263 ASFLAGS_config=
1264 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1265                libc_cv_as_noexecstack, [dnl
1266 cat > conftest.c <<EOF
1267 void foo (void) { }
1268 EOF
1269 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1270                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1271    && grep .note.GNU-stack conftest.s >/dev/null \
1272    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1273                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1274 then
1275   libc_cv_as_noexecstack=yes
1276 else
1277   libc_cv_as_noexecstack=no
1278 fi
1279 rm -f conftest*])
1280 if test $libc_cv_as_noexecstack = yes; then
1281   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1282 fi
1283 AC_SUBST(ASFLAGS_config)
1284
1285 AC_CACHE_CHECK(for -z combreloc,
1286                libc_cv_z_combreloc, [dnl
1287 cat > conftest.c <<EOF
1288 extern int bar (int);
1289 extern int mumble;
1290 int foo (void) { return bar (mumble); }
1291 EOF
1292 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1293                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1294                         -nostdlib -nostartfiles
1295                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1296 then
1297 dnl The following test is a bit weak.  We must use a tool which can test
1298 dnl cross-platform since the gcc used can be a cross compiler.  Without
1299 dnl introducing new options this is not easily doable.  Instead use a tool
1300 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1301 dnl look for a section named .rel.dyn or .rela.dyn.
1302   if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1303     libc_cv_z_combreloc=yes
1304   else
1305     libc_cv_z_combreloc=no
1306   fi
1307 else
1308   libc_cv_z_combreloc=no
1309 fi
1310 rm -f conftest*])
1311 if test "$libc_cv_z_combreloc" = yes; then
1312   AC_DEFINE(HAVE_Z_COMBRELOC)
1313 fi
1314 AC_SUBST(libc_cv_z_combreloc)
1315
1316 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1317                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1318 AC_SUBST(libc_cv_z_execstack)
1319
1320 LIBC_LINKER_FEATURE([--no-dynamic-linker],
1321                     [-Wl,--no-dynamic-linker],
1322                     [libc_cv_no_dynamic_linker=yes],
1323                     [libc_cv_no_dynamic_linker=no])
1324 LIBC_CONFIG_VAR([have-no-dynamic-linker], [$libc_cv_no_dynamic_linker])
1325
1326 AC_CACHE_CHECK(for -static-pie, libc_cv_static_pie, [dnl
1327 LIBC_TRY_CC_OPTION([-static-pie],
1328                    [libc_cv_static_pie=yes],
1329                    [libc_cv_static_pie=no])
1330 ])
1331 LIBC_CONFIG_VAR([have-static-pie], [$libc_cv_static_pie])
1332
1333 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1334 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1335 ])
1336
1337 AC_SUBST(libc_cv_fpie)
1338
1339 AC_CACHE_CHECK(for --hash-style option,
1340                libc_cv_hashstyle, [dnl
1341 cat > conftest.c <<EOF
1342 int _start (void) { return 42; }
1343 EOF
1344 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1345                             -fPIC -shared -o conftest.so conftest.c
1346                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1347 then
1348   libc_cv_hashstyle=yes
1349 else
1350   libc_cv_hashstyle=no
1351 fi
1352 rm -f conftest*])
1353 AC_SUBST(libc_cv_hashstyle)
1354
1355 # The linker's default -shared behavior is good enough if it
1356 # does these things that our custom linker scripts ensure that
1357 # all allocated NOTE sections come first.
1358 if test "$use_default_link" = default; then
1359   AC_CACHE_CHECK([for sufficient default -shared layout],
1360                   libc_cv_use_default_link, [dnl
1361   libc_cv_use_default_link=no
1362   cat > conftest.s <<\EOF
1363           .section .note.a,"a",%note
1364           .balign 4
1365           .long 4,4,9
1366           .string "GNU"
1367           .string "foo"
1368           .section .note.b,"a",%note
1369           .balign 4
1370           .long 4,4,9
1371           .string "GNU"
1372           .string "bar"
1373 EOF
1374   if AC_TRY_COMMAND([dnl
1375   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1376        ac_try=`$READELF -S conftest.so | sed -n \
1377          ['${x;p;}
1378           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1379           t a
1380           b
1381           : a
1382           H']`
1383   then
1384     libc_seen_a=no libc_seen_b=no
1385     set -- $ac_try
1386     while test $# -ge 2 -a "$1" = NOTE; do
1387       case "$2" in
1388       .note.a) libc_seen_a=yes ;;
1389       .note.b) libc_seen_b=yes ;;
1390       esac
1391       shift 2
1392     done
1393     case "$libc_seen_a$libc_seen_b" in
1394     yesyes)
1395       libc_cv_use_default_link=yes
1396       ;;
1397     *)
1398       echo >&AS_MESSAGE_LOG_FD "\
1399 $libc_seen_a$libc_seen_b from:
1400 $ac_try"
1401       ;;
1402     esac
1403   fi
1404   rm -f conftest*])
1405   use_default_link=$libc_cv_use_default_link
1406 fi
1407
1408 AC_CACHE_CHECK(for GLOB_DAT reloc,
1409                libc_cv_has_glob_dat, [dnl
1410 cat > conftest.c <<EOF
1411 extern int mumble;
1412 int foo (void) { return mumble; }
1413 EOF
1414 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1415                         -fPIC -shared -o conftest.so conftest.c
1416                         -nostdlib -nostartfiles $no_ssp
1417                         1>&AS_MESSAGE_LOG_FD])
1418 then
1419 dnl look for GLOB_DAT relocation.
1420   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1421     libc_cv_has_glob_dat=yes
1422   else
1423     libc_cv_has_glob_dat=no
1424   fi
1425 else
1426   libc_cv_has_glob_dat=no
1427 fi
1428 rm -f conftest*])
1429 AC_SUBST(libc_cv_has_glob_dat)
1430
1431 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1432 if libc_cv_output_format=`
1433 ${CC-cc} -nostartfiles -nostdlib $no_ssp -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1434 then
1435   :
1436 else
1437   libc_cv_output_format=
1438 fi
1439 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1440 AC_SUBST(libc_cv_output_format)
1441
1442 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1443 cat > conftest.c <<EOF
1444 int foo;
1445 EOF
1446 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1447                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1448 then
1449   libc_cv_fno_toplevel_reorder=yes
1450 else
1451   libc_cv_fno_toplevel_reorder=no
1452 fi
1453 rm -f conftest*])
1454 if test $libc_cv_fno_toplevel_reorder = yes; then
1455   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1456 else
1457   fno_unit_at_a_time=-fno-unit-at-a-time
1458 fi
1459 AC_SUBST(fno_unit_at_a_time)
1460
1461 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1462 [dnl
1463 cat > conftest.c <<EOF
1464 __thread int i;
1465 void foo (void)
1466 {
1467   i = 10;
1468 }
1469 EOF
1470 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1471                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1472 then
1473   libc_cv_mtls_dialect_gnu2=yes
1474 else
1475   libc_cv_mtls_dialect_gnu2=no
1476 fi
1477 rm -f conftest*])
1478 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1479 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1480
1481 AC_CACHE_CHECK(whether cc puts quotes around section names,
1482                libc_cv_have_section_quotes,
1483                [cat > conftest.c <<EOF
1484                 static const int foo
1485                 __attribute__ ((section ("bar"))) = 1;
1486 EOF
1487                 if ${CC-cc} -S conftest.c -o conftest.s; then
1488                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1489                     libc_cv_have_section_quotes=yes
1490                   else
1491                     libc_cv_have_section_quotes=no
1492                   fi
1493                 else
1494                   libc_cv_have_section_quotes=unknown
1495                 fi
1496                 rm -f conftest.{c,s}
1497                 ])
1498 if test $libc_cv_have_section_quotes = yes; then
1499   AC_DEFINE(HAVE_SECTION_QUOTES)
1500 fi
1501
1502 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1503 cat > conftest.c <<\EOF
1504 void zero (void *x)
1505 {
1506   __builtin_memset (x, 0, 1000);
1507 }
1508 EOF
1509 dnl
1510 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1511 then
1512   libc_cv_gcc_builtin_memset=no
1513 else
1514   libc_cv_gcc_builtin_memset=yes
1515 fi
1516 rm -f conftest* ])
1517 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1518   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1519 fi
1520
1521 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1522 cat > conftest.c <<\EOF
1523 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1524 char *foo (const char *a, const char *b)
1525 {
1526   return __builtin_strstr (a, b);
1527 }
1528 EOF
1529 dnl
1530 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1531 then
1532   libc_cv_gcc_builtin_redirection=yes
1533 else
1534   libc_cv_gcc_builtin_redirection=no
1535 fi
1536 rm -f conftest* ])
1537 if test "$libc_cv_gcc_builtin_redirection" = no; then
1538   AC_MSG_ERROR([support for the symbol redirection needed])
1539 fi
1540
1541 dnl Determine how to disable generation of FMA instructions.
1542 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1543                libc_cv_cc_nofma, [dnl
1544 libc_cv_cc_nofma=
1545 for opt in -ffp-contract=off -mno-fused-madd; do
1546   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1547 done])
1548 AC_SUBST(libc_cv_cc_nofma)
1549
1550 if test -n "$submachine"; then
1551   AC_CACHE_CHECK([for compiler option for CPU variant],
1552                  libc_cv_cc_submachine, [dnl
1553   libc_cv_cc_submachine=no
1554   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1555     LIBC_TRY_CC_OPTION([$opt], [
1556       libc_cv_cc_submachine="$opt"
1557       break], [])
1558   done])
1559   if test "x$libc_cv_cc_submachine" = xno; then
1560     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1561   fi
1562 fi
1563 AC_SUBST(libc_cv_cc_submachine)
1564
1565 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1566 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1567 cat > conftest.c <<EOF
1568 void
1569 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1570 foo (void) {}
1571 EOF
1572 libc_cv_cc_loop_to_function=no
1573 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1574 then
1575   libc_cv_cc_loop_to_function=yes
1576 fi
1577 rm -f conftest*])
1578 if test $libc_cv_cc_loop_to_function = yes; then
1579   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1580 fi
1581 AC_SUBST(libc_cv_cc_loop_to_function)
1582
1583 dnl Check whether we have the gd library available.
1584 AC_MSG_CHECKING(for libgd)
1585 if test "$with_gd" != "no"; then
1586   old_CFLAGS="$CFLAGS"
1587   CFLAGS="$CFLAGS $libgd_include"
1588   old_LDFLAGS="$LDFLAGS"
1589   LDFLAGS="$LDFLAGS $libgd_ldflags"
1590   old_LIBS="$LIBS"
1591   LIBS="$LIBS -lgd -lpng -lz -lm"
1592   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1593   CFLAGS="$old_CFLAGS"
1594   LDFLAGS="$old_LDFLAGS"
1595   LIBS="$old_LIBS"
1596 else
1597   LIBGD=no
1598 fi
1599 AC_MSG_RESULT($LIBGD)
1600 AC_SUBST(LIBGD)
1601
1602 # SELinux detection
1603 if test x$with_selinux = xno ; then
1604   have_selinux=no;
1605 else
1606   # See if we have the SELinux library
1607   AC_CHECK_LIB(selinux, is_selinux_enabled,
1608                have_selinux=yes, have_selinux=no)
1609   if test x$with_selinux = xyes ; then
1610     if test x$have_selinux = xno ; then
1611       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1612     fi
1613   fi
1614 fi
1615 # Check if we're building with SELinux support.
1616 if test "x$have_selinux" = xyes; then
1617   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1618
1619   # See if we have the libaudit library
1620   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1621                have_libaudit=yes, have_libaudit=no)
1622   if test "x$have_libaudit" = xyes; then
1623     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1624   fi
1625   AC_SUBST(have_libaudit)
1626
1627   # See if we have the libcap library
1628   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1629   if test "x$have_libcap" = xyes; then
1630     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1631   fi
1632   AC_SUBST(have_libcap)
1633 fi
1634 AC_SUBST(have_selinux)
1635
1636 CPPUNDEFS=
1637 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1638 dnl Since we are building the implementations of the fortified functions here,
1639 dnl having the macro defined interacts very badly.
1640 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1641 [AC_TRY_COMPILE([], [
1642 #ifdef _FORTIFY_SOURCE
1643 # error bogon
1644 #endif],
1645                 [libc_cv_predef_fortify_source=no],
1646                 [libc_cv_predef_fortify_source=yes])])
1647 if test $libc_cv_predef_fortify_source = yes; then
1648   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1649 fi
1650 AC_SUBST(CPPUNDEFS)
1651
1652 # Some linkers on some architectures support __ehdr_start but with
1653 # bugs.  Make sure usage of it does not create relocations in the
1654 # output (as the linker should resolve them all for us).
1655 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1656                libc_cv_ehdr_start, [
1657 old_CFLAGS="$CFLAGS"
1658 old_LDFLAGS="$LDFLAGS"
1659 old_LIBS="$LIBS"
1660 CFLAGS="$CFLAGS -fPIC"
1661 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1662 LIBS=
1663 AC_LINK_IFELSE([AC_LANG_SOURCE([
1664 typedef struct {
1665   char foo;
1666   long val;
1667 } Ehdr;
1668 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1669 long ehdr (void) { return __ehdr_start.val; }
1670 ])],
1671                [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1672                   libc_cv_ehdr_start=broken
1673                 else
1674                   libc_cv_ehdr_start=yes
1675                 fi], [libc_cv_ehdr_start=no])
1676 CFLAGS="$old_CFLAGS"
1677 LDFLAGS="$old_LDFLAGS"
1678 LIBS="$old_LIBS"
1679 ])
1680 if test "$libc_cv_ehdr_start" = yes; then
1681   AC_DEFINE([HAVE_EHDR_START])
1682 elif test "$libc_cv_ehdr_start" = broken; then
1683   AC_MSG_WARN([linker is broken -- you should upgrade])
1684 fi
1685
1686 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1687                libc_cv_builtin_trap, [dnl
1688 libc_cv_builtin_trap=no
1689 AC_TRY_COMPILE([], [__builtin_trap ()], [
1690 libc_undefs=`$NM -u conftest.o |
1691   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1692     2>&AS_MESSAGE_LOG_FD` || {
1693   AC_MSG_ERROR([confusing output from $NM -u])
1694 }
1695 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1696 if test -z "$libc_undefs"; then
1697   libc_cv_builtin_trap=yes
1698 fi])])
1699 if test $libc_cv_builtin_trap = yes; then
1700   AC_DEFINE([HAVE_BUILTIN_TRAP])
1701 fi
1702
1703 dnl C++ feature tests.
1704 AC_LANG_PUSH([C++])
1705
1706 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1707                libc_cv_cxx_thread_local, [
1708 old_CXXFLAGS="$CXXFLAGS"
1709 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1710 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1711 #include <thread>
1712
1713 // Compiler support.
1714 struct S
1715 {
1716   S ();
1717   ~S ();
1718 };
1719 thread_local S s;
1720 S * get () { return &s; }
1721
1722 // libstdc++ support.
1723 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1724 #error __cxa_thread_atexit_impl not supported
1725 #endif
1726 ])],
1727                [libc_cv_cxx_thread_local=yes],
1728                [libc_cv_cxx_thread_local=no])
1729 CXXFLAGS="$old_CXXFLAGS"
1730 ])
1731 AC_SUBST(libc_cv_cxx_thread_local)
1732
1733 AC_LANG_POP([C++])
1734 dnl End of C++ feature tests.
1735
1736 ### End of automated tests.
1737 ### Now run sysdeps configure fragments.
1738
1739 # They also can set these variables.
1740 use_ldconfig=no
1741 ldd_rewrite_script=no
1742 libc_cv_sysconfdir=$sysconfdir
1743 libc_cv_localstatedir=$localstatedir
1744 libc_cv_gcc_unwind_find_fde=no
1745 libc_cv_idn=no
1746
1747 # Iterate over all the sysdep directories we will use, running their
1748 # configure fragments.
1749 for dir in $sysnames; do
1750   case $dir in
1751     /*) dest=$dir ;;
1752     *)  dest=$srcdir/$dir ;;
1753   esac
1754   if test -r $dest/configure; then
1755     AC_MSG_RESULT(running configure fragment for $dir)
1756     . $dest/configure
1757   fi
1758 done
1759
1760 if test x"$build_mathvec" = xnotset; then
1761   build_mathvec=no
1762 fi
1763 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1764
1765 AC_SUBST(libc_extra_cflags)
1766 AC_SUBST(libc_extra_cppflags)
1767
1768 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1769   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1770 fi
1771 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1772
1773 # A sysdeps configure fragment can reset this if IFUNC is not actually
1774 # usable even though the assembler knows how to generate the symbol type.
1775 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1776   AC_DEFINE(HAVE_IFUNC)
1777 fi
1778
1779 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1780   AC_DEFINE(HAVE_GCC_IFUNC)
1781 fi
1782
1783 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1784 # configure fragment can override the value to prevent this AC_DEFINE.
1785 AC_SUBST(use_nscd)
1786 if test "x$use_nscd" != xno; then
1787   AC_DEFINE([USE_NSCD])
1788 fi
1789 if test "x$build_nscd" = xdefault; then
1790   build_nscd=$use_nscd
1791 fi
1792
1793 AC_SUBST(libc_cv_slibdir)
1794 AC_SUBST(libc_cv_rtlddir)
1795 AC_SUBST(libc_cv_complocaledir)
1796 AC_SUBST(libc_cv_sysconfdir)
1797 AC_SUBST(libc_cv_localstatedir)
1798 AC_SUBST(libc_cv_rootsbindir)
1799
1800 if test x$use_ldconfig = xyes; then
1801   AC_DEFINE(USE_LDCONFIG)
1802 fi
1803 AC_SUBST(use_ldconfig)
1804 AC_SUBST(ldd_rewrite_script)
1805
1806 AC_SUBST(static)
1807 AC_SUBST(shared)
1808
1809 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1810 [libc_cv_pic_default=yes
1811 cat > conftest.c <<EOF
1812 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1813 # error PIC is default.
1814 #endif
1815 EOF
1816 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1817   libc_cv_pic_default=no
1818 fi
1819 rm -f conftest.*])
1820 AC_SUBST(libc_cv_pic_default)
1821
1822 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_cc_pie_default,
1823 [libc_cv_cc_pie_default=yes
1824 cat > conftest.c <<EOF
1825 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1826 # error PIE is default.
1827 #endif
1828 EOF
1829 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1830   libc_cv_cc_pie_default=no
1831 fi
1832 rm -f conftest.*])
1833 libc_cv_pie_default=$libc_cv_cc_pie_default
1834 AC_SUBST(libc_cv_cc_pie_default)
1835 AC_SUBST(libc_cv_pie_default)
1836
1837 # Set the `multidir' variable by grabbing the variable from the compiler.
1838 # We do it once and save the result in a generated makefile.
1839 libc_cv_multidir=`${CC-cc} $CFLAGS $CPPFLAGS -print-multi-directory`
1840 AC_SUBST(libc_cv_multidir)
1841
1842 if test "$static_pie" = yes; then
1843   # The linker must support --no-dynamic-linker.
1844   if test "$libc_cv_no_dynamic_linker" != yes; then
1845     AC_MSG_ERROR([linker support for --no-dynamic-linker needed])
1846   fi
1847   # Default to PIE.
1848   libc_cv_pie_default=yes
1849   AC_DEFINE(ENABLE_STATIC_PIE)
1850 fi
1851 LIBC_CONFIG_VAR([enable-static-pie], [$static_pie])
1852
1853 AC_SUBST(profile)
1854 AC_SUBST(static_nss)
1855
1856 AC_SUBST(DEFINES)
1857
1858 dnl See sysdeps/mach/configure.ac for this variable.
1859 AC_SUBST(mach_interface_list)
1860
1861 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1862 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1863 AC_SUBST(VERSION)
1864 AC_SUBST(RELEASE)
1865
1866 AC_CONFIG_FILES([config.make Makefile])
1867 AC_CONFIG_COMMANDS([default],[[
1868 case $CONFIG_FILES in *config.make*)
1869 echo "$config_vars" >> config.make;;
1870 esac
1871 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1872 AC_OUTPUT