sysdeps/ia64/fpu/s_nextafter.S

   1 .file "nextafter.s"
   2
   3
   4 // Copyright (c) 2000 - 2004, Intel Corporation
   5 // All rights reserved.
   6 //
   7 //
   8 // Redistribution and use in source and binary forms, with or without
   9 // modification, are permitted provided that the following conditions are
  10 // met:
  11 //
  12 // * Redistributions of source code must retain the above copyright
  13 // notice, this list of conditions and the following disclaimer.
  14 //
  15 // * Redistributions in binary form must reproduce the above copyright
  16 // notice, this list of conditions and the following disclaimer in the
  17 // documentation and/or other materials provided with the distribution.
  18 //
  19 // * The name of Intel Corporation may not be used to endorse or promote
  20 // products derived from this software without specific prior written
  21 // permission.
  22
  23 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  24 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  25 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  26 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  27 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  28 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  29 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  30 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  31 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  32 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  33 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  34 //
  35 // Intel Corporation is the author of this code, and requests that all
  36 // problem reports or change requests be submitted to it directly at
  37 // http://www.intel.com/software/products/opensource/libraries/num.htm.
  38 //
  39 // History
  40 //==============================================================
  41 // 02/02/00 Initial version
  42 // 03/03/00 Modified to conform to C9X, and improve speed of main path
  43 // 03/14/00 Fixed case where x is a power of 2, and x > y, improved speed
  44 // 04/04/00 Unwind support added
  45 // 05/12/00 Fixed erroneous denormal flag setting for exponent change cases 1,3
  46 // 08/15/00 Bundle added after call to __libm_error_support to properly
  47 //          set [the previously overwritten] GR_Parameter_RESULT.
  48 // 09/09/00 Updated fcmp so that qnans do not raise invalid
  49 // 12/15/00 Corrected behavior when both args are zero to conform to C99, and
  50 //          fixed flag settings for several cases
  51 // 05/20/02 Cleaned up namespace and sf0 syntax
  52 // 02/10/03 Reordered header: .section, .global, .proc, .align
  53 // 12/14/04 Added error handling on underflow.
  54 //
  55 // API
  56 //==============================================================
  57 // double nextafter( double x, double y );
  58 // input  floating point f8, f9
  59 // output floating point f8
  60 //
  61 // Registers used
  62 //==============================================================
  63 GR_max_pexp     = r14
  64 GR_min_pexp     = r15
  65 GR_exp          = r16
  66 GR_sig          = r17
  67 GR_lnorm_sig    = r18
  68 GR_sign_mask    = r19
  69 GR_exp_mask     = r20
  70 GR_sden_sig     = r21
  71 GR_new_sig      = r22
  72 GR_new_exp      = r23
  73 GR_lden_sig     = r24
  74 GR_snorm_sig    = r25
  75 GR_exp1         = r26
  76 GR_x_exp        = r27
  77 GR_min_den_rexp = r28
  78 // r36-39 parameters for libm_error_support
  79
  80 GR_SAVE_B0                = r34
  81 GR_SAVE_GP                = r35
  82 GR_SAVE_PFS               = r32
  83
  84 GR_Parameter_X            = r36
  85 GR_Parameter_Y            = r37
  86 GR_Parameter_RESULT       = r38
  87 GR_Parameter_TAG          = r39
  88
  89 FR_lnorm_sig       = f10
  90 FR_lnorm_exp       = f11
  91 FR_lnorm           = f12
  92 FR_sden_sig        = f13
  93 FR_sden_exp        = f14
  94 FR_sden            = f15
  95 FR_save_f8         = f33
  96 FR_new_exp         = f34
  97 FR_new_sig         = f35
  98 FR_lden_sig        = f36
  99 FR_snorm_sig       = f37
 100 FR_exp1            = f38
 101 FR_tmp             = f39
 102
 103 //
 104 // Overview of operation
 105 //==============================================================
 106 // nextafter determines the next representable value
 107 // after x in the direction of y.
 108
 109
 110 .section .text
 111 GLOBAL_LIBM_ENTRY(nextafter)
 112
 113 // Extract signexp from x
 114 // Is x < y ?  p10 if yes, p11 if no
 115 // Form smallest denormal significand = ulp size
 116 { .mfi
 117       getf.exp GR_exp      = f8
 118       fcmp.lt.s1 p10,p11 = f8, f9
 119       addl GR_sden_sig = 0x800, r0
 120 }
 121 // Form largest normal significand 0xfffffffffffff800
 122 // Form smallest normal exponent
 123 { .mfi
 124       addl GR_lnorm_sig = -0x800,r0
 125       nop.f 999
 126       addl GR_min_pexp = 0x0fc01, r0 ;;
 127 }
 128 // Extract significand from x
 129 // Is x=y?
 130 // Form largest normal exponent
 131 { .mfi
 132       getf.sig GR_sig      = f8
 133       fcmp.eq.s0 p6,p0 = f8, f9
 134       addl GR_max_pexp = 0x103fe, r0
 135 }
 136 // Move largest normal significand to fp reg for special cases
 137 { .mfi
 138       setf.sig FR_lnorm_sig = GR_lnorm_sig
 139       nop.f 999
 140       addl GR_sign_mask = 0x20000, r0 ;;
 141 }
 142
 143 // Move smallest denormal significand and signexp to fp regs
 144 // Is x=nan?
 145 // Set p12 and p13 based on whether significand increases or decreases
 146 // It increases (p12 set) if x<y and x>=0 or if x>y and x<0
 147 // It decreases (p13 set) if x<y and x<0  or if x>y and x>=0
 148 { .mfi
 149       setf.sig FR_sden_sig = GR_sden_sig
 150       fclass.m  p8,p0 = f8, 0xc3
 151 (p10) cmp.lt p12,p13 = GR_exp, GR_sign_mask
 152 }
 153 { .mfi
 154       setf.exp FR_sden_exp = GR_min_pexp
 155 (p11) cmp.ge p12,p13 = GR_exp, GR_sign_mask ;;
 156 }
 157
 158 .pred.rel "mutex",p12,p13
 159
 160 // Form expected new significand, adding or subtracting 1 ulp increment
 161 // If x=y set result to y
 162 // Form smallest normal significand and largest denormal significand
 163 { .mfi
 164 (p12) add GR_new_sig = GR_sig, GR_sden_sig
 165 (p6)  fmerge.s f8=f9,f9
 166       dep.z GR_snorm_sig = 1,63,1 // 0x8000000000000000
 167 }
 168 { .mlx
 169 (p13) sub GR_new_sig = GR_sig, GR_sden_sig
 170       movl GR_lden_sig = 0x7ffffffffffff800 ;;
 171 }
 172
 173 // Move expected result significand and signexp to fp regs
 174 // Is y=nan?
 175 // Form new exponent in case result exponent needs incrementing or decrementing
 176 { .mfi
 177       setf.exp FR_new_exp = GR_exp
 178       fclass.m  p9,p0 = f9, 0xc3
 179 (p12) add GR_exp1 = 1, GR_exp
 180 }
 181 { .mib
 182       setf.sig FR_new_sig = GR_new_sig
 183 (p13) add GR_exp1 = -1, GR_exp
 184 (p6)  br.ret.spnt    b0 ;;             // Exit if x=y
 185 }
 186
 187 // Move largest normal signexp to fp reg for special cases
 188 // Is x=zero?
 189 { .mfi
 190       setf.exp FR_lnorm_exp = GR_max_pexp
 191       fclass.m  p7,p0 = f8, 0x7
 192       nop.i 999
 193 }
 194 { .mfb
 195       nop.m 999
 196 (p8)  fma.s0 f8 = f8,f1,f9
 197 (p8)  br.ret.spnt    b0 ;;             // Exit if x=nan
 198 }
 199
 200 // Move exp+-1 and smallest normal significand to fp regs for special cases
 201 // Is x=inf?
 202 { .mfi
 203       setf.exp FR_exp1 = GR_exp1
 204       fclass.m  p6,p0 = f8, 0x23
 205       addl GR_exp_mask = 0x1ffff, r0
 206 }
 207 { .mfb
 208       setf.sig FR_snorm_sig = GR_snorm_sig
 209 (p9)  fma.s0 f8 = f8,f1,f9
 210 (p9)  br.ret.spnt    b0 ;;             // Exit if y=nan
 211 }
 212
 213 // Move largest denormal significand to fp regs for special cases
 214 // Save x
 215 { .mfb
 216       setf.sig FR_lden_sig = GR_lden_sig
 217       mov FR_save_f8 = f8
 218 (p7)  br.cond.spnt NEXT_ZERO ;;   // Exit if x=0
 219 }
 220
 221 // Mask off the sign to get x_exp
 222 { .mfb
 223       and GR_x_exp = GR_exp_mask, GR_exp
 224       nop.f 999
 225 (p6)  br.cond.spnt NEXT_INF ;;   // Exit if x=inf
 226 }
 227
 228 // Check 6 special cases when significand rolls over:
 229 //  1 sig size incr, x_sig=max_sig, x_exp < max_exp
 230 //     Set p6, result is sig=min_sig, exp++
 231 //  2 sig size incr, x_sig=max_sig, x_exp >= max_exp
 232 //     Set p7, result is inf, signal overflow
 233 //  3 sig size decr, x_sig=min_sig, x_exp > min_exp
 234 //     Set p8, result is sig=max_sig, exp--
 235 //  4 sig size decr, x_sig=min_sig, x_exp = min_exp
 236 //     Set p9, result is sig=max_den_sig, exp same, signal underflow and inexact
 237 //  5 sig size decr, x_sig=min_den_sig, x_exp = min_exp
 238 //     Set p10, result is zero, sign of x, signal underflow and inexact
 239 //  6 sig size decr, x_sig=min_sig, x_exp < min_exp
 240 //     Set p14, result is zero, sign of x, signal underflow and inexact
 241 //
 242 // Form exponent of smallest double denormal (if normalized register format)
 243 { .mmi
 244       adds GR_min_den_rexp = -52, GR_min_pexp
 245 (p12) cmp.eq.unc p6,p0 = GR_new_sig, r0
 246 (p13) cmp.eq.unc p8,p10 = GR_new_sig, GR_lden_sig ;;
 247 }
 248
 249 { .mmi
 250 (p6)  cmp.lt.unc p6,p7 = GR_x_exp, GR_max_pexp
 251 (p8)  cmp.gt.unc p8,p9 = GR_x_exp, GR_min_pexp
 252 (p10) cmp.eq.unc p10,p0 = GR_new_sig, r0 ;;
 253 }
 254
 255 // Create small normal in case need to generate underflow flag
 256 { .mfi
 257 (p10) cmp.le.unc p10,p0 = GR_x_exp, GR_min_pexp
 258       fmerge.se FR_tmp = FR_sden_exp, FR_lnorm_sig
 259 (p9)  cmp.gt.unc p9,p14 = GR_x_exp, GR_min_den_rexp
 260 }
 261 // Branch if cases 1, 2, 3
 262 { .bbb
 263 (p6)  br.cond.spnt NEXT_EXPUP
 264 (p7)  br.cond.spnt NEXT_OVERFLOW
 265 (p8)  br.cond.spnt NEXT_EXPDOWN ;;
 266 }
 267
 268 // Branch if cases 4, 5, 6
 269 { .bbb
 270 (p9)  br.cond.spnt NEXT_NORM_TO_DENORM
 271 (p10) br.cond.spnt NEXT_UNDERFLOW_TO_ZERO
 272 (p14) br.cond.spnt NEXT_UNDERFLOW_TO_ZERO ;;
 273 }
 274
 275 // Here if no special cases
 276 // Set p6 if result will be a denormal, so can force underflow flag
 277 //    Case 1:  x_exp=min_exp, x_sig=unnormalized
 278 //    Case 2:  x_exp<min_exp
 279 { .mfi
 280       cmp.lt p6,p7 = GR_x_exp, GR_min_pexp
 281       fmerge.se f8 = FR_new_exp, FR_new_sig
 282       nop.i 999 ;;
 283 }
 284
 285 { .mfi
 286       nop.m 999
 287       nop.f 999
 288 (p7)  tbit.z p6,p0 = GR_new_sig, 63 ;;
 289 }
 290
 291 NEXT_COMMON_FINISH:
 292 // Force underflow and inexact if denormal result
 293 { .mfi
 294       nop.m 999
 295 (p6)  fma.d.s0 FR_tmp = FR_tmp,FR_tmp,f0
 296       nop.i 999
 297 }
 298 { .mfb
 299       nop.m 999
 300       fnorm.d.s0 f8 = f8 // Final normalization to result precision
 301 (p6)  br.cond.spnt NEXT_UNDERFLOW ;;
 302 }
 303
 304 { .mfb
 305       nop.m 999
 306       nop.f 999
 307       br.ret.sptk b0;;
 308 }
 309
 310 //Special cases
 311 NEXT_EXPUP:
 312 { .mfb
 313       cmp.lt p6,p7 = GR_x_exp, GR_min_pexp
 314       fmerge.se f8 = FR_exp1, FR_snorm_sig
 315       br.cond.sptk NEXT_COMMON_FINISH ;;
 316 }
 317
 318 NEXT_EXPDOWN:
 319 { .mfb
 320       cmp.lt p6,p7 = GR_x_exp, GR_min_pexp
 321       fmerge.se f8 = FR_exp1, FR_lnorm_sig
 322       br.cond.sptk NEXT_COMMON_FINISH ;;
 323 }
 324
 325 NEXT_NORM_TO_DENORM:
 326 { .mfi
 327       nop.m 999
 328       fmerge.se f8 = FR_new_exp, FR_lden_sig
 329       nop.i 999
 330 }
 331 // Force underflow and inexact if denormal result
 332 { .mfb
 333       nop.m 999
 334       fma.d.s0 FR_tmp = FR_tmp,FR_tmp,f0
 335       br.cond.sptk NEXT_UNDERFLOW ;;
 336 }
 337
 338 NEXT_UNDERFLOW_TO_ZERO:
 339 { .mfb
 340       cmp.eq p6,p0 = r0,r0
 341       fmerge.s f8 = FR_save_f8,f0
 342       br.cond.sptk NEXT_COMMON_FINISH ;;
 343 }
 344
 345 NEXT_INF:
 346 // Here if f8 is +- infinity
 347 // INF
 348 // if f8 is +inf, no matter what y is return  largest double
 349 // if f8 is -inf, no matter what y is return -largest double
 350
 351 { .mfi
 352       nop.m 999
 353       fmerge.se FR_lnorm = FR_lnorm_exp,FR_lnorm_sig
 354       nop.i 999 ;;
 355 }
 356
 357 { .mfb
 358       nop.m 999
 359       fmerge.s f8 = f8,FR_lnorm
 360       br.ret.sptk    b0 ;;
 361 }
 362
 363 NEXT_ZERO:
 364
 365 // Here if f8 is +- zero
 366 // ZERO
 367 // if f8 is zero and y is +, return + smallest double denormal
 368 // if f8 is zero and y is -, return - smallest double denormal
 369
 370 { .mfi
 371       nop.m 999
 372       fmerge.se FR_sden = FR_sden_exp,FR_sden_sig
 373       nop.i 999 ;;
 374 }
 375
 376 // Create small normal to generate underflow flag
 377 { .mfi
 378       nop.m 999
 379       fmerge.se FR_tmp = FR_sden_exp, FR_lnorm_sig
 380       nop.i 999 ;;
 381 }
 382
 383 // Add correct sign from direction arg
 384 { .mfi
 385       nop.m 999
 386       fmerge.s f8 = f9,FR_sden
 387       nop.i 999 ;;
 388 }
 389
 390 // Force underflow and inexact flags
 391 { .mfb
 392       nop.m 999
 393       fma.d.s0 FR_tmp = FR_tmp,FR_tmp,f0
 394       br.cond.sptk NEXT_UNDERFLOW ;;
 395 }
 396
 397 NEXT_UNDERFLOW:
 398 // Here if result is a denorm, or input is finite and result is zero
 399 // Call error support to report possible range error
 400 { .mib
 401       alloc          r32=ar.pfs,2,2,4,0
 402       mov           GR_Parameter_TAG = 268      // Error code
 403       br.cond.sptk  __libm_error_region    // Branch to error call
 404 }
 405 ;;
 406
 407 NEXT_OVERFLOW:
 408 // Here if input is finite, but result will be infinite
 409 // Use frcpa to generate infinity of correct sign
 410 // Call error support to report possible range error
 411 { .mfi
 412       alloc          r32=ar.pfs,2,2,4,0
 413       frcpa.s1 f8,p6 = FR_save_f8, f0
 414       nop.i 999 ;;
 415 }
 416
 417 // Create largest double
 418 { .mfi
 419       nop.m 999
 420       fmerge.se FR_lnorm = FR_lnorm_exp,FR_lnorm_sig
 421       nop.i 999 ;;
 422 }
 423
 424 // Force overflow and inexact flags to be set
 425 { .mfb
 426       mov           GR_Parameter_TAG = 154      // Error code
 427       fma.d.s0 FR_tmp = FR_lnorm,FR_lnorm,f0
 428       br.cond.sptk  __libm_error_region    // Branch to error call
 429 }
 430 ;;
 431
 432 GLOBAL_LIBM_END(nextafter)
 433 libm_alias_double_other (nextafter, nextafter)
 434
 435
 436 LOCAL_LIBM_ENTRY(__libm_error_region)
 437 .prologue
 438
 439 // (1)
 440 { .mfi
 441         add   GR_Parameter_Y=-32,sp             // Parameter 2 value
 442         nop.f 0
 443 .save   ar.pfs,GR_SAVE_PFS
 444         mov  GR_SAVE_PFS=ar.pfs                 // Save ar.pfs
 445 }
 446 { .mfi
 447 .fframe 64
 448         add sp=-64,sp                          // Create new stack
 449         nop.f 0
 450         mov GR_SAVE_GP=gp                      // Save gp
 451 };;
 452
 453
 454 // (2)
 455 { .mmi
 456         stfd [GR_Parameter_Y] = f9,16         // STORE Parameter 2 on stack
 457         add GR_Parameter_X = 16,sp            // Parameter 1 address
 458 .save   b0, GR_SAVE_B0
 459         mov GR_SAVE_B0=b0                     // Save b0
 460 };;
 461
 462 .body
 463 // (3)
 464 { .mib
 465         stfd [GR_Parameter_X] = FR_save_f8              // STORE Parameter 1 on stack
 466         add   GR_Parameter_RESULT = 0,GR_Parameter_Y           // Parameter 3 address
 467         nop.b 0
 468 }
 469 { .mib
 470         stfd [GR_Parameter_Y] = f8              // STORE Parameter 3 on stack
 471         add   GR_Parameter_Y = -16,GR_Parameter_Y
 472         br.call.sptk b0=__libm_error_support#   // Call error handling function
 473 };;
 474 { .mmi
 475         nop.m 0
 476         nop.m 0
 477         add   GR_Parameter_RESULT = 48,sp
 478 };;
 479
 480 // (4)
 481 { .mmi
 482         ldfd  f8 = [GR_Parameter_RESULT]       // Get return result off stack
 483 .restore sp
 484         add   sp = 64,sp                       // Restore stack pointer
 485         mov   b0 = GR_SAVE_B0                  // Restore return address
 486 };;
 487 { .mib
 488         mov   gp = GR_SAVE_GP                  // Restore gp
 489         mov   ar.pfs = GR_SAVE_PFS             // Restore ar.pfs
 490         br.ret.sptk     b0                     // Return
 491 };;
 492
 493 LOCAL_LIBM_END(__libm_error_region)
 494
 495
 496 .type   __libm_error_support#,@function
 497 .global __libm_error_support#