sysdeps/i386/i686/memmove.S

   1 /* Copy memory block and return pointer to beginning of destination block
   2    For Intel 80x86, x>=6.
   3    This file is part of the GNU C Library.
   4    Copyright (C) 2003-2014 Free Software Foundation, Inc.
   5    Contributed by Ulrich Drepper <drepper@cygnus.com>, 2003.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, see
  19    <http://www.gnu.org/licenses/>.  */
  20
  21 #include <sysdep.h>
  22 #include "asm-syntax.h"
  23
  24 #define PARMS   4+4     /* one spilled register */
  25 #define RTN     PARMS
  26
  27         .text
  28
  29 #ifdef USE_AS_BCOPY
  30 # define SRC    RTN
  31 # define DEST   SRC+4
  32 # define LEN    DEST+4
  33 #else
  34 # define DEST   RTN
  35 # define SRC    DEST+4
  36 # define LEN    SRC+4
  37
  38 # if defined PIC && !defined NOT_IN_libc
  39 ENTRY_CHK (__memmove_chk)
  40         movl    12(%esp), %eax
  41         cmpl    %eax, 16(%esp)
  42         jb      HIDDEN_JUMPTARGET (__chk_fail)
  43 END_CHK (__memmove_chk)
  44 # endif
  45 #endif
  46
  47 ENTRY (memmove)
  48
  49         pushl   %edi
  50         cfi_adjust_cfa_offset (4)
  51
  52         movl    LEN(%esp), %ecx
  53         movl    DEST(%esp), %edi
  54         cfi_rel_offset (edi, 0)
  55         movl    %esi, %edx
  56         movl    SRC(%esp), %esi
  57         cfi_register (esi, edx)
  58
  59         movl    %edi, %eax
  60         subl    %esi, %eax
  61         cmpl    %eax, %edi
  62         jae     3f
  63
  64         cld
  65         shrl    $1, %ecx
  66         jnc     1f
  67         movsb
  68 1:      shrl    $1, %ecx
  69         jnc     2f
  70         movsw
  71 2:      rep
  72         movsl
  73         movl    %edx, %esi
  74         cfi_restore (esi)
  75 #ifndef USE_AS_BCOPY
  76         movl    DEST(%esp), %eax
  77 #endif
  78
  79         popl    %edi
  80         cfi_adjust_cfa_offset (-4)
  81         cfi_restore (edi)
  82
  83         ret
  84
  85         cfi_adjust_cfa_offset (4)
  86         cfi_rel_offset (edi, 0)
  87         cfi_register (esi, edx)
  88
  89         /* Backward copying.  */
  90 3:      std
  91         leal    -1(%edi, %ecx), %edi
  92         leal    -1(%esi, %ecx), %esi
  93         shrl    $1, %ecx
  94         jnc     1f
  95         movsb
  96 1:      subl    $1, %edi
  97         subl    $1, %esi
  98         shrl    $1, %ecx
  99         jnc     2f
 100         movsw
 101 2:      subl    $2, %edi
 102         subl    $2, %esi
 103         rep
 104         movsl
 105         movl    %edx, %esi
 106         cfi_restore (esi)
 107 #ifndef USE_AS_BCOPY
 108         movl    DEST(%esp), %eax
 109 #endif
 110
 111         cld
 112         popl    %edi
 113         cfi_adjust_cfa_offset (-4)
 114         cfi_restore (edi)
 115
 116         ret
 117 END (memmove)
 118 #ifndef USE_AS_BCOPY
 119 libc_hidden_builtin_def (memmove)
 120 #endif