sysdeps/i386/bsd-setjmp.S

   1 /* BSD `setjmp' entry point to `sigsetjmp (..., 1)'.  i386 version.
   2    Copyright (C) 1994-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* This just does a tail-call to `__sigsetjmp (ARG, 1)'.
  20    We cannot do it in C because it must be a tail-call, so frame-unwinding
  21    in setjmp doesn't clobber the state restored by longjmp.  */
  22
  23 #include <sysdep.h>
  24 #include <jmpbuf-offsets.h>
  25 #include <stap-probe.h>
  26
  27 #define PARMS  4                /* no space for saved regs */
  28 #define JMPBUF PARMS
  29 #define SIGMSK JMPBUF+4
  30
  31 ENTRY (setjmp)
  32         /* Note that we have to use a non-exported symbol in the next
  33            jump since otherwise gas will emit it as a jump through the
  34            PLT which is what we cannot use here.  */
  35
  36         movl JMPBUF(%esp), %eax
  37
  38         /* Save registers.  */
  39         movl %ebx, (JB_BX*4)(%eax)
  40         movl %esi, (JB_SI*4)(%eax)
  41         movl %edi, (JB_DI*4)(%eax)
  42         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  43 #ifdef PTR_MANGLE
  44         PTR_MANGLE (%ecx)
  45 #endif
  46         movl %ecx, (JB_SP*4)(%eax)
  47         movl 0(%esp), %ecx      /* Save PC we are returning to now.  */
  48         LIBC_PROBE (setjmp, 3, 4@%eax, -4@$1, 4@%ecx)
  49 #ifdef PTR_MANGLE
  50         PTR_MANGLE (%ecx)
  51 #endif
  52         movl %ecx, (JB_PC*4)(%eax)
  53         movl %ebp, (JB_BP*4)(%eax) /* Save caller's frame pointer.  */
  54
  55         /* Call __sigjmp_save.  */
  56         pushl $1
  57         cfi_adjust_cfa_offset (4)
  58         pushl 8(%esp)
  59         cfi_adjust_cfa_offset (4)
  60         call __sigjmp_save
  61         popl %ecx
  62         cfi_adjust_cfa_offset (-4)
  63         popl %edx
  64         cfi_adjust_cfa_offset (-4)
  65         ret
  66 END (setjmp)