sysdeps/arm/armv6t2/memchr.S

   1 /* Copyright (C) 2011-2016 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Code contributed by Dave Gilbert <david.gilbert@linaro.org>
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21 @ This memchr routine is optimised on a Cortex-A9 and should work on all ARMv7
  22 @ and ARMv6T2 processors.  It has a fast path for short sizes, and has an
  23 @ optimised path for large data sets; the worst case is finding the match early
  24 @ in a large data set.
  25 @ Note: The use of cbz/cbnz means it's Thumb only
  26
  27 @ 2011-07-15 david.gilbert@linaro.org
  28 @    Copy from Cortex strings release 21 and change license
  29 @ http://bazaar.launchpad.net/~linaro-toolchain-dev/cortex-strings/trunk/view/head:/src/linaro-a9/memchr.S
  30 @    Change function declarations/entry/exit
  31 @ 2011-12-01 david.gilbert@linaro.org
  32 @    Add some fixes from comments received (including use of ldrd instead ldm)
  33 @ 2011-12-07 david.gilbert@linaro.org
  34 @    Removed cbz from align loop - can't be taken
  35
  36 @ this lets us check a flag in a 00/ff byte easily in either endianness
  37 #ifdef __ARMEB__
  38 #define CHARTSTMASK(c) 1<<(31-(c*8))
  39 #else
  40 #define CHARTSTMASK(c) 1<<(c*8)
  41 #endif
  42         .syntax unified
  43
  44         .text
  45 #ifdef NO_THUMB
  46         .arm
  47 #else
  48         .thumb
  49         .thumb_func
  50 #endif
  51         .global memchr
  52         .type memchr,%function
  53 ENTRY(memchr)
  54         @ r0 = start of memory to scan
  55         @ r1 = character to look for
  56         @ r2 = length
  57         @ returns r0 = pointer to character or NULL if not found
  58         and     r1,r1,#0xff     @ Don't think we can trust the caller to actually pass a char
  59
  60         cmp     r2,#16          @ If it's short don't bother with anything clever
  61         blt     20f
  62
  63         tst     r0, #7          @ If it's already aligned skip the next bit
  64         beq     10f
  65
  66         @ Work up to an aligned point
  67 5:
  68         sfi_breg r0, \
  69         ldrb    r3, [\B],#1
  70         subs    r2, r2, #1
  71         cmp     r3, r1
  72         beq     50f             @ If it matches exit found
  73         tst     r0, #7
  74         bne     5b              @ If not aligned yet then do next byte
  75
  76 10:
  77         @ At this point, we are aligned, we know we have at least 8 bytes to work with
  78         push    {r4,r5,r6,r7}
  79         cfi_adjust_cfa_offset (16)
  80         cfi_rel_offset (r4, 0)
  81         cfi_rel_offset (r5, 4)
  82         cfi_rel_offset (r6, 8)
  83         cfi_rel_offset (r7, 12)
  84
  85         cfi_remember_state
  86
  87         orr     r1, r1, r1, lsl #8      @ expand the match word across to all bytes
  88         orr     r1, r1, r1, lsl #16
  89         bic     r6, r2, #7      @ Number of double words to work with * 8
  90         mvns    r7, #0          @ all F's
  91         movs    r3, #0
  92
  93 15:
  94         sfi_breg r0, \
  95         ldrd    r4,r5, [\B],#8
  96 #ifndef NO_THUMB
  97         subs    r6, r6, #8
  98 #endif
  99         eor     r4,r4, r1       @ Get it so that r4,r5 have 00's where the bytes match the target
 100         eor     r5,r5, r1
 101         uadd8   r4, r4, r7      @ Parallel add 0xff - sets the GE bits for anything that wasn't 0
 102         sel     r4, r3, r7      @ bytes are 00 for none-00 bytes, or ff for 00 bytes - NOTE INVERSION
 103         uadd8   r5, r5, r7      @ Parallel add 0xff - sets the GE bits for anything that wasn't 0
 104         sel     r5, r4, r7      @ chained....bytes are 00 for none-00 bytes, or ff for 00 bytes - NOTE INVERSION
 105 #ifndef NO_THUMB
 106         cbnz    r5, 60f
 107 #else
 108         cmp     r5, #0
 109         bne     60f
 110         subs    r6, r6, #8
 111 #endif
 112         bne     15b             @ (Flags from the subs above) If not run out of bytes then go around again
 113
 114         pop     {r4,r5,r6,r7}
 115         cfi_adjust_cfa_offset (-16)
 116         cfi_restore (r4)
 117         cfi_restore (r5)
 118         cfi_restore (r6)
 119         cfi_restore (r7)
 120
 121         and     r1,r1,#0xff     @ Get r1 back to a single character from the expansion above
 122         and     r2,r2,#7        @ Leave the count remaining as the number after the double words have been done
 123
 124 20:
 125 #ifndef NO_THUMB
 126         cbz     r2, 40f         @ 0 length or hit the end already then not found
 127 #else
 128         cmp     r2, #0
 129         beq     40f
 130 #endif
 131
 132 21:  @ Post aligned section, or just a short call
 133         sfi_breg r0, \
 134         ldrb    r3,[\B],#1
 135 #ifndef NO_THUMB
 136         subs    r2,r2,#1
 137         eor     r3,r3,r1        @ r3 = 0 if match - doesn't break flags from sub
 138         cbz     r3, 50f
 139 #else
 140         eors    r3, r3, r1
 141         beq     50f
 142         subs    r2, r2, #1
 143 #endif
 144         bne     21b             @ on r2 flags
 145
 146 40:
 147         movs    r0,#0           @ not found
 148         DO_RET(lr)
 149
 150 50:
 151         subs    r0,r0,#1        @ found
 152         DO_RET(lr)
 153
 154 60:  @ We're here because the fast path found a hit - now we have to track down exactly which word it was
 155      @ r0 points to the start of the double word after the one that was tested
 156      @ r4 has the 00/ff pattern for the first word, r5 has the chained value
 157         cfi_restore_state
 158         cmp     r4, #0
 159         itte    eq
 160         moveq   r4, r5          @ the end is in the 2nd word
 161         subeq   r0,r0,#3        @ Points to 2nd byte of 2nd word
 162         subne   r0,r0,#7        @ or 2nd byte of 1st word
 163
 164         @ r0 currently points to the 2nd byte of the word containing the hit
 165         tst     r4, # CHARTSTMASK(0)    @ 1st character
 166         bne     61f
 167         adds    r0,r0,#1
 168         tst     r4, # CHARTSTMASK(1)    @ 2nd character
 169         ittt    eq
 170         addeq   r0,r0,#1
 171         tsteq   r4, # (3<<15)           @ 2nd & 3rd character
 172         @ If not the 3rd must be the last one
 173         addeq   r0,r0,#1
 174
 175 61:
 176         pop     {r4,r5,r6,r7}
 177         cfi_adjust_cfa_offset (-16)
 178         cfi_restore (r4)
 179         cfi_restore (r5)
 180         cfi_restore (r6)
 181         cfi_restore (r7)
 182
 183         subs    r0,r0,#1
 184         DO_RET(lr)
 185
 186 END(memchr)
 187 libc_hidden_builtin_def (memchr)