sysdeps/i386/fpu/e_acosh.S

   1 /* ix87 specific implementation of arcsinh.
   2    Copyright (C) 1996, 2005, 2011-2012 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <machine/asm.h>
  21
  22         .section .rodata.cst8,"aM",@progbits,8
  23
  24         .p2align 3
  25         ASM_TYPE_DIRECTIVE(one,@object)
  26 one:    .double 1.0
  27         ASM_SIZE_DIRECTIVE(one)
  28         ASM_TYPE_DIRECTIVE(limit,@object)
  29 limit:  .double 0.29
  30         ASM_SIZE_DIRECTIVE(limit)
  31
  32 #ifdef PIC
  33 #define MO(op) op##@GOTOFF(%edx)
  34 #else
  35 #define MO(op) op
  36 #endif
  37
  38         .text
  39 ENTRY(__ieee754_acosh)
  40         movl    8(%esp), %ecx
  41         cmpl    $0x3ff00000, %ecx
  42         jl      5f                      // < 1 => invalid
  43         fldln2                          // log(2)
  44         fldl    4(%esp)                 // x : log(2)
  45         cmpl    $0x41b00000, %ecx
  46         ja      3f                      // x > 2^28
  47 #ifdef  PIC
  48         LOAD_PIC_REG (dx)
  49 #endif
  50         cmpl    $0x40000000, %ecx
  51         ja      4f                      // x > 2
  52
  53         // 1 <= x <= 2 => y = log1p(x-1+sqrt(2*(x-1)+(x-1)^2))
  54         fsubl   MO(one)                 // x-1 : log(2)
  55         fld     %st                     // x-1 : x-1 : log(2)
  56         fmul    %st(1)                  // (x-1)^2 : x-1 : log(2)
  57         fadd    %st(1)                  // x-1+(x-1)^2 : x-1 : log(2)
  58         fadd    %st(1)                  // 2*(x-1)+(x-1)^2 : x-1 : log(2)
  59         fsqrt                           // sqrt(2*(x-1)+(x-1)^2) : x-1 : log(2)
  60         faddp                           // x-1+sqrt(2*(x-1)+(x-1)^2) : log(2)
  61         fcoml   MO(limit)
  62         fnstsw
  63         sahf
  64         ja      2f
  65         fyl2xp1                         // log1p(x-1+sqrt(2*(x-1)+(x-1)^2))
  66         ret
  67
  68 2:      faddl   MO(one)                 // x+sqrt(2*(x-1)+(x-1)^2) : log(2)
  69         fyl2x                           // log(x+sqrt(2*(x-1)+(x-1)^2))
  70         ret
  71
  72         // x > 2^28 => y = log(x) + log(2)
  73         .align ALIGNARG(4)
  74 3:      fyl2x                           // log(x)
  75         fldln2                          // log(2) : log(x)
  76         faddp                           // log(x)+log(2)
  77         ret
  78
  79         // 2^28 > x > 2 => y = log(2*x - 1/(x+sqrt(x*x-1)))
  80         .align ALIGNARG(4)
  81 4:      fld     %st                     // x : x : log(2)
  82         fadd    %st, %st(1)             // x : 2*x : log(2)
  83         fld     %st                     // x : x : 2*x : log(2)
  84         fmul    %st(1)                  // x^2 : x : 2*x : log(2)
  85         fsubl   MO(one)                 // x^2-1 : x : 2*x : log(2)
  86         fsqrt                           // sqrt(x^2-1) : x : 2*x : log(2)
  87         faddp                           // x+sqrt(x^2-1) : 2*x : log(2)
  88         fdivrl  MO(one)                 // 1/(x+sqrt(x^2-1)) : 2*x : log(2)
  89         fsubrp                          // 2*x+1/(x+sqrt(x^2)-1) : log(2)
  90         fyl2x                           // log(2*x+1/(x+sqrt(x^2-1)))
  91         ret
  92
  93         // x < 1 => NaN
  94         .align ALIGNARG(4)
  95 5:      fldz
  96         fdiv    %st, %st(0)
  97         ret
  98 END(__ieee754_acosh)
  99 strong_alias (__ieee754_acosh, __acosh_finite)