sysdeps/i386/fpu/s_asinhf.S

   1 /* ix87 specific implementation of arcsinh.
   2    Copyright (C) 1996-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <machine/asm.h>
  21
  22         .section .rodata
  23
  24         .align ALIGNARG(4)
  25         .type huge,@object
  26 huge:   .double 1e+36
  27         ASM_SIZE_DIRECTIVE(huge)
  28         .type one,@object
  29 one:    .double 1.0
  30         ASM_SIZE_DIRECTIVE(one)
  31         .type limit,@object
  32 limit:  .double 0.29
  33         ASM_SIZE_DIRECTIVE(limit)
  34
  35 #ifdef PIC
  36 #define MO(op) op##@GOTOFF(%edx)
  37 #else
  38 #define MO(op) op
  39 #endif
  40
  41         .text
  42 ENTRY(__asinhf)
  43         movl    4(%esp), %ecx
  44         movl    $0x7fffffff, %eax
  45         andl    %ecx, %eax
  46         andl    $0x80000000, %ecx
  47         movl    %eax, %edx
  48         orl     $0x807fffff, %edx
  49         incl    %edx
  50         jz      7f                      // x in ±Inf or NaN
  51         xorl    %ecx, 4(%esp)
  52         flds    4(%esp)                 // |x|
  53         cmpl    $0x38000000, %eax
  54         jb      2f                      // |x| < 2^-14
  55         fldln2                          // log(2) : |x|
  56         cmpl    $0x47000000, %eax
  57         fxch                            // |x| : log(2)
  58         ja      3f                      // |x| > 2^14
  59 #ifdef  PIC
  60         LOAD_PIC_REG (dx)
  61 #endif
  62         cmpl    $0x40000000, %eax
  63         ja      5f                      // |x| > 2
  64
  65         // 2^-14 <= |x| <= 2 => y = sign(x)*log1p(|x|+|x|^2/(1+sqrt(1+|x|^2)))
  66         fld     %st                     // |x| : |x| : log(2)
  67         fmul    %st(1)                  // |x|^2 : |x| : log(2)
  68         fld     %st                     // |x|^2 : |x|^2 : |x| : log(2)
  69         faddl   MO(one)                 // 1+|x|^2 : |x|^2 : |x| : log(2)
  70         fsqrt                           // sqrt(1+|x|^2) : |x|^2 : |x| : log(2)
  71         faddl   MO(one)                 // 1+sqrt(1+|x|^2) : |x|^2 : |x| : log(2)
  72         fdivrp                          // |x|^2/(1+sqrt(1+|x|^2)) : |x| : log(2)
  73         faddp                           // |x|+|x|^2/(1+sqrt(1+|x|^2)) : log(2)
  74         fcoml   MO(limit)
  75         fnstsw
  76         sahf
  77         ja      6f
  78         fyl2xp1
  79         jecxz   4f
  80         fchs
  81 4:      ret
  82
  83 7:      flds    4(%esp)
  84         ret
  85
  86 6:      faddl   MO(one)
  87         fyl2x
  88         jecxz   4f
  89         fchs
  90 4:      ret
  91
  92         // |x| < 2^-14 => y = x (inexact iff |x| != 0.0)
  93         .align ALIGNARG(4)
  94 2:
  95 #ifdef  PIC
  96         LOAD_PIC_REG (dx)
  97 #endif
  98         jecxz   4f
  99         fchs                            // x
 100 4:      fld     %st                     // x : x
 101         faddl   MO(huge)                // huge+x : x
 102         fstp    %st(0)                  // x
 103         ret
 104
 105         // |x| > 2^14 => y = sign(x) * (log(|x|) + log(2))
 106         .align ALIGNARG(4)
 107 3:      fyl2x                           // log(|x|)
 108         fldln2                          // log(2) : log(|x|)
 109         faddp                           // log(|x|)+log(2)
 110         jecxz   4f
 111         fchs
 112 4:      ret
 113
 114         // |x| > 2 => y = sign(x) * log(2*|x| + 1/(|x|+sqrt(x*x+1)))
 115         .align ALIGNARG(4)
 116 5:      fld     %st                     // |x| : |x| : log(2)
 117         fadd    %st, %st(1)             // |x| : 2*|x| : log(2)
 118         fld     %st                     // |x| : |x| : 2*|x| : log(2)
 119         fmul    %st(1)                  // |x|^2 : |x| : 2*|x| : log(2)
 120         faddl   MO(one)                 // 1+|x|^2 : |x| : 2*|x| : log(2)
 121         fsqrt                           // sqrt(1+|x|^2) : |x| : 2*|x| : log(2)
 122         faddp                           // |x|+sqrt(1+|x|^2) : 2*|x| : log(2)
 123         fdivrl  MO(one)                 // 1/(|x|+sqrt(1+|x|^2)) : 2*|x| : log(2)
 124         faddp                           // 2*|x|+1/(|x|+sqrt(1+|x|^2)) : log(2)
 125         fyl2x                           // log(2*|x|+1/(|x|+sqrt(1+|x|^2)))
 126         jecxz   4f
 127         fchs
 128 4:      ret
 129 END(__asinhf)
 130 weak_alias (__asinhf, asinhf)