ports/sysdeps/unix/mips/sysdep.S

   1 /* Copyright (C) 1992-2014 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Brendan Kehoe (brendan@zen.org).
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #define _ERRNO_H
  21 #include <bits/errno.h>
  22 #include <sys/asm.h>
  23
  24         .set    nomips16
  25
  26 #ifdef _LIBC_REENTRANT
  27
  28 LOCALSZ= 3
  29 FRAMESZ= (((NARGSAVE+LOCALSZ)*SZREG)+ALSZ)&ALMASK
  30 RAOFF= FRAMESZ-(1*SZREG)
  31 GPOFF= FRAMESZ-(2*SZREG)
  32 V0OFF= FRAMESZ-(3*SZREG)
  33
  34 ENTRY(__syscall_error)
  35 #ifdef __PIC__
  36         .set noat
  37         SETUP_GPX (AT)
  38         .set at
  39 #endif
  40         PTR_SUBU sp, FRAMESZ
  41         .set noat
  42         SETUP_GPX64(GPOFF,AT)
  43         .set at
  44 #ifdef __PIC__
  45         SAVE_GP(GPOFF)
  46 #endif
  47         REG_S   v0, V0OFF(sp)
  48         REG_S   ra, RAOFF(sp)
  49
  50 #if defined (EWOULDBLOCK_sys) && EWOULDBLOCK_sys != EAGAIN
  51         /* We translate the system's EWOULDBLOCK error into EAGAIN.
  52            The GNU C library always defines EWOULDBLOCK==EAGAIN.
  53            EWOULDBLOCK_sys is the original number.  */
  54         bne     v0, EWOULDBLOCK_sys, L(skip)
  55         nop
  56         li      v0, EAGAIN
  57 L(skip):
  58 #endif
  59         /* Find our per-thread errno address  */
  60         jal     __errno_location
  61
  62         /* Store the error value.  */
  63         REG_L   t0, V0OFF(sp)
  64         sw      t0, 0(v0)
  65
  66         /* And just kick back a -1.  */
  67         REG_L   ra, RAOFF(sp)
  68         RESTORE_GP64
  69         PTR_ADDU sp, FRAMESZ
  70         li      v0, -1
  71         j       ra
  72         END(__syscall_error)
  73
  74 #else /* _LIBC_REENTRANT */
  75
  76
  77 ENTRY(__syscall_error)
  78 #ifdef __PIC__
  79         SETUP_GPX (AT)
  80 #endif
  81         SETUP_GPX64 (t9, AT)
  82
  83 #if defined (EWOULDBLOCK_sys) && EWOULDBLOCK_sys != EAGAIN
  84         /* We translate the system's EWOULDBLOCK error into EAGAIN.
  85            The GNU C library always defines EWOULDBLOCK==EAGAIN.
  86            EWOULDBLOCK_sys is the original number.  */
  87         bne v0, EWOULDBLOCK_sys, L(skip)
  88         li v0, EAGAIN
  89 L(skip):
  90 #endif
  91         /* Store it in errno... */
  92         sw v0, errno
  93
  94         /* And just kick back a -1.  */
  95         li v0, -1
  96
  97         RESTORE_GP64
  98         j ra
  99         END(__syscall_error)
 100 #endif  /* _LIBC_REENTRANT  */