sysdeps/powerpc/powerpc32/fpu/s_trunc.S

   1 /* trunc function.  PowerPC32 version.
   2    Copyright (C) 2004-2016 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <math_ldbl_opt.h>
  21
  22         .section        .rodata.cst4,"aM",@progbits,4
  23         .align  2
  24 .LC0:   /* 2**52 */
  25         .long 0x59800000
  26
  27 /* double [fp1] trunc (double x [fp1])
  28    IEEE 1003.1 trunc function.  IEEE specifies "trunc to the integer
  29    value, in floating format, nearest to but no larger in magnitude
  30    then the argument."
  31    We set "round toward Zero" mode and trunc by adding +-2**52 then
  32    subtracting +-2**52.  */
  33
  34         .section        ".text"
  35 ENTRY (__trunc)
  36         mffs    fp11            /* Save current FPU rounding mode.  */
  37 #ifdef SHARED
  38         mflr    r11
  39         cfi_register(lr,r11)
  40         SETUP_GOT_ACCESS(r9,got_label)
  41         addis   r9,r9,.LC0-got_label@ha
  42         lfs     fp13,.LC0-got_label@l(r9)
  43         mtlr    r11
  44         cfi_same_value (lr)
  45 #else
  46         lis     r9,.LC0@ha
  47         lfs     fp13,.LC0@l(r9)
  48 #endif
  49         fabs    fp0,fp1
  50         fsub    fp12,fp13,fp13  /* generate 0.0  */
  51         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  52         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  53         bnllr-  cr7
  54         mtfsfi  7,1             /* Set rounding toward 0 mode.  */
  55         ble-    cr6,.L4
  56         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  57         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  58         fabs    fp1,fp1         /* if (x == 0.0)  */
  59                                 /* x = 0.0; */
  60         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  61         blr
  62 .L4:
  63         bge-    cr6,.L9         /* if (x < 0.0)  */
  64         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  65         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  66         fnabs   fp1,fp1         /* if (x == 0.0)  */
  67                                 /* x = -0.0; */
  68 .L9:
  69         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  70         blr
  71         END (__trunc)
  72
  73 weak_alias (__trunc, trunc)
  74
  75 #ifdef NO_LONG_DOUBLE
  76 weak_alias (__trunc, truncl)
  77 strong_alias (__trunc, __truncl)
  78 #endif
  79 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_1)
  80 compat_symbol (libm, __trunc, truncl, GLIBC_2_1)
  81 #endif