ports/sysdeps/unix/sysv/linux/m68k/vfork.S

   1 /* Copyright (C) 1999, 2002, 2003, 2010, 2012 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Andreas Schwab <schwab@gnu.org>.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #define _ERRNO_H        1
  21 #include <bits/errno.h>
  22 #include <kernel-features.h>
  23
  24 #ifndef SAVE_PID
  25 #define SAVE_PID
  26 #endif
  27
  28 #ifndef RESTORE_PID
  29 #define RESTORE_PID
  30 #endif
  31
  32 /* Clone the calling process, but without copying the whole address space.
  33    The calling process is suspended until the new process exits or is
  34    replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
  35    and the process ID of the new process to the old process.  */
  36
  37 ENTRY (__vfork)
  38
  39 #ifdef __NR_vfork
  40
  41         /* SAVE_PID clobbers call-clobbered registers and
  42            saves data in D1 and A1.  */
  43
  44         SAVE_PID
  45
  46         /* Pop the return PC value into A0.  */
  47         movel   %sp@+, %a0
  48         cfi_adjust_cfa_offset (-4)
  49         cfi_register (%pc, %a0)
  50
  51         /* Stuff the syscall number in D0 and trap into the kernel.  */
  52         movel   #SYS_ify (vfork), %d0
  53         trap    #0
  54
  55         RESTORE_PID
  56
  57         tstl    %d0
  58         jmi     .Lerror         /* Branch forward if it failed.  */
  59
  60         /* Jump to the return PC.  */
  61         jmp     %a0@
  62
  63 .Lerror:
  64         /* Push back the return PC.  */
  65         movel   %a0,%sp@-
  66         cfi_adjust_cfa_offset (4)
  67         cfi_rel_offset (%pc, 0)
  68
  69 # ifdef __ASSUME_VFORK_SYSCALL
  70 #  ifndef PIC
  71         jbra    SYSCALL_ERROR_LABEL
  72 #  endif
  73 # else
  74         /* Check if vfork syscall is known at all.  */
  75         movel   #-ENOSYS,%d1
  76         cmpl    %d0,%d1
  77         jne     SYSCALL_ERROR_LABEL
  78
  79 # endif
  80 #endif
  81
  82 #ifndef __ASSUME_VFORK_SYSCALL
  83         /* If we don't have vfork, fork is close enough.  */
  84
  85         movel   #SYS_ify (fork), %d0
  86         trap    #0
  87         tstl    %d0
  88         jmi     SYSCALL_ERROR_LABEL
  89         rts
  90 #endif
  91
  92 PSEUDO_END (__vfork)
  93 libc_hidden_def (__vfork)
  94
  95 weak_alias (__vfork, vfork)