sysdeps/powerpc/powerpc32/fpu/s_rint.S

   1 /* Round to int floating-point values.  PowerPC32 version.
   2    Copyright (C) 2004-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* This has been coded in assembler because GCC makes such a mess of it
  20    when it's coded in C.  */
  21
  22 #include <sysdep.h>
  23 #include <math_ldbl_opt.h>
  24
  25         .section        .rodata.cst4,"aM",@progbits,4
  26         .align  2
  27 .LC0:   /* 2**52 */
  28         .long 0x59800000
  29
  30         .section        ".text"
  31 ENTRY (__rint)
  32 #ifdef SHARED
  33         mflr    r11
  34         cfi_register(lr,r11)
  35         SETUP_GOT_ACCESS(r9,got_label)
  36         addis   r9,r9,.LC0-got_label@ha
  37         lfs     fp13,.LC0-got_label@l(r9)
  38         mtlr    r11
  39         cfi_same_value (lr)
  40 #else
  41         lis     r9,.LC0@ha
  42         lfs     fp13,.LC0@l(r9)
  43 #endif
  44         fabs    fp0,fp1
  45         fsub    fp12,fp13,fp13  /* generate 0.0  */
  46         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  47         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  48         bnllr   cr7
  49         bng     cr6,.L4
  50         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  51         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  52         fabs    fp1,fp1         /* if (x == 0.0)  */
  53         blr                     /* x = 0.0; */
  54 .L4:
  55         bnllr   cr6             /* if (x < 0.0)  */
  56         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  57         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  58         fnabs   fp1,fp1         /* if (x == 0.0)  */
  59         blr                     /* x = -0.0; */
  60         END (__rint)
  61
  62 weak_alias (__rint, rint)
  63
  64 #ifdef NO_LONG_DOUBLE
  65 weak_alias (__rint, rintl)
  66 strong_alias (__rint, __rintl)
  67 #endif
  68 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_0)
  69 compat_symbol (libm, __rint, rintl, GLIBC_2_0)
  70 #endif