ports/sysdeps/unix/sysv/linux/aarch64/clone.S

   1 /* Copyright (C) 1996-2014 Free Software Foundation, Inc.
   2
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* clone() is even more special than fork() as it mucks with stacks
  20    and invokes a function in the right context after its all over.  */
  21
  22 #include <sysdep.h>
  23 #define _ERRNO_H        1
  24 #include <bits/errno.h>
  25
  26 #define CLONE_VM_BIT      8
  27 #define CLONE_VM          (1 << CLONE_VM_BIT)
  28
  29 #define CLONE_THREAD_BIT  16
  30 #define CLONE_THREAD      (1 << CLONE_THREAD_BIT)
  31
  32 /* int clone(int (*fn)(void *arg),            x0
  33              void *child_stack,               x1
  34              int flags,                       x2
  35              void *arg,                       x3
  36              pid_t *ptid,                     x4
  37              struct user_desc *tls,           x5
  38              pid_t *ctid);                    x6
  39  */
  40         .text
  41 ENTRY(__clone)
  42         /* Sanity check args.  */
  43         cbz     x0, 1f
  44         cbz     x1, 1f
  45         /* Insert the args onto the new stack.  */
  46         stp     x0, x3, [x1, #-16]!     /* Fn, arg.  */
  47
  48         /* Do the system call.  */
  49         mov     x0, x2                  /* flags  */
  50
  51         /* New sp is already in x1.  */
  52         mov     x2, x4                  /* ptid  */
  53         mov     x3, x5                  /* tls  */
  54         mov     x4, x6                  /* ctid  */
  55
  56 #ifdef RESET_PID
  57         /* We rely on the kernel preserving the argument regsiters across a
  58            each system call so that we can inspect the flags against after
  59            the clone call.  */
  60         mov     x5, x0
  61 #endif
  62
  63         mov     x8, #SYS_ify(clone)
  64         /* X0:flags, x1:newsp, x2:parenttidptr, x3:newtls, x4:childtid.  */
  65         svc     0x0
  66         cmp     x0, #0
  67         beq     2f
  68         blt     3f
  69         RET
  70 1:      mov     x0, #-EINVAL
  71 3:
  72         b       syscall_error
  73
  74 2:
  75 #ifdef RESET_PID
  76         tbnz    x5, #CLONE_THREAD_BIT, 3f
  77         mov     x0, #-1
  78         tbnz    x5, #CLONE_VM_BIT, 2f
  79         mov     x8, #SYS_ify(getpid)
  80         svc     0x0
  81 2:
  82         mrs     x1, tpidr_el0
  83         sub     x1, x1, #PTHREAD_SIZEOF
  84         str     w0, [x1, #PTHREAD_PID_OFFSET]
  85         str     w0, [x1, #PTHREAD_TID_OFFSET]
  86
  87 3:
  88 #endif
  89         /* Pick the function arg and call address from the stack and
  90            execute.  */
  91         ldp     x1, x0, [sp], #16
  92         blr     x1
  93
  94         /* We are done, pass the return value through x0.  */
  95         b       HIDDEN_JUMPTARGET(_exit)
  96
  97 PSEUDO_END (__clone)
  98
  99 weak_alias (__clone, clone)