sysdeps/powerpc/powerpc32/fpu/s_copysignl.S

   1 /* Copy a sign bit between floating-point values.
   2    IBM extended format long double version.
   3    Copyright (C) 2006-2019 Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23 ENTRY(__copysignl)
  24 /* long double [f1,f2] copysign (long double [f1,f2] x, long double [f3,f4] y);
  25    copysign(x,y) returns a value with the magnitude of x and
  26    with the sign bit of y.  */
  27 #ifdef _ARCH_PPCGR
  28         /* fsel available.  */
  29         stwu    r1,-16(r1)
  30         cfi_adjust_cfa_offset (16)
  31         stfd    fp3,8(r1)
  32         fmr     fp0,fp1
  33         fabs    fp1,fp1
  34         lwz     r3,8+HIWORD(r1)
  35         cmpwi   cr6,r3,0
  36         addi    r1,r1,16
  37         cfi_adjust_cfa_offset (-16)
  38         fneg    fp3,fp2
  39         fsel    fp2,fp0,fp2,fp3
  40         bgelr   cr6
  41         fneg    fp1,fp1
  42         fneg    fp2,fp2
  43         blr
  44 #else
  45         stwu    r1,-32(r1)
  46         cfi_adjust_cfa_offset (32)
  47         stfd    fp3,8(r1)
  48         stfd    fp1,16(r1)
  49         lwz     r3,8+HIWORD(r1)
  50         lwz     r4,16+HIWORD(r1)
  51         xor     r3,r3,r4
  52         cmpwi   cr6,r3,0
  53         addi    r1,r1,32
  54         cfi_adjust_cfa_offset (-32)
  55         bgelr   cr6
  56         fneg    fp1,fp1
  57         fneg    fp2,fp2
  58         blr
  59 #endif
  60 END (__copysignl)
  61
  62 #if IS_IN (libm)
  63 long_double_symbol (libm, __copysignl, copysignl)
  64 #else
  65 long_double_symbol (libc, __copysignl, copysignl)
  66 #endif