nptl/sysdeps/unix/sysv/linux/sh/sem_wait.S

   1 /* Copyright (C) 2003-2013 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, see
  16    <http://www.gnu.org/licenses/>.  */
  17
  18 #include <sysdep.h>
  19 #include <shlib-compat.h>
  20 #include <pthread-errnos.h>
  21 #include <tcb-offsets.h>
  22 #include <structsem.h>
  23 #include <lowlevellock.h>
  24 #include "lowlevel-atomic.h"
  25
  26
  27 #if VALUE != 0
  28 # error "code needs to be rewritten for VALUE != 0"
  29 #endif
  30
  31         .text
  32
  33         .globl  __new_sem_wait
  34         .type   __new_sem_wait,@function
  35         .align  5
  36         cfi_startproc
  37 __new_sem_wait:
  38 .LSTARTCODE:
  39 #ifdef SHARED
  40         cfi_personality(DW_EH_PE_pcrel | DW_EH_PE_sdata4 | DW_EH_PE_indirect,
  41                         DW.ref.__gcc_personality_v0)
  42         cfi_lsda(DW_EH_PE_pcrel | DW_EH_PE_sdata4, .LexceptSTART)
  43 #else
  44         cfi_personality(DW_EH_PE_absptr, __gcc_personality_v0)
  45         cfi_lsda(DW_EH_PE_absptr, .LexceptSTART)
  46 #endif
  47         mov.l   r8, @-r15
  48         cfi_adjust_cfa_offset (4)
  49         cfi_rel_offset (r8, 0)
  50         mov.l   r10, @-r15
  51         cfi_adjust_cfa_offset (4)
  52         cfi_rel_offset (r10, 0)
  53         mov.l   r12, @-r15
  54         cfi_adjust_cfa_offset (4)
  55         cfi_rel_offset (r12, 0)
  56         sts.l   pr, @-r15
  57         cfi_adjust_cfa_offset (4)
  58         cfi_rel_offset (pr, 0)
  59
  60         mov     r4, r8
  61         mov.l   @r8, r0
  62 2:
  63         tst     r0, r0
  64         bt      1f
  65         mov     r0, r3
  66         mov     r0, r4
  67         add     #-1, r3
  68         CMPXCHG (r4, @r8, r3, r2)
  69         bf/s    2b
  70          mov    r2, r0
  71 7:
  72         mov     #0, r0
  73 9:
  74         cfi_remember_state
  75         lds.l   @r15+, pr
  76         cfi_adjust_cfa_offset (-4)
  77         cfi_restore (pr)
  78         mov.l   @r15+, r12
  79         cfi_adjust_cfa_offset (-4)
  80         cfi_restore (r12)
  81         mov.l   @r15+, r10
  82         cfi_adjust_cfa_offset (-4)
  83         cfi_restore (r10)
  84         rts
  85          mov.l  @r15+, r8
  86         /* Omit CFI for restore in delay slot.  */
  87         cfi_restore_state
  88
  89 .Lafter_ret:
  90 1:
  91         INC (@(NWAITERS,r8),r2)
  92
  93 .LcleanupSTART:
  94 6:
  95         mov.l   .Lenable0, r1
  96         bsrf    r1
  97          nop
  98 .Lenable0b:
  99         mov     r0, r10
 100
 101         mov     r8, r4
 102 #if FUTEX_WAIT == 0
 103         mov.l   @(PRIVATE,r8), r5
 104 #else
 105         mov.l   @(PRIVATE,r8), r5
 106         mov     #FUTEX_WAIT, r0
 107         or      r0, r5
 108 #endif
 109         mov     #0, r6
 110         mov     #0, r7
 111         mov     #SYS_futex, r3
 112         extu.b  r3, r3
 113         trapa   #0x14
 114         SYSCALL_INST_PAD
 115
 116         mov.l   .Ldisable0, r1
 117         mov     r10, r4
 118         bsrf    r1
 119          mov    r0, r10
 120 .Ldisable0b:
 121         mov     r10, r0
 122 .LcleanupEND:
 123
 124         tst     r0, r0
 125         bt      3f
 126         cmp/eq  #-EWOULDBLOCK, r0
 127         bf      4f
 128
 129 3:
 130         mov.l   @r8, r0
 131 5:
 132         tst     r0, r0
 133         bt      6b
 134
 135         mov     r0, r3
 136         mov     r0, r4
 137         add     #-1, r3
 138         CMPXCHG (r4, @r8, r3, r2)
 139         bf/s    5b
 140          mov    r2, r0
 141
 142         DEC (@(NWAITERS,r8), r2)
 143         bra     7b
 144          nop
 145
 146 4:
 147         neg     r0, r0
 148         mov     r0, r4
 149         DEC (@(NWAITERS,r8), r2)
 150         mov     r4, r8
 151         mova    .Lgot0, r0
 152         mov.l   .Lgot0, r12
 153         add     r0, r12
 154
 155         mov.l   .Lerrno0, r0
 156         stc     gbr, r1
 157         mov.l   @(r0, r12), r0
 158         bra     .Lexit
 159          add    r1, r0
 160         .align  2
 161 .Lerrno0:
 162         .long   errno@GOTTPOFF
 163 .Lexit:
 164         mov.l   r8, @r0
 165         bra     9b
 166          mov    #-1, r0
 167
 168         .align  2
 169 .Lgot0:
 170         .long   _GLOBAL_OFFSET_TABLE_
 171 .Lenable0:
 172         .long   __pthread_enable_asynccancel-.Lenable0b
 173 .Ldisable0:
 174         .long   __pthread_disable_asynccancel-.Ldisable0b
 175         .size   __new_sem_wait,.-__new_sem_wait
 176         versioned_symbol(libpthread, __new_sem_wait, sem_wait, GLIBC_2_1)
 177
 178
 179         .type   sem_wait_cleanup,@function
 180 sem_wait_cleanup:
 181         DEC (@(NWAITERS,r8), r2)
 182 .LcallUR:
 183         mov.l   .Lresume, r1
 184 #ifdef PIC
 185         add     r12, r1
 186 #endif
 187         jsr     @r1
 188          nop
 189         sleep
 190
 191         .align  2
 192 .Lresume:
 193 #ifdef PIC
 194         .long   _Unwind_Resume@GOTOFF
 195 #else
 196         .long   _Unwind_Resume
 197 #endif
 198 .LENDCODE:
 199         cfi_endproc
 200         .size   sem_wait_cleanup,.-sem_wait_cleanup
 201
 202
 203         .section .gcc_except_table,"a",@progbits
 204 .LexceptSTART:
 205         .byte   DW_EH_PE_omit                   ! @LPStart format (omit)
 206         .byte   DW_EH_PE_omit                   ! @TType format (omit)
 207         .byte   DW_EH_PE_uleb128                ! call-site format
 208         .uleb128 .Lcstend-.Lcstbegin
 209 .Lcstbegin:
 210         .uleb128 .LcleanupSTART-.LSTARTCODE
 211         .uleb128 .LcleanupEND-.LcleanupSTART
 212         .uleb128 sem_wait_cleanup-.LSTARTCODE
 213         .uleb128  0
 214         .uleb128 .LcallUR-.LSTARTCODE
 215         .uleb128 .LENDCODE-.LcallUR
 216         .uleb128 0
 217         .uleb128  0
 218 .Lcstend:
 219
 220 #ifdef SHARED
 221         .hidden DW.ref.__gcc_personality_v0
 222         .weak   DW.ref.__gcc_personality_v0
 223         .section .gnu.linkonce.d.DW.ref.__gcc_personality_v0,"aw",@progbits
 224         .align  4
 225         .type   DW.ref.__gcc_personality_v0, @object
 226         .size   DW.ref.__gcc_personality_v0, 4
 227 DW.ref.__gcc_personality_v0:
 228         .long   __gcc_personality_v0
 229 #endif