sysdeps/powerpc/powerpc32/fpu/s_nearbyint.S

   1 /* Round to int floating-point values.  PowerPC32 version.
   2    Copyright (C) 2011-2019 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Adhemerval Zanella <azanella@br.ibm.com>, 2011
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 /* This has been coded in assembler because GCC makes such a mess of it
  21    when it's coded in C.  */
  22
  23 #include <sysdep.h>
  24 #include <math_ldbl_opt.h>
  25 #include <libm-alias-double.h>
  26
  27
  28 /* double [fp1] nearbyint(double [fp1] x) */
  29
  30         .section        .rodata.cst4,"aM",@progbits,4
  31         .align  2
  32 .LC0:   /* 2**52 */
  33         .long 0x59800000        /* TWO52: 2**52 */
  34
  35         .section        ".text"
  36 ENTRY (__nearbyint)
  37 #ifdef SHARED
  38         mflr    r11
  39         cfi_register(lr,r11)
  40         bcl     20,31,1f
  41 1:      mflr    r9
  42         addis   r9,r9,.LC0-1b@ha
  43         lfs     fp13,.LC0-1b@l(r9)
  44         mtlr    r11
  45         cfi_same_value (lr)
  46 #else
  47         lis     r9,.LC0@ha
  48         lfs     fp13,.LC0@l(r9)
  49 #endif
  50         fabs    fp0,fp1
  51         fsub    fp12,fp13,fp13  /* generate 0.0  */
  52         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52 */
  53         bge     cr7,.L10
  54         fcmpu   cr7,fp1,fp12    /* if (x > 0.0 */
  55         ble     cr7,L(lessthanzero)
  56         mffs    fp11
  57         mtfsb0  4*cr7+lt        /* Disable FE_INEXACT exception */
  58         fadd    fp1,fp1,fp13    /* x += TWO52 */
  59         fsub    fp1,fp1,fp13    /* x -= TWO52 */
  60         fabs    fp1,fp1         /* if (x == 0.0 */
  61         mtfsf   0xff,fp11       /* Restore FE_INEXACT state.  */
  62         blr
  63 L(lessthanzero):
  64         bgelr   cr7
  65         mffs    fp11
  66         mtfsb0  4*cr7+lt        /* Disable FE_INEXACT exception */
  67         fsub    fp1,fp1,fp13    /* x -= TWO52 */
  68         fadd    fp1,fp1,fp13    /* x += TWO52 */
  69         fnabs   fp1,fp1         /* if (x == 0.0) */
  70         mtfsf   0xff,fp11       /* Restore FE_INEXACT state.  */
  71         blr
  72 .L10:
  73         /* Ensure sNaN input is converted to qNaN.  */
  74         fcmpu   cr7,fp1,fp1
  75         beqlr   cr7
  76         fadd    fp1,fp1,fp1
  77         blr
  78 END (__nearbyint)
  79
  80 libm_alias_double (__nearbyint, nearbyint)